Linux 4.5: get_link instead of follow_link+put_link
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #    define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 # define _FILE_OFFSET_BITS 64
48 # define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 # include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])
76 ])
77
78 dnl General feature options.
79 AC_ARG_ENABLE([namei-fileserver],
80     [AS_HELP_STRING([--enable-namei-fileserver],
81         [force compilation of namei fileserver in preference to inode
82          fileserver])],
83     [],
84     [enable_namei_fileserver="default"])
85 AC_ARG_ENABLE([supergroups],
86     [AS_HELP_STRING([--enable-supergroups],
87         [enable support for nested pts groups])],
88     [],
89     [enable_supergroups="no"])
90 AC_ARG_ENABLE([bitmap-later],
91     [AS_HELP_STRING([--enable-bitmap-later],
92         [enable fast startup of file server by not reading bitmap till
93          needed])],
94     [AS_IF([test x"$withval" = xyes],
95         [AC_MSG_WARN([bitmap-later is only used by non-demand-attach
96             fileservers.  Please migrate to demand-attach instead.])])],
97     [enable_bitmap_later="no"])
98 AC_ARG_ENABLE([unix-sockets],
99     [AS_HELP_STRING([--disable-unix-sockets],
100         [disable use of unix domain sockets for fssync (defaults to enabled)])],
101     [],
102     [enable_unix_sockets="yes"])
103 AC_ARG_ENABLE([tivoli-tsm],
104     [AS_HELP_STRING([--enable-tivoli-tsm],
105         [enable use of the Tivoli TSM API libraries for butc support])],
106     [],
107     [enable_tivoli_tsm="no"])
108 AC_ARG_ENABLE([pthreaded-ubik],
109     [AS_HELP_STRING([--disable-pthreaded-ubik],
110         [disable installation of pthreaded ubik applications (defaults to
111          enabled)])],
112     [],
113     [enable_pthreaded_ubik="yes"])
114
115 dnl Kernel module build options.
116 AC_ARG_WITH([linux-kernel-headers],
117     [AS_HELP_STRING([--with-linux-kernel-headers=path],
118         [use the kernel headers found at path (optional, defaults to
119          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
120          then /usr/src/linux-2.4, and lastly /usr/src/linux)])
121 ])
122 AC_ARG_WITH([linux-kernel-build],
123     [AS_HELP_STRING([--with-linux-kernel-build=path],
124         [use the kernel build found at path(optional, defaults to
125         kernel headers path)]
126 )])
127 AC_ARG_WITH([bsd-kernel-headers],
128     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
129         [use the kernel headers found at path (optional, defaults to
130          /usr/src/sys)])
131 ])
132 AC_ARG_WITH([bsd-kernel-build],
133     [AS_HELP_STRING([--with-bsd-kernel-build=path],
134         [use the kernel build found at path (optional, defaults to
135          KSRC/i386/compile/GENERIC)])
136 ])
137 AC_ARG_WITH([linux-kernel-packaging],
138     [AS_HELP_STRING([--with-linux-kernel-packaging],
139         [use standard naming conventions to aid Linux kernel build packaging
140          (disables MPS, sets the kernel module name to openafs.ko, and
141          installs kernel modules into the standard Linux location)])],
142     [AC_SUBST([LINUX_KERNEL_PACKAGING], [yes])
143      AC_SUBST([LINUX_LIBAFS_NAME], [openafs])],
144     [AC_SUBST([LINUX_LIBAFS_NAME], [libafs])
145 ])
146 AC_ARG_ENABLE([kernel-module],
147     [AS_HELP_STRING([--disable-kernel-module],
148         [disable compilation of the kernel module (defaults to enabled)])],
149     [],
150     [enable_kernel_module="yes"])
151 AC_ARG_ENABLE([redhat-buildsys],
152     [AS_HELP_STRING([--enable-redhat-buildsys],
153         [enable compilation of the redhat build system kernel (defaults to
154          disabled)])],
155     [],
156     [enable_redhat_buildsys="no"])
157
158 dnl Installation locations.
159 AC_ARG_ENABLE([transarc-paths],
160     [AS_HELP_STRING([--enable-transarc-paths],
161         [use Transarc style paths like /usr/afs and /usr/vice])],
162     [],
163     [enable_transarc_paths="no"])
164
165 dnl Deprecated crypto
166 AC_ARG_ENABLE([kauth],
167     [AS_HELP_STRING([--enable-kauth],
168         [install the deprecated kauth server, pam modules, and utilities
169          (defaults to disabled)])],
170     [enable_pam="yes"],
171     [enable_kauth="no"
172      enable_pam="no"])
173
174 dnl Optimization and debugging flags.
175 AC_ARG_ENABLE([strip-binaries],
176     [AS_HELP_STRING([--disable-strip-binaries],
177         [disable stripping of symbol information from binaries (defaults to
178          enabled)])],
179     [],
180     [enable_strip_binaries="maybe"])
181 AC_ARG_ENABLE([debug],
182     [AS_HELP_STRING([--enable-debug],
183         [enable compilation of the user space code with debugging information
184          (defaults to disabled)])],
185     [],
186     [enable_debug="no"])
187 AC_ARG_ENABLE([optimize],
188     [AS_HELP_STRING([--disable-optimize],
189         [disable optimization for compilation of the user space code (defaults
190          to enabled)])],
191     [],
192     [enable_optimize="yes"])
193 AC_ARG_ENABLE([warnings],
194     [AS_HELP_STRING([--enable-warnings],
195         [enable compilation warnings when building with gcc (defaults to
196          disabled)])],
197     [],
198     [enable_warnings="no"])
199 AC_ARG_ENABLE([checking],
200     [AS_HELP_STRING([--enable-checking],
201         [turn compilation warnings into errors when building with gcc (defaults
202          to disabled)])],
203     [enable_checking="$enableval"],
204     [enable_checking="no"])
205 AC_ARG_ENABLE([debug-locks],
206     [AS_HELP_STRING([--enable-debug-locks],
207         [turn on lock debugging assertions (defaults to disabled)])],
208     [enable_debug_locks="$enableval"],
209     [enable_debug_locks="no"])
210 AC_ARG_ENABLE([debug-kernel],
211     [AS_HELP_STRING([--enable-debug-kernel],
212         [enable compilation of the kernel module with debugging information
213          (defaults to disabled)])],
214     [],
215     [enable_debug_kernel="no"])
216 AC_ARG_ENABLE([optimize-kernel],
217     [AS_HELP_STRING([--disable-optimize-kernel],
218         [disable compilation of the kernel module with optimization (defaults
219          based on platform)])],
220     [],
221     [enable_optimize_kernel=""])
222 AC_ARG_ENABLE([debug-lwp],
223     [AS_HELP_STRING([--enable-debug-lwp],
224         [enable compilation of the LWP code with debugging information
225          (defaults to disabled)])],
226     [],
227     [enable_debug_lwp="no"])
228 AC_ARG_ENABLE([optimize-lwp],
229     [AS_HELP_STRING([--disable-optimize-lwp],
230         [disable optimization for compilation of the LWP code (defaults to
231          enabled)])],
232     [],
233     [enable_optimize_lwp="yes"])
234 AC_ARG_ENABLE([debug-pam],
235     [AS_HELP_STRING([--enable-debug-pam],
236         [enable compilation of the PAM code with debugging information
237          (defaults to disabled)])],
238     [],
239     [enable_debug_pam="no"])
240 AC_ARG_ENABLE([optimize-pam],
241     [AS_HELP_STRING([--disable-optimize-pam],
242         [disable optimization for compilation of the PAM code (defaults to
243          enabled)])],
244     [],
245     [enable_optimize_pam="yes"])
246 AC_ARG_ENABLE([linux-syscall-probing],
247     [AS_HELP_STRING([--enable-linux-syscall-probing],
248         [enable Linux syscall probing (defaults to autodetect)])],
249     [],
250     [enable_linux_syscall_probing="maybe"])
251 AC_ARG_ENABLE([linux-d_splice_alias-extra-iput],
252     [AS_HELP_STRING([--enable-linux-d_splice_alias-extra-iput],
253         [Linux kernels in the 3.17 series prior to 3.17.3 had a bug
254          wherein error returns from the d_splice_alias() function were
255          leaking a reference on the inode.  The bug was fixed for the
256          3.17.3 kernel, and the possibility of an error return was only
257          introduced in kernel 3.17, so only the narrow range of kernels
258          is affected.  Enable this option for builds on systems with
259          kernels affected by this bug, to manually release the reference
260          on error returns and correct the reference counting.
261          Linux commit 51486b900ee92856b977eacfc5bfbe6565028070 (or
262          equivalent) is the fix for the upstream bug, so if such a commit
263          is present, leave this option disabled.  We apologize
264          that you are required to know this about your running kernel,
265          but luckily only a narrow range of versions is affected.])],
266     [],
267     [enable_linux_d_splice_alias_extra_iput="no"])
268 AC_ARG_WITH([crosstools-dir],
269     [AS_HELP_STRING([--with-crosstools-dir=path],
270         [use path for native versions of rxgen, compile_et and config])
271 ])
272
273 AC_ARG_WITH([xslt-processor],
274         AS_HELP_STRING([--with-xslt-processor=ARG],
275         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
276         [XSLTPROC="$withval"],
277         [AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo])])
278
279 AC_ARG_WITH([html-xsl],
280         AS_HELP_STRING([--with-html-xsl],
281         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
282         [HTML_XSL="$withval"],
283         [HTML_XSL="html/chunk.xsl"])
284
285 AC_ARG_WITH([docbook2pdf],
286         AS_HELP_STRING([--with-docbook2pdf=ARG],
287         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
288         [DOCBOOK2PDF="$withval"],
289         [AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo])])
290
291 AC_ARG_WITH([docbook-stylesheets],
292         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
293         [location of DocBook stylesheets (default is to search a set of likely paths)]),
294         [DOCBOOK_STYLESHEETS="$withval"],
295         [OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS],
296                 [/usr/share/xml/docbook/stylesheet/nwalsh/current \
297                  /usr/share/xml/docbook/stylesheet/nwalsh \
298                  /usr/share/xml/docbook/xsl-stylesheets \
299                  /usr/share/sgml/docbook/docbook-xsl-stylesheets \
300                  /usr/share/sgml/docbook/xsl-stylesheets \
301                  /usr/share/docbook-xsl \
302                  /usr/share/sgml/docbkxsl \
303                  /usr/local/share/xsl/docbook \
304                  /sw/share/xml/xsl/docbook-xsl \
305                  /opt/local/share/xsl/docbook-xsl],
306                 [$HTML_XSL])
307            AS_IF([test "x$DOCBOOK_STYLESHEETS" = "x"],
308                 [AC_WARN([Docbook stylesheets not found; some documentation can't be built])
309            ])
310         ])
311
312 AC_ARG_WITH([dot],
313         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
314         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
315         [], [with_dot="maybe"])
316
317 enable_login="no"
318
319 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
320 dnl documentation build.
321 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
322 AC_CHECK_PROGS([DOXYGEN], [doxygen])
323
324 dnl Optionally generate graphs with doxygen.
325 case "$with_dot" in
326 maybe)
327     AC_CHECK_PROGS([DOT], [dot])
328     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
329     ;;
330 yes)
331     HAVE_DOT="yes"
332     ;;
333 no)
334     HAVE_DOT="no"
335     ;;
336 *)
337     HAVE_DOT="yes"
338     DOT_PATH=$with_dot
339 esac
340 AC_SUBST(HAVE_DOT)
341 AC_SUBST(DOT_PATH)
342
343 dnl Checks for UNIX variants.
344 AC_ISC_POSIX
345
346 dnl Various compiler setup.
347 AC_TYPE_PID_T
348 AC_TYPE_SIZE_T
349
350 dnl Checks for programs.
351 AC_PROG_INSTALL
352 AC_PROG_LN_S
353 AC_PROG_RANLIB
354 AC_PROG_YACC
355 AM_PROG_LEX
356 dnl if we are flex, be lex-compatible
357 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
358
359 OPENAFS_FORCE_ABS_INSTALL
360 OPENAFS_CHECK_BIGENDIAN
361 OPENAFS_PRINTF_TAKES_Z_LEN
362
363 AC_MSG_CHECKING(your OS)
364 system=$host
365 case $system in
366         *-linux*)
367
368                 MKAFS_OSTYPE=LINUX
369                 if test "x$enable_redhat_buildsys" = "xyes"; then
370                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
371                 fi
372                 if test "x$enable_kernel_module" = "xyes"; then
373                  if test "x$with_linux_kernel_headers" != "x"; then
374                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
375                  else
376                    for utsdir in "/lib/modules/`uname -r`/build" \
377                                  "/lib/modules/`uname -r`/source" \
378                                  "/usr/src/linux-2.4" \
379                                  "/usr/src/linux"; do
380                      LINUX_KERNEL_PATH="$utsdir"
381                      for utsfile in "include/generated/utsrelease.h" \
382                                     "include/linux/utsrelease.h" \
383                                     "include/linux/version.h" \
384                                     "include/linux/version-up.h"; do
385                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
386                          break 2
387                        fi
388                      done
389                    done
390                  fi
391                  if test "x$with_linux_kernel_build" != "x"; then
392                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
393                  else
394                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
395                  fi
396                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
397                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
398                    LINUX_VERSION="$linux_kvers"
399                  else
400                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
401                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
402                      LINUX_VERSION="$linux_kvers"
403                    else
404                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
405                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
406                        if test "x$linux_kvers" = "x"; then
407                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
408                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
409                            if test "x$linux_kvers" = "x"; then
410                              AC_MSG_ERROR(Linux headers lack version definition [2])
411                              exit 1
412                            else
413                              LINUX_VERSION="$linux_kvers"
414                            fi
415                          else
416                            AC_MSG_ERROR(Linux headers lack version definition)
417                            exit 1
418                          fi
419                        else
420                          LINUX_VERSION="$linux_kvers"
421                        fi
422                      else
423                        enable_kernel_module="no"
424                      fi
425                    fi
426                  fi
427                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
428                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
429                      enable_kernel_module="no"
430                  fi
431                  if test "x$enable_kernel_module" = "xno"; then
432                   if test "x$with_linux_kernel_headers" != "x"; then
433                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
434                    exit 1
435                   else
436                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
437                   fi
438                  fi
439                  dnl do we need to determine SUBARCH from autoconf.h
440                  SUBARCH=default
441                 fi
442                 AC_MSG_RESULT(linux)
443                 GUESS_LINUX_VERSION=
444                 if test "x$enable_kernel_module" = "xyes"; then
445                  GUESS_LINUX_VERSION=${LINUX_VERSION}
446                 else
447                  GUESS_LINUX_VERSION=`uname -r`
448                 fi
449                 case "$GUESS_LINUX_VERSION" in
450                   2.2.*) AFS_SYSKVERS=22 ;;
451                   2.4.*) AFS_SYSKVERS=24 ;;
452                   [2.6.* | [3-9]* | [1-2][0-9]*]) AFS_SYSKVERS=26 ;;
453                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
454                 esac
455                 ;;
456         *-solaris*)
457                 MKAFS_OSTYPE=SOLARIS
458                 AC_MSG_RESULT(sun4)
459                 AC_PATH_PROG(SOLARISCC, [cc], ,
460                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
461                 if test "x$SOLARISCC" = "x" ; then
462                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
463                 fi
464                 SOLARIS_UFSVFS_HAS_DQRWLOCK
465                 SOLARIS_FS_HAS_FS_ROLLED
466                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
467                 SOLARIS_HAVE_VN_RENAMEPATH
468                 ;;
469         *-sunos*)
470                 MKAFS_OSTYPE=SUNOS
471                 enable_kernel_module=no
472                 AC_MSG_RESULT(sun4)
473                 ;;
474         *-hpux*)
475                 MKAFS_OSTYPE=HPUX
476                 AC_MSG_RESULT(hp_ux)
477                 if test -f "/usr/old/usr/include/ndir.h"; then
478                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
479                 fi
480                 ;;
481         *-irix*)
482                 if test -d /usr/include/sys/SN/SN1; then
483                  IRIX_BUILD_IP35="IP35"
484                 fi
485                 MKAFS_OSTYPE=IRIX
486                 AC_MSG_RESULT(sgi)
487                 ;;
488         *-aix*)
489                 MKAFS_OSTYPE=AIX
490                 AC_MSG_RESULT(rs_aix)
491                 ;;
492         arm-*-darwin*)
493                 MKAFS_OSTYPE=DARWIN
494                 AC_MSG_RESULT(arm_darwin)
495                 ;;
496         powerpc-*-darwin*)
497                 MKAFS_OSTYPE=DARWIN
498                 AC_MSG_RESULT(ppc_darwin)
499                 ;;
500         i386-*-darwin*)
501                 MKAFS_OSTYPE=DARWIN
502                 AC_MSG_RESULT(x86_darwin)
503                 ;;
504         x86_64-*-darwin*)
505                 MKAFS_OSTYPE=DARWIN
506                 AC_MSG_RESULT(x86_darwin)
507                 ;;
508         i386-*-freebsd*)
509                 MKAFS_OSTYPE=FBSD
510                 AC_MSG_RESULT(i386_fbsd)
511                 ;;
512         x86_64-*-freebsd*)
513                 MKAFS_OSTYPE=FBSD
514                 AC_MSG_RESULT(amd64_fbsd)
515                 ;;
516         *-netbsd*)
517                 MKAFS_OSTYPE=NBSD
518                 AC_MSG_RESULT(nbsd)
519                 ;;
520         x86_64-*-openbsd*)
521                 MKAFS_OSTYPE=OBSD
522                 AC_MSG_RESULT(amd64_obsd)
523                 ;;
524         i386-*-openbsd*)
525                 MKAFS_OSTYPE=OBSD
526                 AC_MSG_RESULT(i386_obsd)
527                 ;;
528         *-dragonfly*)
529                 MKAFS_OSTYPE=DFBSD
530                 AC_MSG_RESULT(i386_dfbsd)
531                 ;;
532         *)
533                 AC_MSG_RESULT($system)
534                 ;;
535 esac
536
537 if test "x$with_afs_sysname" != "x"; then
538         AFS_SYSNAME="$with_afs_sysname"
539 else
540         AC_MSG_CHECKING(your AFS sysname)
541         case $host in
542                 i?86-*-openbsd?.?)
543                         v=${host#*openbsd}
544                         vM=${v%.*}
545                         vm=${v#*.}
546                         AFS_SYSNAME="i386_obsd${vM}${vm}"
547                         ;;
548                 sparc64-*-openbsd?.?)
549                         v=${host#*openbsd}
550                         vM=${v%.*}
551                         vm=${v#*.}
552                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
553                         ;;
554                 x86_64-*-openbsd?.?)
555                         v=${host#*openbsd}
556                         vM=${v%.*}
557                         vm=${v#*.}
558                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
559                         ;;
560                 i?86-*-freebsd*.*)
561                         v=${host#*freebsd}
562                         vM=${v%.*}
563                         vm=${v#*.}
564                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
565                         ;;
566                 x86_64-*-freebsd*.*)
567                         v=${host#*freebsd}
568                         vM=${v%.*}
569                         vm=${v#*.}
570                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
571                         ;;
572                 i386-*-dragonfly?.*)
573                         v=${host#*dragonfly}
574                         vM=${v%.*}
575                         vm=${v#*.}
576                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
577                         ;;
578                 i?86-*-netbsd*1.6[[M-Z]]*)
579                         AFS_SYSNAME="i386_nbsd20"
580                         ;;
581                 powerpc-*-netbsd*1.6[[M-Z]]*)
582                         AFS_SYSNAME="ppc_nbsd20"
583                         ;;
584                 *-*-netbsd*)
585                         arch=${host%%-unknown*}
586                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
587                                                -e 's/powerpc/ppc/g')
588                         v=${host#*netbsd}
589                         v=${v#*aout}
590                         v=${v#*ecoff}
591                         v=${v#*elf}
592                         vM=${v%%.*}
593                         vM=${vM%.*}
594                         v=${v#*.}
595                         vm=${v%%.*}
596                         vm=${vm%.*}
597                         vm=${vm%%[[_A-Z]]*}
598                         if test $vm -eq 99 ; then
599                                 vM=$((vM+1))
600                         fi
601                         if test $vM -gt 1 ; then
602                                 vm=0
603                         fi
604                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
605                         ;;
606                 hppa*-hp-hpux11.0*)
607                         AFS_SYSNAME="hp_ux110"
608                         ;;
609                 hppa*-hp-hpux11.11)
610                         AFS_SYSNAME="hp_ux11i"
611                         ;;
612                 hppa*-hp-hpux11.23)
613                         AFS_SYSNAME="hp_ux1123"
614                         ;;
615                 ia64-hp-hpux11.22)
616                         AFS_SYSNAME="ia64_hpux1122"
617                         ;;
618                 ia64-hp-hpux*)
619                         AFS_SYSNAME="ia64_hpux1123"
620                         ;;
621                 hppa*-hp-hpux10*)
622                         AFS_SYSNAME="hp_ux102"
623                         ;;
624                 powerpc-apple-darwin7*)
625                         AFS_SYSNAME="ppc_darwin_70"
626                         OSXSDK="macosx10.3"
627                         ;;
628                 powerpc-apple-darwin8.*)
629                         AFS_SYSNAME="ppc_darwin_80"
630                         OSXSDK="macosx10.4"
631                         ;;
632                 i386-apple-darwin8.*)
633                         AFS_SYSNAME="x86_darwin_80"
634                         OSXSDK="macosx10.4"
635                         ;;
636                 powerpc-apple-darwin9.*)
637                         AFS_SYSNAME="ppc_darwin_90"
638                         OSXSDK="macosx10.5"
639                         ;;
640                 i386-apple-darwin9.*)
641                         AFS_SYSNAME="x86_darwin_90"
642                         OSXSDK="macosx10.5"
643                         ;;
644                 i?86-apple-darwin10.*)
645                         AFS_SYSNAME="x86_darwin_100"
646                         OSXSDK="macosx10.6"
647                         ;;
648                 x86_64-apple-darwin10.*)
649                         AFS_SYSNAME="x86_darwin_100"
650                         OSXSDK="macosx10.6"
651                         ;;
652                 arm-apple-darwin10.*)
653                         AFS_SYSNAME="arm_darwin_100"
654                         OSXSDK="iphoneos4.0"
655                         ;;
656                 x86_64-apple-darwin11.*)
657                         AFS_SYSNAME="x86_darwin_110"
658                         OSXSDK="macosx10.7"
659                         ;;
660                 i?86-apple-darwin11.*)
661                         AFS_SYSNAME="x86_darwin_110"
662                         OSXSDK="macosx10.7"
663                         ;;
664                 x86_64-apple-darwin12.*)
665                         AFS_SYSNAME="x86_darwin_120"
666                         OSXSDK="macosx10.8"
667                         ;;
668                 i?86-apple-darwin12.*)
669                         AFS_SYSNAME="x86_darwin_120"
670                         OSXSDK="macosx10.8"
671                         ;;
672                 x86_64-apple-darwin13.*)
673                         AFS_SYSNAME="x86_darwin_130"
674                         OSXSDK="macosx10.9"
675                         ;;
676                 i?86-apple-darwin13.*)
677                         AFS_SYSNAME="x86_darwin_130"
678                         OSXSDK="macosx10.9"
679                         ;;
680                 x86_64-apple-darwin14.*)
681                         AFS_SYSNAME="x86_darwin_140"
682                         OSXSDK="macosx10.10"
683                         ;;
684                 i?86-apple-darwin14.*)
685                         AFS_SYSNAME="x86_darwin_140"
686                         OSXSDK="macosx10.10"
687                         ;;
688                 x86_64-apple-darwin15.*)
689                         AFS_SYSNAME="x86_darwin_150"
690                         OSXSDK="macosx10.11"
691                         ;;
692                 i?86-apple-darwin15.*)
693                         AFS_SYSNAME="x86_darwin_150"
694                         OSXSDK="macosx10.11"
695                         ;;
696                 sparc-sun-solaris2.8)
697                         AFS_SYSNAME="sun4x_58"
698                         ;;
699                 sparc-sun-solaris2.9)
700                         AFS_SYSNAME="sun4x_59"
701                         ;;
702                 sparc-sun-solaris2.10)
703                         AFS_SYSNAME="sun4x_510"
704                         ;;
705                 sparc-sun-solaris2.11)
706                         AFS_SYSNAME="sun4x_511"
707                         ;;
708                 i386-pc-solaris2.8)
709                         AFS_SYSNAME="sunx86_58"
710                         ;;
711                 i386-pc-solaris2.9)
712                         AFS_SYSNAME="sunx86_59"
713                         ;;
714                 i386-pc-solaris2.10)
715                         AFS_SYSNAME="sunx86_510"
716                         ;;
717                 i386-pc-solaris2.11)
718                         AFS_SYSNAME="sunx86_511"
719                         ;;
720                 alpha*-dec-osf4.0*)
721                         AFS_SYSNAME="alpha_dux40"
722                         ;;
723                 alpha*-dec-osf5.0*)
724                         AFS_SYSNAME="alpha_dux50"
725                         ;;
726                 alpha*-dec-osf5.1*)
727                         AFS_SYSNAME="alpha_dux51"
728                         ;;
729                 mips-sgi-irix6.5)
730                         AFS_SYSNAME="sgi_65"
731                         enable_pam="no"
732                         ;;
733                 ia64-*-linux*)
734                         AFS_SYSNAME="ia64_linuxXX"
735                         ;;
736                 powerpc-*-linux*)
737                         AFS_SYSNAME="`/bin/arch`_linuxXX"
738                         ;;
739                 powerpc64-*-linux*)
740                         AFS_SYSNAME="ppc64_linuxXX"
741                         ;;
742                 alpha*-linux*)
743                         AFS_SYSNAME="alpha_linux_XX"
744                         ;;
745                 s390-*-linux*)
746                         AFS_SYSNAME="s390_linuxXX"
747                         ;;
748                 s390x-*-linux*)
749                         AFS_SYSNAME="s390x_linuxXX"
750                         ;;
751                 sparc-*-linux*)
752                         AFS_SYSNAME="`/bin/arch`_linuxXX"
753                         ;;
754                 sparc64-*-linux*)
755                         AFS_SYSNAME="sparc64_linuxXX"
756                         ;;
757                 i?86-*-linux*)
758                         AFS_SYSNAME="i386_linuxXX"
759                         ;;
760                 arm*-linux*)
761                         AFS_SYSNAME="arm_linuxXX"
762                         ;;
763                 parisc-*-linux-gnu|hppa-*-linux-gnu)
764                         AFS_SYSNAME="parisc_linuxXX"
765                         enable_pam="no"
766                         ;;
767                 power*-ibm-aix4.2*)
768                         AFS_SYSNAME="rs_aix42"
769                         enable_pam="no"
770                         ;;
771                 power*-ibm-aix4.3*)
772                         AFS_SYSNAME="rs_aix42"
773                         enable_pam="no"
774                         ;;
775                 power*-ibm-aix5.1*)
776                         AFS_SYSNAME="rs_aix51"
777                         enable_pam="no"
778                         ;;
779                 power*-ibm-aix5.2*)
780                         AFS_SYSNAME="rs_aix52"
781                         enable_pam="no"
782                         ;;
783                 power*-ibm-aix5.3*)
784                         AFS_SYSNAME="rs_aix53"
785                         enable_pam="no"
786                         ;;
787                 power*-ibm-aix6.1*)
788                         AFS_SYSNAME="rs_aix61"
789                         enable_pam="no"
790                         ;;
791                 x86_64-*-linux-gnu)
792                         AFS_SYSNAME="amd64_linuxXX"
793                         enable_pam="yes"
794                         ;;
795                 *)
796                         AC_MSG_ERROR(An AFS sysname is required)
797                         exit 1
798                         ;;
799         esac
800         case $AFS_SYSNAME in
801                 *_linux* | *_umlinux*)
802                         if test "x${AFS_SYSKVERS}" = "x"; then
803                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
804                         fi
805                         if test "x${AFS_SYSKVERS}" = "x24" ||
806                                 test "x${AFS_SYSKVERS}" = "x22"; then
807                             AC_MSG_ERROR([Linux 2.4.x and older are no longer supported by OpenAFS.  Please use an OpenAFS 1.6.x release on those systems.])
808                         fi
809                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
810                         AFS_SYSNAME="$_AFS_SYSNAME"
811                         AC_TRY_KBUILD(
812                          [],
813                          [#ifndef CONFIG_USERMODE
814                           #error not UML
815                           #endif],
816                          ac_cv_linux_is_uml=yes,)
817                         if test "${ac_cv_linux_is_uml}" = yes; then
818                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
819                         fi
820                         AFS_SYSNAME="$_AFS_SYSNAME"
821                         ;;
822         esac
823         AC_MSG_RESULT($AFS_SYSNAME)
824 fi
825
826 case $AFS_SYSNAME in
827         *_darwin*)
828                 AC_CHECK_HEADERS(crt_externs.h)
829                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
830                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
831                 AC_SUBST(OSXSDK)
832                 ;;
833 esac
834
835 dnl Some hosts have a separate common param file they should include.  Figure
836 dnl out if we're on one of them now that we know the sysname.
837 case $AFS_SYSNAME in
838     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
839     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
840     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
841     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
842     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
843     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
844     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
845     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
846     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
847     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
848     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
849     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
850     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
851     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
852     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
853     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
854     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
855     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
856     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
857     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
858     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
859     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
860     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
861     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
862     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
863     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
864     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
865     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
866     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
867     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
868     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
869     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
870     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
871     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
872 # Linux alpha adds an extra underscore for no good reason.
873     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
874     *_fbsd_*)   AFS_PARAM_COMMON=param.generic_fbsd.h ;;
875 esac
876
877 OPENAFS_OSCONF
878
879 case $AFS_SYSNAME in *_linux* | *_umlinux*)
880
881                 # Add (sub-) architecture-specific paths needed by conftests
882                 case $AFS_SYSNAME  in
883                         *_umlinux26)
884                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
885                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
886                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
887                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
888                 esac
889
890                 if test "x$enable_kernel_module" = "xyes"; then
891                  if test "x$enable_debug_kernel" = "xno"; then
892                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
893                  fi
894                  OPENAFS_GCC_SUPPORTS_MARCH
895                  AC_SUBST(P5PLUS_KOPTS)
896                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
897                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
898                  OPENAFS_GCC_SUPPORTS_NO_COMMON
899                  OPENAFS_GCC_SUPPORTS_PIPE
900                  AC_SUBST(LINUX_GCC_KOPTS)
901
902                  dnl Setup the kernel build environment
903                  LINUX_KBUILD_USES_EXTRA_CFLAGS
904                  LINUX_KERNEL_COMPILE_WORKS
905
906                  dnl Operation signature checks
907                  AC_CHECK_LINUX_OPERATION([inode_operations], [follow_link], [no_nameidata],
908                                           [#include <linux/fs.h>],
909                                           [const char *],
910                                           [struct dentry *dentry, void **link_data])
911                  AC_CHECK_LINUX_OPERATION([inode_operations], [put_link], [no_nameidata],
912                                           [#include <linux/fs.h>],
913                                           [void],
914                                           [struct inode *inode, void *link_data])
915
916                  dnl Check for header files
917                  AC_CHECK_LINUX_HEADER([config.h])
918                  AC_CHECK_LINUX_HEADER([exportfs.h])
919                  AC_CHECK_LINUX_HEADER([freezer.h])
920                  AC_CHECK_LINUX_HEADER([key-type.h])
921                  AC_CHECK_LINUX_HEADER([semaphore.h])
922                  AC_CHECK_LINUX_HEADER([seq_file.h])
923
924                  dnl Type existence checks
925                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
926                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
927
928                  dnl Check for structure elements
929                  AC_CHECK_LINUX_STRUCT([address_space], [backing_dev_info], [fs.h])
930                  AC_CHECK_LINUX_STRUCT([address_space_operations],
931                                        [write_begin], [fs.h])
932                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
933                                        [backing-dev.h])
934                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
935                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
936                  AC_CHECK_LINUX_STRUCT([dentry], [d_u.d_alias], [dcache.h])
937                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
938                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
939                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
940                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
941                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
942                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
943                  AC_CHECK_LINUX_STRUCT([file], [f_path], [fs.h])
944                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
945                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
946                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
947                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
948                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
949                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
950                  AC_CHECK_LINUX_STRUCT([inode_operations], [get_link], [fs.h])
951                  AC_CHECK_LINUX_STRUCT([key], [payload.value], [key.h])
952                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
953                  AC_CHECK_LINUX_STRUCT([key_type], [match_preparse], [key-type.h])
954                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
955                  AC_CHECK_LINUX_STRUCT([msghdr], [msg_iter], [socket.h])
956                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
957                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
958                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
959                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
960                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
961                                        [fs.h])
962                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
963                                        [fs.h])
964                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
965                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
966                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
967                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
968                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
969                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
970                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
971                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
972                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
973                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
974                  AC_CHECK_LINUX_STRUCT([task_struct], [total_link_count], [sched.h])
975                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
976
977                  dnl Check for typed structure elements
978                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
979                                              [buf], [fs.h])
980
981                  dnl Function existence checks
982
983                  AC_CHECK_LINUX_FUNC([__vfs_read],
984                                      [#include <linux/fs.h>],
985                                      [__vfs_read(NULL, NULL, 0, NULL);])
986                  AC_CHECK_LINUX_FUNC([bdi_init],
987                                      [#include <linux/backing-dev.h>],
988                                      [bdi_init(NULL);])
989                  AC_CHECK_LINUX_FUNC([PageChecked],
990                                      [#include <linux/mm.h>
991 #include <linux/page-flags.h>],
992                                      [struct page *_page;
993                                       int bchecked = PageChecked(_page);])
994                  AC_CHECK_LINUX_FUNC([PageFsMisc],
995                                      [#include <linux/mm.h>
996 #include <linux/page-flags.h>],
997                                      [struct page *_page;
998                                       int bchecked = PageFsMisc(_page);])
999                  AC_CHECK_LINUX_FUNC([clear_inode],
1000                                      [#include <linux/fs.h>],
1001                                      [clear_inode(NULL);])
1002                  AC_CHECK_LINUX_FUNC([current_kernel_time],
1003                                      [#include <linux/time.h>],
1004                                      [struct timespec s;
1005                                       s = current_kernel_time();])
1006                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
1007                                      [#include <linux/fs.h>],
1008                                      [d_alloc_anon(NULL);])
1009                  AC_CHECK_LINUX_FUNC([d_count],
1010                                      [#include <linux/dcache.h>],
1011                                      [d_count(NULL);])
1012                  AC_CHECK_LINUX_FUNC([d_make_root],
1013                                      [#include <linux/fs.h>],
1014                                      [d_make_root(NULL);])
1015                  AC_CHECK_LINUX_FUNC([do_sync_read],
1016                                      [#include <linux/fs.h>],
1017                                      [do_sync_read(NULL, NULL, 0, NULL);])
1018                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
1019                                      [#include <linux/sched.h>],
1020                                      [pid_t p; find_task_by_pid(p);])
1021                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
1022                                      [#include <linux/fs.h>],
1023                                      [generic_file_aio_read(NULL,NULL,0,0);])
1024                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
1025                                      [#include <linux/pagemap.h>],
1026                                      [grab_cache_page_write_begin(NULL, 0, 0);])
1027                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
1028                                      [#include <linux/list.h>],
1029                                      [hlist_unhashed(0);])
1030                  AC_CHECK_LINUX_FUNC([ihold],
1031                                      [#include <linux/fs.h>],
1032                                      [ihold(NULL);])
1033                  AC_CHECK_LINUX_FUNC([i_size_read],
1034                                      [#include <linux/fs.h>],
1035                                      [i_size_read(NULL);])
1036                  AC_CHECK_LINUX_FUNC([inode_setattr],
1037                                      [#include <linux/fs.h>],
1038                                      [inode_setattr(NULL, NULL);])
1039                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
1040                                      [#include <linux/fs.h>],
1041                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
1042                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
1043                                      [#include <linux/net.h>],
1044                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
1045                  AC_CHECK_LINUX_FUNC([locks_lock_file_wait],
1046                                      [#include <linux/fs.h>],
1047                                      [locks_lock_file_wait(NULL, NULL);])
1048                  AC_CHECK_LINUX_FUNC([page_follow_link],
1049                                      [#include <linux/fs.h>],
1050                                      [page_follow_link(0,0);])
1051                  AC_CHECK_LINUX_FUNC([page_get_link],
1052                                      [#include <linux/fs.h>],
1053                                      [page_get_link(0,0,0);])
1054                  AC_CHECK_LINUX_FUNC([page_offset],
1055                                      [#include <linux/pagemap.h>],
1056                                      [page_offset(NULL);])
1057                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
1058                                      [#include <linux/pagevec.h>],
1059                                      [__pagevec_lru_add_file(NULL);])
1060                  AC_CHECK_LINUX_FUNC([path_lookup],
1061                                      [#include <linux/fs.h>
1062                                       #include <linux/namei.h>],
1063                                      [path_lookup(NULL, 0, NULL);])
1064                  AC_CHECK_LINUX_FUNC([proc_create],
1065                                      [#include <linux/proc_fs.h>],
1066                                      [proc_create(NULL, 0, NULL, NULL);])
1067                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
1068                                      [#include <linux/rcupdate.h>],
1069                                      [rcu_read_lock();])
1070                  AC_CHECK_LINUX_FUNC([set_nlink],
1071                                      [#include <linux/fs.h>],
1072                                      [set_nlink(NULL, 1);])
1073                  AC_CHECK_LINUX_FUNC([sock_create_kern],
1074                                      [#include <linux/net.h>],
1075                                      [sock_create_kern(0, 0, 0, NULL);])
1076                  AC_CHECK_LINUX_FUNC([sock_create_kern_ns],
1077                                      [#include <linux/net.h>],
1078                                      [sock_create_kern(NULL, 0, 0, 0, NULL);])
1079                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
1080                                      [#include <linux/splice.h>],
1081                                      [splice_direct_to_actor(NULL,NULL,NULL);])
1082                  AC_CHECK_LINUX_FUNC([default_file_splice_read],
1083                                      [#include <linux/fs.h>],
1084                                      [default_file_splice_read(NULL,NULL,NULL, 0, 0);])
1085                  AC_CHECK_LINUX_FUNC([svc_addr_in],
1086                                      [#include <linux/sunrpc/svc.h>],
1087                                      [svc_addr_in(NULL);])
1088                  AC_CHECK_LINUX_FUNC([zero_user_segments],
1089                                      [#include <linux/highmem.h>],
1090                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1091                  AC_CHECK_LINUX_FUNC([noop_fsync],
1092                                      [#include <linux/fs.h>],
1093                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1094                  AC_CHECK_LINUX_FUNC([kthread_run],
1095                                      [#include <linux/kernel.h>
1096                                       #include <linux/kthread.h>],
1097                                      [kthread_run(NULL, NULL, "test");])
1098                  AC_CHECK_LINUX_FUNC([inode_nohighmem],
1099                                      [#include <linux/fs.h>],
1100                                      [inode_nohighmem(NULL);])
1101
1102                  dnl Consequences - things which get set as a result of the
1103                  dnl                above tests
1104                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1105                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1106                                   [define to disable the nfs translator])])
1107
1108                  dnl Assorted more complex tests
1109                  LINUX_AIO_NONVECTOR
1110                  LINUX_EXPORTS_PROC_ROOT_FS
1111                  LINUX_KMEM_CACHE_INIT
1112                  LINUX_HAVE_KMEM_CACHE_T
1113                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1114                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1115                  LINUX_D_PATH_TAKES_STRUCT_PATH
1116                  LINUX_NEW_EXPORT_OPS
1117                  LINUX_INODE_SETATTR_RETURN_TYPE
1118                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1119                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1120                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1121                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1122                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1123                  LINUX_DOP_D_DELETE_TAKES_CONST
1124                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1125                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1126                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1127                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1128                  LINUX_AOP_WRITEBACK_CONTROL
1129                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1130                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1131                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1132                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1133                  LINUX_KERNEL_SOCK_CREATE
1134                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1135                  LINUX_NEED_RHCONFIG
1136                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1137                  LINUX_EXPORTS_TASKLIST_LOCK
1138                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1139                  LINUX_STATFS_TAKES_DENTRY
1140                  LINUX_REFRIGERATOR
1141                  LINUX_HAVE_TRY_TO_FREEZE
1142                  LINUX_LINUX_KEYRING_SUPPORT
1143                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1144                  LINUX_KEY_ALLOC_NEEDS_CRED
1145                  LINUX_INIT_WORK_HAS_DATA
1146                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1147                  LINUX_HAVE_DCACHE_LOCK
1148                  LINUX_D_COUNT_IS_INT
1149                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1150                  LINUX_IOP_CREATE_TAKES_UMODE_T
1151                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1152                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1153                  LINUX_DENTRY_OPEN_TAKES_PATH
1154                  LINUX_D_ALIAS_IS_HLIST
1155                  LINUX_HLIST_ITERATOR_NO_NODE
1156                  LINUX_IOP_I_CREATE_TAKES_BOOL
1157                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1158                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1159                  LINUX_D_INVALIDATE_IS_VOID
1160
1161                  dnl If we are guaranteed that keyrings will work - that is
1162                  dnl  a) The kernel has keyrings enabled
1163                  dnl  b) The code is new enough to give us a key_type_keyring
1164                  dnl then we just disable syscall probing unless we've been
1165                  dnl told otherwise
1166
1167                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1168                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1169                           [enable_linux_syscall_probing="no"],
1170                           [enable_linux_syscall_probing="yes"])
1171                  ])
1172
1173                  dnl Syscall probing needs a few tests of its own, and just
1174                  dnl won't work if the kernel doesn't export init_mm
1175                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1176                    LINUX_EXPORTS_INIT_MM
1177                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1178                      AC_MSG_ERROR(
1179                        [Can't do syscall probing without exported init_mm])
1180                    ])
1181                    LINUX_EXPORTS_SYS_CHDIR
1182                    LINUX_EXPORTS_SYS_OPEN
1183                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1184                              [define to enable syscall table probes])
1185                  ])
1186
1187                  dnl Packaging and SMP build
1188                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1189                    LINUX_WHICH_MODULES
1190                  else
1191                    AC_SUBST(MPS,'SP')
1192                  fi
1193
1194                  dnl Syscall probing
1195                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1196                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1197                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1198                    ])
1199                    ac_cv_linux_exports_sys_call_table=no
1200                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1201                      ac_cv_linux_exports_ia32_sys_call_table=yes
1202                    fi
1203                  else
1204                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1205                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1206                    LINUX_EXPORTS_SYS_CALL_TABLE
1207                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1208                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1209                          linux_syscall_method=none
1210                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1211                             linux_syscall_method=scan
1212                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1213                                linux_syscall_method=scan_with_kallsyms_address
1214                             fi
1215                          fi
1216                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1217                             linux_syscall_method=kallsyms_symbol
1218                          fi
1219                          if test "x$linux_syscall_method" = "xnone"; then
1220                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1221                             linux_syscall_method=scan
1222                          fi
1223                    fi
1224                  fi
1225                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1226                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1227                  fi
1228                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1229                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1230                  fi
1231                  if test "x$ac_cv_linux_func_page_get_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1232                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1233                  else
1234                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1235                  fi
1236                  if test "x$ac_cv_linux_func_page_get_link" != "xyes" -a "x$ac_cv_linux_struct_inode_operations_has_get_link" = "xyes"; then
1237                         AC_MSG_ERROR([Your kernel does not use follow_link - not supported without symlink cache API])
1238                         exit 1
1239                  fi
1240                 :
1241                 fi
1242                 if test "x$enable_linux_d_splice_alias_extra_iput" = xyes; then
1243                     AC_DEFINE(D_SPLICE_ALIAS_LEAK_ON_ERROR, 1, [for internal use])
1244                 fi
1245 dnl Linux-only, but just enable always.
1246                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1247 esac
1248
1249 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1250     [ac_cv_sync_fetch_and_add],
1251     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1252                     [ac_cv_sync_fetch_and_add=yes],
1253                     [ac_cv_sync_fetch_and_add=no])
1254 ])
1255 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1256       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1257                 [define if your C compiler has __sync_add_and_fetch])])
1258
1259 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1260     [ac_cv_sockaddr_len],
1261     [AC_TRY_COMPILE( [#include <sys/types.h>
1262 #include <sys/socket.h>],
1263                      [struct sockaddr *a; a->sa_len=0;],
1264                      [ac_cv_sockaddr_len=yes],
1265                      [ac_cv_sockaddr_len=no])
1266 ])
1267 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1268       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1269                  [define if you struct sockaddr sa_len])])
1270
1271 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1272         echo Skipping library tests because they confuse Irix.
1273 else
1274   AC_SEARCH_LIBS([socket], [socket inet])
1275   AC_SEARCH_LIBS([connect], [nsl])
1276   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1277
1278   dnl darwin wants it, aix hates it
1279   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1280   AC_TRY_COMPILE([
1281   #include <stdlib.h>
1282   #include <stdio.h>
1283   #include <sys/types.h>
1284   #include <sys/socket.h>
1285   #include <netinet/in.h>
1286   #include <arpa/inet.h>
1287   #include <arpa/nameser.h>
1288   #include <arpa/nameser_compat.h>
1289   #include <resolv.h>
1290   ], [static int i; i = 0;],
1291   [AC_MSG_RESULT(yes)
1292    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1293   [AC_MSG_RESULT(no)
1294    ])
1295
1296   openafs_save_libs="$LIBS"
1297   AC_MSG_CHECKING([for res_search])
1298   AC_FUNC_RES_SEARCH
1299
1300   if test "$ac_cv_func_res_search" = no; then
1301       for lib in dns nsl resolv; do
1302         if test "$ac_cv_func_res_search" != yes; then
1303           LIBS="-l$lib $LIBS"
1304           AC_FUNC_RES_SEARCH
1305           LIBS="$openafs_save_libs"
1306         fi
1307       done    
1308       if test "$ac_cv_func_res_search" = yes; then
1309         LIB_AFSDB="-l$lib"
1310         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1311         AC_MSG_RESULT([yes, in lib$lib])
1312       else
1313         AC_MSG_RESULT(no)
1314       fi
1315   else
1316     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1317     AC_MSG_RESULT(yes)
1318   fi
1319   
1320 fi
1321 XLIBS="$LIB_AFSDB $XLIBS"
1322
1323 AC_CHECK_RESOLV_RETRANS
1324
1325 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1326     [ac_cv_setsockopt_iprecverr],
1327     [AC_TRY_COMPILE( [
1328 #include <sys/types.h>
1329 #include <sys/socket.h>
1330 #include <netinet/in.h>],
1331 [int on=1;
1332 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1333         [ac_cv_setsockopt_iprecverr=yes],
1334         [ac_cv_setsockopt_iprecverr=no])])
1335
1336 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1337       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1338                  [define if we can receive socket errors via IP_RECVERR])])
1339
1340 PTHREAD_LIBS=error
1341 if test "x$MKAFS_OSTYPE" = OBSD; then
1342         PTHREAD_LIBS="-pthread"
1343 fi
1344 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1345         PTHREAD_LIBS="-pthread"
1346 fi
1347 if test "x$PTHREAD_LIBS" = xerror; then
1348         AC_CHECK_LIB(pthread, pthread_attr_init,
1349                 PTHREAD_LIBS="-lpthread")
1350 fi
1351 if test "x$PTHREAD_LIBS" = xerror; then
1352         AC_CHECK_LIB(pthreads, pthread_attr_init,
1353                 PTHREAD_LIBS="-lpthreads")
1354 fi
1355 if test "x$PTHREAD_LIBS" = xerror; then
1356         AC_CHECK_LIB(c_r, pthread_attr_init,
1357                 PTHREAD_LIBS="-lc_r")
1358 fi
1359 if test "x$PTHREAD_LIBS" = xerror; then
1360         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1361 fi
1362 if test "x$PTHREAD_LIBS" = xerror; then
1363         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1364         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1365                 PTHREAD_LIBS="-lpthread")
1366 fi
1367 if test "x$PTHREAD_LIBS" = xerror; then
1368         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1369 fi
1370 AC_SUBST(PTHREAD_LIBS)
1371
1372 HOST_CPU="$host_cpu"
1373
1374 if test "x$with_bsd_kernel_headers" != "x"; then
1375         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1376 else
1377         BSD_KERNEL_PATH="/usr/src/sys"
1378 fi
1379
1380 if test "x$with_bsd_kernel_build" != "x"; then
1381         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1382 else
1383         case $AFS_SYSNAME in
1384                 *_fbsd_*)
1385                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1386                         ;;
1387                 *_nbsd*)
1388                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1389         esac
1390 fi
1391
1392 # Fast restart
1393 if test "$enable_supergroups" = "yes"; then
1394         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1395 fi
1396
1397 if test "$enable_bitmap_later" = "yes"; then
1398         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1399 fi
1400
1401 if test "$enable_unix_sockets" = "yes"; then
1402         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1403         USE_UNIX_SOCKETS="yes"
1404 else
1405         USE_UNIX_SOCKETS="no"
1406 fi
1407 AC_SUBST(USE_UNIX_SOCKETS)
1408
1409 if test "$enable_namei_fileserver" = "yes"; then
1410         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1411         VFSCK=""
1412 else
1413         if test "$enable_namei_fileserver" = "default"; then
1414                 case $host in
1415                         *-solaris2.10*)
1416                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1417                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1418                                 VFSCK=""
1419                                 ;;
1420                         *-solaris2.11*)
1421                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1422                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1423                                 VFSCK=""
1424                                 ;;
1425                         *)
1426                                 VFSCK="vfsck"
1427                                 ;;
1428                 esac
1429         else
1430                 VFSCK="vfsck"
1431         fi
1432 fi
1433
1434 dnl check for tivoli
1435 AC_MSG_CHECKING(for tivoli tsm butc support)
1436 XBSA_CFLAGS=""
1437 if test "$enable_tivoli_tsm" = "yes"; then
1438         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1439         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1440         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1441         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1442         XBSADIR5=/usr/tivoli/tsm/client/api/bin64/sample
1443         XBSADIR6=/opt/tivoli/tsm/client/api/bin64/sample
1444
1445         if test -r "$XBSADIR3/dsmapifp.h"; then
1446                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1447                 XBSA_XLIBS="-ldl"
1448                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1449         elif test -r "$XBSADIR4/dsmapifp.h"; then
1450                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1451                 XBSA_XLIBS="-ldl"
1452                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1453         elif test -r "$XBSADIR5/dsmapifp.h"; then
1454                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR5"
1455                 XBSA_XLIBS="-ldl"
1456                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1457         elif test -r "$XBSADIR6/dsmapifp.h"; then
1458                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR6"
1459                 XBSA_XLIBS="-ldl"
1460                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1461         elif test -r "$XBSADIR1/xbsa.h"; then
1462                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1463                 XBSA_XLIBS=""
1464                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1465         elif test -r "$XBSADIR2/xbsa.h"; then
1466                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1467                 XBSA_XLIBS=""
1468                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1469         else
1470                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1471         fi
1472 else
1473         AC_MSG_RESULT([no])
1474 fi
1475 AC_SUBST(XBSA_CFLAGS)
1476 AC_SUBST(XBSA_XLIBS) 
1477 XLIBS="$XBSA_XLIBS $XLIBS"
1478
1479 dnl checks for header files.
1480 AC_HEADER_STDC
1481 AC_HEADER_SYS_WAIT
1482 AC_HEADER_DIRENT
1483 AC_CHECK_HEADERS([ \
1484                    arpa/inet.h \
1485                    arpa/nameser.h \
1486                    curses.h\
1487                    direct.h \
1488                    errno.h \
1489                    fcntl.h \
1490                    grp.h \
1491                    math.h \
1492                    mntent.h \
1493                    ncurses.h \
1494                    ncurses/ncurses.h \
1495                    netdb.h \
1496                    netinet/in.h \
1497                    pthread_np.h \
1498                    pwd.h \
1499                    regex.h \
1500                    security/pam_appl.h \
1501                    signal.h \
1502                    stdint.h \
1503                    stdio_ext.h \
1504                    stdlib.h \
1505                    string.h \
1506                    strings.h \
1507                    sys/bitypes.h \
1508                    sys/bswap.h \
1509                    sys/dk.h \
1510                    sys/fcntl.h \
1511                    sys/file.h \
1512                    sys/fs_types.h \
1513                    sys/fstyp.h \
1514                    sys/ioctl.h \
1515                    sys/ipc.h \
1516                    sys/lockf.h \
1517                    sys/map.h \
1518                    sys/mount.h \
1519                    sys/mntent.h \
1520                    sys/mnttab.h \
1521                    sys/pag.h \
1522                    sys/param.h \
1523                    sys/resource.h \
1524                    sys/select.h \
1525                    sys/statfs.h \
1526                    sys/statvfs.h \
1527                    sys/socket.h \
1528                    sys/sysctl.h \
1529                    sys/time.h \
1530                    sys/types.h \
1531                    sys/uio.h \
1532                    sys/un.h \
1533                    sys/vfs.h \
1534                    syslog.h \
1535                    termios.h \
1536                    time.h \
1537                    ucontext.h \
1538                    unistd.h \
1539                    windows.h \
1540                 ])
1541
1542 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1543 #ifdef HAVE_NETINET_IN_H
1544 # include <netinet/in.h>
1545 #endif])
1546
1547 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1548 #ifdef HAVE_SYS_SOCKET_H
1549 # include <sys/socket.h>
1550 #endif])
1551
1552 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1553 #ifdef HAVE_SYS_SOCKET_H
1554 # include <sys/socket.h>
1555 #endif
1556 #ifdef HAVE_NETINET_IN_H
1557 # include <netinet/in.h>
1558 #endif
1559 #ifdef HAVE_NET_IF_H
1560 # include <net/if.h>
1561 #endif])
1562
1563 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1564 #ifdef HAVE_SECURITY_PAM_APPL_H
1565 # include <security/pam_appl.h>
1566 #endif])
1567
1568 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1569
1570 AC_CHECK_TYPES([fsblkcnt_t],,,[
1571 #include <sys/types.h>
1572 #ifdef HAVE_SYS_BITYPES_H
1573 #include <sys/bitypes.h>
1574 #endif
1575 #ifdef HAVE_SYS_STATFS_H
1576 #include <sys/statfs.h>
1577 #endif
1578 #ifdef HAVE_SYS_STATVFS_H
1579 #include <sys/statvfs.h>
1580 #endif
1581 ])
1582
1583 dnl see what struct stat has for timestamps
1584 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1585
1586 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1587
1588 if test "$enable_debug_locks" = yes; then
1589         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1590 fi
1591
1592 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1593         HAVE_PAM="YES"
1594 else
1595         HAVE_PAM="no"
1596 fi
1597 AC_SUBST(HAVE_PAM)
1598
1599 if test "$enable_login" = yes; then
1600         BUILD_LOGIN="yes"
1601 else
1602         BUILD_LOGIN="no"
1603 fi
1604 AC_SUBST(BUILD_LOGIN)
1605
1606 if test "$enable_kauth" = yes; then
1607         INSTALL_KAUTH="yes"
1608 else
1609         INSTALL_KAUTH="no"
1610 fi
1611 AC_SUBST(INSTALL_KAUTH)
1612
1613 AC_CHECK_FUNCS([ \
1614         arc4random \
1615         closelog \
1616         fcntl \
1617         fseeko64 \
1618         ftello64 \
1619         getcwd \
1620         getegid \
1621         geteuid \
1622         getgid \
1623         getuid \
1624         getrlimit \
1625         issetugid \
1626         mkstemp \
1627         openlog \
1628         poll \
1629         pread \
1630         preadv \
1631         preadv64 \
1632         pwrite \
1633         pwritev \
1634         pwritev64 \
1635         regcomp \
1636         regerror \
1637         regexec \
1638         setitimer \
1639         setvbuf \
1640         sigaction \
1641         strcasestr \
1642         strerror \
1643         sysconf \
1644         sysctl \
1645         syslog \
1646         tdestroy \
1647         timegm \
1648 ])
1649
1650 OPENAFS_ROKEN()
1651 OPENAFS_HCRYPTO()
1652 OPENAFS_CURSES()
1653 OPENAFS_C_ATTRIBUTE()
1654 OPENAFS_C_PRAGMA()
1655
1656 dnl Functions that Heimdal's libroken provides, but that we
1657 dnl haven't found a need for yet, and so haven't imported
1658 AC_CHECK_FUNCS([ \
1659         chown \
1660         fchown \
1661         gethostname \
1662         lstat \
1663         inet_aton \
1664         putenv \
1665         readv \
1666         setenv \
1667         strdup \
1668         strftime \
1669         strndup \
1670         strsep \
1671         unsetenv \
1672 ])
1673
1674 dnl Functions that are in objects that we always build from libroken
1675 AC_CHECK_FUNCS([ \
1676         asprintf \
1677         asnprintf \
1678         vasprintf \
1679         vasnprintf \
1680         vsnprintf \
1681         snprintf \
1682 ])
1683
1684 dnl Functions that we're going to try and get from libroken
1685 AC_REPLACE_FUNCS([ \
1686         daemon \
1687         ecalloc \
1688         emalloc \
1689         erealloc \
1690         err \
1691         errx \
1692         flock \
1693         freeaddrinfo \
1694         gai_strerror \
1695         getaddrinfo \
1696         getdtablesize \
1697         getnameinfo \
1698         getopt \
1699         getprogname \
1700         gettimeofday \
1701         inet_ntop \
1702         inet_pton \
1703         localtime_r \
1704         mkstemp \
1705         setenv \
1706         setprogname \
1707         strcasecmp \
1708         strlcat \
1709         strnlen \
1710         strlcpy \
1711         strsep \
1712         tdelete \
1713         tfind \
1714         tsearch \
1715         twalk \
1716         unsetenv \
1717         verr \
1718         verrx \
1719         vsyslog \
1720         vwarn \
1721         vwarnx \
1722         warn \
1723         warnx \
1724 ])
1725
1726 dnl Headers that we're going to try and get from libroken
1727 AC_CHECK_HEADERS([ \
1728         err.h \
1729         search.h \
1730 ])
1731
1732 AC_CHECK_DECLS([h_errno], [], [], [
1733 #include <sys/types.h>
1734 #ifdef HAVE_NETDB_H
1735 #include <netdb.h>
1736 #endif
1737 ])
1738
1739 AC_HEADER_TIME
1740
1741 ROKEN_HEADERS=
1742 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1743       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1744       [])
1745 AC_SUBST(ROKEN_HEADERS)
1746
1747 dnl Stuff that's harder ...
1748 AC_MSG_CHECKING([for bswap16])
1749 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1750 #ifdef HAVE_SYS_TYPES_H
1751 #include <sys/types.h>
1752 #endif
1753 #ifdef HAVE_SYS_BSWAP_H
1754 #include <sys/bswap.h>
1755 #endif
1756 ],
1757 [short a, b; b = bswap16(a); ])],
1758 [AC_MSG_RESULT(yes)
1759  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1760 ],
1761 [AC_MSG_RESULT(no)])
1762
1763 AC_MSG_CHECKING([for bswap32])
1764 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1765 #include <sys/types.h>
1766 #endif
1767 #ifdef HAVE_SYS_BSWAP_H
1768 #include <sys/bswap.h>
1769 #endif
1770 ],
1771 [int a, b; b = bswap32(a); ])],
1772 [AC_MSG_RESULT(yes)
1773  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1774 ],
1775 [AC_MSG_RESULT(no)])
1776
1777 case $AFS_SYSNAME in
1778 *hp_ux* | *hpux*)
1779    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1780    ;;
1781 *)
1782    AC_MSG_CHECKING([for positional I/O])
1783    if test "$ac_cv_func_pread" = "yes" && \
1784            test "$ac_cv_func_pwrite" = "yes"; then
1785       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1786       AC_MSG_RESULT(yes)
1787    else
1788      AC_MSG_RESULT(no)
1789    fi
1790    AC_MSG_CHECKING([for vectored positional I/O])
1791    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1792                "$ac_cv_func_pwritev" = "yes" -a \
1793                "$ac_cv_func_preadv64" = "yes" -a \
1794                "$ac_cv_func_pwritev64" = "yes"],
1795          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1796           AC_MSG_RESULT(yes)],
1797          [AC_MSG_RESULT(no)])
1798    ;;
1799 esac
1800
1801 AC_MSG_CHECKING([for POSIX regex library])
1802 if test "$ac_cv_header_regex_h" = "yes" && \
1803         test "$ac_cv_func_regcomp" = "yes" && \
1804         test "$ac_cv_func_regexec" = "yes" && \
1805         test "$ac_cv_func_regerror" = "yes"; then
1806     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1807     AC_MSG_RESULT(yes)
1808 else
1809     AC_MSG_RESULT(no)
1810 fi
1811
1812 dnl Look for "non-portable" pthreads functions.
1813 save_LIBS="$LIBS"
1814 LIBS="$LIBS $PTHREAD_LIBS"
1815 AC_CHECK_FUNCS([ \
1816         pthread_set_name_np \
1817         pthread_setname_np \
1818 ])
1819
1820 dnl Sadly, there are three different versions of pthread_setname_np.
1821 dnl Try to cater for all of them.
1822 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1823     AC_MSG_CHECKING([for signature of pthread_setname_np])
1824     AC_TRY_COMPILE([
1825 #include <pthread.h>
1826 #ifdef HAVE_PTHREAD_NP_H
1827 #include <pthread_np.h>
1828 #endif
1829 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1830         AC_MSG_RESULT([three arguments])
1831         pthread_setname_np_args=3], [
1832         AC_TRY_COMPILE([
1833 #include <pthread.h>
1834 #ifdef HAVE_PTHREAD_NP_H
1835 #include <pthread_np.h>
1836 #endif
1837 ], [pthread_setname_np(pthread_self(), "test")], [
1838             AC_MSG_RESULT([two arguments])
1839             pthread_setname_np_args=2], [
1840             AC_TRY_COMPILE([
1841 #include <pthread.h>
1842 #ifdef HAVE_PTHREAD_NP_H
1843 #include <pthread_np.h>
1844 #endif
1845 ], [pthread_setname_np("test")], [
1846                 AC_MSG_RESULT([one argument])
1847                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1848 ])
1849 ])
1850 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1851 fi
1852 LIBS="$save_LIBS"
1853
1854 openafs_cv_saved_CFLAGS="$CFLAGS"
1855 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1856
1857 AC_TYPE_SIGNAL
1858 OPENAFS_RETSIGTYPE
1859 AC_CHECK_SIZEOF(void *)
1860 AC_CHECK_SIZEOF(unsigned long long)
1861 AC_CHECK_SIZEOF(unsigned long)
1862 AC_CHECK_SIZEOF(unsigned int)
1863 AC_TYPE_INTPTR_T
1864 AC_TYPE_UINTPTR_T
1865 AC_TYPE_SSIZE_T
1866 AC_CHECK_TYPE([sig_atomic_t],[],
1867     [AC_DEFINE([sig_atomic_t], [int],
1868         [Define to int if <signal.h> does not define.])],
1869 [#include <sys/types.h>
1870 #include <signal.h>])
1871 AC_CHECK_TYPE([socklen_t],[],
1872     [AC_DEFINE([socklen_t], [int],
1873         [Define to int if <sys/socket.h> does not define.])],
1874 [#include <sys/types.h>
1875 #include <sys/socket.h>])
1876 AC_CHECK_TYPES(off64_t)
1877 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1878 AC_CHECK_TYPES([struct winsize], [], [], [
1879 #ifdef HAVE_TERMIOS_H
1880 # include <termios.h>
1881 #else
1882 # include <sys/termios.h>
1883 #endif
1884 #include <sys/ioctl.h>])
1885 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1886                 struct sockaddr_storage],
1887                [], [], [
1888 #include <sys/types.h>
1889 #include <sys/socket.h>
1890 ])
1891 AC_CHECK_TYPES([sa_family_t], [], [], [
1892 #include <sys/types.h>
1893 #include <sys/socket.h>
1894 ])
1895 AC_CHECK_TYPES([struct addrinfo], [], [], [
1896 #include <sys/types.h>
1897 #ifdef HAVE_NETDB_H
1898 #include <netdb.h>
1899 #endif
1900 ])
1901 AC_CHECK_TYPES([long long], [], [], [])
1902
1903 AC_SIZEOF_TYPE(long)
1904
1905 CFLAGS="$openafs_cv_saved_CFLAGS"
1906
1907 RRA_HEADER_PAM_CONST
1908
1909
1910 dnl Directory PATH handling
1911 if test "x$enable_transarc_paths" = "xyes"  ; then 
1912     afsconfdir=${afsconfdir=/usr/afs/etc}
1913     viceetcdir=${viceetcdir=/usr/vice/etc}
1914     afskerneldir=${afskerneldir=${viceetcdir}}
1915     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1916     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1917     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1918     afsdbdir=${afsdbdir=/usr/afs/db}
1919     afslogsdir=${afslogsdir=/usr/afs/logs}
1920     afslocaldir=${afslocaldir=/usr/afs/local}
1921     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1922     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1923     afsdatadir=${afsdatadir=/usr/vice/etc}
1924 else 
1925     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1926     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1927     afskerneldir=${afskerneldir='${libdir}/openafs'}
1928     afssrvbindir=${afssrvbindir='${bindir}'}
1929     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1930     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1931     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1932     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1933     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1934     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1935     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1936     afsdatadir=${afsdatadir='${datadir}/openafs'}
1937 fi
1938 AC_SUBST(afsconfdir)
1939 AC_SUBST(viceetcdir)
1940 AC_SUBST(afskerneldir)
1941 AC_SUBST(afssrvbindir)
1942 AC_SUBST(afssrvsbindir)
1943 AC_SUBST(afssrvlibexecdir)
1944 AC_SUBST(afsdbdir)
1945 AC_SUBST(afslogsdir)
1946 AC_SUBST(afslocaldir)
1947 AC_SUBST(afsbackupdir)
1948 AC_SUBST(afsbosconfigdir)
1949 AC_SUBST(afsdatadir)
1950
1951 if test "x$enable_kernel_module" = "xyes"; then
1952 ENABLE_KERNEL_MODULE=libafs
1953 fi
1954
1955 if test "x$enable_pthreaded_ubik" = "xyes"; then
1956 ENABLE_PTHREADED_UBIK=yes
1957 fi
1958
1959 AC_SUBST(VFSCK)
1960 AC_SUBST(AFS_SYSNAME)
1961 AC_SUBST(AFS_PARAM_COMMON)
1962 AC_SUBST(ENABLE_KERNEL_MODULE)
1963 AC_SUBST(ENABLE_PTHREADED_UBIK)
1964 AC_SUBST(LIB_AFSDB)
1965 AC_SUBST(LINUX_KERNEL_PATH)
1966 AC_SUBST(LINUX_KERNEL_BUILD)
1967 AC_SUBST(HOST_CPU)
1968 AC_SUBST(BSD_KERNEL_PATH)
1969 AC_SUBST(BSD_KERNEL_BUILD)
1970 AC_SUBST(LINUX_VERSION)
1971 AC_SUBST(MKAFS_OSTYPE)
1972 AC_SUBST(TOP_OBJDIR)
1973 AC_SUBST(TOP_SRCDIR)
1974 AC_SUBST(TOP_INCDIR)
1975 AC_SUBST(TOP_LIBDIR)
1976 AC_SUBST(DEST)
1977 AC_SUBST(DARWIN_INFOFILE)
1978 AC_SUBST(IRIX_BUILD_IP35)
1979 AC_SUBST(HTML_XSL)
1980 AC_SUBST(XSLTPROC)
1981 AC_SUBST(DOCBOOK2PDF)
1982 AC_SUBST(DOCBOOK_STYLESHEETS)
1983
1984 OPENAFS_FUSE
1985 OPENAFS_SWIG
1986
1987 TOP_SRCDIR="${srcdir}/src"
1988 dnl
1989 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1990 dnl
1991 case $TOP_SRCDIR in
1992         /*)
1993                 ;;
1994         *)
1995                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1996                 ;;
1997 esac
1998
1999 TOP_OBJDIR="${SRCDIR_PARENT}"
2000 TOP_INCDIR="${SRCDIR_PARENT}/include"
2001 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
2002 if test "${DEST}x" = "x"; then
2003         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
2004 fi
2005
2006 if test "x$with_crosstools_dir" != "x"; then
2007         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
2008                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
2009                 CONFIGTOOL_PATH=$with_crosstools_dir/config
2010                 RXGEN_PATH=$with_crosstools_dir/rxgen
2011         else
2012                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
2013                 exit 1
2014         fi
2015 else
2016         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
2017         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
2018         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
2019 fi
2020 AC_SUBST(COMPILE_ET_PATH)
2021 AC_SUBST(CONFIGTOOL_PATH)
2022 AC_SUBST(RXGEN_PATH)
2023
2024 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
2025 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
2026 AC_SUBST(HELPER_SPLINT)
2027 AC_SUBST(HELPER_SPLINTCFG)
2028
2029 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
2030
2031 dnl Check to see if crypt lives in a different library
2032 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
2033 AC_SUBST(LIB_crypt)
2034
2035 dnl Check to see if the compiler support labels in structs
2036 AC_MSG_CHECKING(for label support in structs)
2037 AC_TRY_COMPILE([], [
2038 extern void osi_UFSOpen(void);
2039 struct labeltest {
2040    void (*open) (void);
2041 };
2042 struct labeltest struct_labeltest = {
2043    .open       = osi_UFSOpen,
2044 }
2045 ],
2046 [AC_MSG_RESULT(yes)
2047  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
2048 ],
2049 [AC_MSG_RESULT(no)
2050 ])
2051
2052 AC_MSG_CHECKING([checking for dirfd])
2053 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
2054 #ifdef HAVE_DIRENT_H
2055 #include <dirent.h>
2056 #endif
2057 ]],
2058         [[DIR *d = 0; dirfd(d);]])],
2059         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
2060 if test "$ac_rk_have_dirfd" = "yes" ; then
2061         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
2062 fi
2063 AC_MSG_RESULT($ac_rk_have_dirfd)
2064
2065 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
2066 #ifdef HAVE_DIRENT_H
2067 #include <dirent.h>
2068 #endif])
2069
2070 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
2071 [#ifdef HAVE_SYS_RESOURCE_H
2072 #include <sys/resource.h>
2073 #endif])
2074
2075 dnl Check for UUID library
2076 AC_CHECK_HEADERS([uuid/uuid.h])
2077 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
2078 AC_CHECK_FUNCS([uuid_generate])
2079 ])
2080
2081