opr: fix generated target
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([pam],
79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
80     ,
81     [enable_pam="yes"])
82 AC_ARG_ENABLE([namei-fileserver],
83     [AS_HELP_STRING([--enable-namei-fileserver],
84         [force compilation of namei fileserver in preference to inode
85          fileserver])],
86     , 
87     [enable_namei_fileserver="default"])
88 AC_ARG_ENABLE([supergroups],
89     [AS_HELP_STRING([--enable-supergroups],
90         [enable support for nested pts groups])],
91     , 
92     [enable_supergroups="no"])
93 AC_ARG_ENABLE([bitmap-later],
94     [AS_HELP_STRING([--enable-bitmap-later],
95         [enable fast startup of file server by not reading bitmap till
96          needed])],
97     , 
98     [enable_bitmap_later="no"])
99 AC_ARG_ENABLE([unix-sockets],
100     [AS_HELP_STRING([--disable-unix-sockets],
101         [disable use of unix domain sockets for fssync (defaults to enabled)])],
102     ,
103     [enable_unix_sockets="yes"])
104 AC_ARG_ENABLE([tivoli-tsm],
105     [AS_HELP_STRING([--enable-tivoli-tsm],
106         [enable use of the Tivoli TSM API libraries for butc support])],
107     , 
108     [enable_tivoli_tsm="no"])
109 AC_ARG_ENABLE([pthreaded-ubik],
110     [AS_HELP_STRING([--enable-pthreaded-ubik],
111         [enable installation of pthreaded ubik applications (defaults to
112          disabled)])],
113     ,
114     [enable_pthreaded_ubik="no"])
115
116 dnl Kernel module build options.
117 AC_ARG_WITH([linux-kernel-headers],
118     [AS_HELP_STRING([--with-linux-kernel-headers=path],
119         [use the kernel headers found at path (optional, defaults to
120          /usr/src/linux-2.4, then /usr/src/linux)])])
121 AC_ARG_WITH([linux-kernel-build],
122     [AS_HELP_STRING([--with-linux-kernel-build=path],
123         [use the kernel build found at path(optional, defaults to 
124         /usr/src/linux-2.4, then /usr/src/linux)])])
125 AC_ARG_WITH([bsd-kernel-headers],
126     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
127         [use the kernel headers found at path (optional, defaults to
128          /usr/src/sys)])])
129 AC_ARG_WITH([bsd-kernel-build],
130     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
131         [use the kernel build found at path (optional, defaults to
132          KSRC/i386/compile/GENERIC)])])
133 AC_ARG_WITH([linux-kernel-packaging],
134     [AS_HELP_STRING([--with-linux-kernel-packaging],
135         [use standard naming conventions to aid Linux kernel build packaging
136          (disables MPS, sets the kernel module name to openafs.ko, and
137          installs kernel modules into the standard Linux location)])],
138     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
139      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
140     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
141 AC_ARG_ENABLE([kernel-module],
142     [AS_HELP_STRING([--disable-kernel-module],
143         [disable compilation of the kernel module (defaults to enabled)])],
144     , 
145     [enable_kernel_module="yes"])
146 AC_ARG_ENABLE([redhat-buildsys],
147     [AS_HELP_STRING([--enable-redhat-buildsys],
148         [enable compilation of the redhat build system kernel (defaults to
149          disabled)])],
150     ,
151     [enable_redhat_buildsys="no"])
152
153 dnl Installation locations.
154 AC_ARG_ENABLE([transarc-paths],
155     [AS_HELP_STRING([--enable-transarc-paths],
156         [use Transarc style paths like /usr/afs and /usr/vice])],
157     , 
158     [enable_transarc_paths="no"])
159
160 dnl Optimization and debugging flags.
161 AC_ARG_ENABLE([strip-binaries],
162     [AS_HELP_STRING([--disable-strip-binaries],
163         [disable stripping of symbol information from binaries (defaults to
164          enabled)])],
165     ,
166     [enable_strip_binaries="maybe"])
167 AC_ARG_ENABLE([debug],
168     [AS_HELP_STRING([--enable-debug],
169         [enable compilation of the user space code with debugging information
170          (defaults to disabled)])],
171     , 
172     [enable_debug="no"])
173 AC_ARG_ENABLE([optimize],
174     [AS_HELP_STRING([--disable-optimize],
175         [disable optimization for compilation of the user space code (defaults
176          to enabled)])],
177     , 
178     [enable_optimize="yes"])
179 AC_ARG_ENABLE([warnings],
180     [AS_HELP_STRING([--enable-warnings],
181         [enable compilation warnings when building with gcc (defaults to
182          disabled)])],
183     ,
184     [enable_warnings="no"])
185 AC_ARG_ENABLE([checking],
186     [AS_HELP_STRING([--enable-checking],
187         [turn compilation warnings into errors when building with gcc (defaults
188          to disabled)])],
189     [enable_checking="$enableval"],
190     [enable_checking="no"])
191 AC_ARG_ENABLE([debug-kernel],
192     [AS_HELP_STRING([--enable-debug-kernel],
193         [enable compilation of the kernel module with debugging information
194          (defaults to disabled)])],
195     ,
196     [enable_debug_kernel="no"])
197 AC_ARG_ENABLE([optimize-kernel],
198     [AS_HELP_STRING([--disable-optimize-kernel],
199         [disable compilation of the kernel module with optimization (defaults
200          based on platform)])],
201     , 
202     [enable_optimize_kernel="yes"])
203 AC_ARG_ENABLE([debug-lwp],
204     [AS_HELP_STRING([--enable-debug-lwp],
205         [enable compilation of the LWP code with debugging information
206          (defaults to disabled)])],
207     ,
208     [enable_debug_lwp="no"])
209 AC_ARG_ENABLE([optimize-lwp],
210     [AS_HELP_STRING([--disable-optimize-lwp],
211         [disable optimization for compilation of the LWP code (defaults to
212          enabled)])],
213     ,
214     [enable_optimize_lwp="yes"])
215 AC_ARG_ENABLE([debug-pam],
216     [AS_HELP_STRING([--enable-debug-pam],
217         [enable compilation of the PAM code with debugging information
218          (defaults to disabled)])],
219     ,
220     [enable_debug_pam="no"])
221 AC_ARG_ENABLE([optimize-pam],
222     [AS_HELP_STRING([--disable-optimize-pam],
223         [disable optimization for compilation of the PAM code (defaults to
224          enabled)])],
225     ,
226     [enable_optimize_pam="yes"])
227 AC_ARG_ENABLE([linux-syscall-probing],
228     [AS_HELP_STRING([--enable-linux-syscall-probing],
229         [enable Linux syscall probing (defaults to autodetect)])],
230     ,
231     [enable_linux_syscall_probing="maybe"])
232     
233 AC_ARG_WITH([xslt-processor],
234         AS_HELP_STRING([--with-xslt-processor=ARG],
235         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
236         [XSLTPROC="$withval"],
237         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
238
239 AC_ARG_WITH([html-xsl], 
240         AS_HELP_STRING([--with-html-xsl],
241         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
242         [HTML_XSL="$withval"],
243         [HTML_XSL="html/chunk.xsl"])
244
245 AC_ARG_WITH([docbook2pdf],
246         AS_HELP_STRING([--with-docbook2pdf=ARG],
247         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
248         [DOCBOOK2PDF="$withval"],
249         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
250
251 AC_ARG_WITH([docbook-stylesheets],
252         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
253         [location of DocBook stylesheets (default is to search a set of likely paths)]),
254         [DOCBOOK_STYLESHEETS="$withval"],
255         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
256         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
257                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
258         fi)
259
260 enable_login="no"
261
262 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
263 dnl documentation build.
264 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
265
266 dnl weird ass systems
267 dnl AC_AIX
268 AC_ISC_POSIX
269 dnl AC_MINIX
270
271 dnl Various compiler setup.
272 AC_TYPE_PID_T
273 AC_TYPE_SIZE_T
274
275 dnl Checks for programs.
276 AC_PROG_INSTALL
277 AC_PROG_LN_S
278 AC_PROG_RANLIB
279 AC_PROG_YACC
280 AM_PROG_LEX
281 dnl if we are flex, be lex-compatible
282 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
283
284 OPENAFS_FORCE_ABS_INSTALL
285 OPENAFS_CHECK_BIGENDIAN
286 OPENAFS_PRINTF_TAKES_Z_LEN
287
288 AC_MSG_CHECKING(your OS)
289 system=$host
290 case $system in
291         *-linux*)
292
293                 MKAFS_OSTYPE=LINUX
294                 if test "x$enable_redhat_buildsys" = "xyes"; then
295                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
296                 fi
297                 if test "x$enable_kernel_module" = "xyes"; then
298                  if test "x$with_linux_kernel_headers" != "x"; then
299                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
300                  else
301                    LINUX_KERNEL_PATH="/lib/modules/`uname -r`/source"
302                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
303                      LINUX_KERNEL_PATH="/lib/modules/`uname -r`/build"
304                    fi
305                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
306                      LINUX_KERNEL_PATH="/usr/src/linux-2.4"
307                    fi
308                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
309                      LINUX_KERNEL_PATH="/usr/src/linux"
310                    fi
311                  fi
312                  if test "x$with_linux_kernel_build" != "x"; then
313                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
314                  else
315                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
316                  fi
317                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
318                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
319                    LINUX_VERSION="$linux_kvers"
320                  else
321                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
322                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
323                      LINUX_VERSION="$linux_kvers"
324                    else
325                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
326                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
327                        if test "x$linux_kvers" = "x"; then
328                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
329                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
330                            if test "x$linux_kvers" = "x"; then
331                              AC_MSG_ERROR(Linux headers lack version definition [2])
332                              exit 1
333                            else
334                              LINUX_VERSION="$linux_kvers"
335                            fi
336                          else
337                            AC_MSG_ERROR(Linux headers lack version definition)
338                            exit 1
339                          fi
340                        else
341                          LINUX_VERSION="$linux_kvers"
342                        fi
343                      else
344                        enable_kernel_module="no"
345                      fi
346                    fi
347                  fi
348                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
349                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
350                      enable_kernel_module="no"
351                  fi
352                  if test "x$enable_kernel_module" = "xno"; then
353                   if test "x$with_linux_kernel_headers" != "x"; then
354                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
355                    exit 1
356                   else
357                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
358                   fi
359                  fi
360                  dnl do we need to determine SUBARCH from autoconf.h
361                  SUBARCH=default
362                 fi
363                 AC_MSG_RESULT(linux)
364                 if test "x$enable_kernel_module" = "xyes"; then
365                  case "$LINUX_VERSION" in
366                   2.2.*) AFS_SYSKVERS=22 ;;
367                   2.4.*) AFS_SYSKVERS=24 ;;
368                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
369                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
370                  esac
371                 fi
372                 ;;
373         *-solaris*)
374                 MKAFS_OSTYPE=SOLARIS
375                 AC_MSG_RESULT(sun4)
376                 AC_PATH_PROG(SOLARISCC, [cc], ,
377                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin])
378                 SOLARIS_UFSVFS_HAS_DQRWLOCK
379                 SOLARIS_FS_HAS_FS_ROLLED
380                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
381                 ;;
382         *-sunos*)
383                 MKAFS_OSTYPE=SUNOS
384                 enable_kernel_module=no
385                 AC_MSG_RESULT(sun4)
386                 ;;
387         *-hpux*)
388                 MKAFS_OSTYPE=HPUX
389                 AC_MSG_RESULT(hp_ux)
390                 if test -f "/usr/old/usr/include/ndir.h"; then
391                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
392                 fi
393                 ;;
394         *-irix*)
395                 if test -d /usr/include/sys/SN/SN1; then
396                  IRIX_BUILD_IP35="IP35"
397                 fi
398                 MKAFS_OSTYPE=IRIX
399                 AC_MSG_RESULT(sgi)
400                 ;;
401         *-aix*)
402                 MKAFS_OSTYPE=AIX
403                 AC_MSG_RESULT(rs_aix)
404                 ;;
405         arm-*-darwin*)
406                 MKAFS_OSTYPE=DARWIN
407                 AC_MSG_RESULT(arm_darwin)
408                 ;;
409         powerpc-*-darwin*)
410                 MKAFS_OSTYPE=DARWIN
411                 AC_MSG_RESULT(ppc_darwin)
412                 ;;
413         i386-*-darwin*)
414                 MKAFS_OSTYPE=DARWIN
415                 AC_MSG_RESULT(x86_darwin)
416                 ;;
417         x86_64-*-darwin*)
418                 MKAFS_OSTYPE=DARWIN
419                 AC_MSG_RESULT(x86_darwin)
420                 ;;
421         i386-*-freebsd*)
422                 MKAFS_OSTYPE=FBSD
423                 AC_MSG_RESULT(i386_fbsd)
424                 ;;
425         x86_64-*-freebsd*)
426                 MKAFS_OSTYPE=FBSD
427                 AC_MSG_RESULT(amd64_fbsd)
428                 ;;
429         *-netbsd*)
430                 MKAFS_OSTYPE=NBSD
431                 AC_MSG_RESULT(nbsd)
432                 ;;
433         x86_64-*-openbsd*)
434                 MKAFS_OSTYPE=OBSD
435                 AC_MSG_RESULT(amd64_obsd)
436                 ;;
437         i386-*-openbsd*)
438                 MKAFS_OSTYPE=OBSD
439                 AC_MSG_RESULT(i386_obsd)
440                 ;;
441         *-dragonfly*)
442                 MKAFS_OSTYPE=DFBSD
443                 AC_MSG_RESULT(i386_dfbsd)
444                 ;;
445         *)
446                 AC_MSG_RESULT($system)
447                 ;;
448 esac
449
450 if test "x$with_afs_sysname" != "x"; then
451         AFS_SYSNAME="$with_afs_sysname"
452 else
453         AC_MSG_CHECKING(your AFS sysname)
454         case $host in
455                 i?86-*-openbsd?.?)
456                         v=${host#*openbsd}
457                         vM=${v%.*}
458                         vm=${v#*.}
459                         AFS_SYSNAME="i386_obsd${vM}${vm}"
460                         ;;
461                 sparc64-*-openbsd?.?)
462                         v=${host#*openbsd}
463                         vM=${v%.*}
464                         vm=${v#*.}
465                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
466                         ;;
467                 x86_64-*-openbsd?.?)
468                         v=${host#*openbsd}
469                         vM=${v%.*}
470                         vm=${v#*.}
471                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
472                         ;;
473                 i?86-*-freebsd?.*)
474                         v=${host#*freebsd}
475                         vM=${v%.*}
476                         vm=${v#*.}
477                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
478                         ;;
479                 x86_64-*-freebsd?.*)
480                         v=${host#*freebsd}
481                         vM=${v%.*}
482                         vm=${v#*.}
483                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
484                         ;;
485                 i386-*-dragonfly?.*)
486                         v=${host#*dragonfly}
487                         vM=${v%.*}
488                         vm=${v#*.}
489                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
490                         ;;
491                 i?86-*-netbsd*1.6[[M-Z]]*)
492                         AFS_SYSNAME="i386_nbsd20"
493                         ;;
494                 powerpc-*-netbsd*1.6[[M-Z]]*)
495                         AFS_SYSNAME="ppc_nbsd20"
496                         ;;
497                 *-*-netbsd*)
498                         arch=${host%%-unknown*}
499                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
500                                                -e 's/powerpc/ppc/g')
501                         v=${host#*netbsd}
502                         v=${v#*aout}
503                         v=${v#*ecoff}
504                         v=${v#*elf}
505                         vM=${v%%.*}
506                         vM=${vM%.*}
507                         v=${v#*.}
508                         vm=${v%%.*}
509                         vm=${vm%.*}
510                         vm=${vm%%[[_A-Z]]*}
511                         if test $vm -eq 99 ; then
512                                 vM=$((vM+1))
513                         fi
514                         if test $vM -gt 1 ; then
515                                 vm=0
516                         fi
517                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
518                         ;;
519                 hppa*-hp-hpux11.0*)
520                         AFS_SYSNAME="hp_ux110"
521                         ;;
522                 hppa*-hp-hpux11.11)
523                         AFS_SYSNAME="hp_ux11i"
524                         ;;
525                 hppa*-hp-hpux11.23)
526                         AFS_SYSNAME="hp_ux1123"
527                         ;;
528                 ia64-hp-hpux11.22)
529                         AFS_SYSNAME="ia64_hpux1122"
530                         ;;
531                 ia64-hp-hpux*)
532                         AFS_SYSNAME="ia64_hpux1123"
533                         ;;
534                 hppa*-hp-hpux10*)
535                         AFS_SYSNAME="hp_ux102"
536                         ;;
537                 powerpc-apple-darwin7*)
538                         AFS_SYSNAME="ppc_darwin_70"
539                         OSXSDK="macosx10.3"
540                         ;;
541                 powerpc-apple-darwin8.*)
542                         AFS_SYSNAME="ppc_darwin_80"
543                         OSXSDK="macosx10.4"
544                         ;;
545                 i386-apple-darwin8.*)
546                         AFS_SYSNAME="x86_darwin_80"
547                         OSXSDK="macosx10.4"
548                         ;;
549                 powerpc-apple-darwin9.*)
550                         AFS_SYSNAME="ppc_darwin_90"
551                         OSXSDK="macosx10.5"
552                         ;;
553                 i386-apple-darwin9.*)
554                         AFS_SYSNAME="x86_darwin_90"
555                         OSXSDK="macosx10.5"
556                         ;;
557                 i?86-apple-darwin10.*)
558                         AFS_SYSNAME="x86_darwin_100"
559                         OSXSDK="macosx10.6"
560                         ;;
561                 x86_64-apple-darwin10.*)
562                         AFS_SYSNAME="x86_darwin_100"
563                         OSXSDK="macosx10.6"
564                         ;;
565                 arm-apple-darwin10.*)
566                         AFS_SYSNAME="arm_darwin_100"
567                         OSXSDK="iphoneos4.0"
568                         ;;
569                 x86_64-apple-darwin11.*)
570                         AFS_SYSNAME="x86_darwin_110"
571                         OSXSDK="macosx10.7"
572                         ;;
573                 i?86-apple-darwin11.*)
574                         AFS_SYSNAME="x86_darwin_110"
575                         OSXSDK="macosx10.7"
576                         ;;
577                 sparc-sun-solaris2.8)
578                         AFS_SYSNAME="sun4x_58"
579                         ;;
580                 sparc-sun-solaris2.9)
581                         AFS_SYSNAME="sun4x_59"
582                         ;;
583                 sparc-sun-solaris2.10)
584                         AFS_SYSNAME="sun4x_510"
585                         ;;
586                 sparc-sun-solaris2.11)
587                         AFS_SYSNAME="sun4x_511"
588                         ;;
589                 sparc-sun-sunos4*)
590                         AFS_SYSNAME="sun4_413"
591                         enable_login="yes"
592                         ;;
593                 i386-pc-solaris2.8)
594                         AFS_SYSNAME="sunx86_58"
595                         ;;
596                 i386-pc-solaris2.9)
597                         AFS_SYSNAME="sunx86_59"
598                         ;;
599                 i386-pc-solaris2.10)
600                         AFS_SYSNAME="sunx86_510"
601                         ;;
602                 i386-pc-solaris2.11)
603                         AFS_SYSNAME="sunx86_511"
604                         ;;
605                 alpha*-dec-osf4.0*)
606                         AFS_SYSNAME="alpha_dux40"
607                         ;;
608                 alpha*-dec-osf5.0*)
609                         AFS_SYSNAME="alpha_dux50"
610                         ;;
611                 alpha*-dec-osf5.1*)
612                         AFS_SYSNAME="alpha_dux51"
613                         ;;
614                 mips-sgi-irix6.5)
615                         AFS_SYSNAME="sgi_65"
616                         ;;
617                 ia64-*-linux*)
618                         AFS_SYSNAME="ia64_linuxXX"
619                         ;;
620                 powerpc-*-linux*)
621                         AFS_SYSNAME="`/bin/arch`_linuxXX"
622                         ;;
623                 powerpc64-*-linux*)
624                         AFS_SYSNAME="ppc64_linuxXX"
625                         ;;
626                 alpha*-linux*)
627                         AFS_SYSNAME="alpha_linux_XX"
628                         ;;
629                 s390-*-linux*)
630                         AFS_SYSNAME="s390_linuxXX"
631                         ;;
632                 s390x-*-linux*)
633                         AFS_SYSNAME="s390x_linuxXX"
634                         ;;
635                 sparc-*-linux*)
636                         AFS_SYSNAME="`/bin/arch`_linuxXX"
637                         ;;
638                 sparc64-*-linux*)
639                         AFS_SYSNAME="sparc64_linuxXX"
640                         ;;
641                 i?86-*-linux*)
642                         AFS_SYSNAME="i386_linuxXX"
643                         ;;
644                 arm*-linux*)
645                         AFS_SYSNAME="arm_linuxXX"
646                         ;;
647                 parisc-*-linux-gnu|hppa-*-linux-gnu)
648                         AFS_SYSNAME="parisc_linuxXX"
649                         enable_pam="no"
650                         ;;
651                 power*-ibm-aix4.2*)
652                         AFS_SYSNAME="rs_aix42"
653                         enable_pam="no"
654                         ;;
655                 power*-ibm-aix4.3*)
656                         AFS_SYSNAME="rs_aix42"
657                         enable_pam="no"
658                         ;;
659                 power*-ibm-aix5.1*)
660                         AFS_SYSNAME="rs_aix51"
661                         enable_pam="no"
662                         ;;
663                 power*-ibm-aix5.2*)
664                         AFS_SYSNAME="rs_aix52"
665                         enable_pam="no"
666                         ;;
667                 power*-ibm-aix5.3*)
668                         AFS_SYSNAME="rs_aix53"
669                         enable_pam="no"
670                         ;;
671                 power*-ibm-aix6.1*)
672                         AFS_SYSNAME="rs_aix61"
673                         enable_pam="no"
674                         ;;
675                 x86_64-*-linux-gnu)
676                         AFS_SYSNAME="amd64_linuxXX"
677                         enable_pam="yes"
678                         ;;
679                 *)
680                         AC_MSG_ERROR(An AFS sysname is required)
681                         exit 1
682                         ;;
683         esac
684         case $AFS_SYSNAME in
685                 *_linux* | *_umlinux*)
686                         if test "x${AFS_SYSKVERS}" = "x"; then
687                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
688                         fi
689                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
690                         AFS_SYSNAME="$_AFS_SYSNAME"
691                         AC_TRY_KBUILD(
692                          [],
693                          [#ifndef CONFIG_USERMODE
694                           #error not UML
695                           #endif],
696                          ac_cv_linux_is_uml=yes,)
697                         if test "${ac_cv_linux_is_uml}" = yes; then
698                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
699                         fi
700                         AFS_SYSNAME="$_AFS_SYSNAME"
701                         ;;
702         esac
703         AC_MSG_RESULT($AFS_SYSNAME)
704 fi
705
706 case $AFS_SYSNAME in
707         *_darwin*)
708                 AC_CHECK_HEADERS(crt_externs.h)
709                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
710                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
711                 AC_SUBST(OSXSDK)
712                 ;;
713 esac
714
715 dnl Some hosts have a separate common param file they should include.  Figure
716 dnl out if we're on one of them now that we know the sysname.
717 case $AFS_SYSNAME in
718     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
719     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
720     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
721     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
722     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
723     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
724     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
725     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
726     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
727     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
728     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
729     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
730     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
731     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
732     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
733     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
734     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
735     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
736     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
737     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
738     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
739     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
740     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
741     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
742     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
743     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
744     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
745     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
746     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
747 # Linux alpha adds an extra underscore for no good reason.
748     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
749     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
750     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
751 esac
752
753 OPENAFS_OSCONF
754
755 case $AFS_SYSNAME in *_linux* | *_umlinux*)
756
757                 # Add (sub-) architecture-specific paths needed by conftests
758                 case $AFS_SYSNAME  in
759                         *_umlinux26)
760                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
761                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
762                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
763                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
764                 esac
765
766                 if test "x$enable_kernel_module" = "xyes"; then
767                  if test "x$enable_debug_kernel" = "xno"; then
768                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
769                  fi
770                  OPENAFS_GCC_SUPPORTS_MARCH
771                  AC_SUBST(P5PLUS_KOPTS)
772                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
773                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
774                  OPENAFS_GCC_SUPPORTS_NO_COMMON
775                  OPENAFS_GCC_SUPPORTS_PIPE
776                  AC_SUBST(LINUX_GCC_KOPTS)
777
778                  dnl Setup the kernel build environment
779                  LINUX_KBUILD_USES_EXTRA_CFLAGS
780                  LINUX_KERNEL_COMPILE_WORKS
781
782                  dnl Check for header files
783                  AC_CHECK_LINUX_HEADER([config.h])
784                  AC_CHECK_LINUX_HEADER([completion.h])
785                  AC_CHECK_LINUX_HEADER([exportfs.h])
786                  AC_CHECK_LINUX_HEADER([freezer.h])
787                  AC_CHECK_LINUX_HEADER([key-type.h])
788                  AC_CHECK_LINUX_HEADER([semaphore.h])
789                  AC_CHECK_LINUX_HEADER([seq_file.h])
790
791                  dnl Check for structure elements
792                  AC_CHECK_LINUX_STRUCT([address_space_operations],
793                                        [write_begin], [fs.h])
794                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
795                                        [backing-dev.h])
796                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
797                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
798                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
799                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
800                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
801                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
802                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
803                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
804                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
805                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
806                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
807                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
808                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
809                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
810                                        [fs.h])
811                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
812                                        [fs.h])
813                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
814                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
815                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
816                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
817                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
818                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
819                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
820                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
821                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
822                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
823                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
824
825                  dnl Check for typed structure elements
826                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
827                                              [buf], [fs.h])
828
829                  dnl Function existence checks
830
831                  AC_CHECK_LINUX_FUNC([bdi_init],
832                                      [#include <linux/backing-dev.h>],
833                                      [bdi_init(NULL);])
834                  AC_CHECK_LINUX_FUNC([PageChecked],
835                                      [#include <linux/mm.h>
836 #include <linux/page-flags.h>],
837                                      [struct page *_page;
838                                       int bchecked = PageChecked(_page);])
839                  AC_CHECK_LINUX_FUNC([PageFsMisc],
840                                      [#include <linux/mm.h>
841 #include <linux/page-flags.h>],
842                                      [struct page *_page;
843                                       int bchecked = PageFsMisc(_page);])
844                  AC_CHECK_LINUX_FUNC([current_kernel_time],
845                                      [#include <linux/time.h>],
846                                      [struct timespec s;
847                                       s = current_kernel_time();])
848                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
849                                      [#include <linux/fs.h>],
850                                      [d_alloc_anon(NULL);])
851                  AC_CHECK_LINUX_FUNC([do_sync_read],
852                                      [#include <linux/fs.h>],
853                                      [do_sync_read(NULL, NULL, 0, NULL);])
854                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
855                                      [#include <linux/sched.h>],
856                                      [pid_t p; find_task_by_pid(p);])
857                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
858                                      [#include <linux/fs.h>],
859                                      [generic_file_aio_read(NULL,NULL,0,0);])
860                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
861                                      [#include <linux/pagemap.h>],
862                                      [grab_cache_page_write_begin(NULL, 0, 0);])
863                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
864                                      [#include <linux/list.h>],
865                                      [hlist_unhashed(0);])
866                  AC_CHECK_LINUX_FUNC([i_size_read],
867                                      [#include <linux/fs.h>],
868                                      [i_size_read(NULL);])
869                  AC_CHECK_LINUX_FUNC([inode_setattr],
870                                      [#include <linux/fs.h>],
871                                      [inode_setattr(NULL, NULL);])
872                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
873                                      [#include <linux/net.h>],
874                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
875                  AC_CHECK_LINUX_FUNC([page_follow_link],
876                                      [#include <linux/fs.h>],
877                                      [page_follow_link(0,0);])
878                  AC_CHECK_LINUX_FUNC([page_offset],
879                                      [#include <linux/pagemap.h>],
880                                      [page_offset(NULL);])
881                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
882                                      [#include <linux/pagevec.h>],
883                                      [__pagevec_lru_add_file(NULL);])
884                  AC_CHECK_LINUX_FUNC([path_lookup],
885                                      [#include <linux/fs.h>
886                                       #include <linux/namei.h>],
887                                      [path_lookup(NULL, 0, NULL);])
888                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
889                                      [#include <linux/rcupdate.h>],
890                                      [rcu_read_lock();])
891                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
892                                      [#include <linux/splice.h>],
893                                      [splice_direct_to_actor(NULL,NULL,NULL);])
894                  AC_CHECK_LINUX_FUNC([svc_addr_in],
895                                      [#include <linux/sunrpc/svc.h>],
896                                      [svc_addr_in(NULL);])
897                  AC_CHECK_LINUX_FUNC([zero_user_segments],
898                                      [#include <linux/highmem.h>],
899                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
900                  AC_CHECK_LINUX_FUNC([noop_fsync],
901                                      [#include <linux/fs.h>],
902                                      [noop_fsync(NULL, 0, 0, 0);])
903
904                  dnl Consequences - things which get set as a result of the
905                  dnl                above tests
906                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
907                        [AC_DEFINE([AFS_NONFSTRANS], 1,
908                                   [define to disable the nfs translator])])
909
910                  dnl Assorted more complex tests
911                  LINUX_EXPORTS_PROC_ROOT_FS
912                  LINUX_KMEM_CACHE_INIT
913                  LINUX_HAVE_KMEM_CACHE_T
914                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
915                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
916                  LINUX_D_PATH_TAKES_STRUCT_PATH
917                  LINUX_NEW_EXPORT_OPS
918                  LINUX_INODE_SETATTR_RETURN_TYPE
919                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
920                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
921                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
922                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
923                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
924                  LINUX_DOP_D_DELETE_TAKES_CONST
925                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
926                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
927                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
928                  LINUX_FOP_F_FSYNC_TAKES_RANGE
929                  LINUX_AOP_WRITEBACK_CONTROL
930                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
931                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
932                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
933                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
934                  LINUX_KERNEL_SOCK_CREATE
935                  LINUX_EXPORTS_KEY_TYPE_KEYRING
936                  LINUX_NEED_RHCONFIG
937                  LINUX_RECALC_SIGPENDING_ARG_TYPE
938                  LINUX_EXPORTS_TASKLIST_LOCK
939                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
940                  LINUX_STATFS_TAKES_DENTRY
941                  LINUX_REFRIGERATOR
942                  LINUX_HAVE_TRY_TO_FREEZE
943                  LINUX_LINUX_KEYRING_SUPPORT
944                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
945                  LINUX_KEY_ALLOC_NEEDS_CRED
946                  LINUX_INIT_WORK_HAS_DATA
947                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
948                  LINUX_HAVE_DCACHE_LOCK
949                  LINUX_D_COUNT_IS_INT
950                  LINUX_HAVE_SET_NLINK
951
952                  dnl If we are guaranteed that keyrings will work - that is
953                  dnl  a) The kernel has keyrings enabled
954                  dnl  b) The code is new enough to give us a key_type_keyring
955                  dnl then we just disable syscall probing unless we've been
956                  dnl told otherwise
957
958                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
959                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
960                           [enable_linux_syscall_probing="no"],
961                           [enable_linux_syscall_probing="yes"])
962                  ])
963
964                  dnl Syscall probing needs a few tests of its own, and just
965                  dnl won't work if the kernel doesn't export init_mm
966                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
967                    LINUX_EXPORTS_INIT_MM
968                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
969                      AC_MSG_ERROR(
970                        [Can't do syscall probing without exported init_mm])
971                    ])
972                    LINUX_EXPORTS_SYS_CHDIR
973                    LINUX_EXPORTS_SYS_OPEN
974                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
975                              [define to enable syscall table probes])
976                  ])
977
978                  dnl Packaging and SMP build
979                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
980                    LINUX_WHICH_MODULES
981                  else
982                    AC_SUBST(MPS,'SP')
983                  fi
984
985                  dnl Syscall probing
986                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
987                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
988                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
989                    ])
990                    ac_cv_linux_exports_sys_call_table=no
991                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
992                      ac_cv_linux_exports_ia32_sys_call_table=yes
993                    fi
994                  else
995                    LINUX_EXPORTS_KALLSYMS_ADDRESS
996                    LINUX_EXPORTS_KALLSYMS_SYMBOL
997                    LINUX_EXPORTS_SYS_CALL_TABLE
998                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
999                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1000                          linux_syscall_method=none
1001                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1002                             linux_syscall_method=scan
1003                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1004                                linux_syscall_method=scan_with_kallsyms_address
1005                             fi
1006                          fi
1007                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1008                             linux_syscall_method=kallsyms_symbol
1009                          fi
1010                          if test "x$linux_syscall_method" = "xnone"; then
1011                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1012                             linux_syscall_method=scan
1013                          fi
1014                    fi
1015                  fi
1016                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1017                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1018                  fi
1019                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1020                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1021                  fi
1022                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1023                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1024                  else
1025                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1026                  fi
1027                 :
1028                 fi
1029 dnl Linux-only, but just enable always.
1030                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1031 esac
1032
1033 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1034     [ac_cv_sync_fetch_and_add],
1035     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1036                     [ac_cv_sync_fetch_and_add=yes],
1037                     [ac_cv_sync_fetch_and_add=no])
1038 ])
1039 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1040       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1041                 [define if your C compiler has __sync_add_and_fetch])])
1042
1043 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1044     [ac_cv_sockaddr_len],
1045     [AC_TRY_COMPILE( [#include <sys/types.h>
1046 #include <sys/socket.h>],
1047                      [struct sockaddr *a; a->sa_len=0;],
1048                      [ac_cv_sockaddr_len=yes],
1049                      [ac_cv_sockaddr_len=no])
1050 ])
1051 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1052       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1053                  [define if you struct sockaddr sa_len])])
1054
1055 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1056         echo Skipping library tests because they confuse Irix.
1057 else
1058   AC_SEARCH_LIBS([socket], [socket inet])
1059   AC_SEARCH_LIBS([connect], [nsl])
1060   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1061
1062   dnl darwin wants it, aix hates it
1063   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1064   AC_TRY_COMPILE([
1065   #include <stdlib.h>
1066   #include <stdio.h>
1067   #include <sys/types.h>
1068   #include <sys/socket.h>
1069   #include <netinet/in.h>
1070   #include <arpa/inet.h>
1071   #include <arpa/nameser.h>
1072   #include <arpa/nameser_compat.h>
1073   #include <resolv.h>
1074   ], [static int i; i = 0;],
1075   [AC_MSG_RESULT(yes)
1076    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1077   [AC_MSG_RESULT(no)
1078    ])
1079
1080   openafs_save_libs="$LIBS"
1081   AC_MSG_CHECKING([for res_search])
1082   AC_FUNC_RES_SEARCH
1083
1084   if test "$ac_cv_func_res_search" = no; then
1085       for lib in dns nsl resolv; do
1086         if test "$ac_cv_func_res_search" != yes; then
1087           LIBS="-l$lib $LIBS"
1088           AC_FUNC_RES_SEARCH
1089           LIBS="$openafs_save_libs"
1090         fi
1091       done    
1092       if test "$ac_cv_func_res_search" = yes; then
1093         LIB_AFSDB="-l$lib"
1094         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1095         AC_MSG_RESULT([yes, in lib$lib])
1096       else
1097         AC_MSG_RESULT(no)
1098       fi
1099   else
1100     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1101     AC_MSG_RESULT(yes)
1102   fi
1103   
1104 fi
1105 XLIBS="$LIB_AFSDB $XLIBS"
1106
1107 AC_CHECK_RESOLV_RETRANS
1108
1109 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1110     [ac_cv_setsockopt_iprecverr],
1111     [AC_TRY_COMPILE( [
1112 #include <sys/types.h>
1113 #include <sys/socket.h>
1114 #include <netinet/in.h>],
1115 [int on=1;
1116 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1117         [ac_cv_setsockopt_iprecverr=yes],
1118         [ac_cv_setsockopt_iprecverr=no])])
1119
1120 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1121       [AC_DEFINE(ADAPT_PMTU_RECVERR, 1,
1122                  [define if asynchronous socket errors can be received])])
1123
1124 PTHREAD_LIBS=error
1125 if test "x$MKAFS_OSTYPE" = OBSD; then
1126         PTHREAD_LIBS="-pthread"
1127 fi
1128 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1129         PTHREAD_LIBS="-pthread"
1130 fi
1131 if test "x$PTHREAD_LIBS" = xerror; then
1132         AC_CHECK_LIB(pthread, pthread_attr_init,
1133                 PTHREAD_LIBS="-lpthread")
1134 fi
1135 if test "x$PTHREAD_LIBS" = xerror; then
1136         AC_CHECK_LIB(pthreads, pthread_attr_init,
1137                 PTHREAD_LIBS="-lpthreads")
1138 fi
1139 if test "x$PTHREAD_LIBS" = xerror; then
1140         AC_CHECK_LIB(c_r, pthread_attr_init,
1141                 PTHREAD_LIBS="-lc_r")
1142 fi
1143 if test "x$PTHREAD_LIBS" = xerror; then
1144         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1145 fi
1146 if test "x$PTHREAD_LIBS" = xerror; then
1147         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1148         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1149                 PTHREAD_LIBS="-lpthread")
1150 fi
1151 if test "x$PTHREAD_LIBS" = xerror; then
1152         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1153 fi
1154 AC_SUBST(PTHREAD_LIBS)
1155
1156 HOST_CPU="$host_cpu"
1157
1158 if test "x$with_bsd_kernel_headers" != "x"; then
1159         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1160 else
1161         BSD_KERNEL_PATH="/usr/src/sys"
1162 fi
1163
1164 if test "x$with_bsd_kernel_build" != "x"; then
1165         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1166 else
1167         case $AFS_SYSNAME in
1168                 *_fbsd_*)
1169                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1170                         ;;
1171                 *_nbsd*)
1172                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1173         esac
1174 fi
1175
1176 # Fast restart
1177 if test "$enable_supergroups" = "yes"; then
1178         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1179 fi
1180
1181 if test "$enable_bitmap_later" = "yes"; then
1182         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1183 fi
1184
1185 if test "$enable_unix_sockets" = "yes"; then
1186         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1187         USE_UNIX_SOCKETS="yes"
1188 else
1189         USE_UNIX_SOCKETS="no"
1190 fi
1191 AC_SUBST(USE_UNIX_SOCKETS)
1192
1193 dnl if test "$ac_cv_setsockopt_iprecverr" = "yes"; then
1194 dnl     AC_DEFINE(ADAPT_PMTU, 1, [define if you want to decode icmp unreachable packets to discover path mtu])
1195 dnl fi
1196
1197 if test "$enable_namei_fileserver" = "yes"; then
1198         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1199         VFSCK=""
1200 else
1201         if test "$enable_namei_fileserver" = "default"; then
1202                 case $host in
1203                         *-solaris2.10*)
1204                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1205                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1206                                 VFSCK=""
1207                                 ;;
1208                         *-solaris2.11*)
1209                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1210                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1211                                 VFSCK=""
1212                                 ;;
1213                         *)
1214                                 VFSCK="vfsck"
1215                                 ;;
1216                 esac
1217         else
1218                 VFSCK="vfsck"
1219         fi
1220 fi
1221
1222 dnl check for tivoli
1223 AC_MSG_CHECKING(for tivoli tsm butc support)
1224 XBSA_CFLAGS=""
1225 if test "$enable_tivoli_tsm" = "yes"; then
1226         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1227         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1228         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1229         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1230
1231         if test -r "$XBSADIR3/dsmapifp.h"; then
1232                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1233                 XBSA_XLIBS="-ldl"
1234                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1235         elif test -r "$XBSADIR4/dsmapifp.h"; then
1236                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1237                 XBSA_XLIBS="-ldl"
1238                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1239         elif test -r "$XBSADIR1/xbsa.h"; then
1240                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1241                 XBSA_XLIBS=""
1242                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1243         elif test -r "$XBSADIR2/xbsa.h"; then
1244                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1245                 XBSA_XLIBS=""
1246                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1247         else
1248                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1249         fi
1250 else
1251         AC_MSG_RESULT([no])
1252 fi
1253 AC_SUBST(XBSA_CFLAGS)
1254 AC_SUBST(XBSA_XLIBS) 
1255
1256 dnl checks for header files.
1257 AC_HEADER_STDC
1258 AC_HEADER_SYS_WAIT
1259 AC_HEADER_DIRENT
1260 AC_CHECK_HEADERS([ \
1261                    arpa/inet.h \
1262                    arpa/nameser.h \
1263                    curses.h\
1264                    direct.h \
1265                    et/com_err.h \
1266                    errno.h \
1267                    fcntl.h \
1268                    grp.h \
1269                    math.h \
1270                    mntent.h \
1271                    ncurses.h \
1272                    netdb.h \
1273                    netinet/in.h \
1274                    pthread_np.h \
1275                    pwd.h \
1276                    regex.h \
1277                    security/pam_appl.h \
1278                    signal.h \
1279                    stdint.h \
1280                    stdio_ext.h \
1281                    stdlib.h \
1282                    string.h \
1283                    strings.h \
1284                    sys/bitypes.h \
1285                    sys/bswap.h \
1286                    sys/dk.h \
1287                    sys/fcntl.h \
1288                    sys/file.h \
1289                    sys/fs_types.h \
1290                    sys/fstyp.h \
1291                    sys/ioctl.h \
1292                    sys/ipc.h \
1293                    sys/lockf.h \
1294                    sys/map.h \
1295                    sys/mount.h \
1296                    sys/mntent.h \
1297                    sys/mnttab.h \
1298                    sys/pag.h \
1299                    sys/param.h \
1300                    sys/resource.h \
1301                    sys/select.h \
1302                    sys/statfs.h \
1303                    sys/statvfs.h \
1304                    sys/socket.h \
1305                    sys/sysctl.h \
1306                    sys/time.h \
1307                    sys/types.h \
1308                    sys/uio.h \
1309                    sys/un.h \
1310                    sys/vfs.h \
1311                    syslog.h \
1312                    termios.h \
1313                    time.h \
1314                    ucontext.h \
1315                    unistd.h \
1316                    windows.h \
1317                 ])
1318
1319 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1320 #ifdef HAVE_NETINET_IN_H
1321 # include <netinet/in.h>
1322 #endif])
1323
1324 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1325 #ifdef HAVE_SYS_SOCKET_H
1326 # include <sys/socket.h>
1327 #endif])
1328
1329 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1330 #ifdef HAVE_SYS_SOCKET_H
1331 # include <sys/socket.h>
1332 #endif
1333 #ifdef HAVE_NETINET_IN_H
1334 # include <netinet/in.h>
1335 #endif
1336 #ifdef HAVE_NET_IF_H
1337 # include <net/if.h>
1338 #endif])
1339
1340 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1341 #ifdef HAVE_SECURITY_PAM_APPL_H
1342 # include <security/pam_appl.h>
1343 #endif])
1344
1345 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1346
1347 AC_CHECK_TYPES([fsblkcnt_t],,,[
1348 #include <sys/types.h>
1349 #ifdef HAVE_SYS_BITYPES_H
1350 #include <sys/bitypes.h>
1351 #endif
1352 #ifdef HAVE_SYS_STATFS_H
1353 #include <sys/statfs.h>
1354 #endif
1355 #ifdef HAVE_SYS_STATVFS_H
1356 #include <sys/statvfs.h>
1357 #endif
1358 ])
1359
1360 dnl see what struct stat has for timestamps
1361 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1362
1363 dnl check for curses-lib
1364 save_LIBS=$LIBS
1365 AC_CHECK_LIB( [ncurses], [setupterm],
1366 [LIB_curses=-lncurses],
1367     [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1368         [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])
1369     ])
1370 ])
1371 LIBS=$save_LIBS
1372 AC_SUBST(LIB_curses)
1373
1374 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1375
1376 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1377 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1378         case $AFS_SYSNAME in
1379         sgi_*)
1380                 HAVE_PAM="no"
1381                 ;;
1382         *)
1383                 HAVE_PAM="yes"
1384                 ;;
1385         esac
1386 else
1387         HAVE_PAM="no"
1388 fi
1389 AC_SUBST(HAVE_PAM)
1390
1391 if test "$enable_login" = yes; then
1392         BUILD_LOGIN="yes"
1393 else
1394         BUILD_LOGIN="no"
1395 fi
1396 AC_SUBST(BUILD_LOGIN)
1397
1398 AC_CHECK_FUNCS([ \
1399         arc4random \
1400         fcntl \
1401         fseeko64 \
1402         ftello64 \
1403         getcwd \
1404         getegid \
1405         geteuid \
1406         getgid \
1407         getuid \
1408         getprogname \
1409         getrlimit \
1410         issetugid \
1411         mkstemp \
1412         pread \
1413         preadv \
1414         preadv64 \
1415         pwrite \
1416         pwritev \
1417         pwritev64 \
1418         regcomp \
1419         regerror \
1420         regexec \
1421         setitimer \
1422         setprogname \
1423         setvbuf \
1424         sigaction \
1425         strcasestr \
1426         strerror \
1427         sysconf \
1428         sysctl \
1429         timegm \
1430 ])
1431
1432 OPENAFS_ROKEN()
1433 OPENAFS_C_ATTRIBUTE()
1434
1435 dnl Functions that Heimdal's libroken provides, but that we
1436 dnl haven't found a need for yet, and so haven't imported
1437 AC_CHECK_FUNCS([ \
1438         chown \
1439         fchown \
1440         gethostname \
1441         lstat \
1442         inet_aton \
1443         inet_ntop \
1444         inet_pton \
1445         putenv \
1446         readv \
1447         setenv \
1448         strdup \
1449         strftime \
1450         strndup \
1451         strsep \
1452         unsetenv \
1453 ])
1454
1455 dnl Functions that are in objects that we always build from libroken
1456 AC_CHECK_FUNCS([ \
1457         asprintf \
1458         asnprintf \
1459         vasprintf \
1460         vasnprintf \
1461         vsnprintf \
1462         snprintf \
1463 ])
1464
1465 dnl Functions that we're going to try and get from libroken
1466 AC_REPLACE_FUNCS([ \
1467         daemon \
1468         ecalloc \
1469         emalloc \
1470         erealloc \
1471         err \
1472         errx \
1473         flock \
1474         getdtablesize \
1475         getopt \
1476         getprogname \
1477         gettimeofday \
1478         localtime_r \
1479         mkstemp \
1480         setenv \
1481         strcasecmp \
1482         strlcat \
1483         strnlen \
1484         strlcpy \
1485         strsep \
1486         tdelete \
1487         tfind \
1488         tsearch \
1489         twalk \
1490         unsetenv \
1491         verr \
1492         verrx \
1493         vsyslog \
1494         vwarn \
1495         vwarnx \
1496         warn \
1497         warnx \
1498 ])
1499
1500 dnl Headers that we're going to try and get from libroken
1501 AC_CHECK_HEADERS([ \
1502         err.h \
1503         search.h \
1504 ])
1505
1506 AC_CHECK_DECLS([h_errno], [], [], [
1507 #include <sys/types.h>
1508 #ifdef HAVE_NETDB_H
1509 #include <netdb.h>
1510 #endif
1511 ])
1512
1513 AC_HEADER_TIME
1514
1515 ROKEN_HEADERS=
1516 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1517       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1518       [])
1519 AC_SUBST(ROKEN_HEADERS)
1520
1521 dnl Stuff that's harder ...
1522 AC_MSG_CHECKING([for bswap16])
1523 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1524 #ifdef HAVE_SYS_TYPES_H
1525 #include <sys/types.h>
1526 #endif
1527 #ifdef HAVE_SYS_BSWAP_H
1528 #include <sys/bswap.h>
1529 #endif
1530 ],
1531 [short a, b; b = bswap16(a); ])],
1532 [AC_MSG_RESULT(yes)
1533  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1534 ],
1535 [AC_MSG_RESULT(no)])
1536
1537 AC_MSG_CHECKING([for bswap32])
1538 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1539 #include <sys/types.h>
1540 #endif
1541 #ifdef HAVE_SYS_BSWAP_H
1542 #include <sys/bswap.h>
1543 #endif
1544 ],
1545 [int a, b; b = bswap32(a); ])],
1546 [AC_MSG_RESULT(yes)
1547  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1548 ],
1549 [AC_MSG_RESULT(no)])
1550
1551 case $AFS_SYSNAME in
1552 *hp_ux* | *hpux*)
1553    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1554    ;;
1555 *)
1556    AC_MSG_CHECKING([for positional I/O])
1557    if test "$ac_cv_func_pread" = "yes" && \
1558            test "$ac_cv_func_pwrite" = "yes"; then
1559       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1560       AC_MSG_RESULT(yes)
1561    else
1562      AC_MSG_RESULT(no)
1563    fi
1564    AC_MSG_CHECKING([for vectored positional I/O])
1565    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1566                "$ac_cv_func_pwritev" = "yes" -a \
1567                "$ac_cv_func_preadv64" = "yes" -a \
1568                "$ac_cv_func_pwritev64" = "yes"],
1569          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1570           AC_MSG_RESULT(yes)],
1571          [AC_MSG_RESULT(no)])
1572    ;;
1573 esac
1574
1575 AC_MSG_CHECKING([for POSIX regex library])
1576 if test "$ac_cv_header_regex_h" = "yes" && \
1577         test "$ac_cv_func_regcomp" = "yes" && \
1578         test "$ac_cv_func_regexec" = "yes" && \
1579         test "$ac_cv_func_regerror" = "yes"; then
1580     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1581     AC_MSG_RESULT(yes)
1582 else
1583     AC_MSG_RESULT(no)
1584 fi
1585
1586 dnl Look for "non-portable" pthreads functions.
1587 save_LIBS="$LIBS"
1588 LIBS="$LIBS $PTHREAD_LIBS"
1589 AC_CHECK_FUNCS([ \
1590         pthread_set_name_np \
1591         pthread_setname_np \
1592 ])
1593
1594 dnl Sadly, there are three different versions of pthread_setname_np.
1595 dnl Try to cater for all of them.
1596 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1597     AC_MSG_CHECKING([for signature of pthread_setname_np])
1598     AC_TRY_COMPILE([
1599 #include <pthread.h>
1600 #ifdef HAVE_PTHREAD_NP_H
1601 #include <pthread_np.h>
1602 #endif
1603 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1604         AC_MSG_RESULT([three arguments])
1605         pthread_setname_np_args=3], [
1606         AC_TRY_COMPILE([
1607 #include <pthread.h>
1608 #ifdef HAVE_PTHREAD_NP_H
1609 #include <pthread_np.h>
1610 #endif
1611 ], [pthread_setname_np(pthread_self(), "test")], [
1612             AC_MSG_RESULT([two arguments])
1613             pthread_setname_np_args=2], [
1614             AC_TRY_COMPILE([
1615 #include <pthread.h>
1616 #ifdef HAVE_PTHREAD_NP_H
1617 #include <pthread_np.h>
1618 #endif
1619 ], [pthread_setname_np("test")], [
1620                 AC_MSG_RESULT([one argument])
1621                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1622 ])
1623 ])
1624 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1625 fi
1626 LIBS="$save_LIBS"
1627
1628 openafs_cv_saved_CFLAGS="$CFLAGS"
1629 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1630
1631 AC_TYPE_SIGNAL
1632 OPENAFS_RETSIGTYPE
1633 AC_CHECK_SIZEOF(void *)
1634 AC_CHECK_SIZEOF(unsigned long long)
1635 AC_CHECK_SIZEOF(unsigned long)
1636 AC_CHECK_SIZEOF(unsigned int)
1637 AC_TYPE_INTPTR_T
1638 AC_TYPE_UINTPTR_T
1639 AC_TYPE_SSIZE_T
1640 AC_CHECK_TYPE([sig_atomic_t],[],
1641     [AC_DEFINE([sig_atomic_t], [int],
1642         [Define to int if <signal.h> does not define.])],
1643 [#include <sys/types.h>
1644 #include <signal.h>])
1645 AC_CHECK_TYPE([socklen_t],[],
1646     [AC_DEFINE([socklen_t], [int],
1647         [Define to int if <sys/socket.h> does not define.])],
1648 [#include <sys/types.h>
1649 #include <sys/socket.h>])
1650 AC_CHECK_TYPES(off64_t)
1651 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1652 AC_CHECK_TYPES([struct winsize], [], [], [
1653 #ifdef HAVE_TERMIOS_H
1654 # include <termios.h>
1655 #else
1656 # include <sys/termios.h>
1657 #endif
1658 #include <sys/ioctl.h>])
1659 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1660                 struct sockaddr_storage],
1661                [], [], [
1662 #include <sys/types.h>
1663 #include <sys/socket.h>
1664 ])
1665 AC_CHECK_TYPES([sa_family_t], [], [], [
1666 #include <sys/types.h>
1667 #include <sys/socket.h>
1668 ])
1669 AC_CHECK_TYPES([struct addrinfo], [], [], [
1670 #include <sys/types.h>
1671 #ifdef HAVE_NETDB_H
1672 #include <netdb.h>
1673 #endif
1674 ])
1675 AC_CHECK_TYPES([long long], [], [], [])
1676
1677 AC_SIZEOF_TYPE(long)
1678
1679 CFLAGS="$openafs_cv_saved_CFLAGS"
1680
1681 RRA_HEADER_PAM_CONST
1682
1683
1684 dnl Directory PATH handling
1685 if test "x$enable_transarc_paths" = "xyes"  ; then 
1686     afsconfdir=${afsconfdir=/usr/afs/etc}
1687     viceetcdir=${viceetcdir=/usr/vice/etc}
1688     afskerneldir=${afskerneldir=${viceetcdir}}
1689     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1690     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1691     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1692     afsdbdir=${afsdbdir=/usr/afs/db}
1693     afslogsdir=${afslogsdir=/usr/afs/logs}
1694     afslocaldir=${afslocaldir=/usr/afs/local}
1695     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1696     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1697     afsdatadir=${afsdatadir=/usr/vice/etc}
1698 else 
1699     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1700     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1701     afskerneldir=${afskerneldir='${libdir}/openafs'}
1702     afssrvbindir=${afssrvbindir='${bindir}'}
1703     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1704     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1705     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1706     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1707     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1708     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1709     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1710     afsdatadir=${afsdatadir='${datadir}/openafs'}
1711 fi
1712 AC_SUBST(afsconfdir)
1713 AC_SUBST(viceetcdir)
1714 AC_SUBST(afskerneldir)
1715 AC_SUBST(afssrvbindir)
1716 AC_SUBST(afssrvsbindir)
1717 AC_SUBST(afssrvlibexecdir)
1718 AC_SUBST(afsdbdir)
1719 AC_SUBST(afslogsdir)
1720 AC_SUBST(afslocaldir)
1721 AC_SUBST(afsbackupdir)
1722 AC_SUBST(afsbosconfigdir)
1723 AC_SUBST(afsdatadir)
1724
1725 if test "x$enable_kernel_module" = "xyes"; then
1726 ENABLE_KERNEL_MODULE=libafs
1727 fi
1728
1729 if test "x$enable_pthreaded_ubik" = "xyes"; then
1730 ENABLE_PTHREADED_UBIK=yes
1731 fi
1732
1733 AC_SUBST(VFSCK)
1734 AC_SUBST(AFS_SYSNAME)
1735 AC_SUBST(AFS_PARAM_COMMON)
1736 AC_SUBST(ENABLE_KERNEL_MODULE)
1737 AC_SUBST(ENABLE_PTHREADED_UBIK)
1738 AC_SUBST(LIB_AFSDB)
1739 AC_SUBST(LINUX_KERNEL_PATH)
1740 AC_SUBST(LINUX_KERNEL_BUILD)
1741 AC_SUBST(HOST_CPU)
1742 AC_SUBST(BSD_KERNEL_PATH)
1743 AC_SUBST(BSD_KERNEL_BUILD)
1744 AC_SUBST(LINUX_VERSION)
1745 AC_SUBST(MKAFS_OSTYPE)
1746 AC_SUBST(TOP_OBJDIR)
1747 AC_SUBST(TOP_SRCDIR)
1748 AC_SUBST(TOP_INCDIR)
1749 AC_SUBST(TOP_LIBDIR)
1750 AC_SUBST(DEST)
1751 AC_SUBST(DARWIN_INFOFILE)
1752 AC_SUBST(IRIX_BUILD_IP35)
1753 AC_SUBST(HTML_XSL)
1754 AC_SUBST(XSLTPROC)
1755 AC_SUBST(DOCBOOK2PDF)
1756 AC_SUBST(DOCBOOK_STYLESHEETS)
1757
1758 OPENAFS_FUSE
1759 OPENAFS_SWIG
1760
1761 TOP_SRCDIR="${srcdir}/src"
1762 dnl
1763 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1764 dnl
1765 case $TOP_SRCDIR in
1766         /*)
1767                 ;;
1768         *)
1769                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1770                 ;;
1771 esac
1772
1773 TOP_OBJDIR="${SRCDIR_PARENT}"
1774 TOP_INCDIR="${SRCDIR_PARENT}/include"
1775 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1776 if test "${DEST}x" = "x"; then
1777         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1778 fi
1779
1780 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1781 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1782 AC_SUBST(HELPER_SPLINT)
1783 AC_SUBST(HELPER_SPLINTCFG)
1784
1785 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1786
1787 dnl Check to see if crypt lives in a different library
1788 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1789 AC_SUBST(LIB_crypt)
1790
1791 dnl Check to see if the compiler support labels in structs
1792 AC_MSG_CHECKING(for label support in structs)
1793 AC_TRY_COMPILE([], [
1794 extern void osi_UFSOpen(void);
1795 struct labeltest {
1796    void (*open) (void);
1797 };
1798 struct labeltest struct_labeltest = {
1799    .open       = osi_UFSOpen,
1800 }
1801 ],
1802 [AC_MSG_RESULT(yes)
1803  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1804 ],
1805 [AC_MSG_RESULT(no)
1806 ])
1807
1808 AC_MSG_CHECKING([checking for dirfd])
1809 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1810 #ifdef HAVE_DIRENT_H
1811 #include <dirent.h>
1812 #endif
1813 ]],
1814         [[DIR *d = 0; dirfd(d);]])],
1815         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1816 if test "$ac_rk_have_dirfd" = "yes" ; then
1817         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1818 fi
1819 AC_MSG_RESULT($ac_rk_have_dirfd)
1820
1821 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1822 #ifdef HAVE_DIRENT_H
1823 #include <dirent.h>
1824 #endif])
1825
1826 dnl Eventually, this will look for the system one, or for OpenSSL
1827 LIB_hcrypto="-lafshcrypto"
1828 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1829 AC_SUBST(LIB_hcrypto)
1830 AC_SUBST(LDFLAGS_hcrypto)
1831 ])
1832
1833 AC_DEFUN([SUMMARY], [
1834     # Print a configuration summary
1835 echo 
1836 echo "**************************************"
1837 echo configure summary
1838 echo
1839 AS_IF([test $LIB_curses],[
1840 echo "LIB_curses :                $LIB_curses" ],[
1841 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1842 ])
1843 echo 
1844 echo "**************************************"
1845 ])