De-duplicate a couple afs_CheckCode uniquifiers
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([pam],
79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
80     ,
81     [enable_pam="yes"])
82 AC_ARG_ENABLE([gtx],
83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
84 AC_ARG_ENABLE([uss],
85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
86 AC_ARG_ENABLE([namei-fileserver],
87     [AS_HELP_STRING([--enable-namei-fileserver],
88         [force compilation of namei fileserver in preference to inode
89          fileserver])],
90     , 
91     [enable_namei_fileserver="default"])
92 AC_ARG_ENABLE([supergroups],
93     [AS_HELP_STRING([--enable-supergroups],
94         [enable support for nested pts groups])],
95     , 
96     [enable_supergroups="no"])
97 AC_ARG_ENABLE([bitmap-later],
98     [AS_HELP_STRING([--enable-bitmap-later],
99         [enable fast startup of file server by not reading bitmap till
100          needed])],
101     , 
102     [enable_bitmap_later="no"])
103 AC_ARG_ENABLE([unix-sockets],
104     [AS_HELP_STRING([--disable-unix-sockets],
105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
106     ,
107     [enable_unix_sockets="yes"])
108 AC_ARG_ENABLE([tivoli-tsm],
109     [AS_HELP_STRING([--enable-tivoli-tsm],
110         [enable use of the Tivoli TSM API libraries for butc support])],
111     , 
112     [enable_tivoli_tsm="no"])
113 AC_ARG_ENABLE([pthreaded-ubik],
114     [AS_HELP_STRING([--enable-pthreaded-ubik],
115         [enable installation of pthreaded ubik applications (defaults to
116          disabled)])],
117     ,
118     [enable_pthreaded_ubik="no"])
119
120 dnl Kernel module build options.
121 AC_ARG_WITH([linux-kernel-headers],
122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
123         [use the kernel headers found at path (optional, defaults to
124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
126 AC_ARG_WITH([linux-kernel-build],
127     [AS_HELP_STRING([--with-linux-kernel-build=path],
128         [use the kernel build found at path(optional, defaults to 
129         kernel headers path)])])
130 AC_ARG_WITH([bsd-kernel-headers],
131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
132         [use the kernel headers found at path (optional, defaults to
133          /usr/src/sys)])])
134 AC_ARG_WITH([bsd-kernel-build],
135     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
136         [use the kernel build found at path (optional, defaults to
137          KSRC/i386/compile/GENERIC)])])
138 AC_ARG_WITH([linux-kernel-packaging],
139     [AS_HELP_STRING([--with-linux-kernel-packaging],
140         [use standard naming conventions to aid Linux kernel build packaging
141          (disables MPS, sets the kernel module name to openafs.ko, and
142          installs kernel modules into the standard Linux location)])],
143     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
144      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
145     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
146 AC_ARG_ENABLE([kernel-module],
147     [AS_HELP_STRING([--disable-kernel-module],
148         [disable compilation of the kernel module (defaults to enabled)])],
149     , 
150     [enable_kernel_module="yes"])
151 AC_ARG_ENABLE([redhat-buildsys],
152     [AS_HELP_STRING([--enable-redhat-buildsys],
153         [enable compilation of the redhat build system kernel (defaults to
154          disabled)])],
155     ,
156     [enable_redhat_buildsys="no"])
157
158 dnl Installation locations.
159 AC_ARG_ENABLE([transarc-paths],
160     [AS_HELP_STRING([--enable-transarc-paths],
161         [use Transarc style paths like /usr/afs and /usr/vice])],
162     , 
163     [enable_transarc_paths="no"])
164
165 dnl Deprecated crypto
166 AC_ARG_ENABLE([kauth],
167     [AS_HELP_STRING([--disable-kauth],
168         [do not install the deprecated kauth server and utilities (defaults to
169          enabled)])],
170     ,
171     [enable_kauth="yes"])
172
173 dnl Optimization and debugging flags.
174 AC_ARG_ENABLE([strip-binaries],
175     [AS_HELP_STRING([--disable-strip-binaries],
176         [disable stripping of symbol information from binaries (defaults to
177          enabled)])],
178     ,
179     [enable_strip_binaries="maybe"])
180 AC_ARG_ENABLE([debug],
181     [AS_HELP_STRING([--enable-debug],
182         [enable compilation of the user space code with debugging information
183          (defaults to disabled)])],
184     , 
185     [enable_debug="no"])
186 AC_ARG_ENABLE([optimize],
187     [AS_HELP_STRING([--disable-optimize],
188         [disable optimization for compilation of the user space code (defaults
189          to enabled)])],
190     , 
191     [enable_optimize="yes"])
192 AC_ARG_ENABLE([warnings],
193     [AS_HELP_STRING([--enable-warnings],
194         [enable compilation warnings when building with gcc (defaults to
195          disabled)])],
196     ,
197     [enable_warnings="no"])
198 AC_ARG_ENABLE([checking],
199     [AS_HELP_STRING([--enable-checking],
200         [turn compilation warnings into errors when building with gcc (defaults
201          to disabled)])],
202     [enable_checking="$enableval"],
203     [enable_checking="no"])
204 AC_ARG_ENABLE([debug-locks],
205     [AS_HELP_STRING([--enable-debug-locks],
206         [turn on lock debugging assertions (defaults to disabled)])],
207     [enable_debug_locks="$enableval"],
208     [enable_debug_locks="no"])
209 AC_ARG_ENABLE([debug-kernel],
210     [AS_HELP_STRING([--enable-debug-kernel],
211         [enable compilation of the kernel module with debugging information
212          (defaults to disabled)])],
213     ,
214     [enable_debug_kernel="no"])
215 AC_ARG_ENABLE([optimize-kernel],
216     [AS_HELP_STRING([--disable-optimize-kernel],
217         [disable compilation of the kernel module with optimization (defaults
218          based on platform)])],
219     , 
220     [enable_optimize_kernel=""])
221 AC_ARG_ENABLE([debug-lwp],
222     [AS_HELP_STRING([--enable-debug-lwp],
223         [enable compilation of the LWP code with debugging information
224          (defaults to disabled)])],
225     ,
226     [enable_debug_lwp="no"])
227 AC_ARG_ENABLE([optimize-lwp],
228     [AS_HELP_STRING([--disable-optimize-lwp],
229         [disable optimization for compilation of the LWP code (defaults to
230          enabled)])],
231     ,
232     [enable_optimize_lwp="yes"])
233 AC_ARG_ENABLE([debug-pam],
234     [AS_HELP_STRING([--enable-debug-pam],
235         [enable compilation of the PAM code with debugging information
236          (defaults to disabled)])],
237     ,
238     [enable_debug_pam="no"])
239 AC_ARG_ENABLE([optimize-pam],
240     [AS_HELP_STRING([--disable-optimize-pam],
241         [disable optimization for compilation of the PAM code (defaults to
242          enabled)])],
243     ,
244     [enable_optimize_pam="yes"])
245 AC_ARG_ENABLE([linux-syscall-probing],
246     [AS_HELP_STRING([--enable-linux-syscall-probing],
247         [enable Linux syscall probing (defaults to autodetect)])],
248     ,
249     [enable_linux_syscall_probing="maybe"])
250 AC_ARG_WITH([crosstools-dir],
251     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
252     
253 AC_ARG_WITH([xslt-processor],
254         AS_HELP_STRING([--with-xslt-processor=ARG],
255         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
256         [XSLTPROC="$withval"],
257         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
258
259 AC_ARG_WITH([html-xsl], 
260         AS_HELP_STRING([--with-html-xsl],
261         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
262         [HTML_XSL="$withval"],
263         [HTML_XSL="html/chunk.xsl"])
264
265 AC_ARG_WITH([docbook2pdf],
266         AS_HELP_STRING([--with-docbook2pdf=ARG],
267         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
268         [DOCBOOK2PDF="$withval"],
269         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
270
271 AC_ARG_WITH([docbook-stylesheets],
272         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
273         [location of DocBook stylesheets (default is to search a set of likely paths)]),
274         [DOCBOOK_STYLESHEETS="$withval"],
275         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
276         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
277                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
278         fi)
279
280 enable_login="no"
281
282 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
283 dnl documentation build.
284 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
285
286 dnl weird ass systems
287 dnl AC_AIX
288 AC_ISC_POSIX
289 dnl AC_MINIX
290
291 dnl Various compiler setup.
292 AC_TYPE_PID_T
293 AC_TYPE_SIZE_T
294
295 dnl Checks for programs.
296 AC_PROG_INSTALL
297 AC_PROG_LN_S
298 AC_PROG_RANLIB
299 AC_PROG_YACC
300 AM_PROG_LEX
301 dnl if we are flex, be lex-compatible
302 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
303
304 OPENAFS_FORCE_ABS_INSTALL
305 OPENAFS_CHECK_BIGENDIAN
306 OPENAFS_PRINTF_TAKES_Z_LEN
307
308 AC_MSG_CHECKING(your OS)
309 system=$host
310 case $system in
311         *-linux*)
312
313                 MKAFS_OSTYPE=LINUX
314                 if test "x$enable_redhat_buildsys" = "xyes"; then
315                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
316                 fi
317                 if test "x$enable_kernel_module" = "xyes"; then
318                  if test "x$with_linux_kernel_headers" != "x"; then
319                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
320                  else
321                    for utsdir in "/lib/modules/`uname -r`/build" \
322                                  "/lib/modules/`uname -r`/source" \
323                                  "/usr/src/linux-2.4" \
324                                  "/usr/src/linux"; do
325                      LINUX_KERNEL_PATH="$utsdir"
326                      for utsfile in "include/generated/utsrelease.h" \
327                                     "include/linux/utsrelease.h" \
328                                     "include/linux/version.h" \
329                                     "include/linux/version-up.h"; do
330                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
331                          break 2
332                        fi
333                      done
334                    done
335                  fi
336                  if test "x$with_linux_kernel_build" != "x"; then
337                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
338                  else
339                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
340                  fi
341                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
342                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
343                    LINUX_VERSION="$linux_kvers"
344                  else
345                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
346                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
347                      LINUX_VERSION="$linux_kvers"
348                    else
349                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
350                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
351                        if test "x$linux_kvers" = "x"; then
352                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
353                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
354                            if test "x$linux_kvers" = "x"; then
355                              AC_MSG_ERROR(Linux headers lack version definition [2])
356                              exit 1
357                            else
358                              LINUX_VERSION="$linux_kvers"
359                            fi
360                          else
361                            AC_MSG_ERROR(Linux headers lack version definition)
362                            exit 1
363                          fi
364                        else
365                          LINUX_VERSION="$linux_kvers"
366                        fi
367                      else
368                        enable_kernel_module="no"
369                      fi
370                    fi
371                  fi
372                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
373                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
374                      enable_kernel_module="no"
375                  fi
376                  if test "x$enable_kernel_module" = "xno"; then
377                   if test "x$with_linux_kernel_headers" != "x"; then
378                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
379                    exit 1
380                   else
381                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
382                   fi
383                  fi
384                  dnl do we need to determine SUBARCH from autoconf.h
385                  SUBARCH=default
386                 fi
387                 AC_MSG_RESULT(linux)
388                 if test "x$enable_kernel_module" = "xyes"; then
389                  case "$LINUX_VERSION" in
390                   2.2.*) AFS_SYSKVERS=22 ;;
391                   2.4.*) AFS_SYSKVERS=24 ;;
392                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
393                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
394                  esac
395                 fi
396                 ;;
397         *-solaris*)
398                 MKAFS_OSTYPE=SOLARIS
399                 AC_MSG_RESULT(sun4)
400                 AC_PATH_PROG(SOLARISCC, [cc], ,
401                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
402                 if test "x$SOLARISCC" = "x" ; then
403                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
404                 fi
405                 SOLARIS_UFSVFS_HAS_DQRWLOCK
406                 SOLARIS_FS_HAS_FS_ROLLED
407                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
408                 SOLARIS_HAVE_VN_RENAMEPATH
409                 ;;
410         *-sunos*)
411                 MKAFS_OSTYPE=SUNOS
412                 enable_kernel_module=no
413                 AC_MSG_RESULT(sun4)
414                 ;;
415         *-hpux*)
416                 MKAFS_OSTYPE=HPUX
417                 AC_MSG_RESULT(hp_ux)
418                 if test -f "/usr/old/usr/include/ndir.h"; then
419                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
420                 fi
421                 ;;
422         *-irix*)
423                 if test -d /usr/include/sys/SN/SN1; then
424                  IRIX_BUILD_IP35="IP35"
425                 fi
426                 MKAFS_OSTYPE=IRIX
427                 AC_MSG_RESULT(sgi)
428                 ;;
429         *-aix*)
430                 MKAFS_OSTYPE=AIX
431                 AC_MSG_RESULT(rs_aix)
432                 ;;
433         arm-*-darwin*)
434                 MKAFS_OSTYPE=DARWIN
435                 AC_MSG_RESULT(arm_darwin)
436                 ;;
437         powerpc-*-darwin*)
438                 MKAFS_OSTYPE=DARWIN
439                 AC_MSG_RESULT(ppc_darwin)
440                 ;;
441         i386-*-darwin*)
442                 MKAFS_OSTYPE=DARWIN
443                 AC_MSG_RESULT(x86_darwin)
444                 ;;
445         x86_64-*-darwin*)
446                 MKAFS_OSTYPE=DARWIN
447                 AC_MSG_RESULT(x86_darwin)
448                 ;;
449         i386-*-freebsd*)
450                 MKAFS_OSTYPE=FBSD
451                 AC_MSG_RESULT(i386_fbsd)
452                 ;;
453         x86_64-*-freebsd*)
454                 MKAFS_OSTYPE=FBSD
455                 AC_MSG_RESULT(amd64_fbsd)
456                 ;;
457         *-netbsd*)
458                 MKAFS_OSTYPE=NBSD
459                 AC_MSG_RESULT(nbsd)
460                 ;;
461         x86_64-*-openbsd*)
462                 MKAFS_OSTYPE=OBSD
463                 AC_MSG_RESULT(amd64_obsd)
464                 ;;
465         i386-*-openbsd*)
466                 MKAFS_OSTYPE=OBSD
467                 AC_MSG_RESULT(i386_obsd)
468                 ;;
469         *-dragonfly*)
470                 MKAFS_OSTYPE=DFBSD
471                 AC_MSG_RESULT(i386_dfbsd)
472                 ;;
473         *)
474                 AC_MSG_RESULT($system)
475                 ;;
476 esac
477
478 if test "x$with_afs_sysname" != "x"; then
479         AFS_SYSNAME="$with_afs_sysname"
480 else
481         AC_MSG_CHECKING(your AFS sysname)
482         case $host in
483                 i?86-*-openbsd?.?)
484                         v=${host#*openbsd}
485                         vM=${v%.*}
486                         vm=${v#*.}
487                         AFS_SYSNAME="i386_obsd${vM}${vm}"
488                         ;;
489                 sparc64-*-openbsd?.?)
490                         v=${host#*openbsd}
491                         vM=${v%.*}
492                         vm=${v#*.}
493                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
494                         ;;
495                 x86_64-*-openbsd?.?)
496                         v=${host#*openbsd}
497                         vM=${v%.*}
498                         vm=${v#*.}
499                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
500                         ;;
501                 i?86-*-freebsd*.*)
502                         v=${host#*freebsd}
503                         vM=${v%.*}
504                         vm=${v#*.}
505                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
506                         ;;
507                 x86_64-*-freebsd*.*)
508                         v=${host#*freebsd}
509                         vM=${v%.*}
510                         vm=${v#*.}
511                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
512                         ;;
513                 i386-*-dragonfly?.*)
514                         v=${host#*dragonfly}
515                         vM=${v%.*}
516                         vm=${v#*.}
517                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
518                         ;;
519                 i?86-*-netbsd*1.6[[M-Z]]*)
520                         AFS_SYSNAME="i386_nbsd20"
521                         ;;
522                 powerpc-*-netbsd*1.6[[M-Z]]*)
523                         AFS_SYSNAME="ppc_nbsd20"
524                         ;;
525                 *-*-netbsd*)
526                         arch=${host%%-unknown*}
527                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
528                                                -e 's/powerpc/ppc/g')
529                         v=${host#*netbsd}
530                         v=${v#*aout}
531                         v=${v#*ecoff}
532                         v=${v#*elf}
533                         vM=${v%%.*}
534                         vM=${vM%.*}
535                         v=${v#*.}
536                         vm=${v%%.*}
537                         vm=${vm%.*}
538                         vm=${vm%%[[_A-Z]]*}
539                         if test $vm -eq 99 ; then
540                                 vM=$((vM+1))
541                         fi
542                         if test $vM -gt 1 ; then
543                                 vm=0
544                         fi
545                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
546                         ;;
547                 hppa*-hp-hpux11.0*)
548                         AFS_SYSNAME="hp_ux110"
549                         ;;
550                 hppa*-hp-hpux11.11)
551                         AFS_SYSNAME="hp_ux11i"
552                         ;;
553                 hppa*-hp-hpux11.23)
554                         AFS_SYSNAME="hp_ux1123"
555                         ;;
556                 ia64-hp-hpux11.22)
557                         AFS_SYSNAME="ia64_hpux1122"
558                         ;;
559                 ia64-hp-hpux*)
560                         AFS_SYSNAME="ia64_hpux1123"
561                         ;;
562                 hppa*-hp-hpux10*)
563                         AFS_SYSNAME="hp_ux102"
564                         ;;
565                 powerpc-apple-darwin7*)
566                         AFS_SYSNAME="ppc_darwin_70"
567                         OSXSDK="macosx10.3"
568                         ;;
569                 powerpc-apple-darwin8.*)
570                         AFS_SYSNAME="ppc_darwin_80"
571                         OSXSDK="macosx10.4"
572                         ;;
573                 i386-apple-darwin8.*)
574                         AFS_SYSNAME="x86_darwin_80"
575                         OSXSDK="macosx10.4"
576                         ;;
577                 powerpc-apple-darwin9.*)
578                         AFS_SYSNAME="ppc_darwin_90"
579                         OSXSDK="macosx10.5"
580                         ;;
581                 i386-apple-darwin9.*)
582                         AFS_SYSNAME="x86_darwin_90"
583                         OSXSDK="macosx10.5"
584                         ;;
585                 i?86-apple-darwin10.*)
586                         AFS_SYSNAME="x86_darwin_100"
587                         OSXSDK="macosx10.6"
588                         ;;
589                 x86_64-apple-darwin10.*)
590                         AFS_SYSNAME="x86_darwin_100"
591                         OSXSDK="macosx10.6"
592                         ;;
593                 arm-apple-darwin10.*)
594                         AFS_SYSNAME="arm_darwin_100"
595                         OSXSDK="iphoneos4.0"
596                         ;;
597                 x86_64-apple-darwin11.*)
598                         AFS_SYSNAME="x86_darwin_110"
599                         OSXSDK="macosx10.7"
600                         ;;
601                 i?86-apple-darwin11.*)
602                         AFS_SYSNAME="x86_darwin_110"
603                         OSXSDK="macosx10.7"
604                         ;;
605                 x86_64-apple-darwin12.*)
606                         AFS_SYSNAME="x86_darwin_120"
607                         OSXSDK="macosx10.8"
608                         ;;
609                 i?86-apple-darwin12.*)
610                         AFS_SYSNAME="x86_darwin_120"
611                         OSXSDK="macosx10.8"
612                         ;;
613                 x86_64-apple-darwin13.*)
614                         AFS_SYSNAME="x86_darwin_130"
615                         OSXSDK="macosx10.9"
616                         ;;
617                 i?86-apple-darwin13.*)
618                         AFS_SYSNAME="x86_darwin_130"
619                         OSXSDK="macosx10.9"
620                         ;;
621                 sparc-sun-solaris2.8)
622                         AFS_SYSNAME="sun4x_58"
623                         ;;
624                 sparc-sun-solaris2.9)
625                         AFS_SYSNAME="sun4x_59"
626                         ;;
627                 sparc-sun-solaris2.10)
628                         AFS_SYSNAME="sun4x_510"
629                         ;;
630                 sparc-sun-solaris2.11)
631                         AFS_SYSNAME="sun4x_511"
632                         ;;
633                 i386-pc-solaris2.8)
634                         AFS_SYSNAME="sunx86_58"
635                         ;;
636                 i386-pc-solaris2.9)
637                         AFS_SYSNAME="sunx86_59"
638                         ;;
639                 i386-pc-solaris2.10)
640                         AFS_SYSNAME="sunx86_510"
641                         ;;
642                 i386-pc-solaris2.11)
643                         AFS_SYSNAME="sunx86_511"
644                         ;;
645                 alpha*-dec-osf4.0*)
646                         AFS_SYSNAME="alpha_dux40"
647                         ;;
648                 alpha*-dec-osf5.0*)
649                         AFS_SYSNAME="alpha_dux50"
650                         ;;
651                 alpha*-dec-osf5.1*)
652                         AFS_SYSNAME="alpha_dux51"
653                         ;;
654                 mips-sgi-irix6.5)
655                         AFS_SYSNAME="sgi_65"
656                         ;;
657                 ia64-*-linux*)
658                         AFS_SYSNAME="ia64_linuxXX"
659                         ;;
660                 powerpc-*-linux*)
661                         AFS_SYSNAME="`/bin/arch`_linuxXX"
662                         ;;
663                 powerpc64-*-linux*)
664                         AFS_SYSNAME="ppc64_linuxXX"
665                         ;;
666                 alpha*-linux*)
667                         AFS_SYSNAME="alpha_linux_XX"
668                         ;;
669                 s390-*-linux*)
670                         AFS_SYSNAME="s390_linuxXX"
671                         ;;
672                 s390x-*-linux*)
673                         AFS_SYSNAME="s390x_linuxXX"
674                         ;;
675                 sparc-*-linux*)
676                         AFS_SYSNAME="`/bin/arch`_linuxXX"
677                         ;;
678                 sparc64-*-linux*)
679                         AFS_SYSNAME="sparc64_linuxXX"
680                         ;;
681                 i?86-*-linux*)
682                         AFS_SYSNAME="i386_linuxXX"
683                         ;;
684                 arm*-linux*)
685                         AFS_SYSNAME="arm_linuxXX"
686                         ;;
687                 parisc-*-linux-gnu|hppa-*-linux-gnu)
688                         AFS_SYSNAME="parisc_linuxXX"
689                         enable_pam="no"
690                         ;;
691                 power*-ibm-aix4.2*)
692                         AFS_SYSNAME="rs_aix42"
693                         enable_pam="no"
694                         ;;
695                 power*-ibm-aix4.3*)
696                         AFS_SYSNAME="rs_aix42"
697                         enable_pam="no"
698                         ;;
699                 power*-ibm-aix5.1*)
700                         AFS_SYSNAME="rs_aix51"
701                         enable_pam="no"
702                         ;;
703                 power*-ibm-aix5.2*)
704                         AFS_SYSNAME="rs_aix52"
705                         enable_pam="no"
706                         ;;
707                 power*-ibm-aix5.3*)
708                         AFS_SYSNAME="rs_aix53"
709                         enable_pam="no"
710                         ;;
711                 power*-ibm-aix6.1*)
712                         AFS_SYSNAME="rs_aix61"
713                         enable_pam="no"
714                         ;;
715                 x86_64-*-linux-gnu)
716                         AFS_SYSNAME="amd64_linuxXX"
717                         enable_pam="yes"
718                         ;;
719                 *)
720                         AC_MSG_ERROR(An AFS sysname is required)
721                         exit 1
722                         ;;
723         esac
724         case $AFS_SYSNAME in
725                 *_linux* | *_umlinux*)
726                         if test "x${AFS_SYSKVERS}" = "x"; then
727                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
728                         fi
729                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
730                         AFS_SYSNAME="$_AFS_SYSNAME"
731                         AC_TRY_KBUILD(
732                          [],
733                          [#ifndef CONFIG_USERMODE
734                           #error not UML
735                           #endif],
736                          ac_cv_linux_is_uml=yes,)
737                         if test "${ac_cv_linux_is_uml}" = yes; then
738                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
739                         fi
740                         AFS_SYSNAME="$_AFS_SYSNAME"
741                         ;;
742         esac
743         AC_MSG_RESULT($AFS_SYSNAME)
744 fi
745
746 case $AFS_SYSNAME in
747         *_darwin*)
748                 AC_CHECK_HEADERS(crt_externs.h)
749                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
750                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
751                 AC_SUBST(OSXSDK)
752                 ;;
753 esac
754
755 dnl Some hosts have a separate common param file they should include.  Figure
756 dnl out if we're on one of them now that we know the sysname.
757 case $AFS_SYSNAME in
758     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
759     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
760     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
761     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
762     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
763     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
764     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
765     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
766     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
767     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
768     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
769     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
770     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
771     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
772     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
773     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
774     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
775     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
776     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
777     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
778     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
779     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
780     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
781     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
782     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
783     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
784     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
785     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
786     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
787     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
788     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
789     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
790     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
791     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
792     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
793 # Linux alpha adds an extra underscore for no good reason.
794     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
795     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
796     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
797 esac
798
799 OPENAFS_OSCONF
800
801 case $AFS_SYSNAME in *_linux* | *_umlinux*)
802
803                 # Add (sub-) architecture-specific paths needed by conftests
804                 case $AFS_SYSNAME  in
805                         *_umlinux26)
806                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
807                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
808                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
809                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
810                 esac
811
812                 if test "x$enable_kernel_module" = "xyes"; then
813                  if test "x$enable_debug_kernel" = "xno"; then
814                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
815                  fi
816                  OPENAFS_GCC_SUPPORTS_MARCH
817                  AC_SUBST(P5PLUS_KOPTS)
818                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
819                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
820                  OPENAFS_GCC_SUPPORTS_NO_COMMON
821                  OPENAFS_GCC_SUPPORTS_PIPE
822                  AC_SUBST(LINUX_GCC_KOPTS)
823
824                  dnl Setup the kernel build environment
825                  LINUX_KBUILD_USES_EXTRA_CFLAGS
826                  LINUX_KERNEL_COMPILE_WORKS
827
828                  dnl Check for header files
829                  AC_CHECK_LINUX_HEADER([config.h])
830                  AC_CHECK_LINUX_HEADER([completion.h])
831                  AC_CHECK_LINUX_HEADER([exportfs.h])
832                  AC_CHECK_LINUX_HEADER([freezer.h])
833                  AC_CHECK_LINUX_HEADER([key-type.h])
834                  AC_CHECK_LINUX_HEADER([semaphore.h])
835                  AC_CHECK_LINUX_HEADER([seq_file.h])
836
837                  dnl Type existence checks
838                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
839                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
840
841                  dnl Check for structure elements
842                  AC_CHECK_LINUX_STRUCT([address_space_operations],
843                                        [write_begin], [fs.h])
844                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
845                                        [backing-dev.h])
846                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
847                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
848                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
849                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
850                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
851                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
852                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
853                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
854                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
855                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
856                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
857                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
858                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
859                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
860                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
861                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
862                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
863                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
864                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
865                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
866                                        [fs.h])
867                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
868                                        [fs.h])
869                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
870                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
871                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
872                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
873                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
874                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
875                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
876                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
877                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
878                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
879                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
880
881                  dnl Check for typed structure elements
882                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
883                                              [buf], [fs.h])
884
885                  dnl Function existence checks
886
887                  AC_CHECK_LINUX_FUNC([bdi_init],
888                                      [#include <linux/backing-dev.h>],
889                                      [bdi_init(NULL);])
890                  AC_CHECK_LINUX_FUNC([PageChecked],
891                                      [#include <linux/mm.h>
892 #include <linux/page-flags.h>],
893                                      [struct page *_page;
894                                       int bchecked = PageChecked(_page);])
895                  AC_CHECK_LINUX_FUNC([PageFsMisc],
896                                      [#include <linux/mm.h>
897 #include <linux/page-flags.h>],
898                                      [struct page *_page;
899                                       int bchecked = PageFsMisc(_page);])
900                  AC_CHECK_LINUX_FUNC([clear_inode],
901                                      [#include <linux/fs.h>],
902                                      [clear_inode(NULL);])
903                  AC_CHECK_LINUX_FUNC([current_kernel_time],
904                                      [#include <linux/time.h>],
905                                      [struct timespec s;
906                                       s = current_kernel_time();])
907                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
908                                      [#include <linux/fs.h>],
909                                      [d_alloc_anon(NULL);])
910                  AC_CHECK_LINUX_FUNC([d_count],
911                                      [#include <linux/dcache.h>],
912                                      [d_count(NULL);])
913                  AC_CHECK_LINUX_FUNC([d_make_root],
914                                      [#include <linux/fs.h>],
915                                      [d_make_root(NULL);])
916                  AC_CHECK_LINUX_FUNC([do_sync_read],
917                                      [#include <linux/fs.h>],
918                                      [do_sync_read(NULL, NULL, 0, NULL);])
919                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
920                                      [#include <linux/sched.h>],
921                                      [pid_t p; find_task_by_pid(p);])
922                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
923                                      [#include <linux/fs.h>],
924                                      [generic_file_aio_read(NULL,NULL,0,0);])
925                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
926                                      [#include <linux/pagemap.h>],
927                                      [grab_cache_page_write_begin(NULL, 0, 0);])
928                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
929                                      [#include <linux/list.h>],
930                                      [hlist_unhashed(0);])
931                  AC_CHECK_LINUX_FUNC([i_size_read],
932                                      [#include <linux/fs.h>],
933                                      [i_size_read(NULL);])
934                  AC_CHECK_LINUX_FUNC([inode_setattr],
935                                      [#include <linux/fs.h>],
936                                      [inode_setattr(NULL, NULL);])
937                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
938                                      [#include <linux/net.h>],
939                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
940                  AC_CHECK_LINUX_FUNC([page_follow_link],
941                                      [#include <linux/fs.h>],
942                                      [page_follow_link(0,0);])
943                  AC_CHECK_LINUX_FUNC([page_offset],
944                                      [#include <linux/pagemap.h>],
945                                      [page_offset(NULL);])
946                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
947                                      [#include <linux/pagevec.h>],
948                                      [__pagevec_lru_add_file(NULL);])
949                  AC_CHECK_LINUX_FUNC([path_lookup],
950                                      [#include <linux/fs.h>
951                                       #include <linux/namei.h>],
952                                      [path_lookup(NULL, 0, NULL);])
953                  AC_CHECK_LINUX_FUNC([proc_create],
954                                      [#include <linux/proc_fs.h>],
955                                      [proc_create(NULL, 0, NULL, NULL);])
956                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
957                                      [#include <linux/rcupdate.h>],
958                                      [rcu_read_lock();])
959                  AC_CHECK_LINUX_FUNC([set_nlink],
960                                      [#include <linux/fs.h>],
961                                      [set_nlink(NULL, 1);])
962                  AC_CHECK_LINUX_FUNC([sock_create_kern],
963                                      [#include <linux/net.h>],
964                                      [sock_create_kern(0, 0, 0, NULL);])
965                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
966                                      [#include <linux/splice.h>],
967                                      [splice_direct_to_actor(NULL,NULL,NULL);])
968                  AC_CHECK_LINUX_FUNC([svc_addr_in],
969                                      [#include <linux/sunrpc/svc.h>],
970                                      [svc_addr_in(NULL);])
971                  AC_CHECK_LINUX_FUNC([zero_user_segments],
972                                      [#include <linux/highmem.h>],
973                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
974                  AC_CHECK_LINUX_FUNC([noop_fsync],
975                                      [#include <linux/fs.h>],
976                                      [void *address = &noop_fsync; printk("%p\n", address)];)
977                  AC_CHECK_LINUX_FUNC([kthread_run],
978                                      [#include <linux/kernel.h>
979                                       #include <linux/kthread.h>],
980                                      [kthread_run(NULL, NULL, "test");])
981
982                  dnl Consequences - things which get set as a result of the
983                  dnl                above tests
984                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
985                        [AC_DEFINE([AFS_NONFSTRANS], 1,
986                                   [define to disable the nfs translator])])
987
988                  dnl Assorted more complex tests
989                  LINUX_AIO_NONVECTOR
990                  LINUX_EXPORTS_PROC_ROOT_FS
991                  LINUX_KMEM_CACHE_INIT
992                  LINUX_HAVE_KMEM_CACHE_T
993                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
994                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
995                  LINUX_D_PATH_TAKES_STRUCT_PATH
996                  LINUX_NEW_EXPORT_OPS
997                  LINUX_INODE_SETATTR_RETURN_TYPE
998                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
999                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1000                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1001                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1002                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1003                  LINUX_DOP_D_DELETE_TAKES_CONST
1004                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1005                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1006                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1007                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1008                  LINUX_AOP_WRITEBACK_CONTROL
1009                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1010                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1011                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1012                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1013                  LINUX_KERNEL_SOCK_CREATE
1014                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1015                  LINUX_NEED_RHCONFIG
1016                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1017                  LINUX_EXPORTS_TASKLIST_LOCK
1018                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1019                  LINUX_STATFS_TAKES_DENTRY
1020                  LINUX_REFRIGERATOR
1021                  LINUX_HAVE_TRY_TO_FREEZE
1022                  LINUX_LINUX_KEYRING_SUPPORT
1023                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1024                  LINUX_KEY_ALLOC_NEEDS_CRED
1025                  LINUX_INIT_WORK_HAS_DATA
1026                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1027                  LINUX_HAVE_DCACHE_LOCK
1028                  LINUX_D_COUNT_IS_INT
1029                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1030                  LINUX_IOP_CREATE_TAKES_UMODE_T
1031                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1032                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1033                  LINUX_DENTRY_OPEN_TAKES_PATH
1034                  LINUX_D_ALIAS_IS_HLIST
1035                  LINUX_HLIST_ITERATOR_NO_NODE
1036                  LINUX_IOP_I_CREATE_TAKES_BOOL
1037                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1038                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1039
1040                  dnl If we are guaranteed that keyrings will work - that is
1041                  dnl  a) The kernel has keyrings enabled
1042                  dnl  b) The code is new enough to give us a key_type_keyring
1043                  dnl then we just disable syscall probing unless we've been
1044                  dnl told otherwise
1045
1046                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1047                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1048                           [enable_linux_syscall_probing="no"],
1049                           [enable_linux_syscall_probing="yes"])
1050                  ])
1051
1052                  dnl Syscall probing needs a few tests of its own, and just
1053                  dnl won't work if the kernel doesn't export init_mm
1054                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1055                    LINUX_EXPORTS_INIT_MM
1056                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1057                      AC_MSG_ERROR(
1058                        [Can't do syscall probing without exported init_mm])
1059                    ])
1060                    LINUX_EXPORTS_SYS_CHDIR
1061                    LINUX_EXPORTS_SYS_OPEN
1062                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1063                              [define to enable syscall table probes])
1064                  ])
1065
1066                  dnl Packaging and SMP build
1067                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1068                    LINUX_WHICH_MODULES
1069                  else
1070                    AC_SUBST(MPS,'SP')
1071                  fi
1072
1073                  dnl Syscall probing
1074                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1075                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1076                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1077                    ])
1078                    ac_cv_linux_exports_sys_call_table=no
1079                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1080                      ac_cv_linux_exports_ia32_sys_call_table=yes
1081                    fi
1082                  else
1083                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1084                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1085                    LINUX_EXPORTS_SYS_CALL_TABLE
1086                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1087                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1088                          linux_syscall_method=none
1089                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1090                             linux_syscall_method=scan
1091                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1092                                linux_syscall_method=scan_with_kallsyms_address
1093                             fi
1094                          fi
1095                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1096                             linux_syscall_method=kallsyms_symbol
1097                          fi
1098                          if test "x$linux_syscall_method" = "xnone"; then
1099                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1100                             linux_syscall_method=scan
1101                          fi
1102                    fi
1103                  fi
1104                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1105                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1106                  fi
1107                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1108                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1109                  fi
1110                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1111                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1112                  else
1113                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1114                  fi
1115                 :
1116                 fi
1117 dnl Linux-only, but just enable always.
1118                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1119 esac
1120
1121 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1122     [ac_cv_sync_fetch_and_add],
1123     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1124                     [ac_cv_sync_fetch_and_add=yes],
1125                     [ac_cv_sync_fetch_and_add=no])
1126 ])
1127 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1128       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1129                 [define if your C compiler has __sync_add_and_fetch])])
1130
1131 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1132     [ac_cv_sockaddr_len],
1133     [AC_TRY_COMPILE( [#include <sys/types.h>
1134 #include <sys/socket.h>],
1135                      [struct sockaddr *a; a->sa_len=0;],
1136                      [ac_cv_sockaddr_len=yes],
1137                      [ac_cv_sockaddr_len=no])
1138 ])
1139 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1140       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1141                  [define if you struct sockaddr sa_len])])
1142
1143 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1144         echo Skipping library tests because they confuse Irix.
1145 else
1146   AC_SEARCH_LIBS([socket], [socket inet])
1147   AC_SEARCH_LIBS([connect], [nsl])
1148   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1149
1150   dnl darwin wants it, aix hates it
1151   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1152   AC_TRY_COMPILE([
1153   #include <stdlib.h>
1154   #include <stdio.h>
1155   #include <sys/types.h>
1156   #include <sys/socket.h>
1157   #include <netinet/in.h>
1158   #include <arpa/inet.h>
1159   #include <arpa/nameser.h>
1160   #include <arpa/nameser_compat.h>
1161   #include <resolv.h>
1162   ], [static int i; i = 0;],
1163   [AC_MSG_RESULT(yes)
1164    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1165   [AC_MSG_RESULT(no)
1166    ])
1167
1168   openafs_save_libs="$LIBS"
1169   AC_MSG_CHECKING([for res_search])
1170   AC_FUNC_RES_SEARCH
1171
1172   if test "$ac_cv_func_res_search" = no; then
1173       for lib in dns nsl resolv; do
1174         if test "$ac_cv_func_res_search" != yes; then
1175           LIBS="-l$lib $LIBS"
1176           AC_FUNC_RES_SEARCH
1177           LIBS="$openafs_save_libs"
1178         fi
1179       done    
1180       if test "$ac_cv_func_res_search" = yes; then
1181         LIB_AFSDB="-l$lib"
1182         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1183         AC_MSG_RESULT([yes, in lib$lib])
1184       else
1185         AC_MSG_RESULT(no)
1186       fi
1187   else
1188     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1189     AC_MSG_RESULT(yes)
1190   fi
1191   
1192 fi
1193 XLIBS="$LIB_AFSDB $XLIBS"
1194
1195 AC_CHECK_RESOLV_RETRANS
1196
1197 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1198     [ac_cv_setsockopt_iprecverr],
1199     [AC_TRY_COMPILE( [
1200 #include <sys/types.h>
1201 #include <sys/socket.h>
1202 #include <netinet/in.h>],
1203 [int on=1;
1204 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1205         [ac_cv_setsockopt_iprecverr=yes],
1206         [ac_cv_setsockopt_iprecverr=no])])
1207
1208 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1209       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1210                  [define if we can receive socket errors via IP_RECVERR])])
1211
1212 PTHREAD_LIBS=error
1213 if test "x$MKAFS_OSTYPE" = OBSD; then
1214         PTHREAD_LIBS="-pthread"
1215 fi
1216 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1217         PTHREAD_LIBS="-pthread"
1218 fi
1219 if test "x$PTHREAD_LIBS" = xerror; then
1220         AC_CHECK_LIB(pthread, pthread_attr_init,
1221                 PTHREAD_LIBS="-lpthread")
1222 fi
1223 if test "x$PTHREAD_LIBS" = xerror; then
1224         AC_CHECK_LIB(pthreads, pthread_attr_init,
1225                 PTHREAD_LIBS="-lpthreads")
1226 fi
1227 if test "x$PTHREAD_LIBS" = xerror; then
1228         AC_CHECK_LIB(c_r, pthread_attr_init,
1229                 PTHREAD_LIBS="-lc_r")
1230 fi
1231 if test "x$PTHREAD_LIBS" = xerror; then
1232         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1233 fi
1234 if test "x$PTHREAD_LIBS" = xerror; then
1235         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1236         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1237                 PTHREAD_LIBS="-lpthread")
1238 fi
1239 if test "x$PTHREAD_LIBS" = xerror; then
1240         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1241 fi
1242 AC_SUBST(PTHREAD_LIBS)
1243
1244 HOST_CPU="$host_cpu"
1245
1246 if test "x$with_bsd_kernel_headers" != "x"; then
1247         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1248 else
1249         BSD_KERNEL_PATH="/usr/src/sys"
1250 fi
1251
1252 if test "x$with_bsd_kernel_build" != "x"; then
1253         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1254 else
1255         case $AFS_SYSNAME in
1256                 *_fbsd_*)
1257                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1258                         ;;
1259                 *_nbsd*)
1260                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1261         esac
1262 fi
1263
1264 # Fast restart
1265 if test "$enable_supergroups" = "yes"; then
1266         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1267 fi
1268
1269 if test "$enable_bitmap_later" = "yes"; then
1270         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1271 fi
1272
1273 if test "$enable_unix_sockets" = "yes"; then
1274         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1275         USE_UNIX_SOCKETS="yes"
1276 else
1277         USE_UNIX_SOCKETS="no"
1278 fi
1279 AC_SUBST(USE_UNIX_SOCKETS)
1280
1281 if test "$enable_namei_fileserver" = "yes"; then
1282         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1283         VFSCK=""
1284 else
1285         if test "$enable_namei_fileserver" = "default"; then
1286                 case $host in
1287                         *-solaris2.10*)
1288                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1289                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1290                                 VFSCK=""
1291                                 ;;
1292                         *-solaris2.11*)
1293                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1294                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1295                                 VFSCK=""
1296                                 ;;
1297                         *)
1298                                 VFSCK="vfsck"
1299                                 ;;
1300                 esac
1301         else
1302                 VFSCK="vfsck"
1303         fi
1304 fi
1305
1306 dnl check for tivoli
1307 AC_MSG_CHECKING(for tivoli tsm butc support)
1308 XBSA_CFLAGS=""
1309 if test "$enable_tivoli_tsm" = "yes"; then
1310         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1311         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1312         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1313         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1314
1315         if test -r "$XBSADIR3/dsmapifp.h"; then
1316                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1317                 XBSA_XLIBS="-ldl"
1318                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1319         elif test -r "$XBSADIR4/dsmapifp.h"; then
1320                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1321                 XBSA_XLIBS="-ldl"
1322                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1323         elif test -r "$XBSADIR1/xbsa.h"; then
1324                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1325                 XBSA_XLIBS=""
1326                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1327         elif test -r "$XBSADIR2/xbsa.h"; then
1328                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1329                 XBSA_XLIBS=""
1330                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1331         else
1332                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1333         fi
1334 else
1335         AC_MSG_RESULT([no])
1336 fi
1337 AC_SUBST(XBSA_CFLAGS)
1338 AC_SUBST(XBSA_XLIBS) 
1339
1340 dnl checks for header files.
1341 AC_HEADER_STDC
1342 AC_HEADER_SYS_WAIT
1343 AC_HEADER_DIRENT
1344 AC_CHECK_HEADERS([ \
1345                    arpa/inet.h \
1346                    arpa/nameser.h \
1347                    curses.h\
1348                    direct.h \
1349                    errno.h \
1350                    fcntl.h \
1351                    grp.h \
1352                    math.h \
1353                    mntent.h \
1354                    ncurses.h \
1355                    ncurses/ncurses.h \
1356                    netdb.h \
1357                    netinet/in.h \
1358                    pthread_np.h \
1359                    pwd.h \
1360                    regex.h \
1361                    security/pam_appl.h \
1362                    signal.h \
1363                    stdint.h \
1364                    stdio_ext.h \
1365                    stdlib.h \
1366                    string.h \
1367                    strings.h \
1368                    sys/bitypes.h \
1369                    sys/bswap.h \
1370                    sys/dk.h \
1371                    sys/fcntl.h \
1372                    sys/file.h \
1373                    sys/fs_types.h \
1374                    sys/fstyp.h \
1375                    sys/ioctl.h \
1376                    sys/ipc.h \
1377                    sys/lockf.h \
1378                    sys/map.h \
1379                    sys/mount.h \
1380                    sys/mntent.h \
1381                    sys/mnttab.h \
1382                    sys/pag.h \
1383                    sys/param.h \
1384                    sys/resource.h \
1385                    sys/select.h \
1386                    sys/statfs.h \
1387                    sys/statvfs.h \
1388                    sys/socket.h \
1389                    sys/sysctl.h \
1390                    sys/time.h \
1391                    sys/types.h \
1392                    sys/uio.h \
1393                    sys/un.h \
1394                    sys/vfs.h \
1395                    syslog.h \
1396                    termios.h \
1397                    time.h \
1398                    ucontext.h \
1399                    unistd.h \
1400                    windows.h \
1401                 ])
1402
1403 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1404 #ifdef HAVE_NETINET_IN_H
1405 # include <netinet/in.h>
1406 #endif])
1407
1408 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1409 #ifdef HAVE_SYS_SOCKET_H
1410 # include <sys/socket.h>
1411 #endif])
1412
1413 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1414 #ifdef HAVE_SYS_SOCKET_H
1415 # include <sys/socket.h>
1416 #endif
1417 #ifdef HAVE_NETINET_IN_H
1418 # include <netinet/in.h>
1419 #endif
1420 #ifdef HAVE_NET_IF_H
1421 # include <net/if.h>
1422 #endif])
1423
1424 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1425 #ifdef HAVE_SECURITY_PAM_APPL_H
1426 # include <security/pam_appl.h>
1427 #endif])
1428
1429 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1430
1431 AC_CHECK_TYPES([fsblkcnt_t],,,[
1432 #include <sys/types.h>
1433 #ifdef HAVE_SYS_BITYPES_H
1434 #include <sys/bitypes.h>
1435 #endif
1436 #ifdef HAVE_SYS_STATFS_H
1437 #include <sys/statfs.h>
1438 #endif
1439 #ifdef HAVE_SYS_STATVFS_H
1440 #include <sys/statvfs.h>
1441 #endif
1442 ])
1443
1444 dnl see what struct stat has for timestamps
1445 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1446
1447 dnl check for curses-lib
1448 AS_IF([test "x$enable_gtx" != "xno"],
1449       [save_LIBS=$LIBS
1450       AC_CHECK_LIB( [ncurses], [setupterm],
1451       [LIB_curses=-lncurses],
1452         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1453           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1454       ])
1455       LIBS=$save_LIBS
1456       AC_SUBST(LIB_curses)])
1457         
1458 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1459
1460 if test "$enable_debug_locks" = yes; then
1461         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1462 fi
1463
1464 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1465 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1466         case $AFS_SYSNAME in
1467         sgi_*)
1468                 HAVE_PAM="no"
1469                 ;;
1470         *)
1471                 HAVE_PAM="yes"
1472                 ;;
1473         esac
1474 else
1475         HAVE_PAM="no"
1476 fi
1477 AC_SUBST(HAVE_PAM)
1478
1479 if test "$enable_login" = yes; then
1480         BUILD_LOGIN="yes"
1481 else
1482         BUILD_LOGIN="no"
1483 fi
1484 AC_SUBST(BUILD_LOGIN)
1485
1486 if test "$enable_uss" = yes; then
1487         BUILD_USS="yes"
1488 else
1489         BUILD_USS="no"
1490 fi
1491 AC_SUBST(BUILD_USS)
1492
1493 if test "$enable_kauth" = yes; then
1494         INSTALL_KAUTH="yes"
1495 else
1496         INSTALL_KAUTH="no"
1497 fi
1498 AC_SUBST(INSTALL_KAUTH)
1499
1500 AC_CHECK_FUNCS([ \
1501         arc4random \
1502         fcntl \
1503         fseeko64 \
1504         ftello64 \
1505         getcwd \
1506         getegid \
1507         geteuid \
1508         getgid \
1509         getuid \
1510         getrlimit \
1511         issetugid \
1512         mkstemp \
1513         poll \
1514         pread \
1515         preadv \
1516         preadv64 \
1517         pwrite \
1518         pwritev \
1519         pwritev64 \
1520         regcomp \
1521         regerror \
1522         regexec \
1523         setitimer \
1524         setvbuf \
1525         sigaction \
1526         strcasestr \
1527         strerror \
1528         sysconf \
1529         sysctl \
1530         tdestroy \
1531         timegm \
1532 ])
1533
1534 OPENAFS_ROKEN()
1535 OPENAFS_C_ATTRIBUTE()
1536
1537 dnl Functions that Heimdal's libroken provides, but that we
1538 dnl haven't found a need for yet, and so haven't imported
1539 AC_CHECK_FUNCS([ \
1540         chown \
1541         fchown \
1542         gethostname \
1543         lstat \
1544         inet_aton \
1545         inet_ntop \
1546         inet_pton \
1547         putenv \
1548         readv \
1549         setenv \
1550         strdup \
1551         strftime \
1552         strndup \
1553         strsep \
1554         unsetenv \
1555 ])
1556
1557 dnl Functions that are in objects that we always build from libroken
1558 AC_CHECK_FUNCS([ \
1559         asprintf \
1560         asnprintf \
1561         vasprintf \
1562         vasnprintf \
1563         vsnprintf \
1564         snprintf \
1565 ])
1566
1567 dnl Functions that we're going to try and get from libroken
1568 AC_REPLACE_FUNCS([ \
1569         daemon \
1570         ecalloc \
1571         emalloc \
1572         erealloc \
1573         err \
1574         errx \
1575         flock \
1576         getdtablesize \
1577         getopt \
1578         getprogname \
1579         gettimeofday \
1580         localtime_r \
1581         mkstemp \
1582         setenv \
1583         setprogname \
1584         strcasecmp \
1585         strlcat \
1586         strnlen \
1587         strlcpy \
1588         strsep \
1589         tdelete \
1590         tfind \
1591         tsearch \
1592         twalk \
1593         unsetenv \
1594         verr \
1595         verrx \
1596         vsyslog \
1597         vwarn \
1598         vwarnx \
1599         warn \
1600         warnx \
1601 ])
1602
1603 dnl Headers that we're going to try and get from libroken
1604 AC_CHECK_HEADERS([ \
1605         err.h \
1606         search.h \
1607 ])
1608
1609 AC_CHECK_DECLS([h_errno], [], [], [
1610 #include <sys/types.h>
1611 #ifdef HAVE_NETDB_H
1612 #include <netdb.h>
1613 #endif
1614 ])
1615
1616 AC_HEADER_TIME
1617
1618 ROKEN_HEADERS=
1619 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1620       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1621       [])
1622 AC_SUBST(ROKEN_HEADERS)
1623
1624 dnl Stuff that's harder ...
1625 AC_MSG_CHECKING([for bswap16])
1626 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1627 #ifdef HAVE_SYS_TYPES_H
1628 #include <sys/types.h>
1629 #endif
1630 #ifdef HAVE_SYS_BSWAP_H
1631 #include <sys/bswap.h>
1632 #endif
1633 ],
1634 [short a, b; b = bswap16(a); ])],
1635 [AC_MSG_RESULT(yes)
1636  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1637 ],
1638 [AC_MSG_RESULT(no)])
1639
1640 AC_MSG_CHECKING([for bswap32])
1641 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1642 #include <sys/types.h>
1643 #endif
1644 #ifdef HAVE_SYS_BSWAP_H
1645 #include <sys/bswap.h>
1646 #endif
1647 ],
1648 [int a, b; b = bswap32(a); ])],
1649 [AC_MSG_RESULT(yes)
1650  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1651 ],
1652 [AC_MSG_RESULT(no)])
1653
1654 case $AFS_SYSNAME in
1655 *hp_ux* | *hpux*)
1656    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1657    ;;
1658 *)
1659    AC_MSG_CHECKING([for positional I/O])
1660    if test "$ac_cv_func_pread" = "yes" && \
1661            test "$ac_cv_func_pwrite" = "yes"; then
1662       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1663       AC_MSG_RESULT(yes)
1664    else
1665      AC_MSG_RESULT(no)
1666    fi
1667    AC_MSG_CHECKING([for vectored positional I/O])
1668    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1669                "$ac_cv_func_pwritev" = "yes" -a \
1670                "$ac_cv_func_preadv64" = "yes" -a \
1671                "$ac_cv_func_pwritev64" = "yes"],
1672          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1673           AC_MSG_RESULT(yes)],
1674          [AC_MSG_RESULT(no)])
1675    ;;
1676 esac
1677
1678 AC_MSG_CHECKING([for POSIX regex library])
1679 if test "$ac_cv_header_regex_h" = "yes" && \
1680         test "$ac_cv_func_regcomp" = "yes" && \
1681         test "$ac_cv_func_regexec" = "yes" && \
1682         test "$ac_cv_func_regerror" = "yes"; then
1683     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1684     AC_MSG_RESULT(yes)
1685 else
1686     AC_MSG_RESULT(no)
1687 fi
1688
1689 dnl Look for "non-portable" pthreads functions.
1690 save_LIBS="$LIBS"
1691 LIBS="$LIBS $PTHREAD_LIBS"
1692 AC_CHECK_FUNCS([ \
1693         pthread_set_name_np \
1694         pthread_setname_np \
1695 ])
1696
1697 dnl Sadly, there are three different versions of pthread_setname_np.
1698 dnl Try to cater for all of them.
1699 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1700     AC_MSG_CHECKING([for signature of pthread_setname_np])
1701     AC_TRY_COMPILE([
1702 #include <pthread.h>
1703 #ifdef HAVE_PTHREAD_NP_H
1704 #include <pthread_np.h>
1705 #endif
1706 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1707         AC_MSG_RESULT([three arguments])
1708         pthread_setname_np_args=3], [
1709         AC_TRY_COMPILE([
1710 #include <pthread.h>
1711 #ifdef HAVE_PTHREAD_NP_H
1712 #include <pthread_np.h>
1713 #endif
1714 ], [pthread_setname_np(pthread_self(), "test")], [
1715             AC_MSG_RESULT([two arguments])
1716             pthread_setname_np_args=2], [
1717             AC_TRY_COMPILE([
1718 #include <pthread.h>
1719 #ifdef HAVE_PTHREAD_NP_H
1720 #include <pthread_np.h>
1721 #endif
1722 ], [pthread_setname_np("test")], [
1723                 AC_MSG_RESULT([one argument])
1724                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1725 ])
1726 ])
1727 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1728 fi
1729 LIBS="$save_LIBS"
1730
1731 openafs_cv_saved_CFLAGS="$CFLAGS"
1732 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1733
1734 AC_TYPE_SIGNAL
1735 OPENAFS_RETSIGTYPE
1736 AC_CHECK_SIZEOF(void *)
1737 AC_CHECK_SIZEOF(unsigned long long)
1738 AC_CHECK_SIZEOF(unsigned long)
1739 AC_CHECK_SIZEOF(unsigned int)
1740 AC_TYPE_INTPTR_T
1741 AC_TYPE_UINTPTR_T
1742 AC_TYPE_SSIZE_T
1743 AC_CHECK_TYPE([sig_atomic_t],[],
1744     [AC_DEFINE([sig_atomic_t], [int],
1745         [Define to int if <signal.h> does not define.])],
1746 [#include <sys/types.h>
1747 #include <signal.h>])
1748 AC_CHECK_TYPE([socklen_t],[],
1749     [AC_DEFINE([socklen_t], [int],
1750         [Define to int if <sys/socket.h> does not define.])],
1751 [#include <sys/types.h>
1752 #include <sys/socket.h>])
1753 AC_CHECK_TYPES(off64_t)
1754 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1755 AC_CHECK_TYPES([struct winsize], [], [], [
1756 #ifdef HAVE_TERMIOS_H
1757 # include <termios.h>
1758 #else
1759 # include <sys/termios.h>
1760 #endif
1761 #include <sys/ioctl.h>])
1762 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1763                 struct sockaddr_storage],
1764                [], [], [
1765 #include <sys/types.h>
1766 #include <sys/socket.h>
1767 ])
1768 AC_CHECK_TYPES([sa_family_t], [], [], [
1769 #include <sys/types.h>
1770 #include <sys/socket.h>
1771 ])
1772 AC_CHECK_TYPES([struct addrinfo], [], [], [
1773 #include <sys/types.h>
1774 #ifdef HAVE_NETDB_H
1775 #include <netdb.h>
1776 #endif
1777 ])
1778 AC_CHECK_TYPES([long long], [], [], [])
1779
1780 AC_SIZEOF_TYPE(long)
1781
1782 CFLAGS="$openafs_cv_saved_CFLAGS"
1783
1784 RRA_HEADER_PAM_CONST
1785
1786
1787 dnl Directory PATH handling
1788 if test "x$enable_transarc_paths" = "xyes"  ; then 
1789     afsconfdir=${afsconfdir=/usr/afs/etc}
1790     viceetcdir=${viceetcdir=/usr/vice/etc}
1791     afskerneldir=${afskerneldir=${viceetcdir}}
1792     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1793     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1794     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1795     afsdbdir=${afsdbdir=/usr/afs/db}
1796     afslogsdir=${afslogsdir=/usr/afs/logs}
1797     afslocaldir=${afslocaldir=/usr/afs/local}
1798     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1799     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1800     afsdatadir=${afsdatadir=/usr/vice/etc}
1801 else 
1802     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1803     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1804     afskerneldir=${afskerneldir='${libdir}/openafs'}
1805     afssrvbindir=${afssrvbindir='${bindir}'}
1806     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1807     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1808     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1809     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1810     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1811     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1812     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1813     afsdatadir=${afsdatadir='${datadir}/openafs'}
1814 fi
1815 AC_SUBST(afsconfdir)
1816 AC_SUBST(viceetcdir)
1817 AC_SUBST(afskerneldir)
1818 AC_SUBST(afssrvbindir)
1819 AC_SUBST(afssrvsbindir)
1820 AC_SUBST(afssrvlibexecdir)
1821 AC_SUBST(afsdbdir)
1822 AC_SUBST(afslogsdir)
1823 AC_SUBST(afslocaldir)
1824 AC_SUBST(afsbackupdir)
1825 AC_SUBST(afsbosconfigdir)
1826 AC_SUBST(afsdatadir)
1827
1828 if test "x$enable_kernel_module" = "xyes"; then
1829 ENABLE_KERNEL_MODULE=libafs
1830 fi
1831
1832 if test "x$enable_pthreaded_ubik" = "xyes"; then
1833 ENABLE_PTHREADED_UBIK=yes
1834 fi
1835
1836 AC_SUBST(VFSCK)
1837 AC_SUBST(AFS_SYSNAME)
1838 AC_SUBST(AFS_PARAM_COMMON)
1839 AC_SUBST(ENABLE_KERNEL_MODULE)
1840 AC_SUBST(ENABLE_PTHREADED_UBIK)
1841 AC_SUBST(LIB_AFSDB)
1842 AC_SUBST(LINUX_KERNEL_PATH)
1843 AC_SUBST(LINUX_KERNEL_BUILD)
1844 AC_SUBST(HOST_CPU)
1845 AC_SUBST(BSD_KERNEL_PATH)
1846 AC_SUBST(BSD_KERNEL_BUILD)
1847 AC_SUBST(LINUX_VERSION)
1848 AC_SUBST(MKAFS_OSTYPE)
1849 AC_SUBST(TOP_OBJDIR)
1850 AC_SUBST(TOP_SRCDIR)
1851 AC_SUBST(TOP_INCDIR)
1852 AC_SUBST(TOP_LIBDIR)
1853 AC_SUBST(DEST)
1854 AC_SUBST(DARWIN_INFOFILE)
1855 AC_SUBST(IRIX_BUILD_IP35)
1856 AC_SUBST(HTML_XSL)
1857 AC_SUBST(XSLTPROC)
1858 AC_SUBST(DOCBOOK2PDF)
1859 AC_SUBST(DOCBOOK_STYLESHEETS)
1860
1861 OPENAFS_FUSE
1862 OPENAFS_SWIG
1863
1864 TOP_SRCDIR="${srcdir}/src"
1865 dnl
1866 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1867 dnl
1868 case $TOP_SRCDIR in
1869         /*)
1870                 ;;
1871         *)
1872                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1873                 ;;
1874 esac
1875
1876 TOP_OBJDIR="${SRCDIR_PARENT}"
1877 TOP_INCDIR="${SRCDIR_PARENT}/include"
1878 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1879 if test "${DEST}x" = "x"; then
1880         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1881 fi
1882
1883 if test "x$with_crosstools_dir" != "x"; then
1884         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1885                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1886                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1887                 RXGEN_PATH=$with_crosstools_dir/rxgen
1888         else
1889                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1890                 exit 1
1891         fi
1892 else
1893         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1894         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1895         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1896 fi
1897 AC_SUBST(COMPILE_ET_PATH)
1898 AC_SUBST(CONFIGTOOL_PATH)
1899 AC_SUBST(RXGEN_PATH)
1900
1901 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1902 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1903 AC_SUBST(HELPER_SPLINT)
1904 AC_SUBST(HELPER_SPLINTCFG)
1905
1906 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1907
1908 dnl Check to see if crypt lives in a different library
1909 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1910 AC_SUBST(LIB_crypt)
1911
1912 dnl Check to see if the compiler support labels in structs
1913 AC_MSG_CHECKING(for label support in structs)
1914 AC_TRY_COMPILE([], [
1915 extern void osi_UFSOpen(void);
1916 struct labeltest {
1917    void (*open) (void);
1918 };
1919 struct labeltest struct_labeltest = {
1920    .open       = osi_UFSOpen,
1921 }
1922 ],
1923 [AC_MSG_RESULT(yes)
1924  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1925 ],
1926 [AC_MSG_RESULT(no)
1927 ])
1928
1929 AC_MSG_CHECKING([checking for dirfd])
1930 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1931 #ifdef HAVE_DIRENT_H
1932 #include <dirent.h>
1933 #endif
1934 ]],
1935         [[DIR *d = 0; dirfd(d);]])],
1936         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1937 if test "$ac_rk_have_dirfd" = "yes" ; then
1938         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1939 fi
1940 AC_MSG_RESULT($ac_rk_have_dirfd)
1941
1942 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1943 #ifdef HAVE_DIRENT_H
1944 #include <dirent.h>
1945 #endif])
1946
1947 dnl Eventually, this will look for the system one, or for OpenSSL
1948 LIB_hcrypto="-lafshcrypto"
1949 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1950 AC_SUBST(LIB_hcrypto)
1951 AC_SUBST(LDFLAGS_hcrypto)
1952
1953 dnl Check for UUID library
1954 AC_CHECK_HEADERS([uuid/uuid.h])
1955 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1956 AC_CHECK_FUNCS([uuid_generate])
1957 ])
1958
1959