FBSD: typo fix
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([pam],
79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
80     ,
81     [enable_pam="yes"])
82 AC_ARG_ENABLE([namei-fileserver],
83     [AS_HELP_STRING([--enable-namei-fileserver],
84         [force compilation of namei fileserver in preference to inode
85          fileserver])],
86     , 
87     [enable_namei_fileserver="default"])
88 AC_ARG_ENABLE([supergroups],
89     [AS_HELP_STRING([--enable-supergroups],
90         [enable support for nested pts groups])],
91     , 
92     [enable_supergroups="no"])
93 AC_ARG_ENABLE([bitmap-later],
94     [AS_HELP_STRING([--enable-bitmap-later],
95         [enable fast startup of file server by not reading bitmap till
96          needed])],
97     , 
98     [enable_bitmap_later="no"])
99 AC_ARG_ENABLE([unix-sockets],
100     [AS_HELP_STRING([--disable-unix-sockets],
101         [disable use of unix domain sockets for fssync (defaults to enabled)])],
102     ,
103     [enable_unix_sockets="yes"])
104 AC_ARG_ENABLE([tivoli-tsm],
105     [AS_HELP_STRING([--enable-tivoli-tsm],
106         [enable use of the Tivoli TSM API libraries for butc support])],
107     , 
108     [enable_tivoli_tsm="no"])
109 AC_ARG_ENABLE([pthreaded-ubik],
110     [AS_HELP_STRING([--enable-pthreaded-ubik],
111         [enable installation of pthreaded ubik applications (defaults to
112          disabled)])],
113     ,
114     [enable_pthreaded_ubik="no"])
115
116 dnl Kernel module build options.
117 AC_ARG_WITH([linux-kernel-headers],
118     [AS_HELP_STRING([--with-linux-kernel-headers=path],
119         [use the kernel headers found at path (optional, defaults to
120          /usr/src/linux-2.4, then /usr/src/linux)])])
121 AC_ARG_WITH([linux-kernel-build],
122     [AS_HELP_STRING([--with-linux-kernel-build=path],
123         [use the kernel build found at path(optional, defaults to 
124         /usr/src/linux-2.4, then /usr/src/linux)])])
125 AC_ARG_WITH([bsd-kernel-headers],
126     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
127         [use the kernel headers found at path (optional, defaults to
128          /usr/src/sys)])])
129 AC_ARG_WITH([bsd-kernel-build],
130     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
131         [use the kernel build found at path (optional, defaults to
132          KSRC/i386/compile/GENERIC)])])
133 AC_ARG_WITH([linux-kernel-packaging],
134     [AS_HELP_STRING([--with-linux-kernel-packaging],
135         [use standard naming conventions to aid Linux kernel build packaging
136          (disables MPS, sets the kernel module name to openafs.ko, and
137          installs kernel modules into the standard Linux location)])],
138     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
139      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
140     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
141 AC_ARG_ENABLE([kernel-module],
142     [AS_HELP_STRING([--disable-kernel-module],
143         [disable compilation of the kernel module (defaults to enabled)])],
144     , 
145     [enable_kernel_module="yes"])
146 AC_ARG_ENABLE([redhat-buildsys],
147     [AS_HELP_STRING([--enable-redhat-buildsys],
148         [enable compilation of the redhat build system kernel (defaults to
149          disabled)])],
150     ,
151     [enable_redhat_buildsys="no"])
152
153 dnl Installation locations.
154 AC_ARG_ENABLE([transarc-paths],
155     [AS_HELP_STRING([--enable-transarc-paths],
156         [use Transarc style paths like /usr/afs and /usr/vice])],
157     , 
158     [enable_transarc_paths="no"])
159
160 dnl Optimization and debugging flags.
161 AC_ARG_ENABLE([strip-binaries],
162     [AS_HELP_STRING([--disable-strip-binaries],
163         [disable stripping of symbol information from binaries (defaults to
164          enabled)])],
165     ,
166     [enable_strip_binaries="maybe"])
167 AC_ARG_ENABLE([debug],
168     [AS_HELP_STRING([--enable-debug],
169         [enable compilation of the user space code with debugging information
170          (defaults to disabled)])],
171     , 
172     [enable_debug="no"])
173 AC_ARG_ENABLE([optimize],
174     [AS_HELP_STRING([--disable-optimize],
175         [disable optimization for compilation of the user space code (defaults
176          to enabled)])],
177     , 
178     [enable_optimize="yes"])
179 AC_ARG_ENABLE([warnings],
180     [AS_HELP_STRING([--enable-warnings],
181         [enable compilation warnings when building with gcc (defaults to
182          disabled)])],
183     ,
184     [enable_warnings="no"])
185 AC_ARG_ENABLE([checking],
186     [AS_HELP_STRING([--enable-checking],
187         [turn compilation warnings into errors when building with gcc (defaults
188          to disabled)])],
189     [enable_checking="$enableval"],
190     [enable_checking="no"])
191 AC_ARG_ENABLE([debug-kernel],
192     [AS_HELP_STRING([--enable-debug-kernel],
193         [enable compilation of the kernel module with debugging information
194          (defaults to disabled)])],
195     ,
196     [enable_debug_kernel="no"])
197 AC_ARG_ENABLE([optimize-kernel],
198     [AS_HELP_STRING([--disable-optimize-kernel],
199         [disable compilation of the kernel module with optimization (defaults
200          based on platform)])],
201     , 
202     [enable_optimize_kernel="yes"])
203 AC_ARG_ENABLE([debug-lwp],
204     [AS_HELP_STRING([--enable-debug-lwp],
205         [enable compilation of the LWP code with debugging information
206          (defaults to disabled)])],
207     ,
208     [enable_debug_lwp="no"])
209 AC_ARG_ENABLE([optimize-lwp],
210     [AS_HELP_STRING([--disable-optimize-lwp],
211         [disable optimization for compilation of the LWP code (defaults to
212          enabled)])],
213     ,
214     [enable_optimize_lwp="yes"])
215 AC_ARG_ENABLE([debug-pam],
216     [AS_HELP_STRING([--enable-debug-pam],
217         [enable compilation of the PAM code with debugging information
218          (defaults to disabled)])],
219     ,
220     [enable_debug_pam="no"])
221 AC_ARG_ENABLE([optimize-pam],
222     [AS_HELP_STRING([--disable-optimize-pam],
223         [disable optimization for compilation of the PAM code (defaults to
224          enabled)])],
225     ,
226     [enable_optimize_pam="yes"])
227 AC_ARG_ENABLE([linux-syscall-probing],
228     [AS_HELP_STRING([--enable-linux-syscall-probing],
229         [enable Linux syscall probing (defaults to autodetect)])],
230     ,
231     [enable_linux_syscall_probing="maybe"])
232     
233 AC_ARG_WITH([xslt-processor],
234         AS_HELP_STRING([--with-xslt-processor=ARG],
235         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
236         [XSLTPROC="$withval"],
237         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
238
239 AC_ARG_WITH([html-xsl], 
240         AS_HELP_STRING([--with-html-xsl],
241         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
242         [HTML_XSL="$withval"],
243         [HTML_XSL="html/chunk.xsl"])
244
245 AC_ARG_WITH([docbook2pdf],
246         AS_HELP_STRING([--with-docbook2pdf=ARG],
247         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
248         [DOCBOOK2PDF="$withval"],
249         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
250
251 AC_ARG_WITH([docbook-stylesheets],
252         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
253         [location of DocBook stylesheets (default is to search a set of likely paths)]),
254         [DOCBOOK_STYLESHEETS="$withval"],
255         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
256         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
257                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
258         fi)
259
260 enable_login="no"
261
262 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
263 dnl documentation build.
264 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
265
266 dnl weird ass systems
267 dnl AC_AIX
268 AC_ISC_POSIX
269 dnl AC_MINIX
270
271 dnl Various compiler setup.
272 AC_TYPE_PID_T
273 AC_TYPE_SIZE_T
274
275 dnl Checks for programs.
276 AC_PROG_INSTALL
277 AC_PROG_LN_S
278 AC_PROG_RANLIB
279 AC_PROG_YACC
280 AM_PROG_LEX
281 dnl if we are flex, be lex-compatible
282 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
283
284 OPENAFS_FORCE_ABS_INSTALL
285 OPENAFS_CHECK_BIGENDIAN
286 OPENAFS_PRINTF_TAKES_Z_LEN
287
288 AC_MSG_CHECKING(your OS)
289 system=$host
290 case $system in
291         *-linux*)
292
293                 MKAFS_OSTYPE=LINUX
294                 if test "x$enable_redhat_buildsys" = "xyes"; then
295                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
296                 fi
297                 if test "x$enable_kernel_module" = "xyes"; then
298                  if test "x$with_linux_kernel_headers" != "x"; then
299                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
300                  else
301                    LINUX_KERNEL_PATH="/lib/modules/`uname -r`/source"
302                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
303                      LINUX_KERNEL_PATH="/lib/modules/`uname -r`/build"
304                    fi
305                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
306                      LINUX_KERNEL_PATH="/usr/src/linux-2.4"
307                    fi
308                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
309                      LINUX_KERNEL_PATH="/usr/src/linux"
310                    fi
311                  fi
312                  if test "x$with_linux_kernel_build" != "x"; then
313                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
314                  else
315                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
316                  fi
317                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
318                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
319                    LINUX_VERSION="$linux_kvers"
320                  else
321                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
322                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
323                      LINUX_VERSION="$linux_kvers"
324                    else
325                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
326                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
327                        if test "x$linux_kvers" = "x"; then
328                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
329                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
330                            if test "x$linux_kvers" = "x"; then
331                              AC_MSG_ERROR(Linux headers lack version definition [2])
332                              exit 1
333                            else
334                              LINUX_VERSION="$linux_kvers"
335                            fi
336                          else
337                            AC_MSG_ERROR(Linux headers lack version definition)
338                            exit 1
339                          fi
340                        else
341                          LINUX_VERSION="$linux_kvers"
342                        fi
343                      else
344                        enable_kernel_module="no"
345                      fi
346                    fi
347                  fi
348                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
349                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
350                      enable_kernel_module="no"
351                  fi
352                  if test "x$enable_kernel_module" = "xno"; then
353                   if test "x$with_linux_kernel_headers" != "x"; then
354                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
355                    exit 1
356                   else
357                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
358                   fi
359                  fi
360                  dnl do we need to determine SUBARCH from autoconf.h
361                  SUBARCH=default
362                 fi
363                 AC_MSG_RESULT(linux)
364                 if test "x$enable_kernel_module" = "xyes"; then
365                  case "$LINUX_VERSION" in
366                   2.2.*) AFS_SYSKVERS=22 ;;
367                   2.4.*) AFS_SYSKVERS=24 ;;
368                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
369                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
370                  esac
371                 fi
372                 ;;
373         *-solaris*)
374                 MKAFS_OSTYPE=SOLARIS
375                 AC_MSG_RESULT(sun4)
376                 AC_PATH_PROG(SOLARISCC, [cc], ,
377                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin])
378                 SOLARIS_UFSVFS_HAS_DQRWLOCK
379                 SOLARIS_FS_HAS_FS_ROLLED
380                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
381                 ;;
382         *-sunos*)
383                 MKAFS_OSTYPE=SUNOS
384                 enable_kernel_module=no
385                 AC_MSG_RESULT(sun4)
386                 ;;
387         *-hpux*)
388                 MKAFS_OSTYPE=HPUX
389                 AC_MSG_RESULT(hp_ux)
390                 if test -f "/usr/old/usr/include/ndir.h"; then
391                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
392                 fi
393                 ;;
394         *-irix*)
395                 if test -d /usr/include/sys/SN/SN1; then
396                  IRIX_BUILD_IP35="IP35"
397                 fi
398                 MKAFS_OSTYPE=IRIX
399                 AC_MSG_RESULT(sgi)
400                 ;;
401         *-aix*)
402                 MKAFS_OSTYPE=AIX
403                 AC_MSG_RESULT(rs_aix)
404                 ;;
405         arm-*-darwin*)
406                 MKAFS_OSTYPE=DARWIN
407                 AC_MSG_RESULT(arm_darwin)
408                 ;;
409         powerpc-*-darwin*)
410                 MKAFS_OSTYPE=DARWIN
411                 AC_MSG_RESULT(ppc_darwin)
412                 ;;
413         i386-*-darwin*)
414                 MKAFS_OSTYPE=DARWIN
415                 AC_MSG_RESULT(x86_darwin)
416                 ;;
417         x86_64-*-darwin*)
418                 MKAFS_OSTYPE=DARWIN
419                 AC_MSG_RESULT(x86_darwin)
420                 ;;
421         i386-*-freebsd*)
422                 MKAFS_OSTYPE=FBSD
423                 AC_MSG_RESULT(i386_fbsd)
424                 ;;
425         x86_64-*-freebsd*)
426                 MKAFS_OSTYPE=FBSD
427                 AC_MSG_RESULT(amd64_fbsd)
428                 ;;
429         *-netbsd*)
430                 MKAFS_OSTYPE=NBSD
431                 AC_MSG_RESULT(nbsd)
432                 ;;
433         x86_64-*-openbsd*)
434                 MKAFS_OSTYPE=OBSD
435                 AC_MSG_RESULT(amd64_obsd)
436                 ;;
437         i386-*-openbsd*)
438                 MKAFS_OSTYPE=OBSD
439                 AC_MSG_RESULT(i386_obsd)
440                 ;;
441         *-dragonfly*)
442                 MKAFS_OSTYPE=DFBSD
443                 AC_MSG_RESULT(i386_dfbsd)
444                 ;;
445         *)
446                 AC_MSG_RESULT($system)
447                 ;;
448 esac
449
450 if test "x$with_afs_sysname" != "x"; then
451         AFS_SYSNAME="$with_afs_sysname"
452 else
453         AC_MSG_CHECKING(your AFS sysname)
454         case $host in
455                 i?86-*-openbsd?.?)
456                         v=${host#*openbsd}
457                         vM=${v%.*}
458                         vm=${v#*.}
459                         AFS_SYSNAME="i386_obsd${vM}${vm}"
460                         ;;
461                 sparc64-*-openbsd?.?)
462                         v=${host#*openbsd}
463                         vM=${v%.*}
464                         vm=${v#*.}
465                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
466                         ;;
467                 x86_64-*-openbsd?.?)
468                         v=${host#*openbsd}
469                         vM=${v%.*}
470                         vm=${v#*.}
471                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
472                         ;;
473                 i?86-*-freebsd?.*)
474                         v=${host#*freebsd}
475                         vM=${v%.*}
476                         vm=${v#*.}
477                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
478                         ;;
479                 x86_64-*-freebsd?.*)
480                         v=${host#*freebsd}
481                         vM=${v%.*}
482                         vm=${v#*.}
483                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
484                         ;;
485                 i386-*-dragonfly?.*)
486                         v=${host#*dragonfly}
487                         vM=${v%.*}
488                         vm=${v#*.}
489                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
490                         ;;
491                 i?86-*-netbsd*1.6[[M-Z]]*)
492                         AFS_SYSNAME="i386_nbsd20"
493                         ;;
494                 powerpc-*-netbsd*1.6[[M-Z]]*)
495                         AFS_SYSNAME="ppc_nbsd20"
496                         ;;
497                 *-*-netbsd*)
498                         arch=${host%%-unknown*}
499                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
500                                                -e 's/powerpc/ppc/g')
501                         v=${host#*netbsd}
502                         v=${v#*aout}
503                         v=${v#*ecoff}
504                         v=${v#*elf}
505                         vM=${v%%.*}
506                         vM=${vM%.*}
507                         v=${v#*.}
508                         vm=${v%%.*}
509                         vm=${vm%.*}
510                         vm=${vm%%[[_A-Z]]*}
511                         if test $vm -eq 99 ; then
512                                 vM=$((vM+1))
513                         fi
514                         if test $vM -gt 1 ; then
515                                 vm=0
516                         fi
517                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
518                         ;;
519                 hppa*-hp-hpux11.0*)
520                         AFS_SYSNAME="hp_ux110"
521                         ;;
522                 hppa*-hp-hpux11.11)
523                         AFS_SYSNAME="hp_ux11i"
524                         ;;
525                 hppa*-hp-hpux11.23)
526                         AFS_SYSNAME="hp_ux1123"
527                         ;;
528                 ia64-hp-hpux11.22)
529                         AFS_SYSNAME="ia64_hpux1122"
530                         ;;
531                 ia64-hp-hpux*)
532                         AFS_SYSNAME="ia64_hpux1123"
533                         ;;
534                 hppa*-hp-hpux10*)
535                         AFS_SYSNAME="hp_ux102"
536                         ;;
537                 powerpc-apple-darwin7*)
538                         AFS_SYSNAME="ppc_darwin_70"
539                         OSXSDK="macosx10.3"
540                         ;;
541                 powerpc-apple-darwin8.*)
542                         AFS_SYSNAME="ppc_darwin_80"
543                         OSXSDK="macosx10.4"
544                         ;;
545                 i386-apple-darwin8.*)
546                         AFS_SYSNAME="x86_darwin_80"
547                         OSXSDK="macosx10.4"
548                         ;;
549                 powerpc-apple-darwin9.*)
550                         AFS_SYSNAME="ppc_darwin_90"
551                         OSXSDK="macosx10.5"
552                         ;;
553                 i386-apple-darwin9.*)
554                         AFS_SYSNAME="x86_darwin_90"
555                         OSXSDK="macosx10.5"
556                         ;;
557                 i?86-apple-darwin10.*)
558                         AFS_SYSNAME="x86_darwin_100"
559                         OSXSDK="macosx10.6"
560                         ;;
561                 x86_64-apple-darwin10.*)
562                         AFS_SYSNAME="x86_darwin_100"
563                         OSXSDK="macosx10.6"
564                         ;;
565                 arm-apple-darwin10.*)
566                         AFS_SYSNAME="arm_darwin_100"
567                         OSXSDK="iphoneos4.0"
568                         ;;
569                 x86_64-apple-darwin11.*)
570                         AFS_SYSNAME="x86_darwin_110"
571                         OSXSDK="macosx10.7"
572                         ;;
573                 i?86-apple-darwin11.*)
574                         AFS_SYSNAME="x86_darwin_110"
575                         OSXSDK="macosx10.7"
576                         ;;
577                 sparc-sun-solaris2.8)
578                         AFS_SYSNAME="sun4x_58"
579                         ;;
580                 sparc-sun-solaris2.9)
581                         AFS_SYSNAME="sun4x_59"
582                         ;;
583                 sparc-sun-solaris2.10)
584                         AFS_SYSNAME="sun4x_510"
585                         ;;
586                 sparc-sun-solaris2.11)
587                         AFS_SYSNAME="sun4x_511"
588                         ;;
589                 sparc-sun-sunos4*)
590                         AFS_SYSNAME="sun4_413"
591                         enable_login="yes"
592                         ;;
593                 i386-pc-solaris2.8)
594                         AFS_SYSNAME="sunx86_58"
595                         ;;
596                 i386-pc-solaris2.9)
597                         AFS_SYSNAME="sunx86_59"
598                         ;;
599                 i386-pc-solaris2.10)
600                         AFS_SYSNAME="sunx86_510"
601                         ;;
602                 i386-pc-solaris2.11)
603                         AFS_SYSNAME="sunx86_511"
604                         ;;
605                 alpha*-dec-osf4.0*)
606                         AFS_SYSNAME="alpha_dux40"
607                         ;;
608                 alpha*-dec-osf5.0*)
609                         AFS_SYSNAME="alpha_dux50"
610                         ;;
611                 alpha*-dec-osf5.1*)
612                         AFS_SYSNAME="alpha_dux51"
613                         ;;
614                 mips-sgi-irix6.5)
615                         AFS_SYSNAME="sgi_65"
616                         ;;
617                 ia64-*-linux*)
618                         AFS_SYSNAME="ia64_linuxXX"
619                         ;;
620                 powerpc-*-linux*)
621                         AFS_SYSNAME="`/bin/arch`_linuxXX"
622                         ;;
623                 powerpc64-*-linux*)
624                         AFS_SYSNAME="ppc64_linuxXX"
625                         ;;
626                 alpha*-linux*)
627                         AFS_SYSNAME="alpha_linux_XX"
628                         ;;
629                 s390-*-linux*)
630                         AFS_SYSNAME="s390_linuxXX"
631                         ;;
632                 s390x-*-linux*)
633                         AFS_SYSNAME="s390x_linuxXX"
634                         ;;
635                 sparc-*-linux*)
636                         AFS_SYSNAME="`/bin/arch`_linuxXX"
637                         ;;
638                 sparc64-*-linux*)
639                         AFS_SYSNAME="sparc64_linuxXX"
640                         ;;
641                 i?86-*-linux*)
642                         AFS_SYSNAME="i386_linuxXX"
643                         ;;
644                 arm*-linux*)
645                         AFS_SYSNAME="arm_linuxXX"
646                         ;;
647                 parisc-*-linux-gnu|hppa-*-linux-gnu)
648                         AFS_SYSNAME="parisc_linuxXX"
649                         enable_pam="no"
650                         ;;
651                 power*-ibm-aix4.2*)
652                         AFS_SYSNAME="rs_aix42"
653                         enable_pam="no"
654                         ;;
655                 power*-ibm-aix4.3*)
656                         AFS_SYSNAME="rs_aix42"
657                         enable_pam="no"
658                         ;;
659                 power*-ibm-aix5.1*)
660                         AFS_SYSNAME="rs_aix51"
661                         enable_pam="no"
662                         ;;
663                 power*-ibm-aix5.2*)
664                         AFS_SYSNAME="rs_aix52"
665                         enable_pam="no"
666                         ;;
667                 power*-ibm-aix5.3*)
668                         AFS_SYSNAME="rs_aix53"
669                         enable_pam="no"
670                         ;;
671                 power*-ibm-aix6.1*)
672                         AFS_SYSNAME="rs_aix61"
673                         enable_pam="no"
674                         ;;
675                 x86_64-*-linux-gnu)
676                         AFS_SYSNAME="amd64_linuxXX"
677                         enable_pam="yes"
678                         ;;
679                 *)
680                         AC_MSG_ERROR(An AFS sysname is required)
681                         exit 1
682                         ;;
683         esac
684         case $AFS_SYSNAME in
685                 *_linux* | *_umlinux*)
686                         if test "x${AFS_SYSKVERS}" = "x"; then
687                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
688                         fi
689                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
690                         AFS_SYSNAME="$_AFS_SYSNAME"
691                         AC_TRY_KBUILD(
692                          [],
693                          [#ifndef CONFIG_USERMODE
694                           #error not UML
695                           #endif],
696                          ac_cv_linux_is_uml=yes,)
697                         if test "${ac_cv_linux_is_uml}" = yes; then
698                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
699                         fi
700                         AFS_SYSNAME="$_AFS_SYSNAME"
701                         ;;
702         esac
703         AC_MSG_RESULT($AFS_SYSNAME)
704 fi
705
706 case $AFS_SYSNAME in
707         *_darwin*)
708                 AC_CHECK_HEADERS(crt_externs.h)
709                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
710                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
711                 AC_SUBST(OSXSDK)
712                 ;;
713 esac
714
715 dnl Some hosts have a separate common param file they should include.  Figure
716 dnl out if we're on one of them now that we know the sysname.
717 case $AFS_SYSNAME in
718     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
719     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
720     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
721     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
722     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
723     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
724     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
725     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
726     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
727     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
728     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
729     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
730     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
731     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
732     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
733     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
734     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
735     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
736     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
737     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
738     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
739     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
740     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
741     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
742     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
743     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
744     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
745     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
746     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
747 # Linux alpha adds an extra underscore for no good reason.
748     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
749     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
750     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
751 esac
752
753 case $AFS_SYSNAME in *_linux* | *_umlinux*)
754
755                 # Add (sub-) architecture-specific paths needed by conftests
756                 case $AFS_SYSNAME  in
757                         *_umlinux26)
758                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
759                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
760                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
761                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
762                 esac
763
764                 if test "x$enable_kernel_module" = "xyes"; then
765                  if test "x$enable_debug_kernel" = "xno"; then
766                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
767                  fi
768                  OPENAFS_GCC_SUPPORTS_MARCH
769                  AC_SUBST(P5PLUS_KOPTS)
770                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
771                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
772                  OPENAFS_GCC_SUPPORTS_NO_COMMON
773                  OPENAFS_GCC_SUPPORTS_PIPE
774                  AC_SUBST(LINUX_GCC_KOPTS)
775
776                  dnl Setup the kernel build environment
777                  LINUX_KBUILD_USES_EXTRA_CFLAGS
778                  LINUX_KERNEL_COMPILE_WORKS
779
780                  dnl Check for header files
781                  AC_CHECK_LINUX_HEADER([config.h])
782                  AC_CHECK_LINUX_HEADER([completion.h])
783                  AC_CHECK_LINUX_HEADER([exportfs.h])
784                  AC_CHECK_LINUX_HEADER([freezer.h])
785                  AC_CHECK_LINUX_HEADER([key-type.h])
786                  AC_CHECK_LINUX_HEADER([semaphore.h])
787                  AC_CHECK_LINUX_HEADER([seq_file.h])
788
789                  dnl Check for structure elements
790                  AC_CHECK_LINUX_STRUCT([address_space_operations],
791                                        [write_begin], [fs.h])
792                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
793                                        [backing-dev.h])
794                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
795                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
796                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
797                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
798                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
799                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
800                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
801                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
802                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
803                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
804                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
805                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
806                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
807                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
808                                        [fs.h])
809                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
810                                        [fs.h])
811                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
812                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
813                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
814                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
815                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
816                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
817                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
818                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
819                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
820                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
821                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
822
823                  dnl Check for typed structure elements
824                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
825                                              [buf], [fs.h])
826
827                  dnl Function existence checks
828
829                  AC_CHECK_LINUX_FUNC([bdi_init],
830                                      [#include <linux/backing-dev.h>],
831                                      [bdi_init(NULL);])
832                  AC_CHECK_LINUX_FUNC([PageChecked],
833                                      [#include <linux/mm.h>
834 #include <linux/page-flags.h>],
835                                      [struct page *_page;
836                                       int bchecked = PageChecked(_page);])
837                  AC_CHECK_LINUX_FUNC([PageFsMisc],
838                                      [#include <linux/mm.h>
839 #include <linux/page-flags.h>],
840                                      [struct page *_page;
841                                       int bchecked = PageFsMisc(_page);])
842                  AC_CHECK_LINUX_FUNC([current_kernel_time],
843                                      [#include <linux/time.h>],
844                                      [struct timespec s;
845                                       s = current_kernel_time();])
846                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
847                                      [#include <linux/fs.h>],
848                                      [d_alloc_anon(NULL);])
849                  AC_CHECK_LINUX_FUNC([do_sync_read],
850                                      [#include <linux/fs.h>],
851                                      [do_sync_read(NULL, NULL, 0, NULL);])
852                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
853                                      [#include <linux/sched.h>],
854                                      [pid_t p; find_task_by_pid(p);])
855                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
856                                      [#include <linux/fs.h>],
857                                      [generic_file_aio_read(NULL,NULL,0,0);])
858                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
859                                      [#include <linux/pagemap.h>],
860                                      [grab_cache_page_write_begin(NULL, 0, 0);])
861                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
862                                      [#include <linux/list.h>],
863                                      [hlist_unhashed(0);])
864                  AC_CHECK_LINUX_FUNC([i_size_read],
865                                      [#include <linux/fs.h>],
866                                      [i_size_read(NULL);])
867                  AC_CHECK_LINUX_FUNC([inode_setattr],
868                                      [#include <linux/fs.h>],
869                                      [inode_setattr(NULL, NULL);])
870                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
871                                      [#include <linux/net.h>],
872                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
873                  AC_CHECK_LINUX_FUNC([page_follow_link],
874                                      [#include <linux/fs.h>],
875                                      [page_follow_link(0,0);])
876                  AC_CHECK_LINUX_FUNC([page_offset],
877                                      [#include <linux/pagemap.h>],
878                                      [page_offset(NULL);])
879                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
880                                      [#include <linux/pagevec.h>],
881                                      [__pagevec_lru_add_file(NULL);])
882                  AC_CHECK_LINUX_FUNC([path_lookup],
883                                      [#include <linux/fs.h>
884                                       #include <linux/namei.h>],
885                                      [path_lookup(NULL, 0, NULL);])
886                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
887                                      [#include <linux/rcupdate.h>],
888                                      [rcu_read_lock();])
889                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
890                                      [#include <linux/splice.h>],
891                                      [splice_direct_to_actor(NULL,NULL,NULL);])
892                  AC_CHECK_LINUX_FUNC([svc_addr_in],
893                                      [#include <linux/sunrpc/svc.h>],
894                                      [svc_addr_in(NULL);])
895                  AC_CHECK_LINUX_FUNC([zero_user_segments],
896                                      [#include <linux/highmem.h>],
897                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
898
899                  dnl Consequences - things which get set as a result of the
900                  dnl                above tests
901                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
902                        [AC_DEFINE([AFS_NONFSTRANS], 1,
903                                   [define to disable the nfs translator])])
904
905                  dnl Assorted more complex tests
906                  LINUX_EXPORTS_PROC_ROOT_FS
907                  LINUX_KMEM_CACHE_INIT
908                  LINUX_HAVE_KMEM_CACHE_T
909                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
910                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
911                  LINUX_D_PATH_TAKES_STRUCT_PATH
912                  LINUX_NEW_EXPORT_OPS
913                  LINUX_INODE_SETATTR_RETURN_TYPE
914                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
915                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
916                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
917                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
918                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
919                  LINUX_DOP_D_DELETE_TAKES_CONST
920                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
921                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
922                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
923                  LINUX_FOP_F_FSYNC_TAKES_RANGE
924                  LINUX_AOP_WRITEBACK_CONTROL
925                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
926                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
927                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
928                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
929                  LINUX_KERNEL_SOCK_CREATE
930                  LINUX_EXPORTS_KEY_TYPE_KEYRING
931                  LINUX_NEED_RHCONFIG
932                  LINUX_RECALC_SIGPENDING_ARG_TYPE
933                  LINUX_EXPORTS_TASKLIST_LOCK
934                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
935                  LINUX_STATFS_TAKES_DENTRY
936                  LINUX_REFRIGERATOR
937                  LINUX_HAVE_TRY_TO_FREEZE
938                  LINUX_LINUX_KEYRING_SUPPORT
939                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
940                  LINUX_KEY_ALLOC_NEEDS_CRED
941                  LINUX_INIT_WORK_HAS_DATA
942                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
943                  LINUX_HAVE_DCACHE_LOCK
944                  LINUX_D_COUNT_IS_INT
945
946                  dnl If we are guaranteed that keyrings will work - that is
947                  dnl  a) The kernel has keyrings enabled
948                  dnl  b) The code is new enough to give us a key_type_keyring
949                  dnl then we just disable syscall probing unless we've been
950                  dnl told otherwise
951
952                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
953                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
954                           [enable_linux_syscall_probing="no"],
955                           [enable_linux_syscall_probing="yes"])
956                  ])
957
958                  dnl Syscall probing needs a few tests of its own, and just
959                  dnl won't work if the kernel doesn't export init_mm
960                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
961                    LINUX_EXPORTS_INIT_MM
962                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
963                      AC_MSG_ERROR(
964                        [Can't do syscall probing without exported init_mm])
965                    ])
966                    LINUX_EXPORTS_SYS_CHDIR
967                    LINUX_EXPORTS_SYS_OPEN
968                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
969                              [define to enable syscall table probes])
970                  ])
971
972                  dnl Packaging and SMP build
973                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
974                    LINUX_WHICH_MODULES
975                  else
976                    AC_SUBST(MPS,'SP')
977                  fi
978
979                  dnl Syscall probing
980                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
981                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
982                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
983                    ])
984                    ac_cv_linux_exports_sys_call_table=no
985                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
986                      ac_cv_linux_exports_ia32_sys_call_table=yes
987                    fi
988                  else
989                    LINUX_EXPORTS_KALLSYMS_ADDRESS
990                    LINUX_EXPORTS_KALLSYMS_SYMBOL
991                    LINUX_EXPORTS_SYS_CALL_TABLE
992                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
993                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
994                          linux_syscall_method=none
995                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
996                             linux_syscall_method=scan
997                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
998                                linux_syscall_method=scan_with_kallsyms_address
999                             fi
1000                          fi
1001                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1002                             linux_syscall_method=kallsyms_symbol
1003                          fi
1004                          if test "x$linux_syscall_method" = "xnone"; then
1005                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1006                             linux_syscall_method=scan
1007                          fi
1008                    fi
1009                  fi
1010                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1011                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1012                  fi
1013                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1014                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1015                  fi
1016                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1017                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1018                  else
1019                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1020                  fi
1021                 :
1022                 fi
1023 dnl Linux-only, but just enable always.
1024                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1025 esac
1026
1027 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1028     [ac_cv_sync_fetch_and_add],
1029     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1030                     [ac_cv_sync_fetch_and_add=yes],
1031                     [ac_cv_sync_fetch_and_add=no])
1032 ])
1033 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1034       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1035                 [define if your C compiler has __sync_add_and_fetch])])
1036
1037 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1038     [ac_cv_sockaddr_len],
1039     [AC_TRY_COMPILE( [#include <sys/types.h>
1040 #include <sys/socket.h>],
1041                      [struct sockaddr *a; a->sa_len=0;],
1042                      [ac_cv_sockaddr_len=yes],
1043                      [ac_cv_sockaddr_len=no])
1044 ])
1045 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1046       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1047                  [define if you struct sockaddr sa_len])])
1048
1049 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1050         echo Skipping library tests because they confuse Irix.
1051 else
1052   AC_SEARCH_LIBS([socket], [socket inet])
1053   AC_SEARCH_LIBS([connect], [nsl])
1054   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1055
1056   dnl darwin wants it, aix hates it
1057   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1058   AC_TRY_COMPILE([
1059   #include <stdlib.h>
1060   #include <stdio.h>
1061   #include <sys/types.h>
1062   #include <sys/socket.h>
1063   #include <netinet/in.h>
1064   #include <arpa/inet.h>
1065   #include <arpa/nameser.h>
1066   #include <arpa/nameser_compat.h>
1067   #include <resolv.h>
1068   ], [static int i; i = 0;],
1069   [AC_MSG_RESULT(yes)
1070    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1071   [AC_MSG_RESULT(no)
1072    ])
1073
1074   openafs_save_libs="$LIBS"
1075   AC_MSG_CHECKING([for res_search])
1076   AC_FUNC_RES_SEARCH
1077
1078   if test "$ac_cv_func_res_search" = no; then
1079       for lib in dns nsl resolv; do
1080         if test "$ac_cv_func_res_search" != yes; then
1081           LIBS="-l$lib $LIBS"
1082           AC_FUNC_RES_SEARCH
1083           LIBS="$openafs_save_libs"
1084         fi
1085       done    
1086       if test "$ac_cv_func_res_search" = yes; then
1087         LIB_AFSDB="-l$lib"
1088         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1089         AC_MSG_RESULT([yes, in lib$lib])
1090       else
1091         AC_MSG_RESULT(no)
1092       fi
1093   else
1094     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1095     AC_MSG_RESULT(yes)
1096   fi
1097   
1098 fi
1099
1100 AC_CHECK_RESOLV_RETRANS
1101
1102 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1103     [ac_cv_setsockopt_iprecverr],
1104     [AC_TRY_COMPILE( [
1105 #include <sys/types.h>
1106 #include <sys/socket.h>
1107 #include <netinet/in.h>],
1108 [int on=1;
1109 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1110         [ac_cv_setsockopt_iprecverr=yes],
1111         [ac_cv_setsockopt_iprecverr=no])])
1112
1113 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1114       [AC_DEFINE(ADAPT_PMTU_RECVERR, 1,
1115                  [define if asynchronous socket errors can be received])])
1116
1117 PTHREAD_LIBS=error
1118 if test "x$MKAFS_OSTYPE" = OBSD; then
1119         PTHREAD_LIBS="-pthread"
1120 fi
1121 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1122         PTHREAD_LIBS="-pthread"
1123 fi
1124 if test "x$PTHREAD_LIBS" = xerror; then
1125         AC_CHECK_LIB(pthread, pthread_attr_init,
1126                 PTHREAD_LIBS="-lpthread")
1127 fi
1128 if test "x$PTHREAD_LIBS" = xerror; then
1129         AC_CHECK_LIB(pthreads, pthread_attr_init,
1130                 PTHREAD_LIBS="-lpthreads")
1131 fi
1132 if test "x$PTHREAD_LIBS" = xerror; then
1133         AC_CHECK_LIB(c_r, pthread_attr_init,
1134                 PTHREAD_LIBS="-lc_r")
1135 fi
1136 if test "x$PTHREAD_LIBS" = xerror; then
1137         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1138 fi
1139 if test "x$PTHREAD_LIBS" = xerror; then
1140         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1141         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1142                 PTHREAD_LIBS="-lpthread")
1143 fi
1144 if test "x$PTHREAD_LIBS" = xerror; then
1145         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1146 fi
1147 AC_SUBST(PTHREAD_LIBS)
1148
1149 HOST_CPU="$host_cpu"
1150
1151 if test "x$with_bsd_kernel_headers" != "x"; then
1152         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1153 else
1154         BSD_KERNEL_PATH="/usr/src/sys"
1155 fi
1156
1157 if test "x$with_bsd_kernel_build" != "x"; then
1158         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1159 else
1160         case $AFS_SYSNAME in
1161                 *_fbsd_*)
1162                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1163                         ;;
1164                 *_nbsd*)
1165                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1166         esac
1167 fi
1168
1169 # Fast restart
1170 if test "$enable_supergroups" = "yes"; then
1171         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1172 fi
1173
1174 if test "$enable_bitmap_later" = "yes"; then
1175         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1176 fi
1177
1178 if test "$enable_unix_sockets" = "yes"; then
1179         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1180         USE_UNIX_SOCKETS="yes"
1181 else
1182         USE_UNIX_SOCKETS="no"
1183 fi
1184 AC_SUBST(USE_UNIX_SOCKETS)
1185
1186 dnl if test "$ac_cv_setsockopt_iprecverr" = "yes"; then
1187 dnl     AC_DEFINE(ADAPT_PMTU, 1, [define if you want to decode icmp unreachable packets to discover path mtu])
1188 dnl fi
1189
1190 if test "$enable_namei_fileserver" = "yes"; then
1191         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1192         VFSCK=""
1193 else
1194         if test "$enable_namei_fileserver" = "default"; then
1195                 case $host in
1196                         *-solaris2.10*)
1197                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1198                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1199                                 VFSCK=""
1200                                 ;;
1201                         *-solaris2.11*)
1202                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1203                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1204                                 VFSCK=""
1205                                 ;;
1206                         *)
1207                                 VFSCK="vfsck"
1208                                 ;;
1209                 esac
1210         else
1211                 VFSCK="vfsck"
1212         fi
1213 fi
1214
1215 dnl check for tivoli
1216 AC_MSG_CHECKING(for tivoli tsm butc support)
1217 XBSA_CFLAGS=""
1218 if test "$enable_tivoli_tsm" = "yes"; then
1219         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1220         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1221         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1222         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1223
1224         if test -r "$XBSADIR3/dsmapifp.h"; then
1225                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1226                 XBSA_XLIBS="-ldl"
1227                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1228         elif test -r "$XBSADIR4/dsmapifp.h"; then
1229                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1230                 XBSA_XLIBS="-ldl"
1231                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1232         elif test -r "$XBSADIR1/xbsa.h"; then
1233                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1234                 XBSA_XLIBS=""
1235                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1236         elif test -r "$XBSADIR2/xbsa.h"; then
1237                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1238                 XBSA_XLIBS=""
1239                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1240         else
1241                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1242         fi
1243 else
1244         AC_MSG_RESULT([no])
1245 fi
1246 AC_SUBST(XBSA_CFLAGS)
1247 AC_SUBST(XBSA_XLIBS) 
1248
1249 dnl checks for header files.
1250 AC_HEADER_STDC
1251 AC_HEADER_SYS_WAIT
1252 AC_HEADER_DIRENT
1253 AC_CHECK_HEADERS([ \
1254                    arpa/inet.h \
1255                    arpa/nameser.h \
1256                    curses.h\
1257                    direct.h \
1258                    et/com_err.h \
1259                    errno.h \
1260                    fcntl.h \
1261                    grp.h \
1262                    math.h \
1263                    mntent.h \
1264                    ncurses.h \
1265                    netdb.h \
1266                    netinet/in.h \
1267                    pthread_np.h \
1268                    pwd.h \
1269                    regex.h \
1270                    security/pam_appl.h \
1271                    signal.h \
1272                    stdint.h \
1273                    stdio_ext.h \
1274                    stdlib.h \
1275                    string.h \
1276                    strings.h \
1277                    sys/bitypes.h \
1278                    sys/bswap.h \
1279                    sys/dk.h \
1280                    sys/fcntl.h \
1281                    sys/file.h \
1282                    sys/fs_types.h \
1283                    sys/fstyp.h \
1284                    sys/ioctl.h \
1285                    sys/ipc.h \
1286                    sys/lockf.h \
1287                    sys/map.h \
1288                    sys/mount.h \
1289                    sys/mntent.h \
1290                    sys/mnttab.h \
1291                    sys/pag.h \
1292                    sys/param.h \
1293                    sys/resource.h \
1294                    sys/select.h \
1295                    sys/statfs.h \
1296                    sys/statvfs.h \
1297                    sys/socket.h \
1298                    sys/sysctl.h \
1299                    sys/time.h \
1300                    sys/types.h \
1301                    sys/uio.h \
1302                    sys/un.h \
1303                    sys/vfs.h \
1304                    syslog.h \
1305                    termios.h \
1306                    time.h \
1307                    ucontext.h \
1308                    unistd.h \
1309                    windows.h \
1310                 ])
1311
1312 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1313 #ifdef HAVE_NETINET_IN_H
1314 # include <netinet/in.h>
1315 #endif])
1316
1317 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1318 #ifdef HAVE_SYS_SOCKET_H
1319 # include <sys/socket.h>
1320 #endif])
1321
1322 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1323 #ifdef HAVE_SYS_SOCKET_H
1324 # include <sys/socket.h>
1325 #endif
1326 #ifdef HAVE_NETINET_IN_H
1327 # include <netinet/in.h>
1328 #endif
1329 #ifdef HAVE_NET_IF_H
1330 # include <net/if.h>
1331 #endif])
1332
1333 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1334 #ifdef HAVE_SECURITY_PAM_APPL_H
1335 # include <security/pam_appl.h>
1336 #endif])
1337
1338 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1339
1340 AC_CHECK_TYPES([fsblkcnt_t],,,[
1341 #include <sys/types.h>
1342 #ifdef HAVE_SYS_BITYPES_H
1343 #include <sys/bitypes.h>
1344 #endif
1345 #ifdef HAVE_SYS_STATFS_H
1346 #include <sys/statfs.h>
1347 #endif
1348 #ifdef HAVE_SYS_STATVFS_H
1349 #include <sys/statvfs.h>
1350 #endif
1351 ])
1352
1353 dnl see what struct stat has for timestamps
1354 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1355
1356 dnl check for curses-lib
1357 save_LIBS=$LIBS
1358 AC_CHECK_LIB( [ncurses], [setupterm],
1359 [LIB_curses=-lncurses],
1360     [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1361         [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])
1362     ])
1363 ])
1364 LIBS=$save_LIBS
1365 AC_SUBST(LIB_curses)
1366
1367 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1368
1369 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1370 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1371         case $AFS_SYSNAME in
1372         sgi_*)
1373                 HAVE_PAM="no"
1374                 ;;
1375         *)
1376                 HAVE_PAM="yes"
1377                 ;;
1378         esac
1379 else
1380         HAVE_PAM="no"
1381 fi
1382 AC_SUBST(HAVE_PAM)
1383
1384 if test "$enable_login" = yes; then
1385         BUILD_LOGIN="yes"
1386 else
1387         BUILD_LOGIN="no"
1388 fi
1389 AC_SUBST(BUILD_LOGIN)
1390
1391 AC_CHECK_FUNCS([ \
1392         arc4random \
1393         fcntl \
1394         fseeko64 \
1395         ftello64 \
1396         getcwd \
1397         getegid \
1398         geteuid \
1399         getgid \
1400         getuid \
1401         getprogname \
1402         getrlimit \
1403         issetugid \
1404         mkstemp \
1405         pread \
1406         preadv \
1407         preadv64 \
1408         pwrite \
1409         pwritev \
1410         pwritev64 \
1411         regcomp \
1412         regerror \
1413         regexec \
1414         setitimer \
1415         setprogname \
1416         setvbuf \
1417         sigaction \
1418         strcasestr \
1419         strerror \
1420         sysconf \
1421         sysctl \
1422         timegm \
1423 ])
1424
1425 OPENAFS_ROKEN()
1426 OPENAFS_C_ATTRIBUTE()
1427
1428 dnl Functions that Heimdal's libroken provides, but that we
1429 dnl haven't found a need for yet, and so haven't imported
1430 AC_CHECK_FUNCS([ \
1431         chown \
1432         fchown \
1433         gethostname \
1434         lstat \
1435         inet_aton \
1436         inet_ntop \
1437         inet_pton \
1438         putenv \
1439         readv \
1440         setenv \
1441         strdup \
1442         strftime \
1443         strndup \
1444         strsep \
1445         unsetenv \
1446 ])
1447
1448 dnl Functions that are in objects that we always build from libroken
1449 AC_CHECK_FUNCS([ \
1450         asprintf \
1451         asnprintf \
1452         vasprintf \
1453         vasnprintf \
1454         vsnprintf \
1455         snprintf \
1456 ])
1457
1458 dnl Functions that we're going to try and get from libroken
1459 AC_REPLACE_FUNCS([ \
1460         daemon \
1461         ecalloc \
1462         emalloc \
1463         erealloc \
1464         err \
1465         errx \
1466         flock \
1467         getdtablesize \
1468         getopt \
1469         getprogname \
1470         gettimeofday \
1471         localtime_r \
1472         mkstemp \
1473         strcasecmp \
1474         strlcat \
1475         strnlen \
1476         strlcpy \
1477         strsep \
1478         tdelete \
1479         tfind \
1480         tsearch \
1481         twalk \
1482         verr \
1483         verrx \
1484         vsyslog \
1485         vwarn \
1486         vwarnx \
1487         warn \
1488         warnx \
1489 ])
1490
1491 dnl Headers that we're going to try and get from libroken
1492 AC_CHECK_HEADERS([ \
1493         err.h \
1494         search.h \
1495 ])
1496
1497 AC_CHECK_DECLS([h_errno], [], [], [
1498 #include <sys/types.h>
1499 #ifdef HAVE_NETDB_H
1500 #include <netdb.h>
1501 #endif
1502 ])
1503
1504 AC_HEADER_TIME
1505
1506 ROKEN_HEADERS=
1507 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1508       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1509       [])
1510 AC_SUBST(ROKEN_HEADERS)
1511
1512 dnl Stuff that's harder ...
1513 AC_MSG_CHECKING([for bswap16])
1514 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1515 #ifdef HAVE_SYS_TYPES_H
1516 #include <sys/types.h>
1517 #endif
1518 #ifdef HAVE_SYS_BSWAP_H
1519 #include <sys/bswap.h>
1520 #endif
1521 ],
1522 [short a, b; b = bswap16(a); ])],
1523 [AC_MSG_RESULT(yes)
1524  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1525 ],
1526 [AC_MSG_RESULT(no)])
1527
1528 AC_MSG_CHECKING([for bswap32])
1529 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1530 #include <sys/types.h>
1531 #endif
1532 #ifdef HAVE_SYS_BSWAP_H
1533 #include <sys/bswap.h>
1534 #endif
1535 ],
1536 [int a, b; b = bswap32(a); ])],
1537 [AC_MSG_RESULT(yes)
1538  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1539 ],
1540 [AC_MSG_RESULT(no)])
1541
1542 case $AFS_SYSNAME in
1543 *hp_ux* | *hpux*)
1544    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1545    ;;
1546 *)
1547    AC_MSG_CHECKING([for positional I/O])
1548    if test "$ac_cv_func_pread" = "yes" && \
1549            test "$ac_cv_func_pwrite" = "yes"; then
1550       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1551       AC_MSG_RESULT(yes)
1552    else
1553      AC_MSG_RESULT(no)
1554    fi
1555    AC_MSG_CHECKING([for vectored positional I/O])
1556    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1557                "$ac_cv_func_pwritev" = "yes" -a \
1558                "$ac_cv_func_preadv64" = "yes" -a \
1559                "$ac_cv_func_pwritev64" = "yes"],
1560          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1561           AC_MSG_RESULT(yes)],
1562          [AC_MSG_RESULT(no)])
1563    ;;
1564 esac
1565
1566 AC_MSG_CHECKING([for POSIX regex library])
1567 if test "$ac_cv_header_regex_h" = "yes" && \
1568         test "$ac_cv_func_regcomp" = "yes" && \
1569         test "$ac_cv_func_regexec" = "yes" && \
1570         test "$ac_cv_func_regerror" = "yes"; then
1571     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1572     AC_MSG_RESULT(yes)
1573 else
1574     AC_MSG_RESULT(no)
1575 fi
1576
1577 dnl Look for "non-portable" pthreads functions.
1578 save_LIBS="$LIBS"
1579 LIBS="$LIBS $PTHREAD_LIBS"
1580 AC_CHECK_FUNCS([ \
1581         pthread_set_name_np \
1582         pthread_setname_np \
1583 ])
1584
1585 dnl Sadly, there are three different versions of pthread_setname_np.
1586 dnl Try to cater for all of them.
1587 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1588     AC_MSG_CHECKING([for signature of pthread_setname_np])
1589     AC_TRY_COMPILE([
1590 #include <pthread.h>
1591 #ifdef HAVE_PTHREAD_NP_H
1592 #include <pthread_np.h>
1593 #endif
1594 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1595         AC_MSG_RESULT([three arguments])
1596         pthread_setname_np_args=3], [
1597         AC_TRY_COMPILE([
1598 #include <pthread.h>
1599 #ifdef HAVE_PTHREAD_NP_H
1600 #include <pthread_np.h>
1601 #endif
1602 ], [pthread_setname_np(pthread_self(), "test")], [
1603             AC_MSG_RESULT([two arguments])
1604             pthread_setname_np_args=2], [
1605             AC_TRY_COMPILE([
1606 #include <pthread.h>
1607 #ifdef HAVE_PTHREAD_NP_H
1608 #include <pthread_np.h>
1609 #endif
1610 ], [pthread_setname_np("test")], [
1611                 AC_MSG_RESULT([one argument])
1612                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1613 ])
1614 ])
1615 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1616 fi
1617 LIBS="$save_LIBS"
1618
1619 OPENAFS_OSCONF
1620 openafs_cv_saved_CFLAGS="$CFLAGS"
1621 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1622
1623 AC_TYPE_SIGNAL
1624 OPENAFS_RETSIGTYPE
1625 AC_CHECK_SIZEOF(void *)
1626 AC_CHECK_SIZEOF(unsigned long long)
1627 AC_CHECK_SIZEOF(unsigned long)
1628 AC_CHECK_SIZEOF(unsigned int)
1629 AC_TYPE_INTPTR_T
1630 AC_TYPE_UINTPTR_T
1631 AC_TYPE_SSIZE_T
1632 AC_CHECK_TYPE([sig_atomic_t],[],
1633     [AC_DEFINE([sig_atomic_t], [int],
1634         [Define to int if <signal.h> does not define.])],
1635 [#include <sys/types.h>
1636 #include <signal.h>])
1637 AC_CHECK_TYPE([socklen_t],[],
1638     [AC_DEFINE([socklen_t], [int],
1639         [Define to int if <sys/socket.h> does not define.])],
1640 [#include <sys/types.h>
1641 #include <sys/socket.h>])
1642 AC_CHECK_TYPES(off64_t)
1643 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1644 AC_CHECK_TYPES([struct winsize], [], [], [
1645 #ifdef HAVE_TERMIOS_H
1646 # include <termios.h>
1647 #else
1648 # include <sys/termios.h>
1649 #endif
1650 #include <sys/ioctl.h>])
1651 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1652                 struct sockaddr_storage],
1653                [], [], [
1654 #include <sys/types.h>
1655 #include <sys/socket.h>
1656 ])
1657 AC_CHECK_TYPES([sa_family_t], [], [], [
1658 #include <sys/types.h>
1659 #include <sys/socket.h>
1660 ])
1661 AC_CHECK_TYPES([struct addrinfo], [], [], [
1662 #include <sys/types.h>
1663 #ifdef HAVE_NETDB_H
1664 #include <netdb.h>
1665 #endif
1666 ])
1667 AC_CHECK_TYPES([long long], [], [], [])
1668
1669 AC_SIZEOF_TYPE(long)
1670
1671 CFLAGS="$openafs_cv_saved_CFLAGS"
1672
1673 RRA_HEADER_PAM_CONST
1674
1675
1676 dnl Directory PATH handling
1677 if test "x$enable_transarc_paths" = "xyes"  ; then 
1678     afsconfdir=${afsconfdir=/usr/afs/etc}
1679     viceetcdir=${viceetcdir=/usr/vice/etc}
1680     afskerneldir=${afskerneldir=${viceetcdir}}
1681     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1682     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1683     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1684     afsdbdir=${afsdbdir=/usr/afs/db}
1685     afslogsdir=${afslogsdir=/usr/afs/logs}
1686     afslocaldir=${afslocaldir=/usr/afs/local}
1687     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1688     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1689     afsdatadir=${afsdatadir=/usr/vice/etc}
1690 else 
1691     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1692     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1693     afskerneldir=${afskerneldir='${libdir}/openafs'}
1694     afssrvbindir=${afssrvbindir='${bindir}'}
1695     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1696     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1697     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1698     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1699     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1700     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1701     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1702     afsdatadir=${afsdatadir='${datadir}/openafs'}
1703 fi
1704 AC_SUBST(afsconfdir)
1705 AC_SUBST(viceetcdir)
1706 AC_SUBST(afskerneldir)
1707 AC_SUBST(afssrvbindir)
1708 AC_SUBST(afssrvsbindir)
1709 AC_SUBST(afssrvlibexecdir)
1710 AC_SUBST(afsdbdir)
1711 AC_SUBST(afslogsdir)
1712 AC_SUBST(afslocaldir)
1713 AC_SUBST(afsbackupdir)
1714 AC_SUBST(afsbosconfigdir)
1715 AC_SUBST(afsdatadir)
1716
1717 if test "x$enable_kernel_module" = "xyes"; then
1718 ENABLE_KERNEL_MODULE=libafs
1719 fi
1720
1721 if test "x$enable_pthreaded_ubik" = "xyes"; then
1722 ENABLE_PTHREADED_UBIK=yes
1723 fi
1724
1725 AC_SUBST(VFSCK)
1726 AC_SUBST(AFS_SYSNAME)
1727 AC_SUBST(AFS_PARAM_COMMON)
1728 AC_SUBST(ENABLE_KERNEL_MODULE)
1729 AC_SUBST(ENABLE_PTHREADED_UBIK)
1730 AC_SUBST(LIB_AFSDB)
1731 AC_SUBST(LINUX_KERNEL_PATH)
1732 AC_SUBST(LINUX_KERNEL_BUILD)
1733 AC_SUBST(HOST_CPU)
1734 AC_SUBST(BSD_KERNEL_PATH)
1735 AC_SUBST(BSD_KERNEL_BUILD)
1736 AC_SUBST(LINUX_VERSION)
1737 AC_SUBST(MKAFS_OSTYPE)
1738 AC_SUBST(TOP_OBJDIR)
1739 AC_SUBST(TOP_SRCDIR)
1740 AC_SUBST(TOP_INCDIR)
1741 AC_SUBST(TOP_LIBDIR)
1742 AC_SUBST(DEST)
1743 AC_SUBST(DARWIN_INFOFILE)
1744 AC_SUBST(IRIX_BUILD_IP35)
1745 AC_SUBST(HTML_XSL)
1746 AC_SUBST(XSLTPROC)
1747 AC_SUBST(DOCBOOK2PDF)
1748 AC_SUBST(DOCBOOK_STYLESHEETS)
1749
1750 OPENAFS_FUSE
1751 OPENAFS_SWIG
1752
1753 TOP_SRCDIR="${srcdir}/src"
1754 dnl
1755 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1756 dnl
1757 case $TOP_SRCDIR in
1758         /*)
1759                 ;;
1760         *)
1761                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1762                 ;;
1763 esac
1764
1765 TOP_OBJDIR="${SRCDIR_PARENT}"
1766 TOP_INCDIR="${SRCDIR_PARENT}/include"
1767 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1768 if test "${DEST}x" = "x"; then
1769         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1770 fi
1771
1772 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1773 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1774 AC_SUBST(HELPER_SPLINT)
1775 AC_SUBST(HELPER_SPLINTCFG)
1776
1777 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1778
1779 dnl Check to see if crypt lives in a different library
1780 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1781 AC_SUBST(LIB_crypt)
1782
1783 dnl Check to see if the compiler support labels in structs
1784 AC_MSG_CHECKING(for label support in structs)
1785 AC_TRY_COMPILE([], [
1786 extern void osi_UFSOpen(void);
1787 struct labeltest {
1788    void (*open) (void);
1789 };
1790 struct labeltest struct_labeltest = {
1791    .open       = osi_UFSOpen,
1792 }
1793 ],
1794 [AC_MSG_RESULT(yes)
1795  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1796 ],
1797 [AC_MSG_RESULT(no)
1798 ])
1799
1800 AC_MSG_CHECKING([checking for dirfd])
1801 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1802 #ifdef HAVE_DIRENT_H
1803 #include <dirent.h>
1804 #endif
1805 ]],
1806         [[DIR *d = 0; dirfd(d);]])],
1807         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1808 if test "$ac_rk_have_dirfd" = "yes" ; then
1809         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1810 fi
1811 AC_MSG_RESULT($ac_rk_have_dirfd)
1812
1813 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1814 #ifdef HAVE_DIRENT_H
1815 #include <dirent.h>
1816 #endif])
1817
1818 dnl Eventually, this will look for the system one, or for OpenSSL
1819 LIB_hcrypto="-lafshcrypto"
1820 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1821 AC_SUBST(LIB_hcrypto)
1822 AC_SUBST(LDFLAGS_hcrypto)
1823 ])
1824
1825 AC_DEFUN([SUMMARY], [
1826     # Print a configuration summary
1827 echo 
1828 echo "**************************************"
1829 echo configure summary
1830 echo
1831 AS_IF([test $LIB_curses],[
1832 echo "LIB_curses :                $LIB_curses" ],[
1833 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1834 ])
1835 echo 
1836 echo "**************************************"
1837 ])