doc: Add 'fs nukenfscreds' manpage
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([pam],
79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
80     ,
81     [enable_pam="yes"])
82 AC_ARG_ENABLE([gtx],
83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
84 AC_ARG_ENABLE([uss],
85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
86 AC_ARG_ENABLE([namei-fileserver],
87     [AS_HELP_STRING([--enable-namei-fileserver],
88         [force compilation of namei fileserver in preference to inode
89          fileserver])],
90     , 
91     [enable_namei_fileserver="default"])
92 AC_ARG_ENABLE([supergroups],
93     [AS_HELP_STRING([--enable-supergroups],
94         [enable support for nested pts groups])],
95     , 
96     [enable_supergroups="no"])
97 AC_ARG_ENABLE([bitmap-later],
98     [AS_HELP_STRING([--enable-bitmap-later],
99         [enable fast startup of file server by not reading bitmap till
100          needed])],
101     , 
102     [enable_bitmap_later="no"])
103 AC_ARG_ENABLE([unix-sockets],
104     [AS_HELP_STRING([--disable-unix-sockets],
105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
106     ,
107     [enable_unix_sockets="yes"])
108 AC_ARG_ENABLE([tivoli-tsm],
109     [AS_HELP_STRING([--enable-tivoli-tsm],
110         [enable use of the Tivoli TSM API libraries for butc support])],
111     , 
112     [enable_tivoli_tsm="no"])
113 AC_ARG_ENABLE([pthreaded-ubik],
114     [AS_HELP_STRING([--enable-pthreaded-ubik],
115         [enable installation of pthreaded ubik applications (defaults to
116          disabled)])],
117     ,
118     [enable_pthreaded_ubik="no"])
119
120 dnl Kernel module build options.
121 AC_ARG_WITH([linux-kernel-headers],
122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
123         [use the kernel headers found at path (optional, defaults to
124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
126 AC_ARG_WITH([linux-kernel-build],
127     [AS_HELP_STRING([--with-linux-kernel-build=path],
128         [use the kernel build found at path(optional, defaults to 
129         kernel headers path)])])
130 AC_ARG_WITH([bsd-kernel-headers],
131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
132         [use the kernel headers found at path (optional, defaults to
133          /usr/src/sys)])])
134 AC_ARG_WITH([bsd-kernel-build],
135     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
136         [use the kernel build found at path (optional, defaults to
137          KSRC/i386/compile/GENERIC)])])
138 AC_ARG_WITH([linux-kernel-packaging],
139     [AS_HELP_STRING([--with-linux-kernel-packaging],
140         [use standard naming conventions to aid Linux kernel build packaging
141          (disables MPS, sets the kernel module name to openafs.ko, and
142          installs kernel modules into the standard Linux location)])],
143     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
144      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
145     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
146 AC_ARG_ENABLE([kernel-module],
147     [AS_HELP_STRING([--disable-kernel-module],
148         [disable compilation of the kernel module (defaults to enabled)])],
149     , 
150     [enable_kernel_module="yes"])
151 AC_ARG_ENABLE([redhat-buildsys],
152     [AS_HELP_STRING([--enable-redhat-buildsys],
153         [enable compilation of the redhat build system kernel (defaults to
154          disabled)])],
155     ,
156     [enable_redhat_buildsys="no"])
157
158 dnl Installation locations.
159 AC_ARG_ENABLE([transarc-paths],
160     [AS_HELP_STRING([--enable-transarc-paths],
161         [use Transarc style paths like /usr/afs and /usr/vice])],
162     , 
163     [enable_transarc_paths="no"])
164
165 dnl Deprecated crypto
166 AC_ARG_ENABLE([kauth],
167     [AS_HELP_STRING([--disable-kauth],
168         [do not install the deprecated kauth server and utilities (defaults to
169          enabled)])],
170     ,
171     [enable_kauth="yes"])
172
173 dnl Optimization and debugging flags.
174 AC_ARG_ENABLE([strip-binaries],
175     [AS_HELP_STRING([--disable-strip-binaries],
176         [disable stripping of symbol information from binaries (defaults to
177          enabled)])],
178     ,
179     [enable_strip_binaries="maybe"])
180 AC_ARG_ENABLE([debug],
181     [AS_HELP_STRING([--enable-debug],
182         [enable compilation of the user space code with debugging information
183          (defaults to disabled)])],
184     , 
185     [enable_debug="no"])
186 AC_ARG_ENABLE([optimize],
187     [AS_HELP_STRING([--disable-optimize],
188         [disable optimization for compilation of the user space code (defaults
189          to enabled)])],
190     , 
191     [enable_optimize="yes"])
192 AC_ARG_ENABLE([warnings],
193     [AS_HELP_STRING([--enable-warnings],
194         [enable compilation warnings when building with gcc (defaults to
195          disabled)])],
196     ,
197     [enable_warnings="no"])
198 AC_ARG_ENABLE([checking],
199     [AS_HELP_STRING([--enable-checking],
200         [turn compilation warnings into errors when building with gcc (defaults
201          to disabled)])],
202     [enable_checking="$enableval"],
203     [enable_checking="no"])
204 AC_ARG_ENABLE([debug-locks],
205     [AS_HELP_STRING([--enable-debug-locks],
206         [turn on lock debugging assertions (defaults to disabled)])],
207     [enable_debug_locks="$enableval"],
208     [enable_debug_locks="no"])
209 AC_ARG_ENABLE([debug-kernel],
210     [AS_HELP_STRING([--enable-debug-kernel],
211         [enable compilation of the kernel module with debugging information
212          (defaults to disabled)])],
213     ,
214     [enable_debug_kernel="no"])
215 AC_ARG_ENABLE([optimize-kernel],
216     [AS_HELP_STRING([--disable-optimize-kernel],
217         [disable compilation of the kernel module with optimization (defaults
218          based on platform)])],
219     , 
220     [enable_optimize_kernel=""])
221 AC_ARG_ENABLE([debug-lwp],
222     [AS_HELP_STRING([--enable-debug-lwp],
223         [enable compilation of the LWP code with debugging information
224          (defaults to disabled)])],
225     ,
226     [enable_debug_lwp="no"])
227 AC_ARG_ENABLE([optimize-lwp],
228     [AS_HELP_STRING([--disable-optimize-lwp],
229         [disable optimization for compilation of the LWP code (defaults to
230          enabled)])],
231     ,
232     [enable_optimize_lwp="yes"])
233 AC_ARG_ENABLE([debug-pam],
234     [AS_HELP_STRING([--enable-debug-pam],
235         [enable compilation of the PAM code with debugging information
236          (defaults to disabled)])],
237     ,
238     [enable_debug_pam="no"])
239 AC_ARG_ENABLE([optimize-pam],
240     [AS_HELP_STRING([--disable-optimize-pam],
241         [disable optimization for compilation of the PAM code (defaults to
242          enabled)])],
243     ,
244     [enable_optimize_pam="yes"])
245 AC_ARG_ENABLE([linux-syscall-probing],
246     [AS_HELP_STRING([--enable-linux-syscall-probing],
247         [enable Linux syscall probing (defaults to autodetect)])],
248     ,
249     [enable_linux_syscall_probing="maybe"])
250 AC_ARG_WITH([crosstools-dir],
251     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
252     
253 AC_ARG_WITH([xslt-processor],
254         AS_HELP_STRING([--with-xslt-processor=ARG],
255         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
256         [XSLTPROC="$withval"],
257         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
258
259 AC_ARG_WITH([html-xsl], 
260         AS_HELP_STRING([--with-html-xsl],
261         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
262         [HTML_XSL="$withval"],
263         [HTML_XSL="html/chunk.xsl"])
264
265 AC_ARG_WITH([docbook2pdf],
266         AS_HELP_STRING([--with-docbook2pdf=ARG],
267         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
268         [DOCBOOK2PDF="$withval"],
269         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
270
271 AC_ARG_WITH([docbook-stylesheets],
272         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
273         [location of DocBook stylesheets (default is to search a set of likely paths)]),
274         [DOCBOOK_STYLESHEETS="$withval"],
275         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
276         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
277                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
278         fi)
279
280 enable_login="no"
281
282 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
283 dnl documentation build.
284 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
285
286 dnl weird ass systems
287 dnl AC_AIX
288 AC_ISC_POSIX
289 dnl AC_MINIX
290
291 dnl Various compiler setup.
292 AC_TYPE_PID_T
293 AC_TYPE_SIZE_T
294
295 dnl Checks for programs.
296 AC_PROG_INSTALL
297 AC_PROG_LN_S
298 AC_PROG_RANLIB
299 AC_PROG_YACC
300 AM_PROG_LEX
301 dnl if we are flex, be lex-compatible
302 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
303
304 OPENAFS_FORCE_ABS_INSTALL
305 OPENAFS_CHECK_BIGENDIAN
306 OPENAFS_PRINTF_TAKES_Z_LEN
307
308 AC_MSG_CHECKING(your OS)
309 system=$host
310 case $system in
311         *-linux*)
312
313                 MKAFS_OSTYPE=LINUX
314                 if test "x$enable_redhat_buildsys" = "xyes"; then
315                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
316                 fi
317                 if test "x$enable_kernel_module" = "xyes"; then
318                  if test "x$with_linux_kernel_headers" != "x"; then
319                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
320                  else
321                    for utsdir in "/lib/modules/`uname -r`/build" \
322                                  "/lib/modules/`uname -r`/source" \
323                                  "/usr/src/linux-2.4" \
324                                  "/usr/src/linux"; do
325                      LINUX_KERNEL_PATH="$utsdir"
326                      for utsfile in "include/generated/utsrelease.h" \
327                                     "include/linux/utsrelease.h" \
328                                     "include/linux/version.h" \
329                                     "include/linux/version-up.h"; do
330                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
331                          break 2
332                        fi
333                      done
334                    done
335                  fi
336                  if test "x$with_linux_kernel_build" != "x"; then
337                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
338                  else
339                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
340                  fi
341                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
342                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
343                    LINUX_VERSION="$linux_kvers"
344                  else
345                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
346                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
347                      LINUX_VERSION="$linux_kvers"
348                    else
349                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
350                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
351                        if test "x$linux_kvers" = "x"; then
352                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
353                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
354                            if test "x$linux_kvers" = "x"; then
355                              AC_MSG_ERROR(Linux headers lack version definition [2])
356                              exit 1
357                            else
358                              LINUX_VERSION="$linux_kvers"
359                            fi
360                          else
361                            AC_MSG_ERROR(Linux headers lack version definition)
362                            exit 1
363                          fi
364                        else
365                          LINUX_VERSION="$linux_kvers"
366                        fi
367                      else
368                        enable_kernel_module="no"
369                      fi
370                    fi
371                  fi
372                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
373                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
374                      enable_kernel_module="no"
375                  fi
376                  if test "x$enable_kernel_module" = "xno"; then
377                   if test "x$with_linux_kernel_headers" != "x"; then
378                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
379                    exit 1
380                   else
381                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
382                   fi
383                  fi
384                  dnl do we need to determine SUBARCH from autoconf.h
385                  SUBARCH=default
386                 fi
387                 AC_MSG_RESULT(linux)
388                 if test "x$enable_kernel_module" = "xyes"; then
389                  case "$LINUX_VERSION" in
390                   2.2.*) AFS_SYSKVERS=22 ;;
391                   2.4.*) AFS_SYSKVERS=24 ;;
392                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
393                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
394                  esac
395                 fi
396                 ;;
397         *-solaris*)
398                 MKAFS_OSTYPE=SOLARIS
399                 AC_MSG_RESULT(sun4)
400                 AC_PATH_PROG(SOLARISCC, [cc], ,
401                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
402                 if test "x$SOLARISCC" = "x" ; then
403                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
404                 fi
405                 SOLARIS_UFSVFS_HAS_DQRWLOCK
406                 SOLARIS_FS_HAS_FS_ROLLED
407                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
408                 SOLARIS_HAVE_VN_RENAMEPATH
409                 ;;
410         *-sunos*)
411                 MKAFS_OSTYPE=SUNOS
412                 enable_kernel_module=no
413                 AC_MSG_RESULT(sun4)
414                 ;;
415         *-hpux*)
416                 MKAFS_OSTYPE=HPUX
417                 AC_MSG_RESULT(hp_ux)
418                 if test -f "/usr/old/usr/include/ndir.h"; then
419                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
420                 fi
421                 ;;
422         *-irix*)
423                 if test -d /usr/include/sys/SN/SN1; then
424                  IRIX_BUILD_IP35="IP35"
425                 fi
426                 MKAFS_OSTYPE=IRIX
427                 AC_MSG_RESULT(sgi)
428                 ;;
429         *-aix*)
430                 MKAFS_OSTYPE=AIX
431                 AC_MSG_RESULT(rs_aix)
432                 ;;
433         arm-*-darwin*)
434                 MKAFS_OSTYPE=DARWIN
435                 AC_MSG_RESULT(arm_darwin)
436                 ;;
437         powerpc-*-darwin*)
438                 MKAFS_OSTYPE=DARWIN
439                 AC_MSG_RESULT(ppc_darwin)
440                 ;;
441         i386-*-darwin*)
442                 MKAFS_OSTYPE=DARWIN
443                 AC_MSG_RESULT(x86_darwin)
444                 ;;
445         x86_64-*-darwin*)
446                 MKAFS_OSTYPE=DARWIN
447                 AC_MSG_RESULT(x86_darwin)
448                 ;;
449         i386-*-freebsd*)
450                 MKAFS_OSTYPE=FBSD
451                 AC_MSG_RESULT(i386_fbsd)
452                 ;;
453         x86_64-*-freebsd*)
454                 MKAFS_OSTYPE=FBSD
455                 AC_MSG_RESULT(amd64_fbsd)
456                 ;;
457         *-netbsd*)
458                 MKAFS_OSTYPE=NBSD
459                 AC_MSG_RESULT(nbsd)
460                 ;;
461         x86_64-*-openbsd*)
462                 MKAFS_OSTYPE=OBSD
463                 AC_MSG_RESULT(amd64_obsd)
464                 ;;
465         i386-*-openbsd*)
466                 MKAFS_OSTYPE=OBSD
467                 AC_MSG_RESULT(i386_obsd)
468                 ;;
469         *-dragonfly*)
470                 MKAFS_OSTYPE=DFBSD
471                 AC_MSG_RESULT(i386_dfbsd)
472                 ;;
473         *)
474                 AC_MSG_RESULT($system)
475                 ;;
476 esac
477
478 if test "x$with_afs_sysname" != "x"; then
479         AFS_SYSNAME="$with_afs_sysname"
480 else
481         AC_MSG_CHECKING(your AFS sysname)
482         case $host in
483                 i?86-*-openbsd?.?)
484                         v=${host#*openbsd}
485                         vM=${v%.*}
486                         vm=${v#*.}
487                         AFS_SYSNAME="i386_obsd${vM}${vm}"
488                         ;;
489                 sparc64-*-openbsd?.?)
490                         v=${host#*openbsd}
491                         vM=${v%.*}
492                         vm=${v#*.}
493                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
494                         ;;
495                 x86_64-*-openbsd?.?)
496                         v=${host#*openbsd}
497                         vM=${v%.*}
498                         vm=${v#*.}
499                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
500                         ;;
501                 i?86-*-freebsd*.*)
502                         v=${host#*freebsd}
503                         vM=${v%.*}
504                         vm=${v#*.}
505                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
506                         ;;
507                 x86_64-*-freebsd*.*)
508                         v=${host#*freebsd}
509                         vM=${v%.*}
510                         vm=${v#*.}
511                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
512                         ;;
513                 i386-*-dragonfly?.*)
514                         v=${host#*dragonfly}
515                         vM=${v%.*}
516                         vm=${v#*.}
517                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
518                         ;;
519                 i?86-*-netbsd*1.6[[M-Z]]*)
520                         AFS_SYSNAME="i386_nbsd20"
521                         ;;
522                 powerpc-*-netbsd*1.6[[M-Z]]*)
523                         AFS_SYSNAME="ppc_nbsd20"
524                         ;;
525                 *-*-netbsd*)
526                         arch=${host%%-unknown*}
527                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
528                                                -e 's/powerpc/ppc/g')
529                         v=${host#*netbsd}
530                         v=${v#*aout}
531                         v=${v#*ecoff}
532                         v=${v#*elf}
533                         vM=${v%%.*}
534                         vM=${vM%.*}
535                         v=${v#*.}
536                         vm=${v%%.*}
537                         vm=${vm%.*}
538                         vm=${vm%%[[_A-Z]]*}
539                         if test $vm -eq 99 ; then
540                                 vM=$((vM+1))
541                         fi
542                         if test $vM -gt 1 ; then
543                                 vm=0
544                         fi
545                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
546                         ;;
547                 hppa*-hp-hpux11.0*)
548                         AFS_SYSNAME="hp_ux110"
549                         ;;
550                 hppa*-hp-hpux11.11)
551                         AFS_SYSNAME="hp_ux11i"
552                         ;;
553                 hppa*-hp-hpux11.23)
554                         AFS_SYSNAME="hp_ux1123"
555                         ;;
556                 ia64-hp-hpux11.22)
557                         AFS_SYSNAME="ia64_hpux1122"
558                         ;;
559                 ia64-hp-hpux*)
560                         AFS_SYSNAME="ia64_hpux1123"
561                         ;;
562                 hppa*-hp-hpux10*)
563                         AFS_SYSNAME="hp_ux102"
564                         ;;
565                 powerpc-apple-darwin7*)
566                         AFS_SYSNAME="ppc_darwin_70"
567                         OSXSDK="macosx10.3"
568                         ;;
569                 powerpc-apple-darwin8.*)
570                         AFS_SYSNAME="ppc_darwin_80"
571                         OSXSDK="macosx10.4"
572                         ;;
573                 i386-apple-darwin8.*)
574                         AFS_SYSNAME="x86_darwin_80"
575                         OSXSDK="macosx10.4"
576                         ;;
577                 powerpc-apple-darwin9.*)
578                         AFS_SYSNAME="ppc_darwin_90"
579                         OSXSDK="macosx10.5"
580                         ;;
581                 i386-apple-darwin9.*)
582                         AFS_SYSNAME="x86_darwin_90"
583                         OSXSDK="macosx10.5"
584                         ;;
585                 i?86-apple-darwin10.*)
586                         AFS_SYSNAME="x86_darwin_100"
587                         OSXSDK="macosx10.6"
588                         ;;
589                 x86_64-apple-darwin10.*)
590                         AFS_SYSNAME="x86_darwin_100"
591                         OSXSDK="macosx10.6"
592                         ;;
593                 arm-apple-darwin10.*)
594                         AFS_SYSNAME="arm_darwin_100"
595                         OSXSDK="iphoneos4.0"
596                         ;;
597                 x86_64-apple-darwin11.*)
598                         AFS_SYSNAME="x86_darwin_110"
599                         OSXSDK="macosx10.7"
600                         ;;
601                 i?86-apple-darwin11.*)
602                         AFS_SYSNAME="x86_darwin_110"
603                         OSXSDK="macosx10.7"
604                         ;;
605                 x86_64-apple-darwin12.*)
606                         AFS_SYSNAME="x86_darwin_120"
607                         OSXSDK="macosx10.8"
608                         ;;
609                 i?86-apple-darwin12.*)
610                         AFS_SYSNAME="x86_darwin_120"
611                         OSXSDK="macosx10.8"
612                         ;;
613                 sparc-sun-solaris2.8)
614                         AFS_SYSNAME="sun4x_58"
615                         ;;
616                 sparc-sun-solaris2.9)
617                         AFS_SYSNAME="sun4x_59"
618                         ;;
619                 sparc-sun-solaris2.10)
620                         AFS_SYSNAME="sun4x_510"
621                         ;;
622                 sparc-sun-solaris2.11)
623                         AFS_SYSNAME="sun4x_511"
624                         ;;
625                 i386-pc-solaris2.8)
626                         AFS_SYSNAME="sunx86_58"
627                         ;;
628                 i386-pc-solaris2.9)
629                         AFS_SYSNAME="sunx86_59"
630                         ;;
631                 i386-pc-solaris2.10)
632                         AFS_SYSNAME="sunx86_510"
633                         ;;
634                 i386-pc-solaris2.11)
635                         AFS_SYSNAME="sunx86_511"
636                         ;;
637                 alpha*-dec-osf4.0*)
638                         AFS_SYSNAME="alpha_dux40"
639                         ;;
640                 alpha*-dec-osf5.0*)
641                         AFS_SYSNAME="alpha_dux50"
642                         ;;
643                 alpha*-dec-osf5.1*)
644                         AFS_SYSNAME="alpha_dux51"
645                         ;;
646                 mips-sgi-irix6.5)
647                         AFS_SYSNAME="sgi_65"
648                         ;;
649                 ia64-*-linux*)
650                         AFS_SYSNAME="ia64_linuxXX"
651                         ;;
652                 powerpc-*-linux*)
653                         AFS_SYSNAME="`/bin/arch`_linuxXX"
654                         ;;
655                 powerpc64-*-linux*)
656                         AFS_SYSNAME="ppc64_linuxXX"
657                         ;;
658                 alpha*-linux*)
659                         AFS_SYSNAME="alpha_linux_XX"
660                         ;;
661                 s390-*-linux*)
662                         AFS_SYSNAME="s390_linuxXX"
663                         ;;
664                 s390x-*-linux*)
665                         AFS_SYSNAME="s390x_linuxXX"
666                         ;;
667                 sparc-*-linux*)
668                         AFS_SYSNAME="`/bin/arch`_linuxXX"
669                         ;;
670                 sparc64-*-linux*)
671                         AFS_SYSNAME="sparc64_linuxXX"
672                         ;;
673                 i?86-*-linux*)
674                         AFS_SYSNAME="i386_linuxXX"
675                         ;;
676                 arm*-linux*)
677                         AFS_SYSNAME="arm_linuxXX"
678                         ;;
679                 parisc-*-linux-gnu|hppa-*-linux-gnu)
680                         AFS_SYSNAME="parisc_linuxXX"
681                         enable_pam="no"
682                         ;;
683                 power*-ibm-aix4.2*)
684                         AFS_SYSNAME="rs_aix42"
685                         enable_pam="no"
686                         ;;
687                 power*-ibm-aix4.3*)
688                         AFS_SYSNAME="rs_aix42"
689                         enable_pam="no"
690                         ;;
691                 power*-ibm-aix5.1*)
692                         AFS_SYSNAME="rs_aix51"
693                         enable_pam="no"
694                         ;;
695                 power*-ibm-aix5.2*)
696                         AFS_SYSNAME="rs_aix52"
697                         enable_pam="no"
698                         ;;
699                 power*-ibm-aix5.3*)
700                         AFS_SYSNAME="rs_aix53"
701                         enable_pam="no"
702                         ;;
703                 power*-ibm-aix6.1*)
704                         AFS_SYSNAME="rs_aix61"
705                         enable_pam="no"
706                         ;;
707                 x86_64-*-linux-gnu)
708                         AFS_SYSNAME="amd64_linuxXX"
709                         enable_pam="yes"
710                         ;;
711                 *)
712                         AC_MSG_ERROR(An AFS sysname is required)
713                         exit 1
714                         ;;
715         esac
716         case $AFS_SYSNAME in
717                 *_linux* | *_umlinux*)
718                         if test "x${AFS_SYSKVERS}" = "x"; then
719                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
720                         fi
721                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
722                         AFS_SYSNAME="$_AFS_SYSNAME"
723                         AC_TRY_KBUILD(
724                          [],
725                          [#ifndef CONFIG_USERMODE
726                           #error not UML
727                           #endif],
728                          ac_cv_linux_is_uml=yes,)
729                         if test "${ac_cv_linux_is_uml}" = yes; then
730                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
731                         fi
732                         AFS_SYSNAME="$_AFS_SYSNAME"
733                         ;;
734         esac
735         AC_MSG_RESULT($AFS_SYSNAME)
736 fi
737
738 case $AFS_SYSNAME in
739         *_darwin*)
740                 AC_CHECK_HEADERS(crt_externs.h)
741                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
742                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
743                 AC_SUBST(OSXSDK)
744                 ;;
745 esac
746
747 dnl Some hosts have a separate common param file they should include.  Figure
748 dnl out if we're on one of them now that we know the sysname.
749 case $AFS_SYSNAME in
750     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
751     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
752     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
753     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
754     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
755     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
756     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
757     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
758     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
759     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
760     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
761     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
762     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
763     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
764     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
765     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
766     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
767     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
768     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
769     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
770     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
771     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
772     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
773     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
774     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
775     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
776     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
777     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
778     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
779     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
780     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
781     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
782     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
783     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
784     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
785 # Linux alpha adds an extra underscore for no good reason.
786     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
787     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
788     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
789 esac
790
791 OPENAFS_OSCONF
792
793 case $AFS_SYSNAME in *_linux* | *_umlinux*)
794
795                 # Add (sub-) architecture-specific paths needed by conftests
796                 case $AFS_SYSNAME  in
797                         *_umlinux26)
798                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
799                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
800                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
801                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
802                 esac
803
804                 if test "x$enable_kernel_module" = "xyes"; then
805                  if test "x$enable_debug_kernel" = "xno"; then
806                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
807                  fi
808                  OPENAFS_GCC_SUPPORTS_MARCH
809                  AC_SUBST(P5PLUS_KOPTS)
810                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
811                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
812                  OPENAFS_GCC_SUPPORTS_NO_COMMON
813                  OPENAFS_GCC_SUPPORTS_PIPE
814                  AC_SUBST(LINUX_GCC_KOPTS)
815
816                  dnl Setup the kernel build environment
817                  LINUX_KBUILD_USES_EXTRA_CFLAGS
818                  LINUX_KERNEL_COMPILE_WORKS
819
820                  dnl Check for header files
821                  AC_CHECK_LINUX_HEADER([config.h])
822                  AC_CHECK_LINUX_HEADER([completion.h])
823                  AC_CHECK_LINUX_HEADER([exportfs.h])
824                  AC_CHECK_LINUX_HEADER([freezer.h])
825                  AC_CHECK_LINUX_HEADER([key-type.h])
826                  AC_CHECK_LINUX_HEADER([semaphore.h])
827                  AC_CHECK_LINUX_HEADER([seq_file.h])
828
829                  dnl Type existence checks
830                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
831
832                  dnl Check for structure elements
833                  AC_CHECK_LINUX_STRUCT([address_space_operations],
834                                        [write_begin], [fs.h])
835                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
836                                        [backing-dev.h])
837                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
838                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
839                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
840                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
841                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
842                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
843                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
844                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
845                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
846                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
847                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
848                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
849                  AC_CHECK_LINUX_STRUCT([filename], [name], [fs.h])
850                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
851                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
852                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
853                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
854                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
855                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
856                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
857                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
858                                        [fs.h])
859                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
860                                        [fs.h])
861                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
862                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
863                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
864                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
865                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
866                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
867                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
868                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
869                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
870                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
871                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
872
873                  dnl Check for typed structure elements
874                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
875                                              [buf], [fs.h])
876
877                  dnl Function existence checks
878
879                  AC_CHECK_LINUX_FUNC([bdi_init],
880                                      [#include <linux/backing-dev.h>],
881                                      [bdi_init(NULL);])
882                  AC_CHECK_LINUX_FUNC([PageChecked],
883                                      [#include <linux/mm.h>
884 #include <linux/page-flags.h>],
885                                      [struct page *_page;
886                                       int bchecked = PageChecked(_page);])
887                  AC_CHECK_LINUX_FUNC([PageFsMisc],
888                                      [#include <linux/mm.h>
889 #include <linux/page-flags.h>],
890                                      [struct page *_page;
891                                       int bchecked = PageFsMisc(_page);])
892                  AC_CHECK_LINUX_FUNC([clear_inode],
893                                      [#include <linux/fs.h>],
894                                      [clear_inode(NULL);])
895                  AC_CHECK_LINUX_FUNC([current_kernel_time],
896                                      [#include <linux/time.h>],
897                                      [struct timespec s;
898                                       s = current_kernel_time();])
899                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
900                                      [#include <linux/fs.h>],
901                                      [d_alloc_anon(NULL);])
902                  AC_CHECK_LINUX_FUNC([d_count],
903                                      [#include <linux/dcache.h>],
904                                      [d_count(NULL);])
905                  AC_CHECK_LINUX_FUNC([d_make_root],
906                                      [#include <linux/fs.h>],
907                                      [d_make_root(NULL);])
908                  AC_CHECK_LINUX_FUNC([do_sync_read],
909                                      [#include <linux/fs.h>],
910                                      [do_sync_read(NULL, NULL, 0, NULL);])
911                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
912                                      [#include <linux/sched.h>],
913                                      [pid_t p; find_task_by_pid(p);])
914                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
915                                      [#include <linux/fs.h>],
916                                      [generic_file_aio_read(NULL,NULL,0,0);])
917                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
918                                      [#include <linux/pagemap.h>],
919                                      [grab_cache_page_write_begin(NULL, 0, 0);])
920                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
921                                      [#include <linux/list.h>],
922                                      [hlist_unhashed(0);])
923                  AC_CHECK_LINUX_FUNC([i_size_read],
924                                      [#include <linux/fs.h>],
925                                      [i_size_read(NULL);])
926                  AC_CHECK_LINUX_FUNC([inode_setattr],
927                                      [#include <linux/fs.h>],
928                                      [inode_setattr(NULL, NULL);])
929                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
930                                      [#include <linux/net.h>],
931                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
932                  AC_CHECK_LINUX_FUNC([page_follow_link],
933                                      [#include <linux/fs.h>],
934                                      [page_follow_link(0,0);])
935                  AC_CHECK_LINUX_FUNC([page_offset],
936                                      [#include <linux/pagemap.h>],
937                                      [page_offset(NULL);])
938                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
939                                      [#include <linux/pagevec.h>],
940                                      [__pagevec_lru_add_file(NULL);])
941                  AC_CHECK_LINUX_FUNC([path_lookup],
942                                      [#include <linux/fs.h>
943                                       #include <linux/namei.h>],
944                                      [path_lookup(NULL, 0, NULL);])
945                  AC_CHECK_LINUX_FUNC([proc_create],
946                                      [#include <linux/proc_fs.h>],
947                                      [proc_create(NULL, 0, NULL, NULL);])
948                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
949                                      [#include <linux/rcupdate.h>],
950                                      [rcu_read_lock();])
951                  AC_CHECK_LINUX_FUNC([set_nlink],
952                                      [#include <linux/fs.h>],
953                                      [set_nlink(NULL, 1);])
954                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
955                                      [#include <linux/splice.h>],
956                                      [splice_direct_to_actor(NULL,NULL,NULL);])
957                  AC_CHECK_LINUX_FUNC([svc_addr_in],
958                                      [#include <linux/sunrpc/svc.h>],
959                                      [svc_addr_in(NULL);])
960                  AC_CHECK_LINUX_FUNC([zero_user_segments],
961                                      [#include <linux/highmem.h>],
962                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
963                  AC_CHECK_LINUX_FUNC([noop_fsync],
964                                      [#include <linux/fs.h>],
965                                      [void *address = &noop_fsync; printk("%p\n", address)];)
966                  AC_CHECK_LINUX_FUNC([kthread_run],
967                                      [#include <linux/kernel.h>
968                                       #include <linux/kthread.h>],
969                                      [kthread_run(NULL, NULL, "test");])
970
971                  dnl Consequences - things which get set as a result of the
972                  dnl                above tests
973                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
974                        [AC_DEFINE([AFS_NONFSTRANS], 1,
975                                   [define to disable the nfs translator])])
976
977                  dnl Assorted more complex tests
978                  LINUX_AIO_NONVECTOR
979                  LINUX_EXPORTS_PROC_ROOT_FS
980                  LINUX_KMEM_CACHE_INIT
981                  LINUX_HAVE_KMEM_CACHE_T
982                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
983                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
984                  LINUX_D_PATH_TAKES_STRUCT_PATH
985                  LINUX_NEW_EXPORT_OPS
986                  LINUX_INODE_SETATTR_RETURN_TYPE
987                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
988                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
989                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
990                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
991                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
992                  LINUX_DOP_D_DELETE_TAKES_CONST
993                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
994                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
995                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
996                  LINUX_FOP_F_FSYNC_TAKES_RANGE
997                  LINUX_AOP_WRITEBACK_CONTROL
998                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
999                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1000                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1001                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1002                  LINUX_KERNEL_SOCK_CREATE
1003                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1004                  LINUX_NEED_RHCONFIG
1005                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1006                  LINUX_EXPORTS_TASKLIST_LOCK
1007                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1008                  LINUX_STATFS_TAKES_DENTRY
1009                  LINUX_REFRIGERATOR
1010                  LINUX_HAVE_TRY_TO_FREEZE
1011                  LINUX_LINUX_KEYRING_SUPPORT
1012                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1013                  LINUX_KEY_ALLOC_NEEDS_CRED
1014                  LINUX_INIT_WORK_HAS_DATA
1015                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1016                  LINUX_HAVE_DCACHE_LOCK
1017                  LINUX_D_COUNT_IS_INT
1018                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1019                  LINUX_IOP_CREATE_TAKES_UMODE_T
1020                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1021                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1022                  LINUX_DENTRY_OPEN_TAKES_PATH
1023                  LINUX_D_ALIAS_IS_HLIST
1024                  LINUX_HLIST_ITERATOR_NO_NODE
1025                  LINUX_IOP_I_CREATE_TAKES_BOOL
1026                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1027                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1028
1029                  dnl If we are guaranteed that keyrings will work - that is
1030                  dnl  a) The kernel has keyrings enabled
1031                  dnl  b) The code is new enough to give us a key_type_keyring
1032                  dnl then we just disable syscall probing unless we've been
1033                  dnl told otherwise
1034
1035                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1036                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1037                           [enable_linux_syscall_probing="no"],
1038                           [enable_linux_syscall_probing="yes"])
1039                  ])
1040
1041                  dnl Syscall probing needs a few tests of its own, and just
1042                  dnl won't work if the kernel doesn't export init_mm
1043                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1044                    LINUX_EXPORTS_INIT_MM
1045                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1046                      AC_MSG_ERROR(
1047                        [Can't do syscall probing without exported init_mm])
1048                    ])
1049                    LINUX_EXPORTS_SYS_CHDIR
1050                    LINUX_EXPORTS_SYS_OPEN
1051                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1052                              [define to enable syscall table probes])
1053                  ])
1054
1055                  dnl Packaging and SMP build
1056                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1057                    LINUX_WHICH_MODULES
1058                  else
1059                    AC_SUBST(MPS,'SP')
1060                  fi
1061
1062                  dnl Syscall probing
1063                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1064                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1065                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1066                    ])
1067                    ac_cv_linux_exports_sys_call_table=no
1068                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1069                      ac_cv_linux_exports_ia32_sys_call_table=yes
1070                    fi
1071                  else
1072                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1073                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1074                    LINUX_EXPORTS_SYS_CALL_TABLE
1075                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1076                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1077                          linux_syscall_method=none
1078                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1079                             linux_syscall_method=scan
1080                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1081                                linux_syscall_method=scan_with_kallsyms_address
1082                             fi
1083                          fi
1084                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1085                             linux_syscall_method=kallsyms_symbol
1086                          fi
1087                          if test "x$linux_syscall_method" = "xnone"; then
1088                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1089                             linux_syscall_method=scan
1090                          fi
1091                    fi
1092                  fi
1093                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1094                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1095                  fi
1096                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1097                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1098                  fi
1099                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1100                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1101                  else
1102                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1103                  fi
1104                 :
1105                 fi
1106 dnl Linux-only, but just enable always.
1107                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1108 esac
1109
1110 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1111     [ac_cv_sync_fetch_and_add],
1112     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1113                     [ac_cv_sync_fetch_and_add=yes],
1114                     [ac_cv_sync_fetch_and_add=no])
1115 ])
1116 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1117       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1118                 [define if your C compiler has __sync_add_and_fetch])])
1119
1120 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1121     [ac_cv_sockaddr_len],
1122     [AC_TRY_COMPILE( [#include <sys/types.h>
1123 #include <sys/socket.h>],
1124                      [struct sockaddr *a; a->sa_len=0;],
1125                      [ac_cv_sockaddr_len=yes],
1126                      [ac_cv_sockaddr_len=no])
1127 ])
1128 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1129       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1130                  [define if you struct sockaddr sa_len])])
1131
1132 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1133         echo Skipping library tests because they confuse Irix.
1134 else
1135   AC_SEARCH_LIBS([socket], [socket inet])
1136   AC_SEARCH_LIBS([connect], [nsl])
1137   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1138
1139   dnl darwin wants it, aix hates it
1140   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1141   AC_TRY_COMPILE([
1142   #include <stdlib.h>
1143   #include <stdio.h>
1144   #include <sys/types.h>
1145   #include <sys/socket.h>
1146   #include <netinet/in.h>
1147   #include <arpa/inet.h>
1148   #include <arpa/nameser.h>
1149   #include <arpa/nameser_compat.h>
1150   #include <resolv.h>
1151   ], [static int i; i = 0;],
1152   [AC_MSG_RESULT(yes)
1153    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1154   [AC_MSG_RESULT(no)
1155    ])
1156
1157   openafs_save_libs="$LIBS"
1158   AC_MSG_CHECKING([for res_search])
1159   AC_FUNC_RES_SEARCH
1160
1161   if test "$ac_cv_func_res_search" = no; then
1162       for lib in dns nsl resolv; do
1163         if test "$ac_cv_func_res_search" != yes; then
1164           LIBS="-l$lib $LIBS"
1165           AC_FUNC_RES_SEARCH
1166           LIBS="$openafs_save_libs"
1167         fi
1168       done    
1169       if test "$ac_cv_func_res_search" = yes; then
1170         LIB_AFSDB="-l$lib"
1171         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1172         AC_MSG_RESULT([yes, in lib$lib])
1173       else
1174         AC_MSG_RESULT(no)
1175       fi
1176   else
1177     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1178     AC_MSG_RESULT(yes)
1179   fi
1180   
1181 fi
1182 XLIBS="$LIB_AFSDB $XLIBS"
1183
1184 AC_CHECK_RESOLV_RETRANS
1185
1186 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1187     [ac_cv_setsockopt_iprecverr],
1188     [AC_TRY_COMPILE( [
1189 #include <sys/types.h>
1190 #include <sys/socket.h>
1191 #include <netinet/in.h>],
1192 [int on=1;
1193 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1194         [ac_cv_setsockopt_iprecverr=yes],
1195         [ac_cv_setsockopt_iprecverr=no])])
1196
1197 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1198       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1199                  [define if we can receive socket errors via IP_RECVERR])])
1200
1201 PTHREAD_LIBS=error
1202 if test "x$MKAFS_OSTYPE" = OBSD; then
1203         PTHREAD_LIBS="-pthread"
1204 fi
1205 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1206         PTHREAD_LIBS="-pthread"
1207 fi
1208 if test "x$PTHREAD_LIBS" = xerror; then
1209         AC_CHECK_LIB(pthread, pthread_attr_init,
1210                 PTHREAD_LIBS="-lpthread")
1211 fi
1212 if test "x$PTHREAD_LIBS" = xerror; then
1213         AC_CHECK_LIB(pthreads, pthread_attr_init,
1214                 PTHREAD_LIBS="-lpthreads")
1215 fi
1216 if test "x$PTHREAD_LIBS" = xerror; then
1217         AC_CHECK_LIB(c_r, pthread_attr_init,
1218                 PTHREAD_LIBS="-lc_r")
1219 fi
1220 if test "x$PTHREAD_LIBS" = xerror; then
1221         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1222 fi
1223 if test "x$PTHREAD_LIBS" = xerror; then
1224         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1225         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1226                 PTHREAD_LIBS="-lpthread")
1227 fi
1228 if test "x$PTHREAD_LIBS" = xerror; then
1229         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1230 fi
1231 AC_SUBST(PTHREAD_LIBS)
1232
1233 HOST_CPU="$host_cpu"
1234
1235 if test "x$with_bsd_kernel_headers" != "x"; then
1236         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1237 else
1238         BSD_KERNEL_PATH="/usr/src/sys"
1239 fi
1240
1241 if test "x$with_bsd_kernel_build" != "x"; then
1242         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1243 else
1244         case $AFS_SYSNAME in
1245                 *_fbsd_*)
1246                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1247                         ;;
1248                 *_nbsd*)
1249                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1250         esac
1251 fi
1252
1253 # Fast restart
1254 if test "$enable_supergroups" = "yes"; then
1255         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1256 fi
1257
1258 if test "$enable_bitmap_later" = "yes"; then
1259         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1260 fi
1261
1262 if test "$enable_unix_sockets" = "yes"; then
1263         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1264         USE_UNIX_SOCKETS="yes"
1265 else
1266         USE_UNIX_SOCKETS="no"
1267 fi
1268 AC_SUBST(USE_UNIX_SOCKETS)
1269
1270 if test "$enable_namei_fileserver" = "yes"; then
1271         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1272         VFSCK=""
1273 else
1274         if test "$enable_namei_fileserver" = "default"; then
1275                 case $host in
1276                         *-solaris2.10*)
1277                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1278                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1279                                 VFSCK=""
1280                                 ;;
1281                         *-solaris2.11*)
1282                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1283                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1284                                 VFSCK=""
1285                                 ;;
1286                         *)
1287                                 VFSCK="vfsck"
1288                                 ;;
1289                 esac
1290         else
1291                 VFSCK="vfsck"
1292         fi
1293 fi
1294
1295 dnl check for tivoli
1296 AC_MSG_CHECKING(for tivoli tsm butc support)
1297 XBSA_CFLAGS=""
1298 if test "$enable_tivoli_tsm" = "yes"; then
1299         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1300         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1301         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1302         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1303
1304         if test -r "$XBSADIR3/dsmapifp.h"; then
1305                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1306                 XBSA_XLIBS="-ldl"
1307                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1308         elif test -r "$XBSADIR4/dsmapifp.h"; then
1309                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1310                 XBSA_XLIBS="-ldl"
1311                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1312         elif test -r "$XBSADIR1/xbsa.h"; then
1313                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1314                 XBSA_XLIBS=""
1315                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1316         elif test -r "$XBSADIR2/xbsa.h"; then
1317                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1318                 XBSA_XLIBS=""
1319                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1320         else
1321                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1322         fi
1323 else
1324         AC_MSG_RESULT([no])
1325 fi
1326 AC_SUBST(XBSA_CFLAGS)
1327 AC_SUBST(XBSA_XLIBS) 
1328
1329 dnl checks for header files.
1330 AC_HEADER_STDC
1331 AC_HEADER_SYS_WAIT
1332 AC_HEADER_DIRENT
1333 AC_CHECK_HEADERS([ \
1334                    arpa/inet.h \
1335                    arpa/nameser.h \
1336                    curses.h\
1337                    direct.h \
1338                    errno.h \
1339                    fcntl.h \
1340                    grp.h \
1341                    math.h \
1342                    mntent.h \
1343                    ncurses.h \
1344                    ncurses/ncurses.h \
1345                    netdb.h \
1346                    netinet/in.h \
1347                    pthread_np.h \
1348                    pwd.h \
1349                    regex.h \
1350                    security/pam_appl.h \
1351                    signal.h \
1352                    stdint.h \
1353                    stdio_ext.h \
1354                    stdlib.h \
1355                    string.h \
1356                    strings.h \
1357                    sys/bitypes.h \
1358                    sys/bswap.h \
1359                    sys/dk.h \
1360                    sys/fcntl.h \
1361                    sys/file.h \
1362                    sys/fs_types.h \
1363                    sys/fstyp.h \
1364                    sys/ioctl.h \
1365                    sys/ipc.h \
1366                    sys/lockf.h \
1367                    sys/map.h \
1368                    sys/mount.h \
1369                    sys/mntent.h \
1370                    sys/mnttab.h \
1371                    sys/pag.h \
1372                    sys/param.h \
1373                    sys/resource.h \
1374                    sys/select.h \
1375                    sys/statfs.h \
1376                    sys/statvfs.h \
1377                    sys/socket.h \
1378                    sys/sysctl.h \
1379                    sys/time.h \
1380                    sys/types.h \
1381                    sys/uio.h \
1382                    sys/un.h \
1383                    sys/vfs.h \
1384                    syslog.h \
1385                    termios.h \
1386                    time.h \
1387                    ucontext.h \
1388                    unistd.h \
1389                    windows.h \
1390                 ])
1391
1392 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1393 #ifdef HAVE_NETINET_IN_H
1394 # include <netinet/in.h>
1395 #endif])
1396
1397 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1398 #ifdef HAVE_SYS_SOCKET_H
1399 # include <sys/socket.h>
1400 #endif])
1401
1402 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1403 #ifdef HAVE_SYS_SOCKET_H
1404 # include <sys/socket.h>
1405 #endif
1406 #ifdef HAVE_NETINET_IN_H
1407 # include <netinet/in.h>
1408 #endif
1409 #ifdef HAVE_NET_IF_H
1410 # include <net/if.h>
1411 #endif])
1412
1413 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1414 #ifdef HAVE_SECURITY_PAM_APPL_H
1415 # include <security/pam_appl.h>
1416 #endif])
1417
1418 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1419
1420 AC_CHECK_TYPES([fsblkcnt_t],,,[
1421 #include <sys/types.h>
1422 #ifdef HAVE_SYS_BITYPES_H
1423 #include <sys/bitypes.h>
1424 #endif
1425 #ifdef HAVE_SYS_STATFS_H
1426 #include <sys/statfs.h>
1427 #endif
1428 #ifdef HAVE_SYS_STATVFS_H
1429 #include <sys/statvfs.h>
1430 #endif
1431 ])
1432
1433 dnl see what struct stat has for timestamps
1434 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1435
1436 dnl check for curses-lib
1437 AS_IF([test "x$enable_gtx" != "xno"],
1438       [save_LIBS=$LIBS
1439       AC_CHECK_LIB( [ncurses], [setupterm],
1440       [LIB_curses=-lncurses],
1441         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1442           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1443       ])
1444       LIBS=$save_LIBS
1445       AC_SUBST(LIB_curses)])
1446         
1447 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1448
1449 if test "$enable_debug_locks" = yes; then
1450         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1451 fi
1452
1453 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1454 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1455         case $AFS_SYSNAME in
1456         sgi_*)
1457                 HAVE_PAM="no"
1458                 ;;
1459         *)
1460                 HAVE_PAM="yes"
1461                 ;;
1462         esac
1463 else
1464         HAVE_PAM="no"
1465 fi
1466 AC_SUBST(HAVE_PAM)
1467
1468 if test "$enable_login" = yes; then
1469         BUILD_LOGIN="yes"
1470 else
1471         BUILD_LOGIN="no"
1472 fi
1473 AC_SUBST(BUILD_LOGIN)
1474
1475 if test "$enable_uss" = yes; then
1476         BUILD_USS="yes"
1477 else
1478         BUILD_USS="no"
1479 fi
1480 AC_SUBST(BUILD_USS)
1481
1482 if test "$enable_kauth" = yes; then
1483         INSTALL_KAUTH="yes"
1484 else
1485         INSTALL_KAUTH="no"
1486 fi
1487 AC_SUBST(INSTALL_KAUTH)
1488
1489 AC_CHECK_FUNCS([ \
1490         arc4random \
1491         fcntl \
1492         fseeko64 \
1493         ftello64 \
1494         getcwd \
1495         getegid \
1496         geteuid \
1497         getgid \
1498         getuid \
1499         getrlimit \
1500         issetugid \
1501         mkstemp \
1502         poll \
1503         pread \
1504         preadv \
1505         preadv64 \
1506         pwrite \
1507         pwritev \
1508         pwritev64 \
1509         regcomp \
1510         regerror \
1511         regexec \
1512         setitimer \
1513         setvbuf \
1514         sigaction \
1515         strcasestr \
1516         strerror \
1517         sysconf \
1518         sysctl \
1519         tdestroy \
1520         timegm \
1521 ])
1522
1523 OPENAFS_ROKEN()
1524 OPENAFS_C_ATTRIBUTE()
1525
1526 dnl Functions that Heimdal's libroken provides, but that we
1527 dnl haven't found a need for yet, and so haven't imported
1528 AC_CHECK_FUNCS([ \
1529         chown \
1530         fchown \
1531         gethostname \
1532         lstat \
1533         inet_aton \
1534         inet_ntop \
1535         inet_pton \
1536         putenv \
1537         readv \
1538         setenv \
1539         strdup \
1540         strftime \
1541         strndup \
1542         strsep \
1543         unsetenv \
1544 ])
1545
1546 dnl Functions that are in objects that we always build from libroken
1547 AC_CHECK_FUNCS([ \
1548         asprintf \
1549         asnprintf \
1550         vasprintf \
1551         vasnprintf \
1552         vsnprintf \
1553         snprintf \
1554 ])
1555
1556 dnl Functions that we're going to try and get from libroken
1557 AC_REPLACE_FUNCS([ \
1558         daemon \
1559         ecalloc \
1560         emalloc \
1561         erealloc \
1562         err \
1563         errx \
1564         flock \
1565         getdtablesize \
1566         getopt \
1567         getprogname \
1568         gettimeofday \
1569         localtime_r \
1570         mkstemp \
1571         setenv \
1572         setprogname \
1573         strcasecmp \
1574         strlcat \
1575         strnlen \
1576         strlcpy \
1577         strsep \
1578         tdelete \
1579         tfind \
1580         tsearch \
1581         twalk \
1582         unsetenv \
1583         verr \
1584         verrx \
1585         vsyslog \
1586         vwarn \
1587         vwarnx \
1588         warn \
1589         warnx \
1590 ])
1591
1592 dnl Headers that we're going to try and get from libroken
1593 AC_CHECK_HEADERS([ \
1594         err.h \
1595         search.h \
1596 ])
1597
1598 AC_CHECK_DECLS([h_errno], [], [], [
1599 #include <sys/types.h>
1600 #ifdef HAVE_NETDB_H
1601 #include <netdb.h>
1602 #endif
1603 ])
1604
1605 AC_HEADER_TIME
1606
1607 ROKEN_HEADERS=
1608 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1609       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1610       [])
1611 AC_SUBST(ROKEN_HEADERS)
1612
1613 dnl Stuff that's harder ...
1614 AC_MSG_CHECKING([for bswap16])
1615 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1616 #ifdef HAVE_SYS_TYPES_H
1617 #include <sys/types.h>
1618 #endif
1619 #ifdef HAVE_SYS_BSWAP_H
1620 #include <sys/bswap.h>
1621 #endif
1622 ],
1623 [short a, b; b = bswap16(a); ])],
1624 [AC_MSG_RESULT(yes)
1625  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1626 ],
1627 [AC_MSG_RESULT(no)])
1628
1629 AC_MSG_CHECKING([for bswap32])
1630 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1631 #include <sys/types.h>
1632 #endif
1633 #ifdef HAVE_SYS_BSWAP_H
1634 #include <sys/bswap.h>
1635 #endif
1636 ],
1637 [int a, b; b = bswap32(a); ])],
1638 [AC_MSG_RESULT(yes)
1639  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1640 ],
1641 [AC_MSG_RESULT(no)])
1642
1643 case $AFS_SYSNAME in
1644 *hp_ux* | *hpux*)
1645    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1646    ;;
1647 *)
1648    AC_MSG_CHECKING([for positional I/O])
1649    if test "$ac_cv_func_pread" = "yes" && \
1650            test "$ac_cv_func_pwrite" = "yes"; then
1651       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1652       AC_MSG_RESULT(yes)
1653    else
1654      AC_MSG_RESULT(no)
1655    fi
1656    AC_MSG_CHECKING([for vectored positional I/O])
1657    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1658                "$ac_cv_func_pwritev" = "yes" -a \
1659                "$ac_cv_func_preadv64" = "yes" -a \
1660                "$ac_cv_func_pwritev64" = "yes"],
1661          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1662           AC_MSG_RESULT(yes)],
1663          [AC_MSG_RESULT(no)])
1664    ;;
1665 esac
1666
1667 AC_MSG_CHECKING([for POSIX regex library])
1668 if test "$ac_cv_header_regex_h" = "yes" && \
1669         test "$ac_cv_func_regcomp" = "yes" && \
1670         test "$ac_cv_func_regexec" = "yes" && \
1671         test "$ac_cv_func_regerror" = "yes"; then
1672     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1673     AC_MSG_RESULT(yes)
1674 else
1675     AC_MSG_RESULT(no)
1676 fi
1677
1678 dnl Look for "non-portable" pthreads functions.
1679 save_LIBS="$LIBS"
1680 LIBS="$LIBS $PTHREAD_LIBS"
1681 AC_CHECK_FUNCS([ \
1682         pthread_set_name_np \
1683         pthread_setname_np \
1684 ])
1685
1686 dnl Sadly, there are three different versions of pthread_setname_np.
1687 dnl Try to cater for all of them.
1688 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1689     AC_MSG_CHECKING([for signature of pthread_setname_np])
1690     AC_TRY_COMPILE([
1691 #include <pthread.h>
1692 #ifdef HAVE_PTHREAD_NP_H
1693 #include <pthread_np.h>
1694 #endif
1695 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1696         AC_MSG_RESULT([three arguments])
1697         pthread_setname_np_args=3], [
1698         AC_TRY_COMPILE([
1699 #include <pthread.h>
1700 #ifdef HAVE_PTHREAD_NP_H
1701 #include <pthread_np.h>
1702 #endif
1703 ], [pthread_setname_np(pthread_self(), "test")], [
1704             AC_MSG_RESULT([two arguments])
1705             pthread_setname_np_args=2], [
1706             AC_TRY_COMPILE([
1707 #include <pthread.h>
1708 #ifdef HAVE_PTHREAD_NP_H
1709 #include <pthread_np.h>
1710 #endif
1711 ], [pthread_setname_np("test")], [
1712                 AC_MSG_RESULT([one argument])
1713                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1714 ])
1715 ])
1716 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1717 fi
1718 LIBS="$save_LIBS"
1719
1720 openafs_cv_saved_CFLAGS="$CFLAGS"
1721 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1722
1723 AC_TYPE_SIGNAL
1724 OPENAFS_RETSIGTYPE
1725 AC_CHECK_SIZEOF(void *)
1726 AC_CHECK_SIZEOF(unsigned long long)
1727 AC_CHECK_SIZEOF(unsigned long)
1728 AC_CHECK_SIZEOF(unsigned int)
1729 AC_TYPE_INTPTR_T
1730 AC_TYPE_UINTPTR_T
1731 AC_TYPE_SSIZE_T
1732 AC_CHECK_TYPE([sig_atomic_t],[],
1733     [AC_DEFINE([sig_atomic_t], [int],
1734         [Define to int if <signal.h> does not define.])],
1735 [#include <sys/types.h>
1736 #include <signal.h>])
1737 AC_CHECK_TYPE([socklen_t],[],
1738     [AC_DEFINE([socklen_t], [int],
1739         [Define to int if <sys/socket.h> does not define.])],
1740 [#include <sys/types.h>
1741 #include <sys/socket.h>])
1742 AC_CHECK_TYPES(off64_t)
1743 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1744 AC_CHECK_TYPES([struct winsize], [], [], [
1745 #ifdef HAVE_TERMIOS_H
1746 # include <termios.h>
1747 #else
1748 # include <sys/termios.h>
1749 #endif
1750 #include <sys/ioctl.h>])
1751 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1752                 struct sockaddr_storage],
1753                [], [], [
1754 #include <sys/types.h>
1755 #include <sys/socket.h>
1756 ])
1757 AC_CHECK_TYPES([sa_family_t], [], [], [
1758 #include <sys/types.h>
1759 #include <sys/socket.h>
1760 ])
1761 AC_CHECK_TYPES([struct addrinfo], [], [], [
1762 #include <sys/types.h>
1763 #ifdef HAVE_NETDB_H
1764 #include <netdb.h>
1765 #endif
1766 ])
1767 AC_CHECK_TYPES([long long], [], [], [])
1768
1769 AC_SIZEOF_TYPE(long)
1770
1771 CFLAGS="$openafs_cv_saved_CFLAGS"
1772
1773 RRA_HEADER_PAM_CONST
1774
1775
1776 dnl Directory PATH handling
1777 if test "x$enable_transarc_paths" = "xyes"  ; then 
1778     afsconfdir=${afsconfdir=/usr/afs/etc}
1779     viceetcdir=${viceetcdir=/usr/vice/etc}
1780     afskerneldir=${afskerneldir=${viceetcdir}}
1781     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1782     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1783     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1784     afsdbdir=${afsdbdir=/usr/afs/db}
1785     afslogsdir=${afslogsdir=/usr/afs/logs}
1786     afslocaldir=${afslocaldir=/usr/afs/local}
1787     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1788     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1789     afsdatadir=${afsdatadir=/usr/vice/etc}
1790 else 
1791     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1792     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1793     afskerneldir=${afskerneldir='${libdir}/openafs'}
1794     afssrvbindir=${afssrvbindir='${bindir}'}
1795     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1796     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1797     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1798     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1799     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1800     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1801     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1802     afsdatadir=${afsdatadir='${datadir}/openafs'}
1803 fi
1804 AC_SUBST(afsconfdir)
1805 AC_SUBST(viceetcdir)
1806 AC_SUBST(afskerneldir)
1807 AC_SUBST(afssrvbindir)
1808 AC_SUBST(afssrvsbindir)
1809 AC_SUBST(afssrvlibexecdir)
1810 AC_SUBST(afsdbdir)
1811 AC_SUBST(afslogsdir)
1812 AC_SUBST(afslocaldir)
1813 AC_SUBST(afsbackupdir)
1814 AC_SUBST(afsbosconfigdir)
1815 AC_SUBST(afsdatadir)
1816
1817 if test "x$enable_kernel_module" = "xyes"; then
1818 ENABLE_KERNEL_MODULE=libafs
1819 fi
1820
1821 if test "x$enable_pthreaded_ubik" = "xyes"; then
1822 ENABLE_PTHREADED_UBIK=yes
1823 fi
1824
1825 AC_SUBST(VFSCK)
1826 AC_SUBST(AFS_SYSNAME)
1827 AC_SUBST(AFS_PARAM_COMMON)
1828 AC_SUBST(ENABLE_KERNEL_MODULE)
1829 AC_SUBST(ENABLE_PTHREADED_UBIK)
1830 AC_SUBST(LIB_AFSDB)
1831 AC_SUBST(LINUX_KERNEL_PATH)
1832 AC_SUBST(LINUX_KERNEL_BUILD)
1833 AC_SUBST(HOST_CPU)
1834 AC_SUBST(BSD_KERNEL_PATH)
1835 AC_SUBST(BSD_KERNEL_BUILD)
1836 AC_SUBST(LINUX_VERSION)
1837 AC_SUBST(MKAFS_OSTYPE)
1838 AC_SUBST(TOP_OBJDIR)
1839 AC_SUBST(TOP_SRCDIR)
1840 AC_SUBST(TOP_INCDIR)
1841 AC_SUBST(TOP_LIBDIR)
1842 AC_SUBST(DEST)
1843 AC_SUBST(DARWIN_INFOFILE)
1844 AC_SUBST(IRIX_BUILD_IP35)
1845 AC_SUBST(HTML_XSL)
1846 AC_SUBST(XSLTPROC)
1847 AC_SUBST(DOCBOOK2PDF)
1848 AC_SUBST(DOCBOOK_STYLESHEETS)
1849
1850 OPENAFS_FUSE
1851 OPENAFS_SWIG
1852
1853 TOP_SRCDIR="${srcdir}/src"
1854 dnl
1855 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1856 dnl
1857 case $TOP_SRCDIR in
1858         /*)
1859                 ;;
1860         *)
1861                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1862                 ;;
1863 esac
1864
1865 TOP_OBJDIR="${SRCDIR_PARENT}"
1866 TOP_INCDIR="${SRCDIR_PARENT}/include"
1867 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1868 if test "${DEST}x" = "x"; then
1869         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1870 fi
1871
1872 if test "x$with_crosstools_dir" != "x"; then
1873         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1874                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1875                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1876                 RXGEN_PATH=$with_crosstools_dir/rxgen
1877         else
1878                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1879                 exit 1
1880         fi
1881 else
1882         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1883         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1884         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1885 fi
1886 AC_SUBST(COMPILE_ET_PATH)
1887 AC_SUBST(CONFIGTOOL_PATH)
1888 AC_SUBST(RXGEN_PATH)
1889
1890 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1891 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1892 AC_SUBST(HELPER_SPLINT)
1893 AC_SUBST(HELPER_SPLINTCFG)
1894
1895 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1896
1897 dnl Check to see if crypt lives in a different library
1898 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1899 AC_SUBST(LIB_crypt)
1900
1901 dnl Check to see if the compiler support labels in structs
1902 AC_MSG_CHECKING(for label support in structs)
1903 AC_TRY_COMPILE([], [
1904 extern void osi_UFSOpen(void);
1905 struct labeltest {
1906    void (*open) (void);
1907 };
1908 struct labeltest struct_labeltest = {
1909    .open       = osi_UFSOpen,
1910 }
1911 ],
1912 [AC_MSG_RESULT(yes)
1913  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1914 ],
1915 [AC_MSG_RESULT(no)
1916 ])
1917
1918 AC_MSG_CHECKING([checking for dirfd])
1919 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1920 #ifdef HAVE_DIRENT_H
1921 #include <dirent.h>
1922 #endif
1923 ]],
1924         [[DIR *d = 0; dirfd(d);]])],
1925         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1926 if test "$ac_rk_have_dirfd" = "yes" ; then
1927         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1928 fi
1929 AC_MSG_RESULT($ac_rk_have_dirfd)
1930
1931 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1932 #ifdef HAVE_DIRENT_H
1933 #include <dirent.h>
1934 #endif])
1935
1936 dnl Eventually, this will look for the system one, or for OpenSSL
1937 LIB_hcrypto="-lafshcrypto"
1938 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1939 AC_SUBST(LIB_hcrypto)
1940 AC_SUBST(LDFLAGS_hcrypto)
1941
1942 dnl Check for UUID library
1943 AC_CHECK_HEADERS([uuid/uuid.h])
1944 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1945 AC_CHECK_FUNCS([uuid_generate])
1946 ])
1947
1948
1949 AC_DEFUN([SUMMARY], [
1950     # Print a configuration summary
1951 echo 
1952 echo "**************************************"
1953 echo configure summary
1954 echo
1955 AS_IF([test $LIB_curses],[
1956 echo "LIB_curses :                $LIB_curses" ],[
1957 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1958 ])
1959 echo 
1960 echo "**************************************"
1961 ])