fileserver: add volume number to error-messages
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([pam],
79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
80     ,
81     [enable_pam="yes"])
82 AC_ARG_ENABLE([gtx],
83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
84 AC_ARG_ENABLE([uss],
85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
86 AC_ARG_ENABLE([namei-fileserver],
87     [AS_HELP_STRING([--enable-namei-fileserver],
88         [force compilation of namei fileserver in preference to inode
89          fileserver])],
90     , 
91     [enable_namei_fileserver="default"])
92 AC_ARG_ENABLE([supergroups],
93     [AS_HELP_STRING([--enable-supergroups],
94         [enable support for nested pts groups])],
95     , 
96     [enable_supergroups="no"])
97 AC_ARG_ENABLE([bitmap-later],
98     [AS_HELP_STRING([--enable-bitmap-later],
99         [enable fast startup of file server by not reading bitmap till
100          needed])],
101     , 
102     [enable_bitmap_later="no"])
103 AC_ARG_ENABLE([unix-sockets],
104     [AS_HELP_STRING([--disable-unix-sockets],
105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
106     ,
107     [enable_unix_sockets="yes"])
108 AC_ARG_ENABLE([tivoli-tsm],
109     [AS_HELP_STRING([--enable-tivoli-tsm],
110         [enable use of the Tivoli TSM API libraries for butc support])],
111     , 
112     [enable_tivoli_tsm="no"])
113 AC_ARG_ENABLE([pthreaded-ubik],
114     [AS_HELP_STRING([--enable-pthreaded-ubik],
115         [enable installation of pthreaded ubik applications (defaults to
116          disabled)])],
117     ,
118     [enable_pthreaded_ubik="no"])
119
120 dnl Kernel module build options.
121 AC_ARG_WITH([linux-kernel-headers],
122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
123         [use the kernel headers found at path (optional, defaults to
124          /usr/src/linux-2.4, then /usr/src/linux)])])
125 AC_ARG_WITH([linux-kernel-build],
126     [AS_HELP_STRING([--with-linux-kernel-build=path],
127         [use the kernel build found at path(optional, defaults to 
128         /usr/src/linux-2.4, then /usr/src/linux)])])
129 AC_ARG_WITH([bsd-kernel-headers],
130     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
131         [use the kernel headers found at path (optional, defaults to
132          /usr/src/sys)])])
133 AC_ARG_WITH([bsd-kernel-build],
134     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
135         [use the kernel build found at path (optional, defaults to
136          KSRC/i386/compile/GENERIC)])])
137 AC_ARG_WITH([linux-kernel-packaging],
138     [AS_HELP_STRING([--with-linux-kernel-packaging],
139         [use standard naming conventions to aid Linux kernel build packaging
140          (disables MPS, sets the kernel module name to openafs.ko, and
141          installs kernel modules into the standard Linux location)])],
142     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
143      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
144     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
145 AC_ARG_ENABLE([kernel-module],
146     [AS_HELP_STRING([--disable-kernel-module],
147         [disable compilation of the kernel module (defaults to enabled)])],
148     , 
149     [enable_kernel_module="yes"])
150 AC_ARG_ENABLE([redhat-buildsys],
151     [AS_HELP_STRING([--enable-redhat-buildsys],
152         [enable compilation of the redhat build system kernel (defaults to
153          disabled)])],
154     ,
155     [enable_redhat_buildsys="no"])
156
157 dnl Installation locations.
158 AC_ARG_ENABLE([transarc-paths],
159     [AS_HELP_STRING([--enable-transarc-paths],
160         [use Transarc style paths like /usr/afs and /usr/vice])],
161     , 
162     [enable_transarc_paths="no"])
163
164 dnl Optimization and debugging flags.
165 AC_ARG_ENABLE([strip-binaries],
166     [AS_HELP_STRING([--disable-strip-binaries],
167         [disable stripping of symbol information from binaries (defaults to
168          enabled)])],
169     ,
170     [enable_strip_binaries="maybe"])
171 AC_ARG_ENABLE([debug],
172     [AS_HELP_STRING([--enable-debug],
173         [enable compilation of the user space code with debugging information
174          (defaults to disabled)])],
175     , 
176     [enable_debug="no"])
177 AC_ARG_ENABLE([optimize],
178     [AS_HELP_STRING([--disable-optimize],
179         [disable optimization for compilation of the user space code (defaults
180          to enabled)])],
181     , 
182     [enable_optimize="yes"])
183 AC_ARG_ENABLE([warnings],
184     [AS_HELP_STRING([--enable-warnings],
185         [enable compilation warnings when building with gcc (defaults to
186          disabled)])],
187     ,
188     [enable_warnings="no"])
189 AC_ARG_ENABLE([checking],
190     [AS_HELP_STRING([--enable-checking],
191         [turn compilation warnings into errors when building with gcc (defaults
192          to disabled)])],
193     [enable_checking="$enableval"],
194     [enable_checking="no"])
195 AC_ARG_ENABLE([debug-kernel],
196     [AS_HELP_STRING([--enable-debug-kernel],
197         [enable compilation of the kernel module with debugging information
198          (defaults to disabled)])],
199     ,
200     [enable_debug_kernel="no"])
201 AC_ARG_ENABLE([optimize-kernel],
202     [AS_HELP_STRING([--disable-optimize-kernel],
203         [disable compilation of the kernel module with optimization (defaults
204          based on platform)])],
205     , 
206     [enable_optimize_kernel=""])
207 AC_ARG_ENABLE([debug-lwp],
208     [AS_HELP_STRING([--enable-debug-lwp],
209         [enable compilation of the LWP code with debugging information
210          (defaults to disabled)])],
211     ,
212     [enable_debug_lwp="no"])
213 AC_ARG_ENABLE([optimize-lwp],
214     [AS_HELP_STRING([--disable-optimize-lwp],
215         [disable optimization for compilation of the LWP code (defaults to
216          enabled)])],
217     ,
218     [enable_optimize_lwp="yes"])
219 AC_ARG_ENABLE([debug-pam],
220     [AS_HELP_STRING([--enable-debug-pam],
221         [enable compilation of the PAM code with debugging information
222          (defaults to disabled)])],
223     ,
224     [enable_debug_pam="no"])
225 AC_ARG_ENABLE([optimize-pam],
226     [AS_HELP_STRING([--disable-optimize-pam],
227         [disable optimization for compilation of the PAM code (defaults to
228          enabled)])],
229     ,
230     [enable_optimize_pam="yes"])
231 AC_ARG_ENABLE([linux-syscall-probing],
232     [AS_HELP_STRING([--enable-linux-syscall-probing],
233         [enable Linux syscall probing (defaults to autodetect)])],
234     ,
235     [enable_linux_syscall_probing="maybe"])
236     
237 AC_ARG_WITH([xslt-processor],
238         AS_HELP_STRING([--with-xslt-processor=ARG],
239         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
240         [XSLTPROC="$withval"],
241         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
242
243 AC_ARG_WITH([html-xsl], 
244         AS_HELP_STRING([--with-html-xsl],
245         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
246         [HTML_XSL="$withval"],
247         [HTML_XSL="html/chunk.xsl"])
248
249 AC_ARG_WITH([docbook2pdf],
250         AS_HELP_STRING([--with-docbook2pdf=ARG],
251         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
252         [DOCBOOK2PDF="$withval"],
253         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
254
255 AC_ARG_WITH([docbook-stylesheets],
256         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
257         [location of DocBook stylesheets (default is to search a set of likely paths)]),
258         [DOCBOOK_STYLESHEETS="$withval"],
259         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
260         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
261                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
262         fi)
263
264 enable_login="no"
265
266 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
267 dnl documentation build.
268 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
269
270 dnl weird ass systems
271 dnl AC_AIX
272 AC_ISC_POSIX
273 dnl AC_MINIX
274
275 dnl Various compiler setup.
276 AC_TYPE_PID_T
277 AC_TYPE_SIZE_T
278
279 dnl Checks for programs.
280 AC_PROG_INSTALL
281 AC_PROG_LN_S
282 AC_PROG_RANLIB
283 AC_PROG_YACC
284 AM_PROG_LEX
285 dnl if we are flex, be lex-compatible
286 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
287
288 OPENAFS_FORCE_ABS_INSTALL
289 OPENAFS_CHECK_BIGENDIAN
290 OPENAFS_PRINTF_TAKES_Z_LEN
291
292 AC_MSG_CHECKING(your OS)
293 system=$host
294 case $system in
295         *-linux*)
296
297                 MKAFS_OSTYPE=LINUX
298                 if test "x$enable_redhat_buildsys" = "xyes"; then
299                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
300                 fi
301                 if test "x$enable_kernel_module" = "xyes"; then
302                  if test "x$with_linux_kernel_headers" != "x"; then
303                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
304                  else
305                    LINUX_KERNEL_PATH="/lib/modules/`uname -r`/source"
306                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
307                      LINUX_KERNEL_PATH="/lib/modules/`uname -r`/build"
308                    fi
309                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
310                      LINUX_KERNEL_PATH="/usr/src/linux-2.4"
311                    fi
312                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
313                      LINUX_KERNEL_PATH="/usr/src/linux"
314                    fi
315                  fi
316                  if test "x$with_linux_kernel_build" != "x"; then
317                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
318                  else
319                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
320                  fi
321                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
322                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
323                    LINUX_VERSION="$linux_kvers"
324                  else
325                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
326                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
327                      LINUX_VERSION="$linux_kvers"
328                    else
329                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
330                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
331                        if test "x$linux_kvers" = "x"; then
332                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
333                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
334                            if test "x$linux_kvers" = "x"; then
335                              AC_MSG_ERROR(Linux headers lack version definition [2])
336                              exit 1
337                            else
338                              LINUX_VERSION="$linux_kvers"
339                            fi
340                          else
341                            AC_MSG_ERROR(Linux headers lack version definition)
342                            exit 1
343                          fi
344                        else
345                          LINUX_VERSION="$linux_kvers"
346                        fi
347                      else
348                        enable_kernel_module="no"
349                      fi
350                    fi
351                  fi
352                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
353                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
354                      enable_kernel_module="no"
355                  fi
356                  if test "x$enable_kernel_module" = "xno"; then
357                   if test "x$with_linux_kernel_headers" != "x"; then
358                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
359                    exit 1
360                   else
361                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
362                   fi
363                  fi
364                  dnl do we need to determine SUBARCH from autoconf.h
365                  SUBARCH=default
366                 fi
367                 AC_MSG_RESULT(linux)
368                 if test "x$enable_kernel_module" = "xyes"; then
369                  case "$LINUX_VERSION" in
370                   2.2.*) AFS_SYSKVERS=22 ;;
371                   2.4.*) AFS_SYSKVERS=24 ;;
372                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
373                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
374                  esac
375                 fi
376                 ;;
377         *-solaris*)
378                 MKAFS_OSTYPE=SOLARIS
379                 AC_MSG_RESULT(sun4)
380                 AC_PATH_PROG(SOLARISCC, [cc], ,
381                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
382                 if test "x$SOLARISCC" = "x" ; then
383                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
384                 fi
385                 SOLARIS_UFSVFS_HAS_DQRWLOCK
386                 SOLARIS_FS_HAS_FS_ROLLED
387                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
388                 ;;
389         *-sunos*)
390                 MKAFS_OSTYPE=SUNOS
391                 enable_kernel_module=no
392                 AC_MSG_RESULT(sun4)
393                 ;;
394         *-hpux*)
395                 MKAFS_OSTYPE=HPUX
396                 AC_MSG_RESULT(hp_ux)
397                 if test -f "/usr/old/usr/include/ndir.h"; then
398                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
399                 fi
400                 ;;
401         *-irix*)
402                 if test -d /usr/include/sys/SN/SN1; then
403                  IRIX_BUILD_IP35="IP35"
404                 fi
405                 MKAFS_OSTYPE=IRIX
406                 AC_MSG_RESULT(sgi)
407                 ;;
408         *-aix*)
409                 MKAFS_OSTYPE=AIX
410                 AC_MSG_RESULT(rs_aix)
411                 ;;
412         arm-*-darwin*)
413                 MKAFS_OSTYPE=DARWIN
414                 AC_MSG_RESULT(arm_darwin)
415                 ;;
416         powerpc-*-darwin*)
417                 MKAFS_OSTYPE=DARWIN
418                 AC_MSG_RESULT(ppc_darwin)
419                 ;;
420         i386-*-darwin*)
421                 MKAFS_OSTYPE=DARWIN
422                 AC_MSG_RESULT(x86_darwin)
423                 ;;
424         x86_64-*-darwin*)
425                 MKAFS_OSTYPE=DARWIN
426                 AC_MSG_RESULT(x86_darwin)
427                 ;;
428         i386-*-freebsd*)
429                 MKAFS_OSTYPE=FBSD
430                 AC_MSG_RESULT(i386_fbsd)
431                 ;;
432         x86_64-*-freebsd*)
433                 MKAFS_OSTYPE=FBSD
434                 AC_MSG_RESULT(amd64_fbsd)
435                 ;;
436         *-netbsd*)
437                 MKAFS_OSTYPE=NBSD
438                 AC_MSG_RESULT(nbsd)
439                 ;;
440         x86_64-*-openbsd*)
441                 MKAFS_OSTYPE=OBSD
442                 AC_MSG_RESULT(amd64_obsd)
443                 ;;
444         i386-*-openbsd*)
445                 MKAFS_OSTYPE=OBSD
446                 AC_MSG_RESULT(i386_obsd)
447                 ;;
448         *-dragonfly*)
449                 MKAFS_OSTYPE=DFBSD
450                 AC_MSG_RESULT(i386_dfbsd)
451                 ;;
452         *)
453                 AC_MSG_RESULT($system)
454                 ;;
455 esac
456
457 if test "x$with_afs_sysname" != "x"; then
458         AFS_SYSNAME="$with_afs_sysname"
459 else
460         AC_MSG_CHECKING(your AFS sysname)
461         case $host in
462                 i?86-*-openbsd?.?)
463                         v=${host#*openbsd}
464                         vM=${v%.*}
465                         vm=${v#*.}
466                         AFS_SYSNAME="i386_obsd${vM}${vm}"
467                         ;;
468                 sparc64-*-openbsd?.?)
469                         v=${host#*openbsd}
470                         vM=${v%.*}
471                         vm=${v#*.}
472                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
473                         ;;
474                 x86_64-*-openbsd?.?)
475                         v=${host#*openbsd}
476                         vM=${v%.*}
477                         vm=${v#*.}
478                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
479                         ;;
480                 i?86-*-freebsd?.*)
481                         v=${host#*freebsd}
482                         vM=${v%.*}
483                         vm=${v#*.}
484                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
485                         ;;
486                 x86_64-*-freebsd?.*)
487                         v=${host#*freebsd}
488                         vM=${v%.*}
489                         vm=${v#*.}
490                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
491                         ;;
492                 i386-*-dragonfly?.*)
493                         v=${host#*dragonfly}
494                         vM=${v%.*}
495                         vm=${v#*.}
496                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
497                         ;;
498                 i?86-*-netbsd*1.6[[M-Z]]*)
499                         AFS_SYSNAME="i386_nbsd20"
500                         ;;
501                 powerpc-*-netbsd*1.6[[M-Z]]*)
502                         AFS_SYSNAME="ppc_nbsd20"
503                         ;;
504                 *-*-netbsd*)
505                         arch=${host%%-unknown*}
506                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
507                                                -e 's/powerpc/ppc/g')
508                         v=${host#*netbsd}
509                         v=${v#*aout}
510                         v=${v#*ecoff}
511                         v=${v#*elf}
512                         vM=${v%%.*}
513                         vM=${vM%.*}
514                         v=${v#*.}
515                         vm=${v%%.*}
516                         vm=${vm%.*}
517                         vm=${vm%%[[_A-Z]]*}
518                         if test $vm -eq 99 ; then
519                                 vM=$((vM+1))
520                         fi
521                         if test $vM -gt 1 ; then
522                                 vm=0
523                         fi
524                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
525                         ;;
526                 hppa*-hp-hpux11.0*)
527                         AFS_SYSNAME="hp_ux110"
528                         ;;
529                 hppa*-hp-hpux11.11)
530                         AFS_SYSNAME="hp_ux11i"
531                         ;;
532                 hppa*-hp-hpux11.23)
533                         AFS_SYSNAME="hp_ux1123"
534                         ;;
535                 ia64-hp-hpux11.22)
536                         AFS_SYSNAME="ia64_hpux1122"
537                         ;;
538                 ia64-hp-hpux*)
539                         AFS_SYSNAME="ia64_hpux1123"
540                         ;;
541                 hppa*-hp-hpux10*)
542                         AFS_SYSNAME="hp_ux102"
543                         ;;
544                 powerpc-apple-darwin7*)
545                         AFS_SYSNAME="ppc_darwin_70"
546                         OSXSDK="macosx10.3"
547                         ;;
548                 powerpc-apple-darwin8.*)
549                         AFS_SYSNAME="ppc_darwin_80"
550                         OSXSDK="macosx10.4"
551                         ;;
552                 i386-apple-darwin8.*)
553                         AFS_SYSNAME="x86_darwin_80"
554                         OSXSDK="macosx10.4"
555                         ;;
556                 powerpc-apple-darwin9.*)
557                         AFS_SYSNAME="ppc_darwin_90"
558                         OSXSDK="macosx10.5"
559                         ;;
560                 i386-apple-darwin9.*)
561                         AFS_SYSNAME="x86_darwin_90"
562                         OSXSDK="macosx10.5"
563                         ;;
564                 i?86-apple-darwin10.*)
565                         AFS_SYSNAME="x86_darwin_100"
566                         OSXSDK="macosx10.6"
567                         ;;
568                 x86_64-apple-darwin10.*)
569                         AFS_SYSNAME="x86_darwin_100"
570                         OSXSDK="macosx10.6"
571                         ;;
572                 arm-apple-darwin10.*)
573                         AFS_SYSNAME="arm_darwin_100"
574                         OSXSDK="iphoneos4.0"
575                         ;;
576                 x86_64-apple-darwin11.*)
577                         AFS_SYSNAME="x86_darwin_110"
578                         OSXSDK="macosx10.7"
579                         ;;
580                 i?86-apple-darwin11.*)
581                         AFS_SYSNAME="x86_darwin_110"
582                         OSXSDK="macosx10.7"
583                         ;;
584                 x86_64-apple-darwin12.*)
585                         AFS_SYSNAME="x86_darwin_120"
586                         OSXSDK="macosx10.8"
587                         ;;
588                 i?86-apple-darwin12.*)
589                         AFS_SYSNAME="x86_darwin_120"
590                         OSXSDK="macosx10.8"
591                         ;;
592                 sparc-sun-solaris2.8)
593                         AFS_SYSNAME="sun4x_58"
594                         ;;
595                 sparc-sun-solaris2.9)
596                         AFS_SYSNAME="sun4x_59"
597                         ;;
598                 sparc-sun-solaris2.10)
599                         AFS_SYSNAME="sun4x_510"
600                         ;;
601                 sparc-sun-solaris2.11)
602                         AFS_SYSNAME="sun4x_511"
603                         ;;
604                 i386-pc-solaris2.8)
605                         AFS_SYSNAME="sunx86_58"
606                         ;;
607                 i386-pc-solaris2.9)
608                         AFS_SYSNAME="sunx86_59"
609                         ;;
610                 i386-pc-solaris2.10)
611                         AFS_SYSNAME="sunx86_510"
612                         ;;
613                 i386-pc-solaris2.11)
614                         AFS_SYSNAME="sunx86_511"
615                         ;;
616                 alpha*-dec-osf4.0*)
617                         AFS_SYSNAME="alpha_dux40"
618                         ;;
619                 alpha*-dec-osf5.0*)
620                         AFS_SYSNAME="alpha_dux50"
621                         ;;
622                 alpha*-dec-osf5.1*)
623                         AFS_SYSNAME="alpha_dux51"
624                         ;;
625                 mips-sgi-irix6.5)
626                         AFS_SYSNAME="sgi_65"
627                         ;;
628                 ia64-*-linux*)
629                         AFS_SYSNAME="ia64_linuxXX"
630                         ;;
631                 powerpc-*-linux*)
632                         AFS_SYSNAME="`/bin/arch`_linuxXX"
633                         ;;
634                 powerpc64-*-linux*)
635                         AFS_SYSNAME="ppc64_linuxXX"
636                         ;;
637                 alpha*-linux*)
638                         AFS_SYSNAME="alpha_linux_XX"
639                         ;;
640                 s390-*-linux*)
641                         AFS_SYSNAME="s390_linuxXX"
642                         ;;
643                 s390x-*-linux*)
644                         AFS_SYSNAME="s390x_linuxXX"
645                         ;;
646                 sparc-*-linux*)
647                         AFS_SYSNAME="`/bin/arch`_linuxXX"
648                         ;;
649                 sparc64-*-linux*)
650                         AFS_SYSNAME="sparc64_linuxXX"
651                         ;;
652                 i?86-*-linux*)
653                         AFS_SYSNAME="i386_linuxXX"
654                         ;;
655                 arm*-linux*)
656                         AFS_SYSNAME="arm_linuxXX"
657                         ;;
658                 parisc-*-linux-gnu|hppa-*-linux-gnu)
659                         AFS_SYSNAME="parisc_linuxXX"
660                         enable_pam="no"
661                         ;;
662                 power*-ibm-aix4.2*)
663                         AFS_SYSNAME="rs_aix42"
664                         enable_pam="no"
665                         ;;
666                 power*-ibm-aix4.3*)
667                         AFS_SYSNAME="rs_aix42"
668                         enable_pam="no"
669                         ;;
670                 power*-ibm-aix5.1*)
671                         AFS_SYSNAME="rs_aix51"
672                         enable_pam="no"
673                         ;;
674                 power*-ibm-aix5.2*)
675                         AFS_SYSNAME="rs_aix52"
676                         enable_pam="no"
677                         ;;
678                 power*-ibm-aix5.3*)
679                         AFS_SYSNAME="rs_aix53"
680                         enable_pam="no"
681                         ;;
682                 power*-ibm-aix6.1*)
683                         AFS_SYSNAME="rs_aix61"
684                         enable_pam="no"
685                         ;;
686                 x86_64-*-linux-gnu)
687                         AFS_SYSNAME="amd64_linuxXX"
688                         enable_pam="yes"
689                         ;;
690                 *)
691                         AC_MSG_ERROR(An AFS sysname is required)
692                         exit 1
693                         ;;
694         esac
695         case $AFS_SYSNAME in
696                 *_linux* | *_umlinux*)
697                         if test "x${AFS_SYSKVERS}" = "x"; then
698                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
699                         fi
700                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
701                         AFS_SYSNAME="$_AFS_SYSNAME"
702                         AC_TRY_KBUILD(
703                          [],
704                          [#ifndef CONFIG_USERMODE
705                           #error not UML
706                           #endif],
707                          ac_cv_linux_is_uml=yes,)
708                         if test "${ac_cv_linux_is_uml}" = yes; then
709                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
710                         fi
711                         AFS_SYSNAME="$_AFS_SYSNAME"
712                         ;;
713         esac
714         AC_MSG_RESULT($AFS_SYSNAME)
715 fi
716
717 case $AFS_SYSNAME in
718         *_darwin*)
719                 AC_CHECK_HEADERS(crt_externs.h)
720                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
721                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
722                 AC_SUBST(OSXSDK)
723                 ;;
724 esac
725
726 dnl Some hosts have a separate common param file they should include.  Figure
727 dnl out if we're on one of them now that we know the sysname.
728 case $AFS_SYSNAME in
729     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
730     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
731     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
732     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
733     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
734     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
735     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
736     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
737     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
738     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
739     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
740     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
741     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
742     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
743     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
744     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
745     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
746     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
747     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
748     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
749     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
750     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
751     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
752     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
753     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
754     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
755     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
756     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
757     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
758 # Linux alpha adds an extra underscore for no good reason.
759     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
760     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
761     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
762 esac
763
764 OPENAFS_OSCONF
765
766 case $AFS_SYSNAME in *_linux* | *_umlinux*)
767
768                 # Add (sub-) architecture-specific paths needed by conftests
769                 case $AFS_SYSNAME  in
770                         *_umlinux26)
771                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
772                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
773                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
774                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
775                 esac
776
777                 if test "x$enable_kernel_module" = "xyes"; then
778                  if test "x$enable_debug_kernel" = "xno"; then
779                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
780                  fi
781                  OPENAFS_GCC_SUPPORTS_MARCH
782                  AC_SUBST(P5PLUS_KOPTS)
783                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
784                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
785                  OPENAFS_GCC_SUPPORTS_NO_COMMON
786                  OPENAFS_GCC_SUPPORTS_PIPE
787                  AC_SUBST(LINUX_GCC_KOPTS)
788
789                  dnl Setup the kernel build environment
790                  LINUX_KBUILD_USES_EXTRA_CFLAGS
791                  LINUX_KERNEL_COMPILE_WORKS
792
793                  dnl Check for header files
794                  AC_CHECK_LINUX_HEADER([config.h])
795                  AC_CHECK_LINUX_HEADER([completion.h])
796                  AC_CHECK_LINUX_HEADER([exportfs.h])
797                  AC_CHECK_LINUX_HEADER([freezer.h])
798                  AC_CHECK_LINUX_HEADER([key-type.h])
799                  AC_CHECK_LINUX_HEADER([semaphore.h])
800                  AC_CHECK_LINUX_HEADER([seq_file.h])
801
802                  dnl Check for structure elements
803                  AC_CHECK_LINUX_STRUCT([address_space_operations],
804                                        [write_begin], [fs.h])
805                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
806                                        [backing-dev.h])
807                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
808                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
809                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
810                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
811                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
812                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
813                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
814                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
815                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
816                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
817                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
818                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
819                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
820                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
821                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
822                                        [fs.h])
823                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
824                                        [fs.h])
825                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
826                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
827                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
828                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
829                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
830                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
831                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
832                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
833                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
834                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
835                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
836
837                  dnl Check for typed structure elements
838                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
839                                              [buf], [fs.h])
840
841                  dnl Function existence checks
842
843                  AC_CHECK_LINUX_FUNC([bdi_init],
844                                      [#include <linux/backing-dev.h>],
845                                      [bdi_init(NULL);])
846                  AC_CHECK_LINUX_FUNC([PageChecked],
847                                      [#include <linux/mm.h>
848 #include <linux/page-flags.h>],
849                                      [struct page *_page;
850                                       int bchecked = PageChecked(_page);])
851                  AC_CHECK_LINUX_FUNC([PageFsMisc],
852                                      [#include <linux/mm.h>
853 #include <linux/page-flags.h>],
854                                      [struct page *_page;
855                                       int bchecked = PageFsMisc(_page);])
856                  AC_CHECK_LINUX_FUNC([clear_inode],
857                                      [#include <linux/fs.h>],
858                                      [clear_inode(NULL);])
859                  AC_CHECK_LINUX_FUNC([current_kernel_time],
860                                      [#include <linux/time.h>],
861                                      [struct timespec s;
862                                       s = current_kernel_time();])
863                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
864                                      [#include <linux/fs.h>],
865                                      [d_alloc_anon(NULL);])
866                  AC_CHECK_LINUX_FUNC([d_make_root],
867                                      [#include <linux/fs.h>],
868                                      [d_make_root(NULL);])
869                  AC_CHECK_LINUX_FUNC([do_sync_read],
870                                      [#include <linux/fs.h>],
871                                      [do_sync_read(NULL, NULL, 0, NULL);])
872                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
873                                      [#include <linux/sched.h>],
874                                      [pid_t p; find_task_by_pid(p);])
875                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
876                                      [#include <linux/fs.h>],
877                                      [generic_file_aio_read(NULL,NULL,0,0);])
878                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
879                                      [#include <linux/pagemap.h>],
880                                      [grab_cache_page_write_begin(NULL, 0, 0);])
881                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
882                                      [#include <linux/list.h>],
883                                      [hlist_unhashed(0);])
884                  AC_CHECK_LINUX_FUNC([i_size_read],
885                                      [#include <linux/fs.h>],
886                                      [i_size_read(NULL);])
887                  AC_CHECK_LINUX_FUNC([inode_setattr],
888                                      [#include <linux/fs.h>],
889                                      [inode_setattr(NULL, NULL);])
890                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
891                                      [#include <linux/net.h>],
892                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
893                  AC_CHECK_LINUX_FUNC([page_follow_link],
894                                      [#include <linux/fs.h>],
895                                      [page_follow_link(0,0);])
896                  AC_CHECK_LINUX_FUNC([page_offset],
897                                      [#include <linux/pagemap.h>],
898                                      [page_offset(NULL);])
899                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
900                                      [#include <linux/pagevec.h>],
901                                      [__pagevec_lru_add_file(NULL);])
902                  AC_CHECK_LINUX_FUNC([path_lookup],
903                                      [#include <linux/fs.h>
904                                       #include <linux/namei.h>],
905                                      [path_lookup(NULL, 0, NULL);])
906                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
907                                      [#include <linux/rcupdate.h>],
908                                      [rcu_read_lock();])
909                  AC_CHECK_LINUX_FUNC([set_nlink],
910                                      [#include <linux/fs.h>],
911                                      [set_nlink(NULL, 1);])
912                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
913                                      [#include <linux/splice.h>],
914                                      [splice_direct_to_actor(NULL,NULL,NULL);])
915                  AC_CHECK_LINUX_FUNC([svc_addr_in],
916                                      [#include <linux/sunrpc/svc.h>],
917                                      [svc_addr_in(NULL);])
918                  AC_CHECK_LINUX_FUNC([zero_user_segments],
919                                      [#include <linux/highmem.h>],
920                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
921                  AC_CHECK_LINUX_FUNC([noop_fsync],
922                                      [#include <linux/fs.h>],
923                                      [void *address = &noop_fsync; printk("%p\n", address)];)
924                  AC_CHECK_LINUX_FUNC([kthread_run],
925                                      [#include <linux/kernel.h>
926                                       #include <linux/kthread.h>],
927                                      [kthread_run(NULL, NULL, "test");])
928
929                  dnl Consequences - things which get set as a result of the
930                  dnl                above tests
931                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
932                        [AC_DEFINE([AFS_NONFSTRANS], 1,
933                                   [define to disable the nfs translator])])
934
935                  dnl Assorted more complex tests
936                  LINUX_EXPORTS_PROC_ROOT_FS
937                  LINUX_KMEM_CACHE_INIT
938                  LINUX_HAVE_KMEM_CACHE_T
939                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
940                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
941                  LINUX_D_PATH_TAKES_STRUCT_PATH
942                  LINUX_NEW_EXPORT_OPS
943                  LINUX_INODE_SETATTR_RETURN_TYPE
944                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
945                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
946                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
947                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
948                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
949                  LINUX_DOP_D_DELETE_TAKES_CONST
950                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
951                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
952                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
953                  LINUX_FOP_F_FSYNC_TAKES_RANGE
954                  LINUX_AOP_WRITEBACK_CONTROL
955                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
956                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
957                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
958                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
959                  LINUX_KERNEL_SOCK_CREATE
960                  LINUX_EXPORTS_KEY_TYPE_KEYRING
961                  LINUX_NEED_RHCONFIG
962                  LINUX_RECALC_SIGPENDING_ARG_TYPE
963                  LINUX_EXPORTS_TASKLIST_LOCK
964                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
965                  LINUX_STATFS_TAKES_DENTRY
966                  LINUX_REFRIGERATOR
967                  LINUX_HAVE_TRY_TO_FREEZE
968                  LINUX_LINUX_KEYRING_SUPPORT
969                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
970                  LINUX_KEY_ALLOC_NEEDS_CRED
971                  LINUX_INIT_WORK_HAS_DATA
972                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
973                  LINUX_HAVE_DCACHE_LOCK
974                  LINUX_D_COUNT_IS_INT
975                  LINUX_IOP_MKDIR_TAKES_UMODE_T
976                  LINUX_IOP_CREATE_TAKES_UMODE_T
977                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
978                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
979                  LINUX_DENTRY_OPEN_TAKES_PATH
980                  LINUX_D_ALIAS_IS_HLIST
981                  LINUX_IOP_I_CREATE_TAKES_BOOL
982                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
983                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
984
985                  dnl If we are guaranteed that keyrings will work - that is
986                  dnl  a) The kernel has keyrings enabled
987                  dnl  b) The code is new enough to give us a key_type_keyring
988                  dnl then we just disable syscall probing unless we've been
989                  dnl told otherwise
990
991                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
992                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
993                           [enable_linux_syscall_probing="no"],
994                           [enable_linux_syscall_probing="yes"])
995                  ])
996
997                  dnl Syscall probing needs a few tests of its own, and just
998                  dnl won't work if the kernel doesn't export init_mm
999                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1000                    LINUX_EXPORTS_INIT_MM
1001                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1002                      AC_MSG_ERROR(
1003                        [Can't do syscall probing without exported init_mm])
1004                    ])
1005                    LINUX_EXPORTS_SYS_CHDIR
1006                    LINUX_EXPORTS_SYS_OPEN
1007                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1008                              [define to enable syscall table probes])
1009                  ])
1010
1011                  dnl Packaging and SMP build
1012                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1013                    LINUX_WHICH_MODULES
1014                  else
1015                    AC_SUBST(MPS,'SP')
1016                  fi
1017
1018                  dnl Syscall probing
1019                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1020                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1021                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1022                    ])
1023                    ac_cv_linux_exports_sys_call_table=no
1024                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1025                      ac_cv_linux_exports_ia32_sys_call_table=yes
1026                    fi
1027                  else
1028                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1029                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1030                    LINUX_EXPORTS_SYS_CALL_TABLE
1031                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1032                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1033                          linux_syscall_method=none
1034                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1035                             linux_syscall_method=scan
1036                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1037                                linux_syscall_method=scan_with_kallsyms_address
1038                             fi
1039                          fi
1040                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1041                             linux_syscall_method=kallsyms_symbol
1042                          fi
1043                          if test "x$linux_syscall_method" = "xnone"; then
1044                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1045                             linux_syscall_method=scan
1046                          fi
1047                    fi
1048                  fi
1049                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1050                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1051                  fi
1052                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1053                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1054                  fi
1055                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1056                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1057                  else
1058                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1059                  fi
1060                 :
1061                 fi
1062 dnl Linux-only, but just enable always.
1063                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1064 esac
1065
1066 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1067     [ac_cv_sync_fetch_and_add],
1068     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1069                     [ac_cv_sync_fetch_and_add=yes],
1070                     [ac_cv_sync_fetch_and_add=no])
1071 ])
1072 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1073       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1074                 [define if your C compiler has __sync_add_and_fetch])])
1075
1076 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1077     [ac_cv_sockaddr_len],
1078     [AC_TRY_COMPILE( [#include <sys/types.h>
1079 #include <sys/socket.h>],
1080                      [struct sockaddr *a; a->sa_len=0;],
1081                      [ac_cv_sockaddr_len=yes],
1082                      [ac_cv_sockaddr_len=no])
1083 ])
1084 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1085       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1086                  [define if you struct sockaddr sa_len])])
1087
1088 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1089         echo Skipping library tests because they confuse Irix.
1090 else
1091   AC_SEARCH_LIBS([socket], [socket inet])
1092   AC_SEARCH_LIBS([connect], [nsl])
1093   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1094
1095   dnl darwin wants it, aix hates it
1096   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1097   AC_TRY_COMPILE([
1098   #include <stdlib.h>
1099   #include <stdio.h>
1100   #include <sys/types.h>
1101   #include <sys/socket.h>
1102   #include <netinet/in.h>
1103   #include <arpa/inet.h>
1104   #include <arpa/nameser.h>
1105   #include <arpa/nameser_compat.h>
1106   #include <resolv.h>
1107   ], [static int i; i = 0;],
1108   [AC_MSG_RESULT(yes)
1109    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1110   [AC_MSG_RESULT(no)
1111    ])
1112
1113   openafs_save_libs="$LIBS"
1114   AC_MSG_CHECKING([for res_search])
1115   AC_FUNC_RES_SEARCH
1116
1117   if test "$ac_cv_func_res_search" = no; then
1118       for lib in dns nsl resolv; do
1119         if test "$ac_cv_func_res_search" != yes; then
1120           LIBS="-l$lib $LIBS"
1121           AC_FUNC_RES_SEARCH
1122           LIBS="$openafs_save_libs"
1123         fi
1124       done    
1125       if test "$ac_cv_func_res_search" = yes; then
1126         LIB_AFSDB="-l$lib"
1127         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1128         AC_MSG_RESULT([yes, in lib$lib])
1129       else
1130         AC_MSG_RESULT(no)
1131       fi
1132   else
1133     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1134     AC_MSG_RESULT(yes)
1135   fi
1136   
1137 fi
1138 XLIBS="$LIB_AFSDB $XLIBS"
1139
1140 AC_CHECK_RESOLV_RETRANS
1141
1142 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1143     [ac_cv_setsockopt_iprecverr],
1144     [AC_TRY_COMPILE( [
1145 #include <sys/types.h>
1146 #include <sys/socket.h>
1147 #include <netinet/in.h>],
1148 [int on=1;
1149 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1150         [ac_cv_setsockopt_iprecverr=yes],
1151         [ac_cv_setsockopt_iprecverr=no])])
1152
1153 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1154       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1155                  [define if we can receive socket errors via IP_RECVERR])])
1156
1157 PTHREAD_LIBS=error
1158 if test "x$MKAFS_OSTYPE" = OBSD; then
1159         PTHREAD_LIBS="-pthread"
1160 fi
1161 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1162         PTHREAD_LIBS="-pthread"
1163 fi
1164 if test "x$PTHREAD_LIBS" = xerror; then
1165         AC_CHECK_LIB(pthread, pthread_attr_init,
1166                 PTHREAD_LIBS="-lpthread")
1167 fi
1168 if test "x$PTHREAD_LIBS" = xerror; then
1169         AC_CHECK_LIB(pthreads, pthread_attr_init,
1170                 PTHREAD_LIBS="-lpthreads")
1171 fi
1172 if test "x$PTHREAD_LIBS" = xerror; then
1173         AC_CHECK_LIB(c_r, pthread_attr_init,
1174                 PTHREAD_LIBS="-lc_r")
1175 fi
1176 if test "x$PTHREAD_LIBS" = xerror; then
1177         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1178 fi
1179 if test "x$PTHREAD_LIBS" = xerror; then
1180         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1181         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1182                 PTHREAD_LIBS="-lpthread")
1183 fi
1184 if test "x$PTHREAD_LIBS" = xerror; then
1185         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1186 fi
1187 AC_SUBST(PTHREAD_LIBS)
1188
1189 HOST_CPU="$host_cpu"
1190
1191 if test "x$with_bsd_kernel_headers" != "x"; then
1192         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1193 else
1194         BSD_KERNEL_PATH="/usr/src/sys"
1195 fi
1196
1197 if test "x$with_bsd_kernel_build" != "x"; then
1198         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1199 else
1200         case $AFS_SYSNAME in
1201                 *_fbsd_*)
1202                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1203                         ;;
1204                 *_nbsd*)
1205                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1206         esac
1207 fi
1208
1209 # Fast restart
1210 if test "$enable_supergroups" = "yes"; then
1211         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1212 fi
1213
1214 if test "$enable_bitmap_later" = "yes"; then
1215         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1216 fi
1217
1218 if test "$enable_unix_sockets" = "yes"; then
1219         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1220         USE_UNIX_SOCKETS="yes"
1221 else
1222         USE_UNIX_SOCKETS="no"
1223 fi
1224 AC_SUBST(USE_UNIX_SOCKETS)
1225
1226 if test "$enable_namei_fileserver" = "yes"; then
1227         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1228         VFSCK=""
1229 else
1230         if test "$enable_namei_fileserver" = "default"; then
1231                 case $host in
1232                         *-solaris2.10*)
1233                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1234                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1235                                 VFSCK=""
1236                                 ;;
1237                         *-solaris2.11*)
1238                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1239                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1240                                 VFSCK=""
1241                                 ;;
1242                         *)
1243                                 VFSCK="vfsck"
1244                                 ;;
1245                 esac
1246         else
1247                 VFSCK="vfsck"
1248         fi
1249 fi
1250
1251 dnl check for tivoli
1252 AC_MSG_CHECKING(for tivoli tsm butc support)
1253 XBSA_CFLAGS=""
1254 if test "$enable_tivoli_tsm" = "yes"; then
1255         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1256         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1257         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1258         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1259
1260         if test -r "$XBSADIR3/dsmapifp.h"; then
1261                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1262                 XBSA_XLIBS="-ldl"
1263                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1264         elif test -r "$XBSADIR4/dsmapifp.h"; then
1265                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1266                 XBSA_XLIBS="-ldl"
1267                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1268         elif test -r "$XBSADIR1/xbsa.h"; then
1269                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1270                 XBSA_XLIBS=""
1271                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1272         elif test -r "$XBSADIR2/xbsa.h"; then
1273                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1274                 XBSA_XLIBS=""
1275                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1276         else
1277                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1278         fi
1279 else
1280         AC_MSG_RESULT([no])
1281 fi
1282 AC_SUBST(XBSA_CFLAGS)
1283 AC_SUBST(XBSA_XLIBS) 
1284
1285 dnl checks for header files.
1286 AC_HEADER_STDC
1287 AC_HEADER_SYS_WAIT
1288 AC_HEADER_DIRENT
1289 AC_CHECK_HEADERS([ \
1290                    arpa/inet.h \
1291                    arpa/nameser.h \
1292                    curses.h\
1293                    direct.h \
1294                    et/com_err.h \
1295                    errno.h \
1296                    fcntl.h \
1297                    grp.h \
1298                    math.h \
1299                    mntent.h \
1300                    ncurses.h \
1301                    netdb.h \
1302                    netinet/in.h \
1303                    pthread_np.h \
1304                    pwd.h \
1305                    regex.h \
1306                    security/pam_appl.h \
1307                    signal.h \
1308                    stdint.h \
1309                    stdio_ext.h \
1310                    stdlib.h \
1311                    string.h \
1312                    strings.h \
1313                    sys/bitypes.h \
1314                    sys/bswap.h \
1315                    sys/dk.h \
1316                    sys/fcntl.h \
1317                    sys/file.h \
1318                    sys/fs_types.h \
1319                    sys/fstyp.h \
1320                    sys/ioctl.h \
1321                    sys/ipc.h \
1322                    sys/lockf.h \
1323                    sys/map.h \
1324                    sys/mount.h \
1325                    sys/mntent.h \
1326                    sys/mnttab.h \
1327                    sys/pag.h \
1328                    sys/param.h \
1329                    sys/resource.h \
1330                    sys/select.h \
1331                    sys/statfs.h \
1332                    sys/statvfs.h \
1333                    sys/socket.h \
1334                    sys/sysctl.h \
1335                    sys/time.h \
1336                    sys/types.h \
1337                    sys/uio.h \
1338                    sys/un.h \
1339                    sys/vfs.h \
1340                    syslog.h \
1341                    termios.h \
1342                    time.h \
1343                    ucontext.h \
1344                    unistd.h \
1345                    windows.h \
1346                 ])
1347
1348 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1349 #ifdef HAVE_NETINET_IN_H
1350 # include <netinet/in.h>
1351 #endif])
1352
1353 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1354 #ifdef HAVE_SYS_SOCKET_H
1355 # include <sys/socket.h>
1356 #endif])
1357
1358 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1359 #ifdef HAVE_SYS_SOCKET_H
1360 # include <sys/socket.h>
1361 #endif
1362 #ifdef HAVE_NETINET_IN_H
1363 # include <netinet/in.h>
1364 #endif
1365 #ifdef HAVE_NET_IF_H
1366 # include <net/if.h>
1367 #endif])
1368
1369 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1370 #ifdef HAVE_SECURITY_PAM_APPL_H
1371 # include <security/pam_appl.h>
1372 #endif])
1373
1374 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1375
1376 AC_CHECK_TYPES([fsblkcnt_t],,,[
1377 #include <sys/types.h>
1378 #ifdef HAVE_SYS_BITYPES_H
1379 #include <sys/bitypes.h>
1380 #endif
1381 #ifdef HAVE_SYS_STATFS_H
1382 #include <sys/statfs.h>
1383 #endif
1384 #ifdef HAVE_SYS_STATVFS_H
1385 #include <sys/statvfs.h>
1386 #endif
1387 ])
1388
1389 dnl see what struct stat has for timestamps
1390 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1391
1392 dnl check for curses-lib
1393 AS_IF([test "x$enable_gtx" != "xno"],
1394       [save_LIBS=$LIBS
1395       AC_CHECK_LIB( [ncurses], [setupterm],
1396       [LIB_curses=-lncurses],
1397         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1398           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1399       ])
1400       LIBS=$save_LIBS
1401       AC_SUBST(LIB_curses)])
1402         
1403 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1404
1405 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1406 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1407         case $AFS_SYSNAME in
1408         sgi_*)
1409                 HAVE_PAM="no"
1410                 ;;
1411         *)
1412                 HAVE_PAM="yes"
1413                 ;;
1414         esac
1415 else
1416         HAVE_PAM="no"
1417 fi
1418 AC_SUBST(HAVE_PAM)
1419
1420 if test "$enable_login" = yes; then
1421         BUILD_LOGIN="yes"
1422 else
1423         BUILD_LOGIN="no"
1424 fi
1425 AC_SUBST(BUILD_LOGIN)
1426
1427 if test "$enable_uss" = yes; then
1428         BUILD_USS="yes"
1429 else
1430         BUILD_USS="no"
1431 fi
1432 AC_SUBST(BUILD_USS)
1433
1434 AC_CHECK_FUNCS([ \
1435         arc4random \
1436         fcntl \
1437         fseeko64 \
1438         ftello64 \
1439         getcwd \
1440         getegid \
1441         geteuid \
1442         getgid \
1443         getuid \
1444         getrlimit \
1445         issetugid \
1446         mkstemp \
1447         pread \
1448         preadv \
1449         preadv64 \
1450         pwrite \
1451         pwritev \
1452         pwritev64 \
1453         regcomp \
1454         regerror \
1455         regexec \
1456         setitimer \
1457         setvbuf \
1458         sigaction \
1459         strcasestr \
1460         strerror \
1461         sysconf \
1462         sysctl \
1463         tdestroy \
1464         timegm \
1465 ])
1466
1467 OPENAFS_ROKEN()
1468 OPENAFS_C_ATTRIBUTE()
1469
1470 dnl Functions that Heimdal's libroken provides, but that we
1471 dnl haven't found a need for yet, and so haven't imported
1472 AC_CHECK_FUNCS([ \
1473         chown \
1474         fchown \
1475         gethostname \
1476         lstat \
1477         inet_aton \
1478         inet_ntop \
1479         inet_pton \
1480         putenv \
1481         readv \
1482         setenv \
1483         strdup \
1484         strftime \
1485         strndup \
1486         strsep \
1487         unsetenv \
1488 ])
1489
1490 dnl Functions that are in objects that we always build from libroken
1491 AC_CHECK_FUNCS([ \
1492         asprintf \
1493         asnprintf \
1494         vasprintf \
1495         vasnprintf \
1496         vsnprintf \
1497         snprintf \
1498 ])
1499
1500 dnl Functions that we're going to try and get from libroken
1501 AC_REPLACE_FUNCS([ \
1502         daemon \
1503         ecalloc \
1504         emalloc \
1505         erealloc \
1506         err \
1507         errx \
1508         flock \
1509         getdtablesize \
1510         getopt \
1511         getprogname \
1512         gettimeofday \
1513         localtime_r \
1514         mkstemp \
1515         setenv \
1516         setprogname \
1517         strcasecmp \
1518         strlcat \
1519         strnlen \
1520         strlcpy \
1521         strsep \
1522         tdelete \
1523         tfind \
1524         tsearch \
1525         twalk \
1526         unsetenv \
1527         verr \
1528         verrx \
1529         vsyslog \
1530         vwarn \
1531         vwarnx \
1532         warn \
1533         warnx \
1534 ])
1535
1536 dnl Headers that we're going to try and get from libroken
1537 AC_CHECK_HEADERS([ \
1538         err.h \
1539         search.h \
1540 ])
1541
1542 AC_CHECK_DECLS([h_errno], [], [], [
1543 #include <sys/types.h>
1544 #ifdef HAVE_NETDB_H
1545 #include <netdb.h>
1546 #endif
1547 ])
1548
1549 AC_HEADER_TIME
1550
1551 ROKEN_HEADERS=
1552 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1553       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1554       [])
1555 AC_SUBST(ROKEN_HEADERS)
1556
1557 dnl Stuff that's harder ...
1558 AC_MSG_CHECKING([for bswap16])
1559 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1560 #ifdef HAVE_SYS_TYPES_H
1561 #include <sys/types.h>
1562 #endif
1563 #ifdef HAVE_SYS_BSWAP_H
1564 #include <sys/bswap.h>
1565 #endif
1566 ],
1567 [short a, b; b = bswap16(a); ])],
1568 [AC_MSG_RESULT(yes)
1569  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1570 ],
1571 [AC_MSG_RESULT(no)])
1572
1573 AC_MSG_CHECKING([for bswap32])
1574 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1575 #include <sys/types.h>
1576 #endif
1577 #ifdef HAVE_SYS_BSWAP_H
1578 #include <sys/bswap.h>
1579 #endif
1580 ],
1581 [int a, b; b = bswap32(a); ])],
1582 [AC_MSG_RESULT(yes)
1583  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1584 ],
1585 [AC_MSG_RESULT(no)])
1586
1587 case $AFS_SYSNAME in
1588 *hp_ux* | *hpux*)
1589    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1590    ;;
1591 *)
1592    AC_MSG_CHECKING([for positional I/O])
1593    if test "$ac_cv_func_pread" = "yes" && \
1594            test "$ac_cv_func_pwrite" = "yes"; then
1595       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1596       AC_MSG_RESULT(yes)
1597    else
1598      AC_MSG_RESULT(no)
1599    fi
1600    AC_MSG_CHECKING([for vectored positional I/O])
1601    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1602                "$ac_cv_func_pwritev" = "yes" -a \
1603                "$ac_cv_func_preadv64" = "yes" -a \
1604                "$ac_cv_func_pwritev64" = "yes"],
1605          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1606           AC_MSG_RESULT(yes)],
1607          [AC_MSG_RESULT(no)])
1608    ;;
1609 esac
1610
1611 AC_MSG_CHECKING([for POSIX regex library])
1612 if test "$ac_cv_header_regex_h" = "yes" && \
1613         test "$ac_cv_func_regcomp" = "yes" && \
1614         test "$ac_cv_func_regexec" = "yes" && \
1615         test "$ac_cv_func_regerror" = "yes"; then
1616     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1617     AC_MSG_RESULT(yes)
1618 else
1619     AC_MSG_RESULT(no)
1620 fi
1621
1622 dnl Look for "non-portable" pthreads functions.
1623 save_LIBS="$LIBS"
1624 LIBS="$LIBS $PTHREAD_LIBS"
1625 AC_CHECK_FUNCS([ \
1626         pthread_set_name_np \
1627         pthread_setname_np \
1628 ])
1629
1630 dnl Sadly, there are three different versions of pthread_setname_np.
1631 dnl Try to cater for all of them.
1632 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1633     AC_MSG_CHECKING([for signature of pthread_setname_np])
1634     AC_TRY_COMPILE([
1635 #include <pthread.h>
1636 #ifdef HAVE_PTHREAD_NP_H
1637 #include <pthread_np.h>
1638 #endif
1639 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1640         AC_MSG_RESULT([three arguments])
1641         pthread_setname_np_args=3], [
1642         AC_TRY_COMPILE([
1643 #include <pthread.h>
1644 #ifdef HAVE_PTHREAD_NP_H
1645 #include <pthread_np.h>
1646 #endif
1647 ], [pthread_setname_np(pthread_self(), "test")], [
1648             AC_MSG_RESULT([two arguments])
1649             pthread_setname_np_args=2], [
1650             AC_TRY_COMPILE([
1651 #include <pthread.h>
1652 #ifdef HAVE_PTHREAD_NP_H
1653 #include <pthread_np.h>
1654 #endif
1655 ], [pthread_setname_np("test")], [
1656                 AC_MSG_RESULT([one argument])
1657                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1658 ])
1659 ])
1660 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1661 fi
1662 LIBS="$save_LIBS"
1663
1664 openafs_cv_saved_CFLAGS="$CFLAGS"
1665 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1666
1667 AC_TYPE_SIGNAL
1668 OPENAFS_RETSIGTYPE
1669 AC_CHECK_SIZEOF(void *)
1670 AC_CHECK_SIZEOF(unsigned long long)
1671 AC_CHECK_SIZEOF(unsigned long)
1672 AC_CHECK_SIZEOF(unsigned int)
1673 AC_TYPE_INTPTR_T
1674 AC_TYPE_UINTPTR_T
1675 AC_TYPE_SSIZE_T
1676 AC_CHECK_TYPE([sig_atomic_t],[],
1677     [AC_DEFINE([sig_atomic_t], [int],
1678         [Define to int if <signal.h> does not define.])],
1679 [#include <sys/types.h>
1680 #include <signal.h>])
1681 AC_CHECK_TYPE([socklen_t],[],
1682     [AC_DEFINE([socklen_t], [int],
1683         [Define to int if <sys/socket.h> does not define.])],
1684 [#include <sys/types.h>
1685 #include <sys/socket.h>])
1686 AC_CHECK_TYPES(off64_t)
1687 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1688 AC_CHECK_TYPES([struct winsize], [], [], [
1689 #ifdef HAVE_TERMIOS_H
1690 # include <termios.h>
1691 #else
1692 # include <sys/termios.h>
1693 #endif
1694 #include <sys/ioctl.h>])
1695 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1696                 struct sockaddr_storage],
1697                [], [], [
1698 #include <sys/types.h>
1699 #include <sys/socket.h>
1700 ])
1701 AC_CHECK_TYPES([sa_family_t], [], [], [
1702 #include <sys/types.h>
1703 #include <sys/socket.h>
1704 ])
1705 AC_CHECK_TYPES([struct addrinfo], [], [], [
1706 #include <sys/types.h>
1707 #ifdef HAVE_NETDB_H
1708 #include <netdb.h>
1709 #endif
1710 ])
1711 AC_CHECK_TYPES([long long], [], [], [])
1712
1713 AC_SIZEOF_TYPE(long)
1714
1715 CFLAGS="$openafs_cv_saved_CFLAGS"
1716
1717 RRA_HEADER_PAM_CONST
1718
1719
1720 dnl Directory PATH handling
1721 if test "x$enable_transarc_paths" = "xyes"  ; then 
1722     afsconfdir=${afsconfdir=/usr/afs/etc}
1723     viceetcdir=${viceetcdir=/usr/vice/etc}
1724     afskerneldir=${afskerneldir=${viceetcdir}}
1725     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1726     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1727     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1728     afsdbdir=${afsdbdir=/usr/afs/db}
1729     afslogsdir=${afslogsdir=/usr/afs/logs}
1730     afslocaldir=${afslocaldir=/usr/afs/local}
1731     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1732     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1733     afsdatadir=${afsdatadir=/usr/vice/etc}
1734 else 
1735     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1736     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1737     afskerneldir=${afskerneldir='${libdir}/openafs'}
1738     afssrvbindir=${afssrvbindir='${bindir}'}
1739     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1740     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1741     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1742     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1743     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1744     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1745     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1746     afsdatadir=${afsdatadir='${datadir}/openafs'}
1747 fi
1748 AC_SUBST(afsconfdir)
1749 AC_SUBST(viceetcdir)
1750 AC_SUBST(afskerneldir)
1751 AC_SUBST(afssrvbindir)
1752 AC_SUBST(afssrvsbindir)
1753 AC_SUBST(afssrvlibexecdir)
1754 AC_SUBST(afsdbdir)
1755 AC_SUBST(afslogsdir)
1756 AC_SUBST(afslocaldir)
1757 AC_SUBST(afsbackupdir)
1758 AC_SUBST(afsbosconfigdir)
1759 AC_SUBST(afsdatadir)
1760
1761 if test "x$enable_kernel_module" = "xyes"; then
1762 ENABLE_KERNEL_MODULE=libafs
1763 fi
1764
1765 if test "x$enable_pthreaded_ubik" = "xyes"; then
1766 ENABLE_PTHREADED_UBIK=yes
1767 fi
1768
1769 AC_SUBST(VFSCK)
1770 AC_SUBST(AFS_SYSNAME)
1771 AC_SUBST(AFS_PARAM_COMMON)
1772 AC_SUBST(ENABLE_KERNEL_MODULE)
1773 AC_SUBST(ENABLE_PTHREADED_UBIK)
1774 AC_SUBST(LIB_AFSDB)
1775 AC_SUBST(LINUX_KERNEL_PATH)
1776 AC_SUBST(LINUX_KERNEL_BUILD)
1777 AC_SUBST(HOST_CPU)
1778 AC_SUBST(BSD_KERNEL_PATH)
1779 AC_SUBST(BSD_KERNEL_BUILD)
1780 AC_SUBST(LINUX_VERSION)
1781 AC_SUBST(MKAFS_OSTYPE)
1782 AC_SUBST(TOP_OBJDIR)
1783 AC_SUBST(TOP_SRCDIR)
1784 AC_SUBST(TOP_INCDIR)
1785 AC_SUBST(TOP_LIBDIR)
1786 AC_SUBST(DEST)
1787 AC_SUBST(DARWIN_INFOFILE)
1788 AC_SUBST(IRIX_BUILD_IP35)
1789 AC_SUBST(HTML_XSL)
1790 AC_SUBST(XSLTPROC)
1791 AC_SUBST(DOCBOOK2PDF)
1792 AC_SUBST(DOCBOOK_STYLESHEETS)
1793
1794 OPENAFS_FUSE
1795 OPENAFS_SWIG
1796
1797 TOP_SRCDIR="${srcdir}/src"
1798 dnl
1799 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1800 dnl
1801 case $TOP_SRCDIR in
1802         /*)
1803                 ;;
1804         *)
1805                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1806                 ;;
1807 esac
1808
1809 TOP_OBJDIR="${SRCDIR_PARENT}"
1810 TOP_INCDIR="${SRCDIR_PARENT}/include"
1811 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1812 if test "${DEST}x" = "x"; then
1813         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1814 fi
1815
1816 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1817 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1818 AC_SUBST(HELPER_SPLINT)
1819 AC_SUBST(HELPER_SPLINTCFG)
1820
1821 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1822
1823 dnl Check to see if crypt lives in a different library
1824 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1825 AC_SUBST(LIB_crypt)
1826
1827 dnl Check to see if the compiler support labels in structs
1828 AC_MSG_CHECKING(for label support in structs)
1829 AC_TRY_COMPILE([], [
1830 extern void osi_UFSOpen(void);
1831 struct labeltest {
1832    void (*open) (void);
1833 };
1834 struct labeltest struct_labeltest = {
1835    .open       = osi_UFSOpen,
1836 }
1837 ],
1838 [AC_MSG_RESULT(yes)
1839  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1840 ],
1841 [AC_MSG_RESULT(no)
1842 ])
1843
1844 AC_MSG_CHECKING([checking for dirfd])
1845 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1846 #ifdef HAVE_DIRENT_H
1847 #include <dirent.h>
1848 #endif
1849 ]],
1850         [[DIR *d = 0; dirfd(d);]])],
1851         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1852 if test "$ac_rk_have_dirfd" = "yes" ; then
1853         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1854 fi
1855 AC_MSG_RESULT($ac_rk_have_dirfd)
1856
1857 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1858 #ifdef HAVE_DIRENT_H
1859 #include <dirent.h>
1860 #endif])
1861
1862 dnl Eventually, this will look for the system one, or for OpenSSL
1863 LIB_hcrypto="-lafshcrypto"
1864 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1865 AC_SUBST(LIB_hcrypto)
1866 AC_SUBST(LDFLAGS_hcrypto)
1867
1868 dnl Check for UUID library
1869 AC_CHECK_HEADERS([uuid/uuid.h])
1870 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1871 AC_CHECK_FUNCS([uuid_generate])
1872 ])
1873
1874
1875 AC_DEFUN([SUMMARY], [
1876     # Print a configuration summary
1877 echo 
1878 echo "**************************************"
1879 echo configure summary
1880 echo
1881 AS_IF([test $LIB_curses],[
1882 echo "LIB_curses :                $LIB_curses" ],[
1883 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1884 ])
1885 echo 
1886 echo "**************************************"
1887 ])