config: Updates to AFS_HAVE_STATVFS for FreeBSD
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([pam],
79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
80     ,
81     [enable_pam="yes"])
82 AC_ARG_ENABLE([gtx],
83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
84 AC_ARG_ENABLE([uss],
85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
86 AC_ARG_ENABLE([namei-fileserver],
87     [AS_HELP_STRING([--enable-namei-fileserver],
88         [force compilation of namei fileserver in preference to inode
89          fileserver])],
90     , 
91     [enable_namei_fileserver="default"])
92 AC_ARG_ENABLE([supergroups],
93     [AS_HELP_STRING([--enable-supergroups],
94         [enable support for nested pts groups])],
95     , 
96     [enable_supergroups="no"])
97 AC_ARG_ENABLE([bitmap-later],
98     [AS_HELP_STRING([--enable-bitmap-later],
99         [enable fast startup of file server by not reading bitmap till
100          needed])],
101     , 
102     [enable_bitmap_later="no"])
103 AC_ARG_ENABLE([unix-sockets],
104     [AS_HELP_STRING([--disable-unix-sockets],
105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
106     ,
107     [enable_unix_sockets="yes"])
108 AC_ARG_ENABLE([tivoli-tsm],
109     [AS_HELP_STRING([--enable-tivoli-tsm],
110         [enable use of the Tivoli TSM API libraries for butc support])],
111     , 
112     [enable_tivoli_tsm="no"])
113 AC_ARG_ENABLE([pthreaded-ubik],
114     [AS_HELP_STRING([--enable-pthreaded-ubik],
115         [enable installation of pthreaded ubik applications (defaults to
116          disabled)])],
117     ,
118     [enable_pthreaded_ubik="no"])
119
120 dnl Kernel module build options.
121 AC_ARG_WITH([linux-kernel-headers],
122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
123         [use the kernel headers found at path (optional, defaults to
124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
126 AC_ARG_WITH([linux-kernel-build],
127     [AS_HELP_STRING([--with-linux-kernel-build=path],
128         [use the kernel build found at path(optional, defaults to 
129         kernel headers path)])])
130 AC_ARG_WITH([bsd-kernel-headers],
131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
132         [use the kernel headers found at path (optional, defaults to
133          /usr/src/sys)])])
134 AC_ARG_WITH([bsd-kernel-build],
135     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
136         [use the kernel build found at path (optional, defaults to
137          KSRC/i386/compile/GENERIC)])])
138 AC_ARG_WITH([linux-kernel-packaging],
139     [AS_HELP_STRING([--with-linux-kernel-packaging],
140         [use standard naming conventions to aid Linux kernel build packaging
141          (disables MPS, sets the kernel module name to openafs.ko, and
142          installs kernel modules into the standard Linux location)])],
143     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
144      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
145     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
146 AC_ARG_ENABLE([kernel-module],
147     [AS_HELP_STRING([--disable-kernel-module],
148         [disable compilation of the kernel module (defaults to enabled)])],
149     , 
150     [enable_kernel_module="yes"])
151 AC_ARG_ENABLE([redhat-buildsys],
152     [AS_HELP_STRING([--enable-redhat-buildsys],
153         [enable compilation of the redhat build system kernel (defaults to
154          disabled)])],
155     ,
156     [enable_redhat_buildsys="no"])
157
158 dnl Installation locations.
159 AC_ARG_ENABLE([transarc-paths],
160     [AS_HELP_STRING([--enable-transarc-paths],
161         [use Transarc style paths like /usr/afs and /usr/vice])],
162     , 
163     [enable_transarc_paths="no"])
164
165 dnl Deprecated crypto
166 AC_ARG_ENABLE([kauth],
167     [AS_HELP_STRING([--enable-kauth],
168         [install the deprecated kauth server and utilities (defaults to
169          disabled)])],
170     ,
171     [enable_kauth="no"])
172
173 dnl Optimization and debugging flags.
174 AC_ARG_ENABLE([strip-binaries],
175     [AS_HELP_STRING([--disable-strip-binaries],
176         [disable stripping of symbol information from binaries (defaults to
177          enabled)])],
178     ,
179     [enable_strip_binaries="maybe"])
180 AC_ARG_ENABLE([debug],
181     [AS_HELP_STRING([--enable-debug],
182         [enable compilation of the user space code with debugging information
183          (defaults to disabled)])],
184     , 
185     [enable_debug="no"])
186 AC_ARG_ENABLE([optimize],
187     [AS_HELP_STRING([--disable-optimize],
188         [disable optimization for compilation of the user space code (defaults
189          to enabled)])],
190     , 
191     [enable_optimize="yes"])
192 AC_ARG_ENABLE([warnings],
193     [AS_HELP_STRING([--enable-warnings],
194         [enable compilation warnings when building with gcc (defaults to
195          disabled)])],
196     ,
197     [enable_warnings="no"])
198 AC_ARG_ENABLE([checking],
199     [AS_HELP_STRING([--enable-checking],
200         [turn compilation warnings into errors when building with gcc (defaults
201          to disabled)])],
202     [enable_checking="$enableval"],
203     [enable_checking="no"])
204 AC_ARG_ENABLE([debug-locks],
205     [AS_HELP_STRING([--enable-debug-locks],
206         [turn on lock debugging assertions (defaults to disabled)])],
207     [enable_debug_locks="$enableval"],
208     [enable_debug_locks="no"])
209 AC_ARG_ENABLE([debug-kernel],
210     [AS_HELP_STRING([--enable-debug-kernel],
211         [enable compilation of the kernel module with debugging information
212          (defaults to disabled)])],
213     ,
214     [enable_debug_kernel="no"])
215 AC_ARG_ENABLE([optimize-kernel],
216     [AS_HELP_STRING([--disable-optimize-kernel],
217         [disable compilation of the kernel module with optimization (defaults
218          based on platform)])],
219     , 
220     [enable_optimize_kernel=""])
221 AC_ARG_ENABLE([debug-lwp],
222     [AS_HELP_STRING([--enable-debug-lwp],
223         [enable compilation of the LWP code with debugging information
224          (defaults to disabled)])],
225     ,
226     [enable_debug_lwp="no"])
227 AC_ARG_ENABLE([optimize-lwp],
228     [AS_HELP_STRING([--disable-optimize-lwp],
229         [disable optimization for compilation of the LWP code (defaults to
230          enabled)])],
231     ,
232     [enable_optimize_lwp="yes"])
233 AC_ARG_ENABLE([debug-pam],
234     [AS_HELP_STRING([--enable-debug-pam],
235         [enable compilation of the PAM code with debugging information
236          (defaults to disabled)])],
237     ,
238     [enable_debug_pam="no"])
239 AC_ARG_ENABLE([optimize-pam],
240     [AS_HELP_STRING([--disable-optimize-pam],
241         [disable optimization for compilation of the PAM code (defaults to
242          enabled)])],
243     ,
244     [enable_optimize_pam="yes"])
245 AC_ARG_ENABLE([linux-syscall-probing],
246     [AS_HELP_STRING([--enable-linux-syscall-probing],
247         [enable Linux syscall probing (defaults to autodetect)])],
248     ,
249     [enable_linux_syscall_probing="maybe"])
250 AC_ARG_WITH([crosstools-dir],
251     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
252     
253 AC_ARG_WITH([xslt-processor],
254         AS_HELP_STRING([--with-xslt-processor=ARG],
255         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
256         [XSLTPROC="$withval"],
257         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
258
259 AC_ARG_WITH([html-xsl], 
260         AS_HELP_STRING([--with-html-xsl],
261         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
262         [HTML_XSL="$withval"],
263         [HTML_XSL="html/chunk.xsl"])
264
265 AC_ARG_WITH([docbook2pdf],
266         AS_HELP_STRING([--with-docbook2pdf=ARG],
267         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
268         [DOCBOOK2PDF="$withval"],
269         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
270
271 AC_ARG_WITH([docbook-stylesheets],
272         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
273         [location of DocBook stylesheets (default is to search a set of likely paths)]),
274         [DOCBOOK_STYLESHEETS="$withval"],
275         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
276         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
277                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
278         fi)
279
280 AC_ARG_WITH([dot],
281         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
282         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
283         [], [with_dot="maybe"])
284
285 enable_login="no"
286
287 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
288 dnl documentation build.
289 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
290 AC_CHECK_PROGS([DOXYGEN], [doxygen])
291
292 dnl Optionally generate graphs with doxygen.
293 case "$with_dot" in
294 maybe)
295     AC_CHECK_PROGS([DOT], [dot])
296     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
297     ;;
298 yes)
299     HAVE_DOT="yes"
300     ;;
301 no)
302     HAVE_DOT="no"
303     ;;
304 *)
305     HAVE_DOT="yes"
306     DOT_PATH=$with_dot
307 esac
308 AC_SUBST(HAVE_DOT)
309 AC_SUBST(DOT_PATH)
310
311 dnl Checks for UNIX variants.
312 AC_ISC_POSIX
313
314 dnl Various compiler setup.
315 AC_TYPE_PID_T
316 AC_TYPE_SIZE_T
317
318 dnl Checks for programs.
319 AC_PROG_INSTALL
320 AC_PROG_LN_S
321 AC_PROG_RANLIB
322 AC_PROG_YACC
323 AM_PROG_LEX
324 dnl if we are flex, be lex-compatible
325 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
326
327 OPENAFS_FORCE_ABS_INSTALL
328 OPENAFS_CHECK_BIGENDIAN
329 OPENAFS_PRINTF_TAKES_Z_LEN
330
331 AC_MSG_CHECKING(your OS)
332 system=$host
333 case $system in
334         *-linux*)
335
336                 MKAFS_OSTYPE=LINUX
337                 if test "x$enable_redhat_buildsys" = "xyes"; then
338                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
339                 fi
340                 if test "x$enable_kernel_module" = "xyes"; then
341                  if test "x$with_linux_kernel_headers" != "x"; then
342                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
343                  else
344                    for utsdir in "/lib/modules/`uname -r`/build" \
345                                  "/lib/modules/`uname -r`/source" \
346                                  "/usr/src/linux-2.4" \
347                                  "/usr/src/linux"; do
348                      LINUX_KERNEL_PATH="$utsdir"
349                      for utsfile in "include/generated/utsrelease.h" \
350                                     "include/linux/utsrelease.h" \
351                                     "include/linux/version.h" \
352                                     "include/linux/version-up.h"; do
353                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
354                          break 2
355                        fi
356                      done
357                    done
358                  fi
359                  if test "x$with_linux_kernel_build" != "x"; then
360                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
361                  else
362                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
363                  fi
364                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
365                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
366                    LINUX_VERSION="$linux_kvers"
367                  else
368                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
369                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
370                      LINUX_VERSION="$linux_kvers"
371                    else
372                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
373                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
374                        if test "x$linux_kvers" = "x"; then
375                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
376                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
377                            if test "x$linux_kvers" = "x"; then
378                              AC_MSG_ERROR(Linux headers lack version definition [2])
379                              exit 1
380                            else
381                              LINUX_VERSION="$linux_kvers"
382                            fi
383                          else
384                            AC_MSG_ERROR(Linux headers lack version definition)
385                            exit 1
386                          fi
387                        else
388                          LINUX_VERSION="$linux_kvers"
389                        fi
390                      else
391                        enable_kernel_module="no"
392                      fi
393                    fi
394                  fi
395                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
396                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
397                      enable_kernel_module="no"
398                  fi
399                  if test "x$enable_kernel_module" = "xno"; then
400                   if test "x$with_linux_kernel_headers" != "x"; then
401                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
402                    exit 1
403                   else
404                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
405                   fi
406                  fi
407                  dnl do we need to determine SUBARCH from autoconf.h
408                  SUBARCH=default
409                 fi
410                 AC_MSG_RESULT(linux)
411                 if test "x$enable_kernel_module" = "xyes"; then
412                  case "$LINUX_VERSION" in
413                   2.2.*) AFS_SYSKVERS=22 ;;
414                   2.4.*) AFS_SYSKVERS=24 ;;
415                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
416                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
417                  esac
418                 fi
419                 ;;
420         *-solaris*)
421                 MKAFS_OSTYPE=SOLARIS
422                 AC_MSG_RESULT(sun4)
423                 AC_PATH_PROG(SOLARISCC, [cc], ,
424                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
425                 if test "x$SOLARISCC" = "x" ; then
426                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
427                 fi
428                 SOLARIS_UFSVFS_HAS_DQRWLOCK
429                 SOLARIS_FS_HAS_FS_ROLLED
430                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
431                 SOLARIS_HAVE_VN_RENAMEPATH
432                 ;;
433         *-sunos*)
434                 MKAFS_OSTYPE=SUNOS
435                 enable_kernel_module=no
436                 AC_MSG_RESULT(sun4)
437                 ;;
438         *-hpux*)
439                 MKAFS_OSTYPE=HPUX
440                 AC_MSG_RESULT(hp_ux)
441                 if test -f "/usr/old/usr/include/ndir.h"; then
442                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
443                 fi
444                 ;;
445         *-irix*)
446                 if test -d /usr/include/sys/SN/SN1; then
447                  IRIX_BUILD_IP35="IP35"
448                 fi
449                 MKAFS_OSTYPE=IRIX
450                 AC_MSG_RESULT(sgi)
451                 ;;
452         *-aix*)
453                 MKAFS_OSTYPE=AIX
454                 AC_MSG_RESULT(rs_aix)
455                 ;;
456         arm-*-darwin*)
457                 MKAFS_OSTYPE=DARWIN
458                 AC_MSG_RESULT(arm_darwin)
459                 ;;
460         powerpc-*-darwin*)
461                 MKAFS_OSTYPE=DARWIN
462                 AC_MSG_RESULT(ppc_darwin)
463                 ;;
464         i386-*-darwin*)
465                 MKAFS_OSTYPE=DARWIN
466                 AC_MSG_RESULT(x86_darwin)
467                 ;;
468         x86_64-*-darwin*)
469                 MKAFS_OSTYPE=DARWIN
470                 AC_MSG_RESULT(x86_darwin)
471                 ;;
472         i386-*-freebsd*)
473                 MKAFS_OSTYPE=FBSD
474                 AC_MSG_RESULT(i386_fbsd)
475                 ;;
476         x86_64-*-freebsd*)
477                 MKAFS_OSTYPE=FBSD
478                 AC_MSG_RESULT(amd64_fbsd)
479                 ;;
480         *-netbsd*)
481                 MKAFS_OSTYPE=NBSD
482                 AC_MSG_RESULT(nbsd)
483                 ;;
484         x86_64-*-openbsd*)
485                 MKAFS_OSTYPE=OBSD
486                 AC_MSG_RESULT(amd64_obsd)
487                 ;;
488         i386-*-openbsd*)
489                 MKAFS_OSTYPE=OBSD
490                 AC_MSG_RESULT(i386_obsd)
491                 ;;
492         *-dragonfly*)
493                 MKAFS_OSTYPE=DFBSD
494                 AC_MSG_RESULT(i386_dfbsd)
495                 ;;
496         *)
497                 AC_MSG_RESULT($system)
498                 ;;
499 esac
500
501 if test "x$with_afs_sysname" != "x"; then
502         AFS_SYSNAME="$with_afs_sysname"
503 else
504         AC_MSG_CHECKING(your AFS sysname)
505         case $host in
506                 i?86-*-openbsd?.?)
507                         v=${host#*openbsd}
508                         vM=${v%.*}
509                         vm=${v#*.}
510                         AFS_SYSNAME="i386_obsd${vM}${vm}"
511                         ;;
512                 sparc64-*-openbsd?.?)
513                         v=${host#*openbsd}
514                         vM=${v%.*}
515                         vm=${v#*.}
516                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
517                         ;;
518                 x86_64-*-openbsd?.?)
519                         v=${host#*openbsd}
520                         vM=${v%.*}
521                         vm=${v#*.}
522                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
523                         ;;
524                 i?86-*-freebsd*.*)
525                         v=${host#*freebsd}
526                         vM=${v%.*}
527                         vm=${v#*.}
528                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
529                         ;;
530                 x86_64-*-freebsd*.*)
531                         v=${host#*freebsd}
532                         vM=${v%.*}
533                         vm=${v#*.}
534                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
535                         ;;
536                 i386-*-dragonfly?.*)
537                         v=${host#*dragonfly}
538                         vM=${v%.*}
539                         vm=${v#*.}
540                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
541                         ;;
542                 i?86-*-netbsd*1.6[[M-Z]]*)
543                         AFS_SYSNAME="i386_nbsd20"
544                         ;;
545                 powerpc-*-netbsd*1.6[[M-Z]]*)
546                         AFS_SYSNAME="ppc_nbsd20"
547                         ;;
548                 *-*-netbsd*)
549                         arch=${host%%-unknown*}
550                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
551                                                -e 's/powerpc/ppc/g')
552                         v=${host#*netbsd}
553                         v=${v#*aout}
554                         v=${v#*ecoff}
555                         v=${v#*elf}
556                         vM=${v%%.*}
557                         vM=${vM%.*}
558                         v=${v#*.}
559                         vm=${v%%.*}
560                         vm=${vm%.*}
561                         vm=${vm%%[[_A-Z]]*}
562                         if test $vm -eq 99 ; then
563                                 vM=$((vM+1))
564                         fi
565                         if test $vM -gt 1 ; then
566                                 vm=0
567                         fi
568                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
569                         ;;
570                 hppa*-hp-hpux11.0*)
571                         AFS_SYSNAME="hp_ux110"
572                         ;;
573                 hppa*-hp-hpux11.11)
574                         AFS_SYSNAME="hp_ux11i"
575                         ;;
576                 hppa*-hp-hpux11.23)
577                         AFS_SYSNAME="hp_ux1123"
578                         ;;
579                 ia64-hp-hpux11.22)
580                         AFS_SYSNAME="ia64_hpux1122"
581                         ;;
582                 ia64-hp-hpux*)
583                         AFS_SYSNAME="ia64_hpux1123"
584                         ;;
585                 hppa*-hp-hpux10*)
586                         AFS_SYSNAME="hp_ux102"
587                         ;;
588                 powerpc-apple-darwin7*)
589                         AFS_SYSNAME="ppc_darwin_70"
590                         OSXSDK="macosx10.3"
591                         ;;
592                 powerpc-apple-darwin8.*)
593                         AFS_SYSNAME="ppc_darwin_80"
594                         OSXSDK="macosx10.4"
595                         ;;
596                 i386-apple-darwin8.*)
597                         AFS_SYSNAME="x86_darwin_80"
598                         OSXSDK="macosx10.4"
599                         ;;
600                 powerpc-apple-darwin9.*)
601                         AFS_SYSNAME="ppc_darwin_90"
602                         OSXSDK="macosx10.5"
603                         ;;
604                 i386-apple-darwin9.*)
605                         AFS_SYSNAME="x86_darwin_90"
606                         OSXSDK="macosx10.5"
607                         ;;
608                 i?86-apple-darwin10.*)
609                         AFS_SYSNAME="x86_darwin_100"
610                         OSXSDK="macosx10.6"
611                         ;;
612                 x86_64-apple-darwin10.*)
613                         AFS_SYSNAME="x86_darwin_100"
614                         OSXSDK="macosx10.6"
615                         ;;
616                 arm-apple-darwin10.*)
617                         AFS_SYSNAME="arm_darwin_100"
618                         OSXSDK="iphoneos4.0"
619                         ;;
620                 x86_64-apple-darwin11.*)
621                         AFS_SYSNAME="x86_darwin_110"
622                         OSXSDK="macosx10.7"
623                         ;;
624                 i?86-apple-darwin11.*)
625                         AFS_SYSNAME="x86_darwin_110"
626                         OSXSDK="macosx10.7"
627                         ;;
628                 x86_64-apple-darwin12.*)
629                         AFS_SYSNAME="x86_darwin_120"
630                         OSXSDK="macosx10.8"
631                         ;;
632                 i?86-apple-darwin12.*)
633                         AFS_SYSNAME="x86_darwin_120"
634                         OSXSDK="macosx10.8"
635                         ;;
636                 x86_64-apple-darwin13.*)
637                         AFS_SYSNAME="x86_darwin_130"
638                         OSXSDK="macosx10.9"
639                         ;;
640                 i?86-apple-darwin13.*)
641                         AFS_SYSNAME="x86_darwin_130"
642                         OSXSDK="macosx10.9"
643                         ;;
644                 sparc-sun-solaris2.8)
645                         AFS_SYSNAME="sun4x_58"
646                         ;;
647                 sparc-sun-solaris2.9)
648                         AFS_SYSNAME="sun4x_59"
649                         ;;
650                 sparc-sun-solaris2.10)
651                         AFS_SYSNAME="sun4x_510"
652                         ;;
653                 sparc-sun-solaris2.11)
654                         AFS_SYSNAME="sun4x_511"
655                         ;;
656                 i386-pc-solaris2.8)
657                         AFS_SYSNAME="sunx86_58"
658                         ;;
659                 i386-pc-solaris2.9)
660                         AFS_SYSNAME="sunx86_59"
661                         ;;
662                 i386-pc-solaris2.10)
663                         AFS_SYSNAME="sunx86_510"
664                         ;;
665                 i386-pc-solaris2.11)
666                         AFS_SYSNAME="sunx86_511"
667                         ;;
668                 alpha*-dec-osf4.0*)
669                         AFS_SYSNAME="alpha_dux40"
670                         ;;
671                 alpha*-dec-osf5.0*)
672                         AFS_SYSNAME="alpha_dux50"
673                         ;;
674                 alpha*-dec-osf5.1*)
675                         AFS_SYSNAME="alpha_dux51"
676                         ;;
677                 mips-sgi-irix6.5)
678                         AFS_SYSNAME="sgi_65"
679                         ;;
680                 ia64-*-linux*)
681                         AFS_SYSNAME="ia64_linuxXX"
682                         ;;
683                 powerpc-*-linux*)
684                         AFS_SYSNAME="`/bin/arch`_linuxXX"
685                         ;;
686                 powerpc64-*-linux*)
687                         AFS_SYSNAME="ppc64_linuxXX"
688                         ;;
689                 alpha*-linux*)
690                         AFS_SYSNAME="alpha_linux_XX"
691                         ;;
692                 s390-*-linux*)
693                         AFS_SYSNAME="s390_linuxXX"
694                         ;;
695                 s390x-*-linux*)
696                         AFS_SYSNAME="s390x_linuxXX"
697                         ;;
698                 sparc-*-linux*)
699                         AFS_SYSNAME="`/bin/arch`_linuxXX"
700                         ;;
701                 sparc64-*-linux*)
702                         AFS_SYSNAME="sparc64_linuxXX"
703                         ;;
704                 i?86-*-linux*)
705                         AFS_SYSNAME="i386_linuxXX"
706                         ;;
707                 arm*-linux*)
708                         AFS_SYSNAME="arm_linuxXX"
709                         ;;
710                 parisc-*-linux-gnu|hppa-*-linux-gnu)
711                         AFS_SYSNAME="parisc_linuxXX"
712                         enable_pam="no"
713                         ;;
714                 power*-ibm-aix4.2*)
715                         AFS_SYSNAME="rs_aix42"
716                         enable_pam="no"
717                         ;;
718                 power*-ibm-aix4.3*)
719                         AFS_SYSNAME="rs_aix42"
720                         enable_pam="no"
721                         ;;
722                 power*-ibm-aix5.1*)
723                         AFS_SYSNAME="rs_aix51"
724                         enable_pam="no"
725                         ;;
726                 power*-ibm-aix5.2*)
727                         AFS_SYSNAME="rs_aix52"
728                         enable_pam="no"
729                         ;;
730                 power*-ibm-aix5.3*)
731                         AFS_SYSNAME="rs_aix53"
732                         enable_pam="no"
733                         ;;
734                 power*-ibm-aix6.1*)
735                         AFS_SYSNAME="rs_aix61"
736                         enable_pam="no"
737                         ;;
738                 x86_64-*-linux-gnu)
739                         AFS_SYSNAME="amd64_linuxXX"
740                         enable_pam="yes"
741                         ;;
742                 *)
743                         AC_MSG_ERROR(An AFS sysname is required)
744                         exit 1
745                         ;;
746         esac
747         case $AFS_SYSNAME in
748                 *_linux* | *_umlinux*)
749                         if test "x${AFS_SYSKVERS}" = "x"; then
750                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
751                         fi
752                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
753                         AFS_SYSNAME="$_AFS_SYSNAME"
754                         AC_TRY_KBUILD(
755                          [],
756                          [#ifndef CONFIG_USERMODE
757                           #error not UML
758                           #endif],
759                          ac_cv_linux_is_uml=yes,)
760                         if test "${ac_cv_linux_is_uml}" = yes; then
761                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
762                         fi
763                         AFS_SYSNAME="$_AFS_SYSNAME"
764                         ;;
765         esac
766         AC_MSG_RESULT($AFS_SYSNAME)
767 fi
768
769 case $AFS_SYSNAME in
770         *_darwin*)
771                 AC_CHECK_HEADERS(crt_externs.h)
772                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
773                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
774                 AC_SUBST(OSXSDK)
775                 ;;
776 esac
777
778 dnl Some hosts have a separate common param file they should include.  Figure
779 dnl out if we're on one of them now that we know the sysname.
780 case $AFS_SYSNAME in
781     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
782     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
783     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
784     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
785     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
786     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
787     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
788     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
789     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
790     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
791     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
792     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
793     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
794     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
795     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
796     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
797     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
798     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
799     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
800     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
801     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
802     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
803     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
804     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
805     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
806     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
807     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
808     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
809     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
810     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
811     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
812     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
813     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
814     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
815     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
816     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
817 # Linux alpha adds an extra underscore for no good reason.
818     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
819     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
820     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
821 esac
822
823 OPENAFS_OSCONF
824
825 case $AFS_SYSNAME in *_linux* | *_umlinux*)
826
827                 # Add (sub-) architecture-specific paths needed by conftests
828                 case $AFS_SYSNAME  in
829                         *_umlinux26)
830                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
831                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
832                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
833                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
834                 esac
835
836                 if test "x$enable_kernel_module" = "xyes"; then
837                  if test "x$enable_debug_kernel" = "xno"; then
838                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
839                  fi
840                  OPENAFS_GCC_SUPPORTS_MARCH
841                  AC_SUBST(P5PLUS_KOPTS)
842                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
843                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
844                  OPENAFS_GCC_SUPPORTS_NO_COMMON
845                  OPENAFS_GCC_SUPPORTS_PIPE
846                  AC_SUBST(LINUX_GCC_KOPTS)
847
848                  dnl Setup the kernel build environment
849                  LINUX_KBUILD_USES_EXTRA_CFLAGS
850                  LINUX_KERNEL_COMPILE_WORKS
851
852                  dnl Check for header files
853                  AC_CHECK_LINUX_HEADER([config.h])
854                  AC_CHECK_LINUX_HEADER([completion.h])
855                  AC_CHECK_LINUX_HEADER([exportfs.h])
856                  AC_CHECK_LINUX_HEADER([freezer.h])
857                  AC_CHECK_LINUX_HEADER([key-type.h])
858                  AC_CHECK_LINUX_HEADER([semaphore.h])
859                  AC_CHECK_LINUX_HEADER([seq_file.h])
860
861                  dnl Type existence checks
862                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
863                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
864
865                  dnl Check for structure elements
866                  AC_CHECK_LINUX_STRUCT([address_space_operations],
867                                        [write_begin], [fs.h])
868                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
869                                        [backing-dev.h])
870                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
871                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
872                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
873                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
874                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
875                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
876                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
877                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
878                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
879                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
880                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
881                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
882                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
883                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
884                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
885                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
886                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
887                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
888                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
889                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
890                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
891                                        [fs.h])
892                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
893                                        [fs.h])
894                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
895                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
896                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
897                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
898                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
899                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
900                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
901                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
902                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
903                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
904                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
905
906                  dnl Check for typed structure elements
907                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
908                                              [buf], [fs.h])
909
910                  dnl Function existence checks
911
912                  AC_CHECK_LINUX_FUNC([bdi_init],
913                                      [#include <linux/backing-dev.h>],
914                                      [bdi_init(NULL);])
915                  AC_CHECK_LINUX_FUNC([PageChecked],
916                                      [#include <linux/mm.h>
917 #include <linux/page-flags.h>],
918                                      [struct page *_page;
919                                       int bchecked = PageChecked(_page);])
920                  AC_CHECK_LINUX_FUNC([PageFsMisc],
921                                      [#include <linux/mm.h>
922 #include <linux/page-flags.h>],
923                                      [struct page *_page;
924                                       int bchecked = PageFsMisc(_page);])
925                  AC_CHECK_LINUX_FUNC([clear_inode],
926                                      [#include <linux/fs.h>],
927                                      [clear_inode(NULL);])
928                  AC_CHECK_LINUX_FUNC([current_kernel_time],
929                                      [#include <linux/time.h>],
930                                      [struct timespec s;
931                                       s = current_kernel_time();])
932                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
933                                      [#include <linux/fs.h>],
934                                      [d_alloc_anon(NULL);])
935                  AC_CHECK_LINUX_FUNC([d_count],
936                                      [#include <linux/dcache.h>],
937                                      [d_count(NULL);])
938                  AC_CHECK_LINUX_FUNC([d_make_root],
939                                      [#include <linux/fs.h>],
940                                      [d_make_root(NULL);])
941                  AC_CHECK_LINUX_FUNC([do_sync_read],
942                                      [#include <linux/fs.h>],
943                                      [do_sync_read(NULL, NULL, 0, NULL);])
944                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
945                                      [#include <linux/sched.h>],
946                                      [pid_t p; find_task_by_pid(p);])
947                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
948                                      [#include <linux/fs.h>],
949                                      [generic_file_aio_read(NULL,NULL,0,0);])
950                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
951                                      [#include <linux/pagemap.h>],
952                                      [grab_cache_page_write_begin(NULL, 0, 0);])
953                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
954                                      [#include <linux/list.h>],
955                                      [hlist_unhashed(0);])
956                  AC_CHECK_LINUX_FUNC([i_size_read],
957                                      [#include <linux/fs.h>],
958                                      [i_size_read(NULL);])
959                  AC_CHECK_LINUX_FUNC([inode_setattr],
960                                      [#include <linux/fs.h>],
961                                      [inode_setattr(NULL, NULL);])
962                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
963                                      [#include <linux/fs.h>],
964                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
965                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
966                                      [#include <linux/net.h>],
967                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
968                  AC_CHECK_LINUX_FUNC([page_follow_link],
969                                      [#include <linux/fs.h>],
970                                      [page_follow_link(0,0);])
971                  AC_CHECK_LINUX_FUNC([page_offset],
972                                      [#include <linux/pagemap.h>],
973                                      [page_offset(NULL);])
974                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
975                                      [#include <linux/pagevec.h>],
976                                      [__pagevec_lru_add_file(NULL);])
977                  AC_CHECK_LINUX_FUNC([path_lookup],
978                                      [#include <linux/fs.h>
979                                       #include <linux/namei.h>],
980                                      [path_lookup(NULL, 0, NULL);])
981                  AC_CHECK_LINUX_FUNC([proc_create],
982                                      [#include <linux/proc_fs.h>],
983                                      [proc_create(NULL, 0, NULL, NULL);])
984                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
985                                      [#include <linux/rcupdate.h>],
986                                      [rcu_read_lock();])
987                  AC_CHECK_LINUX_FUNC([set_nlink],
988                                      [#include <linux/fs.h>],
989                                      [set_nlink(NULL, 1);])
990                  AC_CHECK_LINUX_FUNC([sock_create_kern],
991                                      [#include <linux/net.h>],
992                                      [sock_create_kern(0, 0, 0, NULL);])
993                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
994                                      [#include <linux/splice.h>],
995                                      [splice_direct_to_actor(NULL,NULL,NULL);])
996                  AC_CHECK_LINUX_FUNC([svc_addr_in],
997                                      [#include <linux/sunrpc/svc.h>],
998                                      [svc_addr_in(NULL);])
999                  AC_CHECK_LINUX_FUNC([zero_user_segments],
1000                                      [#include <linux/highmem.h>],
1001                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1002                  AC_CHECK_LINUX_FUNC([noop_fsync],
1003                                      [#include <linux/fs.h>],
1004                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1005                  AC_CHECK_LINUX_FUNC([kthread_run],
1006                                      [#include <linux/kernel.h>
1007                                       #include <linux/kthread.h>],
1008                                      [kthread_run(NULL, NULL, "test");])
1009
1010                  dnl Consequences - things which get set as a result of the
1011                  dnl                above tests
1012                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1013                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1014                                   [define to disable the nfs translator])])
1015
1016                  dnl Assorted more complex tests
1017                  LINUX_AIO_NONVECTOR
1018                  LINUX_EXPORTS_PROC_ROOT_FS
1019                  LINUX_KMEM_CACHE_INIT
1020                  LINUX_HAVE_KMEM_CACHE_T
1021                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1022                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1023                  LINUX_D_PATH_TAKES_STRUCT_PATH
1024                  LINUX_NEW_EXPORT_OPS
1025                  LINUX_INODE_SETATTR_RETURN_TYPE
1026                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1027                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1028                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1029                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1030                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1031                  LINUX_DOP_D_DELETE_TAKES_CONST
1032                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1033                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1034                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1035                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1036                  LINUX_AOP_WRITEBACK_CONTROL
1037                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1038                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1039                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1040                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1041                  LINUX_KERNEL_SOCK_CREATE
1042                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1043                  LINUX_NEED_RHCONFIG
1044                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1045                  LINUX_EXPORTS_TASKLIST_LOCK
1046                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1047                  LINUX_STATFS_TAKES_DENTRY
1048                  LINUX_REFRIGERATOR
1049                  LINUX_HAVE_TRY_TO_FREEZE
1050                  LINUX_LINUX_KEYRING_SUPPORT
1051                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1052                  LINUX_KEY_ALLOC_NEEDS_CRED
1053                  LINUX_INIT_WORK_HAS_DATA
1054                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1055                  LINUX_HAVE_DCACHE_LOCK
1056                  LINUX_D_COUNT_IS_INT
1057                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1058                  LINUX_IOP_CREATE_TAKES_UMODE_T
1059                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1060                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1061                  LINUX_DENTRY_OPEN_TAKES_PATH
1062                  LINUX_D_ALIAS_IS_HLIST
1063                  LINUX_HLIST_ITERATOR_NO_NODE
1064                  LINUX_IOP_I_CREATE_TAKES_BOOL
1065                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1066                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1067
1068                  dnl If we are guaranteed that keyrings will work - that is
1069                  dnl  a) The kernel has keyrings enabled
1070                  dnl  b) The code is new enough to give us a key_type_keyring
1071                  dnl then we just disable syscall probing unless we've been
1072                  dnl told otherwise
1073
1074                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1075                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1076                           [enable_linux_syscall_probing="no"],
1077                           [enable_linux_syscall_probing="yes"])
1078                  ])
1079
1080                  dnl Syscall probing needs a few tests of its own, and just
1081                  dnl won't work if the kernel doesn't export init_mm
1082                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1083                    LINUX_EXPORTS_INIT_MM
1084                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1085                      AC_MSG_ERROR(
1086                        [Can't do syscall probing without exported init_mm])
1087                    ])
1088                    LINUX_EXPORTS_SYS_CHDIR
1089                    LINUX_EXPORTS_SYS_OPEN
1090                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1091                              [define to enable syscall table probes])
1092                  ])
1093
1094                  dnl Packaging and SMP build
1095                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1096                    LINUX_WHICH_MODULES
1097                  else
1098                    AC_SUBST(MPS,'SP')
1099                  fi
1100
1101                  dnl Syscall probing
1102                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1103                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1104                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1105                    ])
1106                    ac_cv_linux_exports_sys_call_table=no
1107                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1108                      ac_cv_linux_exports_ia32_sys_call_table=yes
1109                    fi
1110                  else
1111                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1112                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1113                    LINUX_EXPORTS_SYS_CALL_TABLE
1114                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1115                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1116                          linux_syscall_method=none
1117                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1118                             linux_syscall_method=scan
1119                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1120                                linux_syscall_method=scan_with_kallsyms_address
1121                             fi
1122                          fi
1123                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1124                             linux_syscall_method=kallsyms_symbol
1125                          fi
1126                          if test "x$linux_syscall_method" = "xnone"; then
1127                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1128                             linux_syscall_method=scan
1129                          fi
1130                    fi
1131                  fi
1132                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1133                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1134                  fi
1135                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1136                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1137                  fi
1138                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1139                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1140                  else
1141                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1142                  fi
1143                 :
1144                 fi
1145 dnl Linux-only, but just enable always.
1146                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1147 esac
1148
1149 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1150     [ac_cv_sync_fetch_and_add],
1151     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1152                     [ac_cv_sync_fetch_and_add=yes],
1153                     [ac_cv_sync_fetch_and_add=no])
1154 ])
1155 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1156       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1157                 [define if your C compiler has __sync_add_and_fetch])])
1158
1159 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1160     [ac_cv_sockaddr_len],
1161     [AC_TRY_COMPILE( [#include <sys/types.h>
1162 #include <sys/socket.h>],
1163                      [struct sockaddr *a; a->sa_len=0;],
1164                      [ac_cv_sockaddr_len=yes],
1165                      [ac_cv_sockaddr_len=no])
1166 ])
1167 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1168       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1169                  [define if you struct sockaddr sa_len])])
1170
1171 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1172         echo Skipping library tests because they confuse Irix.
1173 else
1174   AC_SEARCH_LIBS([socket], [socket inet])
1175   AC_SEARCH_LIBS([connect], [nsl])
1176   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1177
1178   dnl darwin wants it, aix hates it
1179   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1180   AC_TRY_COMPILE([
1181   #include <stdlib.h>
1182   #include <stdio.h>
1183   #include <sys/types.h>
1184   #include <sys/socket.h>
1185   #include <netinet/in.h>
1186   #include <arpa/inet.h>
1187   #include <arpa/nameser.h>
1188   #include <arpa/nameser_compat.h>
1189   #include <resolv.h>
1190   ], [static int i; i = 0;],
1191   [AC_MSG_RESULT(yes)
1192    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1193   [AC_MSG_RESULT(no)
1194    ])
1195
1196   openafs_save_libs="$LIBS"
1197   AC_MSG_CHECKING([for res_search])
1198   AC_FUNC_RES_SEARCH
1199
1200   if test "$ac_cv_func_res_search" = no; then
1201       for lib in dns nsl resolv; do
1202         if test "$ac_cv_func_res_search" != yes; then
1203           LIBS="-l$lib $LIBS"
1204           AC_FUNC_RES_SEARCH
1205           LIBS="$openafs_save_libs"
1206         fi
1207       done    
1208       if test "$ac_cv_func_res_search" = yes; then
1209         LIB_AFSDB="-l$lib"
1210         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1211         AC_MSG_RESULT([yes, in lib$lib])
1212       else
1213         AC_MSG_RESULT(no)
1214       fi
1215   else
1216     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1217     AC_MSG_RESULT(yes)
1218   fi
1219   
1220 fi
1221 XLIBS="$LIB_AFSDB $XLIBS"
1222
1223 AC_CHECK_RESOLV_RETRANS
1224
1225 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1226     [ac_cv_setsockopt_iprecverr],
1227     [AC_TRY_COMPILE( [
1228 #include <sys/types.h>
1229 #include <sys/socket.h>
1230 #include <netinet/in.h>],
1231 [int on=1;
1232 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1233         [ac_cv_setsockopt_iprecverr=yes],
1234         [ac_cv_setsockopt_iprecverr=no])])
1235
1236 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1237       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1238                  [define if we can receive socket errors via IP_RECVERR])])
1239
1240 PTHREAD_LIBS=error
1241 if test "x$MKAFS_OSTYPE" = OBSD; then
1242         PTHREAD_LIBS="-pthread"
1243 fi
1244 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1245         PTHREAD_LIBS="-pthread"
1246 fi
1247 if test "x$PTHREAD_LIBS" = xerror; then
1248         AC_CHECK_LIB(pthread, pthread_attr_init,
1249                 PTHREAD_LIBS="-lpthread")
1250 fi
1251 if test "x$PTHREAD_LIBS" = xerror; then
1252         AC_CHECK_LIB(pthreads, pthread_attr_init,
1253                 PTHREAD_LIBS="-lpthreads")
1254 fi
1255 if test "x$PTHREAD_LIBS" = xerror; then
1256         AC_CHECK_LIB(c_r, pthread_attr_init,
1257                 PTHREAD_LIBS="-lc_r")
1258 fi
1259 if test "x$PTHREAD_LIBS" = xerror; then
1260         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1261 fi
1262 if test "x$PTHREAD_LIBS" = xerror; then
1263         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1264         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1265                 PTHREAD_LIBS="-lpthread")
1266 fi
1267 if test "x$PTHREAD_LIBS" = xerror; then
1268         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1269 fi
1270 AC_SUBST(PTHREAD_LIBS)
1271
1272 HOST_CPU="$host_cpu"
1273
1274 if test "x$with_bsd_kernel_headers" != "x"; then
1275         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1276 else
1277         BSD_KERNEL_PATH="/usr/src/sys"
1278 fi
1279
1280 if test "x$with_bsd_kernel_build" != "x"; then
1281         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1282 else
1283         case $AFS_SYSNAME in
1284                 *_fbsd_*)
1285                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1286                         ;;
1287                 *_nbsd*)
1288                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1289         esac
1290 fi
1291
1292 # Fast restart
1293 if test "$enable_supergroups" = "yes"; then
1294         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1295 fi
1296
1297 if test "$enable_bitmap_later" = "yes"; then
1298         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1299 fi
1300
1301 if test "$enable_unix_sockets" = "yes"; then
1302         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1303         USE_UNIX_SOCKETS="yes"
1304 else
1305         USE_UNIX_SOCKETS="no"
1306 fi
1307 AC_SUBST(USE_UNIX_SOCKETS)
1308
1309 if test "$enable_namei_fileserver" = "yes"; then
1310         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1311         VFSCK=""
1312 else
1313         if test "$enable_namei_fileserver" = "default"; then
1314                 case $host in
1315                         *-solaris2.10*)
1316                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1317                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1318                                 VFSCK=""
1319                                 ;;
1320                         *-solaris2.11*)
1321                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1322                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1323                                 VFSCK=""
1324                                 ;;
1325                         *)
1326                                 VFSCK="vfsck"
1327                                 ;;
1328                 esac
1329         else
1330                 VFSCK="vfsck"
1331         fi
1332 fi
1333
1334 dnl check for tivoli
1335 AC_MSG_CHECKING(for tivoli tsm butc support)
1336 XBSA_CFLAGS=""
1337 if test "$enable_tivoli_tsm" = "yes"; then
1338         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1339         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1340         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1341         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1342
1343         if test -r "$XBSADIR3/dsmapifp.h"; then
1344                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1345                 XBSA_XLIBS="-ldl"
1346                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1347         elif test -r "$XBSADIR4/dsmapifp.h"; then
1348                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1349                 XBSA_XLIBS="-ldl"
1350                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1351         elif test -r "$XBSADIR1/xbsa.h"; then
1352                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1353                 XBSA_XLIBS=""
1354                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1355         elif test -r "$XBSADIR2/xbsa.h"; then
1356                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1357                 XBSA_XLIBS=""
1358                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1359         else
1360                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1361         fi
1362 else
1363         AC_MSG_RESULT([no])
1364 fi
1365 AC_SUBST(XBSA_CFLAGS)
1366 AC_SUBST(XBSA_XLIBS) 
1367
1368 dnl checks for header files.
1369 AC_HEADER_STDC
1370 AC_HEADER_SYS_WAIT
1371 AC_HEADER_DIRENT
1372 AC_CHECK_HEADERS([ \
1373                    arpa/inet.h \
1374                    arpa/nameser.h \
1375                    curses.h\
1376                    direct.h \
1377                    errno.h \
1378                    fcntl.h \
1379                    grp.h \
1380                    math.h \
1381                    mntent.h \
1382                    ncurses.h \
1383                    ncurses/ncurses.h \
1384                    netdb.h \
1385                    netinet/in.h \
1386                    pthread_np.h \
1387                    pwd.h \
1388                    regex.h \
1389                    security/pam_appl.h \
1390                    signal.h \
1391                    stdint.h \
1392                    stdio_ext.h \
1393                    stdlib.h \
1394                    string.h \
1395                    strings.h \
1396                    sys/bitypes.h \
1397                    sys/bswap.h \
1398                    sys/dk.h \
1399                    sys/fcntl.h \
1400                    sys/file.h \
1401                    sys/fs_types.h \
1402                    sys/fstyp.h \
1403                    sys/ioctl.h \
1404                    sys/ipc.h \
1405                    sys/lockf.h \
1406                    sys/map.h \
1407                    sys/mount.h \
1408                    sys/mntent.h \
1409                    sys/mnttab.h \
1410                    sys/pag.h \
1411                    sys/param.h \
1412                    sys/resource.h \
1413                    sys/select.h \
1414                    sys/statfs.h \
1415                    sys/statvfs.h \
1416                    sys/socket.h \
1417                    sys/sysctl.h \
1418                    sys/time.h \
1419                    sys/types.h \
1420                    sys/uio.h \
1421                    sys/un.h \
1422                    sys/vfs.h \
1423                    syslog.h \
1424                    termios.h \
1425                    time.h \
1426                    ucontext.h \
1427                    unistd.h \
1428                    windows.h \
1429                 ])
1430
1431 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1432 #ifdef HAVE_NETINET_IN_H
1433 # include <netinet/in.h>
1434 #endif])
1435
1436 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1437 #ifdef HAVE_SYS_SOCKET_H
1438 # include <sys/socket.h>
1439 #endif])
1440
1441 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1442 #ifdef HAVE_SYS_SOCKET_H
1443 # include <sys/socket.h>
1444 #endif
1445 #ifdef HAVE_NETINET_IN_H
1446 # include <netinet/in.h>
1447 #endif
1448 #ifdef HAVE_NET_IF_H
1449 # include <net/if.h>
1450 #endif])
1451
1452 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1453 #ifdef HAVE_SECURITY_PAM_APPL_H
1454 # include <security/pam_appl.h>
1455 #endif])
1456
1457 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1458
1459 AC_CHECK_TYPES([fsblkcnt_t],,,[
1460 #include <sys/types.h>
1461 #ifdef HAVE_SYS_BITYPES_H
1462 #include <sys/bitypes.h>
1463 #endif
1464 #ifdef HAVE_SYS_STATFS_H
1465 #include <sys/statfs.h>
1466 #endif
1467 #ifdef HAVE_SYS_STATVFS_H
1468 #include <sys/statvfs.h>
1469 #endif
1470 ])
1471
1472 dnl see what struct stat has for timestamps
1473 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1474
1475 dnl check for curses-lib
1476 AS_IF([test "x$enable_gtx" != "xno"],
1477       [save_LIBS=$LIBS
1478       AC_CHECK_LIB( [ncurses], [setupterm],
1479       [LIB_curses=-lncurses],
1480         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1481           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1482       ])
1483       LIBS=$save_LIBS
1484       AC_SUBST(LIB_curses)])
1485         
1486 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1487
1488 if test "$enable_debug_locks" = yes; then
1489         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1490 fi
1491
1492 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1493 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1494         case $AFS_SYSNAME in
1495         sgi_*)
1496                 HAVE_PAM="no"
1497                 ;;
1498         *)
1499                 HAVE_PAM="yes"
1500                 ;;
1501         esac
1502 else
1503         HAVE_PAM="no"
1504 fi
1505 AC_SUBST(HAVE_PAM)
1506
1507 if test "$enable_login" = yes; then
1508         BUILD_LOGIN="yes"
1509 else
1510         BUILD_LOGIN="no"
1511 fi
1512 AC_SUBST(BUILD_LOGIN)
1513
1514 if test "$enable_uss" = yes; then
1515         BUILD_USS="yes"
1516 else
1517         BUILD_USS="no"
1518 fi
1519 AC_SUBST(BUILD_USS)
1520
1521 if test "$enable_kauth" = yes; then
1522         INSTALL_KAUTH="yes"
1523 else
1524         INSTALL_KAUTH="no"
1525 fi
1526 AC_SUBST(INSTALL_KAUTH)
1527
1528 AC_CHECK_FUNCS([ \
1529         arc4random \
1530         fcntl \
1531         fseeko64 \
1532         ftello64 \
1533         getcwd \
1534         getegid \
1535         geteuid \
1536         getgid \
1537         getuid \
1538         getrlimit \
1539         issetugid \
1540         mkstemp \
1541         poll \
1542         pread \
1543         preadv \
1544         preadv64 \
1545         pwrite \
1546         pwritev \
1547         pwritev64 \
1548         regcomp \
1549         regerror \
1550         regexec \
1551         setitimer \
1552         setvbuf \
1553         sigaction \
1554         strcasestr \
1555         strerror \
1556         sysconf \
1557         sysctl \
1558         tdestroy \
1559         timegm \
1560 ])
1561
1562 OPENAFS_ROKEN()
1563 OPENAFS_C_ATTRIBUTE()
1564
1565 dnl Functions that Heimdal's libroken provides, but that we
1566 dnl haven't found a need for yet, and so haven't imported
1567 AC_CHECK_FUNCS([ \
1568         chown \
1569         fchown \
1570         gethostname \
1571         lstat \
1572         inet_aton \
1573         inet_ntop \
1574         inet_pton \
1575         putenv \
1576         readv \
1577         setenv \
1578         strdup \
1579         strftime \
1580         strndup \
1581         strsep \
1582         unsetenv \
1583 ])
1584
1585 dnl Functions that are in objects that we always build from libroken
1586 AC_CHECK_FUNCS([ \
1587         asprintf \
1588         asnprintf \
1589         vasprintf \
1590         vasnprintf \
1591         vsnprintf \
1592         snprintf \
1593 ])
1594
1595 dnl Functions that we're going to try and get from libroken
1596 AC_REPLACE_FUNCS([ \
1597         daemon \
1598         ecalloc \
1599         emalloc \
1600         erealloc \
1601         err \
1602         errx \
1603         flock \
1604         freeaddrinfo \
1605         gai_strerror \
1606         getaddrinfo \
1607         getdtablesize \
1608         getnameinfo \
1609         getopt \
1610         getprogname \
1611         gettimeofday \
1612         localtime_r \
1613         mkstemp \
1614         setenv \
1615         setprogname \
1616         strcasecmp \
1617         strlcat \
1618         strnlen \
1619         strlcpy \
1620         strsep \
1621         tdelete \
1622         tfind \
1623         tsearch \
1624         twalk \
1625         unsetenv \
1626         verr \
1627         verrx \
1628         vsyslog \
1629         vwarn \
1630         vwarnx \
1631         warn \
1632         warnx \
1633 ])
1634
1635 dnl Headers that we're going to try and get from libroken
1636 AC_CHECK_HEADERS([ \
1637         err.h \
1638         search.h \
1639 ])
1640
1641 AC_CHECK_DECLS([h_errno], [], [], [
1642 #include <sys/types.h>
1643 #ifdef HAVE_NETDB_H
1644 #include <netdb.h>
1645 #endif
1646 ])
1647
1648 AC_HEADER_TIME
1649
1650 ROKEN_HEADERS=
1651 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1652       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1653       [])
1654 AC_SUBST(ROKEN_HEADERS)
1655
1656 dnl Stuff that's harder ...
1657 AC_MSG_CHECKING([for bswap16])
1658 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1659 #ifdef HAVE_SYS_TYPES_H
1660 #include <sys/types.h>
1661 #endif
1662 #ifdef HAVE_SYS_BSWAP_H
1663 #include <sys/bswap.h>
1664 #endif
1665 ],
1666 [short a, b; b = bswap16(a); ])],
1667 [AC_MSG_RESULT(yes)
1668  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1669 ],
1670 [AC_MSG_RESULT(no)])
1671
1672 AC_MSG_CHECKING([for bswap32])
1673 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1674 #include <sys/types.h>
1675 #endif
1676 #ifdef HAVE_SYS_BSWAP_H
1677 #include <sys/bswap.h>
1678 #endif
1679 ],
1680 [int a, b; b = bswap32(a); ])],
1681 [AC_MSG_RESULT(yes)
1682  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1683 ],
1684 [AC_MSG_RESULT(no)])
1685
1686 case $AFS_SYSNAME in
1687 *hp_ux* | *hpux*)
1688    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1689    ;;
1690 *)
1691    AC_MSG_CHECKING([for positional I/O])
1692    if test "$ac_cv_func_pread" = "yes" && \
1693            test "$ac_cv_func_pwrite" = "yes"; then
1694       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1695       AC_MSG_RESULT(yes)
1696    else
1697      AC_MSG_RESULT(no)
1698    fi
1699    AC_MSG_CHECKING([for vectored positional I/O])
1700    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1701                "$ac_cv_func_pwritev" = "yes" -a \
1702                "$ac_cv_func_preadv64" = "yes" -a \
1703                "$ac_cv_func_pwritev64" = "yes"],
1704          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1705           AC_MSG_RESULT(yes)],
1706          [AC_MSG_RESULT(no)])
1707    ;;
1708 esac
1709
1710 AC_MSG_CHECKING([for POSIX regex library])
1711 if test "$ac_cv_header_regex_h" = "yes" && \
1712         test "$ac_cv_func_regcomp" = "yes" && \
1713         test "$ac_cv_func_regexec" = "yes" && \
1714         test "$ac_cv_func_regerror" = "yes"; then
1715     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1716     AC_MSG_RESULT(yes)
1717 else
1718     AC_MSG_RESULT(no)
1719 fi
1720
1721 dnl Look for "non-portable" pthreads functions.
1722 save_LIBS="$LIBS"
1723 LIBS="$LIBS $PTHREAD_LIBS"
1724 AC_CHECK_FUNCS([ \
1725         pthread_set_name_np \
1726         pthread_setname_np \
1727 ])
1728
1729 dnl Sadly, there are three different versions of pthread_setname_np.
1730 dnl Try to cater for all of them.
1731 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1732     AC_MSG_CHECKING([for signature of pthread_setname_np])
1733     AC_TRY_COMPILE([
1734 #include <pthread.h>
1735 #ifdef HAVE_PTHREAD_NP_H
1736 #include <pthread_np.h>
1737 #endif
1738 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1739         AC_MSG_RESULT([three arguments])
1740         pthread_setname_np_args=3], [
1741         AC_TRY_COMPILE([
1742 #include <pthread.h>
1743 #ifdef HAVE_PTHREAD_NP_H
1744 #include <pthread_np.h>
1745 #endif
1746 ], [pthread_setname_np(pthread_self(), "test")], [
1747             AC_MSG_RESULT([two arguments])
1748             pthread_setname_np_args=2], [
1749             AC_TRY_COMPILE([
1750 #include <pthread.h>
1751 #ifdef HAVE_PTHREAD_NP_H
1752 #include <pthread_np.h>
1753 #endif
1754 ], [pthread_setname_np("test")], [
1755                 AC_MSG_RESULT([one argument])
1756                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1757 ])
1758 ])
1759 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1760 fi
1761 LIBS="$save_LIBS"
1762
1763 openafs_cv_saved_CFLAGS="$CFLAGS"
1764 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1765
1766 AC_TYPE_SIGNAL
1767 OPENAFS_RETSIGTYPE
1768 AC_CHECK_SIZEOF(void *)
1769 AC_CHECK_SIZEOF(unsigned long long)
1770 AC_CHECK_SIZEOF(unsigned long)
1771 AC_CHECK_SIZEOF(unsigned int)
1772 AC_TYPE_INTPTR_T
1773 AC_TYPE_UINTPTR_T
1774 AC_TYPE_SSIZE_T
1775 AC_CHECK_TYPE([sig_atomic_t],[],
1776     [AC_DEFINE([sig_atomic_t], [int],
1777         [Define to int if <signal.h> does not define.])],
1778 [#include <sys/types.h>
1779 #include <signal.h>])
1780 AC_CHECK_TYPE([socklen_t],[],
1781     [AC_DEFINE([socklen_t], [int],
1782         [Define to int if <sys/socket.h> does not define.])],
1783 [#include <sys/types.h>
1784 #include <sys/socket.h>])
1785 AC_CHECK_TYPES(off64_t)
1786 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1787 AC_CHECK_TYPES([struct winsize], [], [], [
1788 #ifdef HAVE_TERMIOS_H
1789 # include <termios.h>
1790 #else
1791 # include <sys/termios.h>
1792 #endif
1793 #include <sys/ioctl.h>])
1794 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1795                 struct sockaddr_storage],
1796                [], [], [
1797 #include <sys/types.h>
1798 #include <sys/socket.h>
1799 ])
1800 AC_CHECK_TYPES([sa_family_t], [], [], [
1801 #include <sys/types.h>
1802 #include <sys/socket.h>
1803 ])
1804 AC_CHECK_TYPES([struct addrinfo], [], [], [
1805 #include <sys/types.h>
1806 #ifdef HAVE_NETDB_H
1807 #include <netdb.h>
1808 #endif
1809 ])
1810 AC_CHECK_TYPES([long long], [], [], [])
1811
1812 AC_SIZEOF_TYPE(long)
1813
1814 CFLAGS="$openafs_cv_saved_CFLAGS"
1815
1816 RRA_HEADER_PAM_CONST
1817
1818
1819 dnl Directory PATH handling
1820 if test "x$enable_transarc_paths" = "xyes"  ; then 
1821     afsconfdir=${afsconfdir=/usr/afs/etc}
1822     viceetcdir=${viceetcdir=/usr/vice/etc}
1823     afskerneldir=${afskerneldir=${viceetcdir}}
1824     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1825     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1826     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1827     afsdbdir=${afsdbdir=/usr/afs/db}
1828     afslogsdir=${afslogsdir=/usr/afs/logs}
1829     afslocaldir=${afslocaldir=/usr/afs/local}
1830     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1831     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1832     afsdatadir=${afsdatadir=/usr/vice/etc}
1833 else 
1834     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1835     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1836     afskerneldir=${afskerneldir='${libdir}/openafs'}
1837     afssrvbindir=${afssrvbindir='${bindir}'}
1838     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1839     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1840     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1841     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1842     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1843     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1844     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1845     afsdatadir=${afsdatadir='${datadir}/openafs'}
1846 fi
1847 AC_SUBST(afsconfdir)
1848 AC_SUBST(viceetcdir)
1849 AC_SUBST(afskerneldir)
1850 AC_SUBST(afssrvbindir)
1851 AC_SUBST(afssrvsbindir)
1852 AC_SUBST(afssrvlibexecdir)
1853 AC_SUBST(afsdbdir)
1854 AC_SUBST(afslogsdir)
1855 AC_SUBST(afslocaldir)
1856 AC_SUBST(afsbackupdir)
1857 AC_SUBST(afsbosconfigdir)
1858 AC_SUBST(afsdatadir)
1859
1860 if test "x$enable_kernel_module" = "xyes"; then
1861 ENABLE_KERNEL_MODULE=libafs
1862 fi
1863
1864 if test "x$enable_pthreaded_ubik" = "xyes"; then
1865 ENABLE_PTHREADED_UBIK=yes
1866 fi
1867
1868 AC_SUBST(VFSCK)
1869 AC_SUBST(AFS_SYSNAME)
1870 AC_SUBST(AFS_PARAM_COMMON)
1871 AC_SUBST(ENABLE_KERNEL_MODULE)
1872 AC_SUBST(ENABLE_PTHREADED_UBIK)
1873 AC_SUBST(LIB_AFSDB)
1874 AC_SUBST(LINUX_KERNEL_PATH)
1875 AC_SUBST(LINUX_KERNEL_BUILD)
1876 AC_SUBST(HOST_CPU)
1877 AC_SUBST(BSD_KERNEL_PATH)
1878 AC_SUBST(BSD_KERNEL_BUILD)
1879 AC_SUBST(LINUX_VERSION)
1880 AC_SUBST(MKAFS_OSTYPE)
1881 AC_SUBST(TOP_OBJDIR)
1882 AC_SUBST(TOP_SRCDIR)
1883 AC_SUBST(TOP_INCDIR)
1884 AC_SUBST(TOP_LIBDIR)
1885 AC_SUBST(DEST)
1886 AC_SUBST(DARWIN_INFOFILE)
1887 AC_SUBST(IRIX_BUILD_IP35)
1888 AC_SUBST(HTML_XSL)
1889 AC_SUBST(XSLTPROC)
1890 AC_SUBST(DOCBOOK2PDF)
1891 AC_SUBST(DOCBOOK_STYLESHEETS)
1892
1893 OPENAFS_FUSE
1894 OPENAFS_SWIG
1895
1896 TOP_SRCDIR="${srcdir}/src"
1897 dnl
1898 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1899 dnl
1900 case $TOP_SRCDIR in
1901         /*)
1902                 ;;
1903         *)
1904                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1905                 ;;
1906 esac
1907
1908 TOP_OBJDIR="${SRCDIR_PARENT}"
1909 TOP_INCDIR="${SRCDIR_PARENT}/include"
1910 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1911 if test "${DEST}x" = "x"; then
1912         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1913 fi
1914
1915 if test "x$with_crosstools_dir" != "x"; then
1916         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1917                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1918                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1919                 RXGEN_PATH=$with_crosstools_dir/rxgen
1920         else
1921                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1922                 exit 1
1923         fi
1924 else
1925         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1926         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1927         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1928 fi
1929 AC_SUBST(COMPILE_ET_PATH)
1930 AC_SUBST(CONFIGTOOL_PATH)
1931 AC_SUBST(RXGEN_PATH)
1932
1933 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1934 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1935 AC_SUBST(HELPER_SPLINT)
1936 AC_SUBST(HELPER_SPLINTCFG)
1937
1938 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1939
1940 dnl Check to see if crypt lives in a different library
1941 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1942 AC_SUBST(LIB_crypt)
1943
1944 dnl Check to see if the compiler support labels in structs
1945 AC_MSG_CHECKING(for label support in structs)
1946 AC_TRY_COMPILE([], [
1947 extern void osi_UFSOpen(void);
1948 struct labeltest {
1949    void (*open) (void);
1950 };
1951 struct labeltest struct_labeltest = {
1952    .open       = osi_UFSOpen,
1953 }
1954 ],
1955 [AC_MSG_RESULT(yes)
1956  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1957 ],
1958 [AC_MSG_RESULT(no)
1959 ])
1960
1961 AC_MSG_CHECKING([checking for dirfd])
1962 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1963 #ifdef HAVE_DIRENT_H
1964 #include <dirent.h>
1965 #endif
1966 ]],
1967         [[DIR *d = 0; dirfd(d);]])],
1968         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1969 if test "$ac_rk_have_dirfd" = "yes" ; then
1970         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1971 fi
1972 AC_MSG_RESULT($ac_rk_have_dirfd)
1973
1974 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1975 #ifdef HAVE_DIRENT_H
1976 #include <dirent.h>
1977 #endif])
1978
1979 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
1980 [#ifdef HAVE_SYS_RESOURCE_H
1981 #include <sys/resource.h>
1982 #endif])
1983
1984 dnl Eventually, this will look for the system one, or for OpenSSL
1985 LIB_hcrypto="-lafshcrypto"
1986 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1987 AC_SUBST(LIB_hcrypto)
1988 AC_SUBST(LDFLAGS_hcrypto)
1989
1990 dnl Check for UUID library
1991 AC_CHECK_HEADERS([uuid/uuid.h])
1992 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1993 AC_CHECK_FUNCS([uuid_generate])
1994 ])
1995
1996