Linux 3.8: vmtruncate removal
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([pam],
79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
80     ,
81     [enable_pam="yes"])
82 AC_ARG_ENABLE([gtx],
83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
84 AC_ARG_ENABLE([uss],
85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
86 AC_ARG_ENABLE([namei-fileserver],
87     [AS_HELP_STRING([--enable-namei-fileserver],
88         [force compilation of namei fileserver in preference to inode
89          fileserver])],
90     , 
91     [enable_namei_fileserver="default"])
92 AC_ARG_ENABLE([supergroups],
93     [AS_HELP_STRING([--enable-supergroups],
94         [enable support for nested pts groups])],
95     , 
96     [enable_supergroups="no"])
97 AC_ARG_ENABLE([bitmap-later],
98     [AS_HELP_STRING([--enable-bitmap-later],
99         [enable fast startup of file server by not reading bitmap till
100          needed])],
101     , 
102     [enable_bitmap_later="no"])
103 AC_ARG_ENABLE([unix-sockets],
104     [AS_HELP_STRING([--disable-unix-sockets],
105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
106     ,
107     [enable_unix_sockets="yes"])
108 AC_ARG_ENABLE([tivoli-tsm],
109     [AS_HELP_STRING([--enable-tivoli-tsm],
110         [enable use of the Tivoli TSM API libraries for butc support])],
111     , 
112     [enable_tivoli_tsm="no"])
113 AC_ARG_ENABLE([pthreaded-ubik],
114     [AS_HELP_STRING([--enable-pthreaded-ubik],
115         [enable installation of pthreaded ubik applications (defaults to
116          disabled)])],
117     ,
118     [enable_pthreaded_ubik="no"])
119
120 dnl Kernel module build options.
121 AC_ARG_WITH([linux-kernel-headers],
122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
123         [use the kernel headers found at path (optional, defaults to
124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
126 AC_ARG_WITH([linux-kernel-build],
127     [AS_HELP_STRING([--with-linux-kernel-build=path],
128         [use the kernel build found at path(optional, defaults to 
129         kernel headers path)])])
130 AC_ARG_WITH([bsd-kernel-headers],
131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
132         [use the kernel headers found at path (optional, defaults to
133          /usr/src/sys)])])
134 AC_ARG_WITH([bsd-kernel-build],
135     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
136         [use the kernel build found at path (optional, defaults to
137          KSRC/i386/compile/GENERIC)])])
138 AC_ARG_WITH([linux-kernel-packaging],
139     [AS_HELP_STRING([--with-linux-kernel-packaging],
140         [use standard naming conventions to aid Linux kernel build packaging
141          (disables MPS, sets the kernel module name to openafs.ko, and
142          installs kernel modules into the standard Linux location)])],
143     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
144      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
145     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
146 AC_ARG_ENABLE([kernel-module],
147     [AS_HELP_STRING([--disable-kernel-module],
148         [disable compilation of the kernel module (defaults to enabled)])],
149     , 
150     [enable_kernel_module="yes"])
151 AC_ARG_ENABLE([redhat-buildsys],
152     [AS_HELP_STRING([--enable-redhat-buildsys],
153         [enable compilation of the redhat build system kernel (defaults to
154          disabled)])],
155     ,
156     [enable_redhat_buildsys="no"])
157
158 dnl Installation locations.
159 AC_ARG_ENABLE([transarc-paths],
160     [AS_HELP_STRING([--enable-transarc-paths],
161         [use Transarc style paths like /usr/afs and /usr/vice])],
162     , 
163     [enable_transarc_paths="no"])
164
165 dnl Deprecated crypto
166 AC_ARG_ENABLE([kauth],
167     [AS_HELP_STRING([--disable-kauth],
168         [do not install the deprecated kauth server and utilities (defaults to
169          enabled)])],
170     ,
171     [enable_kauth="yes"])
172
173 dnl Optimization and debugging flags.
174 AC_ARG_ENABLE([strip-binaries],
175     [AS_HELP_STRING([--disable-strip-binaries],
176         [disable stripping of symbol information from binaries (defaults to
177          enabled)])],
178     ,
179     [enable_strip_binaries="maybe"])
180 AC_ARG_ENABLE([debug],
181     [AS_HELP_STRING([--enable-debug],
182         [enable compilation of the user space code with debugging information
183          (defaults to disabled)])],
184     , 
185     [enable_debug="no"])
186 AC_ARG_ENABLE([optimize],
187     [AS_HELP_STRING([--disable-optimize],
188         [disable optimization for compilation of the user space code (defaults
189          to enabled)])],
190     , 
191     [enable_optimize="yes"])
192 AC_ARG_ENABLE([warnings],
193     [AS_HELP_STRING([--enable-warnings],
194         [enable compilation warnings when building with gcc (defaults to
195          disabled)])],
196     ,
197     [enable_warnings="no"])
198 AC_ARG_ENABLE([checking],
199     [AS_HELP_STRING([--enable-checking],
200         [turn compilation warnings into errors when building with gcc (defaults
201          to disabled)])],
202     [enable_checking="$enableval"],
203     [enable_checking="no"])
204 AC_ARG_ENABLE([debug-locks],
205     [AS_HELP_STRING([--enable-debug-locks],
206         [turn on lock debugging assertions (defaults to disabled)])],
207     [enable_debug_locks="$enableval"],
208     [enable_debug_locks="no"])
209 AC_ARG_ENABLE([debug-kernel],
210     [AS_HELP_STRING([--enable-debug-kernel],
211         [enable compilation of the kernel module with debugging information
212          (defaults to disabled)])],
213     ,
214     [enable_debug_kernel="no"])
215 AC_ARG_ENABLE([optimize-kernel],
216     [AS_HELP_STRING([--disable-optimize-kernel],
217         [disable compilation of the kernel module with optimization (defaults
218          based on platform)])],
219     , 
220     [enable_optimize_kernel=""])
221 AC_ARG_ENABLE([debug-lwp],
222     [AS_HELP_STRING([--enable-debug-lwp],
223         [enable compilation of the LWP code with debugging information
224          (defaults to disabled)])],
225     ,
226     [enable_debug_lwp="no"])
227 AC_ARG_ENABLE([optimize-lwp],
228     [AS_HELP_STRING([--disable-optimize-lwp],
229         [disable optimization for compilation of the LWP code (defaults to
230          enabled)])],
231     ,
232     [enable_optimize_lwp="yes"])
233 AC_ARG_ENABLE([debug-pam],
234     [AS_HELP_STRING([--enable-debug-pam],
235         [enable compilation of the PAM code with debugging information
236          (defaults to disabled)])],
237     ,
238     [enable_debug_pam="no"])
239 AC_ARG_ENABLE([optimize-pam],
240     [AS_HELP_STRING([--disable-optimize-pam],
241         [disable optimization for compilation of the PAM code (defaults to
242          enabled)])],
243     ,
244     [enable_optimize_pam="yes"])
245 AC_ARG_ENABLE([linux-syscall-probing],
246     [AS_HELP_STRING([--enable-linux-syscall-probing],
247         [enable Linux syscall probing (defaults to autodetect)])],
248     ,
249     [enable_linux_syscall_probing="maybe"])
250 AC_ARG_WITH([crosstools-dir],
251     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
252     
253 AC_ARG_WITH([xslt-processor],
254         AS_HELP_STRING([--with-xslt-processor=ARG],
255         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
256         [XSLTPROC="$withval"],
257         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
258
259 AC_ARG_WITH([html-xsl], 
260         AS_HELP_STRING([--with-html-xsl],
261         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
262         [HTML_XSL="$withval"],
263         [HTML_XSL="html/chunk.xsl"])
264
265 AC_ARG_WITH([docbook2pdf],
266         AS_HELP_STRING([--with-docbook2pdf=ARG],
267         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
268         [DOCBOOK2PDF="$withval"],
269         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
270
271 AC_ARG_WITH([docbook-stylesheets],
272         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
273         [location of DocBook stylesheets (default is to search a set of likely paths)]),
274         [DOCBOOK_STYLESHEETS="$withval"],
275         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
276         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
277                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
278         fi)
279
280 enable_login="no"
281
282 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
283 dnl documentation build.
284 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
285
286 dnl weird ass systems
287 dnl AC_AIX
288 AC_ISC_POSIX
289 dnl AC_MINIX
290
291 dnl Various compiler setup.
292 AC_TYPE_PID_T
293 AC_TYPE_SIZE_T
294
295 dnl Checks for programs.
296 AC_PROG_INSTALL
297 AC_PROG_LN_S
298 AC_PROG_RANLIB
299 AC_PROG_YACC
300 AM_PROG_LEX
301 dnl if we are flex, be lex-compatible
302 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
303
304 OPENAFS_FORCE_ABS_INSTALL
305 OPENAFS_CHECK_BIGENDIAN
306 OPENAFS_PRINTF_TAKES_Z_LEN
307
308 AC_MSG_CHECKING(your OS)
309 system=$host
310 case $system in
311         *-linux*)
312
313                 MKAFS_OSTYPE=LINUX
314                 if test "x$enable_redhat_buildsys" = "xyes"; then
315                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
316                 fi
317                 if test "x$enable_kernel_module" = "xyes"; then
318                  if test "x$with_linux_kernel_headers" != "x"; then
319                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
320                  else
321                    for utsdir in "/lib/modules/`uname -r`/build" \
322                                  "/lib/modules/`uname -r`/source" \
323                                  "/usr/src/linux-2.4" \
324                                  "/usr/src/linux"; do
325                      LINUX_KERNEL_PATH="$utsdir"
326                      for utsfile in "include/generated/utsrelease.h" \
327                                     "include/linux/utsrelease.h" \
328                                     "include/linux/version.h" \
329                                     "include/linux/version-up.h"; do
330                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
331                          break 2
332                        fi
333                      done
334                    done
335                  fi
336                  if test "x$with_linux_kernel_build" != "x"; then
337                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
338                  else
339                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
340                  fi
341                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
342                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
343                    LINUX_VERSION="$linux_kvers"
344                  else
345                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
346                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
347                      LINUX_VERSION="$linux_kvers"
348                    else
349                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
350                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
351                        if test "x$linux_kvers" = "x"; then
352                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
353                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
354                            if test "x$linux_kvers" = "x"; then
355                              AC_MSG_ERROR(Linux headers lack version definition [2])
356                              exit 1
357                            else
358                              LINUX_VERSION="$linux_kvers"
359                            fi
360                          else
361                            AC_MSG_ERROR(Linux headers lack version definition)
362                            exit 1
363                          fi
364                        else
365                          LINUX_VERSION="$linux_kvers"
366                        fi
367                      else
368                        enable_kernel_module="no"
369                      fi
370                    fi
371                  fi
372                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
373                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
374                      enable_kernel_module="no"
375                  fi
376                  if test "x$enable_kernel_module" = "xno"; then
377                   if test "x$with_linux_kernel_headers" != "x"; then
378                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
379                    exit 1
380                   else
381                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
382                   fi
383                  fi
384                  dnl do we need to determine SUBARCH from autoconf.h
385                  SUBARCH=default
386                 fi
387                 AC_MSG_RESULT(linux)
388                 if test "x$enable_kernel_module" = "xyes"; then
389                  case "$LINUX_VERSION" in
390                   2.2.*) AFS_SYSKVERS=22 ;;
391                   2.4.*) AFS_SYSKVERS=24 ;;
392                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
393                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
394                  esac
395                 fi
396                 ;;
397         *-solaris*)
398                 MKAFS_OSTYPE=SOLARIS
399                 AC_MSG_RESULT(sun4)
400                 AC_PATH_PROG(SOLARISCC, [cc], ,
401                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
402                 if test "x$SOLARISCC" = "x" ; then
403                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
404                 fi
405                 SOLARIS_UFSVFS_HAS_DQRWLOCK
406                 SOLARIS_FS_HAS_FS_ROLLED
407                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
408                 ;;
409         *-sunos*)
410                 MKAFS_OSTYPE=SUNOS
411                 enable_kernel_module=no
412                 AC_MSG_RESULT(sun4)
413                 ;;
414         *-hpux*)
415                 MKAFS_OSTYPE=HPUX
416                 AC_MSG_RESULT(hp_ux)
417                 if test -f "/usr/old/usr/include/ndir.h"; then
418                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
419                 fi
420                 ;;
421         *-irix*)
422                 if test -d /usr/include/sys/SN/SN1; then
423                  IRIX_BUILD_IP35="IP35"
424                 fi
425                 MKAFS_OSTYPE=IRIX
426                 AC_MSG_RESULT(sgi)
427                 ;;
428         *-aix*)
429                 MKAFS_OSTYPE=AIX
430                 AC_MSG_RESULT(rs_aix)
431                 ;;
432         arm-*-darwin*)
433                 MKAFS_OSTYPE=DARWIN
434                 AC_MSG_RESULT(arm_darwin)
435                 ;;
436         powerpc-*-darwin*)
437                 MKAFS_OSTYPE=DARWIN
438                 AC_MSG_RESULT(ppc_darwin)
439                 ;;
440         i386-*-darwin*)
441                 MKAFS_OSTYPE=DARWIN
442                 AC_MSG_RESULT(x86_darwin)
443                 ;;
444         x86_64-*-darwin*)
445                 MKAFS_OSTYPE=DARWIN
446                 AC_MSG_RESULT(x86_darwin)
447                 ;;
448         i386-*-freebsd*)
449                 MKAFS_OSTYPE=FBSD
450                 AC_MSG_RESULT(i386_fbsd)
451                 ;;
452         x86_64-*-freebsd*)
453                 MKAFS_OSTYPE=FBSD
454                 AC_MSG_RESULT(amd64_fbsd)
455                 ;;
456         *-netbsd*)
457                 MKAFS_OSTYPE=NBSD
458                 AC_MSG_RESULT(nbsd)
459                 ;;
460         x86_64-*-openbsd*)
461                 MKAFS_OSTYPE=OBSD
462                 AC_MSG_RESULT(amd64_obsd)
463                 ;;
464         i386-*-openbsd*)
465                 MKAFS_OSTYPE=OBSD
466                 AC_MSG_RESULT(i386_obsd)
467                 ;;
468         *-dragonfly*)
469                 MKAFS_OSTYPE=DFBSD
470                 AC_MSG_RESULT(i386_dfbsd)
471                 ;;
472         *)
473                 AC_MSG_RESULT($system)
474                 ;;
475 esac
476
477 if test "x$with_afs_sysname" != "x"; then
478         AFS_SYSNAME="$with_afs_sysname"
479 else
480         AC_MSG_CHECKING(your AFS sysname)
481         case $host in
482                 i?86-*-openbsd?.?)
483                         v=${host#*openbsd}
484                         vM=${v%.*}
485                         vm=${v#*.}
486                         AFS_SYSNAME="i386_obsd${vM}${vm}"
487                         ;;
488                 sparc64-*-openbsd?.?)
489                         v=${host#*openbsd}
490                         vM=${v%.*}
491                         vm=${v#*.}
492                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
493                         ;;
494                 x86_64-*-openbsd?.?)
495                         v=${host#*openbsd}
496                         vM=${v%.*}
497                         vm=${v#*.}
498                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
499                         ;;
500                 i?86-*-freebsd*.*)
501                         v=${host#*freebsd}
502                         vM=${v%.*}
503                         vm=${v#*.}
504                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
505                         ;;
506                 x86_64-*-freebsd*.*)
507                         v=${host#*freebsd}
508                         vM=${v%.*}
509                         vm=${v#*.}
510                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
511                         ;;
512                 i386-*-dragonfly?.*)
513                         v=${host#*dragonfly}
514                         vM=${v%.*}
515                         vm=${v#*.}
516                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
517                         ;;
518                 i?86-*-netbsd*1.6[[M-Z]]*)
519                         AFS_SYSNAME="i386_nbsd20"
520                         ;;
521                 powerpc-*-netbsd*1.6[[M-Z]]*)
522                         AFS_SYSNAME="ppc_nbsd20"
523                         ;;
524                 *-*-netbsd*)
525                         arch=${host%%-unknown*}
526                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
527                                                -e 's/powerpc/ppc/g')
528                         v=${host#*netbsd}
529                         v=${v#*aout}
530                         v=${v#*ecoff}
531                         v=${v#*elf}
532                         vM=${v%%.*}
533                         vM=${vM%.*}
534                         v=${v#*.}
535                         vm=${v%%.*}
536                         vm=${vm%.*}
537                         vm=${vm%%[[_A-Z]]*}
538                         if test $vm -eq 99 ; then
539                                 vM=$((vM+1))
540                         fi
541                         if test $vM -gt 1 ; then
542                                 vm=0
543                         fi
544                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
545                         ;;
546                 hppa*-hp-hpux11.0*)
547                         AFS_SYSNAME="hp_ux110"
548                         ;;
549                 hppa*-hp-hpux11.11)
550                         AFS_SYSNAME="hp_ux11i"
551                         ;;
552                 hppa*-hp-hpux11.23)
553                         AFS_SYSNAME="hp_ux1123"
554                         ;;
555                 ia64-hp-hpux11.22)
556                         AFS_SYSNAME="ia64_hpux1122"
557                         ;;
558                 ia64-hp-hpux*)
559                         AFS_SYSNAME="ia64_hpux1123"
560                         ;;
561                 hppa*-hp-hpux10*)
562                         AFS_SYSNAME="hp_ux102"
563                         ;;
564                 powerpc-apple-darwin7*)
565                         AFS_SYSNAME="ppc_darwin_70"
566                         OSXSDK="macosx10.3"
567                         ;;
568                 powerpc-apple-darwin8.*)
569                         AFS_SYSNAME="ppc_darwin_80"
570                         OSXSDK="macosx10.4"
571                         ;;
572                 i386-apple-darwin8.*)
573                         AFS_SYSNAME="x86_darwin_80"
574                         OSXSDK="macosx10.4"
575                         ;;
576                 powerpc-apple-darwin9.*)
577                         AFS_SYSNAME="ppc_darwin_90"
578                         OSXSDK="macosx10.5"
579                         ;;
580                 i386-apple-darwin9.*)
581                         AFS_SYSNAME="x86_darwin_90"
582                         OSXSDK="macosx10.5"
583                         ;;
584                 i?86-apple-darwin10.*)
585                         AFS_SYSNAME="x86_darwin_100"
586                         OSXSDK="macosx10.6"
587                         ;;
588                 x86_64-apple-darwin10.*)
589                         AFS_SYSNAME="x86_darwin_100"
590                         OSXSDK="macosx10.6"
591                         ;;
592                 arm-apple-darwin10.*)
593                         AFS_SYSNAME="arm_darwin_100"
594                         OSXSDK="iphoneos4.0"
595                         ;;
596                 x86_64-apple-darwin11.*)
597                         AFS_SYSNAME="x86_darwin_110"
598                         OSXSDK="macosx10.7"
599                         ;;
600                 i?86-apple-darwin11.*)
601                         AFS_SYSNAME="x86_darwin_110"
602                         OSXSDK="macosx10.7"
603                         ;;
604                 x86_64-apple-darwin12.*)
605                         AFS_SYSNAME="x86_darwin_120"
606                         OSXSDK="macosx10.8"
607                         ;;
608                 i?86-apple-darwin12.*)
609                         AFS_SYSNAME="x86_darwin_120"
610                         OSXSDK="macosx10.8"
611                         ;;
612                 sparc-sun-solaris2.8)
613                         AFS_SYSNAME="sun4x_58"
614                         ;;
615                 sparc-sun-solaris2.9)
616                         AFS_SYSNAME="sun4x_59"
617                         ;;
618                 sparc-sun-solaris2.10)
619                         AFS_SYSNAME="sun4x_510"
620                         ;;
621                 sparc-sun-solaris2.11)
622                         AFS_SYSNAME="sun4x_511"
623                         ;;
624                 i386-pc-solaris2.8)
625                         AFS_SYSNAME="sunx86_58"
626                         ;;
627                 i386-pc-solaris2.9)
628                         AFS_SYSNAME="sunx86_59"
629                         ;;
630                 i386-pc-solaris2.10)
631                         AFS_SYSNAME="sunx86_510"
632                         ;;
633                 i386-pc-solaris2.11)
634                         AFS_SYSNAME="sunx86_511"
635                         ;;
636                 alpha*-dec-osf4.0*)
637                         AFS_SYSNAME="alpha_dux40"
638                         ;;
639                 alpha*-dec-osf5.0*)
640                         AFS_SYSNAME="alpha_dux50"
641                         ;;
642                 alpha*-dec-osf5.1*)
643                         AFS_SYSNAME="alpha_dux51"
644                         ;;
645                 mips-sgi-irix6.5)
646                         AFS_SYSNAME="sgi_65"
647                         ;;
648                 ia64-*-linux*)
649                         AFS_SYSNAME="ia64_linuxXX"
650                         ;;
651                 powerpc-*-linux*)
652                         AFS_SYSNAME="`/bin/arch`_linuxXX"
653                         ;;
654                 powerpc64-*-linux*)
655                         AFS_SYSNAME="ppc64_linuxXX"
656                         ;;
657                 alpha*-linux*)
658                         AFS_SYSNAME="alpha_linux_XX"
659                         ;;
660                 s390-*-linux*)
661                         AFS_SYSNAME="s390_linuxXX"
662                         ;;
663                 s390x-*-linux*)
664                         AFS_SYSNAME="s390x_linuxXX"
665                         ;;
666                 sparc-*-linux*)
667                         AFS_SYSNAME="`/bin/arch`_linuxXX"
668                         ;;
669                 sparc64-*-linux*)
670                         AFS_SYSNAME="sparc64_linuxXX"
671                         ;;
672                 i?86-*-linux*)
673                         AFS_SYSNAME="i386_linuxXX"
674                         ;;
675                 arm*-linux*)
676                         AFS_SYSNAME="arm_linuxXX"
677                         ;;
678                 parisc-*-linux-gnu|hppa-*-linux-gnu)
679                         AFS_SYSNAME="parisc_linuxXX"
680                         enable_pam="no"
681                         ;;
682                 power*-ibm-aix4.2*)
683                         AFS_SYSNAME="rs_aix42"
684                         enable_pam="no"
685                         ;;
686                 power*-ibm-aix4.3*)
687                         AFS_SYSNAME="rs_aix42"
688                         enable_pam="no"
689                         ;;
690                 power*-ibm-aix5.1*)
691                         AFS_SYSNAME="rs_aix51"
692                         enable_pam="no"
693                         ;;
694                 power*-ibm-aix5.2*)
695                         AFS_SYSNAME="rs_aix52"
696                         enable_pam="no"
697                         ;;
698                 power*-ibm-aix5.3*)
699                         AFS_SYSNAME="rs_aix53"
700                         enable_pam="no"
701                         ;;
702                 power*-ibm-aix6.1*)
703                         AFS_SYSNAME="rs_aix61"
704                         enable_pam="no"
705                         ;;
706                 x86_64-*-linux-gnu)
707                         AFS_SYSNAME="amd64_linuxXX"
708                         enable_pam="yes"
709                         ;;
710                 *)
711                         AC_MSG_ERROR(An AFS sysname is required)
712                         exit 1
713                         ;;
714         esac
715         case $AFS_SYSNAME in
716                 *_linux* | *_umlinux*)
717                         if test "x${AFS_SYSKVERS}" = "x"; then
718                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
719                         fi
720                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
721                         AFS_SYSNAME="$_AFS_SYSNAME"
722                         AC_TRY_KBUILD(
723                          [],
724                          [#ifndef CONFIG_USERMODE
725                           #error not UML
726                           #endif],
727                          ac_cv_linux_is_uml=yes,)
728                         if test "${ac_cv_linux_is_uml}" = yes; then
729                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
730                         fi
731                         AFS_SYSNAME="$_AFS_SYSNAME"
732                         ;;
733         esac
734         AC_MSG_RESULT($AFS_SYSNAME)
735 fi
736
737 case $AFS_SYSNAME in
738         *_darwin*)
739                 AC_CHECK_HEADERS(crt_externs.h)
740                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
741                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
742                 AC_SUBST(OSXSDK)
743                 ;;
744 esac
745
746 dnl Some hosts have a separate common param file they should include.  Figure
747 dnl out if we're on one of them now that we know the sysname.
748 case $AFS_SYSNAME in
749     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
750     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
751     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
752     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
753     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
754     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
755     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
756     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
757     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
758     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
759     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
760     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
761     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
762     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
763     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
764     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
765     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
766     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
767     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
768     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
769     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
770     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
771     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
772     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
773     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
774     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
775     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
776     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
777     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
778 # Linux alpha adds an extra underscore for no good reason.
779     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
780     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
781     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
782 esac
783
784 OPENAFS_OSCONF
785
786 case $AFS_SYSNAME in *_linux* | *_umlinux*)
787
788                 # Add (sub-) architecture-specific paths needed by conftests
789                 case $AFS_SYSNAME  in
790                         *_umlinux26)
791                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
792                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
793                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
794                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
795                 esac
796
797                 if test "x$enable_kernel_module" = "xyes"; then
798                  if test "x$enable_debug_kernel" = "xno"; then
799                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
800                  fi
801                  OPENAFS_GCC_SUPPORTS_MARCH
802                  AC_SUBST(P5PLUS_KOPTS)
803                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
804                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
805                  OPENAFS_GCC_SUPPORTS_NO_COMMON
806                  OPENAFS_GCC_SUPPORTS_PIPE
807                  AC_SUBST(LINUX_GCC_KOPTS)
808
809                  dnl Setup the kernel build environment
810                  LINUX_KBUILD_USES_EXTRA_CFLAGS
811                  LINUX_KERNEL_COMPILE_WORKS
812
813                  dnl Check for header files
814                  AC_CHECK_LINUX_HEADER([config.h])
815                  AC_CHECK_LINUX_HEADER([completion.h])
816                  AC_CHECK_LINUX_HEADER([exportfs.h])
817                  AC_CHECK_LINUX_HEADER([freezer.h])
818                  AC_CHECK_LINUX_HEADER([key-type.h])
819                  AC_CHECK_LINUX_HEADER([semaphore.h])
820                  AC_CHECK_LINUX_HEADER([seq_file.h])
821
822                  dnl Type existence checks
823                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
824
825                  dnl Check for structure elements
826                  AC_CHECK_LINUX_STRUCT([address_space_operations],
827                                        [write_begin], [fs.h])
828                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
829                                        [backing-dev.h])
830                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
831                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
832                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
833                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
834                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
835                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
836                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
837                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
838                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
839                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
840                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
841                  AC_CHECK_LINUX_STRUCT([filename], [name], [fs.h])
842                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
843                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
844                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
845                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
846                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
847                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
848                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
849                                        [fs.h])
850                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
851                                        [fs.h])
852                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
853                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
854                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
855                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
856                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
857                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
858                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
859                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
860                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
861                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
862                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
863
864                  dnl Check for typed structure elements
865                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
866                                              [buf], [fs.h])
867
868                  dnl Function existence checks
869
870                  AC_CHECK_LINUX_FUNC([bdi_init],
871                                      [#include <linux/backing-dev.h>],
872                                      [bdi_init(NULL);])
873                  AC_CHECK_LINUX_FUNC([PageChecked],
874                                      [#include <linux/mm.h>
875 #include <linux/page-flags.h>],
876                                      [struct page *_page;
877                                       int bchecked = PageChecked(_page);])
878                  AC_CHECK_LINUX_FUNC([PageFsMisc],
879                                      [#include <linux/mm.h>
880 #include <linux/page-flags.h>],
881                                      [struct page *_page;
882                                       int bchecked = PageFsMisc(_page);])
883                  AC_CHECK_LINUX_FUNC([clear_inode],
884                                      [#include <linux/fs.h>],
885                                      [clear_inode(NULL);])
886                  AC_CHECK_LINUX_FUNC([current_kernel_time],
887                                      [#include <linux/time.h>],
888                                      [struct timespec s;
889                                       s = current_kernel_time();])
890                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
891                                      [#include <linux/fs.h>],
892                                      [d_alloc_anon(NULL);])
893                  AC_CHECK_LINUX_FUNC([d_make_root],
894                                      [#include <linux/fs.h>],
895                                      [d_make_root(NULL);])
896                  AC_CHECK_LINUX_FUNC([do_sync_read],
897                                      [#include <linux/fs.h>],
898                                      [do_sync_read(NULL, NULL, 0, NULL);])
899                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
900                                      [#include <linux/sched.h>],
901                                      [pid_t p; find_task_by_pid(p);])
902                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
903                                      [#include <linux/fs.h>],
904                                      [generic_file_aio_read(NULL,NULL,0,0);])
905                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
906                                      [#include <linux/pagemap.h>],
907                                      [grab_cache_page_write_begin(NULL, 0, 0);])
908                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
909                                      [#include <linux/list.h>],
910                                      [hlist_unhashed(0);])
911                  AC_CHECK_LINUX_FUNC([i_size_read],
912                                      [#include <linux/fs.h>],
913                                      [i_size_read(NULL);])
914                  AC_CHECK_LINUX_FUNC([inode_setattr],
915                                      [#include <linux/fs.h>],
916                                      [inode_setattr(NULL, NULL);])
917                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
918                                      [#include <linux/net.h>],
919                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
920                  AC_CHECK_LINUX_FUNC([page_follow_link],
921                                      [#include <linux/fs.h>],
922                                      [page_follow_link(0,0);])
923                  AC_CHECK_LINUX_FUNC([page_offset],
924                                      [#include <linux/pagemap.h>],
925                                      [page_offset(NULL);])
926                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
927                                      [#include <linux/pagevec.h>],
928                                      [__pagevec_lru_add_file(NULL);])
929                  AC_CHECK_LINUX_FUNC([path_lookup],
930                                      [#include <linux/fs.h>
931                                       #include <linux/namei.h>],
932                                      [path_lookup(NULL, 0, NULL);])
933                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
934                                      [#include <linux/rcupdate.h>],
935                                      [rcu_read_lock();])
936                  AC_CHECK_LINUX_FUNC([set_nlink],
937                                      [#include <linux/fs.h>],
938                                      [set_nlink(NULL, 1);])
939                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
940                                      [#include <linux/splice.h>],
941                                      [splice_direct_to_actor(NULL,NULL,NULL);])
942                  AC_CHECK_LINUX_FUNC([svc_addr_in],
943                                      [#include <linux/sunrpc/svc.h>],
944                                      [svc_addr_in(NULL);])
945                  AC_CHECK_LINUX_FUNC([zero_user_segments],
946                                      [#include <linux/highmem.h>],
947                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
948                  AC_CHECK_LINUX_FUNC([noop_fsync],
949                                      [#include <linux/fs.h>],
950                                      [void *address = &noop_fsync; printk("%p\n", address)];)
951                  AC_CHECK_LINUX_FUNC([kthread_run],
952                                      [#include <linux/kernel.h>
953                                       #include <linux/kthread.h>],
954                                      [kthread_run(NULL, NULL, "test");])
955
956                  dnl Consequences - things which get set as a result of the
957                  dnl                above tests
958                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
959                        [AC_DEFINE([AFS_NONFSTRANS], 1,
960                                   [define to disable the nfs translator])])
961
962                  dnl Assorted more complex tests
963                  LINUX_AIO_NONVECTOR
964                  LINUX_EXPORTS_PROC_ROOT_FS
965                  LINUX_KMEM_CACHE_INIT
966                  LINUX_HAVE_KMEM_CACHE_T
967                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
968                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
969                  LINUX_D_PATH_TAKES_STRUCT_PATH
970                  LINUX_NEW_EXPORT_OPS
971                  LINUX_INODE_SETATTR_RETURN_TYPE
972                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
973                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
974                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
975                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
976                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
977                  LINUX_DOP_D_DELETE_TAKES_CONST
978                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
979                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
980                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
981                  LINUX_FOP_F_FSYNC_TAKES_RANGE
982                  LINUX_AOP_WRITEBACK_CONTROL
983                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
984                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
985                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
986                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
987                  LINUX_KERNEL_SOCK_CREATE
988                  LINUX_EXPORTS_KEY_TYPE_KEYRING
989                  LINUX_NEED_RHCONFIG
990                  LINUX_RECALC_SIGPENDING_ARG_TYPE
991                  LINUX_EXPORTS_TASKLIST_LOCK
992                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
993                  LINUX_STATFS_TAKES_DENTRY
994                  LINUX_REFRIGERATOR
995                  LINUX_HAVE_TRY_TO_FREEZE
996                  LINUX_LINUX_KEYRING_SUPPORT
997                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
998                  LINUX_KEY_ALLOC_NEEDS_CRED
999                  LINUX_INIT_WORK_HAS_DATA
1000                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1001                  LINUX_HAVE_DCACHE_LOCK
1002                  LINUX_D_COUNT_IS_INT
1003                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1004                  LINUX_IOP_CREATE_TAKES_UMODE_T
1005                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1006                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1007                  LINUX_DENTRY_OPEN_TAKES_PATH
1008                  LINUX_D_ALIAS_IS_HLIST
1009                  LINUX_IOP_I_CREATE_TAKES_BOOL
1010                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1011                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1012
1013                  dnl If we are guaranteed that keyrings will work - that is
1014                  dnl  a) The kernel has keyrings enabled
1015                  dnl  b) The code is new enough to give us a key_type_keyring
1016                  dnl then we just disable syscall probing unless we've been
1017                  dnl told otherwise
1018
1019                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1020                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1021                           [enable_linux_syscall_probing="no"],
1022                           [enable_linux_syscall_probing="yes"])
1023                  ])
1024
1025                  dnl Syscall probing needs a few tests of its own, and just
1026                  dnl won't work if the kernel doesn't export init_mm
1027                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1028                    LINUX_EXPORTS_INIT_MM
1029                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1030                      AC_MSG_ERROR(
1031                        [Can't do syscall probing without exported init_mm])
1032                    ])
1033                    LINUX_EXPORTS_SYS_CHDIR
1034                    LINUX_EXPORTS_SYS_OPEN
1035                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1036                              [define to enable syscall table probes])
1037                  ])
1038
1039                  dnl Packaging and SMP build
1040                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1041                    LINUX_WHICH_MODULES
1042                  else
1043                    AC_SUBST(MPS,'SP')
1044                  fi
1045
1046                  dnl Syscall probing
1047                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1048                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1049                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1050                    ])
1051                    ac_cv_linux_exports_sys_call_table=no
1052                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1053                      ac_cv_linux_exports_ia32_sys_call_table=yes
1054                    fi
1055                  else
1056                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1057                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1058                    LINUX_EXPORTS_SYS_CALL_TABLE
1059                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1060                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1061                          linux_syscall_method=none
1062                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1063                             linux_syscall_method=scan
1064                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1065                                linux_syscall_method=scan_with_kallsyms_address
1066                             fi
1067                          fi
1068                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1069                             linux_syscall_method=kallsyms_symbol
1070                          fi
1071                          if test "x$linux_syscall_method" = "xnone"; then
1072                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1073                             linux_syscall_method=scan
1074                          fi
1075                    fi
1076                  fi
1077                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1078                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1079                  fi
1080                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1081                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1082                  fi
1083                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1084                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1085                  else
1086                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1087                  fi
1088                 :
1089                 fi
1090 dnl Linux-only, but just enable always.
1091                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1092 esac
1093
1094 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1095     [ac_cv_sync_fetch_and_add],
1096     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1097                     [ac_cv_sync_fetch_and_add=yes],
1098                     [ac_cv_sync_fetch_and_add=no])
1099 ])
1100 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1101       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1102                 [define if your C compiler has __sync_add_and_fetch])])
1103
1104 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1105     [ac_cv_sockaddr_len],
1106     [AC_TRY_COMPILE( [#include <sys/types.h>
1107 #include <sys/socket.h>],
1108                      [struct sockaddr *a; a->sa_len=0;],
1109                      [ac_cv_sockaddr_len=yes],
1110                      [ac_cv_sockaddr_len=no])
1111 ])
1112 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1113       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1114                  [define if you struct sockaddr sa_len])])
1115
1116 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1117         echo Skipping library tests because they confuse Irix.
1118 else
1119   AC_SEARCH_LIBS([socket], [socket inet])
1120   AC_SEARCH_LIBS([connect], [nsl])
1121   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1122
1123   dnl darwin wants it, aix hates it
1124   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1125   AC_TRY_COMPILE([
1126   #include <stdlib.h>
1127   #include <stdio.h>
1128   #include <sys/types.h>
1129   #include <sys/socket.h>
1130   #include <netinet/in.h>
1131   #include <arpa/inet.h>
1132   #include <arpa/nameser.h>
1133   #include <arpa/nameser_compat.h>
1134   #include <resolv.h>
1135   ], [static int i; i = 0;],
1136   [AC_MSG_RESULT(yes)
1137    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1138   [AC_MSG_RESULT(no)
1139    ])
1140
1141   openafs_save_libs="$LIBS"
1142   AC_MSG_CHECKING([for res_search])
1143   AC_FUNC_RES_SEARCH
1144
1145   if test "$ac_cv_func_res_search" = no; then
1146       for lib in dns nsl resolv; do
1147         if test "$ac_cv_func_res_search" != yes; then
1148           LIBS="-l$lib $LIBS"
1149           AC_FUNC_RES_SEARCH
1150           LIBS="$openafs_save_libs"
1151         fi
1152       done    
1153       if test "$ac_cv_func_res_search" = yes; then
1154         LIB_AFSDB="-l$lib"
1155         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1156         AC_MSG_RESULT([yes, in lib$lib])
1157       else
1158         AC_MSG_RESULT(no)
1159       fi
1160   else
1161     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1162     AC_MSG_RESULT(yes)
1163   fi
1164   
1165 fi
1166 XLIBS="$LIB_AFSDB $XLIBS"
1167
1168 AC_CHECK_RESOLV_RETRANS
1169
1170 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1171     [ac_cv_setsockopt_iprecverr],
1172     [AC_TRY_COMPILE( [
1173 #include <sys/types.h>
1174 #include <sys/socket.h>
1175 #include <netinet/in.h>],
1176 [int on=1;
1177 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1178         [ac_cv_setsockopt_iprecverr=yes],
1179         [ac_cv_setsockopt_iprecverr=no])])
1180
1181 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1182       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1183                  [define if we can receive socket errors via IP_RECVERR])])
1184
1185 PTHREAD_LIBS=error
1186 if test "x$MKAFS_OSTYPE" = OBSD; then
1187         PTHREAD_LIBS="-pthread"
1188 fi
1189 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1190         PTHREAD_LIBS="-pthread"
1191 fi
1192 if test "x$PTHREAD_LIBS" = xerror; then
1193         AC_CHECK_LIB(pthread, pthread_attr_init,
1194                 PTHREAD_LIBS="-lpthread")
1195 fi
1196 if test "x$PTHREAD_LIBS" = xerror; then
1197         AC_CHECK_LIB(pthreads, pthread_attr_init,
1198                 PTHREAD_LIBS="-lpthreads")
1199 fi
1200 if test "x$PTHREAD_LIBS" = xerror; then
1201         AC_CHECK_LIB(c_r, pthread_attr_init,
1202                 PTHREAD_LIBS="-lc_r")
1203 fi
1204 if test "x$PTHREAD_LIBS" = xerror; then
1205         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1206 fi
1207 if test "x$PTHREAD_LIBS" = xerror; then
1208         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1209         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1210                 PTHREAD_LIBS="-lpthread")
1211 fi
1212 if test "x$PTHREAD_LIBS" = xerror; then
1213         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1214 fi
1215 AC_SUBST(PTHREAD_LIBS)
1216
1217 HOST_CPU="$host_cpu"
1218
1219 if test "x$with_bsd_kernel_headers" != "x"; then
1220         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1221 else
1222         BSD_KERNEL_PATH="/usr/src/sys"
1223 fi
1224
1225 if test "x$with_bsd_kernel_build" != "x"; then
1226         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1227 else
1228         case $AFS_SYSNAME in
1229                 *_fbsd_*)
1230                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1231                         ;;
1232                 *_nbsd*)
1233                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1234         esac
1235 fi
1236
1237 # Fast restart
1238 if test "$enable_supergroups" = "yes"; then
1239         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1240 fi
1241
1242 if test "$enable_bitmap_later" = "yes"; then
1243         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1244 fi
1245
1246 if test "$enable_unix_sockets" = "yes"; then
1247         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1248         USE_UNIX_SOCKETS="yes"
1249 else
1250         USE_UNIX_SOCKETS="no"
1251 fi
1252 AC_SUBST(USE_UNIX_SOCKETS)
1253
1254 if test "$enable_namei_fileserver" = "yes"; then
1255         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1256         VFSCK=""
1257 else
1258         if test "$enable_namei_fileserver" = "default"; then
1259                 case $host in
1260                         *-solaris2.10*)
1261                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1262                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1263                                 VFSCK=""
1264                                 ;;
1265                         *-solaris2.11*)
1266                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1267                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1268                                 VFSCK=""
1269                                 ;;
1270                         *)
1271                                 VFSCK="vfsck"
1272                                 ;;
1273                 esac
1274         else
1275                 VFSCK="vfsck"
1276         fi
1277 fi
1278
1279 dnl check for tivoli
1280 AC_MSG_CHECKING(for tivoli tsm butc support)
1281 XBSA_CFLAGS=""
1282 if test "$enable_tivoli_tsm" = "yes"; then
1283         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1284         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1285         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1286         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1287
1288         if test -r "$XBSADIR3/dsmapifp.h"; then
1289                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1290                 XBSA_XLIBS="-ldl"
1291                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1292         elif test -r "$XBSADIR4/dsmapifp.h"; then
1293                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1294                 XBSA_XLIBS="-ldl"
1295                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1296         elif test -r "$XBSADIR1/xbsa.h"; then
1297                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1298                 XBSA_XLIBS=""
1299                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1300         elif test -r "$XBSADIR2/xbsa.h"; then
1301                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1302                 XBSA_XLIBS=""
1303                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1304         else
1305                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1306         fi
1307 else
1308         AC_MSG_RESULT([no])
1309 fi
1310 AC_SUBST(XBSA_CFLAGS)
1311 AC_SUBST(XBSA_XLIBS) 
1312
1313 dnl checks for header files.
1314 AC_HEADER_STDC
1315 AC_HEADER_SYS_WAIT
1316 AC_HEADER_DIRENT
1317 AC_CHECK_HEADERS([ \
1318                    arpa/inet.h \
1319                    arpa/nameser.h \
1320                    curses.h\
1321                    direct.h \
1322                    et/com_err.h \
1323                    errno.h \
1324                    fcntl.h \
1325                    grp.h \
1326                    math.h \
1327                    mntent.h \
1328                    ncurses.h \
1329                    ncurses/ncurses.h \
1330                    netdb.h \
1331                    netinet/in.h \
1332                    pthread_np.h \
1333                    pwd.h \
1334                    regex.h \
1335                    security/pam_appl.h \
1336                    signal.h \
1337                    stdint.h \
1338                    stdio_ext.h \
1339                    stdlib.h \
1340                    string.h \
1341                    strings.h \
1342                    sys/bitypes.h \
1343                    sys/bswap.h \
1344                    sys/dk.h \
1345                    sys/fcntl.h \
1346                    sys/file.h \
1347                    sys/fs_types.h \
1348                    sys/fstyp.h \
1349                    sys/ioctl.h \
1350                    sys/ipc.h \
1351                    sys/lockf.h \
1352                    sys/map.h \
1353                    sys/mount.h \
1354                    sys/mntent.h \
1355                    sys/mnttab.h \
1356                    sys/pag.h \
1357                    sys/param.h \
1358                    sys/resource.h \
1359                    sys/select.h \
1360                    sys/statfs.h \
1361                    sys/statvfs.h \
1362                    sys/socket.h \
1363                    sys/sysctl.h \
1364                    sys/time.h \
1365                    sys/types.h \
1366                    sys/uio.h \
1367                    sys/un.h \
1368                    sys/vfs.h \
1369                    syslog.h \
1370                    termios.h \
1371                    time.h \
1372                    ucontext.h \
1373                    unistd.h \
1374                    windows.h \
1375                 ])
1376
1377 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1378 #ifdef HAVE_NETINET_IN_H
1379 # include <netinet/in.h>
1380 #endif])
1381
1382 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1383 #ifdef HAVE_SYS_SOCKET_H
1384 # include <sys/socket.h>
1385 #endif])
1386
1387 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1388 #ifdef HAVE_SYS_SOCKET_H
1389 # include <sys/socket.h>
1390 #endif
1391 #ifdef HAVE_NETINET_IN_H
1392 # include <netinet/in.h>
1393 #endif
1394 #ifdef HAVE_NET_IF_H
1395 # include <net/if.h>
1396 #endif])
1397
1398 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1399 #ifdef HAVE_SECURITY_PAM_APPL_H
1400 # include <security/pam_appl.h>
1401 #endif])
1402
1403 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1404
1405 AC_CHECK_TYPES([fsblkcnt_t],,,[
1406 #include <sys/types.h>
1407 #ifdef HAVE_SYS_BITYPES_H
1408 #include <sys/bitypes.h>
1409 #endif
1410 #ifdef HAVE_SYS_STATFS_H
1411 #include <sys/statfs.h>
1412 #endif
1413 #ifdef HAVE_SYS_STATVFS_H
1414 #include <sys/statvfs.h>
1415 #endif
1416 ])
1417
1418 dnl see what struct stat has for timestamps
1419 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1420
1421 dnl check for curses-lib
1422 AS_IF([test "x$enable_gtx" != "xno"],
1423       [save_LIBS=$LIBS
1424       AC_CHECK_LIB( [ncurses], [setupterm],
1425       [LIB_curses=-lncurses],
1426         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1427           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1428       ])
1429       LIBS=$save_LIBS
1430       AC_SUBST(LIB_curses)])
1431         
1432 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1433
1434 if test "$enable_debug_locks" = yes; then
1435         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1436 fi
1437
1438 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1439 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1440         case $AFS_SYSNAME in
1441         sgi_*)
1442                 HAVE_PAM="no"
1443                 ;;
1444         *)
1445                 HAVE_PAM="yes"
1446                 ;;
1447         esac
1448 else
1449         HAVE_PAM="no"
1450 fi
1451 AC_SUBST(HAVE_PAM)
1452
1453 if test "$enable_login" = yes; then
1454         BUILD_LOGIN="yes"
1455 else
1456         BUILD_LOGIN="no"
1457 fi
1458 AC_SUBST(BUILD_LOGIN)
1459
1460 if test "$enable_uss" = yes; then
1461         BUILD_USS="yes"
1462 else
1463         BUILD_USS="no"
1464 fi
1465 AC_SUBST(BUILD_USS)
1466
1467 if test "$enable_kauth" = yes; then
1468         INSTALL_KAUTH="yes"
1469 else
1470         INSTALL_KAUTH="no"
1471 fi
1472 AC_SUBST(INSTALL_KAUTH)
1473
1474 AC_CHECK_FUNCS([ \
1475         arc4random \
1476         fcntl \
1477         fseeko64 \
1478         ftello64 \
1479         getcwd \
1480         getegid \
1481         geteuid \
1482         getgid \
1483         getuid \
1484         getrlimit \
1485         issetugid \
1486         mkstemp \
1487         poll \
1488         pread \
1489         preadv \
1490         preadv64 \
1491         pwrite \
1492         pwritev \
1493         pwritev64 \
1494         regcomp \
1495         regerror \
1496         regexec \
1497         setitimer \
1498         setvbuf \
1499         sigaction \
1500         strcasestr \
1501         strerror \
1502         sysconf \
1503         sysctl \
1504         tdestroy \
1505         timegm \
1506 ])
1507
1508 OPENAFS_ROKEN()
1509 OPENAFS_C_ATTRIBUTE()
1510
1511 dnl Functions that Heimdal's libroken provides, but that we
1512 dnl haven't found a need for yet, and so haven't imported
1513 AC_CHECK_FUNCS([ \
1514         chown \
1515         fchown \
1516         gethostname \
1517         lstat \
1518         inet_aton \
1519         inet_ntop \
1520         inet_pton \
1521         putenv \
1522         readv \
1523         setenv \
1524         strdup \
1525         strftime \
1526         strndup \
1527         strsep \
1528         unsetenv \
1529 ])
1530
1531 dnl Functions that are in objects that we always build from libroken
1532 AC_CHECK_FUNCS([ \
1533         asprintf \
1534         asnprintf \
1535         vasprintf \
1536         vasnprintf \
1537         vsnprintf \
1538         snprintf \
1539 ])
1540
1541 dnl Functions that we're going to try and get from libroken
1542 AC_REPLACE_FUNCS([ \
1543         daemon \
1544         ecalloc \
1545         emalloc \
1546         erealloc \
1547         err \
1548         errx \
1549         flock \
1550         getdtablesize \
1551         getopt \
1552         getprogname \
1553         gettimeofday \
1554         localtime_r \
1555         mkstemp \
1556         setenv \
1557         setprogname \
1558         strcasecmp \
1559         strlcat \
1560         strnlen \
1561         strlcpy \
1562         strsep \
1563         tdelete \
1564         tfind \
1565         tsearch \
1566         twalk \
1567         unsetenv \
1568         verr \
1569         verrx \
1570         vsyslog \
1571         vwarn \
1572         vwarnx \
1573         warn \
1574         warnx \
1575 ])
1576
1577 dnl Headers that we're going to try and get from libroken
1578 AC_CHECK_HEADERS([ \
1579         err.h \
1580         search.h \
1581 ])
1582
1583 AC_CHECK_DECLS([h_errno], [], [], [
1584 #include <sys/types.h>
1585 #ifdef HAVE_NETDB_H
1586 #include <netdb.h>
1587 #endif
1588 ])
1589
1590 AC_HEADER_TIME
1591
1592 ROKEN_HEADERS=
1593 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1594       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1595       [])
1596 AC_SUBST(ROKEN_HEADERS)
1597
1598 dnl Stuff that's harder ...
1599 AC_MSG_CHECKING([for bswap16])
1600 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1601 #ifdef HAVE_SYS_TYPES_H
1602 #include <sys/types.h>
1603 #endif
1604 #ifdef HAVE_SYS_BSWAP_H
1605 #include <sys/bswap.h>
1606 #endif
1607 ],
1608 [short a, b; b = bswap16(a); ])],
1609 [AC_MSG_RESULT(yes)
1610  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1611 ],
1612 [AC_MSG_RESULT(no)])
1613
1614 AC_MSG_CHECKING([for bswap32])
1615 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1616 #include <sys/types.h>
1617 #endif
1618 #ifdef HAVE_SYS_BSWAP_H
1619 #include <sys/bswap.h>
1620 #endif
1621 ],
1622 [int a, b; b = bswap32(a); ])],
1623 [AC_MSG_RESULT(yes)
1624  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1625 ],
1626 [AC_MSG_RESULT(no)])
1627
1628 case $AFS_SYSNAME in
1629 *hp_ux* | *hpux*)
1630    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1631    ;;
1632 *)
1633    AC_MSG_CHECKING([for positional I/O])
1634    if test "$ac_cv_func_pread" = "yes" && \
1635            test "$ac_cv_func_pwrite" = "yes"; then
1636       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1637       AC_MSG_RESULT(yes)
1638    else
1639      AC_MSG_RESULT(no)
1640    fi
1641    AC_MSG_CHECKING([for vectored positional I/O])
1642    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1643                "$ac_cv_func_pwritev" = "yes" -a \
1644                "$ac_cv_func_preadv64" = "yes" -a \
1645                "$ac_cv_func_pwritev64" = "yes"],
1646          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1647           AC_MSG_RESULT(yes)],
1648          [AC_MSG_RESULT(no)])
1649    ;;
1650 esac
1651
1652 AC_MSG_CHECKING([for POSIX regex library])
1653 if test "$ac_cv_header_regex_h" = "yes" && \
1654         test "$ac_cv_func_regcomp" = "yes" && \
1655         test "$ac_cv_func_regexec" = "yes" && \
1656         test "$ac_cv_func_regerror" = "yes"; then
1657     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1658     AC_MSG_RESULT(yes)
1659 else
1660     AC_MSG_RESULT(no)
1661 fi
1662
1663 dnl Look for "non-portable" pthreads functions.
1664 save_LIBS="$LIBS"
1665 LIBS="$LIBS $PTHREAD_LIBS"
1666 AC_CHECK_FUNCS([ \
1667         pthread_set_name_np \
1668         pthread_setname_np \
1669 ])
1670
1671 dnl Sadly, there are three different versions of pthread_setname_np.
1672 dnl Try to cater for all of them.
1673 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1674     AC_MSG_CHECKING([for signature of pthread_setname_np])
1675     AC_TRY_COMPILE([
1676 #include <pthread.h>
1677 #ifdef HAVE_PTHREAD_NP_H
1678 #include <pthread_np.h>
1679 #endif
1680 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1681         AC_MSG_RESULT([three arguments])
1682         pthread_setname_np_args=3], [
1683         AC_TRY_COMPILE([
1684 #include <pthread.h>
1685 #ifdef HAVE_PTHREAD_NP_H
1686 #include <pthread_np.h>
1687 #endif
1688 ], [pthread_setname_np(pthread_self(), "test")], [
1689             AC_MSG_RESULT([two arguments])
1690             pthread_setname_np_args=2], [
1691             AC_TRY_COMPILE([
1692 #include <pthread.h>
1693 #ifdef HAVE_PTHREAD_NP_H
1694 #include <pthread_np.h>
1695 #endif
1696 ], [pthread_setname_np("test")], [
1697                 AC_MSG_RESULT([one argument])
1698                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1699 ])
1700 ])
1701 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1702 fi
1703 LIBS="$save_LIBS"
1704
1705 openafs_cv_saved_CFLAGS="$CFLAGS"
1706 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1707
1708 AC_TYPE_SIGNAL
1709 OPENAFS_RETSIGTYPE
1710 AC_CHECK_SIZEOF(void *)
1711 AC_CHECK_SIZEOF(unsigned long long)
1712 AC_CHECK_SIZEOF(unsigned long)
1713 AC_CHECK_SIZEOF(unsigned int)
1714 AC_TYPE_INTPTR_T
1715 AC_TYPE_UINTPTR_T
1716 AC_TYPE_SSIZE_T
1717 AC_CHECK_TYPE([sig_atomic_t],[],
1718     [AC_DEFINE([sig_atomic_t], [int],
1719         [Define to int if <signal.h> does not define.])],
1720 [#include <sys/types.h>
1721 #include <signal.h>])
1722 AC_CHECK_TYPE([socklen_t],[],
1723     [AC_DEFINE([socklen_t], [int],
1724         [Define to int if <sys/socket.h> does not define.])],
1725 [#include <sys/types.h>
1726 #include <sys/socket.h>])
1727 AC_CHECK_TYPES(off64_t)
1728 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1729 AC_CHECK_TYPES([struct winsize], [], [], [
1730 #ifdef HAVE_TERMIOS_H
1731 # include <termios.h>
1732 #else
1733 # include <sys/termios.h>
1734 #endif
1735 #include <sys/ioctl.h>])
1736 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1737                 struct sockaddr_storage],
1738                [], [], [
1739 #include <sys/types.h>
1740 #include <sys/socket.h>
1741 ])
1742 AC_CHECK_TYPES([sa_family_t], [], [], [
1743 #include <sys/types.h>
1744 #include <sys/socket.h>
1745 ])
1746 AC_CHECK_TYPES([struct addrinfo], [], [], [
1747 #include <sys/types.h>
1748 #ifdef HAVE_NETDB_H
1749 #include <netdb.h>
1750 #endif
1751 ])
1752 AC_CHECK_TYPES([long long], [], [], [])
1753
1754 AC_SIZEOF_TYPE(long)
1755
1756 CFLAGS="$openafs_cv_saved_CFLAGS"
1757
1758 RRA_HEADER_PAM_CONST
1759
1760
1761 dnl Directory PATH handling
1762 if test "x$enable_transarc_paths" = "xyes"  ; then 
1763     afsconfdir=${afsconfdir=/usr/afs/etc}
1764     viceetcdir=${viceetcdir=/usr/vice/etc}
1765     afskerneldir=${afskerneldir=${viceetcdir}}
1766     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1767     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1768     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1769     afsdbdir=${afsdbdir=/usr/afs/db}
1770     afslogsdir=${afslogsdir=/usr/afs/logs}
1771     afslocaldir=${afslocaldir=/usr/afs/local}
1772     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1773     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1774     afsdatadir=${afsdatadir=/usr/vice/etc}
1775 else 
1776     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1777     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1778     afskerneldir=${afskerneldir='${libdir}/openafs'}
1779     afssrvbindir=${afssrvbindir='${bindir}'}
1780     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1781     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1782     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1783     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1784     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1785     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1786     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1787     afsdatadir=${afsdatadir='${datadir}/openafs'}
1788 fi
1789 AC_SUBST(afsconfdir)
1790 AC_SUBST(viceetcdir)
1791 AC_SUBST(afskerneldir)
1792 AC_SUBST(afssrvbindir)
1793 AC_SUBST(afssrvsbindir)
1794 AC_SUBST(afssrvlibexecdir)
1795 AC_SUBST(afsdbdir)
1796 AC_SUBST(afslogsdir)
1797 AC_SUBST(afslocaldir)
1798 AC_SUBST(afsbackupdir)
1799 AC_SUBST(afsbosconfigdir)
1800 AC_SUBST(afsdatadir)
1801
1802 if test "x$enable_kernel_module" = "xyes"; then
1803 ENABLE_KERNEL_MODULE=libafs
1804 fi
1805
1806 if test "x$enable_pthreaded_ubik" = "xyes"; then
1807 ENABLE_PTHREADED_UBIK=yes
1808 fi
1809
1810 AC_SUBST(VFSCK)
1811 AC_SUBST(AFS_SYSNAME)
1812 AC_SUBST(AFS_PARAM_COMMON)
1813 AC_SUBST(ENABLE_KERNEL_MODULE)
1814 AC_SUBST(ENABLE_PTHREADED_UBIK)
1815 AC_SUBST(LIB_AFSDB)
1816 AC_SUBST(LINUX_KERNEL_PATH)
1817 AC_SUBST(LINUX_KERNEL_BUILD)
1818 AC_SUBST(HOST_CPU)
1819 AC_SUBST(BSD_KERNEL_PATH)
1820 AC_SUBST(BSD_KERNEL_BUILD)
1821 AC_SUBST(LINUX_VERSION)
1822 AC_SUBST(MKAFS_OSTYPE)
1823 AC_SUBST(TOP_OBJDIR)
1824 AC_SUBST(TOP_SRCDIR)
1825 AC_SUBST(TOP_INCDIR)
1826 AC_SUBST(TOP_LIBDIR)
1827 AC_SUBST(DEST)
1828 AC_SUBST(DARWIN_INFOFILE)
1829 AC_SUBST(IRIX_BUILD_IP35)
1830 AC_SUBST(HTML_XSL)
1831 AC_SUBST(XSLTPROC)
1832 AC_SUBST(DOCBOOK2PDF)
1833 AC_SUBST(DOCBOOK_STYLESHEETS)
1834
1835 OPENAFS_FUSE
1836 OPENAFS_SWIG
1837
1838 TOP_SRCDIR="${srcdir}/src"
1839 dnl
1840 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1841 dnl
1842 case $TOP_SRCDIR in
1843         /*)
1844                 ;;
1845         *)
1846                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1847                 ;;
1848 esac
1849
1850 TOP_OBJDIR="${SRCDIR_PARENT}"
1851 TOP_INCDIR="${SRCDIR_PARENT}/include"
1852 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1853 if test "${DEST}x" = "x"; then
1854         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1855 fi
1856
1857 if test "x$with_crosstools_dir" != "x"; then
1858         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1859                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1860                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1861                 RXGEN_PATH=$with_crosstools_dir/rxgen
1862         else
1863                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1864                 exit 1
1865         fi
1866 else
1867         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1868         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1869         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1870 fi
1871 AC_SUBST(COMPILE_ET_PATH)
1872 AC_SUBST(CONFIGTOOL_PATH)
1873 AC_SUBST(RXGEN_PATH)
1874
1875 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1876 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1877 AC_SUBST(HELPER_SPLINT)
1878 AC_SUBST(HELPER_SPLINTCFG)
1879
1880 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1881
1882 dnl Check to see if crypt lives in a different library
1883 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1884 AC_SUBST(LIB_crypt)
1885
1886 dnl Check to see if the compiler support labels in structs
1887 AC_MSG_CHECKING(for label support in structs)
1888 AC_TRY_COMPILE([], [
1889 extern void osi_UFSOpen(void);
1890 struct labeltest {
1891    void (*open) (void);
1892 };
1893 struct labeltest struct_labeltest = {
1894    .open       = osi_UFSOpen,
1895 }
1896 ],
1897 [AC_MSG_RESULT(yes)
1898  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1899 ],
1900 [AC_MSG_RESULT(no)
1901 ])
1902
1903 AC_MSG_CHECKING([checking for dirfd])
1904 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1905 #ifdef HAVE_DIRENT_H
1906 #include <dirent.h>
1907 #endif
1908 ]],
1909         [[DIR *d = 0; dirfd(d);]])],
1910         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1911 if test "$ac_rk_have_dirfd" = "yes" ; then
1912         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1913 fi
1914 AC_MSG_RESULT($ac_rk_have_dirfd)
1915
1916 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1917 #ifdef HAVE_DIRENT_H
1918 #include <dirent.h>
1919 #endif])
1920
1921 dnl Eventually, this will look for the system one, or for OpenSSL
1922 LIB_hcrypto="-lafshcrypto"
1923 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1924 AC_SUBST(LIB_hcrypto)
1925 AC_SUBST(LDFLAGS_hcrypto)
1926
1927 dnl Check for UUID library
1928 AC_CHECK_HEADERS([uuid/uuid.h])
1929 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1930 AC_CHECK_FUNCS([uuid_generate])
1931 ])
1932
1933
1934 AC_DEFUN([SUMMARY], [
1935     # Print a configuration summary
1936 echo 
1937 echo "**************************************"
1938 echo configure summary
1939 echo
1940 AS_IF([test $LIB_curses],[
1941 echo "LIB_curses :                $LIB_curses" ],[
1942 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1943 ])
1944 echo 
1945 echo "**************************************"
1946 ])