Finish removing sunos 4.x references and build cruft
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([pam],
79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
80     ,
81     [enable_pam="yes"])
82 AC_ARG_ENABLE([namei-fileserver],
83     [AS_HELP_STRING([--enable-namei-fileserver],
84         [force compilation of namei fileserver in preference to inode
85          fileserver])],
86     , 
87     [enable_namei_fileserver="default"])
88 AC_ARG_ENABLE([supergroups],
89     [AS_HELP_STRING([--enable-supergroups],
90         [enable support for nested pts groups])],
91     , 
92     [enable_supergroups="no"])
93 AC_ARG_ENABLE([bitmap-later],
94     [AS_HELP_STRING([--enable-bitmap-later],
95         [enable fast startup of file server by not reading bitmap till
96          needed])],
97     , 
98     [enable_bitmap_later="no"])
99 AC_ARG_ENABLE([unix-sockets],
100     [AS_HELP_STRING([--disable-unix-sockets],
101         [disable use of unix domain sockets for fssync (defaults to enabled)])],
102     ,
103     [enable_unix_sockets="yes"])
104 AC_ARG_ENABLE([tivoli-tsm],
105     [AS_HELP_STRING([--enable-tivoli-tsm],
106         [enable use of the Tivoli TSM API libraries for butc support])],
107     , 
108     [enable_tivoli_tsm="no"])
109 AC_ARG_ENABLE([pthreaded-ubik],
110     [AS_HELP_STRING([--enable-pthreaded-ubik],
111         [enable installation of pthreaded ubik applications (defaults to
112          disabled)])],
113     ,
114     [enable_pthreaded_ubik="no"])
115
116 dnl Kernel module build options.
117 AC_ARG_WITH([linux-kernel-headers],
118     [AS_HELP_STRING([--with-linux-kernel-headers=path],
119         [use the kernel headers found at path (optional, defaults to
120          /usr/src/linux-2.4, then /usr/src/linux)])])
121 AC_ARG_WITH([linux-kernel-build],
122     [AS_HELP_STRING([--with-linux-kernel-build=path],
123         [use the kernel build found at path(optional, defaults to 
124         /usr/src/linux-2.4, then /usr/src/linux)])])
125 AC_ARG_WITH([bsd-kernel-headers],
126     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
127         [use the kernel headers found at path (optional, defaults to
128          /usr/src/sys)])])
129 AC_ARG_WITH([bsd-kernel-build],
130     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
131         [use the kernel build found at path (optional, defaults to
132          KSRC/i386/compile/GENERIC)])])
133 AC_ARG_WITH([linux-kernel-packaging],
134     [AS_HELP_STRING([--with-linux-kernel-packaging],
135         [use standard naming conventions to aid Linux kernel build packaging
136          (disables MPS, sets the kernel module name to openafs.ko, and
137          installs kernel modules into the standard Linux location)])],
138     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
139      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
140     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
141 AC_ARG_ENABLE([kernel-module],
142     [AS_HELP_STRING([--disable-kernel-module],
143         [disable compilation of the kernel module (defaults to enabled)])],
144     , 
145     [enable_kernel_module="yes"])
146 AC_ARG_ENABLE([redhat-buildsys],
147     [AS_HELP_STRING([--enable-redhat-buildsys],
148         [enable compilation of the redhat build system kernel (defaults to
149          disabled)])],
150     ,
151     [enable_redhat_buildsys="no"])
152
153 dnl Installation locations.
154 AC_ARG_ENABLE([transarc-paths],
155     [AS_HELP_STRING([--enable-transarc-paths],
156         [use Transarc style paths like /usr/afs and /usr/vice])],
157     , 
158     [enable_transarc_paths="no"])
159
160 dnl Optimization and debugging flags.
161 AC_ARG_ENABLE([strip-binaries],
162     [AS_HELP_STRING([--disable-strip-binaries],
163         [disable stripping of symbol information from binaries (defaults to
164          enabled)])],
165     ,
166     [enable_strip_binaries="maybe"])
167 AC_ARG_ENABLE([debug],
168     [AS_HELP_STRING([--enable-debug],
169         [enable compilation of the user space code with debugging information
170          (defaults to disabled)])],
171     , 
172     [enable_debug="no"])
173 AC_ARG_ENABLE([optimize],
174     [AS_HELP_STRING([--disable-optimize],
175         [disable optimization for compilation of the user space code (defaults
176          to enabled)])],
177     , 
178     [enable_optimize="yes"])
179 AC_ARG_ENABLE([warnings],
180     [AS_HELP_STRING([--enable-warnings],
181         [enable compilation warnings when building with gcc (defaults to
182          disabled)])],
183     ,
184     [enable_warnings="no"])
185 AC_ARG_ENABLE([checking],
186     [AS_HELP_STRING([--enable-checking],
187         [turn compilation warnings into errors when building with gcc (defaults
188          to disabled)])],
189     [enable_checking="$enableval"],
190     [enable_checking="no"])
191 AC_ARG_ENABLE([debug-kernel],
192     [AS_HELP_STRING([--enable-debug-kernel],
193         [enable compilation of the kernel module with debugging information
194          (defaults to disabled)])],
195     ,
196     [enable_debug_kernel="no"])
197 AC_ARG_ENABLE([optimize-kernel],
198     [AS_HELP_STRING([--disable-optimize-kernel],
199         [disable compilation of the kernel module with optimization (defaults
200          based on platform)])],
201     , 
202     [enable_optimize_kernel=""])
203 AC_ARG_ENABLE([debug-lwp],
204     [AS_HELP_STRING([--enable-debug-lwp],
205         [enable compilation of the LWP code with debugging information
206          (defaults to disabled)])],
207     ,
208     [enable_debug_lwp="no"])
209 AC_ARG_ENABLE([optimize-lwp],
210     [AS_HELP_STRING([--disable-optimize-lwp],
211         [disable optimization for compilation of the LWP code (defaults to
212          enabled)])],
213     ,
214     [enable_optimize_lwp="yes"])
215 AC_ARG_ENABLE([debug-pam],
216     [AS_HELP_STRING([--enable-debug-pam],
217         [enable compilation of the PAM code with debugging information
218          (defaults to disabled)])],
219     ,
220     [enable_debug_pam="no"])
221 AC_ARG_ENABLE([optimize-pam],
222     [AS_HELP_STRING([--disable-optimize-pam],
223         [disable optimization for compilation of the PAM code (defaults to
224          enabled)])],
225     ,
226     [enable_optimize_pam="yes"])
227 AC_ARG_ENABLE([linux-syscall-probing],
228     [AS_HELP_STRING([--enable-linux-syscall-probing],
229         [enable Linux syscall probing (defaults to autodetect)])],
230     ,
231     [enable_linux_syscall_probing="maybe"])
232     
233 AC_ARG_WITH([xslt-processor],
234         AS_HELP_STRING([--with-xslt-processor=ARG],
235         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
236         [XSLTPROC="$withval"],
237         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
238
239 AC_ARG_WITH([html-xsl], 
240         AS_HELP_STRING([--with-html-xsl],
241         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
242         [HTML_XSL="$withval"],
243         [HTML_XSL="html/chunk.xsl"])
244
245 AC_ARG_WITH([docbook2pdf],
246         AS_HELP_STRING([--with-docbook2pdf=ARG],
247         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
248         [DOCBOOK2PDF="$withval"],
249         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
250
251 AC_ARG_WITH([docbook-stylesheets],
252         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
253         [location of DocBook stylesheets (default is to search a set of likely paths)]),
254         [DOCBOOK_STYLESHEETS="$withval"],
255         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
256         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
257                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
258         fi)
259
260 enable_login="no"
261
262 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
263 dnl documentation build.
264 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
265
266 dnl weird ass systems
267 dnl AC_AIX
268 AC_ISC_POSIX
269 dnl AC_MINIX
270
271 dnl Various compiler setup.
272 AC_TYPE_PID_T
273 AC_TYPE_SIZE_T
274
275 dnl Checks for programs.
276 AC_PROG_INSTALL
277 AC_PROG_LN_S
278 AC_PROG_RANLIB
279 AC_PROG_YACC
280 AM_PROG_LEX
281 dnl if we are flex, be lex-compatible
282 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
283
284 OPENAFS_FORCE_ABS_INSTALL
285 OPENAFS_CHECK_BIGENDIAN
286 OPENAFS_PRINTF_TAKES_Z_LEN
287
288 AC_MSG_CHECKING(your OS)
289 system=$host
290 case $system in
291         *-linux*)
292
293                 MKAFS_OSTYPE=LINUX
294                 if test "x$enable_redhat_buildsys" = "xyes"; then
295                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
296                 fi
297                 if test "x$enable_kernel_module" = "xyes"; then
298                  if test "x$with_linux_kernel_headers" != "x"; then
299                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
300                  else
301                    LINUX_KERNEL_PATH="/lib/modules/`uname -r`/source"
302                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
303                      LINUX_KERNEL_PATH="/lib/modules/`uname -r`/build"
304                    fi
305                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
306                      LINUX_KERNEL_PATH="/usr/src/linux-2.4"
307                    fi
308                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
309                      LINUX_KERNEL_PATH="/usr/src/linux"
310                    fi
311                  fi
312                  if test "x$with_linux_kernel_build" != "x"; then
313                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
314                  else
315                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
316                  fi
317                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
318                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
319                    LINUX_VERSION="$linux_kvers"
320                  else
321                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
322                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
323                      LINUX_VERSION="$linux_kvers"
324                    else
325                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
326                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
327                        if test "x$linux_kvers" = "x"; then
328                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
329                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
330                            if test "x$linux_kvers" = "x"; then
331                              AC_MSG_ERROR(Linux headers lack version definition [2])
332                              exit 1
333                            else
334                              LINUX_VERSION="$linux_kvers"
335                            fi
336                          else
337                            AC_MSG_ERROR(Linux headers lack version definition)
338                            exit 1
339                          fi
340                        else
341                          LINUX_VERSION="$linux_kvers"
342                        fi
343                      else
344                        enable_kernel_module="no"
345                      fi
346                    fi
347                  fi
348                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
349                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
350                      enable_kernel_module="no"
351                  fi
352                  if test "x$enable_kernel_module" = "xno"; then
353                   if test "x$with_linux_kernel_headers" != "x"; then
354                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
355                    exit 1
356                   else
357                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
358                   fi
359                  fi
360                  dnl do we need to determine SUBARCH from autoconf.h
361                  SUBARCH=default
362                 fi
363                 AC_MSG_RESULT(linux)
364                 if test "x$enable_kernel_module" = "xyes"; then
365                  case "$LINUX_VERSION" in
366                   2.2.*) AFS_SYSKVERS=22 ;;
367                   2.4.*) AFS_SYSKVERS=24 ;;
368                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
369                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
370                  esac
371                 fi
372                 ;;
373         *-solaris*)
374                 MKAFS_OSTYPE=SOLARIS
375                 AC_MSG_RESULT(sun4)
376                 AC_PATH_PROG(SOLARISCC, [cc], ,
377                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin])
378                 SOLARIS_UFSVFS_HAS_DQRWLOCK
379                 SOLARIS_FS_HAS_FS_ROLLED
380                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
381                 ;;
382         *-sunos*)
383                 MKAFS_OSTYPE=SUNOS
384                 enable_kernel_module=no
385                 AC_MSG_RESULT(sun4)
386                 ;;
387         *-hpux*)
388                 MKAFS_OSTYPE=HPUX
389                 AC_MSG_RESULT(hp_ux)
390                 if test -f "/usr/old/usr/include/ndir.h"; then
391                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
392                 fi
393                 ;;
394         *-irix*)
395                 if test -d /usr/include/sys/SN/SN1; then
396                  IRIX_BUILD_IP35="IP35"
397                 fi
398                 MKAFS_OSTYPE=IRIX
399                 AC_MSG_RESULT(sgi)
400                 ;;
401         *-aix*)
402                 MKAFS_OSTYPE=AIX
403                 AC_MSG_RESULT(rs_aix)
404                 ;;
405         arm-*-darwin*)
406                 MKAFS_OSTYPE=DARWIN
407                 AC_MSG_RESULT(arm_darwin)
408                 ;;
409         powerpc-*-darwin*)
410                 MKAFS_OSTYPE=DARWIN
411                 AC_MSG_RESULT(ppc_darwin)
412                 ;;
413         i386-*-darwin*)
414                 MKAFS_OSTYPE=DARWIN
415                 AC_MSG_RESULT(x86_darwin)
416                 ;;
417         x86_64-*-darwin*)
418                 MKAFS_OSTYPE=DARWIN
419                 AC_MSG_RESULT(x86_darwin)
420                 ;;
421         i386-*-freebsd*)
422                 MKAFS_OSTYPE=FBSD
423                 AC_MSG_RESULT(i386_fbsd)
424                 ;;
425         x86_64-*-freebsd*)
426                 MKAFS_OSTYPE=FBSD
427                 AC_MSG_RESULT(amd64_fbsd)
428                 ;;
429         *-netbsd*)
430                 MKAFS_OSTYPE=NBSD
431                 AC_MSG_RESULT(nbsd)
432                 ;;
433         x86_64-*-openbsd*)
434                 MKAFS_OSTYPE=OBSD
435                 AC_MSG_RESULT(amd64_obsd)
436                 ;;
437         i386-*-openbsd*)
438                 MKAFS_OSTYPE=OBSD
439                 AC_MSG_RESULT(i386_obsd)
440                 ;;
441         *-dragonfly*)
442                 MKAFS_OSTYPE=DFBSD
443                 AC_MSG_RESULT(i386_dfbsd)
444                 ;;
445         *)
446                 AC_MSG_RESULT($system)
447                 ;;
448 esac
449
450 if test "x$with_afs_sysname" != "x"; then
451         AFS_SYSNAME="$with_afs_sysname"
452 else
453         AC_MSG_CHECKING(your AFS sysname)
454         case $host in
455                 i?86-*-openbsd?.?)
456                         v=${host#*openbsd}
457                         vM=${v%.*}
458                         vm=${v#*.}
459                         AFS_SYSNAME="i386_obsd${vM}${vm}"
460                         ;;
461                 sparc64-*-openbsd?.?)
462                         v=${host#*openbsd}
463                         vM=${v%.*}
464                         vm=${v#*.}
465                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
466                         ;;
467                 x86_64-*-openbsd?.?)
468                         v=${host#*openbsd}
469                         vM=${v%.*}
470                         vm=${v#*.}
471                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
472                         ;;
473                 i?86-*-freebsd?.*)
474                         v=${host#*freebsd}
475                         vM=${v%.*}
476                         vm=${v#*.}
477                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
478                         ;;
479                 x86_64-*-freebsd?.*)
480                         v=${host#*freebsd}
481                         vM=${v%.*}
482                         vm=${v#*.}
483                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
484                         ;;
485                 i386-*-dragonfly?.*)
486                         v=${host#*dragonfly}
487                         vM=${v%.*}
488                         vm=${v#*.}
489                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
490                         ;;
491                 i?86-*-netbsd*1.6[[M-Z]]*)
492                         AFS_SYSNAME="i386_nbsd20"
493                         ;;
494                 powerpc-*-netbsd*1.6[[M-Z]]*)
495                         AFS_SYSNAME="ppc_nbsd20"
496                         ;;
497                 *-*-netbsd*)
498                         arch=${host%%-unknown*}
499                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
500                                                -e 's/powerpc/ppc/g')
501                         v=${host#*netbsd}
502                         v=${v#*aout}
503                         v=${v#*ecoff}
504                         v=${v#*elf}
505                         vM=${v%%.*}
506                         vM=${vM%.*}
507                         v=${v#*.}
508                         vm=${v%%.*}
509                         vm=${vm%.*}
510                         vm=${vm%%[[_A-Z]]*}
511                         if test $vm -eq 99 ; then
512                                 vM=$((vM+1))
513                         fi
514                         if test $vM -gt 1 ; then
515                                 vm=0
516                         fi
517                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
518                         ;;
519                 hppa*-hp-hpux11.0*)
520                         AFS_SYSNAME="hp_ux110"
521                         ;;
522                 hppa*-hp-hpux11.11)
523                         AFS_SYSNAME="hp_ux11i"
524                         ;;
525                 hppa*-hp-hpux11.23)
526                         AFS_SYSNAME="hp_ux1123"
527                         ;;
528                 ia64-hp-hpux11.22)
529                         AFS_SYSNAME="ia64_hpux1122"
530                         ;;
531                 ia64-hp-hpux*)
532                         AFS_SYSNAME="ia64_hpux1123"
533                         ;;
534                 hppa*-hp-hpux10*)
535                         AFS_SYSNAME="hp_ux102"
536                         ;;
537                 powerpc-apple-darwin7*)
538                         AFS_SYSNAME="ppc_darwin_70"
539                         OSXSDK="macosx10.3"
540                         ;;
541                 powerpc-apple-darwin8.*)
542                         AFS_SYSNAME="ppc_darwin_80"
543                         OSXSDK="macosx10.4"
544                         ;;
545                 i386-apple-darwin8.*)
546                         AFS_SYSNAME="x86_darwin_80"
547                         OSXSDK="macosx10.4"
548                         ;;
549                 powerpc-apple-darwin9.*)
550                         AFS_SYSNAME="ppc_darwin_90"
551                         OSXSDK="macosx10.5"
552                         ;;
553                 i386-apple-darwin9.*)
554                         AFS_SYSNAME="x86_darwin_90"
555                         OSXSDK="macosx10.5"
556                         ;;
557                 i?86-apple-darwin10.*)
558                         AFS_SYSNAME="x86_darwin_100"
559                         OSXSDK="macosx10.6"
560                         ;;
561                 x86_64-apple-darwin10.*)
562                         AFS_SYSNAME="x86_darwin_100"
563                         OSXSDK="macosx10.6"
564                         ;;
565                 arm-apple-darwin10.*)
566                         AFS_SYSNAME="arm_darwin_100"
567                         OSXSDK="iphoneos4.0"
568                         ;;
569                 x86_64-apple-darwin11.*)
570                         AFS_SYSNAME="x86_darwin_110"
571                         OSXSDK="macosx10.7"
572                         ;;
573                 i?86-apple-darwin11.*)
574                         AFS_SYSNAME="x86_darwin_110"
575                         OSXSDK="macosx10.7"
576                         ;;
577                 sparc-sun-solaris2.8)
578                         AFS_SYSNAME="sun4x_58"
579                         ;;
580                 sparc-sun-solaris2.9)
581                         AFS_SYSNAME="sun4x_59"
582                         ;;
583                 sparc-sun-solaris2.10)
584                         AFS_SYSNAME="sun4x_510"
585                         ;;
586                 sparc-sun-solaris2.11)
587                         AFS_SYSNAME="sun4x_511"
588                         ;;
589                 i386-pc-solaris2.8)
590                         AFS_SYSNAME="sunx86_58"
591                         ;;
592                 i386-pc-solaris2.9)
593                         AFS_SYSNAME="sunx86_59"
594                         ;;
595                 i386-pc-solaris2.10)
596                         AFS_SYSNAME="sunx86_510"
597                         ;;
598                 i386-pc-solaris2.11)
599                         AFS_SYSNAME="sunx86_511"
600                         ;;
601                 alpha*-dec-osf4.0*)
602                         AFS_SYSNAME="alpha_dux40"
603                         ;;
604                 alpha*-dec-osf5.0*)
605                         AFS_SYSNAME="alpha_dux50"
606                         ;;
607                 alpha*-dec-osf5.1*)
608                         AFS_SYSNAME="alpha_dux51"
609                         ;;
610                 mips-sgi-irix6.5)
611                         AFS_SYSNAME="sgi_65"
612                         ;;
613                 ia64-*-linux*)
614                         AFS_SYSNAME="ia64_linuxXX"
615                         ;;
616                 powerpc-*-linux*)
617                         AFS_SYSNAME="`/bin/arch`_linuxXX"
618                         ;;
619                 powerpc64-*-linux*)
620                         AFS_SYSNAME="ppc64_linuxXX"
621                         ;;
622                 alpha*-linux*)
623                         AFS_SYSNAME="alpha_linux_XX"
624                         ;;
625                 s390-*-linux*)
626                         AFS_SYSNAME="s390_linuxXX"
627                         ;;
628                 s390x-*-linux*)
629                         AFS_SYSNAME="s390x_linuxXX"
630                         ;;
631                 sparc-*-linux*)
632                         AFS_SYSNAME="`/bin/arch`_linuxXX"
633                         ;;
634                 sparc64-*-linux*)
635                         AFS_SYSNAME="sparc64_linuxXX"
636                         ;;
637                 i?86-*-linux*)
638                         AFS_SYSNAME="i386_linuxXX"
639                         ;;
640                 arm*-linux*)
641                         AFS_SYSNAME="arm_linuxXX"
642                         ;;
643                 parisc-*-linux-gnu|hppa-*-linux-gnu)
644                         AFS_SYSNAME="parisc_linuxXX"
645                         enable_pam="no"
646                         ;;
647                 power*-ibm-aix4.2*)
648                         AFS_SYSNAME="rs_aix42"
649                         enable_pam="no"
650                         ;;
651                 power*-ibm-aix4.3*)
652                         AFS_SYSNAME="rs_aix42"
653                         enable_pam="no"
654                         ;;
655                 power*-ibm-aix5.1*)
656                         AFS_SYSNAME="rs_aix51"
657                         enable_pam="no"
658                         ;;
659                 power*-ibm-aix5.2*)
660                         AFS_SYSNAME="rs_aix52"
661                         enable_pam="no"
662                         ;;
663                 power*-ibm-aix5.3*)
664                         AFS_SYSNAME="rs_aix53"
665                         enable_pam="no"
666                         ;;
667                 power*-ibm-aix6.1*)
668                         AFS_SYSNAME="rs_aix61"
669                         enable_pam="no"
670                         ;;
671                 x86_64-*-linux-gnu)
672                         AFS_SYSNAME="amd64_linuxXX"
673                         enable_pam="yes"
674                         ;;
675                 *)
676                         AC_MSG_ERROR(An AFS sysname is required)
677                         exit 1
678                         ;;
679         esac
680         case $AFS_SYSNAME in
681                 *_linux* | *_umlinux*)
682                         if test "x${AFS_SYSKVERS}" = "x"; then
683                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
684                         fi
685                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
686                         AFS_SYSNAME="$_AFS_SYSNAME"
687                         AC_TRY_KBUILD(
688                          [],
689                          [#ifndef CONFIG_USERMODE
690                           #error not UML
691                           #endif],
692                          ac_cv_linux_is_uml=yes,)
693                         if test "${ac_cv_linux_is_uml}" = yes; then
694                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
695                         fi
696                         AFS_SYSNAME="$_AFS_SYSNAME"
697                         ;;
698         esac
699         AC_MSG_RESULT($AFS_SYSNAME)
700 fi
701
702 case $AFS_SYSNAME in
703         *_darwin*)
704                 AC_CHECK_HEADERS(crt_externs.h)
705                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
706                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
707                 AC_SUBST(OSXSDK)
708                 ;;
709 esac
710
711 dnl Some hosts have a separate common param file they should include.  Figure
712 dnl out if we're on one of them now that we know the sysname.
713 case $AFS_SYSNAME in
714     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
715     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
716     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
717     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
718     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
719     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
720     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
721     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
722     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
723     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
724     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
725     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
726     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
727     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
728     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
729     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
730     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
731     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
732     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
733     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
734     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
735     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
736     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
737     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
738     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
739     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
740     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
741     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
742     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
743 # Linux alpha adds an extra underscore for no good reason.
744     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
745     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
746     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
747 esac
748
749 OPENAFS_OSCONF
750
751 case $AFS_SYSNAME in *_linux* | *_umlinux*)
752
753                 # Add (sub-) architecture-specific paths needed by conftests
754                 case $AFS_SYSNAME  in
755                         *_umlinux26)
756                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
757                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
758                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
759                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
760                 esac
761
762                 if test "x$enable_kernel_module" = "xyes"; then
763                  if test "x$enable_debug_kernel" = "xno"; then
764                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
765                  fi
766                  OPENAFS_GCC_SUPPORTS_MARCH
767                  AC_SUBST(P5PLUS_KOPTS)
768                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
769                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
770                  OPENAFS_GCC_SUPPORTS_NO_COMMON
771                  OPENAFS_GCC_SUPPORTS_PIPE
772                  AC_SUBST(LINUX_GCC_KOPTS)
773
774                  dnl Setup the kernel build environment
775                  LINUX_KBUILD_USES_EXTRA_CFLAGS
776                  LINUX_KERNEL_COMPILE_WORKS
777
778                  dnl Check for header files
779                  AC_CHECK_LINUX_HEADER([config.h])
780                  AC_CHECK_LINUX_HEADER([completion.h])
781                  AC_CHECK_LINUX_HEADER([exportfs.h])
782                  AC_CHECK_LINUX_HEADER([freezer.h])
783                  AC_CHECK_LINUX_HEADER([key-type.h])
784                  AC_CHECK_LINUX_HEADER([semaphore.h])
785                  AC_CHECK_LINUX_HEADER([seq_file.h])
786
787                  dnl Check for structure elements
788                  AC_CHECK_LINUX_STRUCT([address_space_operations],
789                                        [write_begin], [fs.h])
790                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
791                                        [backing-dev.h])
792                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
793                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
794                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
795                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
796                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
797                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
798                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
799                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
800                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
801                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
802                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
803                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
804                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
805                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
806                                        [fs.h])
807                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
808                                        [fs.h])
809                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
810                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
811                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
812                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
813                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
814                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
815                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
816                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
817                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
818                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
819                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
820
821                  dnl Check for typed structure elements
822                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
823                                              [buf], [fs.h])
824
825                  dnl Function existence checks
826
827                  AC_CHECK_LINUX_FUNC([bdi_init],
828                                      [#include <linux/backing-dev.h>],
829                                      [bdi_init(NULL);])
830                  AC_CHECK_LINUX_FUNC([PageChecked],
831                                      [#include <linux/mm.h>
832 #include <linux/page-flags.h>],
833                                      [struct page *_page;
834                                       int bchecked = PageChecked(_page);])
835                  AC_CHECK_LINUX_FUNC([PageFsMisc],
836                                      [#include <linux/mm.h>
837 #include <linux/page-flags.h>],
838                                      [struct page *_page;
839                                       int bchecked = PageFsMisc(_page);])
840                  AC_CHECK_LINUX_FUNC([current_kernel_time],
841                                      [#include <linux/time.h>],
842                                      [struct timespec s;
843                                       s = current_kernel_time();])
844                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
845                                      [#include <linux/fs.h>],
846                                      [d_alloc_anon(NULL);])
847                  AC_CHECK_LINUX_FUNC([d_make_root],
848                                      [#include <linux/fs.h>],
849                                      [d_make_root(NULL);])
850                  AC_CHECK_LINUX_FUNC([do_sync_read],
851                                      [#include <linux/fs.h>],
852                                      [do_sync_read(NULL, NULL, 0, NULL);])
853                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
854                                      [#include <linux/sched.h>],
855                                      [pid_t p; find_task_by_pid(p);])
856                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
857                                      [#include <linux/fs.h>],
858                                      [generic_file_aio_read(NULL,NULL,0,0);])
859                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
860                                      [#include <linux/pagemap.h>],
861                                      [grab_cache_page_write_begin(NULL, 0, 0);])
862                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
863                                      [#include <linux/list.h>],
864                                      [hlist_unhashed(0);])
865                  AC_CHECK_LINUX_FUNC([i_size_read],
866                                      [#include <linux/fs.h>],
867                                      [i_size_read(NULL);])
868                  AC_CHECK_LINUX_FUNC([inode_setattr],
869                                      [#include <linux/fs.h>],
870                                      [inode_setattr(NULL, NULL);])
871                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
872                                      [#include <linux/net.h>],
873                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
874                  AC_CHECK_LINUX_FUNC([page_follow_link],
875                                      [#include <linux/fs.h>],
876                                      [page_follow_link(0,0);])
877                  AC_CHECK_LINUX_FUNC([page_offset],
878                                      [#include <linux/pagemap.h>],
879                                      [page_offset(NULL);])
880                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
881                                      [#include <linux/pagevec.h>],
882                                      [__pagevec_lru_add_file(NULL);])
883                  AC_CHECK_LINUX_FUNC([path_lookup],
884                                      [#include <linux/fs.h>
885                                       #include <linux/namei.h>],
886                                      [path_lookup(NULL, 0, NULL);])
887                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
888                                      [#include <linux/rcupdate.h>],
889                                      [rcu_read_lock();])
890                  AC_CHECK_LINUX_FUNC([set_nlink],
891                                      [#include <linux/fs.h>],
892                                      [set_nlink(NULL, 1);])
893                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
894                                      [#include <linux/splice.h>],
895                                      [splice_direct_to_actor(NULL,NULL,NULL);])
896                  AC_CHECK_LINUX_FUNC([svc_addr_in],
897                                      [#include <linux/sunrpc/svc.h>],
898                                      [svc_addr_in(NULL);])
899                  AC_CHECK_LINUX_FUNC([zero_user_segments],
900                                      [#include <linux/highmem.h>],
901                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
902                  AC_CHECK_LINUX_FUNC([noop_fsync],
903                                      [#include <linux/fs.h>],
904                                      [void *address = &noop_fsync; printk("%p\n", address)];)
905
906                  dnl Consequences - things which get set as a result of the
907                  dnl                above tests
908                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
909                        [AC_DEFINE([AFS_NONFSTRANS], 1,
910                                   [define to disable the nfs translator])])
911
912                  dnl Assorted more complex tests
913                  LINUX_EXPORTS_PROC_ROOT_FS
914                  LINUX_KMEM_CACHE_INIT
915                  LINUX_HAVE_KMEM_CACHE_T
916                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
917                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
918                  LINUX_D_PATH_TAKES_STRUCT_PATH
919                  LINUX_NEW_EXPORT_OPS
920                  LINUX_INODE_SETATTR_RETURN_TYPE
921                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
922                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
923                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
924                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
925                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
926                  LINUX_DOP_D_DELETE_TAKES_CONST
927                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
928                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
929                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
930                  LINUX_FOP_F_FSYNC_TAKES_RANGE
931                  LINUX_AOP_WRITEBACK_CONTROL
932                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
933                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
934                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
935                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
936                  LINUX_KERNEL_SOCK_CREATE
937                  LINUX_EXPORTS_KEY_TYPE_KEYRING
938                  LINUX_NEED_RHCONFIG
939                  LINUX_RECALC_SIGPENDING_ARG_TYPE
940                  LINUX_EXPORTS_TASKLIST_LOCK
941                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
942                  LINUX_STATFS_TAKES_DENTRY
943                  LINUX_REFRIGERATOR
944                  LINUX_HAVE_TRY_TO_FREEZE
945                  LINUX_LINUX_KEYRING_SUPPORT
946                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
947                  LINUX_KEY_ALLOC_NEEDS_CRED
948                  LINUX_INIT_WORK_HAS_DATA
949                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
950                  LINUX_HAVE_DCACHE_LOCK
951                  LINUX_D_COUNT_IS_INT
952                  LINUX_IOP_MKDIR_TAKES_UMODE_T
953                  LINUX_IOP_CREATE_TAKES_UMODE_T
954
955                  dnl If we are guaranteed that keyrings will work - that is
956                  dnl  a) The kernel has keyrings enabled
957                  dnl  b) The code is new enough to give us a key_type_keyring
958                  dnl then we just disable syscall probing unless we've been
959                  dnl told otherwise
960
961                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
962                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
963                           [enable_linux_syscall_probing="no"],
964                           [enable_linux_syscall_probing="yes"])
965                  ])
966
967                  dnl Syscall probing needs a few tests of its own, and just
968                  dnl won't work if the kernel doesn't export init_mm
969                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
970                    LINUX_EXPORTS_INIT_MM
971                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
972                      AC_MSG_ERROR(
973                        [Can't do syscall probing without exported init_mm])
974                    ])
975                    LINUX_EXPORTS_SYS_CHDIR
976                    LINUX_EXPORTS_SYS_OPEN
977                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
978                              [define to enable syscall table probes])
979                  ])
980
981                  dnl Packaging and SMP build
982                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
983                    LINUX_WHICH_MODULES
984                  else
985                    AC_SUBST(MPS,'SP')
986                  fi
987
988                  dnl Syscall probing
989                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
990                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
991                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
992                    ])
993                    ac_cv_linux_exports_sys_call_table=no
994                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
995                      ac_cv_linux_exports_ia32_sys_call_table=yes
996                    fi
997                  else
998                    LINUX_EXPORTS_KALLSYMS_ADDRESS
999                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1000                    LINUX_EXPORTS_SYS_CALL_TABLE
1001                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1002                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1003                          linux_syscall_method=none
1004                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1005                             linux_syscall_method=scan
1006                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1007                                linux_syscall_method=scan_with_kallsyms_address
1008                             fi
1009                          fi
1010                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1011                             linux_syscall_method=kallsyms_symbol
1012                          fi
1013                          if test "x$linux_syscall_method" = "xnone"; then
1014                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1015                             linux_syscall_method=scan
1016                          fi
1017                    fi
1018                  fi
1019                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1020                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1021                  fi
1022                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1023                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1024                  fi
1025                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1026                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1027                  else
1028                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1029                  fi
1030                 :
1031                 fi
1032 dnl Linux-only, but just enable always.
1033                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1034 esac
1035
1036 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1037     [ac_cv_sync_fetch_and_add],
1038     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1039                     [ac_cv_sync_fetch_and_add=yes],
1040                     [ac_cv_sync_fetch_and_add=no])
1041 ])
1042 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1043       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1044                 [define if your C compiler has __sync_add_and_fetch])])
1045
1046 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1047     [ac_cv_sockaddr_len],
1048     [AC_TRY_COMPILE( [#include <sys/types.h>
1049 #include <sys/socket.h>],
1050                      [struct sockaddr *a; a->sa_len=0;],
1051                      [ac_cv_sockaddr_len=yes],
1052                      [ac_cv_sockaddr_len=no])
1053 ])
1054 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1055       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1056                  [define if you struct sockaddr sa_len])])
1057
1058 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1059         echo Skipping library tests because they confuse Irix.
1060 else
1061   AC_SEARCH_LIBS([socket], [socket inet])
1062   AC_SEARCH_LIBS([connect], [nsl])
1063   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1064
1065   dnl darwin wants it, aix hates it
1066   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1067   AC_TRY_COMPILE([
1068   #include <stdlib.h>
1069   #include <stdio.h>
1070   #include <sys/types.h>
1071   #include <sys/socket.h>
1072   #include <netinet/in.h>
1073   #include <arpa/inet.h>
1074   #include <arpa/nameser.h>
1075   #include <arpa/nameser_compat.h>
1076   #include <resolv.h>
1077   ], [static int i; i = 0;],
1078   [AC_MSG_RESULT(yes)
1079    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1080   [AC_MSG_RESULT(no)
1081    ])
1082
1083   openafs_save_libs="$LIBS"
1084   AC_MSG_CHECKING([for res_search])
1085   AC_FUNC_RES_SEARCH
1086
1087   if test "$ac_cv_func_res_search" = no; then
1088       for lib in dns nsl resolv; do
1089         if test "$ac_cv_func_res_search" != yes; then
1090           LIBS="-l$lib $LIBS"
1091           AC_FUNC_RES_SEARCH
1092           LIBS="$openafs_save_libs"
1093         fi
1094       done    
1095       if test "$ac_cv_func_res_search" = yes; then
1096         LIB_AFSDB="-l$lib"
1097         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1098         AC_MSG_RESULT([yes, in lib$lib])
1099       else
1100         AC_MSG_RESULT(no)
1101       fi
1102   else
1103     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1104     AC_MSG_RESULT(yes)
1105   fi
1106   
1107 fi
1108 XLIBS="$LIB_AFSDB $XLIBS"
1109
1110 AC_CHECK_RESOLV_RETRANS
1111
1112 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1113     [ac_cv_setsockopt_iprecverr],
1114     [AC_TRY_COMPILE( [
1115 #include <sys/types.h>
1116 #include <sys/socket.h>
1117 #include <netinet/in.h>],
1118 [int on=1;
1119 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1120         [ac_cv_setsockopt_iprecverr=yes],
1121         [ac_cv_setsockopt_iprecverr=no])])
1122
1123 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1124       [AC_DEFINE(ADAPT_PMTU_RECVERR, 1,
1125                  [define if asynchronous socket errors can be received])])
1126
1127 PTHREAD_LIBS=error
1128 if test "x$MKAFS_OSTYPE" = OBSD; then
1129         PTHREAD_LIBS="-pthread"
1130 fi
1131 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1132         PTHREAD_LIBS="-pthread"
1133 fi
1134 if test "x$PTHREAD_LIBS" = xerror; then
1135         AC_CHECK_LIB(pthread, pthread_attr_init,
1136                 PTHREAD_LIBS="-lpthread")
1137 fi
1138 if test "x$PTHREAD_LIBS" = xerror; then
1139         AC_CHECK_LIB(pthreads, pthread_attr_init,
1140                 PTHREAD_LIBS="-lpthreads")
1141 fi
1142 if test "x$PTHREAD_LIBS" = xerror; then
1143         AC_CHECK_LIB(c_r, pthread_attr_init,
1144                 PTHREAD_LIBS="-lc_r")
1145 fi
1146 if test "x$PTHREAD_LIBS" = xerror; then
1147         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1148 fi
1149 if test "x$PTHREAD_LIBS" = xerror; then
1150         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1151         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1152                 PTHREAD_LIBS="-lpthread")
1153 fi
1154 if test "x$PTHREAD_LIBS" = xerror; then
1155         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1156 fi
1157 AC_SUBST(PTHREAD_LIBS)
1158
1159 HOST_CPU="$host_cpu"
1160
1161 if test "x$with_bsd_kernel_headers" != "x"; then
1162         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1163 else
1164         BSD_KERNEL_PATH="/usr/src/sys"
1165 fi
1166
1167 if test "x$with_bsd_kernel_build" != "x"; then
1168         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1169 else
1170         case $AFS_SYSNAME in
1171                 *_fbsd_*)
1172                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1173                         ;;
1174                 *_nbsd*)
1175                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1176         esac
1177 fi
1178
1179 # Fast restart
1180 if test "$enable_supergroups" = "yes"; then
1181         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1182 fi
1183
1184 if test "$enable_bitmap_later" = "yes"; then
1185         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1186 fi
1187
1188 if test "$enable_unix_sockets" = "yes"; then
1189         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1190         USE_UNIX_SOCKETS="yes"
1191 else
1192         USE_UNIX_SOCKETS="no"
1193 fi
1194 AC_SUBST(USE_UNIX_SOCKETS)
1195
1196 dnl if test "$ac_cv_setsockopt_iprecverr" = "yes"; then
1197 dnl     AC_DEFINE(ADAPT_PMTU, 1, [define if you want to decode icmp unreachable packets to discover path mtu])
1198 dnl fi
1199
1200 if test "$enable_namei_fileserver" = "yes"; then
1201         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1202         VFSCK=""
1203 else
1204         if test "$enable_namei_fileserver" = "default"; then
1205                 case $host in
1206                         *-solaris2.10*)
1207                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1208                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1209                                 VFSCK=""
1210                                 ;;
1211                         *-solaris2.11*)
1212                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1213                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1214                                 VFSCK=""
1215                                 ;;
1216                         *)
1217                                 VFSCK="vfsck"
1218                                 ;;
1219                 esac
1220         else
1221                 VFSCK="vfsck"
1222         fi
1223 fi
1224
1225 dnl check for tivoli
1226 AC_MSG_CHECKING(for tivoli tsm butc support)
1227 XBSA_CFLAGS=""
1228 if test "$enable_tivoli_tsm" = "yes"; then
1229         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1230         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1231         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1232         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1233
1234         if test -r "$XBSADIR3/dsmapifp.h"; then
1235                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1236                 XBSA_XLIBS="-ldl"
1237                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1238         elif test -r "$XBSADIR4/dsmapifp.h"; then
1239                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1240                 XBSA_XLIBS="-ldl"
1241                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1242         elif test -r "$XBSADIR1/xbsa.h"; then
1243                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1244                 XBSA_XLIBS=""
1245                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1246         elif test -r "$XBSADIR2/xbsa.h"; then
1247                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1248                 XBSA_XLIBS=""
1249                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1250         else
1251                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1252         fi
1253 else
1254         AC_MSG_RESULT([no])
1255 fi
1256 AC_SUBST(XBSA_CFLAGS)
1257 AC_SUBST(XBSA_XLIBS) 
1258
1259 dnl checks for header files.
1260 AC_HEADER_STDC
1261 AC_HEADER_SYS_WAIT
1262 AC_HEADER_DIRENT
1263 AC_CHECK_HEADERS([ \
1264                    arpa/inet.h \
1265                    arpa/nameser.h \
1266                    curses.h\
1267                    direct.h \
1268                    et/com_err.h \
1269                    errno.h \
1270                    fcntl.h \
1271                    grp.h \
1272                    math.h \
1273                    mntent.h \
1274                    ncurses.h \
1275                    netdb.h \
1276                    netinet/in.h \
1277                    pthread_np.h \
1278                    pwd.h \
1279                    regex.h \
1280                    security/pam_appl.h \
1281                    signal.h \
1282                    stdint.h \
1283                    stdio_ext.h \
1284                    stdlib.h \
1285                    string.h \
1286                    strings.h \
1287                    sys/bitypes.h \
1288                    sys/bswap.h \
1289                    sys/dk.h \
1290                    sys/fcntl.h \
1291                    sys/file.h \
1292                    sys/fs_types.h \
1293                    sys/fstyp.h \
1294                    sys/ioctl.h \
1295                    sys/ipc.h \
1296                    sys/lockf.h \
1297                    sys/map.h \
1298                    sys/mount.h \
1299                    sys/mntent.h \
1300                    sys/mnttab.h \
1301                    sys/pag.h \
1302                    sys/param.h \
1303                    sys/resource.h \
1304                    sys/select.h \
1305                    sys/statfs.h \
1306                    sys/statvfs.h \
1307                    sys/socket.h \
1308                    sys/sysctl.h \
1309                    sys/time.h \
1310                    sys/types.h \
1311                    sys/uio.h \
1312                    sys/un.h \
1313                    sys/vfs.h \
1314                    syslog.h \
1315                    termios.h \
1316                    time.h \
1317                    ucontext.h \
1318                    unistd.h \
1319                    windows.h \
1320                 ])
1321
1322 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1323 #ifdef HAVE_NETINET_IN_H
1324 # include <netinet/in.h>
1325 #endif])
1326
1327 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1328 #ifdef HAVE_SYS_SOCKET_H
1329 # include <sys/socket.h>
1330 #endif])
1331
1332 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1333 #ifdef HAVE_SYS_SOCKET_H
1334 # include <sys/socket.h>
1335 #endif
1336 #ifdef HAVE_NETINET_IN_H
1337 # include <netinet/in.h>
1338 #endif
1339 #ifdef HAVE_NET_IF_H
1340 # include <net/if.h>
1341 #endif])
1342
1343 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1344 #ifdef HAVE_SECURITY_PAM_APPL_H
1345 # include <security/pam_appl.h>
1346 #endif])
1347
1348 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1349
1350 AC_CHECK_TYPES([fsblkcnt_t],,,[
1351 #include <sys/types.h>
1352 #ifdef HAVE_SYS_BITYPES_H
1353 #include <sys/bitypes.h>
1354 #endif
1355 #ifdef HAVE_SYS_STATFS_H
1356 #include <sys/statfs.h>
1357 #endif
1358 #ifdef HAVE_SYS_STATVFS_H
1359 #include <sys/statvfs.h>
1360 #endif
1361 ])
1362
1363 dnl see what struct stat has for timestamps
1364 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1365
1366 dnl check for curses-lib
1367 save_LIBS=$LIBS
1368 AC_CHECK_LIB( [ncurses], [setupterm],
1369 [LIB_curses=-lncurses],
1370     [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1371         [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])
1372     ])
1373 ])
1374 LIBS=$save_LIBS
1375 AC_SUBST(LIB_curses)
1376
1377 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1378
1379 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1380 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1381         case $AFS_SYSNAME in
1382         sgi_*)
1383                 HAVE_PAM="no"
1384                 ;;
1385         *)
1386                 HAVE_PAM="yes"
1387                 ;;
1388         esac
1389 else
1390         HAVE_PAM="no"
1391 fi
1392 AC_SUBST(HAVE_PAM)
1393
1394 if test "$enable_login" = yes; then
1395         BUILD_LOGIN="yes"
1396 else
1397         BUILD_LOGIN="no"
1398 fi
1399 AC_SUBST(BUILD_LOGIN)
1400
1401 AC_CHECK_FUNCS([ \
1402         arc4random \
1403         fcntl \
1404         fseeko64 \
1405         ftello64 \
1406         getcwd \
1407         getegid \
1408         geteuid \
1409         getgid \
1410         getuid \
1411         getprogname \
1412         getrlimit \
1413         issetugid \
1414         mkstemp \
1415         pread \
1416         preadv \
1417         preadv64 \
1418         pwrite \
1419         pwritev \
1420         pwritev64 \
1421         regcomp \
1422         regerror \
1423         regexec \
1424         setitimer \
1425         setprogname \
1426         setvbuf \
1427         sigaction \
1428         strcasestr \
1429         strerror \
1430         sysconf \
1431         sysctl \
1432         timegm \
1433 ])
1434
1435 OPENAFS_ROKEN()
1436 OPENAFS_C_ATTRIBUTE()
1437
1438 dnl Functions that Heimdal's libroken provides, but that we
1439 dnl haven't found a need for yet, and so haven't imported
1440 AC_CHECK_FUNCS([ \
1441         chown \
1442         fchown \
1443         gethostname \
1444         lstat \
1445         inet_aton \
1446         inet_ntop \
1447         inet_pton \
1448         putenv \
1449         readv \
1450         setenv \
1451         strdup \
1452         strftime \
1453         strndup \
1454         strsep \
1455         unsetenv \
1456 ])
1457
1458 dnl Functions that are in objects that we always build from libroken
1459 AC_CHECK_FUNCS([ \
1460         asprintf \
1461         asnprintf \
1462         vasprintf \
1463         vasnprintf \
1464         vsnprintf \
1465         snprintf \
1466 ])
1467
1468 dnl Functions that we're going to try and get from libroken
1469 AC_REPLACE_FUNCS([ \
1470         daemon \
1471         ecalloc \
1472         emalloc \
1473         erealloc \
1474         err \
1475         errx \
1476         flock \
1477         getdtablesize \
1478         getopt \
1479         getprogname \
1480         gettimeofday \
1481         localtime_r \
1482         mkstemp \
1483         setenv \
1484         strcasecmp \
1485         strlcat \
1486         strnlen \
1487         strlcpy \
1488         strsep \
1489         tdelete \
1490         tfind \
1491         tsearch \
1492         twalk \
1493         unsetenv \
1494         verr \
1495         verrx \
1496         vsyslog \
1497         vwarn \
1498         vwarnx \
1499         warn \
1500         warnx \
1501 ])
1502
1503 dnl Headers that we're going to try and get from libroken
1504 AC_CHECK_HEADERS([ \
1505         err.h \
1506         search.h \
1507 ])
1508
1509 AC_CHECK_DECLS([h_errno], [], [], [
1510 #include <sys/types.h>
1511 #ifdef HAVE_NETDB_H
1512 #include <netdb.h>
1513 #endif
1514 ])
1515
1516 AC_HEADER_TIME
1517
1518 ROKEN_HEADERS=
1519 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1520       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1521       [])
1522 AC_SUBST(ROKEN_HEADERS)
1523
1524 dnl Stuff that's harder ...
1525 AC_MSG_CHECKING([for bswap16])
1526 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1527 #ifdef HAVE_SYS_TYPES_H
1528 #include <sys/types.h>
1529 #endif
1530 #ifdef HAVE_SYS_BSWAP_H
1531 #include <sys/bswap.h>
1532 #endif
1533 ],
1534 [short a, b; b = bswap16(a); ])],
1535 [AC_MSG_RESULT(yes)
1536  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1537 ],
1538 [AC_MSG_RESULT(no)])
1539
1540 AC_MSG_CHECKING([for bswap32])
1541 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1542 #include <sys/types.h>
1543 #endif
1544 #ifdef HAVE_SYS_BSWAP_H
1545 #include <sys/bswap.h>
1546 #endif
1547 ],
1548 [int a, b; b = bswap32(a); ])],
1549 [AC_MSG_RESULT(yes)
1550  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1551 ],
1552 [AC_MSG_RESULT(no)])
1553
1554 case $AFS_SYSNAME in
1555 *hp_ux* | *hpux*)
1556    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1557    ;;
1558 *)
1559    AC_MSG_CHECKING([for positional I/O])
1560    if test "$ac_cv_func_pread" = "yes" && \
1561            test "$ac_cv_func_pwrite" = "yes"; then
1562       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1563       AC_MSG_RESULT(yes)
1564    else
1565      AC_MSG_RESULT(no)
1566    fi
1567    AC_MSG_CHECKING([for vectored positional I/O])
1568    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1569                "$ac_cv_func_pwritev" = "yes" -a \
1570                "$ac_cv_func_preadv64" = "yes" -a \
1571                "$ac_cv_func_pwritev64" = "yes"],
1572          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1573           AC_MSG_RESULT(yes)],
1574          [AC_MSG_RESULT(no)])
1575    ;;
1576 esac
1577
1578 AC_MSG_CHECKING([for POSIX regex library])
1579 if test "$ac_cv_header_regex_h" = "yes" && \
1580         test "$ac_cv_func_regcomp" = "yes" && \
1581         test "$ac_cv_func_regexec" = "yes" && \
1582         test "$ac_cv_func_regerror" = "yes"; then
1583     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1584     AC_MSG_RESULT(yes)
1585 else
1586     AC_MSG_RESULT(no)
1587 fi
1588
1589 dnl Look for "non-portable" pthreads functions.
1590 save_LIBS="$LIBS"
1591 LIBS="$LIBS $PTHREAD_LIBS"
1592 AC_CHECK_FUNCS([ \
1593         pthread_set_name_np \
1594         pthread_setname_np \
1595 ])
1596
1597 dnl Sadly, there are three different versions of pthread_setname_np.
1598 dnl Try to cater for all of them.
1599 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1600     AC_MSG_CHECKING([for signature of pthread_setname_np])
1601     AC_TRY_COMPILE([
1602 #include <pthread.h>
1603 #ifdef HAVE_PTHREAD_NP_H
1604 #include <pthread_np.h>
1605 #endif
1606 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1607         AC_MSG_RESULT([three arguments])
1608         pthread_setname_np_args=3], [
1609         AC_TRY_COMPILE([
1610 #include <pthread.h>
1611 #ifdef HAVE_PTHREAD_NP_H
1612 #include <pthread_np.h>
1613 #endif
1614 ], [pthread_setname_np(pthread_self(), "test")], [
1615             AC_MSG_RESULT([two arguments])
1616             pthread_setname_np_args=2], [
1617             AC_TRY_COMPILE([
1618 #include <pthread.h>
1619 #ifdef HAVE_PTHREAD_NP_H
1620 #include <pthread_np.h>
1621 #endif
1622 ], [pthread_setname_np("test")], [
1623                 AC_MSG_RESULT([one argument])
1624                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1625 ])
1626 ])
1627 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1628 fi
1629 LIBS="$save_LIBS"
1630
1631 openafs_cv_saved_CFLAGS="$CFLAGS"
1632 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1633
1634 AC_TYPE_SIGNAL
1635 OPENAFS_RETSIGTYPE
1636 AC_CHECK_SIZEOF(void *)
1637 AC_CHECK_SIZEOF(unsigned long long)
1638 AC_CHECK_SIZEOF(unsigned long)
1639 AC_CHECK_SIZEOF(unsigned int)
1640 AC_TYPE_INTPTR_T
1641 AC_TYPE_UINTPTR_T
1642 AC_TYPE_SSIZE_T
1643 AC_CHECK_TYPE([sig_atomic_t],[],
1644     [AC_DEFINE([sig_atomic_t], [int],
1645         [Define to int if <signal.h> does not define.])],
1646 [#include <sys/types.h>
1647 #include <signal.h>])
1648 AC_CHECK_TYPE([socklen_t],[],
1649     [AC_DEFINE([socklen_t], [int],
1650         [Define to int if <sys/socket.h> does not define.])],
1651 [#include <sys/types.h>
1652 #include <sys/socket.h>])
1653 AC_CHECK_TYPES(off64_t)
1654 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1655 AC_CHECK_TYPES([struct winsize], [], [], [
1656 #ifdef HAVE_TERMIOS_H
1657 # include <termios.h>
1658 #else
1659 # include <sys/termios.h>
1660 #endif
1661 #include <sys/ioctl.h>])
1662 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1663                 struct sockaddr_storage],
1664                [], [], [
1665 #include <sys/types.h>
1666 #include <sys/socket.h>
1667 ])
1668 AC_CHECK_TYPES([sa_family_t], [], [], [
1669 #include <sys/types.h>
1670 #include <sys/socket.h>
1671 ])
1672 AC_CHECK_TYPES([struct addrinfo], [], [], [
1673 #include <sys/types.h>
1674 #ifdef HAVE_NETDB_H
1675 #include <netdb.h>
1676 #endif
1677 ])
1678 AC_CHECK_TYPES([long long], [], [], [])
1679
1680 AC_SIZEOF_TYPE(long)
1681
1682 CFLAGS="$openafs_cv_saved_CFLAGS"
1683
1684 RRA_HEADER_PAM_CONST
1685
1686
1687 dnl Directory PATH handling
1688 if test "x$enable_transarc_paths" = "xyes"  ; then 
1689     afsconfdir=${afsconfdir=/usr/afs/etc}
1690     viceetcdir=${viceetcdir=/usr/vice/etc}
1691     afskerneldir=${afskerneldir=${viceetcdir}}
1692     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1693     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1694     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1695     afsdbdir=${afsdbdir=/usr/afs/db}
1696     afslogsdir=${afslogsdir=/usr/afs/logs}
1697     afslocaldir=${afslocaldir=/usr/afs/local}
1698     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1699     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1700     afsdatadir=${afsdatadir=/usr/vice/etc}
1701 else 
1702     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1703     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1704     afskerneldir=${afskerneldir='${libdir}/openafs'}
1705     afssrvbindir=${afssrvbindir='${bindir}'}
1706     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1707     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1708     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1709     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1710     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1711     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1712     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1713     afsdatadir=${afsdatadir='${datadir}/openafs'}
1714 fi
1715 AC_SUBST(afsconfdir)
1716 AC_SUBST(viceetcdir)
1717 AC_SUBST(afskerneldir)
1718 AC_SUBST(afssrvbindir)
1719 AC_SUBST(afssrvsbindir)
1720 AC_SUBST(afssrvlibexecdir)
1721 AC_SUBST(afsdbdir)
1722 AC_SUBST(afslogsdir)
1723 AC_SUBST(afslocaldir)
1724 AC_SUBST(afsbackupdir)
1725 AC_SUBST(afsbosconfigdir)
1726 AC_SUBST(afsdatadir)
1727
1728 if test "x$enable_kernel_module" = "xyes"; then
1729 ENABLE_KERNEL_MODULE=libafs
1730 fi
1731
1732 if test "x$enable_pthreaded_ubik" = "xyes"; then
1733 ENABLE_PTHREADED_UBIK=yes
1734 fi
1735
1736 AC_SUBST(VFSCK)
1737 AC_SUBST(AFS_SYSNAME)
1738 AC_SUBST(AFS_PARAM_COMMON)
1739 AC_SUBST(ENABLE_KERNEL_MODULE)
1740 AC_SUBST(ENABLE_PTHREADED_UBIK)
1741 AC_SUBST(LIB_AFSDB)
1742 AC_SUBST(LINUX_KERNEL_PATH)
1743 AC_SUBST(LINUX_KERNEL_BUILD)
1744 AC_SUBST(HOST_CPU)
1745 AC_SUBST(BSD_KERNEL_PATH)
1746 AC_SUBST(BSD_KERNEL_BUILD)
1747 AC_SUBST(LINUX_VERSION)
1748 AC_SUBST(MKAFS_OSTYPE)
1749 AC_SUBST(TOP_OBJDIR)
1750 AC_SUBST(TOP_SRCDIR)
1751 AC_SUBST(TOP_INCDIR)
1752 AC_SUBST(TOP_LIBDIR)
1753 AC_SUBST(DEST)
1754 AC_SUBST(DARWIN_INFOFILE)
1755 AC_SUBST(IRIX_BUILD_IP35)
1756 AC_SUBST(HTML_XSL)
1757 AC_SUBST(XSLTPROC)
1758 AC_SUBST(DOCBOOK2PDF)
1759 AC_SUBST(DOCBOOK_STYLESHEETS)
1760
1761 OPENAFS_FUSE
1762 OPENAFS_SWIG
1763
1764 TOP_SRCDIR="${srcdir}/src"
1765 dnl
1766 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1767 dnl
1768 case $TOP_SRCDIR in
1769         /*)
1770                 ;;
1771         *)
1772                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1773                 ;;
1774 esac
1775
1776 TOP_OBJDIR="${SRCDIR_PARENT}"
1777 TOP_INCDIR="${SRCDIR_PARENT}/include"
1778 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1779 if test "${DEST}x" = "x"; then
1780         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1781 fi
1782
1783 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1784 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1785 AC_SUBST(HELPER_SPLINT)
1786 AC_SUBST(HELPER_SPLINTCFG)
1787
1788 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1789
1790 dnl Check to see if crypt lives in a different library
1791 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1792 AC_SUBST(LIB_crypt)
1793
1794 dnl Check to see if the compiler support labels in structs
1795 AC_MSG_CHECKING(for label support in structs)
1796 AC_TRY_COMPILE([], [
1797 extern void osi_UFSOpen(void);
1798 struct labeltest {
1799    void (*open) (void);
1800 };
1801 struct labeltest struct_labeltest = {
1802    .open       = osi_UFSOpen,
1803 }
1804 ],
1805 [AC_MSG_RESULT(yes)
1806  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1807 ],
1808 [AC_MSG_RESULT(no)
1809 ])
1810
1811 AC_MSG_CHECKING([checking for dirfd])
1812 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1813 #ifdef HAVE_DIRENT_H
1814 #include <dirent.h>
1815 #endif
1816 ]],
1817         [[DIR *d = 0; dirfd(d);]])],
1818         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1819 if test "$ac_rk_have_dirfd" = "yes" ; then
1820         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1821 fi
1822 AC_MSG_RESULT($ac_rk_have_dirfd)
1823
1824 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1825 #ifdef HAVE_DIRENT_H
1826 #include <dirent.h>
1827 #endif])
1828
1829 dnl Eventually, this will look for the system one, or for OpenSSL
1830 LIB_hcrypto="-lafshcrypto"
1831 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1832 AC_SUBST(LIB_hcrypto)
1833 AC_SUBST(LDFLAGS_hcrypto)
1834 ])
1835
1836 AC_DEFUN([SUMMARY], [
1837     # Print a configuration summary
1838 echo 
1839 echo "**************************************"
1840 echo configure summary
1841 echo
1842 AS_IF([test $LIB_curses],[
1843 echo "LIB_curses :                $LIB_curses" ],[
1844 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1845 ])
1846 echo 
1847 echo "**************************************"
1848 ])