vos: fix crash when getting a non-loopback host address
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([gtx],
79     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
80 AC_ARG_ENABLE([uss],
81     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
82 AC_ARG_ENABLE([namei-fileserver],
83     [AS_HELP_STRING([--enable-namei-fileserver],
84         [force compilation of namei fileserver in preference to inode
85          fileserver])],
86     , 
87     [enable_namei_fileserver="default"])
88 AC_ARG_ENABLE([supergroups],
89     [AS_HELP_STRING([--enable-supergroups],
90         [enable support for nested pts groups])],
91     , 
92     [enable_supergroups="no"])
93 AC_ARG_ENABLE([bitmap-later],
94     [AS_HELP_STRING([--enable-bitmap-later],
95         [enable fast startup of file server by not reading bitmap till
96          needed])],
97     [AS_IF([test x"$withval" = xyes],
98         [AC_MSG_WARN([bitmap-later is only used by non-demand-attach
99             fileservers.  Please migrate to demand-attach instead.])])],
100     [enable_bitmap_later="no"])
101 AC_ARG_ENABLE([unix-sockets],
102     [AS_HELP_STRING([--disable-unix-sockets],
103         [disable use of unix domain sockets for fssync (defaults to enabled)])],
104     ,
105     [enable_unix_sockets="yes"])
106 AC_ARG_ENABLE([tivoli-tsm],
107     [AS_HELP_STRING([--enable-tivoli-tsm],
108         [enable use of the Tivoli TSM API libraries for butc support])],
109     , 
110     [enable_tivoli_tsm="no"])
111 AC_ARG_ENABLE([pthreaded-ubik],
112     [AS_HELP_STRING([--disable-pthreaded-ubik],
113         [disable installation of pthreaded ubik applications (defaults to
114          enabled)])],
115     ,
116     [enable_pthreaded_ubik="yes"])
117
118 dnl Kernel module build options.
119 AC_ARG_WITH([linux-kernel-headers],
120     [AS_HELP_STRING([--with-linux-kernel-headers=path],
121         [use the kernel headers found at path (optional, defaults to
122          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
123          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
124 AC_ARG_WITH([linux-kernel-build],
125     [AS_HELP_STRING([--with-linux-kernel-build=path],
126         [use the kernel build found at path(optional, defaults to 
127         kernel headers path)])])
128 AC_ARG_WITH([bsd-kernel-headers],
129     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
130         [use the kernel headers found at path (optional, defaults to
131          /usr/src/sys)])])
132 AC_ARG_WITH([bsd-kernel-build],
133     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
134         [use the kernel build found at path (optional, defaults to
135          KSRC/i386/compile/GENERIC)])])
136 AC_ARG_WITH([linux-kernel-packaging],
137     [AS_HELP_STRING([--with-linux-kernel-packaging],
138         [use standard naming conventions to aid Linux kernel build packaging
139          (disables MPS, sets the kernel module name to openafs.ko, and
140          installs kernel modules into the standard Linux location)])],
141     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
142      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
143     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
144 AC_ARG_ENABLE([kernel-module],
145     [AS_HELP_STRING([--disable-kernel-module],
146         [disable compilation of the kernel module (defaults to enabled)])],
147     , 
148     [enable_kernel_module="yes"])
149 AC_ARG_ENABLE([redhat-buildsys],
150     [AS_HELP_STRING([--enable-redhat-buildsys],
151         [enable compilation of the redhat build system kernel (defaults to
152          disabled)])],
153     ,
154     [enable_redhat_buildsys="no"])
155
156 dnl Installation locations.
157 AC_ARG_ENABLE([transarc-paths],
158     [AS_HELP_STRING([--enable-transarc-paths],
159         [use Transarc style paths like /usr/afs and /usr/vice])],
160     , 
161     [enable_transarc_paths="no"])
162
163 dnl Deprecated crypto
164 AC_ARG_ENABLE([kauth],
165     [AS_HELP_STRING([--enable-kauth],
166         [install the deprecated kauth server, pam modules, and utilities
167          (defaults to disabled)])],
168     [enable_pam="yes"],
169     [enable_kauth="no"
170      enable_pam="no"])
171
172 dnl Optimization and debugging flags.
173 AC_ARG_ENABLE([strip-binaries],
174     [AS_HELP_STRING([--disable-strip-binaries],
175         [disable stripping of symbol information from binaries (defaults to
176          enabled)])],
177     ,
178     [enable_strip_binaries="maybe"])
179 AC_ARG_ENABLE([debug],
180     [AS_HELP_STRING([--enable-debug],
181         [enable compilation of the user space code with debugging information
182          (defaults to disabled)])],
183     , 
184     [enable_debug="no"])
185 AC_ARG_ENABLE([optimize],
186     [AS_HELP_STRING([--disable-optimize],
187         [disable optimization for compilation of the user space code (defaults
188          to enabled)])],
189     , 
190     [enable_optimize="yes"])
191 AC_ARG_ENABLE([warnings],
192     [AS_HELP_STRING([--enable-warnings],
193         [enable compilation warnings when building with gcc (defaults to
194          disabled)])],
195     ,
196     [enable_warnings="no"])
197 AC_ARG_ENABLE([checking],
198     [AS_HELP_STRING([--enable-checking],
199         [turn compilation warnings into errors when building with gcc (defaults
200          to disabled)])],
201     [enable_checking="$enableval"],
202     [enable_checking="no"])
203 AC_ARG_ENABLE([debug-locks],
204     [AS_HELP_STRING([--enable-debug-locks],
205         [turn on lock debugging assertions (defaults to disabled)])],
206     [enable_debug_locks="$enableval"],
207     [enable_debug_locks="no"])
208 AC_ARG_ENABLE([debug-kernel],
209     [AS_HELP_STRING([--enable-debug-kernel],
210         [enable compilation of the kernel module with debugging information
211          (defaults to disabled)])],
212     ,
213     [enable_debug_kernel="no"])
214 AC_ARG_ENABLE([optimize-kernel],
215     [AS_HELP_STRING([--disable-optimize-kernel],
216         [disable compilation of the kernel module with optimization (defaults
217          based on platform)])],
218     , 
219     [enable_optimize_kernel=""])
220 AC_ARG_ENABLE([debug-lwp],
221     [AS_HELP_STRING([--enable-debug-lwp],
222         [enable compilation of the LWP code with debugging information
223          (defaults to disabled)])],
224     ,
225     [enable_debug_lwp="no"])
226 AC_ARG_ENABLE([optimize-lwp],
227     [AS_HELP_STRING([--disable-optimize-lwp],
228         [disable optimization for compilation of the LWP code (defaults to
229          enabled)])],
230     ,
231     [enable_optimize_lwp="yes"])
232 AC_ARG_ENABLE([debug-pam],
233     [AS_HELP_STRING([--enable-debug-pam],
234         [enable compilation of the PAM code with debugging information
235          (defaults to disabled)])],
236     ,
237     [enable_debug_pam="no"])
238 AC_ARG_ENABLE([optimize-pam],
239     [AS_HELP_STRING([--disable-optimize-pam],
240         [disable optimization for compilation of the PAM code (defaults to
241          enabled)])],
242     ,
243     [enable_optimize_pam="yes"])
244 AC_ARG_ENABLE([linux-syscall-probing],
245     [AS_HELP_STRING([--enable-linux-syscall-probing],
246         [enable Linux syscall probing (defaults to autodetect)])],
247     ,
248     [enable_linux_syscall_probing="maybe"])
249 AC_ARG_WITH([crosstools-dir],
250     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
251     
252 AC_ARG_WITH([xslt-processor],
253         AS_HELP_STRING([--with-xslt-processor=ARG],
254         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
255         [XSLTPROC="$withval"],
256         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
257
258 AC_ARG_WITH([html-xsl], 
259         AS_HELP_STRING([--with-html-xsl],
260         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
261         [HTML_XSL="$withval"],
262         [HTML_XSL="html/chunk.xsl"])
263
264 AC_ARG_WITH([docbook2pdf],
265         AS_HELP_STRING([--with-docbook2pdf=ARG],
266         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
267         [DOCBOOK2PDF="$withval"],
268         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
269
270 AC_ARG_WITH([docbook-stylesheets],
271         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
272         [location of DocBook stylesheets (default is to search a set of likely paths)]),
273         [DOCBOOK_STYLESHEETS="$withval"],
274         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
275         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
276                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
277         fi)
278
279 AC_ARG_WITH([dot],
280         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
281         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
282         [], [with_dot="maybe"])
283
284 enable_login="no"
285
286 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
287 dnl documentation build.
288 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
289 AC_CHECK_PROGS([DOXYGEN], [doxygen])
290
291 dnl Optionally generate graphs with doxygen.
292 case "$with_dot" in
293 maybe)
294     AC_CHECK_PROGS([DOT], [dot])
295     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
296     ;;
297 yes)
298     HAVE_DOT="yes"
299     ;;
300 no)
301     HAVE_DOT="no"
302     ;;
303 *)
304     HAVE_DOT="yes"
305     DOT_PATH=$with_dot
306 esac
307 AC_SUBST(HAVE_DOT)
308 AC_SUBST(DOT_PATH)
309
310 dnl Checks for UNIX variants.
311 AC_ISC_POSIX
312
313 dnl Various compiler setup.
314 AC_TYPE_PID_T
315 AC_TYPE_SIZE_T
316
317 dnl Checks for programs.
318 AC_PROG_INSTALL
319 AC_PROG_LN_S
320 AC_PROG_RANLIB
321 AC_PROG_YACC
322 AM_PROG_LEX
323 dnl if we are flex, be lex-compatible
324 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
325
326 OPENAFS_FORCE_ABS_INSTALL
327 OPENAFS_CHECK_BIGENDIAN
328 OPENAFS_PRINTF_TAKES_Z_LEN
329
330 AC_MSG_CHECKING(your OS)
331 system=$host
332 case $system in
333         *-linux*)
334
335                 MKAFS_OSTYPE=LINUX
336                 if test "x$enable_redhat_buildsys" = "xyes"; then
337                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
338                 fi
339                 if test "x$enable_kernel_module" = "xyes"; then
340                  if test "x$with_linux_kernel_headers" != "x"; then
341                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
342                  else
343                    for utsdir in "/lib/modules/`uname -r`/build" \
344                                  "/lib/modules/`uname -r`/source" \
345                                  "/usr/src/linux-2.4" \
346                                  "/usr/src/linux"; do
347                      LINUX_KERNEL_PATH="$utsdir"
348                      for utsfile in "include/generated/utsrelease.h" \
349                                     "include/linux/utsrelease.h" \
350                                     "include/linux/version.h" \
351                                     "include/linux/version-up.h"; do
352                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
353                          break 2
354                        fi
355                      done
356                    done
357                  fi
358                  if test "x$with_linux_kernel_build" != "x"; then
359                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
360                  else
361                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
362                  fi
363                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
364                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
365                    LINUX_VERSION="$linux_kvers"
366                  else
367                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
368                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
369                      LINUX_VERSION="$linux_kvers"
370                    else
371                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
372                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
373                        if test "x$linux_kvers" = "x"; then
374                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
375                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
376                            if test "x$linux_kvers" = "x"; then
377                              AC_MSG_ERROR(Linux headers lack version definition [2])
378                              exit 1
379                            else
380                              LINUX_VERSION="$linux_kvers"
381                            fi
382                          else
383                            AC_MSG_ERROR(Linux headers lack version definition)
384                            exit 1
385                          fi
386                        else
387                          LINUX_VERSION="$linux_kvers"
388                        fi
389                      else
390                        enable_kernel_module="no"
391                      fi
392                    fi
393                  fi
394                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
395                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
396                      enable_kernel_module="no"
397                  fi
398                  if test "x$enable_kernel_module" = "xno"; then
399                   if test "x$with_linux_kernel_headers" != "x"; then
400                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
401                    exit 1
402                   else
403                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
404                   fi
405                  fi
406                  dnl do we need to determine SUBARCH from autoconf.h
407                  SUBARCH=default
408                 fi
409                 AC_MSG_RESULT(linux)
410                 if test "x$enable_kernel_module" = "xyes"; then
411                  case "$LINUX_VERSION" in
412                   2.2.*) AFS_SYSKVERS=22 ;;
413                   2.4.*) AFS_SYSKVERS=24 ;;
414                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
415                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
416                  esac
417                 fi
418                 ;;
419         *-solaris*)
420                 MKAFS_OSTYPE=SOLARIS
421                 AC_MSG_RESULT(sun4)
422                 AC_PATH_PROG(SOLARISCC, [cc], ,
423                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
424                 if test "x$SOLARISCC" = "x" ; then
425                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
426                 fi
427                 SOLARIS_UFSVFS_HAS_DQRWLOCK
428                 SOLARIS_FS_HAS_FS_ROLLED
429                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
430                 SOLARIS_HAVE_VN_RENAMEPATH
431                 ;;
432         *-sunos*)
433                 MKAFS_OSTYPE=SUNOS
434                 enable_kernel_module=no
435                 AC_MSG_RESULT(sun4)
436                 ;;
437         *-hpux*)
438                 MKAFS_OSTYPE=HPUX
439                 AC_MSG_RESULT(hp_ux)
440                 if test -f "/usr/old/usr/include/ndir.h"; then
441                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
442                 fi
443                 ;;
444         *-irix*)
445                 if test -d /usr/include/sys/SN/SN1; then
446                  IRIX_BUILD_IP35="IP35"
447                 fi
448                 MKAFS_OSTYPE=IRIX
449                 AC_MSG_RESULT(sgi)
450                 ;;
451         *-aix*)
452                 MKAFS_OSTYPE=AIX
453                 AC_MSG_RESULT(rs_aix)
454                 ;;
455         arm-*-darwin*)
456                 MKAFS_OSTYPE=DARWIN
457                 AC_MSG_RESULT(arm_darwin)
458                 ;;
459         powerpc-*-darwin*)
460                 MKAFS_OSTYPE=DARWIN
461                 AC_MSG_RESULT(ppc_darwin)
462                 ;;
463         i386-*-darwin*)
464                 MKAFS_OSTYPE=DARWIN
465                 AC_MSG_RESULT(x86_darwin)
466                 ;;
467         x86_64-*-darwin*)
468                 MKAFS_OSTYPE=DARWIN
469                 AC_MSG_RESULT(x86_darwin)
470                 ;;
471         i386-*-freebsd*)
472                 MKAFS_OSTYPE=FBSD
473                 AC_MSG_RESULT(i386_fbsd)
474                 ;;
475         x86_64-*-freebsd*)
476                 MKAFS_OSTYPE=FBSD
477                 AC_MSG_RESULT(amd64_fbsd)
478                 ;;
479         *-netbsd*)
480                 MKAFS_OSTYPE=NBSD
481                 AC_MSG_RESULT(nbsd)
482                 ;;
483         x86_64-*-openbsd*)
484                 MKAFS_OSTYPE=OBSD
485                 AC_MSG_RESULT(amd64_obsd)
486                 ;;
487         i386-*-openbsd*)
488                 MKAFS_OSTYPE=OBSD
489                 AC_MSG_RESULT(i386_obsd)
490                 ;;
491         *-dragonfly*)
492                 MKAFS_OSTYPE=DFBSD
493                 AC_MSG_RESULT(i386_dfbsd)
494                 ;;
495         *)
496                 AC_MSG_RESULT($system)
497                 ;;
498 esac
499
500 if test "x$with_afs_sysname" != "x"; then
501         AFS_SYSNAME="$with_afs_sysname"
502 else
503         AC_MSG_CHECKING(your AFS sysname)
504         case $host in
505                 i?86-*-openbsd?.?)
506                         v=${host#*openbsd}
507                         vM=${v%.*}
508                         vm=${v#*.}
509                         AFS_SYSNAME="i386_obsd${vM}${vm}"
510                         ;;
511                 sparc64-*-openbsd?.?)
512                         v=${host#*openbsd}
513                         vM=${v%.*}
514                         vm=${v#*.}
515                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
516                         ;;
517                 x86_64-*-openbsd?.?)
518                         v=${host#*openbsd}
519                         vM=${v%.*}
520                         vm=${v#*.}
521                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
522                         ;;
523                 i?86-*-freebsd*.*)
524                         v=${host#*freebsd}
525                         vM=${v%.*}
526                         vm=${v#*.}
527                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
528                         ;;
529                 x86_64-*-freebsd*.*)
530                         v=${host#*freebsd}
531                         vM=${v%.*}
532                         vm=${v#*.}
533                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
534                         ;;
535                 i386-*-dragonfly?.*)
536                         v=${host#*dragonfly}
537                         vM=${v%.*}
538                         vm=${v#*.}
539                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
540                         ;;
541                 i?86-*-netbsd*1.6[[M-Z]]*)
542                         AFS_SYSNAME="i386_nbsd20"
543                         ;;
544                 powerpc-*-netbsd*1.6[[M-Z]]*)
545                         AFS_SYSNAME="ppc_nbsd20"
546                         ;;
547                 *-*-netbsd*)
548                         arch=${host%%-unknown*}
549                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
550                                                -e 's/powerpc/ppc/g')
551                         v=${host#*netbsd}
552                         v=${v#*aout}
553                         v=${v#*ecoff}
554                         v=${v#*elf}
555                         vM=${v%%.*}
556                         vM=${vM%.*}
557                         v=${v#*.}
558                         vm=${v%%.*}
559                         vm=${vm%.*}
560                         vm=${vm%%[[_A-Z]]*}
561                         if test $vm -eq 99 ; then
562                                 vM=$((vM+1))
563                         fi
564                         if test $vM -gt 1 ; then
565                                 vm=0
566                         fi
567                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
568                         ;;
569                 hppa*-hp-hpux11.0*)
570                         AFS_SYSNAME="hp_ux110"
571                         ;;
572                 hppa*-hp-hpux11.11)
573                         AFS_SYSNAME="hp_ux11i"
574                         ;;
575                 hppa*-hp-hpux11.23)
576                         AFS_SYSNAME="hp_ux1123"
577                         ;;
578                 ia64-hp-hpux11.22)
579                         AFS_SYSNAME="ia64_hpux1122"
580                         ;;
581                 ia64-hp-hpux*)
582                         AFS_SYSNAME="ia64_hpux1123"
583                         ;;
584                 hppa*-hp-hpux10*)
585                         AFS_SYSNAME="hp_ux102"
586                         ;;
587                 powerpc-apple-darwin7*)
588                         AFS_SYSNAME="ppc_darwin_70"
589                         OSXSDK="macosx10.3"
590                         ;;
591                 powerpc-apple-darwin8.*)
592                         AFS_SYSNAME="ppc_darwin_80"
593                         OSXSDK="macosx10.4"
594                         ;;
595                 i386-apple-darwin8.*)
596                         AFS_SYSNAME="x86_darwin_80"
597                         OSXSDK="macosx10.4"
598                         ;;
599                 powerpc-apple-darwin9.*)
600                         AFS_SYSNAME="ppc_darwin_90"
601                         OSXSDK="macosx10.5"
602                         ;;
603                 i386-apple-darwin9.*)
604                         AFS_SYSNAME="x86_darwin_90"
605                         OSXSDK="macosx10.5"
606                         ;;
607                 i?86-apple-darwin10.*)
608                         AFS_SYSNAME="x86_darwin_100"
609                         OSXSDK="macosx10.6"
610                         ;;
611                 x86_64-apple-darwin10.*)
612                         AFS_SYSNAME="x86_darwin_100"
613                         OSXSDK="macosx10.6"
614                         ;;
615                 arm-apple-darwin10.*)
616                         AFS_SYSNAME="arm_darwin_100"
617                         OSXSDK="iphoneos4.0"
618                         ;;
619                 x86_64-apple-darwin11.*)
620                         AFS_SYSNAME="x86_darwin_110"
621                         OSXSDK="macosx10.7"
622                         ;;
623                 i?86-apple-darwin11.*)
624                         AFS_SYSNAME="x86_darwin_110"
625                         OSXSDK="macosx10.7"
626                         ;;
627                 x86_64-apple-darwin12.*)
628                         AFS_SYSNAME="x86_darwin_120"
629                         OSXSDK="macosx10.8"
630                         ;;
631                 i?86-apple-darwin12.*)
632                         AFS_SYSNAME="x86_darwin_120"
633                         OSXSDK="macosx10.8"
634                         ;;
635                 x86_64-apple-darwin13.*)
636                         AFS_SYSNAME="x86_darwin_130"
637                         OSXSDK="macosx10.9"
638                         ;;
639                 i?86-apple-darwin13.*)
640                         AFS_SYSNAME="x86_darwin_130"
641                         OSXSDK="macosx10.9"
642                         ;;
643                 x86_64-apple-darwin14.*)
644                         AFS_SYSNAME="x86_darwin_140"
645                         OSXSDK="macosx10.10"
646                         ;;
647                 i?86-apple-darwin14.*)
648                         AFS_SYSNAME="x86_darwin_140"
649                         OSXSDK="macosx10.10"
650                         ;;
651                 sparc-sun-solaris2.8)
652                         AFS_SYSNAME="sun4x_58"
653                         ;;
654                 sparc-sun-solaris2.9)
655                         AFS_SYSNAME="sun4x_59"
656                         ;;
657                 sparc-sun-solaris2.10)
658                         AFS_SYSNAME="sun4x_510"
659                         ;;
660                 sparc-sun-solaris2.11)
661                         AFS_SYSNAME="sun4x_511"
662                         ;;
663                 i386-pc-solaris2.8)
664                         AFS_SYSNAME="sunx86_58"
665                         ;;
666                 i386-pc-solaris2.9)
667                         AFS_SYSNAME="sunx86_59"
668                         ;;
669                 i386-pc-solaris2.10)
670                         AFS_SYSNAME="sunx86_510"
671                         ;;
672                 i386-pc-solaris2.11)
673                         AFS_SYSNAME="sunx86_511"
674                         ;;
675                 alpha*-dec-osf4.0*)
676                         AFS_SYSNAME="alpha_dux40"
677                         ;;
678                 alpha*-dec-osf5.0*)
679                         AFS_SYSNAME="alpha_dux50"
680                         ;;
681                 alpha*-dec-osf5.1*)
682                         AFS_SYSNAME="alpha_dux51"
683                         ;;
684                 mips-sgi-irix6.5)
685                         AFS_SYSNAME="sgi_65"
686                         enable_pam="no"
687                         ;;
688                 ia64-*-linux*)
689                         AFS_SYSNAME="ia64_linuxXX"
690                         ;;
691                 powerpc-*-linux*)
692                         AFS_SYSNAME="`/bin/arch`_linuxXX"
693                         ;;
694                 powerpc64-*-linux*)
695                         AFS_SYSNAME="ppc64_linuxXX"
696                         ;;
697                 alpha*-linux*)
698                         AFS_SYSNAME="alpha_linux_XX"
699                         ;;
700                 s390-*-linux*)
701                         AFS_SYSNAME="s390_linuxXX"
702                         ;;
703                 s390x-*-linux*)
704                         AFS_SYSNAME="s390x_linuxXX"
705                         ;;
706                 sparc-*-linux*)
707                         AFS_SYSNAME="`/bin/arch`_linuxXX"
708                         ;;
709                 sparc64-*-linux*)
710                         AFS_SYSNAME="sparc64_linuxXX"
711                         ;;
712                 i?86-*-linux*)
713                         AFS_SYSNAME="i386_linuxXX"
714                         ;;
715                 arm*-linux*)
716                         AFS_SYSNAME="arm_linuxXX"
717                         ;;
718                 parisc-*-linux-gnu|hppa-*-linux-gnu)
719                         AFS_SYSNAME="parisc_linuxXX"
720                         enable_pam="no"
721                         ;;
722                 power*-ibm-aix4.2*)
723                         AFS_SYSNAME="rs_aix42"
724                         enable_pam="no"
725                         ;;
726                 power*-ibm-aix4.3*)
727                         AFS_SYSNAME="rs_aix42"
728                         enable_pam="no"
729                         ;;
730                 power*-ibm-aix5.1*)
731                         AFS_SYSNAME="rs_aix51"
732                         enable_pam="no"
733                         ;;
734                 power*-ibm-aix5.2*)
735                         AFS_SYSNAME="rs_aix52"
736                         enable_pam="no"
737                         ;;
738                 power*-ibm-aix5.3*)
739                         AFS_SYSNAME="rs_aix53"
740                         enable_pam="no"
741                         ;;
742                 power*-ibm-aix6.1*)
743                         AFS_SYSNAME="rs_aix61"
744                         enable_pam="no"
745                         ;;
746                 x86_64-*-linux-gnu)
747                         AFS_SYSNAME="amd64_linuxXX"
748                         enable_pam="yes"
749                         ;;
750                 *)
751                         AC_MSG_ERROR(An AFS sysname is required)
752                         exit 1
753                         ;;
754         esac
755         case $AFS_SYSNAME in
756                 *_linux* | *_umlinux*)
757                         if test "x${AFS_SYSKVERS}" = "x"; then
758                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
759                         fi
760                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
761                         AFS_SYSNAME="$_AFS_SYSNAME"
762                         AC_TRY_KBUILD(
763                          [],
764                          [#ifndef CONFIG_USERMODE
765                           #error not UML
766                           #endif],
767                          ac_cv_linux_is_uml=yes,)
768                         if test "${ac_cv_linux_is_uml}" = yes; then
769                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
770                         fi
771                         AFS_SYSNAME="$_AFS_SYSNAME"
772                         ;;
773         esac
774         AC_MSG_RESULT($AFS_SYSNAME)
775 fi
776
777 case $AFS_SYSNAME in
778         *_darwin*)
779                 AC_CHECK_HEADERS(crt_externs.h)
780                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
781                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
782                 AC_SUBST(OSXSDK)
783                 ;;
784 esac
785
786 dnl Some hosts have a separate common param file they should include.  Figure
787 dnl out if we're on one of them now that we know the sysname.
788 case $AFS_SYSNAME in
789     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
790     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
791     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
792     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
793     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
794     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
795     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
796     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
797     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
798     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
799     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
800     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
801     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
802     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
803     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
804     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
805     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
806     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
807     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
808     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
809     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
810     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
811     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
812     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
813     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
814     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
815     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
816     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
817     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
818     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
819     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
820     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
821     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
822     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
823     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
824     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
825 # Linux alpha adds an extra underscore for no good reason.
826     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
827     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
828     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
829     *_fbsd_*)   AFS_PARAM_COMMON=param.generic_fbsd.h ;;
830 esac
831
832 OPENAFS_OSCONF
833
834 case $AFS_SYSNAME in *_linux* | *_umlinux*)
835
836                 # Add (sub-) architecture-specific paths needed by conftests
837                 case $AFS_SYSNAME  in
838                         *_umlinux26)
839                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
840                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
841                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
842                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
843                 esac
844
845                 if test "x$enable_kernel_module" = "xyes"; then
846                  if test "x$enable_debug_kernel" = "xno"; then
847                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
848                  fi
849                  OPENAFS_GCC_SUPPORTS_MARCH
850                  AC_SUBST(P5PLUS_KOPTS)
851                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
852                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
853                  OPENAFS_GCC_SUPPORTS_NO_COMMON
854                  OPENAFS_GCC_SUPPORTS_PIPE
855                  AC_SUBST(LINUX_GCC_KOPTS)
856
857                  dnl Setup the kernel build environment
858                  LINUX_KBUILD_USES_EXTRA_CFLAGS
859                  LINUX_KERNEL_COMPILE_WORKS
860
861                  dnl Check for header files
862                  AC_CHECK_LINUX_HEADER([config.h])
863                  AC_CHECK_LINUX_HEADER([completion.h])
864                  AC_CHECK_LINUX_HEADER([exportfs.h])
865                  AC_CHECK_LINUX_HEADER([freezer.h])
866                  AC_CHECK_LINUX_HEADER([key-type.h])
867                  AC_CHECK_LINUX_HEADER([semaphore.h])
868                  AC_CHECK_LINUX_HEADER([seq_file.h])
869
870                  dnl Type existence checks
871                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
872                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
873
874                  dnl Check for structure elements
875                  AC_CHECK_LINUX_STRUCT([address_space_operations],
876                                        [write_begin], [fs.h])
877                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
878                                        [backing-dev.h])
879                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
880                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
881                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
882                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
883                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
884                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
885                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
886                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
887                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
888                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
889                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
890                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
891                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
892                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
893                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
894                  AC_CHECK_LINUX_STRUCT([key_type], [match_preparse], [key-type.h])
895                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
896                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
897                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
898                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
899                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
900                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
901                                        [fs.h])
902                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
903                                        [fs.h])
904                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
905                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
906                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
907                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
908                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
909                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
910                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
911                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
912                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
913                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
914                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
915
916                  dnl Check for typed structure elements
917                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
918                                              [buf], [fs.h])
919
920                  dnl Function existence checks
921
922                  AC_CHECK_LINUX_FUNC([bdi_init],
923                                      [#include <linux/backing-dev.h>],
924                                      [bdi_init(NULL);])
925                  AC_CHECK_LINUX_FUNC([PageChecked],
926                                      [#include <linux/mm.h>
927 #include <linux/page-flags.h>],
928                                      [struct page *_page;
929                                       int bchecked = PageChecked(_page);])
930                  AC_CHECK_LINUX_FUNC([PageFsMisc],
931                                      [#include <linux/mm.h>
932 #include <linux/page-flags.h>],
933                                      [struct page *_page;
934                                       int bchecked = PageFsMisc(_page);])
935                  AC_CHECK_LINUX_FUNC([clear_inode],
936                                      [#include <linux/fs.h>],
937                                      [clear_inode(NULL);])
938                  AC_CHECK_LINUX_FUNC([current_kernel_time],
939                                      [#include <linux/time.h>],
940                                      [struct timespec s;
941                                       s = current_kernel_time();])
942                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
943                                      [#include <linux/fs.h>],
944                                      [d_alloc_anon(NULL);])
945                  AC_CHECK_LINUX_FUNC([d_count],
946                                      [#include <linux/dcache.h>],
947                                      [d_count(NULL);])
948                  AC_CHECK_LINUX_FUNC([d_make_root],
949                                      [#include <linux/fs.h>],
950                                      [d_make_root(NULL);])
951                  AC_CHECK_LINUX_FUNC([do_sync_read],
952                                      [#include <linux/fs.h>],
953                                      [do_sync_read(NULL, NULL, 0, NULL);])
954                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
955                                      [#include <linux/sched.h>],
956                                      [pid_t p; find_task_by_pid(p);])
957                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
958                                      [#include <linux/fs.h>],
959                                      [generic_file_aio_read(NULL,NULL,0,0);])
960                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
961                                      [#include <linux/pagemap.h>],
962                                      [grab_cache_page_write_begin(NULL, 0, 0);])
963                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
964                                      [#include <linux/list.h>],
965                                      [hlist_unhashed(0);])
966                  AC_CHECK_LINUX_FUNC([i_size_read],
967                                      [#include <linux/fs.h>],
968                                      [i_size_read(NULL);])
969                  AC_CHECK_LINUX_FUNC([inode_setattr],
970                                      [#include <linux/fs.h>],
971                                      [inode_setattr(NULL, NULL);])
972                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
973                                      [#include <linux/fs.h>],
974                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
975                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
976                                      [#include <linux/net.h>],
977                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
978                  AC_CHECK_LINUX_FUNC([page_follow_link],
979                                      [#include <linux/fs.h>],
980                                      [page_follow_link(0,0);])
981                  AC_CHECK_LINUX_FUNC([page_offset],
982                                      [#include <linux/pagemap.h>],
983                                      [page_offset(NULL);])
984                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
985                                      [#include <linux/pagevec.h>],
986                                      [__pagevec_lru_add_file(NULL);])
987                  AC_CHECK_LINUX_FUNC([path_lookup],
988                                      [#include <linux/fs.h>
989                                       #include <linux/namei.h>],
990                                      [path_lookup(NULL, 0, NULL);])
991                  AC_CHECK_LINUX_FUNC([proc_create],
992                                      [#include <linux/proc_fs.h>],
993                                      [proc_create(NULL, 0, NULL, NULL);])
994                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
995                                      [#include <linux/rcupdate.h>],
996                                      [rcu_read_lock();])
997                  AC_CHECK_LINUX_FUNC([set_nlink],
998                                      [#include <linux/fs.h>],
999                                      [set_nlink(NULL, 1);])
1000                  AC_CHECK_LINUX_FUNC([sock_create_kern],
1001                                      [#include <linux/net.h>],
1002                                      [sock_create_kern(0, 0, 0, NULL);])
1003                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
1004                                      [#include <linux/splice.h>],
1005                                      [splice_direct_to_actor(NULL,NULL,NULL);])
1006                  AC_CHECK_LINUX_FUNC([svc_addr_in],
1007                                      [#include <linux/sunrpc/svc.h>],
1008                                      [svc_addr_in(NULL);])
1009                  AC_CHECK_LINUX_FUNC([zero_user_segments],
1010                                      [#include <linux/highmem.h>],
1011                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1012                  AC_CHECK_LINUX_FUNC([noop_fsync],
1013                                      [#include <linux/fs.h>],
1014                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1015                  AC_CHECK_LINUX_FUNC([kthread_run],
1016                                      [#include <linux/kernel.h>
1017                                       #include <linux/kthread.h>],
1018                                      [kthread_run(NULL, NULL, "test");])
1019
1020                  dnl Consequences - things which get set as a result of the
1021                  dnl                above tests
1022                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1023                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1024                                   [define to disable the nfs translator])])
1025
1026                  dnl Assorted more complex tests
1027                  LINUX_AIO_NONVECTOR
1028                  LINUX_EXPORTS_PROC_ROOT_FS
1029                  LINUX_KMEM_CACHE_INIT
1030                  LINUX_HAVE_KMEM_CACHE_T
1031                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1032                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1033                  LINUX_D_PATH_TAKES_STRUCT_PATH
1034                  LINUX_NEW_EXPORT_OPS
1035                  LINUX_INODE_SETATTR_RETURN_TYPE
1036                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1037                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1038                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1039                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1040                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1041                  LINUX_DOP_D_DELETE_TAKES_CONST
1042                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1043                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1044                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1045                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1046                  LINUX_AOP_WRITEBACK_CONTROL
1047                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1048                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1049                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1050                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1051                  LINUX_KERNEL_SOCK_CREATE
1052                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1053                  LINUX_NEED_RHCONFIG
1054                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1055                  LINUX_EXPORTS_TASKLIST_LOCK
1056                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1057                  LINUX_STATFS_TAKES_DENTRY
1058                  LINUX_REFRIGERATOR
1059                  LINUX_HAVE_TRY_TO_FREEZE
1060                  LINUX_LINUX_KEYRING_SUPPORT
1061                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1062                  LINUX_KEY_ALLOC_NEEDS_CRED
1063                  LINUX_INIT_WORK_HAS_DATA
1064                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1065                  LINUX_HAVE_DCACHE_LOCK
1066                  LINUX_D_COUNT_IS_INT
1067                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1068                  LINUX_IOP_CREATE_TAKES_UMODE_T
1069                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1070                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1071                  LINUX_DENTRY_OPEN_TAKES_PATH
1072                  LINUX_D_ALIAS_IS_HLIST
1073                  LINUX_HLIST_ITERATOR_NO_NODE
1074                  LINUX_IOP_I_CREATE_TAKES_BOOL
1075                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1076                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1077                  LINUX_D_INVALIDATE_IS_VOID
1078
1079                  dnl If we are guaranteed that keyrings will work - that is
1080                  dnl  a) The kernel has keyrings enabled
1081                  dnl  b) The code is new enough to give us a key_type_keyring
1082                  dnl then we just disable syscall probing unless we've been
1083                  dnl told otherwise
1084
1085                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1086                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1087                           [enable_linux_syscall_probing="no"],
1088                           [enable_linux_syscall_probing="yes"])
1089                  ])
1090
1091                  dnl Syscall probing needs a few tests of its own, and just
1092                  dnl won't work if the kernel doesn't export init_mm
1093                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1094                    LINUX_EXPORTS_INIT_MM
1095                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1096                      AC_MSG_ERROR(
1097                        [Can't do syscall probing without exported init_mm])
1098                    ])
1099                    LINUX_EXPORTS_SYS_CHDIR
1100                    LINUX_EXPORTS_SYS_OPEN
1101                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1102                              [define to enable syscall table probes])
1103                  ])
1104
1105                  dnl Packaging and SMP build
1106                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1107                    LINUX_WHICH_MODULES
1108                  else
1109                    AC_SUBST(MPS,'SP')
1110                  fi
1111
1112                  dnl Syscall probing
1113                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1114                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1115                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1116                    ])
1117                    ac_cv_linux_exports_sys_call_table=no
1118                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1119                      ac_cv_linux_exports_ia32_sys_call_table=yes
1120                    fi
1121                  else
1122                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1123                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1124                    LINUX_EXPORTS_SYS_CALL_TABLE
1125                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1126                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1127                          linux_syscall_method=none
1128                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1129                             linux_syscall_method=scan
1130                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1131                                linux_syscall_method=scan_with_kallsyms_address
1132                             fi
1133                          fi
1134                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1135                             linux_syscall_method=kallsyms_symbol
1136                          fi
1137                          if test "x$linux_syscall_method" = "xnone"; then
1138                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1139                             linux_syscall_method=scan
1140                          fi
1141                    fi
1142                  fi
1143                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1144                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1145                  fi
1146                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1147                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1148                  fi
1149                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1150                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1151                  else
1152                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1153                  fi
1154                 :
1155                 fi
1156 dnl Linux-only, but just enable always.
1157                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1158 esac
1159
1160 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1161     [ac_cv_sync_fetch_and_add],
1162     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1163                     [ac_cv_sync_fetch_and_add=yes],
1164                     [ac_cv_sync_fetch_and_add=no])
1165 ])
1166 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1167       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1168                 [define if your C compiler has __sync_add_and_fetch])])
1169
1170 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1171     [ac_cv_sockaddr_len],
1172     [AC_TRY_COMPILE( [#include <sys/types.h>
1173 #include <sys/socket.h>],
1174                      [struct sockaddr *a; a->sa_len=0;],
1175                      [ac_cv_sockaddr_len=yes],
1176                      [ac_cv_sockaddr_len=no])
1177 ])
1178 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1179       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1180                  [define if you struct sockaddr sa_len])])
1181
1182 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1183         echo Skipping library tests because they confuse Irix.
1184 else
1185   AC_SEARCH_LIBS([socket], [socket inet])
1186   AC_SEARCH_LIBS([connect], [nsl])
1187   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1188
1189   dnl darwin wants it, aix hates it
1190   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1191   AC_TRY_COMPILE([
1192   #include <stdlib.h>
1193   #include <stdio.h>
1194   #include <sys/types.h>
1195   #include <sys/socket.h>
1196   #include <netinet/in.h>
1197   #include <arpa/inet.h>
1198   #include <arpa/nameser.h>
1199   #include <arpa/nameser_compat.h>
1200   #include <resolv.h>
1201   ], [static int i; i = 0;],
1202   [AC_MSG_RESULT(yes)
1203    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1204   [AC_MSG_RESULT(no)
1205    ])
1206
1207   openafs_save_libs="$LIBS"
1208   AC_MSG_CHECKING([for res_search])
1209   AC_FUNC_RES_SEARCH
1210
1211   if test "$ac_cv_func_res_search" = no; then
1212       for lib in dns nsl resolv; do
1213         if test "$ac_cv_func_res_search" != yes; then
1214           LIBS="-l$lib $LIBS"
1215           AC_FUNC_RES_SEARCH
1216           LIBS="$openafs_save_libs"
1217         fi
1218       done    
1219       if test "$ac_cv_func_res_search" = yes; then
1220         LIB_AFSDB="-l$lib"
1221         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1222         AC_MSG_RESULT([yes, in lib$lib])
1223       else
1224         AC_MSG_RESULT(no)
1225       fi
1226   else
1227     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1228     AC_MSG_RESULT(yes)
1229   fi
1230   
1231 fi
1232 XLIBS="$LIB_AFSDB $XLIBS"
1233
1234 AC_CHECK_RESOLV_RETRANS
1235
1236 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1237     [ac_cv_setsockopt_iprecverr],
1238     [AC_TRY_COMPILE( [
1239 #include <sys/types.h>
1240 #include <sys/socket.h>
1241 #include <netinet/in.h>],
1242 [int on=1;
1243 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1244         [ac_cv_setsockopt_iprecverr=yes],
1245         [ac_cv_setsockopt_iprecverr=no])])
1246
1247 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1248       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1249                  [define if we can receive socket errors via IP_RECVERR])])
1250
1251 PTHREAD_LIBS=error
1252 if test "x$MKAFS_OSTYPE" = OBSD; then
1253         PTHREAD_LIBS="-pthread"
1254 fi
1255 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1256         PTHREAD_LIBS="-pthread"
1257 fi
1258 if test "x$PTHREAD_LIBS" = xerror; then
1259         AC_CHECK_LIB(pthread, pthread_attr_init,
1260                 PTHREAD_LIBS="-lpthread")
1261 fi
1262 if test "x$PTHREAD_LIBS" = xerror; then
1263         AC_CHECK_LIB(pthreads, pthread_attr_init,
1264                 PTHREAD_LIBS="-lpthreads")
1265 fi
1266 if test "x$PTHREAD_LIBS" = xerror; then
1267         AC_CHECK_LIB(c_r, pthread_attr_init,
1268                 PTHREAD_LIBS="-lc_r")
1269 fi
1270 if test "x$PTHREAD_LIBS" = xerror; then
1271         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1272 fi
1273 if test "x$PTHREAD_LIBS" = xerror; then
1274         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1275         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1276                 PTHREAD_LIBS="-lpthread")
1277 fi
1278 if test "x$PTHREAD_LIBS" = xerror; then
1279         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1280 fi
1281 AC_SUBST(PTHREAD_LIBS)
1282
1283 HOST_CPU="$host_cpu"
1284
1285 if test "x$with_bsd_kernel_headers" != "x"; then
1286         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1287 else
1288         BSD_KERNEL_PATH="/usr/src/sys"
1289 fi
1290
1291 if test "x$with_bsd_kernel_build" != "x"; then
1292         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1293 else
1294         case $AFS_SYSNAME in
1295                 *_fbsd_*)
1296                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1297                         ;;
1298                 *_nbsd*)
1299                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1300         esac
1301 fi
1302
1303 # Fast restart
1304 if test "$enable_supergroups" = "yes"; then
1305         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1306 fi
1307
1308 if test "$enable_bitmap_later" = "yes"; then
1309         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1310 fi
1311
1312 if test "$enable_unix_sockets" = "yes"; then
1313         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1314         USE_UNIX_SOCKETS="yes"
1315 else
1316         USE_UNIX_SOCKETS="no"
1317 fi
1318 AC_SUBST(USE_UNIX_SOCKETS)
1319
1320 if test "$enable_namei_fileserver" = "yes"; then
1321         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1322         VFSCK=""
1323 else
1324         if test "$enable_namei_fileserver" = "default"; then
1325                 case $host in
1326                         *-solaris2.10*)
1327                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1328                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1329                                 VFSCK=""
1330                                 ;;
1331                         *-solaris2.11*)
1332                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1333                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1334                                 VFSCK=""
1335                                 ;;
1336                         *)
1337                                 VFSCK="vfsck"
1338                                 ;;
1339                 esac
1340         else
1341                 VFSCK="vfsck"
1342         fi
1343 fi
1344
1345 dnl check for tivoli
1346 AC_MSG_CHECKING(for tivoli tsm butc support)
1347 XBSA_CFLAGS=""
1348 if test "$enable_tivoli_tsm" = "yes"; then
1349         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1350         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1351         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1352         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1353
1354         if test -r "$XBSADIR3/dsmapifp.h"; then
1355                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1356                 XBSA_XLIBS="-ldl"
1357                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1358         elif test -r "$XBSADIR4/dsmapifp.h"; then
1359                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1360                 XBSA_XLIBS="-ldl"
1361                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1362         elif test -r "$XBSADIR1/xbsa.h"; then
1363                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1364                 XBSA_XLIBS=""
1365                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1366         elif test -r "$XBSADIR2/xbsa.h"; then
1367                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1368                 XBSA_XLIBS=""
1369                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1370         else
1371                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1372         fi
1373 else
1374         AC_MSG_RESULT([no])
1375 fi
1376 AC_SUBST(XBSA_CFLAGS)
1377 AC_SUBST(XBSA_XLIBS) 
1378
1379 dnl checks for header files.
1380 AC_HEADER_STDC
1381 AC_HEADER_SYS_WAIT
1382 AC_HEADER_DIRENT
1383 AC_CHECK_HEADERS([ \
1384                    arpa/inet.h \
1385                    arpa/nameser.h \
1386                    curses.h\
1387                    direct.h \
1388                    errno.h \
1389                    fcntl.h \
1390                    grp.h \
1391                    math.h \
1392                    mntent.h \
1393                    ncurses.h \
1394                    ncurses/ncurses.h \
1395                    netdb.h \
1396                    netinet/in.h \
1397                    pthread_np.h \
1398                    pwd.h \
1399                    regex.h \
1400                    security/pam_appl.h \
1401                    signal.h \
1402                    stdint.h \
1403                    stdio_ext.h \
1404                    stdlib.h \
1405                    string.h \
1406                    strings.h \
1407                    sys/bitypes.h \
1408                    sys/bswap.h \
1409                    sys/dk.h \
1410                    sys/fcntl.h \
1411                    sys/file.h \
1412                    sys/fs_types.h \
1413                    sys/fstyp.h \
1414                    sys/ioctl.h \
1415                    sys/ipc.h \
1416                    sys/lockf.h \
1417                    sys/map.h \
1418                    sys/mount.h \
1419                    sys/mntent.h \
1420                    sys/mnttab.h \
1421                    sys/pag.h \
1422                    sys/param.h \
1423                    sys/resource.h \
1424                    sys/select.h \
1425                    sys/statfs.h \
1426                    sys/statvfs.h \
1427                    sys/socket.h \
1428                    sys/sysctl.h \
1429                    sys/time.h \
1430                    sys/types.h \
1431                    sys/uio.h \
1432                    sys/un.h \
1433                    sys/vfs.h \
1434                    syslog.h \
1435                    termios.h \
1436                    time.h \
1437                    ucontext.h \
1438                    unistd.h \
1439                    windows.h \
1440                 ])
1441
1442 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1443 #ifdef HAVE_NETINET_IN_H
1444 # include <netinet/in.h>
1445 #endif])
1446
1447 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1448 #ifdef HAVE_SYS_SOCKET_H
1449 # include <sys/socket.h>
1450 #endif])
1451
1452 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1453 #ifdef HAVE_SYS_SOCKET_H
1454 # include <sys/socket.h>
1455 #endif
1456 #ifdef HAVE_NETINET_IN_H
1457 # include <netinet/in.h>
1458 #endif
1459 #ifdef HAVE_NET_IF_H
1460 # include <net/if.h>
1461 #endif])
1462
1463 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1464 #ifdef HAVE_SECURITY_PAM_APPL_H
1465 # include <security/pam_appl.h>
1466 #endif])
1467
1468 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1469
1470 AC_CHECK_TYPES([fsblkcnt_t],,,[
1471 #include <sys/types.h>
1472 #ifdef HAVE_SYS_BITYPES_H
1473 #include <sys/bitypes.h>
1474 #endif
1475 #ifdef HAVE_SYS_STATFS_H
1476 #include <sys/statfs.h>
1477 #endif
1478 #ifdef HAVE_SYS_STATVFS_H
1479 #include <sys/statvfs.h>
1480 #endif
1481 ])
1482
1483 dnl see what struct stat has for timestamps
1484 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1485
1486 dnl check for curses-lib
1487 AS_IF([test "x$enable_gtx" != "xno"],
1488       [save_LIBS=$LIBS
1489       AC_CHECK_LIB( [ncurses], [setupterm],
1490       [LIB_curses=-lncurses],
1491         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1492           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1493       ])
1494       LIBS=$save_LIBS
1495       AC_SUBST(LIB_curses)])
1496         
1497 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1498
1499 if test "$enable_debug_locks" = yes; then
1500         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1501 fi
1502
1503 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1504         HAVE_PAM="YES"
1505 else
1506         HAVE_PAM="no"
1507 fi
1508 AC_SUBST(HAVE_PAM)
1509
1510 if test "$enable_login" = yes; then
1511         BUILD_LOGIN="yes"
1512 else
1513         BUILD_LOGIN="no"
1514 fi
1515 AC_SUBST(BUILD_LOGIN)
1516
1517 if test "$enable_uss" = yes; then
1518         BUILD_USS="yes"
1519 else
1520         BUILD_USS="no"
1521 fi
1522 AC_SUBST(BUILD_USS)
1523
1524 if test "$enable_kauth" = yes; then
1525         INSTALL_KAUTH="yes"
1526 else
1527         INSTALL_KAUTH="no"
1528 fi
1529 AC_SUBST(INSTALL_KAUTH)
1530
1531 AC_CHECK_FUNCS([ \
1532         arc4random \
1533         fcntl \
1534         fseeko64 \
1535         ftello64 \
1536         getcwd \
1537         getegid \
1538         geteuid \
1539         getgid \
1540         getuid \
1541         getrlimit \
1542         issetugid \
1543         mkstemp \
1544         poll \
1545         pread \
1546         preadv \
1547         preadv64 \
1548         pwrite \
1549         pwritev \
1550         pwritev64 \
1551         regcomp \
1552         regerror \
1553         regexec \
1554         setitimer \
1555         setvbuf \
1556         sigaction \
1557         strcasestr \
1558         strerror \
1559         sysconf \
1560         sysctl \
1561         tdestroy \
1562         timegm \
1563 ])
1564
1565 OPENAFS_ROKEN()
1566 OPENAFS_HCRYPTO()
1567 OPENAFS_C_ATTRIBUTE()
1568
1569 dnl Functions that Heimdal's libroken provides, but that we
1570 dnl haven't found a need for yet, and so haven't imported
1571 AC_CHECK_FUNCS([ \
1572         chown \
1573         fchown \
1574         gethostname \
1575         lstat \
1576         inet_aton \
1577         putenv \
1578         readv \
1579         setenv \
1580         strdup \
1581         strftime \
1582         strndup \
1583         strsep \
1584         unsetenv \
1585 ])
1586
1587 dnl Functions that are in objects that we always build from libroken
1588 AC_CHECK_FUNCS([ \
1589         asprintf \
1590         asnprintf \
1591         vasprintf \
1592         vasnprintf \
1593         vsnprintf \
1594         snprintf \
1595 ])
1596
1597 dnl Functions that we're going to try and get from libroken
1598 AC_REPLACE_FUNCS([ \
1599         daemon \
1600         ecalloc \
1601         emalloc \
1602         erealloc \
1603         err \
1604         errx \
1605         flock \
1606         freeaddrinfo \
1607         gai_strerror \
1608         getaddrinfo \
1609         getdtablesize \
1610         getnameinfo \
1611         getopt \
1612         getprogname \
1613         gettimeofday \
1614         inet_ntop \
1615         inet_pton \
1616         localtime_r \
1617         mkstemp \
1618         setenv \
1619         setprogname \
1620         strcasecmp \
1621         strlcat \
1622         strnlen \
1623         strlcpy \
1624         strsep \
1625         tdelete \
1626         tfind \
1627         tsearch \
1628         twalk \
1629         unsetenv \
1630         verr \
1631         verrx \
1632         vsyslog \
1633         vwarn \
1634         vwarnx \
1635         warn \
1636         warnx \
1637 ])
1638
1639 dnl Headers that we're going to try and get from libroken
1640 AC_CHECK_HEADERS([ \
1641         err.h \
1642         search.h \
1643 ])
1644
1645 AC_CHECK_DECLS([h_errno], [], [], [
1646 #include <sys/types.h>
1647 #ifdef HAVE_NETDB_H
1648 #include <netdb.h>
1649 #endif
1650 ])
1651
1652 AC_HEADER_TIME
1653
1654 ROKEN_HEADERS=
1655 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1656       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1657       [])
1658 AC_SUBST(ROKEN_HEADERS)
1659
1660 dnl Stuff that's harder ...
1661 AC_MSG_CHECKING([for bswap16])
1662 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1663 #ifdef HAVE_SYS_TYPES_H
1664 #include <sys/types.h>
1665 #endif
1666 #ifdef HAVE_SYS_BSWAP_H
1667 #include <sys/bswap.h>
1668 #endif
1669 ],
1670 [short a, b; b = bswap16(a); ])],
1671 [AC_MSG_RESULT(yes)
1672  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1673 ],
1674 [AC_MSG_RESULT(no)])
1675
1676 AC_MSG_CHECKING([for bswap32])
1677 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1678 #include <sys/types.h>
1679 #endif
1680 #ifdef HAVE_SYS_BSWAP_H
1681 #include <sys/bswap.h>
1682 #endif
1683 ],
1684 [int a, b; b = bswap32(a); ])],
1685 [AC_MSG_RESULT(yes)
1686  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1687 ],
1688 [AC_MSG_RESULT(no)])
1689
1690 case $AFS_SYSNAME in
1691 *hp_ux* | *hpux*)
1692    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1693    ;;
1694 *)
1695    AC_MSG_CHECKING([for positional I/O])
1696    if test "$ac_cv_func_pread" = "yes" && \
1697            test "$ac_cv_func_pwrite" = "yes"; then
1698       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1699       AC_MSG_RESULT(yes)
1700    else
1701      AC_MSG_RESULT(no)
1702    fi
1703    AC_MSG_CHECKING([for vectored positional I/O])
1704    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1705                "$ac_cv_func_pwritev" = "yes" -a \
1706                "$ac_cv_func_preadv64" = "yes" -a \
1707                "$ac_cv_func_pwritev64" = "yes"],
1708          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1709           AC_MSG_RESULT(yes)],
1710          [AC_MSG_RESULT(no)])
1711    ;;
1712 esac
1713
1714 AC_MSG_CHECKING([for POSIX regex library])
1715 if test "$ac_cv_header_regex_h" = "yes" && \
1716         test "$ac_cv_func_regcomp" = "yes" && \
1717         test "$ac_cv_func_regexec" = "yes" && \
1718         test "$ac_cv_func_regerror" = "yes"; then
1719     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1720     AC_MSG_RESULT(yes)
1721 else
1722     AC_MSG_RESULT(no)
1723 fi
1724
1725 dnl Look for "non-portable" pthreads functions.
1726 save_LIBS="$LIBS"
1727 LIBS="$LIBS $PTHREAD_LIBS"
1728 AC_CHECK_FUNCS([ \
1729         pthread_set_name_np \
1730         pthread_setname_np \
1731 ])
1732
1733 dnl Sadly, there are three different versions of pthread_setname_np.
1734 dnl Try to cater for all of them.
1735 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1736     AC_MSG_CHECKING([for signature of pthread_setname_np])
1737     AC_TRY_COMPILE([
1738 #include <pthread.h>
1739 #ifdef HAVE_PTHREAD_NP_H
1740 #include <pthread_np.h>
1741 #endif
1742 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1743         AC_MSG_RESULT([three arguments])
1744         pthread_setname_np_args=3], [
1745         AC_TRY_COMPILE([
1746 #include <pthread.h>
1747 #ifdef HAVE_PTHREAD_NP_H
1748 #include <pthread_np.h>
1749 #endif
1750 ], [pthread_setname_np(pthread_self(), "test")], [
1751             AC_MSG_RESULT([two arguments])
1752             pthread_setname_np_args=2], [
1753             AC_TRY_COMPILE([
1754 #include <pthread.h>
1755 #ifdef HAVE_PTHREAD_NP_H
1756 #include <pthread_np.h>
1757 #endif
1758 ], [pthread_setname_np("test")], [
1759                 AC_MSG_RESULT([one argument])
1760                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1761 ])
1762 ])
1763 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1764 fi
1765 LIBS="$save_LIBS"
1766
1767 openafs_cv_saved_CFLAGS="$CFLAGS"
1768 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1769
1770 AC_TYPE_SIGNAL
1771 OPENAFS_RETSIGTYPE
1772 AC_CHECK_SIZEOF(void *)
1773 AC_CHECK_SIZEOF(unsigned long long)
1774 AC_CHECK_SIZEOF(unsigned long)
1775 AC_CHECK_SIZEOF(unsigned int)
1776 AC_TYPE_INTPTR_T
1777 AC_TYPE_UINTPTR_T
1778 AC_TYPE_SSIZE_T
1779 AC_CHECK_TYPE([sig_atomic_t],[],
1780     [AC_DEFINE([sig_atomic_t], [int],
1781         [Define to int if <signal.h> does not define.])],
1782 [#include <sys/types.h>
1783 #include <signal.h>])
1784 AC_CHECK_TYPE([socklen_t],[],
1785     [AC_DEFINE([socklen_t], [int],
1786         [Define to int if <sys/socket.h> does not define.])],
1787 [#include <sys/types.h>
1788 #include <sys/socket.h>])
1789 AC_CHECK_TYPES(off64_t)
1790 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1791 AC_CHECK_TYPES([struct winsize], [], [], [
1792 #ifdef HAVE_TERMIOS_H
1793 # include <termios.h>
1794 #else
1795 # include <sys/termios.h>
1796 #endif
1797 #include <sys/ioctl.h>])
1798 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1799                 struct sockaddr_storage],
1800                [], [], [
1801 #include <sys/types.h>
1802 #include <sys/socket.h>
1803 ])
1804 AC_CHECK_TYPES([sa_family_t], [], [], [
1805 #include <sys/types.h>
1806 #include <sys/socket.h>
1807 ])
1808 AC_CHECK_TYPES([struct addrinfo], [], [], [
1809 #include <sys/types.h>
1810 #ifdef HAVE_NETDB_H
1811 #include <netdb.h>
1812 #endif
1813 ])
1814 AC_CHECK_TYPES([long long], [], [], [])
1815
1816 AC_SIZEOF_TYPE(long)
1817
1818 CFLAGS="$openafs_cv_saved_CFLAGS"
1819
1820 RRA_HEADER_PAM_CONST
1821
1822
1823 dnl Directory PATH handling
1824 if test "x$enable_transarc_paths" = "xyes"  ; then 
1825     afsconfdir=${afsconfdir=/usr/afs/etc}
1826     viceetcdir=${viceetcdir=/usr/vice/etc}
1827     afskerneldir=${afskerneldir=${viceetcdir}}
1828     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1829     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1830     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1831     afsdbdir=${afsdbdir=/usr/afs/db}
1832     afslogsdir=${afslogsdir=/usr/afs/logs}
1833     afslocaldir=${afslocaldir=/usr/afs/local}
1834     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1835     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1836     afsdatadir=${afsdatadir=/usr/vice/etc}
1837 else 
1838     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1839     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1840     afskerneldir=${afskerneldir='${libdir}/openafs'}
1841     afssrvbindir=${afssrvbindir='${bindir}'}
1842     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1843     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1844     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1845     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1846     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1847     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1848     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1849     afsdatadir=${afsdatadir='${datadir}/openafs'}
1850 fi
1851 AC_SUBST(afsconfdir)
1852 AC_SUBST(viceetcdir)
1853 AC_SUBST(afskerneldir)
1854 AC_SUBST(afssrvbindir)
1855 AC_SUBST(afssrvsbindir)
1856 AC_SUBST(afssrvlibexecdir)
1857 AC_SUBST(afsdbdir)
1858 AC_SUBST(afslogsdir)
1859 AC_SUBST(afslocaldir)
1860 AC_SUBST(afsbackupdir)
1861 AC_SUBST(afsbosconfigdir)
1862 AC_SUBST(afsdatadir)
1863
1864 if test "x$enable_kernel_module" = "xyes"; then
1865 ENABLE_KERNEL_MODULE=libafs
1866 fi
1867
1868 if test "x$enable_pthreaded_ubik" = "xyes"; then
1869 ENABLE_PTHREADED_UBIK=yes
1870 fi
1871
1872 AC_SUBST(VFSCK)
1873 AC_SUBST(AFS_SYSNAME)
1874 AC_SUBST(AFS_PARAM_COMMON)
1875 AC_SUBST(ENABLE_KERNEL_MODULE)
1876 AC_SUBST(ENABLE_PTHREADED_UBIK)
1877 AC_SUBST(LIB_AFSDB)
1878 AC_SUBST(LINUX_KERNEL_PATH)
1879 AC_SUBST(LINUX_KERNEL_BUILD)
1880 AC_SUBST(HOST_CPU)
1881 AC_SUBST(BSD_KERNEL_PATH)
1882 AC_SUBST(BSD_KERNEL_BUILD)
1883 AC_SUBST(LINUX_VERSION)
1884 AC_SUBST(MKAFS_OSTYPE)
1885 AC_SUBST(TOP_OBJDIR)
1886 AC_SUBST(TOP_SRCDIR)
1887 AC_SUBST(TOP_INCDIR)
1888 AC_SUBST(TOP_LIBDIR)
1889 AC_SUBST(DEST)
1890 AC_SUBST(DARWIN_INFOFILE)
1891 AC_SUBST(IRIX_BUILD_IP35)
1892 AC_SUBST(HTML_XSL)
1893 AC_SUBST(XSLTPROC)
1894 AC_SUBST(DOCBOOK2PDF)
1895 AC_SUBST(DOCBOOK_STYLESHEETS)
1896
1897 OPENAFS_FUSE
1898 OPENAFS_SWIG
1899
1900 TOP_SRCDIR="${srcdir}/src"
1901 dnl
1902 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1903 dnl
1904 case $TOP_SRCDIR in
1905         /*)
1906                 ;;
1907         *)
1908                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1909                 ;;
1910 esac
1911
1912 TOP_OBJDIR="${SRCDIR_PARENT}"
1913 TOP_INCDIR="${SRCDIR_PARENT}/include"
1914 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1915 if test "${DEST}x" = "x"; then
1916         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1917 fi
1918
1919 if test "x$with_crosstools_dir" != "x"; then
1920         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1921                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1922                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1923                 RXGEN_PATH=$with_crosstools_dir/rxgen
1924         else
1925                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1926                 exit 1
1927         fi
1928 else
1929         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1930         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1931         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1932 fi
1933 AC_SUBST(COMPILE_ET_PATH)
1934 AC_SUBST(CONFIGTOOL_PATH)
1935 AC_SUBST(RXGEN_PATH)
1936
1937 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1938 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1939 AC_SUBST(HELPER_SPLINT)
1940 AC_SUBST(HELPER_SPLINTCFG)
1941
1942 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1943
1944 dnl Check to see if crypt lives in a different library
1945 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1946 AC_SUBST(LIB_crypt)
1947
1948 dnl Check to see if the compiler support labels in structs
1949 AC_MSG_CHECKING(for label support in structs)
1950 AC_TRY_COMPILE([], [
1951 extern void osi_UFSOpen(void);
1952 struct labeltest {
1953    void (*open) (void);
1954 };
1955 struct labeltest struct_labeltest = {
1956    .open       = osi_UFSOpen,
1957 }
1958 ],
1959 [AC_MSG_RESULT(yes)
1960  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1961 ],
1962 [AC_MSG_RESULT(no)
1963 ])
1964
1965 AC_MSG_CHECKING([checking for dirfd])
1966 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1967 #ifdef HAVE_DIRENT_H
1968 #include <dirent.h>
1969 #endif
1970 ]],
1971         [[DIR *d = 0; dirfd(d);]])],
1972         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1973 if test "$ac_rk_have_dirfd" = "yes" ; then
1974         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1975 fi
1976 AC_MSG_RESULT($ac_rk_have_dirfd)
1977
1978 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1979 #ifdef HAVE_DIRENT_H
1980 #include <dirent.h>
1981 #endif])
1982
1983 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
1984 [#ifdef HAVE_SYS_RESOURCE_H
1985 #include <sys/resource.h>
1986 #endif])
1987
1988 dnl Check for UUID library
1989 AC_CHECK_HEADERS([uuid/uuid.h])
1990 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1991 AC_CHECK_FUNCS([uuid_generate])
1992 ])
1993
1994