acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #   define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 #define _FILE_OFFSET_BITS 64
  48 #define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 #include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
  76
  77 dnl General feature options.
  78 AC_ARG_ENABLE([pam],
  79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
  80     ,
  81     [enable_pam="yes"])
  82 AC_ARG_ENABLE([gtx],
  83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
  84 AC_ARG_ENABLE([uss],
  85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
  86 AC_ARG_ENABLE([namei-fileserver],
  87     [AS_HELP_STRING([--enable-namei-fileserver],
  88         [force compilation of namei fileserver in preference to inode
  89          fileserver])],
  90     ,
  91     [enable_namei_fileserver="default"])
  92 AC_ARG_ENABLE([supergroups],
  93     [AS_HELP_STRING([--enable-supergroups],
  94         [enable support for nested pts groups])],
  95     ,
  96     [enable_supergroups="no"])
  97 AC_ARG_ENABLE([bitmap-later],
  98     [AS_HELP_STRING([--enable-bitmap-later],
  99         [enable fast startup of file server by not reading bitmap till
 100          needed])],
 101     ,
 102     [enable_bitmap_later="no"])
 103 AC_ARG_ENABLE([unix-sockets],
 104     [AS_HELP_STRING([--disable-unix-sockets],
 105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 106     ,
 107     [enable_unix_sockets="yes"])
 108 AC_ARG_ENABLE([tivoli-tsm],
 109     [AS_HELP_STRING([--enable-tivoli-tsm],
 110         [enable use of the Tivoli TSM API libraries for butc support])],
 111     ,
 112     [enable_tivoli_tsm="no"])
 113 AC_ARG_ENABLE([pthreaded-ubik],
 114     [AS_HELP_STRING([--enable-pthreaded-ubik],
 115         [enable installation of pthreaded ubik applications (defaults to
 116          disabled)])],
 117     ,
 118     [enable_pthreaded_ubik="no"])
 119
 120 dnl Kernel module build options.
 121 AC_ARG_WITH([linux-kernel-headers],
 122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 123         [use the kernel headers found at path (optional, defaults to
 124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
 125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
 126 AC_ARG_WITH([linux-kernel-build],
 127     [AS_HELP_STRING([--with-linux-kernel-build=path],
 128         [use the kernel build found at path(optional, defaults to
 129         kernel headers path)])])
 130 AC_ARG_WITH([bsd-kernel-headers],
 131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 132         [use the kernel headers found at path (optional, defaults to
 133          /usr/src/sys)])])
 134 AC_ARG_WITH([bsd-kernel-build],
 135     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 136         [use the kernel build found at path (optional, defaults to
 137          KSRC/i386/compile/GENERIC)])])
 138 AC_ARG_WITH([linux-kernel-packaging],
 139     [AS_HELP_STRING([--with-linux-kernel-packaging],
 140         [use standard naming conventions to aid Linux kernel build packaging
 141          (disables MPS, sets the kernel module name to openafs.ko, and
 142          installs kernel modules into the standard Linux location)])],
 143     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
 144      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
 145     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
 146 AC_ARG_ENABLE([kernel-module],
 147     [AS_HELP_STRING([--disable-kernel-module],
 148         [disable compilation of the kernel module (defaults to enabled)])],
 149     ,
 150     [enable_kernel_module="yes"])
 151 AC_ARG_ENABLE([redhat-buildsys],
 152     [AS_HELP_STRING([--enable-redhat-buildsys],
 153         [enable compilation of the redhat build system kernel (defaults to
 154          disabled)])],
 155     ,
 156     [enable_redhat_buildsys="no"])
 157
 158 dnl Installation locations.
 159 AC_ARG_ENABLE([transarc-paths],
 160     [AS_HELP_STRING([--enable-transarc-paths],
 161         [use Transarc style paths like /usr/afs and /usr/vice])],
 162     ,
 163     [enable_transarc_paths="no"])
 164
 165 dnl Deprecated crypto
 166 AC_ARG_ENABLE([kauth],
 167     [AS_HELP_STRING([--disable-kauth],
 168         [do not install the deprecated kauth server and utilities (defaults to
 169          enabled)])],
 170     ,
 171     [enable_kauth="yes"])
 172
 173 dnl Optimization and debugging flags.
 174 AC_ARG_ENABLE([strip-binaries],
 175     [AS_HELP_STRING([--disable-strip-binaries],
 176         [disable stripping of symbol information from binaries (defaults to
 177          enabled)])],
 178     ,
 179     [enable_strip_binaries="maybe"])
 180 AC_ARG_ENABLE([debug],
 181     [AS_HELP_STRING([--enable-debug],
 182         [enable compilation of the user space code with debugging information
 183          (defaults to disabled)])],
 184     ,
 185     [enable_debug="no"])
 186 AC_ARG_ENABLE([optimize],
 187     [AS_HELP_STRING([--disable-optimize],
 188         [disable optimization for compilation of the user space code (defaults
 189          to enabled)])],
 190     ,
 191     [enable_optimize="yes"])
 192 AC_ARG_ENABLE([warnings],
 193     [AS_HELP_STRING([--enable-warnings],
 194         [enable compilation warnings when building with gcc (defaults to
 195          disabled)])],
 196     ,
 197     [enable_warnings="no"])
 198 AC_ARG_ENABLE([checking],
 199     [AS_HELP_STRING([--enable-checking],
 200         [turn compilation warnings into errors when building with gcc (defaults
 201          to disabled)])],
 202     [enable_checking="$enableval"],
 203     [enable_checking="no"])
 204 AC_ARG_ENABLE([debug-locks],
 205     [AS_HELP_STRING([--enable-debug-locks],
 206         [turn on lock debugging assertions (defaults to disabled)])],
 207     [enable_debug_locks="$enableval"],
 208     [enable_debug_locks="no"])
 209 AC_ARG_ENABLE([debug-kernel],
 210     [AS_HELP_STRING([--enable-debug-kernel],
 211         [enable compilation of the kernel module with debugging information
 212          (defaults to disabled)])],
 213     ,
 214     [enable_debug_kernel="no"])
 215 AC_ARG_ENABLE([optimize-kernel],
 216     [AS_HELP_STRING([--disable-optimize-kernel],
 217         [disable compilation of the kernel module with optimization (defaults
 218          based on platform)])],
 219     ,
 220     [enable_optimize_kernel=""])
 221 AC_ARG_ENABLE([debug-lwp],
 222     [AS_HELP_STRING([--enable-debug-lwp],
 223         [enable compilation of the LWP code with debugging information
 224          (defaults to disabled)])],
 225     ,
 226     [enable_debug_lwp="no"])
 227 AC_ARG_ENABLE([optimize-lwp],
 228     [AS_HELP_STRING([--disable-optimize-lwp],
 229         [disable optimization for compilation of the LWP code (defaults to
 230          enabled)])],
 231     ,
 232     [enable_optimize_lwp="yes"])
 233 AC_ARG_ENABLE([debug-pam],
 234     [AS_HELP_STRING([--enable-debug-pam],
 235         [enable compilation of the PAM code with debugging information
 236          (defaults to disabled)])],
 237     ,
 238     [enable_debug_pam="no"])
 239 AC_ARG_ENABLE([optimize-pam],
 240     [AS_HELP_STRING([--disable-optimize-pam],
 241         [disable optimization for compilation of the PAM code (defaults to
 242          enabled)])],
 243     ,
 244     [enable_optimize_pam="yes"])
 245 AC_ARG_ENABLE([linux-syscall-probing],
 246     [AS_HELP_STRING([--enable-linux-syscall-probing],
 247         [enable Linux syscall probing (defaults to autodetect)])],
 248     ,
 249     [enable_linux_syscall_probing="maybe"])
 250 AC_ARG_WITH([crosstools-dir],
 251     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
 252
 253 AC_ARG_WITH([xslt-processor],
 254         AS_HELP_STRING([--with-xslt-processor=ARG],
 255         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 256         [XSLTPROC="$withval"],
 257         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
 258
 259 AC_ARG_WITH([html-xsl],
 260         AS_HELP_STRING([--with-html-xsl],
 261         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 262         [HTML_XSL="$withval"],
 263         [HTML_XSL="html/chunk.xsl"])
 264
 265 AC_ARG_WITH([docbook2pdf],
 266         AS_HELP_STRING([--with-docbook2pdf=ARG],
 267         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 268         [DOCBOOK2PDF="$withval"],
 269         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
 270
 271 AC_ARG_WITH([docbook-stylesheets],
 272         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 273         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 274         [DOCBOOK_STYLESHEETS="$withval"],
 275         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
 276         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
 277                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 278         fi)
 279
 280 enable_login="no"
 281
 282 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 283 dnl documentation build.
 284 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 285
 286 dnl weird ass systems
 287 dnl AC_AIX
 288 AC_ISC_POSIX
 289 dnl AC_MINIX
 290
 291 dnl Various compiler setup.
 292 AC_TYPE_PID_T
 293 AC_TYPE_SIZE_T
 294
 295 dnl Checks for programs.
 296 AC_PROG_INSTALL
 297 AC_PROG_LN_S
 298 AC_PROG_RANLIB
 299 AC_PROG_YACC
 300 AM_PROG_LEX
 301 dnl if we are flex, be lex-compatible
 302 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 303
 304 OPENAFS_FORCE_ABS_INSTALL
 305 OPENAFS_CHECK_BIGENDIAN
 306 OPENAFS_PRINTF_TAKES_Z_LEN
 307
 308 AC_MSG_CHECKING(your OS)
 309 system=$host
 310 case $system in
 311         *-linux*)
 312
 313                 MKAFS_OSTYPE=LINUX
 314                 if test "x$enable_redhat_buildsys" = "xyes"; then
 315                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 316                 fi
 317                 if test "x$enable_kernel_module" = "xyes"; then
 318                  if test "x$with_linux_kernel_headers" != "x"; then
 319                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 320                  else
 321                    for utsdir in "/lib/modules/`uname -r`/build" \
 322                                  "/lib/modules/`uname -r`/source" \
 323                                  "/usr/src/linux-2.4" \
 324                                  "/usr/src/linux"; do
 325                      LINUX_KERNEL_PATH="$utsdir"
 326                      for utsfile in "include/generated/utsrelease.h" \
 327                                     "include/linux/utsrelease.h" \
 328                                     "include/linux/version.h" \
 329                                     "include/linux/version-up.h"; do
 330                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
 331                          break 2
 332                        fi
 333                      done
 334                    done
 335                  fi
 336                  if test "x$with_linux_kernel_build" != "x"; then
 337                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 338                  else
 339                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 340                  fi
 341                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 342                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 343                    LINUX_VERSION="$linux_kvers"
 344                  else
 345                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 346                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 347                      LINUX_VERSION="$linux_kvers"
 348                    else
 349                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 350                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 351                        if test "x$linux_kvers" = "x"; then
 352                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 353                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 354                            if test "x$linux_kvers" = "x"; then
 355                              AC_MSG_ERROR(Linux headers lack version definition [2])
 356                              exit 1
 357                            else
 358                              LINUX_VERSION="$linux_kvers"
 359                            fi
 360                          else
 361                            AC_MSG_ERROR(Linux headers lack version definition)
 362                            exit 1
 363                          fi
 364                        else
 365                          LINUX_VERSION="$linux_kvers"
 366                        fi
 367                      else
 368                        enable_kernel_module="no"
 369                      fi
 370                    fi
 371                  fi
 372                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 373                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 374                      enable_kernel_module="no"
 375                  fi
 376                  if test "x$enable_kernel_module" = "xno"; then
 377                   if test "x$with_linux_kernel_headers" != "x"; then
 378                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 379                    exit 1
 380                   else
 381                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 382                   fi
 383                  fi
 384                  dnl do we need to determine SUBARCH from autoconf.h
 385                  SUBARCH=default
 386                 fi
 387                 AC_MSG_RESULT(linux)
 388                 if test "x$enable_kernel_module" = "xyes"; then
 389                  case "$LINUX_VERSION" in
 390                   2.2.*) AFS_SYSKVERS=22 ;;
 391                   2.4.*) AFS_SYSKVERS=24 ;;
 392                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
 393                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 394                  esac
 395                 fi
 396                 ;;
 397         *-solaris*)
 398                 MKAFS_OSTYPE=SOLARIS
 399                 AC_MSG_RESULT(sun4)
 400                 AC_PATH_PROG(SOLARISCC, [cc], ,
 401                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 402                 if test "x$SOLARISCC" = "x" ; then
 403                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 404                 fi
 405                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 406                 SOLARIS_FS_HAS_FS_ROLLED
 407                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 408                 SOLARIS_HAVE_VN_RENAMEPATH
 409                 ;;
 410         *-sunos*)
 411                 MKAFS_OSTYPE=SUNOS
 412                 enable_kernel_module=no
 413                 AC_MSG_RESULT(sun4)
 414                 ;;
 415         *-hpux*)
 416                 MKAFS_OSTYPE=HPUX
 417                 AC_MSG_RESULT(hp_ux)
 418                 if test -f "/usr/old/usr/include/ndir.h"; then
 419                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 420                 fi
 421                 ;;
 422         *-irix*)
 423                 if test -d /usr/include/sys/SN/SN1; then
 424                  IRIX_BUILD_IP35="IP35"
 425                 fi
 426                 MKAFS_OSTYPE=IRIX
 427                 AC_MSG_RESULT(sgi)
 428                 ;;
 429         *-aix*)
 430                 MKAFS_OSTYPE=AIX
 431                 AC_MSG_RESULT(rs_aix)
 432                 ;;
 433         arm-*-darwin*)
 434                 MKAFS_OSTYPE=DARWIN
 435                 AC_MSG_RESULT(arm_darwin)
 436                 ;;
 437         powerpc-*-darwin*)
 438                 MKAFS_OSTYPE=DARWIN
 439                 AC_MSG_RESULT(ppc_darwin)
 440                 ;;
 441         i386-*-darwin*)
 442                 MKAFS_OSTYPE=DARWIN
 443                 AC_MSG_RESULT(x86_darwin)
 444                 ;;
 445         x86_64-*-darwin*)
 446                 MKAFS_OSTYPE=DARWIN
 447                 AC_MSG_RESULT(x86_darwin)
 448                 ;;
 449         i386-*-freebsd*)
 450                 MKAFS_OSTYPE=FBSD
 451                 AC_MSG_RESULT(i386_fbsd)
 452                 ;;
 453         x86_64-*-freebsd*)
 454                 MKAFS_OSTYPE=FBSD
 455                 AC_MSG_RESULT(amd64_fbsd)
 456                 ;;
 457         *-netbsd*)
 458                 MKAFS_OSTYPE=NBSD
 459                 AC_MSG_RESULT(nbsd)
 460                 ;;
 461         x86_64-*-openbsd*)
 462                 MKAFS_OSTYPE=OBSD
 463                 AC_MSG_RESULT(amd64_obsd)
 464                 ;;
 465         i386-*-openbsd*)
 466                 MKAFS_OSTYPE=OBSD
 467                 AC_MSG_RESULT(i386_obsd)
 468                 ;;
 469         *-dragonfly*)
 470                 MKAFS_OSTYPE=DFBSD
 471                 AC_MSG_RESULT(i386_dfbsd)
 472                 ;;
 473         *)
 474                 AC_MSG_RESULT($system)
 475                 ;;
 476 esac
 477
 478 if test "x$with_afs_sysname" != "x"; then
 479         AFS_SYSNAME="$with_afs_sysname"
 480 else
 481         AC_MSG_CHECKING(your AFS sysname)
 482         case $host in
 483                 i?86-*-openbsd?.?)
 484                         v=${host#*openbsd}
 485                         vM=${v%.*}
 486                         vm=${v#*.}
 487                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 488                         ;;
 489                 sparc64-*-openbsd?.?)
 490                         v=${host#*openbsd}
 491                         vM=${v%.*}
 492                         vm=${v#*.}
 493                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 494                         ;;
 495                 x86_64-*-openbsd?.?)
 496                         v=${host#*openbsd}
 497                         vM=${v%.*}
 498                         vm=${v#*.}
 499                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 500                         ;;
 501                 i?86-*-freebsd*.*)
 502                         v=${host#*freebsd}
 503                         vM=${v%.*}
 504                         vm=${v#*.}
 505                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 506                         ;;
 507                 x86_64-*-freebsd*.*)
 508                         v=${host#*freebsd}
 509                         vM=${v%.*}
 510                         vm=${v#*.}
 511                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 512                         ;;
 513                 i386-*-dragonfly?.*)
 514                         v=${host#*dragonfly}
 515                         vM=${v%.*}
 516                         vm=${v#*.}
 517                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 518                         ;;
 519                 i?86-*-netbsd*1.6[[M-Z]]*)
 520                         AFS_SYSNAME="i386_nbsd20"
 521                         ;;
 522                 powerpc-*-netbsd*1.6[[M-Z]]*)
 523                         AFS_SYSNAME="ppc_nbsd20"
 524                         ;;
 525                 *-*-netbsd*)
 526                         arch=${host%%-unknown*}
 527                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 528                                                -e 's/powerpc/ppc/g')
 529                         v=${host#*netbsd}
 530                         v=${v#*aout}
 531                         v=${v#*ecoff}
 532                         v=${v#*elf}
 533                         vM=${v%%.*}
 534                         vM=${vM%.*}
 535                         v=${v#*.}
 536                         vm=${v%%.*}
 537                         vm=${vm%.*}
 538                         vm=${vm%%[[_A-Z]]*}
 539                         if test $vm -eq 99 ; then
 540                                 vM=$((vM+1))
 541                         fi
 542                         if test $vM -gt 1 ; then
 543                                 vm=0
 544                         fi
 545                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 546                         ;;
 547                 hppa*-hp-hpux11.0*)
 548                         AFS_SYSNAME="hp_ux110"
 549                         ;;
 550                 hppa*-hp-hpux11.11)
 551                         AFS_SYSNAME="hp_ux11i"
 552                         ;;
 553                 hppa*-hp-hpux11.23)
 554                         AFS_SYSNAME="hp_ux1123"
 555                         ;;
 556                 ia64-hp-hpux11.22)
 557                         AFS_SYSNAME="ia64_hpux1122"
 558                         ;;
 559                 ia64-hp-hpux*)
 560                         AFS_SYSNAME="ia64_hpux1123"
 561                         ;;
 562                 hppa*-hp-hpux10*)
 563                         AFS_SYSNAME="hp_ux102"
 564                         ;;
 565                 powerpc-apple-darwin7*)
 566                         AFS_SYSNAME="ppc_darwin_70"
 567                         OSXSDK="macosx10.3"
 568                         ;;
 569                 powerpc-apple-darwin8.*)
 570                         AFS_SYSNAME="ppc_darwin_80"
 571                         OSXSDK="macosx10.4"
 572                         ;;
 573                 i386-apple-darwin8.*)
 574                         AFS_SYSNAME="x86_darwin_80"
 575                         OSXSDK="macosx10.4"
 576                         ;;
 577                 powerpc-apple-darwin9.*)
 578                         AFS_SYSNAME="ppc_darwin_90"
 579                         OSXSDK="macosx10.5"
 580                         ;;
 581                 i386-apple-darwin9.*)
 582                         AFS_SYSNAME="x86_darwin_90"
 583                         OSXSDK="macosx10.5"
 584                         ;;
 585                 i?86-apple-darwin10.*)
 586                         AFS_SYSNAME="x86_darwin_100"
 587                         OSXSDK="macosx10.6"
 588                         ;;
 589                 x86_64-apple-darwin10.*)
 590                         AFS_SYSNAME="x86_darwin_100"
 591                         OSXSDK="macosx10.6"
 592                         ;;
 593                 arm-apple-darwin10.*)
 594                         AFS_SYSNAME="arm_darwin_100"
 595                         OSXSDK="iphoneos4.0"
 596                         ;;
 597                 x86_64-apple-darwin11.*)
 598                         AFS_SYSNAME="x86_darwin_110"
 599                         OSXSDK="macosx10.7"
 600                         ;;
 601                 i?86-apple-darwin11.*)
 602                         AFS_SYSNAME="x86_darwin_110"
 603                         OSXSDK="macosx10.7"
 604                         ;;
 605                 x86_64-apple-darwin12.*)
 606                         AFS_SYSNAME="x86_darwin_120"
 607                         OSXSDK="macosx10.8"
 608                         ;;
 609                 i?86-apple-darwin12.*)
 610                         AFS_SYSNAME="x86_darwin_120"
 611                         OSXSDK="macosx10.8"
 612                         ;;
 613                 sparc-sun-solaris2.8)
 614                         AFS_SYSNAME="sun4x_58"
 615                         ;;
 616                 sparc-sun-solaris2.9)
 617                         AFS_SYSNAME="sun4x_59"
 618                         ;;
 619                 sparc-sun-solaris2.10)
 620                         AFS_SYSNAME="sun4x_510"
 621                         ;;
 622                 sparc-sun-solaris2.11)
 623                         AFS_SYSNAME="sun4x_511"
 624                         ;;
 625                 i386-pc-solaris2.8)
 626                         AFS_SYSNAME="sunx86_58"
 627                         ;;
 628                 i386-pc-solaris2.9)
 629                         AFS_SYSNAME="sunx86_59"
 630                         ;;
 631                 i386-pc-solaris2.10)
 632                         AFS_SYSNAME="sunx86_510"
 633                         ;;
 634                 i386-pc-solaris2.11)
 635                         AFS_SYSNAME="sunx86_511"
 636                         ;;
 637                 alpha*-dec-osf4.0*)
 638                         AFS_SYSNAME="alpha_dux40"
 639                         ;;
 640                 alpha*-dec-osf5.0*)
 641                         AFS_SYSNAME="alpha_dux50"
 642                         ;;
 643                 alpha*-dec-osf5.1*)
 644                         AFS_SYSNAME="alpha_dux51"
 645                         ;;
 646                 mips-sgi-irix6.5)
 647                         AFS_SYSNAME="sgi_65"
 648                         ;;
 649                 ia64-*-linux*)
 650                         AFS_SYSNAME="ia64_linuxXX"
 651                         ;;
 652                 powerpc-*-linux*)
 653                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 654                         ;;
 655                 powerpc64-*-linux*)
 656                         AFS_SYSNAME="ppc64_linuxXX"
 657                         ;;
 658                 alpha*-linux*)
 659                         AFS_SYSNAME="alpha_linux_XX"
 660                         ;;
 661                 s390-*-linux*)
 662                         AFS_SYSNAME="s390_linuxXX"
 663                         ;;
 664                 s390x-*-linux*)
 665                         AFS_SYSNAME="s390x_linuxXX"
 666                         ;;
 667                 sparc-*-linux*)
 668                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 669                         ;;
 670                 sparc64-*-linux*)
 671                         AFS_SYSNAME="sparc64_linuxXX"
 672                         ;;
 673                 i?86-*-linux*)
 674                         AFS_SYSNAME="i386_linuxXX"
 675                         ;;
 676                 arm*-linux*)
 677                         AFS_SYSNAME="arm_linuxXX"
 678                         ;;
 679                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 680                         AFS_SYSNAME="parisc_linuxXX"
 681                         enable_pam="no"
 682                         ;;
 683                 power*-ibm-aix4.2*)
 684                         AFS_SYSNAME="rs_aix42"
 685                         enable_pam="no"
 686                         ;;
 687                 power*-ibm-aix4.3*)
 688                         AFS_SYSNAME="rs_aix42"
 689                         enable_pam="no"
 690                         ;;
 691                 power*-ibm-aix5.1*)
 692                         AFS_SYSNAME="rs_aix51"
 693                         enable_pam="no"
 694                         ;;
 695                 power*-ibm-aix5.2*)
 696                         AFS_SYSNAME="rs_aix52"
 697                         enable_pam="no"
 698                         ;;
 699                 power*-ibm-aix5.3*)
 700                         AFS_SYSNAME="rs_aix53"
 701                         enable_pam="no"
 702                         ;;
 703                 power*-ibm-aix6.1*)
 704                         AFS_SYSNAME="rs_aix61"
 705                         enable_pam="no"
 706                         ;;
 707                 x86_64-*-linux-gnu)
 708                         AFS_SYSNAME="amd64_linuxXX"
 709                         enable_pam="yes"
 710                         ;;
 711                 *)
 712                         AC_MSG_ERROR(An AFS sysname is required)
 713                         exit 1
 714                         ;;
 715         esac
 716         case $AFS_SYSNAME in
 717                 *_linux* | *_umlinux*)
 718                         if test "x${AFS_SYSKVERS}" = "x"; then
 719                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 720                         fi
 721                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 722                         AFS_SYSNAME="$_AFS_SYSNAME"
 723                         AC_TRY_KBUILD(
 724                          [],
 725                          [#ifndef CONFIG_USERMODE
 726                           #error not UML
 727                           #endif],
 728                          ac_cv_linux_is_uml=yes,)
 729                         if test "${ac_cv_linux_is_uml}" = yes; then
 730                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 731                         fi
 732                         AFS_SYSNAME="$_AFS_SYSNAME"
 733                         ;;
 734         esac
 735         AC_MSG_RESULT($AFS_SYSNAME)
 736 fi
 737
 738 case $AFS_SYSNAME in
 739         *_darwin*)
 740                 AC_CHECK_HEADERS(crt_externs.h)
 741                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 742                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 743                 AC_SUBST(OSXSDK)
 744                 ;;
 745 esac
 746
 747 dnl Some hosts have a separate common param file they should include.  Figure
 748 dnl out if we're on one of them now that we know the sysname.
 749 case $AFS_SYSNAME in
 750     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 751     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 752     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 753     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 754     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 755     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 756     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 757     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 758     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 759     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 760     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 761     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 762     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 763     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 764     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 765     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 766     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 767     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 768     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 769     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 770     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 771     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 772     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 773     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 774     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 775     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 776     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 777     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 778     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 779 # Linux alpha adds an extra underscore for no good reason.
 780     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 781     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 782     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 783 esac
 784
 785 OPENAFS_OSCONF
 786
 787 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 788
 789                 # Add (sub-) architecture-specific paths needed by conftests
 790                 case $AFS_SYSNAME  in
 791                         *_umlinux26)
 792                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 793                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 794                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 795                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 796                 esac
 797
 798                 if test "x$enable_kernel_module" = "xyes"; then
 799                  if test "x$enable_debug_kernel" = "xno"; then
 800                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 801                  fi
 802                  OPENAFS_GCC_SUPPORTS_MARCH
 803                  AC_SUBST(P5PLUS_KOPTS)
 804                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 805                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 806                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 807                  OPENAFS_GCC_SUPPORTS_PIPE
 808                  AC_SUBST(LINUX_GCC_KOPTS)
 809
 810                  dnl Setup the kernel build environment
 811                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 812                  LINUX_KERNEL_COMPILE_WORKS
 813
 814                  dnl Check for header files
 815                  AC_CHECK_LINUX_HEADER([config.h])
 816                  AC_CHECK_LINUX_HEADER([completion.h])
 817                  AC_CHECK_LINUX_HEADER([exportfs.h])
 818                  AC_CHECK_LINUX_HEADER([freezer.h])
 819                  AC_CHECK_LINUX_HEADER([key-type.h])
 820                  AC_CHECK_LINUX_HEADER([semaphore.h])
 821                  AC_CHECK_LINUX_HEADER([seq_file.h])
 822
 823                  dnl Type existence checks
 824                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 825
 826                  dnl Check for structure elements
 827                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 828                                        [write_begin], [fs.h])
 829                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 830                                        [backing-dev.h])
 831                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
 832                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 833                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 834                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 835                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 836                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 837                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 838                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 839                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 840                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 841                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 842                  AC_CHECK_LINUX_STRUCT([filename], [name], [fs.h])
 843                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
 844                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
 845                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 846                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 847                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 848                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 849                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 850                                        [fs.h])
 851                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 852                                        [fs.h])
 853                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 854                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 855                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 856                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 857                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 858                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 859                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 860                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 861                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 862                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 863                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 864
 865                  dnl Check for typed structure elements
 866                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 867                                              [buf], [fs.h])
 868
 869                  dnl Function existence checks
 870
 871                  AC_CHECK_LINUX_FUNC([bdi_init],
 872                                      [#include <linux/backing-dev.h>],
 873                                      [bdi_init(NULL);])
 874                  AC_CHECK_LINUX_FUNC([PageChecked],
 875                                      [#include <linux/mm.h>
 876 #include <linux/page-flags.h>],
 877                                      [struct page *_page;
 878                                       int bchecked = PageChecked(_page);])
 879                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 880                                      [#include <linux/mm.h>
 881 #include <linux/page-flags.h>],
 882                                      [struct page *_page;
 883                                       int bchecked = PageFsMisc(_page);])
 884                  AC_CHECK_LINUX_FUNC([clear_inode],
 885                                      [#include <linux/fs.h>],
 886                                      [clear_inode(NULL);])
 887                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 888                                      [#include <linux/time.h>],
 889                                      [struct timespec s;
 890                                       s = current_kernel_time();])
 891                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 892                                      [#include <linux/fs.h>],
 893                                      [d_alloc_anon(NULL);])
 894                  AC_CHECK_LINUX_FUNC([d_make_root],
 895                                      [#include <linux/fs.h>],
 896                                      [d_make_root(NULL);])
 897                  AC_CHECK_LINUX_FUNC([do_sync_read],
 898                                      [#include <linux/fs.h>],
 899                                      [do_sync_read(NULL, NULL, 0, NULL);])
 900                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 901                                      [#include <linux/sched.h>],
 902                                      [pid_t p; find_task_by_pid(p);])
 903                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 904                                      [#include <linux/fs.h>],
 905                                      [generic_file_aio_read(NULL,NULL,0,0);])
 906                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 907                                      [#include <linux/pagemap.h>],
 908                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 909                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 910                                      [#include <linux/list.h>],
 911                                      [hlist_unhashed(0);])
 912                  AC_CHECK_LINUX_FUNC([i_size_read],
 913                                      [#include <linux/fs.h>],
 914                                      [i_size_read(NULL);])
 915                  AC_CHECK_LINUX_FUNC([inode_setattr],
 916                                      [#include <linux/fs.h>],
 917                                      [inode_setattr(NULL, NULL);])
 918                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
 919                                      [#include <linux/net.h>],
 920                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
 921                  AC_CHECK_LINUX_FUNC([page_follow_link],
 922                                      [#include <linux/fs.h>],
 923                                      [page_follow_link(0,0);])
 924                  AC_CHECK_LINUX_FUNC([page_offset],
 925                                      [#include <linux/pagemap.h>],
 926                                      [page_offset(NULL);])
 927                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
 928                                      [#include <linux/pagevec.h>],
 929                                      [__pagevec_lru_add_file(NULL);])
 930                  AC_CHECK_LINUX_FUNC([path_lookup],
 931                                      [#include <linux/fs.h>
 932                                       #include <linux/namei.h>],
 933                                      [path_lookup(NULL, 0, NULL);])
 934                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
 935                                      [#include <linux/rcupdate.h>],
 936                                      [rcu_read_lock();])
 937                  AC_CHECK_LINUX_FUNC([set_nlink],
 938                                      [#include <linux/fs.h>],
 939                                      [set_nlink(NULL, 1);])
 940                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
 941                                      [#include <linux/splice.h>],
 942                                      [splice_direct_to_actor(NULL,NULL,NULL);])
 943                  AC_CHECK_LINUX_FUNC([svc_addr_in],
 944                                      [#include <linux/sunrpc/svc.h>],
 945                                      [svc_addr_in(NULL);])
 946                  AC_CHECK_LINUX_FUNC([zero_user_segments],
 947                                      [#include <linux/highmem.h>],
 948                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
 949                  AC_CHECK_LINUX_FUNC([noop_fsync],
 950                                      [#include <linux/fs.h>],
 951                                      [void *address = &noop_fsync; printk("%p\n", address)];)
 952                  AC_CHECK_LINUX_FUNC([kthread_run],
 953                                      [#include <linux/kernel.h>
 954                                       #include <linux/kthread.h>],
 955                                      [kthread_run(NULL, NULL, "test");])
 956
 957                  dnl Consequences - things which get set as a result of the
 958                  dnl                above tests
 959                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
 960                        [AC_DEFINE([AFS_NONFSTRANS], 1,
 961                                   [define to disable the nfs translator])])
 962
 963                  dnl Assorted more complex tests
 964                  LINUX_AIO_NONVECTOR
 965                  LINUX_EXPORTS_PROC_ROOT_FS
 966                  LINUX_KMEM_CACHE_INIT
 967                  LINUX_HAVE_KMEM_CACHE_T
 968                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
 969                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
 970                  LINUX_D_PATH_TAKES_STRUCT_PATH
 971                  LINUX_NEW_EXPORT_OPS
 972                  LINUX_INODE_SETATTR_RETURN_TYPE
 973                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
 974                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
 975                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
 976                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
 977                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
 978                  LINUX_DOP_D_DELETE_TAKES_CONST
 979                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
 980                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
 981                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
 982                  LINUX_FOP_F_FSYNC_TAKES_RANGE
 983                  LINUX_AOP_WRITEBACK_CONTROL
 984                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
 985                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
 986                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
 987                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
 988                  LINUX_KERNEL_SOCK_CREATE
 989                  LINUX_EXPORTS_KEY_TYPE_KEYRING
 990                  LINUX_NEED_RHCONFIG
 991                  LINUX_RECALC_SIGPENDING_ARG_TYPE
 992                  LINUX_EXPORTS_TASKLIST_LOCK
 993                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
 994                  LINUX_STATFS_TAKES_DENTRY
 995                  LINUX_REFRIGERATOR
 996                  LINUX_HAVE_TRY_TO_FREEZE
 997                  LINUX_LINUX_KEYRING_SUPPORT
 998                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
 999                  LINUX_KEY_ALLOC_NEEDS_CRED
1000                  LINUX_INIT_WORK_HAS_DATA
1001                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1002                  LINUX_HAVE_DCACHE_LOCK
1003                  LINUX_D_COUNT_IS_INT
1004                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1005                  LINUX_IOP_CREATE_TAKES_UMODE_T
1006                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1007                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1008                  LINUX_DENTRY_OPEN_TAKES_PATH
1009                  LINUX_D_ALIAS_IS_HLIST
1010                  LINUX_IOP_I_CREATE_TAKES_BOOL
1011                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1012                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1013
1014                  dnl If we are guaranteed that keyrings will work - that is
1015                  dnl  a) The kernel has keyrings enabled
1016                  dnl  b) The code is new enough to give us a key_type_keyring
1017                  dnl then we just disable syscall probing unless we've been
1018                  dnl told otherwise
1019
1020                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1021                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1022                           [enable_linux_syscall_probing="no"],
1023                           [enable_linux_syscall_probing="yes"])
1024                  ])
1025
1026                  dnl Syscall probing needs a few tests of its own, and just
1027                  dnl won't work if the kernel doesn't export init_mm
1028                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1029                    LINUX_EXPORTS_INIT_MM
1030                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1031                      AC_MSG_ERROR(
1032                        [Can't do syscall probing without exported init_mm])
1033                    ])
1034                    LINUX_EXPORTS_SYS_CHDIR
1035                    LINUX_EXPORTS_SYS_OPEN
1036                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1037                              [define to enable syscall table probes])
1038                  ])
1039
1040                  dnl Packaging and SMP build
1041                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1042                    LINUX_WHICH_MODULES
1043                  else
1044                    AC_SUBST(MPS,'SP')
1045                  fi
1046
1047                  dnl Syscall probing
1048                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1049                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1050                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1051                    ])
1052                    ac_cv_linux_exports_sys_call_table=no
1053                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1054                      ac_cv_linux_exports_ia32_sys_call_table=yes
1055                    fi
1056                  else
1057                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1058                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1059                    LINUX_EXPORTS_SYS_CALL_TABLE
1060                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1061                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1062                          linux_syscall_method=none
1063                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1064                             linux_syscall_method=scan
1065                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1066                                linux_syscall_method=scan_with_kallsyms_address
1067                             fi
1068                          fi
1069                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1070                             linux_syscall_method=kallsyms_symbol
1071                          fi
1072                          if test "x$linux_syscall_method" = "xnone"; then
1073                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1074                             linux_syscall_method=scan
1075                          fi
1076                    fi
1077                  fi
1078                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1079                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1080                  fi
1081                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1082                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1083                  fi
1084                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1085                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1086                  else
1087                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1088                  fi
1089                 :
1090                 fi
1091 dnl Linux-only, but just enable always.
1092                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1093 esac
1094
1095 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1096     [ac_cv_sync_fetch_and_add],
1097     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1098                     [ac_cv_sync_fetch_and_add=yes],
1099                     [ac_cv_sync_fetch_and_add=no])
1100 ])
1101 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1102       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1103                 [define if your C compiler has __sync_add_and_fetch])])
1104
1105 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1106     [ac_cv_sockaddr_len],
1107     [AC_TRY_COMPILE( [#include <sys/types.h>
1108 #include <sys/socket.h>],
1109                      [struct sockaddr *a; a->sa_len=0;],
1110                      [ac_cv_sockaddr_len=yes],
1111                      [ac_cv_sockaddr_len=no])
1112 ])
1113 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1114       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1115                  [define if you struct sockaddr sa_len])])
1116
1117 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1118         echo Skipping library tests because they confuse Irix.
1119 else
1120   AC_SEARCH_LIBS([socket], [socket inet])
1121   AC_SEARCH_LIBS([connect], [nsl])
1122   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1123
1124   dnl darwin wants it, aix hates it
1125   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1126   AC_TRY_COMPILE([
1127   #include <stdlib.h>
1128   #include <stdio.h>
1129   #include <sys/types.h>
1130   #include <sys/socket.h>
1131   #include <netinet/in.h>
1132   #include <arpa/inet.h>
1133   #include <arpa/nameser.h>
1134   #include <arpa/nameser_compat.h>
1135   #include <resolv.h>
1136   ], [static int i; i = 0;],
1137   [AC_MSG_RESULT(yes)
1138    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1139   [AC_MSG_RESULT(no)
1140    ])
1141
1142   openafs_save_libs="$LIBS"
1143   AC_MSG_CHECKING([for res_search])
1144   AC_FUNC_RES_SEARCH
1145
1146   if test "$ac_cv_func_res_search" = no; then
1147       for lib in dns nsl resolv; do
1148         if test "$ac_cv_func_res_search" != yes; then
1149           LIBS="-l$lib $LIBS"
1150           AC_FUNC_RES_SEARCH
1151           LIBS="$openafs_save_libs"
1152         fi
1153       done
1154       if test "$ac_cv_func_res_search" = yes; then
1155         LIB_AFSDB="-l$lib"
1156         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1157         AC_MSG_RESULT([yes, in lib$lib])
1158       else
1159         AC_MSG_RESULT(no)
1160       fi
1161   else
1162     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1163     AC_MSG_RESULT(yes)
1164   fi
1165
1166 fi
1167 XLIBS="$LIB_AFSDB $XLIBS"
1168
1169 AC_CHECK_RESOLV_RETRANS
1170
1171 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1172     [ac_cv_setsockopt_iprecverr],
1173     [AC_TRY_COMPILE( [
1174 #include <sys/types.h>
1175 #include <sys/socket.h>
1176 #include <netinet/in.h>],
1177 [int on=1;
1178 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1179         [ac_cv_setsockopt_iprecverr=yes],
1180         [ac_cv_setsockopt_iprecverr=no])])
1181
1182 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1183       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1184                  [define if we can receive socket errors via IP_RECVERR])])
1185
1186 PTHREAD_LIBS=error
1187 if test "x$MKAFS_OSTYPE" = OBSD; then
1188         PTHREAD_LIBS="-pthread"
1189 fi
1190 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1191         PTHREAD_LIBS="-pthread"
1192 fi
1193 if test "x$PTHREAD_LIBS" = xerror; then
1194         AC_CHECK_LIB(pthread, pthread_attr_init,
1195                 PTHREAD_LIBS="-lpthread")
1196 fi
1197 if test "x$PTHREAD_LIBS" = xerror; then
1198         AC_CHECK_LIB(pthreads, pthread_attr_init,
1199                 PTHREAD_LIBS="-lpthreads")
1200 fi
1201 if test "x$PTHREAD_LIBS" = xerror; then
1202         AC_CHECK_LIB(c_r, pthread_attr_init,
1203                 PTHREAD_LIBS="-lc_r")
1204 fi
1205 if test "x$PTHREAD_LIBS" = xerror; then
1206         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1207 fi
1208 if test "x$PTHREAD_LIBS" = xerror; then
1209         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1210         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1211                 PTHREAD_LIBS="-lpthread")
1212 fi
1213 if test "x$PTHREAD_LIBS" = xerror; then
1214         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1215 fi
1216 AC_SUBST(PTHREAD_LIBS)
1217
1218 HOST_CPU="$host_cpu"
1219
1220 if test "x$with_bsd_kernel_headers" != "x"; then
1221         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1222 else
1223         BSD_KERNEL_PATH="/usr/src/sys"
1224 fi
1225
1226 if test "x$with_bsd_kernel_build" != "x"; then
1227         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1228 else
1229         case $AFS_SYSNAME in
1230                 *_fbsd_*)
1231                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1232                         ;;
1233                 *_nbsd*)
1234                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1235         esac
1236 fi
1237
1238 # Fast restart
1239 if test "$enable_supergroups" = "yes"; then
1240         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1241 fi
1242
1243 if test "$enable_bitmap_later" = "yes"; then
1244         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1245 fi
1246
1247 if test "$enable_unix_sockets" = "yes"; then
1248         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1249         USE_UNIX_SOCKETS="yes"
1250 else
1251         USE_UNIX_SOCKETS="no"
1252 fi
1253 AC_SUBST(USE_UNIX_SOCKETS)
1254
1255 if test "$enable_namei_fileserver" = "yes"; then
1256         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1257         VFSCK=""
1258 else
1259         if test "$enable_namei_fileserver" = "default"; then
1260                 case $host in
1261                         *-solaris2.10*)
1262                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1263                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1264                                 VFSCK=""
1265                                 ;;
1266                         *-solaris2.11*)
1267                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1268                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1269                                 VFSCK=""
1270                                 ;;
1271                         *)
1272                                 VFSCK="vfsck"
1273                                 ;;
1274                 esac
1275         else
1276                 VFSCK="vfsck"
1277         fi
1278 fi
1279
1280 dnl check for tivoli
1281 AC_MSG_CHECKING(for tivoli tsm butc support)
1282 XBSA_CFLAGS=""
1283 if test "$enable_tivoli_tsm" = "yes"; then
1284         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1285         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1286         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1287         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1288
1289         if test -r "$XBSADIR3/dsmapifp.h"; then
1290                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1291                 XBSA_XLIBS="-ldl"
1292                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1293         elif test -r "$XBSADIR4/dsmapifp.h"; then
1294                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1295                 XBSA_XLIBS="-ldl"
1296                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1297         elif test -r "$XBSADIR1/xbsa.h"; then
1298                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1299                 XBSA_XLIBS=""
1300                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1301         elif test -r "$XBSADIR2/xbsa.h"; then
1302                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1303                 XBSA_XLIBS=""
1304                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1305         else
1306                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1307         fi
1308 else
1309         AC_MSG_RESULT([no])
1310 fi
1311 AC_SUBST(XBSA_CFLAGS)
1312 AC_SUBST(XBSA_XLIBS)
1313
1314 dnl checks for header files.
1315 AC_HEADER_STDC
1316 AC_HEADER_SYS_WAIT
1317 AC_HEADER_DIRENT
1318 AC_CHECK_HEADERS([ \
1319                    arpa/inet.h \
1320                    arpa/nameser.h \
1321                    curses.h\
1322                    direct.h \
1323                    et/com_err.h \
1324                    errno.h \
1325                    fcntl.h \
1326                    grp.h \
1327                    math.h \
1328                    mntent.h \
1329                    ncurses.h \
1330                    ncurses/ncurses.h \
1331                    netdb.h \
1332                    netinet/in.h \
1333                    pthread_np.h \
1334                    pwd.h \
1335                    regex.h \
1336                    security/pam_appl.h \
1337                    signal.h \
1338                    stdint.h \
1339                    stdio_ext.h \
1340                    stdlib.h \
1341                    string.h \
1342                    strings.h \
1343                    sys/bitypes.h \
1344                    sys/bswap.h \
1345                    sys/dk.h \
1346                    sys/fcntl.h \
1347                    sys/file.h \
1348                    sys/fs_types.h \
1349                    sys/fstyp.h \
1350                    sys/ioctl.h \
1351                    sys/ipc.h \
1352                    sys/lockf.h \
1353                    sys/map.h \
1354                    sys/mount.h \
1355                    sys/mntent.h \
1356                    sys/mnttab.h \
1357                    sys/pag.h \
1358                    sys/param.h \
1359                    sys/resource.h \
1360                    sys/select.h \
1361                    sys/statfs.h \
1362                    sys/statvfs.h \
1363                    sys/socket.h \
1364                    sys/sysctl.h \
1365                    sys/time.h \
1366                    sys/types.h \
1367                    sys/uio.h \
1368                    sys/un.h \
1369                    sys/vfs.h \
1370                    syslog.h \
1371                    termios.h \
1372                    time.h \
1373                    ucontext.h \
1374                    unistd.h \
1375                    windows.h \
1376                 ])
1377
1378 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1379 #ifdef HAVE_NETINET_IN_H
1380 # include <netinet/in.h>
1381 #endif])
1382
1383 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1384 #ifdef HAVE_SYS_SOCKET_H
1385 # include <sys/socket.h>
1386 #endif])
1387
1388 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1389 #ifdef HAVE_SYS_SOCKET_H
1390 # include <sys/socket.h>
1391 #endif
1392 #ifdef HAVE_NETINET_IN_H
1393 # include <netinet/in.h>
1394 #endif
1395 #ifdef HAVE_NET_IF_H
1396 # include <net/if.h>
1397 #endif])
1398
1399 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1400 #ifdef HAVE_SECURITY_PAM_APPL_H
1401 # include <security/pam_appl.h>
1402 #endif])
1403
1404 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1405
1406 AC_CHECK_TYPES([fsblkcnt_t],,,[
1407 #include <sys/types.h>
1408 #ifdef HAVE_SYS_BITYPES_H
1409 #include <sys/bitypes.h>
1410 #endif
1411 #ifdef HAVE_SYS_STATFS_H
1412 #include <sys/statfs.h>
1413 #endif
1414 #ifdef HAVE_SYS_STATVFS_H
1415 #include <sys/statvfs.h>
1416 #endif
1417 ])
1418
1419 dnl see what struct stat has for timestamps
1420 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1421
1422 dnl check for curses-lib
1423 AS_IF([test "x$enable_gtx" != "xno"],
1424       [save_LIBS=$LIBS
1425       AC_CHECK_LIB( [ncurses], [setupterm],
1426       [LIB_curses=-lncurses],
1427         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1428           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1429       ])
1430       LIBS=$save_LIBS
1431       AC_SUBST(LIB_curses)])
1432
1433 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1434
1435 if test "$enable_debug_locks" = yes; then
1436         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1437 fi
1438
1439 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1440 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1441         case $AFS_SYSNAME in
1442         sgi_*)
1443                 HAVE_PAM="no"
1444                 ;;
1445         *)
1446                 HAVE_PAM="yes"
1447                 ;;
1448         esac
1449 else
1450         HAVE_PAM="no"
1451 fi
1452 AC_SUBST(HAVE_PAM)
1453
1454 if test "$enable_login" = yes; then
1455         BUILD_LOGIN="yes"
1456 else
1457         BUILD_LOGIN="no"
1458 fi
1459 AC_SUBST(BUILD_LOGIN)
1460
1461 if test "$enable_uss" = yes; then
1462         BUILD_USS="yes"
1463 else
1464         BUILD_USS="no"
1465 fi
1466 AC_SUBST(BUILD_USS)
1467
1468 if test "$enable_kauth" = yes; then
1469         INSTALL_KAUTH="yes"
1470 else
1471         INSTALL_KAUTH="no"
1472 fi
1473 AC_SUBST(INSTALL_KAUTH)
1474
1475 AC_CHECK_FUNCS([ \
1476         arc4random \
1477         fcntl \
1478         fseeko64 \
1479         ftello64 \
1480         getcwd \
1481         getegid \
1482         geteuid \
1483         getgid \
1484         getuid \
1485         getrlimit \
1486         issetugid \
1487         mkstemp \
1488         poll \
1489         pread \
1490         preadv \
1491         preadv64 \
1492         pwrite \
1493         pwritev \
1494         pwritev64 \
1495         regcomp \
1496         regerror \
1497         regexec \
1498         setitimer \
1499         setvbuf \
1500         sigaction \
1501         strcasestr \
1502         strerror \
1503         sysconf \
1504         sysctl \
1505         tdestroy \
1506         timegm \
1507 ])
1508
1509 OPENAFS_ROKEN()
1510 OPENAFS_C_ATTRIBUTE()
1511
1512 dnl Functions that Heimdal's libroken provides, but that we
1513 dnl haven't found a need for yet, and so haven't imported
1514 AC_CHECK_FUNCS([ \
1515         chown \
1516         fchown \
1517         gethostname \
1518         lstat \
1519         inet_aton \
1520         inet_ntop \
1521         inet_pton \
1522         putenv \
1523         readv \
1524         setenv \
1525         strdup \
1526         strftime \
1527         strndup \
1528         strsep \
1529         unsetenv \
1530 ])
1531
1532 dnl Functions that are in objects that we always build from libroken
1533 AC_CHECK_FUNCS([ \
1534         asprintf \
1535         asnprintf \
1536         vasprintf \
1537         vasnprintf \
1538         vsnprintf \
1539         snprintf \
1540 ])
1541
1542 dnl Functions that we're going to try and get from libroken
1543 AC_REPLACE_FUNCS([ \
1544         daemon \
1545         ecalloc \
1546         emalloc \
1547         erealloc \
1548         err \
1549         errx \
1550         flock \
1551         getdtablesize \
1552         getopt \
1553         getprogname \
1554         gettimeofday \
1555         localtime_r \
1556         mkstemp \
1557         setenv \
1558         setprogname \
1559         strcasecmp \
1560         strlcat \
1561         strnlen \
1562         strlcpy \
1563         strsep \
1564         tdelete \
1565         tfind \
1566         tsearch \
1567         twalk \
1568         unsetenv \
1569         verr \
1570         verrx \
1571         vsyslog \
1572         vwarn \
1573         vwarnx \
1574         warn \
1575         warnx \
1576 ])
1577
1578 dnl Headers that we're going to try and get from libroken
1579 AC_CHECK_HEADERS([ \
1580         err.h \
1581         search.h \
1582 ])
1583
1584 AC_CHECK_DECLS([h_errno], [], [], [
1585 #include <sys/types.h>
1586 #ifdef HAVE_NETDB_H
1587 #include <netdb.h>
1588 #endif
1589 ])
1590
1591 AC_HEADER_TIME
1592
1593 ROKEN_HEADERS=
1594 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1595       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1596       [])
1597 AC_SUBST(ROKEN_HEADERS)
1598
1599 dnl Stuff that's harder ...
1600 AC_MSG_CHECKING([for bswap16])
1601 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1602 #ifdef HAVE_SYS_TYPES_H
1603 #include <sys/types.h>
1604 #endif
1605 #ifdef HAVE_SYS_BSWAP_H
1606 #include <sys/bswap.h>
1607 #endif
1608 ],
1609 [short a, b; b = bswap16(a); ])],
1610 [AC_MSG_RESULT(yes)
1611  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1612 ],
1613 [AC_MSG_RESULT(no)])
1614
1615 AC_MSG_CHECKING([for bswap32])
1616 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1617 #include <sys/types.h>
1618 #endif
1619 #ifdef HAVE_SYS_BSWAP_H
1620 #include <sys/bswap.h>
1621 #endif
1622 ],
1623 [int a, b; b = bswap32(a); ])],
1624 [AC_MSG_RESULT(yes)
1625  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1626 ],
1627 [AC_MSG_RESULT(no)])
1628
1629 case $AFS_SYSNAME in
1630 *hp_ux* | *hpux*)
1631    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1632    ;;
1633 *)
1634    AC_MSG_CHECKING([for positional I/O])
1635    if test "$ac_cv_func_pread" = "yes" && \
1636            test "$ac_cv_func_pwrite" = "yes"; then
1637       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1638       AC_MSG_RESULT(yes)
1639    else
1640      AC_MSG_RESULT(no)
1641    fi
1642    AC_MSG_CHECKING([for vectored positional I/O])
1643    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1644                "$ac_cv_func_pwritev" = "yes" -a \
1645                "$ac_cv_func_preadv64" = "yes" -a \
1646                "$ac_cv_func_pwritev64" = "yes"],
1647          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1648           AC_MSG_RESULT(yes)],
1649          [AC_MSG_RESULT(no)])
1650    ;;
1651 esac
1652
1653 AC_MSG_CHECKING([for POSIX regex library])
1654 if test "$ac_cv_header_regex_h" = "yes" && \
1655         test "$ac_cv_func_regcomp" = "yes" && \
1656         test "$ac_cv_func_regexec" = "yes" && \
1657         test "$ac_cv_func_regerror" = "yes"; then
1658     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1659     AC_MSG_RESULT(yes)
1660 else
1661     AC_MSG_RESULT(no)
1662 fi
1663
1664 dnl Look for "non-portable" pthreads functions.
1665 save_LIBS="$LIBS"
1666 LIBS="$LIBS $PTHREAD_LIBS"
1667 AC_CHECK_FUNCS([ \
1668         pthread_set_name_np \
1669         pthread_setname_np \
1670 ])
1671
1672 dnl Sadly, there are three different versions of pthread_setname_np.
1673 dnl Try to cater for all of them.
1674 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1675     AC_MSG_CHECKING([for signature of pthread_setname_np])
1676     AC_TRY_COMPILE([
1677 #include <pthread.h>
1678 #ifdef HAVE_PTHREAD_NP_H
1679 #include <pthread_np.h>
1680 #endif
1681 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1682         AC_MSG_RESULT([three arguments])
1683         pthread_setname_np_args=3], [
1684         AC_TRY_COMPILE([
1685 #include <pthread.h>
1686 #ifdef HAVE_PTHREAD_NP_H
1687 #include <pthread_np.h>
1688 #endif
1689 ], [pthread_setname_np(pthread_self(), "test")], [
1690             AC_MSG_RESULT([two arguments])
1691             pthread_setname_np_args=2], [
1692             AC_TRY_COMPILE([
1693 #include <pthread.h>
1694 #ifdef HAVE_PTHREAD_NP_H
1695 #include <pthread_np.h>
1696 #endif
1697 ], [pthread_setname_np("test")], [
1698                 AC_MSG_RESULT([one argument])
1699                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1700 ])
1701 ])
1702 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1703 fi
1704 LIBS="$save_LIBS"
1705
1706 openafs_cv_saved_CFLAGS="$CFLAGS"
1707 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1708
1709 AC_TYPE_SIGNAL
1710 OPENAFS_RETSIGTYPE
1711 AC_CHECK_SIZEOF(void *)
1712 AC_CHECK_SIZEOF(unsigned long long)
1713 AC_CHECK_SIZEOF(unsigned long)
1714 AC_CHECK_SIZEOF(unsigned int)
1715 AC_TYPE_INTPTR_T
1716 AC_TYPE_UINTPTR_T
1717 AC_TYPE_SSIZE_T
1718 AC_CHECK_TYPE([sig_atomic_t],[],
1719     [AC_DEFINE([sig_atomic_t], [int],
1720         [Define to int if <signal.h> does not define.])],
1721 [#include <sys/types.h>
1722 #include <signal.h>])
1723 AC_CHECK_TYPE([socklen_t],[],
1724     [AC_DEFINE([socklen_t], [int],
1725         [Define to int if <sys/socket.h> does not define.])],
1726 [#include <sys/types.h>
1727 #include <sys/socket.h>])
1728 AC_CHECK_TYPES(off64_t)
1729 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1730 AC_CHECK_TYPES([struct winsize], [], [], [
1731 #ifdef HAVE_TERMIOS_H
1732 # include <termios.h>
1733 #else
1734 # include <sys/termios.h>
1735 #endif
1736 #include <sys/ioctl.h>])
1737 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1738                 struct sockaddr_storage],
1739                [], [], [
1740 #include <sys/types.h>
1741 #include <sys/socket.h>
1742 ])
1743 AC_CHECK_TYPES([sa_family_t], [], [], [
1744 #include <sys/types.h>
1745 #include <sys/socket.h>
1746 ])
1747 AC_CHECK_TYPES([struct addrinfo], [], [], [
1748 #include <sys/types.h>
1749 #ifdef HAVE_NETDB_H
1750 #include <netdb.h>
1751 #endif
1752 ])
1753 AC_CHECK_TYPES([long long], [], [], [])
1754
1755 AC_SIZEOF_TYPE(long)
1756
1757 CFLAGS="$openafs_cv_saved_CFLAGS"
1758
1759 RRA_HEADER_PAM_CONST
1760
1761
1762 dnl Directory PATH handling
1763 if test "x$enable_transarc_paths" = "xyes"  ; then
1764     afsconfdir=${afsconfdir=/usr/afs/etc}
1765     viceetcdir=${viceetcdir=/usr/vice/etc}
1766     afskerneldir=${afskerneldir=${viceetcdir}}
1767     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1768     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1769     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1770     afsdbdir=${afsdbdir=/usr/afs/db}
1771     afslogsdir=${afslogsdir=/usr/afs/logs}
1772     afslocaldir=${afslocaldir=/usr/afs/local}
1773     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1774     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1775     afsdatadir=${afsdatadir=/usr/vice/etc}
1776 else
1777     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1778     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1779     afskerneldir=${afskerneldir='${libdir}/openafs'}
1780     afssrvbindir=${afssrvbindir='${bindir}'}
1781     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1782     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1783     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1784     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1785     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1786     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1787     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1788     afsdatadir=${afsdatadir='${datadir}/openafs'}
1789 fi
1790 AC_SUBST(afsconfdir)
1791 AC_SUBST(viceetcdir)
1792 AC_SUBST(afskerneldir)
1793 AC_SUBST(afssrvbindir)
1794 AC_SUBST(afssrvsbindir)
1795 AC_SUBST(afssrvlibexecdir)
1796 AC_SUBST(afsdbdir)
1797 AC_SUBST(afslogsdir)
1798 AC_SUBST(afslocaldir)
1799 AC_SUBST(afsbackupdir)
1800 AC_SUBST(afsbosconfigdir)
1801 AC_SUBST(afsdatadir)
1802
1803 if test "x$enable_kernel_module" = "xyes"; then
1804 ENABLE_KERNEL_MODULE=libafs
1805 fi
1806
1807 if test "x$enable_pthreaded_ubik" = "xyes"; then
1808 ENABLE_PTHREADED_UBIK=yes
1809 fi
1810
1811 AC_SUBST(VFSCK)
1812 AC_SUBST(AFS_SYSNAME)
1813 AC_SUBST(AFS_PARAM_COMMON)
1814 AC_SUBST(ENABLE_KERNEL_MODULE)
1815 AC_SUBST(ENABLE_PTHREADED_UBIK)
1816 AC_SUBST(LIB_AFSDB)
1817 AC_SUBST(LINUX_KERNEL_PATH)
1818 AC_SUBST(LINUX_KERNEL_BUILD)
1819 AC_SUBST(HOST_CPU)
1820 AC_SUBST(BSD_KERNEL_PATH)
1821 AC_SUBST(BSD_KERNEL_BUILD)
1822 AC_SUBST(LINUX_VERSION)
1823 AC_SUBST(MKAFS_OSTYPE)
1824 AC_SUBST(TOP_OBJDIR)
1825 AC_SUBST(TOP_SRCDIR)
1826 AC_SUBST(TOP_INCDIR)
1827 AC_SUBST(TOP_LIBDIR)
1828 AC_SUBST(DEST)
1829 AC_SUBST(DARWIN_INFOFILE)
1830 AC_SUBST(IRIX_BUILD_IP35)
1831 AC_SUBST(HTML_XSL)
1832 AC_SUBST(XSLTPROC)
1833 AC_SUBST(DOCBOOK2PDF)
1834 AC_SUBST(DOCBOOK_STYLESHEETS)
1835
1836 OPENAFS_FUSE
1837 OPENAFS_SWIG
1838
1839 TOP_SRCDIR="${srcdir}/src"
1840 dnl
1841 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1842 dnl
1843 case $TOP_SRCDIR in
1844         /*)
1845                 ;;
1846         *)
1847                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1848                 ;;
1849 esac
1850
1851 TOP_OBJDIR="${SRCDIR_PARENT}"
1852 TOP_INCDIR="${SRCDIR_PARENT}/include"
1853 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1854 if test "${DEST}x" = "x"; then
1855         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1856 fi
1857
1858 if test "x$with_crosstools_dir" != "x"; then
1859         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1860                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1861                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1862                 RXGEN_PATH=$with_crosstools_dir/rxgen
1863         else
1864                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1865                 exit 1
1866         fi
1867 else
1868         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1869         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1870         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1871 fi
1872 AC_SUBST(COMPILE_ET_PATH)
1873 AC_SUBST(CONFIGTOOL_PATH)
1874 AC_SUBST(RXGEN_PATH)
1875
1876 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1877 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1878 AC_SUBST(HELPER_SPLINT)
1879 AC_SUBST(HELPER_SPLINTCFG)
1880
1881 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1882
1883 dnl Check to see if crypt lives in a different library
1884 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1885 AC_SUBST(LIB_crypt)
1886
1887 dnl Check to see if the compiler support labels in structs
1888 AC_MSG_CHECKING(for label support in structs)
1889 AC_TRY_COMPILE([], [
1890 extern void osi_UFSOpen(void);
1891 struct labeltest {
1892    void (*open) (void);
1893 };
1894 struct labeltest struct_labeltest = {
1895    .open       = osi_UFSOpen,
1896 }
1897 ],
1898 [AC_MSG_RESULT(yes)
1899  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1900 ],
1901 [AC_MSG_RESULT(no)
1902 ])
1903
1904 AC_MSG_CHECKING([checking for dirfd])
1905 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1906 #ifdef HAVE_DIRENT_H
1907 #include <dirent.h>
1908 #endif
1909 ]],
1910         [[DIR *d = 0; dirfd(d);]])],
1911         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1912 if test "$ac_rk_have_dirfd" = "yes" ; then
1913         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1914 fi
1915 AC_MSG_RESULT($ac_rk_have_dirfd)
1916
1917 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1918 #ifdef HAVE_DIRENT_H
1919 #include <dirent.h>
1920 #endif])
1921
1922 dnl Eventually, this will look for the system one, or for OpenSSL
1923 LIB_hcrypto="-lafshcrypto"
1924 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1925 AC_SUBST(LIB_hcrypto)
1926 AC_SUBST(LDFLAGS_hcrypto)
1927
1928 dnl Check for UUID library
1929 AC_CHECK_HEADERS([uuid/uuid.h])
1930 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1931 AC_CHECK_FUNCS([uuid_generate])
1932 ])
1933
1934
1935 AC_DEFUN([SUMMARY], [
1936     # Print a configuration summary
1937 echo
1938 echo "**************************************"
1939 echo configure summary
1940 echo
1941 AS_IF([test $LIB_curses],[
1942 echo "LIB_curses :                $LIB_curses" ],[
1943 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1944 ])
1945 echo
1946 echo "**************************************"
1947 ])