acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN(OPENAFS_CONFIGURE_COMMON,[
   8
   9 AC_CANONICAL_HOST
  10 SRCDIR_PARENT=`pwd`
  11
  12 #BOZO_SAVE_CORES BOS_RESTRICTED_MODE BOS_NEW_CONFIG pam sia
  13 AC_ARG_WITH(afs-sysname,
  14 [  --with-afs-sysname=sys    use sys for the afs sysname]
  15 )
  16 AC_ARG_ENABLE( obsolete,
  17 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
  18 AC_ARG_ENABLE( insecure,
  19 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
  20 AC_ARG_ENABLE( afsdb,
  21 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
  22 AC_ARG_ENABLE( bos-restricted-mode,
  23 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
  24 AC_ARG_ENABLE( namei-fileserver,
  25 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
  26 AC_ARG_ENABLE( fast-restart,
  27 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
  28 AC_ARG_ENABLE( bitmap-later,
  29 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
  30 AC_ARG_ENABLE( full-vos-listvol-switch,
  31 [  --enable-full-vos-listvol-switch     enable vos full listvol switch for formatted output],, enable_full_vos_listvol_switch="no")
  32 AC_ARG_WITH(dux-kernel-headers,
  33 [  --with-dux-kernel-headers=path       use the kernel headers found at path(optional, defaults to first match in /usr/sys)]
  34 )
  35 AC_ARG_WITH(linux-kernel-headers,
  36 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux)]
  37 )
  38 AC_ARG_ENABLE(kernel-module,
  39 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
  40 )
  41 AC_ARG_ENABLE(redhat-buildsys,
  42 [  --enable-redhat-buildsys             enable compilation of the redhat build system kernel (defaults to disabled)],, enable_redhat_buildsys="no"
  43 )
  44 AC_ARG_ENABLE(transarc-paths,
  45 [  --enable-transarc-paths                      Use Transarc style paths like /usr/afs and /usr/vice],, enable_transarc_paths="no"
  46 )
  47 AC_ARG_ENABLE(tivoli-tsm,
  48 [  --enable-tivoli-tsm                  Enable use of the Tivoli TSM API libraries for butc support],, enable_tivoli_tsm="no"
  49 )
  50
  51 dnl weird ass systems
  52 AC_AIX
  53 AC_ISC_POSIX
  54 AC_MINIX
  55
  56 dnl Various compiler setup.
  57 AC_C_INLINE
  58 AC_C_CONST
  59 AC_PROG_CC
  60 AC_TYPE_PID_T
  61 AC_TYPE_SIZE_T
  62 AC_TYPE_SIGNAL
  63
  64 dnl Checks for programs.
  65 AC_PROG_INSTALL
  66 AC_PROG_LN_S
  67 AC_PROG_RANLIB
  68 AC_PROG_YACC
  69 AM_PROG_LEX
  70
  71 OPENAFS_CHECK_BIGENDIAN
  72
  73 AC_MSG_CHECKING(your OS)
  74 system=$host
  75 case $system in
  76         *-linux*)
  77                 MKAFS_OSTYPE=LINUX
  78                 if test "x$enable_redhat_buildsys" = "xyes"; then
  79                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS)
  80                 fi
  81                 if test "x$enable_kernel_module" = "xyes"; then
  82                  if test "x$with_linux_kernel_headers" != "x"; then
  83                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
  84                  else
  85                    LINUX_KERNEL_PATH="/usr/src/linux"
  86                  fi
  87                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
  88                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
  89                   if test "x$linux_kvers" = "x"; then
  90                     if test -f "$LINUX_KERNEL_PATH/include/linux/version-up.h"; then
  91                       linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
  92                       if test "x$linux_kvers" = "x"; then
  93
  94                         AC_MSG_ERROR(Linux headers lack version definition [2])
  95                         exit 1
  96                       else
  97                         LINUX_VERSION="$linux_kvers"
  98                       fi
  99                     else
 100                       AC_MSG_ERROR(Linux headers lack version definition)
 101                       exit 1
 102                     fi
 103                   else
 104                     LINUX_VERSION="$linux_kvers"
 105                   fi
 106                  else
 107                     enable_kernel_module="no"
 108                  fi
 109                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
 110                      enable_kernel_module="no"
 111                  fi
 112                  if test "x$enable_kernel_module" = "xno"; then
 113                   if test "x$with_linux_kernel_headers" != "x"; then
 114                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 115                    exit 1
 116                   else
 117                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 118                   fi
 119                  fi
 120                 fi
 121                 AC_MSG_RESULT(linux)
 122                 if test "x$enable_kernel_module" = "xyes"; then
 123                  ifdef([OPENAFS_CONFIGURE_LIBAFS],
 124                    [LINUX_BUILD_VNODE_FROM_INODE(src/config,afs)],
 125                    [LINUX_BUILD_VNODE_FROM_INODE(${srcdir}/src/config,src/afs/LINUX,${srcdir}/src/afs/LINUX)]
 126                  )
 127                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK
 128                  LINUX_FS_STRUCT_INODE_HAS_I_TRUNCATE_SEM
 129                  LINUX_FS_STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS
 130                  LINUX_FS_STRUCT_INODE_HAS_I_DEVICES
 131                  LINUX_INODE_SETATTR_RETURN_TYPE
 132                  LINUX_NEED_RHCONFIG
 133                  LINUX_WHICH_MODULES
 134                  if test "x$ac_cv_linux_func_inode_setattr_returns_int" = "xyes" ; then
 135                   AC_DEFINE(INODE_SETATTR_NOT_VOID)
 136                  fi
 137                  if test "x$ac_cv_linux_fs_struct_address_space_has_page_lock" = "xyes"; then
 138                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK)
 139                  fi
 140                  if test "x$ac_cv_linux_fs_struct_inode_has_i_truncate_sem" = "xyes"; then
 141                   AC_DEFINE(STRUCT_INODE_HAS_I_TRUNCATE_SEM)
 142                  fi
 143                  if test "x$ac_cv_linux_fs_struct_inode_has_i_devices" = "xyes"; then
 144                   AC_DEFINE(STRUCT_INODE_HAS_I_DEVICES)
 145                  fi
 146                  if test "x$ac_cv_linux_fs_struct_inode_has_i_dirty_data_buffers" = "xyes"; then
 147                   AC_DEFINE(STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS)
 148                  fi
 149                 :
 150                 fi
 151                 ;;
 152         *-solaris*)
 153                 MKAFS_OSTYPE=SOLARIS
 154                 AC_MSG_RESULT(sun4)
 155                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 156                 SOLARIS_PROC_HAS_P_COREFILE
 157                 ;;
 158         *-hpux*)
 159                 MKAFS_OSTYPE=HPUX
 160                 AC_MSG_RESULT(hp_ux)
 161                 ;;
 162         *-irix*)
 163                 if test -d /usr/include/sys/SN/SN1; then
 164                  IRIX_BUILD_IP35="IP35"
 165                 fi
 166                 MKAFS_OSTYPE=IRIX
 167                 AC_MSG_RESULT(sgi)
 168                 ;;
 169         *-aix*)
 170                 MKAFS_OSTYPE=AIX
 171                 AC_MSG_RESULT(rs_aix)
 172                 ;;
 173         *-osf*)
 174                 MKAFS_OSTYPE=DUX
 175                 AC_MSG_RESULT(alpha_dux)
 176                 if test "x$enable_kernel_module" = "xyes"; then
 177                  if test "x$with_dux_kernel_headers" != "x"; then
 178                    HEADER_RT=`ls ${with_dux_kernel_headers}/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 179                  else
 180                    HEADER_RT=`ls /usr/sys/*/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 181                  fi
 182                 fi
 183                 if test "$HEADER_RT" = "*" ; then
 184                         AC_MSG_ERROR([Need a configured kernel directory])
 185                 fi
 186                 AC_SUBST([HEADER_RT])
 187                 ;;
 188         *-darwin*)
 189                 MKAFS_OSTYPE=DARWIN
 190                 AC_MSG_RESULT(ppc_darwin)
 191                 ;;
 192         *-freebsd*)
 193                 MKAFS_OSTYPE=FBSD
 194                 AC_MSG_RESULT(i386_fbsd)
 195                 ;;
 196         *-netbsd*)
 197                 MKAFS_OSTYPE=NBSD
 198                 AC_MSG_RESULT(nbsd)
 199                 ;;
 200         *-openbsd*)
 201                 MKAFS_OSTYPE=OBSD
 202                 AC_MSG_RESULT(i386_obsd)
 203                 ;;
 204         *)
 205                 AC_MSG_RESULT($system)
 206                 ;;
 207 esac
 208
 209 if test "x$with_afs_sysname" != "x"; then
 210         AFS_SYSNAME="$with_afs_sysname"
 211 else
 212         AC_MSG_CHECKING(your AFS sysname)
 213         case $host in
 214                 i?86-*-freebsd4.2*)
 215                         AFS_SYSNAME="i386_fbsd_42"
 216                         ;;
 217                 i?86-*-netbsd*1.5*)
 218                         AFS_PARAM_COMMON=param.nbsd15.h
 219                         AFS_SYSNAME="i386_nbsd15"
 220                         ;;
 221                 alpha-*-netbsd*1.5*)
 222                         AFS_PARAM_COMMON=param.nbsd15.h
 223                         AFS_SYSNAME="alpha_nbsd15"
 224                         ;;
 225                 hppa*-hp-hpux11*)
 226                         AFS_SYSNAME="hp_ux110"
 227                         ;;
 228                 hppa*-hp-hpux10*)
 229                         AFS_SYSNAME="hp_ux102"
 230                         ;;
 231                 powerpc-apple-darwin1.2*)
 232                         AFS_SYSNAME="ppc_darwin_12"
 233                         ;;
 234                 powerpc-apple-darwin1.3*)
 235                         AFS_SYSNAME="ppc_darwin_13"
 236                         ;;
 237                 powerpc-apple-darwin1.4*)
 238                         AFS_SYSNAME="ppc_darwin_14"
 239                         ;;
 240                 powerpc-apple-darwin5.1*)
 241                         AFS_SYSNAME="ppc_darwin_14"
 242                         ;;
 243                 powerpc-apple-darwin5.2*)
 244                         AFS_SYSNAME="ppc_darwin_14"
 245                         ;;
 246                 sparc-sun-solaris2.5*)
 247                         AFS_SYSNAME="sun4x_55"
 248                         ;;
 249                 sparc-sun-solaris2.6)
 250                         AFS_SYSNAME="sun4x_56"
 251                         ;;
 252                 sparc-sun-solaris2.7)
 253                         AFS_SYSNAME="sun4x_57"
 254                         ;;
 255                 sparc-sun-solaris2.8)
 256                         AFS_SYSNAME="sun4x_58"
 257                         ;;
 258                 sparc-sun-solaris2.9)
 259                         AFS_SYSNAME="sun4x_59"
 260                         ;;
 261                 alpha*-dec-osf4.0*)
 262                         AFS_SYSNAME="alpha_dux40"
 263                         ;;
 264                 alpha*-dec-osf5.0*)
 265                         AFS_SYSNAME="alpha_dux50"
 266                         ;;
 267                 mips-sgi-irix6.5)
 268                         AFS_SYSNAME="sgi_65"
 269                         ;;
 270                 ia64-*-linux*)
 271                         AFS_SYSNAME="ia64_linuxXX"
 272                         ;;
 273                 powerpc-*-linux*)
 274                         AFS_SYSNAME="ppc_linuxXX"
 275                         ;;
 276                 alpha*-linux*)
 277                         AFS_SYSNAME="alpha_linux_XX"
 278                         ;;
 279                 s390-*-linux*)
 280                         AFS_SYSNAME="s390_linuxXX"
 281                         ;;
 282                 sparc-*-linux*)
 283                         AFS_SYSNAME="sparc_linuxXX"
 284                         ;;
 285                 sparc64-*-linux*)
 286                         AFS_SYSNAME="sparc64_linuxXX"
 287                         ;;
 288                 i?86-*-linux*)
 289                         AFS_SYSNAME="i386_linuxXX"
 290                         ;;
 291                 parisc-*-linux-gnu)
 292                         AFS_SYSNAME="parisc_linuxXX"
 293                         ;;
 294                 power*-ibm-aix4.2*)
 295                         AFS_SYSNAME="rs_aix42"
 296                         ;;
 297                 power*-ibm-aix4.3*)
 298                         AFS_SYSNAME="rs_aix42"
 299                         ;;
 300                 *)
 301                         AC_MSG_ERROR(An AFS sysname is required)
 302                         exit 1
 303                         ;;
 304         esac
 305         case $AFS_SYSNAME in
 306                 *_linux*)
 307                         AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $[]1 $[]2}'`
 308                         if test "x${AFS_SYSKVERS}" = "x"; then
 309                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 310                         fi
 311                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 312                         AFS_SYSNAME="$_AFS_SYSNAME"
 313                         ;;
 314         esac
 315         AC_MSG_RESULT($AFS_SYSNAME)
 316 fi
 317
 318 case $AFS_SYSNAME in
 319         *_darwin*)
 320                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 321                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 322                 ;;
 323 esac
 324
 325 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
 326         echo Skipping library tests because they confuse Irix.
 327 else
 328   AC_CHECK_FUNCS(socket)
 329
 330   if test "$ac_cv_func_socket" = no; then
 331     for lib in socket inet; do
 332         if test "$HAVE_SOCKET" != 1; then
 333                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET))
 334         fi
 335     done
 336   fi
 337
 338   AC_CHECK_FUNCS(connect)
 339
 340   if test "$ac_cv_func_connect" = no; then
 341     for lib in nsl; do
 342         if test "$HAVE_CONNECT" != 1; then
 343                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT))
 344         fi
 345     done
 346   fi
 347
 348   AC_CHECK_FUNCS(gethostbyname)
 349   if test "$ac_cv_func_gethostbyname" = no; then
 350         for lib in dns nsl resolv; do
 351           if test "$HAVE_GETHOSTBYNAME" != 1; then
 352             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME))
 353           fi
 354         done
 355   fi
 356
 357   AC_CHECK_FUNCS(res_search)
 358   if test "$ac_cv_func_res_search" = no; then
 359         for lib in dns nsl resolv; do
 360           if test "$HAVE_RES_SEARCH" != 1; then
 361             AC_CHECK_LIB(${lib}, res_search, LIBS="$LIBS -l$lib";HAVE_RES_SEARCH=1;AC_DEFINE(HAVE_RES_SEARCH))
 362           fi
 363         done
 364         if test "$HAVE_RES_SEARCH" = 1; then
 365           LIB_res_search="-l$lib"
 366         fi
 367   fi
 368 fi
 369
 370 PTHREAD_LIBS=error
 371 AC_CHECK_LIB(pthread, pthread_attr_init,
 372              PTHREAD_LIBS="-lpthread")
 373 if test "x$PTHREAD_LIBS" = xerror; then
 374         AC_CHECK_LIB(pthreads, pthread_attr_init,
 375                 PTHREAD_LIBS="-lpthreads")
 376 fi
 377 if test "x$PTHREAD_LIBS" = xerror; then
 378         AC_CHECK_LIB(c_r, pthread_attr_init,
 379                 PTHREAD_LIBS="-lc_r")
 380 fi
 381 if test "x$PTHREAD_LIBS" = xerror; then
 382         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
 383 fi
 384 if test "x$PTHREAD_LIBS" = xerror; then
 385         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
 386 fi
 387 AC_SUBST(PTHREAD_LIBS)
 388
 389 WITH_OBSOLETE=NO
 390 if test "$enable_obsolete" = "yes"; then
 391         WITH_OBSOLETE=YES
 392 fi
 393
 394 WITH_INSECURE=NO
 395 if test "$enable_insecure" = "yes"; then
 396         WITH_INSECURE=YES
 397 fi
 398
 399 # Fast restart
 400 if test "$enable_fast_restart" = "yes"; then
 401         AC_DEFINE(FAST_RESTART)
 402 fi
 403
 404 if test "$enable_bitmap_later" = "yes"; then
 405         AC_DEFINE(BITMAP_LATER)
 406 fi
 407
 408 if test "$enable_full_vos_listvol_switch" = "yes"; then
 409         AC_DEFINE(FULL_LISTVOL_SWITCH)
 410 fi
 411
 412 if test "$enable_bos_restricted_mode" = "yes"; then
 413         AC_DEFINE(BOS_RESTRICTED_MODE)
 414 fi
 415
 416 if test "$enable_namei_fileserver" = "yes"; then
 417         AC_DEFINE(AFS_NAMEI_ENV)
 418 fi
 419
 420 if test "$enable_afsdb" = "yes"; then
 421         LIB_AFSDB="$LIB_res_search"
 422         AC_DEFINE(AFS_AFSDB_ENV)
 423 fi
 424
 425 dnl check for tivoli
 426 AC_MSG_CHECKING(for tivoli tsm butc support)
 427 XBSA_CFLAGS=""
 428 if test "$enable_tivoli_tsm" = "yes"; then
 429         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
 430         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
 431
 432         if test -e "$XBSADIR1/xbsa.h"; then
 433                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
 434                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 435         elif test -e "$XBSADIR2/xbsa.h"; then
 436                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
 437                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 438         else
 439                 AC_MSG_RESULT([no, missing xbsa.h header file])
 440         fi
 441 else
 442         AC_MSG_RESULT([no])
 443 fi
 444 AC_SUBST(XBSA_CFLAGS)
 445
 446 dnl checks for header files.
 447 AC_HEADER_STDC
 448 AC_HEADER_SYS_WAIT
 449 AC_HEADER_DIRENT
 450 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
 451 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
 452 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h)
 453 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
 454 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h)
 455 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h)
 456
 457 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf re_comp re_exec)
 458 AC_CHECK_FUNCS(setprogname getprogname)
 459
 460 dnl Directory PATH handling
 461 if test "x$enable_transarc_paths" = "xyes"  ; then
 462     afsconfdir=${afsconfdir=/usr/afs/etc}
 463     viceetcdir=${viceetcdir=/usr/vice/etc}
 464     afskerneldir=${afskerneldir=${viceetcdir}}
 465     afssrvbindir=${afssrvbindir=/usr/afs/bin}
 466     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
 467     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
 468     afsdbdir=${afsdbdir=/usr/afs/db}
 469     afslogsdir=${afslogsdir=/usr/afs/logs}
 470     afslocaldir=${afslocaldir=/usr/afs/local}
 471     afsbackupdir=${afsbackupdir=/usr/afs/backup}
 472     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
 473 else
 474     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
 475     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
 476     afskerneldir=${afskerneldir='${libdir}/openafs'}
 477     afssrvbindir=${afssrvbindir='${bindir}'}
 478     afssrvsbindir=${afssrvsbindir='${sbindir}'}
 479     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
 480     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
 481     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
 482     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
 483     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
 484     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
 485 fi
 486 AC_SUBST(afsconfdir)
 487 AC_SUBST(viceetcdir)
 488 AC_SUBST(afskerneldir)
 489 AC_SUBST(afssrvbindir)
 490 AC_SUBST(afssrvsbindir)
 491 AC_SUBST(afssrvlibexecdir)
 492 AC_SUBST(afsdbdir)
 493 AC_SUBST(afslogsdir)
 494 AC_SUBST(afslocaldir)
 495 AC_SUBST(afsbackupdir)
 496 AC_SUBST(afsbosconfigdir)
 497
 498 if test "x$enable_kernel_module" = "xyes"; then
 499 ENABLE_KERNEL_MODULE=libafs
 500 fi
 501
 502 AC_SUBST(AFS_SYSNAME)
 503 AC_SUBST(AFS_PARAM_COMMON)
 504 AC_SUBST(ENABLE_KERNEL_MODULE)
 505 AC_SUBST(LIB_AFSDB)
 506 AC_SUBST(LINUX_KERNEL_PATH)
 507 AC_SUBST(LINUX_VERSION)
 508 AC_SUBST(MKAFS_OSTYPE)
 509 AC_SUBST(TOP_OBJDIR)
 510 AC_SUBST(TOP_SRCDIR)
 511 AC_SUBST(TOP_INCDIR)
 512 AC_SUBST(TOP_LIBDIR)
 513 AC_SUBST(DEST)
 514 AC_SUBST(WITH_OBSOLETE)
 515 AC_SUBST(WITH_INSECURE)
 516 AC_SUBST(DARWIN_INFOFILE)
 517 AC_SUBST(IRIX_BUILD_IP35)
 518
 519 OPENAFS_OSCONF
 520
 521 ])