7e0245046ee2603fabc96236b3556612d3f9ee54
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([pam],
79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
80     ,
81     [enable_pam="yes"])
82 AC_ARG_ENABLE([gtx],
83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
84 AC_ARG_ENABLE([uss],
85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
86 AC_ARG_ENABLE([namei-fileserver],
87     [AS_HELP_STRING([--enable-namei-fileserver],
88         [force compilation of namei fileserver in preference to inode
89          fileserver])],
90     , 
91     [enable_namei_fileserver="default"])
92 AC_ARG_ENABLE([supergroups],
93     [AS_HELP_STRING([--enable-supergroups],
94         [enable support for nested pts groups])],
95     , 
96     [enable_supergroups="no"])
97 AC_ARG_ENABLE([bitmap-later],
98     [AS_HELP_STRING([--enable-bitmap-later],
99         [enable fast startup of file server by not reading bitmap till
100          needed])],
101     , 
102     [enable_bitmap_later="no"])
103 AC_ARG_ENABLE([unix-sockets],
104     [AS_HELP_STRING([--disable-unix-sockets],
105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
106     ,
107     [enable_unix_sockets="yes"])
108 AC_ARG_ENABLE([tivoli-tsm],
109     [AS_HELP_STRING([--enable-tivoli-tsm],
110         [enable use of the Tivoli TSM API libraries for butc support])],
111     , 
112     [enable_tivoli_tsm="no"])
113 AC_ARG_ENABLE([pthreaded-ubik],
114     [AS_HELP_STRING([--enable-pthreaded-ubik],
115         [enable installation of pthreaded ubik applications (defaults to
116          disabled)])],
117     ,
118     [enable_pthreaded_ubik="no"])
119
120 dnl Kernel module build options.
121 AC_ARG_WITH([linux-kernel-headers],
122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
123         [use the kernel headers found at path (optional, defaults to
124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
126 AC_ARG_WITH([linux-kernel-build],
127     [AS_HELP_STRING([--with-linux-kernel-build=path],
128         [use the kernel build found at path(optional, defaults to 
129         kernel headers path)])])
130 AC_ARG_WITH([bsd-kernel-headers],
131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
132         [use the kernel headers found at path (optional, defaults to
133          /usr/src/sys)])])
134 AC_ARG_WITH([bsd-kernel-build],
135     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
136         [use the kernel build found at path (optional, defaults to
137          KSRC/i386/compile/GENERIC)])])
138 AC_ARG_WITH([linux-kernel-packaging],
139     [AS_HELP_STRING([--with-linux-kernel-packaging],
140         [use standard naming conventions to aid Linux kernel build packaging
141          (disables MPS, sets the kernel module name to openafs.ko, and
142          installs kernel modules into the standard Linux location)])],
143     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
144      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
145     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
146 AC_ARG_ENABLE([kernel-module],
147     [AS_HELP_STRING([--disable-kernel-module],
148         [disable compilation of the kernel module (defaults to enabled)])],
149     , 
150     [enable_kernel_module="yes"])
151 AC_ARG_ENABLE([redhat-buildsys],
152     [AS_HELP_STRING([--enable-redhat-buildsys],
153         [enable compilation of the redhat build system kernel (defaults to
154          disabled)])],
155     ,
156     [enable_redhat_buildsys="no"])
157
158 dnl Installation locations.
159 AC_ARG_ENABLE([transarc-paths],
160     [AS_HELP_STRING([--enable-transarc-paths],
161         [use Transarc style paths like /usr/afs and /usr/vice])],
162     , 
163     [enable_transarc_paths="no"])
164
165 dnl Deprecated crypto
166 AC_ARG_ENABLE([kauth],
167     [AS_HELP_STRING([--enable-kauth],
168         [install the deprecated kauth server and utilities (defaults to
169          disabled)])],
170     ,
171     [enable_kauth="no"])
172
173 dnl Optimization and debugging flags.
174 AC_ARG_ENABLE([strip-binaries],
175     [AS_HELP_STRING([--disable-strip-binaries],
176         [disable stripping of symbol information from binaries (defaults to
177          enabled)])],
178     ,
179     [enable_strip_binaries="maybe"])
180 AC_ARG_ENABLE([debug],
181     [AS_HELP_STRING([--enable-debug],
182         [enable compilation of the user space code with debugging information
183          (defaults to disabled)])],
184     , 
185     [enable_debug="no"])
186 AC_ARG_ENABLE([optimize],
187     [AS_HELP_STRING([--disable-optimize],
188         [disable optimization for compilation of the user space code (defaults
189          to enabled)])],
190     , 
191     [enable_optimize="yes"])
192 AC_ARG_ENABLE([warnings],
193     [AS_HELP_STRING([--enable-warnings],
194         [enable compilation warnings when building with gcc (defaults to
195          disabled)])],
196     ,
197     [enable_warnings="no"])
198 AC_ARG_ENABLE([checking],
199     [AS_HELP_STRING([--enable-checking],
200         [turn compilation warnings into errors when building with gcc (defaults
201          to disabled)])],
202     [enable_checking="$enableval"],
203     [enable_checking="no"])
204 AC_ARG_ENABLE([debug-locks],
205     [AS_HELP_STRING([--enable-debug-locks],
206         [turn on lock debugging assertions (defaults to disabled)])],
207     [enable_debug_locks="$enableval"],
208     [enable_debug_locks="no"])
209 AC_ARG_ENABLE([debug-kernel],
210     [AS_HELP_STRING([--enable-debug-kernel],
211         [enable compilation of the kernel module with debugging information
212          (defaults to disabled)])],
213     ,
214     [enable_debug_kernel="no"])
215 AC_ARG_ENABLE([optimize-kernel],
216     [AS_HELP_STRING([--disable-optimize-kernel],
217         [disable compilation of the kernel module with optimization (defaults
218          based on platform)])],
219     , 
220     [enable_optimize_kernel=""])
221 AC_ARG_ENABLE([debug-lwp],
222     [AS_HELP_STRING([--enable-debug-lwp],
223         [enable compilation of the LWP code with debugging information
224          (defaults to disabled)])],
225     ,
226     [enable_debug_lwp="no"])
227 AC_ARG_ENABLE([optimize-lwp],
228     [AS_HELP_STRING([--disable-optimize-lwp],
229         [disable optimization for compilation of the LWP code (defaults to
230          enabled)])],
231     ,
232     [enable_optimize_lwp="yes"])
233 AC_ARG_ENABLE([debug-pam],
234     [AS_HELP_STRING([--enable-debug-pam],
235         [enable compilation of the PAM code with debugging information
236          (defaults to disabled)])],
237     ,
238     [enable_debug_pam="no"])
239 AC_ARG_ENABLE([optimize-pam],
240     [AS_HELP_STRING([--disable-optimize-pam],
241         [disable optimization for compilation of the PAM code (defaults to
242          enabled)])],
243     ,
244     [enable_optimize_pam="yes"])
245 AC_ARG_ENABLE([linux-syscall-probing],
246     [AS_HELP_STRING([--enable-linux-syscall-probing],
247         [enable Linux syscall probing (defaults to autodetect)])],
248     ,
249     [enable_linux_syscall_probing="maybe"])
250 AC_ARG_WITH([crosstools-dir],
251     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
252     
253 AC_ARG_WITH([xslt-processor],
254         AS_HELP_STRING([--with-xslt-processor=ARG],
255         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
256         [XSLTPROC="$withval"],
257         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
258
259 AC_ARG_WITH([html-xsl], 
260         AS_HELP_STRING([--with-html-xsl],
261         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
262         [HTML_XSL="$withval"],
263         [HTML_XSL="html/chunk.xsl"])
264
265 AC_ARG_WITH([docbook2pdf],
266         AS_HELP_STRING([--with-docbook2pdf=ARG],
267         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
268         [DOCBOOK2PDF="$withval"],
269         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
270
271 AC_ARG_WITH([docbook-stylesheets],
272         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
273         [location of DocBook stylesheets (default is to search a set of likely paths)]),
274         [DOCBOOK_STYLESHEETS="$withval"],
275         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
276         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
277                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
278         fi)
279
280 enable_login="no"
281
282 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
283 dnl documentation build.
284 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
285
286 dnl Checks for UNIX variants.
287 AC_ISC_POSIX
288
289 dnl Various compiler setup.
290 AC_TYPE_PID_T
291 AC_TYPE_SIZE_T
292
293 dnl Checks for programs.
294 AC_PROG_INSTALL
295 AC_PROG_LN_S
296 AC_PROG_RANLIB
297 AC_PROG_YACC
298 AM_PROG_LEX
299 dnl if we are flex, be lex-compatible
300 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
301
302 OPENAFS_FORCE_ABS_INSTALL
303 OPENAFS_CHECK_BIGENDIAN
304 OPENAFS_PRINTF_TAKES_Z_LEN
305
306 AC_MSG_CHECKING(your OS)
307 system=$host
308 case $system in
309         *-linux*)
310
311                 MKAFS_OSTYPE=LINUX
312                 if test "x$enable_redhat_buildsys" = "xyes"; then
313                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
314                 fi
315                 if test "x$enable_kernel_module" = "xyes"; then
316                  if test "x$with_linux_kernel_headers" != "x"; then
317                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
318                  else
319                    for utsdir in "/lib/modules/`uname -r`/build" \
320                                  "/lib/modules/`uname -r`/source" \
321                                  "/usr/src/linux-2.4" \
322                                  "/usr/src/linux"; do
323                      LINUX_KERNEL_PATH="$utsdir"
324                      for utsfile in "include/generated/utsrelease.h" \
325                                     "include/linux/utsrelease.h" \
326                                     "include/linux/version.h" \
327                                     "include/linux/version-up.h"; do
328                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
329                          break 2
330                        fi
331                      done
332                    done
333                  fi
334                  if test "x$with_linux_kernel_build" != "x"; then
335                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
336                  else
337                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
338                  fi
339                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
340                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
341                    LINUX_VERSION="$linux_kvers"
342                  else
343                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
344                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
345                      LINUX_VERSION="$linux_kvers"
346                    else
347                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
348                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
349                        if test "x$linux_kvers" = "x"; then
350                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
351                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
352                            if test "x$linux_kvers" = "x"; then
353                              AC_MSG_ERROR(Linux headers lack version definition [2])
354                              exit 1
355                            else
356                              LINUX_VERSION="$linux_kvers"
357                            fi
358                          else
359                            AC_MSG_ERROR(Linux headers lack version definition)
360                            exit 1
361                          fi
362                        else
363                          LINUX_VERSION="$linux_kvers"
364                        fi
365                      else
366                        enable_kernel_module="no"
367                      fi
368                    fi
369                  fi
370                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
371                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
372                      enable_kernel_module="no"
373                  fi
374                  if test "x$enable_kernel_module" = "xno"; then
375                   if test "x$with_linux_kernel_headers" != "x"; then
376                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
377                    exit 1
378                   else
379                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
380                   fi
381                  fi
382                  dnl do we need to determine SUBARCH from autoconf.h
383                  SUBARCH=default
384                 fi
385                 AC_MSG_RESULT(linux)
386                 if test "x$enable_kernel_module" = "xyes"; then
387                  case "$LINUX_VERSION" in
388                   2.2.*) AFS_SYSKVERS=22 ;;
389                   2.4.*) AFS_SYSKVERS=24 ;;
390                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
391                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
392                  esac
393                 fi
394                 ;;
395         *-solaris*)
396                 MKAFS_OSTYPE=SOLARIS
397                 AC_MSG_RESULT(sun4)
398                 AC_PATH_PROG(SOLARISCC, [cc], ,
399                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
400                 if test "x$SOLARISCC" = "x" ; then
401                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
402                 fi
403                 SOLARIS_UFSVFS_HAS_DQRWLOCK
404                 SOLARIS_FS_HAS_FS_ROLLED
405                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
406                 SOLARIS_HAVE_VN_RENAMEPATH
407                 ;;
408         *-sunos*)
409                 MKAFS_OSTYPE=SUNOS
410                 enable_kernel_module=no
411                 AC_MSG_RESULT(sun4)
412                 ;;
413         *-hpux*)
414                 MKAFS_OSTYPE=HPUX
415                 AC_MSG_RESULT(hp_ux)
416                 if test -f "/usr/old/usr/include/ndir.h"; then
417                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
418                 fi
419                 ;;
420         *-irix*)
421                 if test -d /usr/include/sys/SN/SN1; then
422                  IRIX_BUILD_IP35="IP35"
423                 fi
424                 MKAFS_OSTYPE=IRIX
425                 AC_MSG_RESULT(sgi)
426                 ;;
427         *-aix*)
428                 MKAFS_OSTYPE=AIX
429                 AC_MSG_RESULT(rs_aix)
430                 ;;
431         arm-*-darwin*)
432                 MKAFS_OSTYPE=DARWIN
433                 AC_MSG_RESULT(arm_darwin)
434                 ;;
435         powerpc-*-darwin*)
436                 MKAFS_OSTYPE=DARWIN
437                 AC_MSG_RESULT(ppc_darwin)
438                 ;;
439         i386-*-darwin*)
440                 MKAFS_OSTYPE=DARWIN
441                 AC_MSG_RESULT(x86_darwin)
442                 ;;
443         x86_64-*-darwin*)
444                 MKAFS_OSTYPE=DARWIN
445                 AC_MSG_RESULT(x86_darwin)
446                 ;;
447         i386-*-freebsd*)
448                 MKAFS_OSTYPE=FBSD
449                 AC_MSG_RESULT(i386_fbsd)
450                 ;;
451         x86_64-*-freebsd*)
452                 MKAFS_OSTYPE=FBSD
453                 AC_MSG_RESULT(amd64_fbsd)
454                 ;;
455         *-netbsd*)
456                 MKAFS_OSTYPE=NBSD
457                 AC_MSG_RESULT(nbsd)
458                 ;;
459         x86_64-*-openbsd*)
460                 MKAFS_OSTYPE=OBSD
461                 AC_MSG_RESULT(amd64_obsd)
462                 ;;
463         i386-*-openbsd*)
464                 MKAFS_OSTYPE=OBSD
465                 AC_MSG_RESULT(i386_obsd)
466                 ;;
467         *-dragonfly*)
468                 MKAFS_OSTYPE=DFBSD
469                 AC_MSG_RESULT(i386_dfbsd)
470                 ;;
471         *)
472                 AC_MSG_RESULT($system)
473                 ;;
474 esac
475
476 if test "x$with_afs_sysname" != "x"; then
477         AFS_SYSNAME="$with_afs_sysname"
478 else
479         AC_MSG_CHECKING(your AFS sysname)
480         case $host in
481                 i?86-*-openbsd?.?)
482                         v=${host#*openbsd}
483                         vM=${v%.*}
484                         vm=${v#*.}
485                         AFS_SYSNAME="i386_obsd${vM}${vm}"
486                         ;;
487                 sparc64-*-openbsd?.?)
488                         v=${host#*openbsd}
489                         vM=${v%.*}
490                         vm=${v#*.}
491                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
492                         ;;
493                 x86_64-*-openbsd?.?)
494                         v=${host#*openbsd}
495                         vM=${v%.*}
496                         vm=${v#*.}
497                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
498                         ;;
499                 i?86-*-freebsd*.*)
500                         v=${host#*freebsd}
501                         vM=${v%.*}
502                         vm=${v#*.}
503                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
504                         ;;
505                 x86_64-*-freebsd*.*)
506                         v=${host#*freebsd}
507                         vM=${v%.*}
508                         vm=${v#*.}
509                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
510                         ;;
511                 i386-*-dragonfly?.*)
512                         v=${host#*dragonfly}
513                         vM=${v%.*}
514                         vm=${v#*.}
515                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
516                         ;;
517                 i?86-*-netbsd*1.6[[M-Z]]*)
518                         AFS_SYSNAME="i386_nbsd20"
519                         ;;
520                 powerpc-*-netbsd*1.6[[M-Z]]*)
521                         AFS_SYSNAME="ppc_nbsd20"
522                         ;;
523                 *-*-netbsd*)
524                         arch=${host%%-unknown*}
525                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
526                                                -e 's/powerpc/ppc/g')
527                         v=${host#*netbsd}
528                         v=${v#*aout}
529                         v=${v#*ecoff}
530                         v=${v#*elf}
531                         vM=${v%%.*}
532                         vM=${vM%.*}
533                         v=${v#*.}
534                         vm=${v%%.*}
535                         vm=${vm%.*}
536                         vm=${vm%%[[_A-Z]]*}
537                         if test $vm -eq 99 ; then
538                                 vM=$((vM+1))
539                         fi
540                         if test $vM -gt 1 ; then
541                                 vm=0
542                         fi
543                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
544                         ;;
545                 hppa*-hp-hpux11.0*)
546                         AFS_SYSNAME="hp_ux110"
547                         ;;
548                 hppa*-hp-hpux11.11)
549                         AFS_SYSNAME="hp_ux11i"
550                         ;;
551                 hppa*-hp-hpux11.23)
552                         AFS_SYSNAME="hp_ux1123"
553                         ;;
554                 ia64-hp-hpux11.22)
555                         AFS_SYSNAME="ia64_hpux1122"
556                         ;;
557                 ia64-hp-hpux*)
558                         AFS_SYSNAME="ia64_hpux1123"
559                         ;;
560                 hppa*-hp-hpux10*)
561                         AFS_SYSNAME="hp_ux102"
562                         ;;
563                 powerpc-apple-darwin7*)
564                         AFS_SYSNAME="ppc_darwin_70"
565                         OSXSDK="macosx10.3"
566                         ;;
567                 powerpc-apple-darwin8.*)
568                         AFS_SYSNAME="ppc_darwin_80"
569                         OSXSDK="macosx10.4"
570                         ;;
571                 i386-apple-darwin8.*)
572                         AFS_SYSNAME="x86_darwin_80"
573                         OSXSDK="macosx10.4"
574                         ;;
575                 powerpc-apple-darwin9.*)
576                         AFS_SYSNAME="ppc_darwin_90"
577                         OSXSDK="macosx10.5"
578                         ;;
579                 i386-apple-darwin9.*)
580                         AFS_SYSNAME="x86_darwin_90"
581                         OSXSDK="macosx10.5"
582                         ;;
583                 i?86-apple-darwin10.*)
584                         AFS_SYSNAME="x86_darwin_100"
585                         OSXSDK="macosx10.6"
586                         ;;
587                 x86_64-apple-darwin10.*)
588                         AFS_SYSNAME="x86_darwin_100"
589                         OSXSDK="macosx10.6"
590                         ;;
591                 arm-apple-darwin10.*)
592                         AFS_SYSNAME="arm_darwin_100"
593                         OSXSDK="iphoneos4.0"
594                         ;;
595                 x86_64-apple-darwin11.*)
596                         AFS_SYSNAME="x86_darwin_110"
597                         OSXSDK="macosx10.7"
598                         ;;
599                 i?86-apple-darwin11.*)
600                         AFS_SYSNAME="x86_darwin_110"
601                         OSXSDK="macosx10.7"
602                         ;;
603                 x86_64-apple-darwin12.*)
604                         AFS_SYSNAME="x86_darwin_120"
605                         OSXSDK="macosx10.8"
606                         ;;
607                 i?86-apple-darwin12.*)
608                         AFS_SYSNAME="x86_darwin_120"
609                         OSXSDK="macosx10.8"
610                         ;;
611                 x86_64-apple-darwin13.*)
612                         AFS_SYSNAME="x86_darwin_130"
613                         OSXSDK="macosx10.9"
614                         ;;
615                 i?86-apple-darwin13.*)
616                         AFS_SYSNAME="x86_darwin_130"
617                         OSXSDK="macosx10.9"
618                         ;;
619                 sparc-sun-solaris2.8)
620                         AFS_SYSNAME="sun4x_58"
621                         ;;
622                 sparc-sun-solaris2.9)
623                         AFS_SYSNAME="sun4x_59"
624                         ;;
625                 sparc-sun-solaris2.10)
626                         AFS_SYSNAME="sun4x_510"
627                         ;;
628                 sparc-sun-solaris2.11)
629                         AFS_SYSNAME="sun4x_511"
630                         ;;
631                 i386-pc-solaris2.8)
632                         AFS_SYSNAME="sunx86_58"
633                         ;;
634                 i386-pc-solaris2.9)
635                         AFS_SYSNAME="sunx86_59"
636                         ;;
637                 i386-pc-solaris2.10)
638                         AFS_SYSNAME="sunx86_510"
639                         ;;
640                 i386-pc-solaris2.11)
641                         AFS_SYSNAME="sunx86_511"
642                         ;;
643                 alpha*-dec-osf4.0*)
644                         AFS_SYSNAME="alpha_dux40"
645                         ;;
646                 alpha*-dec-osf5.0*)
647                         AFS_SYSNAME="alpha_dux50"
648                         ;;
649                 alpha*-dec-osf5.1*)
650                         AFS_SYSNAME="alpha_dux51"
651                         ;;
652                 mips-sgi-irix6.5)
653                         AFS_SYSNAME="sgi_65"
654                         ;;
655                 ia64-*-linux*)
656                         AFS_SYSNAME="ia64_linuxXX"
657                         ;;
658                 powerpc-*-linux*)
659                         AFS_SYSNAME="`/bin/arch`_linuxXX"
660                         ;;
661                 powerpc64-*-linux*)
662                         AFS_SYSNAME="ppc64_linuxXX"
663                         ;;
664                 alpha*-linux*)
665                         AFS_SYSNAME="alpha_linux_XX"
666                         ;;
667                 s390-*-linux*)
668                         AFS_SYSNAME="s390_linuxXX"
669                         ;;
670                 s390x-*-linux*)
671                         AFS_SYSNAME="s390x_linuxXX"
672                         ;;
673                 sparc-*-linux*)
674                         AFS_SYSNAME="`/bin/arch`_linuxXX"
675                         ;;
676                 sparc64-*-linux*)
677                         AFS_SYSNAME="sparc64_linuxXX"
678                         ;;
679                 i?86-*-linux*)
680                         AFS_SYSNAME="i386_linuxXX"
681                         ;;
682                 arm*-linux*)
683                         AFS_SYSNAME="arm_linuxXX"
684                         ;;
685                 parisc-*-linux-gnu|hppa-*-linux-gnu)
686                         AFS_SYSNAME="parisc_linuxXX"
687                         enable_pam="no"
688                         ;;
689                 power*-ibm-aix4.2*)
690                         AFS_SYSNAME="rs_aix42"
691                         enable_pam="no"
692                         ;;
693                 power*-ibm-aix4.3*)
694                         AFS_SYSNAME="rs_aix42"
695                         enable_pam="no"
696                         ;;
697                 power*-ibm-aix5.1*)
698                         AFS_SYSNAME="rs_aix51"
699                         enable_pam="no"
700                         ;;
701                 power*-ibm-aix5.2*)
702                         AFS_SYSNAME="rs_aix52"
703                         enable_pam="no"
704                         ;;
705                 power*-ibm-aix5.3*)
706                         AFS_SYSNAME="rs_aix53"
707                         enable_pam="no"
708                         ;;
709                 power*-ibm-aix6.1*)
710                         AFS_SYSNAME="rs_aix61"
711                         enable_pam="no"
712                         ;;
713                 x86_64-*-linux-gnu)
714                         AFS_SYSNAME="amd64_linuxXX"
715                         enable_pam="yes"
716                         ;;
717                 *)
718                         AC_MSG_ERROR(An AFS sysname is required)
719                         exit 1
720                         ;;
721         esac
722         case $AFS_SYSNAME in
723                 *_linux* | *_umlinux*)
724                         if test "x${AFS_SYSKVERS}" = "x"; then
725                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
726                         fi
727                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
728                         AFS_SYSNAME="$_AFS_SYSNAME"
729                         AC_TRY_KBUILD(
730                          [],
731                          [#ifndef CONFIG_USERMODE
732                           #error not UML
733                           #endif],
734                          ac_cv_linux_is_uml=yes,)
735                         if test "${ac_cv_linux_is_uml}" = yes; then
736                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
737                         fi
738                         AFS_SYSNAME="$_AFS_SYSNAME"
739                         ;;
740         esac
741         AC_MSG_RESULT($AFS_SYSNAME)
742 fi
743
744 case $AFS_SYSNAME in
745         *_darwin*)
746                 AC_CHECK_HEADERS(crt_externs.h)
747                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
748                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
749                 AC_SUBST(OSXSDK)
750                 ;;
751 esac
752
753 dnl Some hosts have a separate common param file they should include.  Figure
754 dnl out if we're on one of them now that we know the sysname.
755 case $AFS_SYSNAME in
756     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
757     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
758     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
759     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
760     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
761     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
762     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
763     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
764     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
765     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
766     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
767     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
768     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
769     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
770     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
771     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
772     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
773     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
774     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
775     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
776     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
777     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
778     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
779     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
780     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
781     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
782     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
783     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
784     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
785     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
786     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
787     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
788     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
789     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
790     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
791     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
792 # Linux alpha adds an extra underscore for no good reason.
793     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
794     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
795     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
796 esac
797
798 OPENAFS_OSCONF
799
800 case $AFS_SYSNAME in *_linux* | *_umlinux*)
801
802                 # Add (sub-) architecture-specific paths needed by conftests
803                 case $AFS_SYSNAME  in
804                         *_umlinux26)
805                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
806                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
807                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
808                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
809                 esac
810
811                 if test "x$enable_kernel_module" = "xyes"; then
812                  if test "x$enable_debug_kernel" = "xno"; then
813                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
814                  fi
815                  OPENAFS_GCC_SUPPORTS_MARCH
816                  AC_SUBST(P5PLUS_KOPTS)
817                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
818                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
819                  OPENAFS_GCC_SUPPORTS_NO_COMMON
820                  OPENAFS_GCC_SUPPORTS_PIPE
821                  AC_SUBST(LINUX_GCC_KOPTS)
822
823                  dnl Setup the kernel build environment
824                  LINUX_KBUILD_USES_EXTRA_CFLAGS
825                  LINUX_KERNEL_COMPILE_WORKS
826
827                  dnl Check for header files
828                  AC_CHECK_LINUX_HEADER([config.h])
829                  AC_CHECK_LINUX_HEADER([completion.h])
830                  AC_CHECK_LINUX_HEADER([exportfs.h])
831                  AC_CHECK_LINUX_HEADER([freezer.h])
832                  AC_CHECK_LINUX_HEADER([key-type.h])
833                  AC_CHECK_LINUX_HEADER([semaphore.h])
834                  AC_CHECK_LINUX_HEADER([seq_file.h])
835
836                  dnl Type existence checks
837                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
838                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
839
840                  dnl Check for structure elements
841                  AC_CHECK_LINUX_STRUCT([address_space_operations],
842                                        [write_begin], [fs.h])
843                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
844                                        [backing-dev.h])
845                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
846                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
847                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
848                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
849                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
850                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
851                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
852                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
853                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
854                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
855                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
856                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
857                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
858                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
859                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
860                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
861                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
862                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
863                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
864                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
865                                        [fs.h])
866                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
867                                        [fs.h])
868                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
869                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
870                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
871                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
872                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
873                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
874                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
875                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
876                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
877                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
878                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
879
880                  dnl Check for typed structure elements
881                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
882                                              [buf], [fs.h])
883
884                  dnl Function existence checks
885
886                  AC_CHECK_LINUX_FUNC([bdi_init],
887                                      [#include <linux/backing-dev.h>],
888                                      [bdi_init(NULL);])
889                  AC_CHECK_LINUX_FUNC([PageChecked],
890                                      [#include <linux/mm.h>
891 #include <linux/page-flags.h>],
892                                      [struct page *_page;
893                                       int bchecked = PageChecked(_page);])
894                  AC_CHECK_LINUX_FUNC([PageFsMisc],
895                                      [#include <linux/mm.h>
896 #include <linux/page-flags.h>],
897                                      [struct page *_page;
898                                       int bchecked = PageFsMisc(_page);])
899                  AC_CHECK_LINUX_FUNC([clear_inode],
900                                      [#include <linux/fs.h>],
901                                      [clear_inode(NULL);])
902                  AC_CHECK_LINUX_FUNC([current_kernel_time],
903                                      [#include <linux/time.h>],
904                                      [struct timespec s;
905                                       s = current_kernel_time();])
906                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
907                                      [#include <linux/fs.h>],
908                                      [d_alloc_anon(NULL);])
909                  AC_CHECK_LINUX_FUNC([d_count],
910                                      [#include <linux/dcache.h>],
911                                      [d_count(NULL);])
912                  AC_CHECK_LINUX_FUNC([d_make_root],
913                                      [#include <linux/fs.h>],
914                                      [d_make_root(NULL);])
915                  AC_CHECK_LINUX_FUNC([do_sync_read],
916                                      [#include <linux/fs.h>],
917                                      [do_sync_read(NULL, NULL, 0, NULL);])
918                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
919                                      [#include <linux/sched.h>],
920                                      [pid_t p; find_task_by_pid(p);])
921                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
922                                      [#include <linux/fs.h>],
923                                      [generic_file_aio_read(NULL,NULL,0,0);])
924                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
925                                      [#include <linux/pagemap.h>],
926                                      [grab_cache_page_write_begin(NULL, 0, 0);])
927                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
928                                      [#include <linux/list.h>],
929                                      [hlist_unhashed(0);])
930                  AC_CHECK_LINUX_FUNC([i_size_read],
931                                      [#include <linux/fs.h>],
932                                      [i_size_read(NULL);])
933                  AC_CHECK_LINUX_FUNC([inode_setattr],
934                                      [#include <linux/fs.h>],
935                                      [inode_setattr(NULL, NULL);])
936                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
937                                      [#include <linux/net.h>],
938                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
939                  AC_CHECK_LINUX_FUNC([page_follow_link],
940                                      [#include <linux/fs.h>],
941                                      [page_follow_link(0,0);])
942                  AC_CHECK_LINUX_FUNC([page_offset],
943                                      [#include <linux/pagemap.h>],
944                                      [page_offset(NULL);])
945                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
946                                      [#include <linux/pagevec.h>],
947                                      [__pagevec_lru_add_file(NULL);])
948                  AC_CHECK_LINUX_FUNC([path_lookup],
949                                      [#include <linux/fs.h>
950                                       #include <linux/namei.h>],
951                                      [path_lookup(NULL, 0, NULL);])
952                  AC_CHECK_LINUX_FUNC([proc_create],
953                                      [#include <linux/proc_fs.h>],
954                                      [proc_create(NULL, 0, NULL, NULL);])
955                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
956                                      [#include <linux/rcupdate.h>],
957                                      [rcu_read_lock();])
958                  AC_CHECK_LINUX_FUNC([set_nlink],
959                                      [#include <linux/fs.h>],
960                                      [set_nlink(NULL, 1);])
961                  AC_CHECK_LINUX_FUNC([sock_create_kern],
962                                      [#include <linux/net.h>],
963                                      [sock_create_kern(0, 0, 0, NULL);])
964                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
965                                      [#include <linux/splice.h>],
966                                      [splice_direct_to_actor(NULL,NULL,NULL);])
967                  AC_CHECK_LINUX_FUNC([svc_addr_in],
968                                      [#include <linux/sunrpc/svc.h>],
969                                      [svc_addr_in(NULL);])
970                  AC_CHECK_LINUX_FUNC([zero_user_segments],
971                                      [#include <linux/highmem.h>],
972                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
973                  AC_CHECK_LINUX_FUNC([noop_fsync],
974                                      [#include <linux/fs.h>],
975                                      [void *address = &noop_fsync; printk("%p\n", address)];)
976                  AC_CHECK_LINUX_FUNC([kthread_run],
977                                      [#include <linux/kernel.h>
978                                       #include <linux/kthread.h>],
979                                      [kthread_run(NULL, NULL, "test");])
980
981                  dnl Consequences - things which get set as a result of the
982                  dnl                above tests
983                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
984                        [AC_DEFINE([AFS_NONFSTRANS], 1,
985                                   [define to disable the nfs translator])])
986
987                  dnl Assorted more complex tests
988                  LINUX_AIO_NONVECTOR
989                  LINUX_EXPORTS_PROC_ROOT_FS
990                  LINUX_KMEM_CACHE_INIT
991                  LINUX_HAVE_KMEM_CACHE_T
992                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
993                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
994                  LINUX_D_PATH_TAKES_STRUCT_PATH
995                  LINUX_NEW_EXPORT_OPS
996                  LINUX_INODE_SETATTR_RETURN_TYPE
997                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
998                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
999                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1000                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1001                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1002                  LINUX_DOP_D_DELETE_TAKES_CONST
1003                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1004                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1005                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1006                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1007                  LINUX_AOP_WRITEBACK_CONTROL
1008                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1009                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1010                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1011                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1012                  LINUX_KERNEL_SOCK_CREATE
1013                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1014                  LINUX_NEED_RHCONFIG
1015                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1016                  LINUX_EXPORTS_TASKLIST_LOCK
1017                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1018                  LINUX_STATFS_TAKES_DENTRY
1019                  LINUX_REFRIGERATOR
1020                  LINUX_HAVE_TRY_TO_FREEZE
1021                  LINUX_LINUX_KEYRING_SUPPORT
1022                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1023                  LINUX_KEY_ALLOC_NEEDS_CRED
1024                  LINUX_INIT_WORK_HAS_DATA
1025                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1026                  LINUX_HAVE_DCACHE_LOCK
1027                  LINUX_D_COUNT_IS_INT
1028                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1029                  LINUX_IOP_CREATE_TAKES_UMODE_T
1030                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1031                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1032                  LINUX_DENTRY_OPEN_TAKES_PATH
1033                  LINUX_D_ALIAS_IS_HLIST
1034                  LINUX_HLIST_ITERATOR_NO_NODE
1035                  LINUX_IOP_I_CREATE_TAKES_BOOL
1036                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1037                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1038
1039                  dnl If we are guaranteed that keyrings will work - that is
1040                  dnl  a) The kernel has keyrings enabled
1041                  dnl  b) The code is new enough to give us a key_type_keyring
1042                  dnl then we just disable syscall probing unless we've been
1043                  dnl told otherwise
1044
1045                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1046                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1047                           [enable_linux_syscall_probing="no"],
1048                           [enable_linux_syscall_probing="yes"])
1049                  ])
1050
1051                  dnl Syscall probing needs a few tests of its own, and just
1052                  dnl won't work if the kernel doesn't export init_mm
1053                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1054                    LINUX_EXPORTS_INIT_MM
1055                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1056                      AC_MSG_ERROR(
1057                        [Can't do syscall probing without exported init_mm])
1058                    ])
1059                    LINUX_EXPORTS_SYS_CHDIR
1060                    LINUX_EXPORTS_SYS_OPEN
1061                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1062                              [define to enable syscall table probes])
1063                  ])
1064
1065                  dnl Packaging and SMP build
1066                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1067                    LINUX_WHICH_MODULES
1068                  else
1069                    AC_SUBST(MPS,'SP')
1070                  fi
1071
1072                  dnl Syscall probing
1073                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1074                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1075                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1076                    ])
1077                    ac_cv_linux_exports_sys_call_table=no
1078                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1079                      ac_cv_linux_exports_ia32_sys_call_table=yes
1080                    fi
1081                  else
1082                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1083                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1084                    LINUX_EXPORTS_SYS_CALL_TABLE
1085                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1086                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1087                          linux_syscall_method=none
1088                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1089                             linux_syscall_method=scan
1090                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1091                                linux_syscall_method=scan_with_kallsyms_address
1092                             fi
1093                          fi
1094                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1095                             linux_syscall_method=kallsyms_symbol
1096                          fi
1097                          if test "x$linux_syscall_method" = "xnone"; then
1098                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1099                             linux_syscall_method=scan
1100                          fi
1101                    fi
1102                  fi
1103                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1104                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1105                  fi
1106                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1107                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1108                  fi
1109                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1110                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1111                  else
1112                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1113                  fi
1114                 :
1115                 fi
1116 dnl Linux-only, but just enable always.
1117                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1118 esac
1119
1120 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1121     [ac_cv_sync_fetch_and_add],
1122     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1123                     [ac_cv_sync_fetch_and_add=yes],
1124                     [ac_cv_sync_fetch_and_add=no])
1125 ])
1126 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1127       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1128                 [define if your C compiler has __sync_add_and_fetch])])
1129
1130 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1131     [ac_cv_sockaddr_len],
1132     [AC_TRY_COMPILE( [#include <sys/types.h>
1133 #include <sys/socket.h>],
1134                      [struct sockaddr *a; a->sa_len=0;],
1135                      [ac_cv_sockaddr_len=yes],
1136                      [ac_cv_sockaddr_len=no])
1137 ])
1138 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1139       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1140                  [define if you struct sockaddr sa_len])])
1141
1142 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1143         echo Skipping library tests because they confuse Irix.
1144 else
1145   AC_SEARCH_LIBS([socket], [socket inet])
1146   AC_SEARCH_LIBS([connect], [nsl])
1147   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1148
1149   dnl darwin wants it, aix hates it
1150   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1151   AC_TRY_COMPILE([
1152   #include <stdlib.h>
1153   #include <stdio.h>
1154   #include <sys/types.h>
1155   #include <sys/socket.h>
1156   #include <netinet/in.h>
1157   #include <arpa/inet.h>
1158   #include <arpa/nameser.h>
1159   #include <arpa/nameser_compat.h>
1160   #include <resolv.h>
1161   ], [static int i; i = 0;],
1162   [AC_MSG_RESULT(yes)
1163    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1164   [AC_MSG_RESULT(no)
1165    ])
1166
1167   openafs_save_libs="$LIBS"
1168   AC_MSG_CHECKING([for res_search])
1169   AC_FUNC_RES_SEARCH
1170
1171   if test "$ac_cv_func_res_search" = no; then
1172       for lib in dns nsl resolv; do
1173         if test "$ac_cv_func_res_search" != yes; then
1174           LIBS="-l$lib $LIBS"
1175           AC_FUNC_RES_SEARCH
1176           LIBS="$openafs_save_libs"
1177         fi
1178       done    
1179       if test "$ac_cv_func_res_search" = yes; then
1180         LIB_AFSDB="-l$lib"
1181         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1182         AC_MSG_RESULT([yes, in lib$lib])
1183       else
1184         AC_MSG_RESULT(no)
1185       fi
1186   else
1187     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1188     AC_MSG_RESULT(yes)
1189   fi
1190   
1191 fi
1192 XLIBS="$LIB_AFSDB $XLIBS"
1193
1194 AC_CHECK_RESOLV_RETRANS
1195
1196 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1197     [ac_cv_setsockopt_iprecverr],
1198     [AC_TRY_COMPILE( [
1199 #include <sys/types.h>
1200 #include <sys/socket.h>
1201 #include <netinet/in.h>],
1202 [int on=1;
1203 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1204         [ac_cv_setsockopt_iprecverr=yes],
1205         [ac_cv_setsockopt_iprecverr=no])])
1206
1207 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1208       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1209                  [define if we can receive socket errors via IP_RECVERR])])
1210
1211 PTHREAD_LIBS=error
1212 if test "x$MKAFS_OSTYPE" = OBSD; then
1213         PTHREAD_LIBS="-pthread"
1214 fi
1215 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1216         PTHREAD_LIBS="-pthread"
1217 fi
1218 if test "x$PTHREAD_LIBS" = xerror; then
1219         AC_CHECK_LIB(pthread, pthread_attr_init,
1220                 PTHREAD_LIBS="-lpthread")
1221 fi
1222 if test "x$PTHREAD_LIBS" = xerror; then
1223         AC_CHECK_LIB(pthreads, pthread_attr_init,
1224                 PTHREAD_LIBS="-lpthreads")
1225 fi
1226 if test "x$PTHREAD_LIBS" = xerror; then
1227         AC_CHECK_LIB(c_r, pthread_attr_init,
1228                 PTHREAD_LIBS="-lc_r")
1229 fi
1230 if test "x$PTHREAD_LIBS" = xerror; then
1231         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1232 fi
1233 if test "x$PTHREAD_LIBS" = xerror; then
1234         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1235         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1236                 PTHREAD_LIBS="-lpthread")
1237 fi
1238 if test "x$PTHREAD_LIBS" = xerror; then
1239         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1240 fi
1241 AC_SUBST(PTHREAD_LIBS)
1242
1243 HOST_CPU="$host_cpu"
1244
1245 if test "x$with_bsd_kernel_headers" != "x"; then
1246         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1247 else
1248         BSD_KERNEL_PATH="/usr/src/sys"
1249 fi
1250
1251 if test "x$with_bsd_kernel_build" != "x"; then
1252         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1253 else
1254         case $AFS_SYSNAME in
1255                 *_fbsd_*)
1256                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1257                         ;;
1258                 *_nbsd*)
1259                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1260         esac
1261 fi
1262
1263 # Fast restart
1264 if test "$enable_supergroups" = "yes"; then
1265         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1266 fi
1267
1268 if test "$enable_bitmap_later" = "yes"; then
1269         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1270 fi
1271
1272 if test "$enable_unix_sockets" = "yes"; then
1273         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1274         USE_UNIX_SOCKETS="yes"
1275 else
1276         USE_UNIX_SOCKETS="no"
1277 fi
1278 AC_SUBST(USE_UNIX_SOCKETS)
1279
1280 if test "$enable_namei_fileserver" = "yes"; then
1281         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1282         VFSCK=""
1283 else
1284         if test "$enable_namei_fileserver" = "default"; then
1285                 case $host in
1286                         *-solaris2.10*)
1287                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1288                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1289                                 VFSCK=""
1290                                 ;;
1291                         *-solaris2.11*)
1292                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1293                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1294                                 VFSCK=""
1295                                 ;;
1296                         *)
1297                                 VFSCK="vfsck"
1298                                 ;;
1299                 esac
1300         else
1301                 VFSCK="vfsck"
1302         fi
1303 fi
1304
1305 dnl check for tivoli
1306 AC_MSG_CHECKING(for tivoli tsm butc support)
1307 XBSA_CFLAGS=""
1308 if test "$enable_tivoli_tsm" = "yes"; then
1309         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1310         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1311         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1312         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1313
1314         if test -r "$XBSADIR3/dsmapifp.h"; then
1315                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1316                 XBSA_XLIBS="-ldl"
1317                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1318         elif test -r "$XBSADIR4/dsmapifp.h"; then
1319                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1320                 XBSA_XLIBS="-ldl"
1321                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1322         elif test -r "$XBSADIR1/xbsa.h"; then
1323                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1324                 XBSA_XLIBS=""
1325                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1326         elif test -r "$XBSADIR2/xbsa.h"; then
1327                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1328                 XBSA_XLIBS=""
1329                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1330         else
1331                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1332         fi
1333 else
1334         AC_MSG_RESULT([no])
1335 fi
1336 AC_SUBST(XBSA_CFLAGS)
1337 AC_SUBST(XBSA_XLIBS) 
1338
1339 dnl checks for header files.
1340 AC_HEADER_STDC
1341 AC_HEADER_SYS_WAIT
1342 AC_HEADER_DIRENT
1343 AC_CHECK_HEADERS([ \
1344                    arpa/inet.h \
1345                    arpa/nameser.h \
1346                    curses.h\
1347                    direct.h \
1348                    errno.h \
1349                    fcntl.h \
1350                    grp.h \
1351                    math.h \
1352                    mntent.h \
1353                    ncurses.h \
1354                    ncurses/ncurses.h \
1355                    netdb.h \
1356                    netinet/in.h \
1357                    pthread_np.h \
1358                    pwd.h \
1359                    regex.h \
1360                    security/pam_appl.h \
1361                    signal.h \
1362                    stdint.h \
1363                    stdio_ext.h \
1364                    stdlib.h \
1365                    string.h \
1366                    strings.h \
1367                    sys/bitypes.h \
1368                    sys/bswap.h \
1369                    sys/dk.h \
1370                    sys/fcntl.h \
1371                    sys/file.h \
1372                    sys/fs_types.h \
1373                    sys/fstyp.h \
1374                    sys/ioctl.h \
1375                    sys/ipc.h \
1376                    sys/lockf.h \
1377                    sys/map.h \
1378                    sys/mount.h \
1379                    sys/mntent.h \
1380                    sys/mnttab.h \
1381                    sys/pag.h \
1382                    sys/param.h \
1383                    sys/resource.h \
1384                    sys/select.h \
1385                    sys/statfs.h \
1386                    sys/statvfs.h \
1387                    sys/socket.h \
1388                    sys/sysctl.h \
1389                    sys/time.h \
1390                    sys/types.h \
1391                    sys/uio.h \
1392                    sys/un.h \
1393                    sys/vfs.h \
1394                    syslog.h \
1395                    termios.h \
1396                    time.h \
1397                    ucontext.h \
1398                    unistd.h \
1399                    windows.h \
1400                 ])
1401
1402 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1403 #ifdef HAVE_NETINET_IN_H
1404 # include <netinet/in.h>
1405 #endif])
1406
1407 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1408 #ifdef HAVE_SYS_SOCKET_H
1409 # include <sys/socket.h>
1410 #endif])
1411
1412 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1413 #ifdef HAVE_SYS_SOCKET_H
1414 # include <sys/socket.h>
1415 #endif
1416 #ifdef HAVE_NETINET_IN_H
1417 # include <netinet/in.h>
1418 #endif
1419 #ifdef HAVE_NET_IF_H
1420 # include <net/if.h>
1421 #endif])
1422
1423 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1424 #ifdef HAVE_SECURITY_PAM_APPL_H
1425 # include <security/pam_appl.h>
1426 #endif])
1427
1428 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1429
1430 AC_CHECK_TYPES([fsblkcnt_t],,,[
1431 #include <sys/types.h>
1432 #ifdef HAVE_SYS_BITYPES_H
1433 #include <sys/bitypes.h>
1434 #endif
1435 #ifdef HAVE_SYS_STATFS_H
1436 #include <sys/statfs.h>
1437 #endif
1438 #ifdef HAVE_SYS_STATVFS_H
1439 #include <sys/statvfs.h>
1440 #endif
1441 ])
1442
1443 dnl see what struct stat has for timestamps
1444 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1445
1446 dnl check for curses-lib
1447 AS_IF([test "x$enable_gtx" != "xno"],
1448       [save_LIBS=$LIBS
1449       AC_CHECK_LIB( [ncurses], [setupterm],
1450       [LIB_curses=-lncurses],
1451         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1452           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1453       ])
1454       LIBS=$save_LIBS
1455       AC_SUBST(LIB_curses)])
1456         
1457 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1458
1459 if test "$enable_debug_locks" = yes; then
1460         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1461 fi
1462
1463 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1464 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1465         case $AFS_SYSNAME in
1466         sgi_*)
1467                 HAVE_PAM="no"
1468                 ;;
1469         *)
1470                 HAVE_PAM="yes"
1471                 ;;
1472         esac
1473 else
1474         HAVE_PAM="no"
1475 fi
1476 AC_SUBST(HAVE_PAM)
1477
1478 if test "$enable_login" = yes; then
1479         BUILD_LOGIN="yes"
1480 else
1481         BUILD_LOGIN="no"
1482 fi
1483 AC_SUBST(BUILD_LOGIN)
1484
1485 if test "$enable_uss" = yes; then
1486         BUILD_USS="yes"
1487 else
1488         BUILD_USS="no"
1489 fi
1490 AC_SUBST(BUILD_USS)
1491
1492 if test "$enable_kauth" = yes; then
1493         INSTALL_KAUTH="yes"
1494 else
1495         INSTALL_KAUTH="no"
1496 fi
1497 AC_SUBST(INSTALL_KAUTH)
1498
1499 AC_CHECK_FUNCS([ \
1500         arc4random \
1501         fcntl \
1502         fseeko64 \
1503         ftello64 \
1504         getcwd \
1505         getegid \
1506         geteuid \
1507         getgid \
1508         getuid \
1509         getrlimit \
1510         issetugid \
1511         mkstemp \
1512         poll \
1513         pread \
1514         preadv \
1515         preadv64 \
1516         pwrite \
1517         pwritev \
1518         pwritev64 \
1519         regcomp \
1520         regerror \
1521         regexec \
1522         setitimer \
1523         setvbuf \
1524         sigaction \
1525         strcasestr \
1526         strerror \
1527         sysconf \
1528         sysctl \
1529         tdestroy \
1530         timegm \
1531 ])
1532
1533 OPENAFS_ROKEN()
1534 OPENAFS_C_ATTRIBUTE()
1535
1536 dnl Functions that Heimdal's libroken provides, but that we
1537 dnl haven't found a need for yet, and so haven't imported
1538 AC_CHECK_FUNCS([ \
1539         chown \
1540         fchown \
1541         gethostname \
1542         lstat \
1543         inet_aton \
1544         inet_ntop \
1545         inet_pton \
1546         putenv \
1547         readv \
1548         setenv \
1549         strdup \
1550         strftime \
1551         strndup \
1552         strsep \
1553         unsetenv \
1554 ])
1555
1556 dnl Functions that are in objects that we always build from libroken
1557 AC_CHECK_FUNCS([ \
1558         asprintf \
1559         asnprintf \
1560         vasprintf \
1561         vasnprintf \
1562         vsnprintf \
1563         snprintf \
1564 ])
1565
1566 dnl Functions that we're going to try and get from libroken
1567 AC_REPLACE_FUNCS([ \
1568         daemon \
1569         ecalloc \
1570         emalloc \
1571         erealloc \
1572         err \
1573         errx \
1574         flock \
1575         getdtablesize \
1576         getopt \
1577         getprogname \
1578         gettimeofday \
1579         localtime_r \
1580         mkstemp \
1581         setenv \
1582         setprogname \
1583         strcasecmp \
1584         strlcat \
1585         strnlen \
1586         strlcpy \
1587         strsep \
1588         tdelete \
1589         tfind \
1590         tsearch \
1591         twalk \
1592         unsetenv \
1593         verr \
1594         verrx \
1595         vsyslog \
1596         vwarn \
1597         vwarnx \
1598         warn \
1599         warnx \
1600 ])
1601
1602 dnl Headers that we're going to try and get from libroken
1603 AC_CHECK_HEADERS([ \
1604         err.h \
1605         search.h \
1606 ])
1607
1608 AC_CHECK_DECLS([h_errno], [], [], [
1609 #include <sys/types.h>
1610 #ifdef HAVE_NETDB_H
1611 #include <netdb.h>
1612 #endif
1613 ])
1614
1615 AC_HEADER_TIME
1616
1617 ROKEN_HEADERS=
1618 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1619       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1620       [])
1621 AC_SUBST(ROKEN_HEADERS)
1622
1623 dnl Stuff that's harder ...
1624 AC_MSG_CHECKING([for bswap16])
1625 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1626 #ifdef HAVE_SYS_TYPES_H
1627 #include <sys/types.h>
1628 #endif
1629 #ifdef HAVE_SYS_BSWAP_H
1630 #include <sys/bswap.h>
1631 #endif
1632 ],
1633 [short a, b; b = bswap16(a); ])],
1634 [AC_MSG_RESULT(yes)
1635  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1636 ],
1637 [AC_MSG_RESULT(no)])
1638
1639 AC_MSG_CHECKING([for bswap32])
1640 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1641 #include <sys/types.h>
1642 #endif
1643 #ifdef HAVE_SYS_BSWAP_H
1644 #include <sys/bswap.h>
1645 #endif
1646 ],
1647 [int a, b; b = bswap32(a); ])],
1648 [AC_MSG_RESULT(yes)
1649  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1650 ],
1651 [AC_MSG_RESULT(no)])
1652
1653 case $AFS_SYSNAME in
1654 *hp_ux* | *hpux*)
1655    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1656    ;;
1657 *)
1658    AC_MSG_CHECKING([for positional I/O])
1659    if test "$ac_cv_func_pread" = "yes" && \
1660            test "$ac_cv_func_pwrite" = "yes"; then
1661       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1662       AC_MSG_RESULT(yes)
1663    else
1664      AC_MSG_RESULT(no)
1665    fi
1666    AC_MSG_CHECKING([for vectored positional I/O])
1667    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1668                "$ac_cv_func_pwritev" = "yes" -a \
1669                "$ac_cv_func_preadv64" = "yes" -a \
1670                "$ac_cv_func_pwritev64" = "yes"],
1671          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1672           AC_MSG_RESULT(yes)],
1673          [AC_MSG_RESULT(no)])
1674    ;;
1675 esac
1676
1677 AC_MSG_CHECKING([for POSIX regex library])
1678 if test "$ac_cv_header_regex_h" = "yes" && \
1679         test "$ac_cv_func_regcomp" = "yes" && \
1680         test "$ac_cv_func_regexec" = "yes" && \
1681         test "$ac_cv_func_regerror" = "yes"; then
1682     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1683     AC_MSG_RESULT(yes)
1684 else
1685     AC_MSG_RESULT(no)
1686 fi
1687
1688 dnl Look for "non-portable" pthreads functions.
1689 save_LIBS="$LIBS"
1690 LIBS="$LIBS $PTHREAD_LIBS"
1691 AC_CHECK_FUNCS([ \
1692         pthread_set_name_np \
1693         pthread_setname_np \
1694 ])
1695
1696 dnl Sadly, there are three different versions of pthread_setname_np.
1697 dnl Try to cater for all of them.
1698 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1699     AC_MSG_CHECKING([for signature of pthread_setname_np])
1700     AC_TRY_COMPILE([
1701 #include <pthread.h>
1702 #ifdef HAVE_PTHREAD_NP_H
1703 #include <pthread_np.h>
1704 #endif
1705 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1706         AC_MSG_RESULT([three arguments])
1707         pthread_setname_np_args=3], [
1708         AC_TRY_COMPILE([
1709 #include <pthread.h>
1710 #ifdef HAVE_PTHREAD_NP_H
1711 #include <pthread_np.h>
1712 #endif
1713 ], [pthread_setname_np(pthread_self(), "test")], [
1714             AC_MSG_RESULT([two arguments])
1715             pthread_setname_np_args=2], [
1716             AC_TRY_COMPILE([
1717 #include <pthread.h>
1718 #ifdef HAVE_PTHREAD_NP_H
1719 #include <pthread_np.h>
1720 #endif
1721 ], [pthread_setname_np("test")], [
1722                 AC_MSG_RESULT([one argument])
1723                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1724 ])
1725 ])
1726 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1727 fi
1728 LIBS="$save_LIBS"
1729
1730 openafs_cv_saved_CFLAGS="$CFLAGS"
1731 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1732
1733 AC_TYPE_SIGNAL
1734 OPENAFS_RETSIGTYPE
1735 AC_CHECK_SIZEOF(void *)
1736 AC_CHECK_SIZEOF(unsigned long long)
1737 AC_CHECK_SIZEOF(unsigned long)
1738 AC_CHECK_SIZEOF(unsigned int)
1739 AC_TYPE_INTPTR_T
1740 AC_TYPE_UINTPTR_T
1741 AC_TYPE_SSIZE_T
1742 AC_CHECK_TYPE([sig_atomic_t],[],
1743     [AC_DEFINE([sig_atomic_t], [int],
1744         [Define to int if <signal.h> does not define.])],
1745 [#include <sys/types.h>
1746 #include <signal.h>])
1747 AC_CHECK_TYPE([socklen_t],[],
1748     [AC_DEFINE([socklen_t], [int],
1749         [Define to int if <sys/socket.h> does not define.])],
1750 [#include <sys/types.h>
1751 #include <sys/socket.h>])
1752 AC_CHECK_TYPES(off64_t)
1753 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1754 AC_CHECK_TYPES([struct winsize], [], [], [
1755 #ifdef HAVE_TERMIOS_H
1756 # include <termios.h>
1757 #else
1758 # include <sys/termios.h>
1759 #endif
1760 #include <sys/ioctl.h>])
1761 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1762                 struct sockaddr_storage],
1763                [], [], [
1764 #include <sys/types.h>
1765 #include <sys/socket.h>
1766 ])
1767 AC_CHECK_TYPES([sa_family_t], [], [], [
1768 #include <sys/types.h>
1769 #include <sys/socket.h>
1770 ])
1771 AC_CHECK_TYPES([struct addrinfo], [], [], [
1772 #include <sys/types.h>
1773 #ifdef HAVE_NETDB_H
1774 #include <netdb.h>
1775 #endif
1776 ])
1777 AC_CHECK_TYPES([long long], [], [], [])
1778
1779 AC_SIZEOF_TYPE(long)
1780
1781 CFLAGS="$openafs_cv_saved_CFLAGS"
1782
1783 RRA_HEADER_PAM_CONST
1784
1785
1786 dnl Directory PATH handling
1787 if test "x$enable_transarc_paths" = "xyes"  ; then 
1788     afsconfdir=${afsconfdir=/usr/afs/etc}
1789     viceetcdir=${viceetcdir=/usr/vice/etc}
1790     afskerneldir=${afskerneldir=${viceetcdir}}
1791     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1792     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1793     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1794     afsdbdir=${afsdbdir=/usr/afs/db}
1795     afslogsdir=${afslogsdir=/usr/afs/logs}
1796     afslocaldir=${afslocaldir=/usr/afs/local}
1797     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1798     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1799     afsdatadir=${afsdatadir=/usr/vice/etc}
1800 else 
1801     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1802     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1803     afskerneldir=${afskerneldir='${libdir}/openafs'}
1804     afssrvbindir=${afssrvbindir='${bindir}'}
1805     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1806     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1807     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1808     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1809     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1810     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1811     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1812     afsdatadir=${afsdatadir='${datadir}/openafs'}
1813 fi
1814 AC_SUBST(afsconfdir)
1815 AC_SUBST(viceetcdir)
1816 AC_SUBST(afskerneldir)
1817 AC_SUBST(afssrvbindir)
1818 AC_SUBST(afssrvsbindir)
1819 AC_SUBST(afssrvlibexecdir)
1820 AC_SUBST(afsdbdir)
1821 AC_SUBST(afslogsdir)
1822 AC_SUBST(afslocaldir)
1823 AC_SUBST(afsbackupdir)
1824 AC_SUBST(afsbosconfigdir)
1825 AC_SUBST(afsdatadir)
1826
1827 if test "x$enable_kernel_module" = "xyes"; then
1828 ENABLE_KERNEL_MODULE=libafs
1829 fi
1830
1831 if test "x$enable_pthreaded_ubik" = "xyes"; then
1832 ENABLE_PTHREADED_UBIK=yes
1833 fi
1834
1835 AC_SUBST(VFSCK)
1836 AC_SUBST(AFS_SYSNAME)
1837 AC_SUBST(AFS_PARAM_COMMON)
1838 AC_SUBST(ENABLE_KERNEL_MODULE)
1839 AC_SUBST(ENABLE_PTHREADED_UBIK)
1840 AC_SUBST(LIB_AFSDB)
1841 AC_SUBST(LINUX_KERNEL_PATH)
1842 AC_SUBST(LINUX_KERNEL_BUILD)
1843 AC_SUBST(HOST_CPU)
1844 AC_SUBST(BSD_KERNEL_PATH)
1845 AC_SUBST(BSD_KERNEL_BUILD)
1846 AC_SUBST(LINUX_VERSION)
1847 AC_SUBST(MKAFS_OSTYPE)
1848 AC_SUBST(TOP_OBJDIR)
1849 AC_SUBST(TOP_SRCDIR)
1850 AC_SUBST(TOP_INCDIR)
1851 AC_SUBST(TOP_LIBDIR)
1852 AC_SUBST(DEST)
1853 AC_SUBST(DARWIN_INFOFILE)
1854 AC_SUBST(IRIX_BUILD_IP35)
1855 AC_SUBST(HTML_XSL)
1856 AC_SUBST(XSLTPROC)
1857 AC_SUBST(DOCBOOK2PDF)
1858 AC_SUBST(DOCBOOK_STYLESHEETS)
1859
1860 OPENAFS_FUSE
1861 OPENAFS_SWIG
1862
1863 TOP_SRCDIR="${srcdir}/src"
1864 dnl
1865 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1866 dnl
1867 case $TOP_SRCDIR in
1868         /*)
1869                 ;;
1870         *)
1871                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1872                 ;;
1873 esac
1874
1875 TOP_OBJDIR="${SRCDIR_PARENT}"
1876 TOP_INCDIR="${SRCDIR_PARENT}/include"
1877 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1878 if test "${DEST}x" = "x"; then
1879         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1880 fi
1881
1882 if test "x$with_crosstools_dir" != "x"; then
1883         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1884                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1885                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1886                 RXGEN_PATH=$with_crosstools_dir/rxgen
1887         else
1888                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1889                 exit 1
1890         fi
1891 else
1892         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1893         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1894         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1895 fi
1896 AC_SUBST(COMPILE_ET_PATH)
1897 AC_SUBST(CONFIGTOOL_PATH)
1898 AC_SUBST(RXGEN_PATH)
1899
1900 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1901 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1902 AC_SUBST(HELPER_SPLINT)
1903 AC_SUBST(HELPER_SPLINTCFG)
1904
1905 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1906
1907 dnl Check to see if crypt lives in a different library
1908 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1909 AC_SUBST(LIB_crypt)
1910
1911 dnl Check to see if the compiler support labels in structs
1912 AC_MSG_CHECKING(for label support in structs)
1913 AC_TRY_COMPILE([], [
1914 extern void osi_UFSOpen(void);
1915 struct labeltest {
1916    void (*open) (void);
1917 };
1918 struct labeltest struct_labeltest = {
1919    .open       = osi_UFSOpen,
1920 }
1921 ],
1922 [AC_MSG_RESULT(yes)
1923  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1924 ],
1925 [AC_MSG_RESULT(no)
1926 ])
1927
1928 AC_MSG_CHECKING([checking for dirfd])
1929 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1930 #ifdef HAVE_DIRENT_H
1931 #include <dirent.h>
1932 #endif
1933 ]],
1934         [[DIR *d = 0; dirfd(d);]])],
1935         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1936 if test "$ac_rk_have_dirfd" = "yes" ; then
1937         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1938 fi
1939 AC_MSG_RESULT($ac_rk_have_dirfd)
1940
1941 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1942 #ifdef HAVE_DIRENT_H
1943 #include <dirent.h>
1944 #endif])
1945
1946 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
1947 [#ifdef HAVE_SYS_RESOURCE_H
1948 #include <sys/resource.h>
1949 #endif])
1950
1951 dnl Eventually, this will look for the system one, or for OpenSSL
1952 LIB_hcrypto="-lafshcrypto"
1953 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1954 AC_SUBST(LIB_hcrypto)
1955 AC_SUBST(LDFLAGS_hcrypto)
1956
1957 dnl Check for UUID library
1958 AC_CHECK_HEADERS([uuid/uuid.h])
1959 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1960 AC_CHECK_FUNCS([uuid_generate])
1961 ])
1962
1963