acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #    define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 # define _FILE_OFFSET_BITS 64
  48 # define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 # include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])
  76 ])
  77
  78 dnl General feature options.
  79 AC_ARG_ENABLE([namei-fileserver],
  80     [AS_HELP_STRING([--enable-namei-fileserver],
  81         [force compilation of namei fileserver in preference to inode
  82          fileserver])],
  83     [],
  84     [enable_namei_fileserver="default"])
  85 AC_ARG_ENABLE([supergroups],
  86     [AS_HELP_STRING([--enable-supergroups],
  87         [enable support for nested pts groups])],
  88     [],
  89     [enable_supergroups="no"])
  90 AC_ARG_ENABLE([bitmap-later],
  91     [AS_HELP_STRING([--enable-bitmap-later],
  92         [enable fast startup of file server by not reading bitmap till
  93          needed])],
  94     [AS_IF([test x"$withval" = xyes],
  95         [AC_MSG_WARN([bitmap-later is only used by non-demand-attach
  96             fileservers.  Please migrate to demand-attach instead.])])],
  97     [enable_bitmap_later="no"])
  98 AC_ARG_ENABLE([unix-sockets],
  99     [AS_HELP_STRING([--disable-unix-sockets],
 100         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 101     [],
 102     [enable_unix_sockets="yes"])
 103 AC_ARG_ENABLE([tivoli-tsm],
 104     [AS_HELP_STRING([--enable-tivoli-tsm],
 105         [enable use of the Tivoli TSM API libraries for butc support])],
 106     [],
 107     [enable_tivoli_tsm="no"])
 108 AC_ARG_ENABLE([pthreaded-ubik],
 109     [AS_HELP_STRING([--disable-pthreaded-ubik],
 110         [disable installation of pthreaded ubik applications (defaults to
 111          enabled)])],
 112     [],
 113     [enable_pthreaded_ubik="yes"])
 114 AC_ARG_ENABLE([ubik-read-while-write],
 115     [AS_HELP_STRING([--enable-ubik-read-while-write],
 116         [enable vlserver read from db cache during write locks (EXPERIMENTAL)])],
 117     [],
 118     [enable_ubik_read_while_write="no"])
 119
 120 dnl Kernel module build options.
 121 AC_ARG_WITH([linux-kernel-headers],
 122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 123         [use the kernel headers found at path (optional, defaults to
 124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
 125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])
 126 ])
 127 AC_ARG_WITH([linux-kernel-build],
 128     [AS_HELP_STRING([--with-linux-kernel-build=path],
 129         [use the kernel build found at path(optional, defaults to
 130         kernel headers path)]
 131 )])
 132 AC_ARG_WITH([bsd-kernel-headers],
 133     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 134         [use the kernel headers found at path (optional, defaults to
 135          /usr/src/sys)])
 136 ])
 137 AC_ARG_WITH([bsd-kernel-build],
 138     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 139         [use the kernel build found at path (optional, defaults to
 140          KSRC/i386/compile/GENERIC)])
 141 ])
 142 AC_ARG_WITH([linux-kernel-packaging],
 143     [AS_HELP_STRING([--with-linux-kernel-packaging],
 144         [use standard naming conventions to aid Linux kernel build packaging
 145          (disables MPS, sets the kernel module name to openafs.ko, and
 146          installs kernel modules into the standard Linux location)])],
 147     [AC_SUBST([LINUX_KERNEL_PACKAGING], [yes])
 148      AC_SUBST([LINUX_LIBAFS_NAME], [openafs])],
 149     [AC_SUBST([LINUX_LIBAFS_NAME], [libafs])
 150 ])
 151 AC_ARG_ENABLE([kernel-module],
 152     [AS_HELP_STRING([--disable-kernel-module],
 153         [disable compilation of the kernel module (defaults to enabled)])],
 154     [],
 155     [enable_kernel_module="yes"])
 156 AC_ARG_ENABLE([redhat-buildsys],
 157     [AS_HELP_STRING([--enable-redhat-buildsys],
 158         [enable compilation of the redhat build system kernel (defaults to
 159          disabled)])],
 160     [],
 161     [enable_redhat_buildsys="no"])
 162
 163 dnl Installation locations.
 164 AC_ARG_ENABLE([transarc-paths],
 165     [AS_HELP_STRING([--enable-transarc-paths],
 166         [use Transarc style paths like /usr/afs and /usr/vice])],
 167     [],
 168     [enable_transarc_paths="no"])
 169
 170 dnl Deprecated crypto
 171 AC_ARG_ENABLE([kauth],
 172     [AS_HELP_STRING([--enable-kauth],
 173         [install the deprecated kauth server, pam modules, and utilities
 174          (defaults to disabled)])],
 175     [enable_pam="yes"],
 176     [enable_kauth="no"
 177      enable_pam="no"])
 178
 179 dnl Optimization and debugging flags.
 180 AC_ARG_ENABLE([strip-binaries],
 181     [AS_HELP_STRING([--disable-strip-binaries],
 182         [disable stripping of symbol information from binaries (defaults to
 183          enabled)])],
 184     [],
 185     [enable_strip_binaries="maybe"])
 186 AC_ARG_ENABLE([debug],
 187     [AS_HELP_STRING([--enable-debug],
 188         [enable compilation of the user space code with debugging information
 189          (defaults to disabled)])],
 190     [],
 191     [enable_debug="no"])
 192 AC_ARG_ENABLE([optimize],
 193     [AS_HELP_STRING([--disable-optimize],
 194         [disable optimization for compilation of the user space code (defaults
 195          to enabled)])],
 196     [],
 197     [enable_optimize="yes"])
 198 AC_ARG_ENABLE([warnings],
 199     [AS_HELP_STRING([--enable-warnings],
 200         [enable compilation warnings when building with gcc (defaults to
 201          disabled)])],
 202     [],
 203     [enable_warnings="no"])
 204 AC_ARG_ENABLE([checking],
 205     [AS_HELP_STRING([--enable-checking],
 206         [turn compilation warnings into errors when building with gcc (defaults
 207          to disabled)])],
 208     [enable_checking="$enableval"],
 209     [enable_checking="no"])
 210 AC_ARG_ENABLE([debug-locks],
 211     [AS_HELP_STRING([--enable-debug-locks],
 212         [turn on lock debugging assertions (defaults to disabled)])],
 213     [enable_debug_locks="$enableval"],
 214     [enable_debug_locks="no"])
 215 AC_ARG_ENABLE([debug-kernel],
 216     [AS_HELP_STRING([--enable-debug-kernel],
 217         [enable compilation of the kernel module with debugging information
 218          (defaults to disabled)])],
 219     [],
 220     [enable_debug_kernel="no"])
 221 AC_ARG_ENABLE([optimize-kernel],
 222     [AS_HELP_STRING([--disable-optimize-kernel],
 223         [disable compilation of the kernel module with optimization (defaults
 224          based on platform)])],
 225     [],
 226     [enable_optimize_kernel=""])
 227 AC_ARG_ENABLE([debug-lwp],
 228     [AS_HELP_STRING([--enable-debug-lwp],
 229         [enable compilation of the LWP code with debugging information
 230          (defaults to disabled)])],
 231     [],
 232     [enable_debug_lwp="no"])
 233 AC_ARG_ENABLE([optimize-lwp],
 234     [AS_HELP_STRING([--disable-optimize-lwp],
 235         [disable optimization for compilation of the LWP code (defaults to
 236          enabled)])],
 237     [],
 238     [enable_optimize_lwp="yes"])
 239 AC_ARG_ENABLE([debug-pam],
 240     [AS_HELP_STRING([--enable-debug-pam],
 241         [enable compilation of the PAM code with debugging information
 242          (defaults to disabled)])],
 243     [],
 244     [enable_debug_pam="no"])
 245 AC_ARG_ENABLE([optimize-pam],
 246     [AS_HELP_STRING([--disable-optimize-pam],
 247         [disable optimization for compilation of the PAM code (defaults to
 248          enabled)])],
 249     [],
 250     [enable_optimize_pam="yes"])
 251 AC_ARG_ENABLE([linux-syscall-probing],
 252     [AS_HELP_STRING([--enable-linux-syscall-probing],
 253         [enable Linux syscall probing (defaults to autodetect)])],
 254     [],
 255     [enable_linux_syscall_probing="maybe"])
 256 AC_ARG_ENABLE([linux-d_splice_alias-extra-iput],
 257     [AS_HELP_STRING([--enable-linux-d_splice_alias-extra-iput],
 258         [Linux kernels in the 3.17 series prior to 3.17.3 had a bug
 259          wherein error returns from the d_splice_alias() function were
 260          leaking a reference on the inode.  The bug was fixed for the
 261          3.17.3 kernel, and the possibility of an error return was only
 262          introduced in kernel 3.17, so only the narrow range of kernels
 263          is affected.  Enable this option for builds on systems with
 264          kernels affected by this bug, to manually release the reference
 265          on error returns and correct the reference counting.
 266          Linux commit 51486b900ee92856b977eacfc5bfbe6565028070 (or
 267          equivalent) is the fix for the upstream bug, so if such a commit
 268          is present, leave this option disabled.  We apologize
 269          that you are required to know this about your running kernel,
 270          but luckily only a narrow range of versions is affected.])],
 271     [],
 272     [enable_linux_d_splice_alias_extra_iput="no"])
 273 AC_ARG_WITH([crosstools-dir],
 274     [AS_HELP_STRING([--with-crosstools-dir=path],
 275         [use path for native versions of rxgen, compile_et and config])
 276 ])
 277
 278 AC_ARG_WITH([xslt-processor],
 279         AS_HELP_STRING([--with-xslt-processor=ARG],
 280         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 281         [XSLTPROC="$withval"],
 282         [AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo])])
 283
 284 AC_ARG_WITH([html-xsl],
 285         AS_HELP_STRING([--with-html-xsl],
 286         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 287         [HTML_XSL="$withval"],
 288         [HTML_XSL="html/chunk.xsl"])
 289
 290 AC_ARG_WITH([docbook2pdf],
 291         AS_HELP_STRING([--with-docbook2pdf=ARG],
 292         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 293         [DOCBOOK2PDF="$withval"],
 294         [AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo])])
 295
 296 AC_ARG_WITH([docbook-stylesheets],
 297         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 298         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 299         [DOCBOOK_STYLESHEETS="$withval"],
 300         [OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS],
 301                 [/usr/share/xml/docbook/stylesheet/nwalsh/current \
 302                  /usr/share/xml/docbook/stylesheet/nwalsh \
 303                  /usr/share/xml/docbook/xsl-stylesheets \
 304                  /usr/share/sgml/docbook/docbook-xsl-stylesheets \
 305                  /usr/share/sgml/docbook/xsl-stylesheets \
 306                  /usr/share/docbook-xsl \
 307                  /usr/share/sgml/docbkxsl \
 308                  /usr/local/share/xsl/docbook \
 309                  /sw/share/xml/xsl/docbook-xsl \
 310                  /opt/local/share/xsl/docbook-xsl],
 311                 [$HTML_XSL])
 312            AS_IF([test "x$DOCBOOK_STYLESHEETS" = "x"],
 313                 [AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 314            ])
 315         ])
 316
 317 AC_ARG_WITH([dot],
 318         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
 319         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
 320         [], [with_dot="maybe"])
 321
 322 enable_login="no"
 323
 324 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 325 dnl documentation build.
 326 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 327 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 328
 329 dnl Optionally generate graphs with doxygen.
 330 case "$with_dot" in
 331 maybe)
 332     AC_CHECK_PROGS([DOT], [dot])
 333     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
 334     ;;
 335 yes)
 336     HAVE_DOT="yes"
 337     ;;
 338 no)
 339     HAVE_DOT="no"
 340     ;;
 341 *)
 342     HAVE_DOT="yes"
 343     DOT_PATH=$with_dot
 344 esac
 345 AC_SUBST(HAVE_DOT)
 346 AC_SUBST(DOT_PATH)
 347
 348 dnl Checks for UNIX variants.
 349 AC_ISC_POSIX
 350
 351 dnl Various compiler setup.
 352 AC_TYPE_PID_T
 353 AC_TYPE_SIZE_T
 354
 355 dnl Checks for programs.
 356 AC_PROG_INSTALL
 357 AC_PROG_LN_S
 358 AC_PROG_RANLIB
 359 AC_PROG_YACC
 360 AM_PROG_LEX
 361 dnl if we are flex, be lex-compatible
 362 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 363
 364 OPENAFS_FORCE_ABS_INSTALL
 365 OPENAFS_CHECK_BIGENDIAN
 366 OPENAFS_PRINTF_TAKES_Z_LEN
 367
 368 AC_MSG_CHECKING(your OS)
 369 system=$host
 370 case $system in
 371         *-linux*)
 372
 373                 MKAFS_OSTYPE=LINUX
 374                 if test "x$enable_redhat_buildsys" = "xyes"; then
 375                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 376                 fi
 377                 if test "x$enable_kernel_module" = "xyes"; then
 378                  if test "x$with_linux_kernel_headers" != "x"; then
 379                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 380                  else
 381                    for utsdir in "/lib/modules/`uname -r`/build" \
 382                                  "/lib/modules/`uname -r`/source" \
 383                                  "/usr/src/linux-2.4" \
 384                                  "/usr/src/linux"; do
 385                      LINUX_KERNEL_PATH="$utsdir"
 386                      for utsfile in "include/generated/utsrelease.h" \
 387                                     "include/linux/utsrelease.h" \
 388                                     "include/linux/version.h" \
 389                                     "include/linux/version-up.h"; do
 390                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
 391                          break 2
 392                        fi
 393                      done
 394                    done
 395                  fi
 396                  if test "x$with_linux_kernel_build" != "x"; then
 397                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 398                  else
 399                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 400                  fi
 401                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 402                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 403                    LINUX_VERSION="$linux_kvers"
 404                  else
 405                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 406                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 407                      LINUX_VERSION="$linux_kvers"
 408                    else
 409                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 410                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 411                        if test "x$linux_kvers" = "x"; then
 412                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 413                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 414                            if test "x$linux_kvers" = "x"; then
 415                              AC_MSG_ERROR(Linux headers lack version definition [2])
 416                              exit 1
 417                            else
 418                              LINUX_VERSION="$linux_kvers"
 419                            fi
 420                          else
 421                            AC_MSG_ERROR(Linux headers lack version definition)
 422                            exit 1
 423                          fi
 424                        else
 425                          LINUX_VERSION="$linux_kvers"
 426                        fi
 427                      else
 428                        enable_kernel_module="no"
 429                      fi
 430                    fi
 431                  fi
 432                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 433                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 434                      enable_kernel_module="no"
 435                  fi
 436                  if test "x$enable_kernel_module" = "xno"; then
 437                   if test "x$with_linux_kernel_headers" != "x"; then
 438                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 439                    exit 1
 440                   else
 441                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 442                   fi
 443                  fi
 444                  dnl do we need to determine SUBARCH from autoconf.h
 445                  SUBARCH=default
 446                 fi
 447                 AC_MSG_RESULT(linux)
 448                 GUESS_LINUX_VERSION=
 449                 if test "x$enable_kernel_module" = "xyes"; then
 450                  GUESS_LINUX_VERSION=${LINUX_VERSION}
 451                 else
 452                  GUESS_LINUX_VERSION=`uname -r`
 453                 fi
 454                 case "$GUESS_LINUX_VERSION" in
 455                   2.2.*) AFS_SYSKVERS=22 ;;
 456                   2.4.*) AFS_SYSKVERS=24 ;;
 457                   [2.6.* | [3-9]* | [1-2][0-9]*]) AFS_SYSKVERS=26 ;;
 458                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 459                 esac
 460                 ;;
 461         *-solaris*)
 462                 MKAFS_OSTYPE=SOLARIS
 463                 AC_MSG_RESULT(sun4)
 464                 AC_PATH_PROG(SOLARISCC, [cc], ,
 465                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 466                 if test "x$SOLARISCC" = "x" ; then
 467                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 468                 fi
 469                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 470                 SOLARIS_FS_HAS_FS_ROLLED
 471                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 472                 SOLARIS_HAVE_VN_RENAMEPATH
 473                 ;;
 474         *-sunos*)
 475                 MKAFS_OSTYPE=SUNOS
 476                 enable_kernel_module=no
 477                 AC_MSG_RESULT(sun4)
 478                 ;;
 479         *-hpux*)
 480                 MKAFS_OSTYPE=HPUX
 481                 AC_MSG_RESULT(hp_ux)
 482                 if test -f "/usr/old/usr/include/ndir.h"; then
 483                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 484                 fi
 485                 ;;
 486         *-irix*)
 487                 if test -d /usr/include/sys/SN/SN1; then
 488                  IRIX_BUILD_IP35="IP35"
 489                 fi
 490                 MKAFS_OSTYPE=IRIX
 491                 AC_MSG_RESULT(sgi)
 492                 ;;
 493         *-aix*)
 494                 MKAFS_OSTYPE=AIX
 495                 AC_MSG_RESULT(rs_aix)
 496                 ;;
 497         arm-*-darwin*)
 498                 MKAFS_OSTYPE=DARWIN
 499                 AC_MSG_RESULT(arm_darwin)
 500                 ;;
 501         powerpc-*-darwin*)
 502                 MKAFS_OSTYPE=DARWIN
 503                 AC_MSG_RESULT(ppc_darwin)
 504                 ;;
 505         i386-*-darwin*)
 506                 MKAFS_OSTYPE=DARWIN
 507                 AC_MSG_RESULT(x86_darwin)
 508                 ;;
 509         x86_64-*-darwin*)
 510                 MKAFS_OSTYPE=DARWIN
 511                 AC_MSG_RESULT(x86_darwin)
 512                 ;;
 513         i386-*-freebsd*)
 514                 MKAFS_OSTYPE=FBSD
 515                 AC_MSG_RESULT(i386_fbsd)
 516                 ;;
 517         x86_64-*-freebsd*)
 518                 MKAFS_OSTYPE=FBSD
 519                 AC_MSG_RESULT(amd64_fbsd)
 520                 ;;
 521         *-netbsd*)
 522                 MKAFS_OSTYPE=NBSD
 523                 AC_MSG_RESULT(nbsd)
 524                 ;;
 525         x86_64-*-openbsd*)
 526                 MKAFS_OSTYPE=OBSD
 527                 AC_MSG_RESULT(amd64_obsd)
 528                 ;;
 529         i386-*-openbsd*)
 530                 MKAFS_OSTYPE=OBSD
 531                 AC_MSG_RESULT(i386_obsd)
 532                 ;;
 533         *-dragonfly*)
 534                 MKAFS_OSTYPE=DFBSD
 535                 AC_MSG_RESULT(i386_dfbsd)
 536                 ;;
 537         *)
 538                 AC_MSG_RESULT($system)
 539                 ;;
 540 esac
 541
 542 if test "x$with_afs_sysname" != "x"; then
 543         AFS_SYSNAME="$with_afs_sysname"
 544 else
 545         AC_MSG_CHECKING(your AFS sysname)
 546         case $host in
 547                 i?86-*-openbsd?.?)
 548                         v=${host#*openbsd}
 549                         vM=${v%.*}
 550                         vm=${v#*.}
 551                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 552                         ;;
 553                 sparc64-*-openbsd?.?)
 554                         v=${host#*openbsd}
 555                         vM=${v%.*}
 556                         vm=${v#*.}
 557                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 558                         ;;
 559                 x86_64-*-openbsd?.?)
 560                         v=${host#*openbsd}
 561                         vM=${v%.*}
 562                         vm=${v#*.}
 563                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 564                         ;;
 565                 i?86-*-freebsd*.*)
 566                         v=${host#*freebsd}
 567                         vM=${v%.*}
 568                         vm=${v#*.}
 569                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 570                         ;;
 571                 x86_64-*-freebsd*.*)
 572                         v=${host#*freebsd}
 573                         vM=${v%.*}
 574                         vm=${v#*.}
 575                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 576                         ;;
 577                 i386-*-dragonfly?.*)
 578                         v=${host#*dragonfly}
 579                         vM=${v%.*}
 580                         vm=${v#*.}
 581                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 582                         ;;
 583                 i?86-*-netbsd*1.6[[M-Z]]*)
 584                         AFS_SYSNAME="i386_nbsd20"
 585                         ;;
 586                 powerpc-*-netbsd*1.6[[M-Z]]*)
 587                         AFS_SYSNAME="ppc_nbsd20"
 588                         ;;
 589                 *-*-netbsd*)
 590                         arch=${host%%-unknown*}
 591                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 592                                                -e 's/powerpc/ppc/g')
 593                         v=${host#*netbsd}
 594                         v=${v#*aout}
 595                         v=${v#*ecoff}
 596                         v=${v#*elf}
 597                         vM=${v%%.*}
 598                         vM=${vM%.*}
 599                         v=${v#*.}
 600                         vm=${v%%.*}
 601                         vm=${vm%.*}
 602                         vm=${vm%%[[_A-Z]]*}
 603                         if test $vm -eq 99 ; then
 604                                 vM=$((vM+1))
 605                         fi
 606                         if test $vM -gt 1 ; then
 607                                 vm=0
 608                         fi
 609                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 610                         ;;
 611                 hppa*-hp-hpux11.0*)
 612                         AFS_SYSNAME="hp_ux110"
 613                         ;;
 614                 hppa*-hp-hpux11.11)
 615                         AFS_SYSNAME="hp_ux11i"
 616                         ;;
 617                 hppa*-hp-hpux11.23)
 618                         AFS_SYSNAME="hp_ux1123"
 619                         ;;
 620                 ia64-hp-hpux11.22)
 621                         AFS_SYSNAME="ia64_hpux1122"
 622                         ;;
 623                 ia64-hp-hpux*)
 624                         AFS_SYSNAME="ia64_hpux1123"
 625                         ;;
 626                 hppa*-hp-hpux10*)
 627                         AFS_SYSNAME="hp_ux102"
 628                         ;;
 629                 powerpc-apple-darwin7*)
 630                         AFS_SYSNAME="ppc_darwin_70"
 631                         OSXSDK="macosx10.3"
 632                         ;;
 633                 powerpc-apple-darwin8.*)
 634                         AFS_SYSNAME="ppc_darwin_80"
 635                         OSXSDK="macosx10.4"
 636                         ;;
 637                 i386-apple-darwin8.*)
 638                         AFS_SYSNAME="x86_darwin_80"
 639                         OSXSDK="macosx10.4"
 640                         ;;
 641                 powerpc-apple-darwin9.*)
 642                         AFS_SYSNAME="ppc_darwin_90"
 643                         OSXSDK="macosx10.5"
 644                         ;;
 645                 i386-apple-darwin9.*)
 646                         AFS_SYSNAME="x86_darwin_90"
 647                         OSXSDK="macosx10.5"
 648                         ;;
 649                 i?86-apple-darwin10.*)
 650                         AFS_SYSNAME="x86_darwin_100"
 651                         OSXSDK="macosx10.6"
 652                         ;;
 653                 x86_64-apple-darwin10.*)
 654                         AFS_SYSNAME="x86_darwin_100"
 655                         OSXSDK="macosx10.6"
 656                         ;;
 657                 arm-apple-darwin10.*)
 658                         AFS_SYSNAME="arm_darwin_100"
 659                         OSXSDK="iphoneos4.0"
 660                         ;;
 661                 x86_64-apple-darwin11.*)
 662                         AFS_SYSNAME="x86_darwin_110"
 663                         OSXSDK="macosx10.7"
 664                         ;;
 665                 i?86-apple-darwin11.*)
 666                         AFS_SYSNAME="x86_darwin_110"
 667                         OSXSDK="macosx10.7"
 668                         ;;
 669                 x86_64-apple-darwin12.*)
 670                         AFS_SYSNAME="x86_darwin_120"
 671                         OSXSDK="macosx10.8"
 672                         ;;
 673                 i?86-apple-darwin12.*)
 674                         AFS_SYSNAME="x86_darwin_120"
 675                         OSXSDK="macosx10.8"
 676                         ;;
 677                 x86_64-apple-darwin13.*)
 678                         AFS_SYSNAME="x86_darwin_130"
 679                         OSXSDK="macosx10.9"
 680                         ;;
 681                 i?86-apple-darwin13.*)
 682                         AFS_SYSNAME="x86_darwin_130"
 683                         OSXSDK="macosx10.9"
 684                         ;;
 685                 x86_64-apple-darwin14.*)
 686                         AFS_SYSNAME="x86_darwin_140"
 687                         OSXSDK="macosx10.10"
 688                         ;;
 689                 i?86-apple-darwin14.*)
 690                         AFS_SYSNAME="x86_darwin_140"
 691                         OSXSDK="macosx10.10"
 692                         ;;
 693                 x86_64-apple-darwin15.*)
 694                         AFS_SYSNAME="x86_darwin_150"
 695                         OSXSDK="macosx10.11"
 696                         ;;
 697                 i?86-apple-darwin15.*)
 698                         AFS_SYSNAME="x86_darwin_150"
 699                         OSXSDK="macosx10.11"
 700                         ;;
 701                 sparc-sun-solaris2.8)
 702                         AFS_SYSNAME="sun4x_58"
 703                         ;;
 704                 sparc-sun-solaris2.9)
 705                         AFS_SYSNAME="sun4x_59"
 706                         ;;
 707                 sparc-sun-solaris2.10)
 708                         AFS_SYSNAME="sun4x_510"
 709                         ;;
 710                 sparc-sun-solaris2.11)
 711                         AFS_SYSNAME="sun4x_511"
 712                         ;;
 713                 i386-pc-solaris2.8)
 714                         AFS_SYSNAME="sunx86_58"
 715                         ;;
 716                 i386-pc-solaris2.9)
 717                         AFS_SYSNAME="sunx86_59"
 718                         ;;
 719                 i386-pc-solaris2.10)
 720                         AFS_SYSNAME="sunx86_510"
 721                         ;;
 722                 i386-pc-solaris2.11)
 723                         AFS_SYSNAME="sunx86_511"
 724                         ;;
 725                 alpha*-dec-osf4.0*)
 726                         AFS_SYSNAME="alpha_dux40"
 727                         ;;
 728                 alpha*-dec-osf5.0*)
 729                         AFS_SYSNAME="alpha_dux50"
 730                         ;;
 731                 alpha*-dec-osf5.1*)
 732                         AFS_SYSNAME="alpha_dux51"
 733                         ;;
 734                 mips-sgi-irix6.5)
 735                         AFS_SYSNAME="sgi_65"
 736                         enable_pam="no"
 737                         ;;
 738                 ia64-*-linux*)
 739                         AFS_SYSNAME="ia64_linuxXX"
 740                         ;;
 741                 powerpc-*-linux*)
 742                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 743                         ;;
 744                 powerpc64-*-linux*)
 745                         AFS_SYSNAME="ppc64_linuxXX"
 746                         ;;
 747                 alpha*-linux*)
 748                         AFS_SYSNAME="alpha_linux_XX"
 749                         ;;
 750                 s390-*-linux*)
 751                         AFS_SYSNAME="s390_linuxXX"
 752                         ;;
 753                 s390x-*-linux*)
 754                         AFS_SYSNAME="s390x_linuxXX"
 755                         ;;
 756                 sparc-*-linux*)
 757                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 758                         ;;
 759                 sparc64-*-linux*)
 760                         AFS_SYSNAME="sparc64_linuxXX"
 761                         ;;
 762                 i?86-*-linux*)
 763                         AFS_SYSNAME="i386_linuxXX"
 764                         ;;
 765                 arm*-linux*)
 766                         AFS_SYSNAME="arm_linuxXX"
 767                         ;;
 768                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 769                         AFS_SYSNAME="parisc_linuxXX"
 770                         enable_pam="no"
 771                         ;;
 772                 power*-ibm-aix4.2*)
 773                         AFS_SYSNAME="rs_aix42"
 774                         enable_pam="no"
 775                         ;;
 776                 power*-ibm-aix4.3*)
 777                         AFS_SYSNAME="rs_aix42"
 778                         enable_pam="no"
 779                         ;;
 780                 power*-ibm-aix5.1*)
 781                         AFS_SYSNAME="rs_aix51"
 782                         enable_pam="no"
 783                         ;;
 784                 power*-ibm-aix5.2*)
 785                         AFS_SYSNAME="rs_aix52"
 786                         enable_pam="no"
 787                         ;;
 788                 power*-ibm-aix5.3*)
 789                         AFS_SYSNAME="rs_aix53"
 790                         enable_pam="no"
 791                         ;;
 792                 power*-ibm-aix6.1*)
 793                         AFS_SYSNAME="rs_aix61"
 794                         enable_pam="no"
 795                         ;;
 796                 x86_64-*-linux-gnu)
 797                         AFS_SYSNAME="amd64_linuxXX"
 798                         enable_pam="yes"
 799                         ;;
 800                 *)
 801                         AC_MSG_ERROR(An AFS sysname is required)
 802                         exit 1
 803                         ;;
 804         esac
 805         case $AFS_SYSNAME in
 806                 *_linux* | *_umlinux*)
 807                         if test "x${AFS_SYSKVERS}" = "x"; then
 808                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 809                         fi
 810                         if test "x${AFS_SYSKVERS}" = "x24" ||
 811                                 test "x${AFS_SYSKVERS}" = "x22"; then
 812                             AC_MSG_ERROR([Linux 2.4.x and older are no longer supported by OpenAFS.  Please use an OpenAFS 1.6.x release on those systems.])
 813                         fi
 814                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 815                         AFS_SYSNAME="$_AFS_SYSNAME"
 816                         AC_TRY_KBUILD(
 817                          [],
 818                          [#ifndef CONFIG_USERMODE
 819                           #error not UML
 820                           #endif],
 821                          ac_cv_linux_is_uml=yes,)
 822                         if test "${ac_cv_linux_is_uml}" = yes; then
 823                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 824                         fi
 825                         AFS_SYSNAME="$_AFS_SYSNAME"
 826                         ;;
 827         esac
 828         AC_MSG_RESULT($AFS_SYSNAME)
 829 fi
 830
 831 case $AFS_SYSNAME in
 832         *_darwin*)
 833                 AC_CHECK_HEADERS(crt_externs.h)
 834                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 835                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 836                 AC_SUBST(OSXSDK)
 837                 ;;
 838 esac
 839
 840 dnl Some hosts have a separate common param file they should include.  Figure
 841 dnl out if we're on one of them now that we know the sysname.
 842 case $AFS_SYSNAME in
 843     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 844     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 845     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 846     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 847     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 848     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 849     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 850     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 851     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
 852     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 853     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 854     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 855     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 856     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 857     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 858     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 859     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 860     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 861     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 862     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 863     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 864     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 865     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 866     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 867     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 868     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 869     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 870     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
 871     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
 872     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
 873     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
 874     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
 875     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
 876     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 877 # Linux alpha adds an extra underscore for no good reason.
 878     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 879     *_fbsd_*)   AFS_PARAM_COMMON=param.generic_fbsd.h ;;
 880 esac
 881
 882 OPENAFS_OSCONF
 883
 884 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 885
 886                 # Add (sub-) architecture-specific paths needed by conftests
 887                 case $AFS_SYSNAME  in
 888                         *_umlinux26)
 889                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 890                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 891                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 892                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 893                 esac
 894
 895                 if test "x$enable_kernel_module" = "xyes"; then
 896                  if test "x$enable_debug_kernel" = "xno"; then
 897                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 898                  fi
 899                  OPENAFS_GCC_SUPPORTS_MARCH
 900                  AC_SUBST(P5PLUS_KOPTS)
 901                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 902                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 903                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 904                  OPENAFS_GCC_SUPPORTS_PIPE
 905                  AC_SUBST(LINUX_GCC_KOPTS)
 906
 907                  dnl Setup the kernel build environment
 908                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 909                  LINUX_KERNEL_COMPILE_WORKS
 910
 911                  dnl Operation signature checks
 912                  AC_CHECK_LINUX_OPERATION([inode_operations], [follow_link], [no_nameidata],
 913                                           [#include <linux/fs.h>],
 914                                           [const char *],
 915                                           [struct dentry *dentry, void **link_data])
 916                  AC_CHECK_LINUX_OPERATION([inode_operations], [put_link], [no_nameidata],
 917                                           [#include <linux/fs.h>],
 918                                           [void],
 919                                           [struct inode *inode, void *link_data])
 920
 921                  dnl Check for header files
 922                  AC_CHECK_LINUX_HEADER([config.h])
 923                  AC_CHECK_LINUX_HEADER([exportfs.h])
 924                  AC_CHECK_LINUX_HEADER([freezer.h])
 925                  AC_CHECK_LINUX_HEADER([key-type.h])
 926                  AC_CHECK_LINUX_HEADER([semaphore.h])
 927                  AC_CHECK_LINUX_HEADER([seq_file.h])
 928
 929                  dnl Type existence checks
 930                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 931                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
 932
 933                  dnl Check for structure elements
 934                  AC_CHECK_LINUX_STRUCT([address_space], [backing_dev_info], [fs.h])
 935                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 936                                        [write_begin], [fs.h])
 937                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 938                                        [backing-dev.h])
 939                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
 940                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 941                  AC_CHECK_LINUX_STRUCT([dentry], [d_u.d_alias], [dcache.h])
 942                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 943                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 944                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 945                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 946                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 947                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 948                  AC_CHECK_LINUX_STRUCT([file], [f_path], [fs.h])
 949                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 950                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
 951                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
 952                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 953                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 954                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
 955                  AC_CHECK_LINUX_STRUCT([inode_operations], [get_link], [fs.h])
 956                  AC_CHECK_LINUX_STRUCT([key], [payload.value], [key.h])
 957                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
 958                  AC_CHECK_LINUX_STRUCT([key_type], [match_preparse], [key-type.h])
 959                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
 960                  AC_CHECK_LINUX_STRUCT([msghdr], [msg_iter], [socket.h])
 961                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 962                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 963                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 964                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 965                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 966                                        [fs.h])
 967                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 968                                        [fs.h])
 969                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 970                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 971                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 972                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 973                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 974                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 975                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 976                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 977                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 978                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 979                  AC_CHECK_LINUX_STRUCT([task_struct], [total_link_count], [sched.h])
 980                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 981
 982                  dnl Check for typed structure elements
 983                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 984                                              [buf], [fs.h])
 985
 986                  dnl Function existence checks
 987
 988                  AC_CHECK_LINUX_FUNC([__vfs_read],
 989                                      [#include <linux/fs.h>],
 990                                      [__vfs_read(NULL, NULL, 0, NULL);])
 991                  AC_CHECK_LINUX_FUNC([bdi_init],
 992                                      [#include <linux/backing-dev.h>],
 993                                      [bdi_init(NULL);])
 994                  AC_CHECK_LINUX_FUNC([PageChecked],
 995                                      [#include <linux/mm.h>
 996 #include <linux/page-flags.h>],
 997                                      [struct page *_page;
 998                                       int bchecked = PageChecked(_page);])
 999                  AC_CHECK_LINUX_FUNC([PageFsMisc],
1000                                      [#include <linux/mm.h>
1001 #include <linux/page-flags.h>],
1002                                      [struct page *_page;
1003                                       int bchecked = PageFsMisc(_page);])
1004                  AC_CHECK_LINUX_FUNC([clear_inode],
1005                                      [#include <linux/fs.h>],
1006                                      [clear_inode(NULL);])
1007                  AC_CHECK_LINUX_FUNC([current_kernel_time],
1008                                      [#include <linux/time.h>],
1009                                      [struct timespec s;
1010                                       s = current_kernel_time();])
1011                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
1012                                      [#include <linux/fs.h>],
1013                                      [d_alloc_anon(NULL);])
1014                  AC_CHECK_LINUX_FUNC([d_count],
1015                                      [#include <linux/dcache.h>],
1016                                      [d_count(NULL);])
1017                  AC_CHECK_LINUX_FUNC([d_make_root],
1018                                      [#include <linux/fs.h>],
1019                                      [d_make_root(NULL);])
1020                  AC_CHECK_LINUX_FUNC([do_sync_read],
1021                                      [#include <linux/fs.h>],
1022                                      [do_sync_read(NULL, NULL, 0, NULL);])
1023                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
1024                                      [#include <linux/sched.h>],
1025                                      [pid_t p; find_task_by_pid(p);])
1026                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
1027                                      [#include <linux/fs.h>],
1028                                      [generic_file_aio_read(NULL,NULL,0,0);])
1029                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
1030                                      [#include <linux/pagemap.h>],
1031                                      [grab_cache_page_write_begin(NULL, 0, 0);])
1032                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
1033                                      [#include <linux/list.h>],
1034                                      [hlist_unhashed(0);])
1035                  AC_CHECK_LINUX_FUNC([ihold],
1036                                      [#include <linux/fs.h>],
1037                                      [ihold(NULL);])
1038                  AC_CHECK_LINUX_FUNC([i_size_read],
1039                                      [#include <linux/fs.h>],
1040                                      [i_size_read(NULL);])
1041                  AC_CHECK_LINUX_FUNC([inode_setattr],
1042                                      [#include <linux/fs.h>],
1043                                      [inode_setattr(NULL, NULL);])
1044                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
1045                                      [#include <linux/fs.h>],
1046                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
1047                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
1048                                      [#include <linux/net.h>],
1049                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
1050                  AC_CHECK_LINUX_FUNC([locks_lock_file_wait],
1051                                      [#include <linux/fs.h>],
1052                                      [locks_lock_file_wait(NULL, NULL);])
1053                  AC_CHECK_LINUX_FUNC([page_follow_link],
1054                                      [#include <linux/fs.h>],
1055                                      [page_follow_link(0,0);])
1056                  AC_CHECK_LINUX_FUNC([page_get_link],
1057                                      [#include <linux/fs.h>],
1058                                      [page_get_link(0,0,0);])
1059                  AC_CHECK_LINUX_FUNC([page_offset],
1060                                      [#include <linux/pagemap.h>],
1061                                      [page_offset(NULL);])
1062                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
1063                                      [#include <linux/pagevec.h>],
1064                                      [__pagevec_lru_add_file(NULL);])
1065                  AC_CHECK_LINUX_FUNC([path_lookup],
1066                                      [#include <linux/fs.h>
1067                                       #include <linux/namei.h>],
1068                                      [path_lookup(NULL, 0, NULL);])
1069                  AC_CHECK_LINUX_FUNC([proc_create],
1070                                      [#include <linux/proc_fs.h>],
1071                                      [proc_create(NULL, 0, NULL, NULL);])
1072                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
1073                                      [#include <linux/rcupdate.h>],
1074                                      [rcu_read_lock();])
1075                  AC_CHECK_LINUX_FUNC([set_nlink],
1076                                      [#include <linux/fs.h>],
1077                                      [set_nlink(NULL, 1);])
1078                  AC_CHECK_LINUX_FUNC([sock_create_kern],
1079                                      [#include <linux/net.h>],
1080                                      [sock_create_kern(0, 0, 0, NULL);])
1081                  AC_CHECK_LINUX_FUNC([sock_create_kern_ns],
1082                                      [#include <linux/net.h>],
1083                                      [sock_create_kern(NULL, 0, 0, 0, NULL);])
1084                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
1085                                      [#include <linux/splice.h>],
1086                                      [splice_direct_to_actor(NULL,NULL,NULL);])
1087                  AC_CHECK_LINUX_FUNC([default_file_splice_read],
1088                                      [#include <linux/fs.h>],
1089                                      [default_file_splice_read(NULL,NULL,NULL, 0, 0);])
1090                  AC_CHECK_LINUX_FUNC([svc_addr_in],
1091                                      [#include <linux/sunrpc/svc.h>],
1092                                      [svc_addr_in(NULL);])
1093                  AC_CHECK_LINUX_FUNC([zero_user_segments],
1094                                      [#include <linux/highmem.h>],
1095                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1096                  AC_CHECK_LINUX_FUNC([noop_fsync],
1097                                      [#include <linux/fs.h>],
1098                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1099                  AC_CHECK_LINUX_FUNC([kthread_run],
1100                                      [#include <linux/kernel.h>
1101                                       #include <linux/kthread.h>],
1102                                      [kthread_run(NULL, NULL, "test");])
1103                  AC_CHECK_LINUX_FUNC([inode_nohighmem],
1104                                      [#include <linux/fs.h>],
1105                                      [inode_nohighmem(NULL);])
1106                  AC_CHECK_LINUX_FUNC([inode_lock],
1107                                      [#include <linux/fs.h>],
1108                                      [inode_lock(NULL);])
1109
1110                  dnl Consequences - things which get set as a result of the
1111                  dnl                above tests
1112                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1113                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1114                                   [define to disable the nfs translator])])
1115
1116                  dnl Assorted more complex tests
1117                  LINUX_AIO_NONVECTOR
1118                  LINUX_EXPORTS_PROC_ROOT_FS
1119                  LINUX_KMEM_CACHE_INIT
1120                  LINUX_HAVE_KMEM_CACHE_T
1121                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1122                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1123                  LINUX_D_PATH_TAKES_STRUCT_PATH
1124                  LINUX_NEW_EXPORT_OPS
1125                  LINUX_INODE_SETATTR_RETURN_TYPE
1126                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1127                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1128                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1129                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1130                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1131                  LINUX_DOP_D_DELETE_TAKES_CONST
1132                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1133                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1134                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1135                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1136                  LINUX_AOP_WRITEBACK_CONTROL
1137                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1138                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1139                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1140                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1141                  LINUX_KERNEL_SOCK_CREATE
1142                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1143                  LINUX_NEED_RHCONFIG
1144                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1145                  LINUX_EXPORTS_TASKLIST_LOCK
1146                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1147                  LINUX_STATFS_TAKES_DENTRY
1148                  LINUX_REFRIGERATOR
1149                  LINUX_HAVE_TRY_TO_FREEZE
1150                  LINUX_LINUX_KEYRING_SUPPORT
1151                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1152                  LINUX_KEY_ALLOC_NEEDS_CRED
1153                  LINUX_INIT_WORK_HAS_DATA
1154                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1155                  LINUX_HAVE_DCACHE_LOCK
1156                  LINUX_D_COUNT_IS_INT
1157                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1158                  LINUX_IOP_CREATE_TAKES_UMODE_T
1159                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1160                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1161                  LINUX_DENTRY_OPEN_TAKES_PATH
1162                  LINUX_D_ALIAS_IS_HLIST
1163                  LINUX_HLIST_ITERATOR_NO_NODE
1164                  LINUX_IOP_I_CREATE_TAKES_BOOL
1165                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1166                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1167                  LINUX_D_INVALIDATE_IS_VOID
1168
1169                  dnl If we are guaranteed that keyrings will work - that is
1170                  dnl  a) The kernel has keyrings enabled
1171                  dnl  b) The code is new enough to give us a key_type_keyring
1172                  dnl then we just disable syscall probing unless we've been
1173                  dnl told otherwise
1174
1175                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1176                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1177                           [enable_linux_syscall_probing="no"],
1178                           [enable_linux_syscall_probing="yes"])
1179                  ])
1180
1181                  dnl Syscall probing needs a few tests of its own, and just
1182                  dnl won't work if the kernel doesn't export init_mm
1183                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1184                    LINUX_EXPORTS_INIT_MM
1185                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1186                      AC_MSG_ERROR(
1187                        [Can't do syscall probing without exported init_mm])
1188                    ])
1189                    LINUX_EXPORTS_SYS_CHDIR
1190                    LINUX_EXPORTS_SYS_OPEN
1191                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1192                              [define to enable syscall table probes])
1193                  ])
1194
1195                  dnl Packaging and SMP build
1196                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1197                    LINUX_WHICH_MODULES
1198                  else
1199                    AC_SUBST(MPS,'SP')
1200                  fi
1201
1202                  dnl Syscall probing
1203                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1204                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1205                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1206                    ])
1207                    ac_cv_linux_exports_sys_call_table=no
1208                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1209                      ac_cv_linux_exports_ia32_sys_call_table=yes
1210                    fi
1211                  else
1212                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1213                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1214                    LINUX_EXPORTS_SYS_CALL_TABLE
1215                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1216                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1217                          linux_syscall_method=none
1218                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1219                             linux_syscall_method=scan
1220                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1221                                linux_syscall_method=scan_with_kallsyms_address
1222                             fi
1223                          fi
1224                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1225                             linux_syscall_method=kallsyms_symbol
1226                          fi
1227                          if test "x$linux_syscall_method" = "xnone"; then
1228                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1229                             linux_syscall_method=scan
1230                          fi
1231                    fi
1232                  fi
1233                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1234                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1235                  fi
1236                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1237                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1238                  fi
1239                  if test "x$ac_cv_linux_func_page_get_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1240                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1241                  else
1242                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1243                  fi
1244                  if test "x$ac_cv_linux_func_page_get_link" != "xyes" -a "x$ac_cv_linux_struct_inode_operations_has_get_link" = "xyes"; then
1245                         AC_MSG_ERROR([Your kernel does not use follow_link - not supported without symlink cache API])
1246                         exit 1
1247                  fi
1248                 :
1249                 fi
1250                 if test "x$enable_linux_d_splice_alias_extra_iput" = xyes; then
1251                     AC_DEFINE(D_SPLICE_ALIAS_LEAK_ON_ERROR, 1, [for internal use])
1252                 fi
1253 dnl Linux-only, but just enable always.
1254                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1255 esac
1256
1257 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1258     [ac_cv_sync_fetch_and_add],
1259     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1260                     [ac_cv_sync_fetch_and_add=yes],
1261                     [ac_cv_sync_fetch_and_add=no])
1262 ])
1263 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1264       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1265                 [define if your C compiler has __sync_add_and_fetch])])
1266
1267 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1268     [ac_cv_sockaddr_len],
1269     [AC_TRY_COMPILE( [#include <sys/types.h>
1270 #include <sys/socket.h>],
1271                      [struct sockaddr *a; a->sa_len=0;],
1272                      [ac_cv_sockaddr_len=yes],
1273                      [ac_cv_sockaddr_len=no])
1274 ])
1275 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1276       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1277                  [define if you struct sockaddr sa_len])])
1278
1279 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1280         echo Skipping library tests because they confuse Irix.
1281 else
1282   AC_SEARCH_LIBS([socket], [socket inet])
1283   AC_SEARCH_LIBS([connect], [nsl])
1284   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1285
1286   dnl darwin wants it, aix hates it
1287   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1288   AC_TRY_COMPILE([
1289   #include <stdlib.h>
1290   #include <stdio.h>
1291   #include <sys/types.h>
1292   #include <sys/socket.h>
1293   #include <netinet/in.h>
1294   #include <arpa/inet.h>
1295   #include <arpa/nameser.h>
1296   #include <arpa/nameser_compat.h>
1297   #include <resolv.h>
1298   ], [static int i; i = 0;],
1299   [AC_MSG_RESULT(yes)
1300    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1301   [AC_MSG_RESULT(no)
1302    ])
1303
1304   openafs_save_libs="$LIBS"
1305   AC_MSG_CHECKING([for res_search])
1306   AC_FUNC_RES_SEARCH
1307
1308   if test "$ac_cv_func_res_search" = no; then
1309       for lib in dns nsl resolv; do
1310         if test "$ac_cv_func_res_search" != yes; then
1311           LIBS="-l$lib $LIBS"
1312           AC_FUNC_RES_SEARCH
1313           LIBS="$openafs_save_libs"
1314         fi
1315       done
1316       if test "$ac_cv_func_res_search" = yes; then
1317         LIB_AFSDB="-l$lib"
1318         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1319         AC_MSG_RESULT([yes, in lib$lib])
1320       else
1321         AC_MSG_RESULT(no)
1322       fi
1323   else
1324     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1325     AC_MSG_RESULT(yes)
1326   fi
1327
1328 fi
1329 XLIBS="$LIB_AFSDB $XLIBS"
1330
1331 AC_CHECK_RESOLV_RETRANS
1332
1333 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1334     [ac_cv_setsockopt_iprecverr],
1335     [AC_TRY_COMPILE( [
1336 #include <sys/types.h>
1337 #include <sys/socket.h>
1338 #include <netinet/in.h>],
1339 [int on=1;
1340 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1341         [ac_cv_setsockopt_iprecverr=yes],
1342         [ac_cv_setsockopt_iprecverr=no])])
1343
1344 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1345       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1346                  [define if we can receive socket errors via IP_RECVERR])])
1347
1348 PTHREAD_LIBS=error
1349 if test "x$MKAFS_OSTYPE" = OBSD; then
1350         PTHREAD_LIBS="-pthread"
1351 fi
1352 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1353         PTHREAD_LIBS="-pthread"
1354 fi
1355 if test "x$PTHREAD_LIBS" = xerror; then
1356         AC_CHECK_LIB(pthread, pthread_attr_init,
1357                 PTHREAD_LIBS="-lpthread")
1358 fi
1359 if test "x$PTHREAD_LIBS" = xerror; then
1360         AC_CHECK_LIB(pthreads, pthread_attr_init,
1361                 PTHREAD_LIBS="-lpthreads")
1362 fi
1363 if test "x$PTHREAD_LIBS" = xerror; then
1364         AC_CHECK_LIB(c_r, pthread_attr_init,
1365                 PTHREAD_LIBS="-lc_r")
1366 fi
1367 if test "x$PTHREAD_LIBS" = xerror; then
1368         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1369 fi
1370 if test "x$PTHREAD_LIBS" = xerror; then
1371         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1372         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1373                 PTHREAD_LIBS="-lpthread")
1374 fi
1375 if test "x$PTHREAD_LIBS" = xerror; then
1376         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1377 fi
1378 AC_SUBST(PTHREAD_LIBS)
1379
1380 HOST_CPU="$host_cpu"
1381
1382 if test "x$with_bsd_kernel_headers" != "x"; then
1383         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1384 else
1385         BSD_KERNEL_PATH="/usr/src/sys"
1386 fi
1387
1388 if test "x$with_bsd_kernel_build" != "x"; then
1389         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1390 else
1391         case $AFS_SYSNAME in
1392                 *_fbsd_*)
1393                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1394                         ;;
1395                 *_nbsd*)
1396                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1397         esac
1398 fi
1399
1400 # Fast restart
1401 if test "$enable_supergroups" = "yes"; then
1402         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1403 fi
1404
1405 if test "$enable_bitmap_later" = "yes"; then
1406         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1407 fi
1408
1409 if test "$enable_unix_sockets" = "yes"; then
1410         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1411         USE_UNIX_SOCKETS="yes"
1412 else
1413         USE_UNIX_SOCKETS="no"
1414 fi
1415 AC_SUBST(USE_UNIX_SOCKETS)
1416
1417 if test "$enable_ubik_read_while_write" = "yes"; then
1418         AC_DEFINE(UBIK_READ_WHILE_WRITE, 1, [define if you want to enable ubik read while write])
1419 fi
1420
1421 if test "$enable_namei_fileserver" = "yes"; then
1422         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1423         VFSCK=""
1424 else
1425         if test "$enable_namei_fileserver" = "default"; then
1426                 case $host in
1427                         *-solaris2.10*)
1428                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1429                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1430                                 VFSCK=""
1431                                 ;;
1432                         *-solaris2.11*)
1433                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1434                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1435                                 VFSCK=""
1436                                 ;;
1437                         *)
1438                                 VFSCK="vfsck"
1439                                 ;;
1440                 esac
1441         else
1442                 VFSCK="vfsck"
1443         fi
1444 fi
1445
1446 dnl check for tivoli
1447 AC_MSG_CHECKING(for tivoli tsm butc support)
1448 XBSA_CFLAGS=""
1449 if test "$enable_tivoli_tsm" = "yes"; then
1450         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1451         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1452         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1453         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1454         XBSADIR5=/usr/tivoli/tsm/client/api/bin64/sample
1455         XBSADIR6=/opt/tivoli/tsm/client/api/bin64/sample
1456
1457         if test -r "$XBSADIR3/dsmapifp.h"; then
1458                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1459                 XBSA_XLIBS="-ldl"
1460                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1461         elif test -r "$XBSADIR4/dsmapifp.h"; then
1462                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1463                 XBSA_XLIBS="-ldl"
1464                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1465         elif test -r "$XBSADIR5/dsmapifp.h"; then
1466                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR5"
1467                 XBSA_XLIBS="-ldl"
1468                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1469         elif test -r "$XBSADIR6/dsmapifp.h"; then
1470                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR6"
1471                 XBSA_XLIBS="-ldl"
1472                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1473         elif test -r "$XBSADIR1/xbsa.h"; then
1474                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1475                 XBSA_XLIBS=""
1476                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1477         elif test -r "$XBSADIR2/xbsa.h"; then
1478                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1479                 XBSA_XLIBS=""
1480                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1481         else
1482                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1483         fi
1484 else
1485         AC_MSG_RESULT([no])
1486 fi
1487 AC_SUBST(XBSA_CFLAGS)
1488 AC_SUBST(XBSA_XLIBS)
1489 XLIBS="$XBSA_XLIBS $XLIBS"
1490
1491 dnl checks for header files.
1492 AC_HEADER_STDC
1493 AC_HEADER_SYS_WAIT
1494 AC_HEADER_DIRENT
1495 AC_CHECK_HEADERS([ \
1496                    arpa/inet.h \
1497                    arpa/nameser.h \
1498                    curses.h\
1499                    direct.h \
1500                    errno.h \
1501                    fcntl.h \
1502                    grp.h \
1503                    math.h \
1504                    mntent.h \
1505                    ncurses.h \
1506                    ncurses/ncurses.h \
1507                    netdb.h \
1508                    netinet/in.h \
1509                    pthread_np.h \
1510                    pwd.h \
1511                    regex.h \
1512                    security/pam_appl.h \
1513                    signal.h \
1514                    stdint.h \
1515                    stdio_ext.h \
1516                    stdlib.h \
1517                    string.h \
1518                    strings.h \
1519                    sys/bitypes.h \
1520                    sys/bswap.h \
1521                    sys/dk.h \
1522                    sys/fcntl.h \
1523                    sys/file.h \
1524                    sys/fs_types.h \
1525                    sys/fstyp.h \
1526                    sys/ioctl.h \
1527                    sys/ipc.h \
1528                    sys/lockf.h \
1529                    sys/map.h \
1530                    sys/mount.h \
1531                    sys/mntent.h \
1532                    sys/mnttab.h \
1533                    sys/pag.h \
1534                    sys/param.h \
1535                    sys/resource.h \
1536                    sys/select.h \
1537                    sys/statfs.h \
1538                    sys/statvfs.h \
1539                    sys/socket.h \
1540                    sys/sysctl.h \
1541                    sys/time.h \
1542                    sys/types.h \
1543                    sys/uio.h \
1544                    sys/un.h \
1545                    sys/vfs.h \
1546                    syslog.h \
1547                    termios.h \
1548                    time.h \
1549                    ucontext.h \
1550                    unistd.h \
1551                    windows.h \
1552                 ])
1553
1554 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1555 #ifdef HAVE_NETINET_IN_H
1556 # include <netinet/in.h>
1557 #endif])
1558
1559 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1560 #ifdef HAVE_SYS_SOCKET_H
1561 # include <sys/socket.h>
1562 #endif])
1563
1564 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1565 #ifdef HAVE_SYS_SOCKET_H
1566 # include <sys/socket.h>
1567 #endif
1568 #ifdef HAVE_NETINET_IN_H
1569 # include <netinet/in.h>
1570 #endif
1571 #ifdef HAVE_NET_IF_H
1572 # include <net/if.h>
1573 #endif])
1574
1575 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1576 #ifdef HAVE_SECURITY_PAM_APPL_H
1577 # include <security/pam_appl.h>
1578 #endif])
1579
1580 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1581
1582 AC_CHECK_TYPES([fsblkcnt_t],,,[
1583 #include <sys/types.h>
1584 #ifdef HAVE_SYS_BITYPES_H
1585 #include <sys/bitypes.h>
1586 #endif
1587 #ifdef HAVE_SYS_STATFS_H
1588 #include <sys/statfs.h>
1589 #endif
1590 #ifdef HAVE_SYS_STATVFS_H
1591 #include <sys/statvfs.h>
1592 #endif
1593 ])
1594
1595 dnl see what struct stat has for timestamps
1596 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1597
1598 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1599
1600 if test "$enable_debug_locks" = yes; then
1601         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1602 fi
1603
1604 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1605         HAVE_PAM="yes"
1606 else
1607         HAVE_PAM="no"
1608 fi
1609 AC_SUBST(HAVE_PAM)
1610
1611 if test "$enable_login" = yes; then
1612         BUILD_LOGIN="yes"
1613 else
1614         BUILD_LOGIN="no"
1615 fi
1616 AC_SUBST(BUILD_LOGIN)
1617
1618 if test "$enable_kauth" = yes; then
1619         INSTALL_KAUTH="yes"
1620 else
1621         INSTALL_KAUTH="no"
1622 fi
1623 AC_SUBST(INSTALL_KAUTH)
1624
1625 AC_CHECK_FUNCS([ \
1626         arc4random \
1627         closelog \
1628         fcntl \
1629         fseeko64 \
1630         ftello64 \
1631         getcwd \
1632         getegid \
1633         geteuid \
1634         getgid \
1635         getuid \
1636         getrlimit \
1637         issetugid \
1638         mkstemp \
1639         openlog \
1640         poll \
1641         pread \
1642         preadv \
1643         preadv64 \
1644         pwrite \
1645         pwritev \
1646         pwritev64 \
1647         regcomp \
1648         regerror \
1649         regexec \
1650         setitimer \
1651         setvbuf \
1652         sigaction \
1653         strcasestr \
1654         strerror \
1655         sysconf \
1656         sysctl \
1657         syslog \
1658         tdestroy \
1659         timegm \
1660 ])
1661
1662 OPENAFS_ROKEN()
1663 OPENAFS_HCRYPTO()
1664 OPENAFS_CURSES()
1665 OPENAFS_C_ATTRIBUTE()
1666 OPENAFS_C_PRAGMA()
1667
1668 dnl Functions that Heimdal's libroken provides, but that we
1669 dnl haven't found a need for yet, and so haven't imported
1670 AC_CHECK_FUNCS([ \
1671         chown \
1672         fchown \
1673         gethostname \
1674         lstat \
1675         inet_aton \
1676         putenv \
1677         readv \
1678         setenv \
1679         strdup \
1680         strftime \
1681         strndup \
1682         strsep \
1683         unsetenv \
1684 ])
1685
1686 dnl Functions that are in objects that we always build from libroken
1687 AC_CHECK_FUNCS([ \
1688         asprintf \
1689         asnprintf \
1690         vasprintf \
1691         vasnprintf \
1692         vsnprintf \
1693         snprintf \
1694 ])
1695
1696 dnl Functions that we're going to try and get from libroken
1697 AC_REPLACE_FUNCS([ \
1698         daemon \
1699         ecalloc \
1700         emalloc \
1701         erealloc \
1702         err \
1703         errx \
1704         flock \
1705         freeaddrinfo \
1706         gai_strerror \
1707         getaddrinfo \
1708         getdtablesize \
1709         getnameinfo \
1710         getopt \
1711         getprogname \
1712         gettimeofday \
1713         inet_ntop \
1714         inet_pton \
1715         localtime_r \
1716         mkstemp \
1717         setenv \
1718         setprogname \
1719         strcasecmp \
1720         strlcat \
1721         strnlen \
1722         strlcpy \
1723         strsep \
1724         tdelete \
1725         tfind \
1726         tsearch \
1727         twalk \
1728         unsetenv \
1729         verr \
1730         verrx \
1731         vsyslog \
1732         vwarn \
1733         vwarnx \
1734         warn \
1735         warnx \
1736 ])
1737
1738 dnl Headers that we're going to try and get from libroken
1739 AC_CHECK_HEADERS([ \
1740         err.h \
1741         search.h \
1742 ])
1743
1744 AC_CHECK_DECLS([h_errno], [], [], [
1745 #include <sys/types.h>
1746 #ifdef HAVE_NETDB_H
1747 #include <netdb.h>
1748 #endif
1749 ])
1750
1751 AC_HEADER_TIME
1752
1753 ROKEN_HEADERS=
1754 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1755       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1756       [])
1757 AC_SUBST(ROKEN_HEADERS)
1758
1759 dnl Stuff that's harder ...
1760 AC_MSG_CHECKING([for bswap16])
1761 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1762 #ifdef HAVE_SYS_TYPES_H
1763 #include <sys/types.h>
1764 #endif
1765 #ifdef HAVE_SYS_BSWAP_H
1766 #include <sys/bswap.h>
1767 #endif
1768 ],
1769 [short a, b; b = bswap16(a); ])],
1770 [AC_MSG_RESULT(yes)
1771  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1772 ],
1773 [AC_MSG_RESULT(no)])
1774
1775 AC_MSG_CHECKING([for bswap32])
1776 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1777 #include <sys/types.h>
1778 #endif
1779 #ifdef HAVE_SYS_BSWAP_H
1780 #include <sys/bswap.h>
1781 #endif
1782 ],
1783 [int a, b; b = bswap32(a); ])],
1784 [AC_MSG_RESULT(yes)
1785  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1786 ],
1787 [AC_MSG_RESULT(no)])
1788
1789 case $AFS_SYSNAME in
1790 *hp_ux* | *hpux*)
1791    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1792    ;;
1793 *)
1794    AC_MSG_CHECKING([for positional I/O])
1795    if test "$ac_cv_func_pread" = "yes" && \
1796            test "$ac_cv_func_pwrite" = "yes"; then
1797       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1798       AC_MSG_RESULT(yes)
1799    else
1800      AC_MSG_RESULT(no)
1801    fi
1802    AC_MSG_CHECKING([for vectored positional I/O])
1803    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1804                "$ac_cv_func_pwritev" = "yes" -a \
1805                "$ac_cv_func_preadv64" = "yes" -a \
1806                "$ac_cv_func_pwritev64" = "yes"],
1807          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1808           AC_MSG_RESULT(yes)],
1809          [AC_MSG_RESULT(no)])
1810    ;;
1811 esac
1812
1813 AC_MSG_CHECKING([for POSIX regex library])
1814 if test "$ac_cv_header_regex_h" = "yes" && \
1815         test "$ac_cv_func_regcomp" = "yes" && \
1816         test "$ac_cv_func_regexec" = "yes" && \
1817         test "$ac_cv_func_regerror" = "yes"; then
1818     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1819     AC_MSG_RESULT(yes)
1820 else
1821     AC_MSG_RESULT(no)
1822 fi
1823
1824 dnl Look for "non-portable" pthreads functions.
1825 save_LIBS="$LIBS"
1826 LIBS="$LIBS $PTHREAD_LIBS"
1827 AC_CHECK_FUNCS([ \
1828         pthread_set_name_np \
1829         pthread_setname_np \
1830 ])
1831
1832 dnl Sadly, there are three different versions of pthread_setname_np.
1833 dnl Try to cater for all of them.
1834 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1835     AC_MSG_CHECKING([for signature of pthread_setname_np])
1836     AC_TRY_COMPILE([
1837 #include <pthread.h>
1838 #ifdef HAVE_PTHREAD_NP_H
1839 #include <pthread_np.h>
1840 #endif
1841 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1842         AC_MSG_RESULT([three arguments])
1843         pthread_setname_np_args=3], [
1844         AC_TRY_COMPILE([
1845 #include <pthread.h>
1846 #ifdef HAVE_PTHREAD_NP_H
1847 #include <pthread_np.h>
1848 #endif
1849 ], [pthread_setname_np(pthread_self(), "test")], [
1850             AC_MSG_RESULT([two arguments])
1851             pthread_setname_np_args=2], [
1852             AC_TRY_COMPILE([
1853 #include <pthread.h>
1854 #ifdef HAVE_PTHREAD_NP_H
1855 #include <pthread_np.h>
1856 #endif
1857 ], [pthread_setname_np("test")], [
1858                 AC_MSG_RESULT([one argument])
1859                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1860 ])
1861 ])
1862 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1863 fi
1864 LIBS="$save_LIBS"
1865
1866 openafs_cv_saved_CFLAGS="$CFLAGS"
1867 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1868
1869 AC_TYPE_SIGNAL
1870 OPENAFS_RETSIGTYPE
1871 AC_CHECK_SIZEOF(void *)
1872 AC_CHECK_SIZEOF(unsigned long long)
1873 AC_CHECK_SIZEOF(unsigned long)
1874 AC_CHECK_SIZEOF(unsigned int)
1875 AC_TYPE_INTPTR_T
1876 AC_TYPE_UINTPTR_T
1877 AC_TYPE_SSIZE_T
1878 AC_CHECK_TYPE([sig_atomic_t],[],
1879     [AC_DEFINE([sig_atomic_t], [int],
1880         [Define to int if <signal.h> does not define.])],
1881 [#include <sys/types.h>
1882 #include <signal.h>])
1883 AC_CHECK_TYPE([socklen_t],[],
1884     [AC_DEFINE([socklen_t], [int],
1885         [Define to int if <sys/socket.h> does not define.])],
1886 [#include <sys/types.h>
1887 #include <sys/socket.h>])
1888 AC_CHECK_TYPES(off64_t)
1889 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1890 AC_CHECK_TYPES([struct winsize], [], [], [
1891 #ifdef HAVE_TERMIOS_H
1892 # include <termios.h>
1893 #else
1894 # include <sys/termios.h>
1895 #endif
1896 #include <sys/ioctl.h>])
1897 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1898                 struct sockaddr_storage],
1899                [], [], [
1900 #include <sys/types.h>
1901 #include <sys/socket.h>
1902 ])
1903 AC_CHECK_TYPES([sa_family_t], [], [], [
1904 #include <sys/types.h>
1905 #include <sys/socket.h>
1906 ])
1907 AC_CHECK_TYPES([struct addrinfo], [], [], [
1908 #include <sys/types.h>
1909 #ifdef HAVE_NETDB_H
1910 #include <netdb.h>
1911 #endif
1912 ])
1913 AC_CHECK_TYPES([long long], [], [], [])
1914
1915 AC_SIZEOF_TYPE(long)
1916
1917 CFLAGS="$openafs_cv_saved_CFLAGS"
1918
1919 RRA_HEADER_PAM_CONST
1920
1921
1922 dnl Directory PATH handling
1923 if test "x$enable_transarc_paths" = "xyes"  ; then
1924     afsconfdir=${afsconfdir=/usr/afs/etc}
1925     viceetcdir=${viceetcdir=/usr/vice/etc}
1926     afskerneldir=${afskerneldir=${viceetcdir}}
1927     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1928     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1929     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1930     afsdbdir=${afsdbdir=/usr/afs/db}
1931     afslogsdir=${afslogsdir=/usr/afs/logs}
1932     afslocaldir=${afslocaldir=/usr/afs/local}
1933     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1934     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1935     afsdatadir=${afsdatadir=/usr/vice/etc}
1936 else
1937     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1938     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1939     afskerneldir=${afskerneldir='${libdir}/openafs'}
1940     afssrvbindir=${afssrvbindir='${bindir}'}
1941     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1942     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1943     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1944     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1945     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1946     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1947     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1948     afsdatadir=${afsdatadir='${datadir}/openafs'}
1949 fi
1950 AC_SUBST(afsconfdir)
1951 AC_SUBST(viceetcdir)
1952 AC_SUBST(afskerneldir)
1953 AC_SUBST(afssrvbindir)
1954 AC_SUBST(afssrvsbindir)
1955 AC_SUBST(afssrvlibexecdir)
1956 AC_SUBST(afsdbdir)
1957 AC_SUBST(afslogsdir)
1958 AC_SUBST(afslocaldir)
1959 AC_SUBST(afsbackupdir)
1960 AC_SUBST(afsbosconfigdir)
1961 AC_SUBST(afsdatadir)
1962
1963 if test "x$enable_kernel_module" = "xyes"; then
1964 ENABLE_KERNEL_MODULE=libafs
1965 fi
1966
1967 if test "x$enable_pthreaded_ubik" = "xyes"; then
1968 ENABLE_PTHREADED_UBIK=yes
1969 fi
1970
1971 AC_SUBST(VFSCK)
1972 AC_SUBST(AFS_SYSNAME)
1973 AC_SUBST(AFS_PARAM_COMMON)
1974 AC_SUBST(ENABLE_KERNEL_MODULE)
1975 AC_SUBST(ENABLE_PTHREADED_UBIK)
1976 AC_SUBST(LIB_AFSDB)
1977 AC_SUBST(LINUX_KERNEL_PATH)
1978 AC_SUBST(LINUX_KERNEL_BUILD)
1979 AC_SUBST(HOST_CPU)
1980 AC_SUBST(BSD_KERNEL_PATH)
1981 AC_SUBST(BSD_KERNEL_BUILD)
1982 AC_SUBST(LINUX_VERSION)
1983 AC_SUBST(MKAFS_OSTYPE)
1984 AC_SUBST(TOP_OBJDIR)
1985 AC_SUBST(TOP_SRCDIR)
1986 AC_SUBST(TOP_INCDIR)
1987 AC_SUBST(TOP_LIBDIR)
1988 AC_SUBST(DEST)
1989 AC_SUBST(DARWIN_INFOFILE)
1990 AC_SUBST(IRIX_BUILD_IP35)
1991 AC_SUBST(HTML_XSL)
1992 AC_SUBST(XSLTPROC)
1993 AC_SUBST(DOCBOOK2PDF)
1994 AC_SUBST(DOCBOOK_STYLESHEETS)
1995
1996 OPENAFS_FUSE
1997 OPENAFS_SWIG
1998
1999 TOP_SRCDIR="${srcdir}/src"
2000 dnl
2001 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
2002 dnl
2003 case $TOP_SRCDIR in
2004         /*)
2005                 ;;
2006         *)
2007                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
2008                 ;;
2009 esac
2010
2011 TOP_OBJDIR="${SRCDIR_PARENT}"
2012 TOP_INCDIR="${SRCDIR_PARENT}/include"
2013 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
2014 if test "${DEST}x" = "x"; then
2015         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
2016 fi
2017
2018 if test "x$with_crosstools_dir" != "x"; then
2019         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
2020                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
2021                 CONFIGTOOL_PATH=$with_crosstools_dir/config
2022                 RXGEN_PATH=$with_crosstools_dir/rxgen
2023         else
2024                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
2025                 exit 1
2026         fi
2027 else
2028         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
2029         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
2030         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
2031 fi
2032 AC_SUBST(COMPILE_ET_PATH)
2033 AC_SUBST(CONFIGTOOL_PATH)
2034 AC_SUBST(RXGEN_PATH)
2035
2036 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
2037 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
2038 AC_SUBST(HELPER_SPLINT)
2039 AC_SUBST(HELPER_SPLINTCFG)
2040
2041 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
2042
2043 dnl Check to see if crypt lives in a different library
2044 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
2045 AC_SUBST(LIB_crypt)
2046
2047 dnl Check to see if the compiler support labels in structs
2048 AC_MSG_CHECKING(for label support in structs)
2049 AC_TRY_COMPILE([], [
2050 extern void osi_UFSOpen(void);
2051 struct labeltest {
2052    void (*open) (void);
2053 };
2054 struct labeltest struct_labeltest = {
2055    .open       = osi_UFSOpen,
2056 }
2057 ],
2058 [AC_MSG_RESULT(yes)
2059  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
2060 ],
2061 [AC_MSG_RESULT(no)
2062 ])
2063
2064 AC_MSG_CHECKING([checking for dirfd])
2065 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
2066 #ifdef HAVE_DIRENT_H
2067 #include <dirent.h>
2068 #endif
2069 ]],
2070         [[DIR *d = 0; dirfd(d);]])],
2071         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
2072 if test "$ac_rk_have_dirfd" = "yes" ; then
2073         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
2074 fi
2075 AC_MSG_RESULT($ac_rk_have_dirfd)
2076
2077 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
2078 #ifdef HAVE_DIRENT_H
2079 #include <dirent.h>
2080 #endif])
2081
2082 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
2083 [#ifdef HAVE_SYS_RESOURCE_H
2084 #include <sys/resource.h>
2085 #endif])
2086
2087 dnl Check for UUID library
2088 AC_CHECK_HEADERS([uuid/uuid.h])
2089 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
2090 AC_CHECK_FUNCS([uuid_generate])
2091 ])
2092
2093