acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #   define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 #define _FILE_OFFSET_BITS 64
  48 #define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 #include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
  76
  77 dnl General feature options.
  78 AC_ARG_ENABLE([pam],
  79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
  80     ,
  81     [enable_pam="yes"])
  82 AC_ARG_ENABLE([gtx],
  83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
  84 AC_ARG_ENABLE([uss],
  85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
  86 AC_ARG_ENABLE([namei-fileserver],
  87     [AS_HELP_STRING([--enable-namei-fileserver],
  88         [force compilation of namei fileserver in preference to inode
  89          fileserver])],
  90     ,
  91     [enable_namei_fileserver="default"])
  92 AC_ARG_ENABLE([supergroups],
  93     [AS_HELP_STRING([--enable-supergroups],
  94         [enable support for nested pts groups])],
  95     ,
  96     [enable_supergroups="no"])
  97 AC_ARG_ENABLE([bitmap-later],
  98     [AS_HELP_STRING([--enable-bitmap-later],
  99         [enable fast startup of file server by not reading bitmap till
 100          needed])],
 101     ,
 102     [enable_bitmap_later="no"])
 103 AC_ARG_ENABLE([unix-sockets],
 104     [AS_HELP_STRING([--disable-unix-sockets],
 105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 106     ,
 107     [enable_unix_sockets="yes"])
 108 AC_ARG_ENABLE([tivoli-tsm],
 109     [AS_HELP_STRING([--enable-tivoli-tsm],
 110         [enable use of the Tivoli TSM API libraries for butc support])],
 111     ,
 112     [enable_tivoli_tsm="no"])
 113 AC_ARG_ENABLE([pthreaded-ubik],
 114     [AS_HELP_STRING([--enable-pthreaded-ubik],
 115         [enable installation of pthreaded ubik applications (defaults to
 116          disabled)])],
 117     ,
 118     [enable_pthreaded_ubik="no"])
 119
 120 dnl Kernel module build options.
 121 AC_ARG_WITH([linux-kernel-headers],
 122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 123         [use the kernel headers found at path (optional, defaults to
 124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
 125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
 126 AC_ARG_WITH([linux-kernel-build],
 127     [AS_HELP_STRING([--with-linux-kernel-build=path],
 128         [use the kernel build found at path(optional, defaults to
 129         kernel headers path)])])
 130 AC_ARG_WITH([bsd-kernel-headers],
 131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 132         [use the kernel headers found at path (optional, defaults to
 133          /usr/src/sys)])])
 134 AC_ARG_WITH([bsd-kernel-build],
 135     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 136         [use the kernel build found at path (optional, defaults to
 137          KSRC/i386/compile/GENERIC)])])
 138 AC_ARG_WITH([linux-kernel-packaging],
 139     [AS_HELP_STRING([--with-linux-kernel-packaging],
 140         [use standard naming conventions to aid Linux kernel build packaging
 141          (disables MPS, sets the kernel module name to openafs.ko, and
 142          installs kernel modules into the standard Linux location)])],
 143     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
 144      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
 145     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
 146 AC_ARG_ENABLE([kernel-module],
 147     [AS_HELP_STRING([--disable-kernel-module],
 148         [disable compilation of the kernel module (defaults to enabled)])],
 149     ,
 150     [enable_kernel_module="yes"])
 151 AC_ARG_ENABLE([redhat-buildsys],
 152     [AS_HELP_STRING([--enable-redhat-buildsys],
 153         [enable compilation of the redhat build system kernel (defaults to
 154          disabled)])],
 155     ,
 156     [enable_redhat_buildsys="no"])
 157
 158 dnl Installation locations.
 159 AC_ARG_ENABLE([transarc-paths],
 160     [AS_HELP_STRING([--enable-transarc-paths],
 161         [use Transarc style paths like /usr/afs and /usr/vice])],
 162     ,
 163     [enable_transarc_paths="no"])
 164
 165 dnl Deprecated crypto
 166 AC_ARG_ENABLE([kauth],
 167     [AS_HELP_STRING([--disable-kauth],
 168         [do not install the deprecated kauth server and utilities (defaults to
 169          enabled)])],
 170     ,
 171     [enable_kauth="yes"])
 172
 173 dnl Optimization and debugging flags.
 174 AC_ARG_ENABLE([strip-binaries],
 175     [AS_HELP_STRING([--disable-strip-binaries],
 176         [disable stripping of symbol information from binaries (defaults to
 177          enabled)])],
 178     ,
 179     [enable_strip_binaries="maybe"])
 180 AC_ARG_ENABLE([debug],
 181     [AS_HELP_STRING([--enable-debug],
 182         [enable compilation of the user space code with debugging information
 183          (defaults to disabled)])],
 184     ,
 185     [enable_debug="no"])
 186 AC_ARG_ENABLE([optimize],
 187     [AS_HELP_STRING([--disable-optimize],
 188         [disable optimization for compilation of the user space code (defaults
 189          to enabled)])],
 190     ,
 191     [enable_optimize="yes"])
 192 AC_ARG_ENABLE([warnings],
 193     [AS_HELP_STRING([--enable-warnings],
 194         [enable compilation warnings when building with gcc (defaults to
 195          disabled)])],
 196     ,
 197     [enable_warnings="no"])
 198 AC_ARG_ENABLE([checking],
 199     [AS_HELP_STRING([--enable-checking],
 200         [turn compilation warnings into errors when building with gcc (defaults
 201          to disabled)])],
 202     [enable_checking="$enableval"],
 203     [enable_checking="no"])
 204 AC_ARG_ENABLE([debug-locks],
 205     [AS_HELP_STRING([--enable-debug-locks],
 206         [turn on lock debugging assertions (defaults to disabled)])],
 207     [enable_debug_locks="$enableval"],
 208     [enable_debug_locks="no"])
 209 AC_ARG_ENABLE([debug-kernel],
 210     [AS_HELP_STRING([--enable-debug-kernel],
 211         [enable compilation of the kernel module with debugging information
 212          (defaults to disabled)])],
 213     ,
 214     [enable_debug_kernel="no"])
 215 AC_ARG_ENABLE([optimize-kernel],
 216     [AS_HELP_STRING([--disable-optimize-kernel],
 217         [disable compilation of the kernel module with optimization (defaults
 218          based on platform)])],
 219     ,
 220     [enable_optimize_kernel=""])
 221 AC_ARG_ENABLE([debug-lwp],
 222     [AS_HELP_STRING([--enable-debug-lwp],
 223         [enable compilation of the LWP code with debugging information
 224          (defaults to disabled)])],
 225     ,
 226     [enable_debug_lwp="no"])
 227 AC_ARG_ENABLE([optimize-lwp],
 228     [AS_HELP_STRING([--disable-optimize-lwp],
 229         [disable optimization for compilation of the LWP code (defaults to
 230          enabled)])],
 231     ,
 232     [enable_optimize_lwp="yes"])
 233 AC_ARG_ENABLE([debug-pam],
 234     [AS_HELP_STRING([--enable-debug-pam],
 235         [enable compilation of the PAM code with debugging information
 236          (defaults to disabled)])],
 237     ,
 238     [enable_debug_pam="no"])
 239 AC_ARG_ENABLE([optimize-pam],
 240     [AS_HELP_STRING([--disable-optimize-pam],
 241         [disable optimization for compilation of the PAM code (defaults to
 242          enabled)])],
 243     ,
 244     [enable_optimize_pam="yes"])
 245 AC_ARG_ENABLE([linux-syscall-probing],
 246     [AS_HELP_STRING([--enable-linux-syscall-probing],
 247         [enable Linux syscall probing (defaults to autodetect)])],
 248     ,
 249     [enable_linux_syscall_probing="maybe"])
 250 AC_ARG_WITH([crosstools-dir],
 251     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
 252
 253 AC_ARG_WITH([xslt-processor],
 254         AS_HELP_STRING([--with-xslt-processor=ARG],
 255         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 256         [XSLTPROC="$withval"],
 257         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
 258
 259 AC_ARG_WITH([html-xsl],
 260         AS_HELP_STRING([--with-html-xsl],
 261         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 262         [HTML_XSL="$withval"],
 263         [HTML_XSL="html/chunk.xsl"])
 264
 265 AC_ARG_WITH([docbook2pdf],
 266         AS_HELP_STRING([--with-docbook2pdf=ARG],
 267         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 268         [DOCBOOK2PDF="$withval"],
 269         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
 270
 271 AC_ARG_WITH([docbook-stylesheets],
 272         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 273         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 274         [DOCBOOK_STYLESHEETS="$withval"],
 275         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
 276         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
 277                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 278         fi)
 279
 280 enable_login="no"
 281
 282 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 283 dnl documentation build.
 284 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 285
 286 dnl weird ass systems
 287 dnl AC_AIX
 288 AC_ISC_POSIX
 289 dnl AC_MINIX
 290
 291 dnl Various compiler setup.
 292 AC_TYPE_PID_T
 293 AC_TYPE_SIZE_T
 294
 295 dnl Checks for programs.
 296 AC_PROG_INSTALL
 297 AC_PROG_LN_S
 298 AC_PROG_RANLIB
 299 AC_PROG_YACC
 300 AM_PROG_LEX
 301 dnl if we are flex, be lex-compatible
 302 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 303
 304 OPENAFS_FORCE_ABS_INSTALL
 305 OPENAFS_CHECK_BIGENDIAN
 306 OPENAFS_PRINTF_TAKES_Z_LEN
 307
 308 AC_MSG_CHECKING(your OS)
 309 system=$host
 310 case $system in
 311         *-linux*)
 312
 313                 MKAFS_OSTYPE=LINUX
 314                 if test "x$enable_redhat_buildsys" = "xyes"; then
 315                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 316                 fi
 317                 if test "x$enable_kernel_module" = "xyes"; then
 318                  if test "x$with_linux_kernel_headers" != "x"; then
 319                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 320                  else
 321                    for utsdir in "/lib/modules/`uname -r`/build" \
 322                                  "/lib/modules/`uname -r`/source" \
 323                                  "/usr/src/linux-2.4" \
 324                                  "/usr/src/linux"; do
 325                      LINUX_KERNEL_PATH="$utsdir"
 326                      for utsfile in "include/generated/utsrelease.h" \
 327                                     "include/linux/utsrelease.h" \
 328                                     "include/linux/version.h" \
 329                                     "include/linux/version-up.h"; do
 330                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
 331                          break 2
 332                        fi
 333                      done
 334                    done
 335                  fi
 336                  if test "x$with_linux_kernel_build" != "x"; then
 337                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 338                  else
 339                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 340                  fi
 341                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 342                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 343                    LINUX_VERSION="$linux_kvers"
 344                  else
 345                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 346                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 347                      LINUX_VERSION="$linux_kvers"
 348                    else
 349                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 350                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 351                        if test "x$linux_kvers" = "x"; then
 352                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 353                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 354                            if test "x$linux_kvers" = "x"; then
 355                              AC_MSG_ERROR(Linux headers lack version definition [2])
 356                              exit 1
 357                            else
 358                              LINUX_VERSION="$linux_kvers"
 359                            fi
 360                          else
 361                            AC_MSG_ERROR(Linux headers lack version definition)
 362                            exit 1
 363                          fi
 364                        else
 365                          LINUX_VERSION="$linux_kvers"
 366                        fi
 367                      else
 368                        enable_kernel_module="no"
 369                      fi
 370                    fi
 371                  fi
 372                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 373                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 374                      enable_kernel_module="no"
 375                  fi
 376                  if test "x$enable_kernel_module" = "xno"; then
 377                   if test "x$with_linux_kernel_headers" != "x"; then
 378                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 379                    exit 1
 380                   else
 381                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 382                   fi
 383                  fi
 384                  dnl do we need to determine SUBARCH from autoconf.h
 385                  SUBARCH=default
 386                 fi
 387                 AC_MSG_RESULT(linux)
 388                 if test "x$enable_kernel_module" = "xyes"; then
 389                  case "$LINUX_VERSION" in
 390                   2.2.*) AFS_SYSKVERS=22 ;;
 391                   2.4.*) AFS_SYSKVERS=24 ;;
 392                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
 393                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 394                  esac
 395                 fi
 396                 ;;
 397         *-solaris*)
 398                 MKAFS_OSTYPE=SOLARIS
 399                 AC_MSG_RESULT(sun4)
 400                 AC_PATH_PROG(SOLARISCC, [cc], ,
 401                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 402                 if test "x$SOLARISCC" = "x" ; then
 403                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 404                 fi
 405                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 406                 SOLARIS_FS_HAS_FS_ROLLED
 407                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 408                 SOLARIS_HAVE_VN_RENAMEPATH
 409                 ;;
 410         *-sunos*)
 411                 MKAFS_OSTYPE=SUNOS
 412                 enable_kernel_module=no
 413                 AC_MSG_RESULT(sun4)
 414                 ;;
 415         *-hpux*)
 416                 MKAFS_OSTYPE=HPUX
 417                 AC_MSG_RESULT(hp_ux)
 418                 if test -f "/usr/old/usr/include/ndir.h"; then
 419                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 420                 fi
 421                 ;;
 422         *-irix*)
 423                 if test -d /usr/include/sys/SN/SN1; then
 424                  IRIX_BUILD_IP35="IP35"
 425                 fi
 426                 MKAFS_OSTYPE=IRIX
 427                 AC_MSG_RESULT(sgi)
 428                 ;;
 429         *-aix*)
 430                 MKAFS_OSTYPE=AIX
 431                 AC_MSG_RESULT(rs_aix)
 432                 ;;
 433         arm-*-darwin*)
 434                 MKAFS_OSTYPE=DARWIN
 435                 AC_MSG_RESULT(arm_darwin)
 436                 ;;
 437         powerpc-*-darwin*)
 438                 MKAFS_OSTYPE=DARWIN
 439                 AC_MSG_RESULT(ppc_darwin)
 440                 ;;
 441         i386-*-darwin*)
 442                 MKAFS_OSTYPE=DARWIN
 443                 AC_MSG_RESULT(x86_darwin)
 444                 ;;
 445         x86_64-*-darwin*)
 446                 MKAFS_OSTYPE=DARWIN
 447                 AC_MSG_RESULT(x86_darwin)
 448                 ;;
 449         i386-*-freebsd*)
 450                 MKAFS_OSTYPE=FBSD
 451                 AC_MSG_RESULT(i386_fbsd)
 452                 ;;
 453         x86_64-*-freebsd*)
 454                 MKAFS_OSTYPE=FBSD
 455                 AC_MSG_RESULT(amd64_fbsd)
 456                 ;;
 457         *-netbsd*)
 458                 MKAFS_OSTYPE=NBSD
 459                 AC_MSG_RESULT(nbsd)
 460                 ;;
 461         x86_64-*-openbsd*)
 462                 MKAFS_OSTYPE=OBSD
 463                 AC_MSG_RESULT(amd64_obsd)
 464                 ;;
 465         i386-*-openbsd*)
 466                 MKAFS_OSTYPE=OBSD
 467                 AC_MSG_RESULT(i386_obsd)
 468                 ;;
 469         *-dragonfly*)
 470                 MKAFS_OSTYPE=DFBSD
 471                 AC_MSG_RESULT(i386_dfbsd)
 472                 ;;
 473         *)
 474                 AC_MSG_RESULT($system)
 475                 ;;
 476 esac
 477
 478 if test "x$with_afs_sysname" != "x"; then
 479         AFS_SYSNAME="$with_afs_sysname"
 480 else
 481         AC_MSG_CHECKING(your AFS sysname)
 482         case $host in
 483                 i?86-*-openbsd?.?)
 484                         v=${host#*openbsd}
 485                         vM=${v%.*}
 486                         vm=${v#*.}
 487                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 488                         ;;
 489                 sparc64-*-openbsd?.?)
 490                         v=${host#*openbsd}
 491                         vM=${v%.*}
 492                         vm=${v#*.}
 493                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 494                         ;;
 495                 x86_64-*-openbsd?.?)
 496                         v=${host#*openbsd}
 497                         vM=${v%.*}
 498                         vm=${v#*.}
 499                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 500                         ;;
 501                 i?86-*-freebsd*.*)
 502                         v=${host#*freebsd}
 503                         vM=${v%.*}
 504                         vm=${v#*.}
 505                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 506                         ;;
 507                 x86_64-*-freebsd*.*)
 508                         v=${host#*freebsd}
 509                         vM=${v%.*}
 510                         vm=${v#*.}
 511                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 512                         ;;
 513                 i386-*-dragonfly?.*)
 514                         v=${host#*dragonfly}
 515                         vM=${v%.*}
 516                         vm=${v#*.}
 517                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 518                         ;;
 519                 i?86-*-netbsd*1.6[[M-Z]]*)
 520                         AFS_SYSNAME="i386_nbsd20"
 521                         ;;
 522                 powerpc-*-netbsd*1.6[[M-Z]]*)
 523                         AFS_SYSNAME="ppc_nbsd20"
 524                         ;;
 525                 *-*-netbsd*)
 526                         arch=${host%%-unknown*}
 527                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 528                                                -e 's/powerpc/ppc/g')
 529                         v=${host#*netbsd}
 530                         v=${v#*aout}
 531                         v=${v#*ecoff}
 532                         v=${v#*elf}
 533                         vM=${v%%.*}
 534                         vM=${vM%.*}
 535                         v=${v#*.}
 536                         vm=${v%%.*}
 537                         vm=${vm%.*}
 538                         vm=${vm%%[[_A-Z]]*}
 539                         if test $vm -eq 99 ; then
 540                                 vM=$((vM+1))
 541                         fi
 542                         if test $vM -gt 1 ; then
 543                                 vm=0
 544                         fi
 545                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 546                         ;;
 547                 hppa*-hp-hpux11.0*)
 548                         AFS_SYSNAME="hp_ux110"
 549                         ;;
 550                 hppa*-hp-hpux11.11)
 551                         AFS_SYSNAME="hp_ux11i"
 552                         ;;
 553                 hppa*-hp-hpux11.23)
 554                         AFS_SYSNAME="hp_ux1123"
 555                         ;;
 556                 ia64-hp-hpux11.22)
 557                         AFS_SYSNAME="ia64_hpux1122"
 558                         ;;
 559                 ia64-hp-hpux*)
 560                         AFS_SYSNAME="ia64_hpux1123"
 561                         ;;
 562                 hppa*-hp-hpux10*)
 563                         AFS_SYSNAME="hp_ux102"
 564                         ;;
 565                 powerpc-apple-darwin7*)
 566                         AFS_SYSNAME="ppc_darwin_70"
 567                         OSXSDK="macosx10.3"
 568                         ;;
 569                 powerpc-apple-darwin8.*)
 570                         AFS_SYSNAME="ppc_darwin_80"
 571                         OSXSDK="macosx10.4"
 572                         ;;
 573                 i386-apple-darwin8.*)
 574                         AFS_SYSNAME="x86_darwin_80"
 575                         OSXSDK="macosx10.4"
 576                         ;;
 577                 powerpc-apple-darwin9.*)
 578                         AFS_SYSNAME="ppc_darwin_90"
 579                         OSXSDK="macosx10.5"
 580                         ;;
 581                 i386-apple-darwin9.*)
 582                         AFS_SYSNAME="x86_darwin_90"
 583                         OSXSDK="macosx10.5"
 584                         ;;
 585                 i?86-apple-darwin10.*)
 586                         AFS_SYSNAME="x86_darwin_100"
 587                         OSXSDK="macosx10.6"
 588                         ;;
 589                 x86_64-apple-darwin10.*)
 590                         AFS_SYSNAME="x86_darwin_100"
 591                         OSXSDK="macosx10.6"
 592                         ;;
 593                 arm-apple-darwin10.*)
 594                         AFS_SYSNAME="arm_darwin_100"
 595                         OSXSDK="iphoneos4.0"
 596                         ;;
 597                 x86_64-apple-darwin11.*)
 598                         AFS_SYSNAME="x86_darwin_110"
 599                         OSXSDK="macosx10.7"
 600                         ;;
 601                 i?86-apple-darwin11.*)
 602                         AFS_SYSNAME="x86_darwin_110"
 603                         OSXSDK="macosx10.7"
 604                         ;;
 605                 x86_64-apple-darwin12.*)
 606                         AFS_SYSNAME="x86_darwin_120"
 607                         OSXSDK="macosx10.8"
 608                         ;;
 609                 i?86-apple-darwin12.*)
 610                         AFS_SYSNAME="x86_darwin_120"
 611                         OSXSDK="macosx10.8"
 612                         ;;
 613                 x86_64-apple-darwin13.*)
 614                         AFS_SYSNAME="x86_darwin_130"
 615                         OSXSDK="macosx10.9"
 616                         ;;
 617                 i?86-apple-darwin13.*)
 618                         AFS_SYSNAME="x86_darwin_130"
 619                         OSXSDK="macosx10.9"
 620                         ;;
 621                 sparc-sun-solaris2.8)
 622                         AFS_SYSNAME="sun4x_58"
 623                         ;;
 624                 sparc-sun-solaris2.9)
 625                         AFS_SYSNAME="sun4x_59"
 626                         ;;
 627                 sparc-sun-solaris2.10)
 628                         AFS_SYSNAME="sun4x_510"
 629                         ;;
 630                 sparc-sun-solaris2.11)
 631                         AFS_SYSNAME="sun4x_511"
 632                         ;;
 633                 i386-pc-solaris2.8)
 634                         AFS_SYSNAME="sunx86_58"
 635                         ;;
 636                 i386-pc-solaris2.9)
 637                         AFS_SYSNAME="sunx86_59"
 638                         ;;
 639                 i386-pc-solaris2.10)
 640                         AFS_SYSNAME="sunx86_510"
 641                         ;;
 642                 i386-pc-solaris2.11)
 643                         AFS_SYSNAME="sunx86_511"
 644                         ;;
 645                 alpha*-dec-osf4.0*)
 646                         AFS_SYSNAME="alpha_dux40"
 647                         ;;
 648                 alpha*-dec-osf5.0*)
 649                         AFS_SYSNAME="alpha_dux50"
 650                         ;;
 651                 alpha*-dec-osf5.1*)
 652                         AFS_SYSNAME="alpha_dux51"
 653                         ;;
 654                 mips-sgi-irix6.5)
 655                         AFS_SYSNAME="sgi_65"
 656                         ;;
 657                 ia64-*-linux*)
 658                         AFS_SYSNAME="ia64_linuxXX"
 659                         ;;
 660                 powerpc-*-linux*)
 661                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 662                         ;;
 663                 powerpc64-*-linux*)
 664                         AFS_SYSNAME="ppc64_linuxXX"
 665                         ;;
 666                 alpha*-linux*)
 667                         AFS_SYSNAME="alpha_linux_XX"
 668                         ;;
 669                 s390-*-linux*)
 670                         AFS_SYSNAME="s390_linuxXX"
 671                         ;;
 672                 s390x-*-linux*)
 673                         AFS_SYSNAME="s390x_linuxXX"
 674                         ;;
 675                 sparc-*-linux*)
 676                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 677                         ;;
 678                 sparc64-*-linux*)
 679                         AFS_SYSNAME="sparc64_linuxXX"
 680                         ;;
 681                 i?86-*-linux*)
 682                         AFS_SYSNAME="i386_linuxXX"
 683                         ;;
 684                 arm*-linux*)
 685                         AFS_SYSNAME="arm_linuxXX"
 686                         ;;
 687                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 688                         AFS_SYSNAME="parisc_linuxXX"
 689                         enable_pam="no"
 690                         ;;
 691                 power*-ibm-aix4.2*)
 692                         AFS_SYSNAME="rs_aix42"
 693                         enable_pam="no"
 694                         ;;
 695                 power*-ibm-aix4.3*)
 696                         AFS_SYSNAME="rs_aix42"
 697                         enable_pam="no"
 698                         ;;
 699                 power*-ibm-aix5.1*)
 700                         AFS_SYSNAME="rs_aix51"
 701                         enable_pam="no"
 702                         ;;
 703                 power*-ibm-aix5.2*)
 704                         AFS_SYSNAME="rs_aix52"
 705                         enable_pam="no"
 706                         ;;
 707                 power*-ibm-aix5.3*)
 708                         AFS_SYSNAME="rs_aix53"
 709                         enable_pam="no"
 710                         ;;
 711                 power*-ibm-aix6.1*)
 712                         AFS_SYSNAME="rs_aix61"
 713                         enable_pam="no"
 714                         ;;
 715                 x86_64-*-linux-gnu)
 716                         AFS_SYSNAME="amd64_linuxXX"
 717                         enable_pam="yes"
 718                         ;;
 719                 *)
 720                         AC_MSG_ERROR(An AFS sysname is required)
 721                         exit 1
 722                         ;;
 723         esac
 724         case $AFS_SYSNAME in
 725                 *_linux* | *_umlinux*)
 726                         if test "x${AFS_SYSKVERS}" = "x"; then
 727                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 728                         fi
 729                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 730                         AFS_SYSNAME="$_AFS_SYSNAME"
 731                         AC_TRY_KBUILD(
 732                          [],
 733                          [#ifndef CONFIG_USERMODE
 734                           #error not UML
 735                           #endif],
 736                          ac_cv_linux_is_uml=yes,)
 737                         if test "${ac_cv_linux_is_uml}" = yes; then
 738                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 739                         fi
 740                         AFS_SYSNAME="$_AFS_SYSNAME"
 741                         ;;
 742         esac
 743         AC_MSG_RESULT($AFS_SYSNAME)
 744 fi
 745
 746 case $AFS_SYSNAME in
 747         *_darwin*)
 748                 AC_CHECK_HEADERS(crt_externs.h)
 749                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 750                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 751                 AC_SUBST(OSXSDK)
 752                 ;;
 753 esac
 754
 755 dnl Some hosts have a separate common param file they should include.  Figure
 756 dnl out if we're on one of them now that we know the sysname.
 757 case $AFS_SYSNAME in
 758     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 759     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 760     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 761     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 762     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 763     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 764     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 765     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 766     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
 767     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 768     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 769     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 770     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 771     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 772     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 773     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 774     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 775     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 776     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 777     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 778     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 779     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 780     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 781     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 782     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 783     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 784     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 785     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
 786     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
 787     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
 788     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
 789     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
 790     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 791     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 792     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 793 # Linux alpha adds an extra underscore for no good reason.
 794     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 795     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 796     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 797 esac
 798
 799 OPENAFS_OSCONF
 800
 801 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 802
 803                 # Add (sub-) architecture-specific paths needed by conftests
 804                 case $AFS_SYSNAME  in
 805                         *_umlinux26)
 806                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 807                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 808                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 809                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 810                 esac
 811
 812                 if test "x$enable_kernel_module" = "xyes"; then
 813                  if test "x$enable_debug_kernel" = "xno"; then
 814                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 815                  fi
 816                  OPENAFS_GCC_SUPPORTS_MARCH
 817                  AC_SUBST(P5PLUS_KOPTS)
 818                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 819                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 820                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 821                  OPENAFS_GCC_SUPPORTS_PIPE
 822                  AC_SUBST(LINUX_GCC_KOPTS)
 823
 824                  dnl Setup the kernel build environment
 825                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 826                  LINUX_KERNEL_COMPILE_WORKS
 827
 828                  dnl Check for header files
 829                  AC_CHECK_LINUX_HEADER([config.h])
 830                  AC_CHECK_LINUX_HEADER([completion.h])
 831                  AC_CHECK_LINUX_HEADER([exportfs.h])
 832                  AC_CHECK_LINUX_HEADER([freezer.h])
 833                  AC_CHECK_LINUX_HEADER([key-type.h])
 834                  AC_CHECK_LINUX_HEADER([semaphore.h])
 835                  AC_CHECK_LINUX_HEADER([seq_file.h])
 836
 837                  dnl Type existence checks
 838                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 839                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
 840
 841                  dnl Check for structure elements
 842                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 843                                        [write_begin], [fs.h])
 844                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 845                                        [backing-dev.h])
 846                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
 847                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 848                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 849                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 850                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 851                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 852                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 853                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 854                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 855                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
 856                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 857                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 858                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
 859                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
 860                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
 861                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 862                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 863                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 864                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 865                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 866                                        [fs.h])
 867                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 868                                        [fs.h])
 869                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 870                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 871                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 872                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 873                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 874                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 875                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 876                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 877                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 878                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 879                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 880
 881                  dnl Check for typed structure elements
 882                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 883                                              [buf], [fs.h])
 884
 885                  dnl Function existence checks
 886
 887                  AC_CHECK_LINUX_FUNC([bdi_init],
 888                                      [#include <linux/backing-dev.h>],
 889                                      [bdi_init(NULL);])
 890                  AC_CHECK_LINUX_FUNC([PageChecked],
 891                                      [#include <linux/mm.h>
 892 #include <linux/page-flags.h>],
 893                                      [struct page *_page;
 894                                       int bchecked = PageChecked(_page);])
 895                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 896                                      [#include <linux/mm.h>
 897 #include <linux/page-flags.h>],
 898                                      [struct page *_page;
 899                                       int bchecked = PageFsMisc(_page);])
 900                  AC_CHECK_LINUX_FUNC([clear_inode],
 901                                      [#include <linux/fs.h>],
 902                                      [clear_inode(NULL);])
 903                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 904                                      [#include <linux/time.h>],
 905                                      [struct timespec s;
 906                                       s = current_kernel_time();])
 907                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 908                                      [#include <linux/fs.h>],
 909                                      [d_alloc_anon(NULL);])
 910                  AC_CHECK_LINUX_FUNC([d_count],
 911                                      [#include <linux/dcache.h>],
 912                                      [d_count(NULL);])
 913                  AC_CHECK_LINUX_FUNC([d_make_root],
 914                                      [#include <linux/fs.h>],
 915                                      [d_make_root(NULL);])
 916                  AC_CHECK_LINUX_FUNC([do_sync_read],
 917                                      [#include <linux/fs.h>],
 918                                      [do_sync_read(NULL, NULL, 0, NULL);])
 919                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 920                                      [#include <linux/sched.h>],
 921                                      [pid_t p; find_task_by_pid(p);])
 922                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 923                                      [#include <linux/fs.h>],
 924                                      [generic_file_aio_read(NULL,NULL,0,0);])
 925                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 926                                      [#include <linux/pagemap.h>],
 927                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 928                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 929                                      [#include <linux/list.h>],
 930                                      [hlist_unhashed(0);])
 931                  AC_CHECK_LINUX_FUNC([i_size_read],
 932                                      [#include <linux/fs.h>],
 933                                      [i_size_read(NULL);])
 934                  AC_CHECK_LINUX_FUNC([inode_setattr],
 935                                      [#include <linux/fs.h>],
 936                                      [inode_setattr(NULL, NULL);])
 937                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
 938                                      [#include <linux/net.h>],
 939                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
 940                  AC_CHECK_LINUX_FUNC([page_follow_link],
 941                                      [#include <linux/fs.h>],
 942                                      [page_follow_link(0,0);])
 943                  AC_CHECK_LINUX_FUNC([page_offset],
 944                                      [#include <linux/pagemap.h>],
 945                                      [page_offset(NULL);])
 946                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
 947                                      [#include <linux/pagevec.h>],
 948                                      [__pagevec_lru_add_file(NULL);])
 949                  AC_CHECK_LINUX_FUNC([path_lookup],
 950                                      [#include <linux/fs.h>
 951                                       #include <linux/namei.h>],
 952                                      [path_lookup(NULL, 0, NULL);])
 953                  AC_CHECK_LINUX_FUNC([proc_create],
 954                                      [#include <linux/proc_fs.h>],
 955                                      [proc_create(NULL, 0, NULL, NULL);])
 956                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
 957                                      [#include <linux/rcupdate.h>],
 958                                      [rcu_read_lock();])
 959                  AC_CHECK_LINUX_FUNC([set_nlink],
 960                                      [#include <linux/fs.h>],
 961                                      [set_nlink(NULL, 1);])
 962                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
 963                                      [#include <linux/splice.h>],
 964                                      [splice_direct_to_actor(NULL,NULL,NULL);])
 965                  AC_CHECK_LINUX_FUNC([svc_addr_in],
 966                                      [#include <linux/sunrpc/svc.h>],
 967                                      [svc_addr_in(NULL);])
 968                  AC_CHECK_LINUX_FUNC([zero_user_segments],
 969                                      [#include <linux/highmem.h>],
 970                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
 971                  AC_CHECK_LINUX_FUNC([noop_fsync],
 972                                      [#include <linux/fs.h>],
 973                                      [void *address = &noop_fsync; printk("%p\n", address)];)
 974                  AC_CHECK_LINUX_FUNC([kthread_run],
 975                                      [#include <linux/kernel.h>
 976                                       #include <linux/kthread.h>],
 977                                      [kthread_run(NULL, NULL, "test");])
 978
 979                  dnl Consequences - things which get set as a result of the
 980                  dnl                above tests
 981                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
 982                        [AC_DEFINE([AFS_NONFSTRANS], 1,
 983                                   [define to disable the nfs translator])])
 984
 985                  dnl Assorted more complex tests
 986                  LINUX_AIO_NONVECTOR
 987                  LINUX_EXPORTS_PROC_ROOT_FS
 988                  LINUX_KMEM_CACHE_INIT
 989                  LINUX_HAVE_KMEM_CACHE_T
 990                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
 991                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
 992                  LINUX_D_PATH_TAKES_STRUCT_PATH
 993                  LINUX_NEW_EXPORT_OPS
 994                  LINUX_INODE_SETATTR_RETURN_TYPE
 995                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
 996                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
 997                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
 998                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
 999                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1000                  LINUX_DOP_D_DELETE_TAKES_CONST
1001                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1002                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1003                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1004                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1005                  LINUX_AOP_WRITEBACK_CONTROL
1006                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1007                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1008                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1009                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1010                  LINUX_KERNEL_SOCK_CREATE
1011                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1012                  LINUX_NEED_RHCONFIG
1013                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1014                  LINUX_EXPORTS_TASKLIST_LOCK
1015                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1016                  LINUX_STATFS_TAKES_DENTRY
1017                  LINUX_REFRIGERATOR
1018                  LINUX_HAVE_TRY_TO_FREEZE
1019                  LINUX_LINUX_KEYRING_SUPPORT
1020                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1021                  LINUX_KEY_ALLOC_NEEDS_CRED
1022                  LINUX_INIT_WORK_HAS_DATA
1023                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1024                  LINUX_HAVE_DCACHE_LOCK
1025                  LINUX_D_COUNT_IS_INT
1026                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1027                  LINUX_IOP_CREATE_TAKES_UMODE_T
1028                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1029                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1030                  LINUX_DENTRY_OPEN_TAKES_PATH
1031                  LINUX_D_ALIAS_IS_HLIST
1032                  LINUX_HLIST_ITERATOR_NO_NODE
1033                  LINUX_IOP_I_CREATE_TAKES_BOOL
1034                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1035                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1036
1037                  dnl If we are guaranteed that keyrings will work - that is
1038                  dnl  a) The kernel has keyrings enabled
1039                  dnl  b) The code is new enough to give us a key_type_keyring
1040                  dnl then we just disable syscall probing unless we've been
1041                  dnl told otherwise
1042
1043                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1044                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1045                           [enable_linux_syscall_probing="no"],
1046                           [enable_linux_syscall_probing="yes"])
1047                  ])
1048
1049                  dnl Syscall probing needs a few tests of its own, and just
1050                  dnl won't work if the kernel doesn't export init_mm
1051                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1052                    LINUX_EXPORTS_INIT_MM
1053                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1054                      AC_MSG_ERROR(
1055                        [Can't do syscall probing without exported init_mm])
1056                    ])
1057                    LINUX_EXPORTS_SYS_CHDIR
1058                    LINUX_EXPORTS_SYS_OPEN
1059                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1060                              [define to enable syscall table probes])
1061                  ])
1062
1063                  dnl Packaging and SMP build
1064                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1065                    LINUX_WHICH_MODULES
1066                  else
1067                    AC_SUBST(MPS,'SP')
1068                  fi
1069
1070                  dnl Syscall probing
1071                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1072                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1073                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1074                    ])
1075                    ac_cv_linux_exports_sys_call_table=no
1076                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1077                      ac_cv_linux_exports_ia32_sys_call_table=yes
1078                    fi
1079                  else
1080                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1081                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1082                    LINUX_EXPORTS_SYS_CALL_TABLE
1083                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1084                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1085                          linux_syscall_method=none
1086                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1087                             linux_syscall_method=scan
1088                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1089                                linux_syscall_method=scan_with_kallsyms_address
1090                             fi
1091                          fi
1092                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1093                             linux_syscall_method=kallsyms_symbol
1094                          fi
1095                          if test "x$linux_syscall_method" = "xnone"; then
1096                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1097                             linux_syscall_method=scan
1098                          fi
1099                    fi
1100                  fi
1101                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1102                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1103                  fi
1104                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1105                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1106                  fi
1107                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1108                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1109                  else
1110                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1111                  fi
1112                 :
1113                 fi
1114 dnl Linux-only, but just enable always.
1115                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1116 esac
1117
1118 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1119     [ac_cv_sync_fetch_and_add],
1120     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1121                     [ac_cv_sync_fetch_and_add=yes],
1122                     [ac_cv_sync_fetch_and_add=no])
1123 ])
1124 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1125       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1126                 [define if your C compiler has __sync_add_and_fetch])])
1127
1128 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1129     [ac_cv_sockaddr_len],
1130     [AC_TRY_COMPILE( [#include <sys/types.h>
1131 #include <sys/socket.h>],
1132                      [struct sockaddr *a; a->sa_len=0;],
1133                      [ac_cv_sockaddr_len=yes],
1134                      [ac_cv_sockaddr_len=no])
1135 ])
1136 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1137       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1138                  [define if you struct sockaddr sa_len])])
1139
1140 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1141         echo Skipping library tests because they confuse Irix.
1142 else
1143   AC_SEARCH_LIBS([socket], [socket inet])
1144   AC_SEARCH_LIBS([connect], [nsl])
1145   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1146
1147   dnl darwin wants it, aix hates it
1148   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1149   AC_TRY_COMPILE([
1150   #include <stdlib.h>
1151   #include <stdio.h>
1152   #include <sys/types.h>
1153   #include <sys/socket.h>
1154   #include <netinet/in.h>
1155   #include <arpa/inet.h>
1156   #include <arpa/nameser.h>
1157   #include <arpa/nameser_compat.h>
1158   #include <resolv.h>
1159   ], [static int i; i = 0;],
1160   [AC_MSG_RESULT(yes)
1161    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1162   [AC_MSG_RESULT(no)
1163    ])
1164
1165   openafs_save_libs="$LIBS"
1166   AC_MSG_CHECKING([for res_search])
1167   AC_FUNC_RES_SEARCH
1168
1169   if test "$ac_cv_func_res_search" = no; then
1170       for lib in dns nsl resolv; do
1171         if test "$ac_cv_func_res_search" != yes; then
1172           LIBS="-l$lib $LIBS"
1173           AC_FUNC_RES_SEARCH
1174           LIBS="$openafs_save_libs"
1175         fi
1176       done
1177       if test "$ac_cv_func_res_search" = yes; then
1178         LIB_AFSDB="-l$lib"
1179         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1180         AC_MSG_RESULT([yes, in lib$lib])
1181       else
1182         AC_MSG_RESULT(no)
1183       fi
1184   else
1185     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1186     AC_MSG_RESULT(yes)
1187   fi
1188
1189 fi
1190 XLIBS="$LIB_AFSDB $XLIBS"
1191
1192 AC_CHECK_RESOLV_RETRANS
1193
1194 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1195     [ac_cv_setsockopt_iprecverr],
1196     [AC_TRY_COMPILE( [
1197 #include <sys/types.h>
1198 #include <sys/socket.h>
1199 #include <netinet/in.h>],
1200 [int on=1;
1201 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1202         [ac_cv_setsockopt_iprecverr=yes],
1203         [ac_cv_setsockopt_iprecverr=no])])
1204
1205 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1206       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1207                  [define if we can receive socket errors via IP_RECVERR])])
1208
1209 PTHREAD_LIBS=error
1210 if test "x$MKAFS_OSTYPE" = OBSD; then
1211         PTHREAD_LIBS="-pthread"
1212 fi
1213 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1214         PTHREAD_LIBS="-pthread"
1215 fi
1216 if test "x$PTHREAD_LIBS" = xerror; then
1217         AC_CHECK_LIB(pthread, pthread_attr_init,
1218                 PTHREAD_LIBS="-lpthread")
1219 fi
1220 if test "x$PTHREAD_LIBS" = xerror; then
1221         AC_CHECK_LIB(pthreads, pthread_attr_init,
1222                 PTHREAD_LIBS="-lpthreads")
1223 fi
1224 if test "x$PTHREAD_LIBS" = xerror; then
1225         AC_CHECK_LIB(c_r, pthread_attr_init,
1226                 PTHREAD_LIBS="-lc_r")
1227 fi
1228 if test "x$PTHREAD_LIBS" = xerror; then
1229         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1230 fi
1231 if test "x$PTHREAD_LIBS" = xerror; then
1232         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1233         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1234                 PTHREAD_LIBS="-lpthread")
1235 fi
1236 if test "x$PTHREAD_LIBS" = xerror; then
1237         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1238 fi
1239 AC_SUBST(PTHREAD_LIBS)
1240
1241 HOST_CPU="$host_cpu"
1242
1243 if test "x$with_bsd_kernel_headers" != "x"; then
1244         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1245 else
1246         BSD_KERNEL_PATH="/usr/src/sys"
1247 fi
1248
1249 if test "x$with_bsd_kernel_build" != "x"; then
1250         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1251 else
1252         case $AFS_SYSNAME in
1253                 *_fbsd_*)
1254                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1255                         ;;
1256                 *_nbsd*)
1257                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1258         esac
1259 fi
1260
1261 # Fast restart
1262 if test "$enable_supergroups" = "yes"; then
1263         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1264 fi
1265
1266 if test "$enable_bitmap_later" = "yes"; then
1267         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1268 fi
1269
1270 if test "$enable_unix_sockets" = "yes"; then
1271         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1272         USE_UNIX_SOCKETS="yes"
1273 else
1274         USE_UNIX_SOCKETS="no"
1275 fi
1276 AC_SUBST(USE_UNIX_SOCKETS)
1277
1278 if test "$enable_namei_fileserver" = "yes"; then
1279         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1280         VFSCK=""
1281 else
1282         if test "$enable_namei_fileserver" = "default"; then
1283                 case $host in
1284                         *-solaris2.10*)
1285                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1286                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1287                                 VFSCK=""
1288                                 ;;
1289                         *-solaris2.11*)
1290                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1291                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1292                                 VFSCK=""
1293                                 ;;
1294                         *)
1295                                 VFSCK="vfsck"
1296                                 ;;
1297                 esac
1298         else
1299                 VFSCK="vfsck"
1300         fi
1301 fi
1302
1303 dnl check for tivoli
1304 AC_MSG_CHECKING(for tivoli tsm butc support)
1305 XBSA_CFLAGS=""
1306 if test "$enable_tivoli_tsm" = "yes"; then
1307         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1308         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1309         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1310         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1311
1312         if test -r "$XBSADIR3/dsmapifp.h"; then
1313                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1314                 XBSA_XLIBS="-ldl"
1315                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1316         elif test -r "$XBSADIR4/dsmapifp.h"; then
1317                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1318                 XBSA_XLIBS="-ldl"
1319                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1320         elif test -r "$XBSADIR1/xbsa.h"; then
1321                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1322                 XBSA_XLIBS=""
1323                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1324         elif test -r "$XBSADIR2/xbsa.h"; then
1325                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1326                 XBSA_XLIBS=""
1327                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1328         else
1329                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1330         fi
1331 else
1332         AC_MSG_RESULT([no])
1333 fi
1334 AC_SUBST(XBSA_CFLAGS)
1335 AC_SUBST(XBSA_XLIBS)
1336
1337 dnl checks for header files.
1338 AC_HEADER_STDC
1339 AC_HEADER_SYS_WAIT
1340 AC_HEADER_DIRENT
1341 AC_CHECK_HEADERS([ \
1342                    arpa/inet.h \
1343                    arpa/nameser.h \
1344                    curses.h\
1345                    direct.h \
1346                    errno.h \
1347                    fcntl.h \
1348                    grp.h \
1349                    math.h \
1350                    mntent.h \
1351                    ncurses.h \
1352                    ncurses/ncurses.h \
1353                    netdb.h \
1354                    netinet/in.h \
1355                    pthread_np.h \
1356                    pwd.h \
1357                    regex.h \
1358                    security/pam_appl.h \
1359                    signal.h \
1360                    stdint.h \
1361                    stdio_ext.h \
1362                    stdlib.h \
1363                    string.h \
1364                    strings.h \
1365                    sys/bitypes.h \
1366                    sys/bswap.h \
1367                    sys/dk.h \
1368                    sys/fcntl.h \
1369                    sys/file.h \
1370                    sys/fs_types.h \
1371                    sys/fstyp.h \
1372                    sys/ioctl.h \
1373                    sys/ipc.h \
1374                    sys/lockf.h \
1375                    sys/map.h \
1376                    sys/mount.h \
1377                    sys/mntent.h \
1378                    sys/mnttab.h \
1379                    sys/pag.h \
1380                    sys/param.h \
1381                    sys/resource.h \
1382                    sys/select.h \
1383                    sys/statfs.h \
1384                    sys/statvfs.h \
1385                    sys/socket.h \
1386                    sys/sysctl.h \
1387                    sys/time.h \
1388                    sys/types.h \
1389                    sys/uio.h \
1390                    sys/un.h \
1391                    sys/vfs.h \
1392                    syslog.h \
1393                    termios.h \
1394                    time.h \
1395                    ucontext.h \
1396                    unistd.h \
1397                    windows.h \
1398                 ])
1399
1400 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1401 #ifdef HAVE_NETINET_IN_H
1402 # include <netinet/in.h>
1403 #endif])
1404
1405 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1406 #ifdef HAVE_SYS_SOCKET_H
1407 # include <sys/socket.h>
1408 #endif])
1409
1410 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1411 #ifdef HAVE_SYS_SOCKET_H
1412 # include <sys/socket.h>
1413 #endif
1414 #ifdef HAVE_NETINET_IN_H
1415 # include <netinet/in.h>
1416 #endif
1417 #ifdef HAVE_NET_IF_H
1418 # include <net/if.h>
1419 #endif])
1420
1421 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1422 #ifdef HAVE_SECURITY_PAM_APPL_H
1423 # include <security/pam_appl.h>
1424 #endif])
1425
1426 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1427
1428 AC_CHECK_TYPES([fsblkcnt_t],,,[
1429 #include <sys/types.h>
1430 #ifdef HAVE_SYS_BITYPES_H
1431 #include <sys/bitypes.h>
1432 #endif
1433 #ifdef HAVE_SYS_STATFS_H
1434 #include <sys/statfs.h>
1435 #endif
1436 #ifdef HAVE_SYS_STATVFS_H
1437 #include <sys/statvfs.h>
1438 #endif
1439 ])
1440
1441 dnl see what struct stat has for timestamps
1442 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1443
1444 dnl check for curses-lib
1445 AS_IF([test "x$enable_gtx" != "xno"],
1446       [save_LIBS=$LIBS
1447       AC_CHECK_LIB( [ncurses], [setupterm],
1448       [LIB_curses=-lncurses],
1449         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1450           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1451       ])
1452       LIBS=$save_LIBS
1453       AC_SUBST(LIB_curses)])
1454
1455 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1456
1457 if test "$enable_debug_locks" = yes; then
1458         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1459 fi
1460
1461 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1462 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1463         case $AFS_SYSNAME in
1464         sgi_*)
1465                 HAVE_PAM="no"
1466                 ;;
1467         *)
1468                 HAVE_PAM="yes"
1469                 ;;
1470         esac
1471 else
1472         HAVE_PAM="no"
1473 fi
1474 AC_SUBST(HAVE_PAM)
1475
1476 if test "$enable_login" = yes; then
1477         BUILD_LOGIN="yes"
1478 else
1479         BUILD_LOGIN="no"
1480 fi
1481 AC_SUBST(BUILD_LOGIN)
1482
1483 if test "$enable_uss" = yes; then
1484         BUILD_USS="yes"
1485 else
1486         BUILD_USS="no"
1487 fi
1488 AC_SUBST(BUILD_USS)
1489
1490 if test "$enable_kauth" = yes; then
1491         INSTALL_KAUTH="yes"
1492 else
1493         INSTALL_KAUTH="no"
1494 fi
1495 AC_SUBST(INSTALL_KAUTH)
1496
1497 AC_CHECK_FUNCS([ \
1498         arc4random \
1499         fcntl \
1500         fseeko64 \
1501         ftello64 \
1502         getcwd \
1503         getegid \
1504         geteuid \
1505         getgid \
1506         getuid \
1507         getrlimit \
1508         issetugid \
1509         mkstemp \
1510         poll \
1511         pread \
1512         preadv \
1513         preadv64 \
1514         pwrite \
1515         pwritev \
1516         pwritev64 \
1517         regcomp \
1518         regerror \
1519         regexec \
1520         setitimer \
1521         setvbuf \
1522         sigaction \
1523         strcasestr \
1524         strerror \
1525         sysconf \
1526         sysctl \
1527         tdestroy \
1528         timegm \
1529 ])
1530
1531 OPENAFS_ROKEN()
1532 OPENAFS_C_ATTRIBUTE()
1533
1534 dnl Functions that Heimdal's libroken provides, but that we
1535 dnl haven't found a need for yet, and so haven't imported
1536 AC_CHECK_FUNCS([ \
1537         chown \
1538         fchown \
1539         gethostname \
1540         lstat \
1541         inet_aton \
1542         inet_ntop \
1543         inet_pton \
1544         putenv \
1545         readv \
1546         setenv \
1547         strdup \
1548         strftime \
1549         strndup \
1550         strsep \
1551         unsetenv \
1552 ])
1553
1554 dnl Functions that are in objects that we always build from libroken
1555 AC_CHECK_FUNCS([ \
1556         asprintf \
1557         asnprintf \
1558         vasprintf \
1559         vasnprintf \
1560         vsnprintf \
1561         snprintf \
1562 ])
1563
1564 dnl Functions that we're going to try and get from libroken
1565 AC_REPLACE_FUNCS([ \
1566         daemon \
1567         ecalloc \
1568         emalloc \
1569         erealloc \
1570         err \
1571         errx \
1572         flock \
1573         getdtablesize \
1574         getopt \
1575         getprogname \
1576         gettimeofday \
1577         localtime_r \
1578         mkstemp \
1579         setenv \
1580         setprogname \
1581         strcasecmp \
1582         strlcat \
1583         strnlen \
1584         strlcpy \
1585         strsep \
1586         tdelete \
1587         tfind \
1588         tsearch \
1589         twalk \
1590         unsetenv \
1591         verr \
1592         verrx \
1593         vsyslog \
1594         vwarn \
1595         vwarnx \
1596         warn \
1597         warnx \
1598 ])
1599
1600 dnl Headers that we're going to try and get from libroken
1601 AC_CHECK_HEADERS([ \
1602         err.h \
1603         search.h \
1604 ])
1605
1606 AC_CHECK_DECLS([h_errno], [], [], [
1607 #include <sys/types.h>
1608 #ifdef HAVE_NETDB_H
1609 #include <netdb.h>
1610 #endif
1611 ])
1612
1613 AC_HEADER_TIME
1614
1615 ROKEN_HEADERS=
1616 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1617       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1618       [])
1619 AC_SUBST(ROKEN_HEADERS)
1620
1621 dnl Stuff that's harder ...
1622 AC_MSG_CHECKING([for bswap16])
1623 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1624 #ifdef HAVE_SYS_TYPES_H
1625 #include <sys/types.h>
1626 #endif
1627 #ifdef HAVE_SYS_BSWAP_H
1628 #include <sys/bswap.h>
1629 #endif
1630 ],
1631 [short a, b; b = bswap16(a); ])],
1632 [AC_MSG_RESULT(yes)
1633  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1634 ],
1635 [AC_MSG_RESULT(no)])
1636
1637 AC_MSG_CHECKING([for bswap32])
1638 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1639 #include <sys/types.h>
1640 #endif
1641 #ifdef HAVE_SYS_BSWAP_H
1642 #include <sys/bswap.h>
1643 #endif
1644 ],
1645 [int a, b; b = bswap32(a); ])],
1646 [AC_MSG_RESULT(yes)
1647  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1648 ],
1649 [AC_MSG_RESULT(no)])
1650
1651 case $AFS_SYSNAME in
1652 *hp_ux* | *hpux*)
1653    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1654    ;;
1655 *)
1656    AC_MSG_CHECKING([for positional I/O])
1657    if test "$ac_cv_func_pread" = "yes" && \
1658            test "$ac_cv_func_pwrite" = "yes"; then
1659       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1660       AC_MSG_RESULT(yes)
1661    else
1662      AC_MSG_RESULT(no)
1663    fi
1664    AC_MSG_CHECKING([for vectored positional I/O])
1665    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1666                "$ac_cv_func_pwritev" = "yes" -a \
1667                "$ac_cv_func_preadv64" = "yes" -a \
1668                "$ac_cv_func_pwritev64" = "yes"],
1669          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1670           AC_MSG_RESULT(yes)],
1671          [AC_MSG_RESULT(no)])
1672    ;;
1673 esac
1674
1675 AC_MSG_CHECKING([for POSIX regex library])
1676 if test "$ac_cv_header_regex_h" = "yes" && \
1677         test "$ac_cv_func_regcomp" = "yes" && \
1678         test "$ac_cv_func_regexec" = "yes" && \
1679         test "$ac_cv_func_regerror" = "yes"; then
1680     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1681     AC_MSG_RESULT(yes)
1682 else
1683     AC_MSG_RESULT(no)
1684 fi
1685
1686 dnl Look for "non-portable" pthreads functions.
1687 save_LIBS="$LIBS"
1688 LIBS="$LIBS $PTHREAD_LIBS"
1689 AC_CHECK_FUNCS([ \
1690         pthread_set_name_np \
1691         pthread_setname_np \
1692 ])
1693
1694 dnl Sadly, there are three different versions of pthread_setname_np.
1695 dnl Try to cater for all of them.
1696 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1697     AC_MSG_CHECKING([for signature of pthread_setname_np])
1698     AC_TRY_COMPILE([
1699 #include <pthread.h>
1700 #ifdef HAVE_PTHREAD_NP_H
1701 #include <pthread_np.h>
1702 #endif
1703 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1704         AC_MSG_RESULT([three arguments])
1705         pthread_setname_np_args=3], [
1706         AC_TRY_COMPILE([
1707 #include <pthread.h>
1708 #ifdef HAVE_PTHREAD_NP_H
1709 #include <pthread_np.h>
1710 #endif
1711 ], [pthread_setname_np(pthread_self(), "test")], [
1712             AC_MSG_RESULT([two arguments])
1713             pthread_setname_np_args=2], [
1714             AC_TRY_COMPILE([
1715 #include <pthread.h>
1716 #ifdef HAVE_PTHREAD_NP_H
1717 #include <pthread_np.h>
1718 #endif
1719 ], [pthread_setname_np("test")], [
1720                 AC_MSG_RESULT([one argument])
1721                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1722 ])
1723 ])
1724 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1725 fi
1726 LIBS="$save_LIBS"
1727
1728 openafs_cv_saved_CFLAGS="$CFLAGS"
1729 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1730
1731 AC_TYPE_SIGNAL
1732 OPENAFS_RETSIGTYPE
1733 AC_CHECK_SIZEOF(void *)
1734 AC_CHECK_SIZEOF(unsigned long long)
1735 AC_CHECK_SIZEOF(unsigned long)
1736 AC_CHECK_SIZEOF(unsigned int)
1737 AC_TYPE_INTPTR_T
1738 AC_TYPE_UINTPTR_T
1739 AC_TYPE_SSIZE_T
1740 AC_CHECK_TYPE([sig_atomic_t],[],
1741     [AC_DEFINE([sig_atomic_t], [int],
1742         [Define to int if <signal.h> does not define.])],
1743 [#include <sys/types.h>
1744 #include <signal.h>])
1745 AC_CHECK_TYPE([socklen_t],[],
1746     [AC_DEFINE([socklen_t], [int],
1747         [Define to int if <sys/socket.h> does not define.])],
1748 [#include <sys/types.h>
1749 #include <sys/socket.h>])
1750 AC_CHECK_TYPES(off64_t)
1751 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1752 AC_CHECK_TYPES([struct winsize], [], [], [
1753 #ifdef HAVE_TERMIOS_H
1754 # include <termios.h>
1755 #else
1756 # include <sys/termios.h>
1757 #endif
1758 #include <sys/ioctl.h>])
1759 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1760                 struct sockaddr_storage],
1761                [], [], [
1762 #include <sys/types.h>
1763 #include <sys/socket.h>
1764 ])
1765 AC_CHECK_TYPES([sa_family_t], [], [], [
1766 #include <sys/types.h>
1767 #include <sys/socket.h>
1768 ])
1769 AC_CHECK_TYPES([struct addrinfo], [], [], [
1770 #include <sys/types.h>
1771 #ifdef HAVE_NETDB_H
1772 #include <netdb.h>
1773 #endif
1774 ])
1775 AC_CHECK_TYPES([long long], [], [], [])
1776
1777 AC_SIZEOF_TYPE(long)
1778
1779 CFLAGS="$openafs_cv_saved_CFLAGS"
1780
1781 RRA_HEADER_PAM_CONST
1782
1783
1784 dnl Directory PATH handling
1785 if test "x$enable_transarc_paths" = "xyes"  ; then
1786     afsconfdir=${afsconfdir=/usr/afs/etc}
1787     viceetcdir=${viceetcdir=/usr/vice/etc}
1788     afskerneldir=${afskerneldir=${viceetcdir}}
1789     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1790     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1791     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1792     afsdbdir=${afsdbdir=/usr/afs/db}
1793     afslogsdir=${afslogsdir=/usr/afs/logs}
1794     afslocaldir=${afslocaldir=/usr/afs/local}
1795     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1796     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1797     afsdatadir=${afsdatadir=/usr/vice/etc}
1798 else
1799     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1800     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1801     afskerneldir=${afskerneldir='${libdir}/openafs'}
1802     afssrvbindir=${afssrvbindir='${bindir}'}
1803     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1804     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1805     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1806     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1807     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1808     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1809     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1810     afsdatadir=${afsdatadir='${datadir}/openafs'}
1811 fi
1812 AC_SUBST(afsconfdir)
1813 AC_SUBST(viceetcdir)
1814 AC_SUBST(afskerneldir)
1815 AC_SUBST(afssrvbindir)
1816 AC_SUBST(afssrvsbindir)
1817 AC_SUBST(afssrvlibexecdir)
1818 AC_SUBST(afsdbdir)
1819 AC_SUBST(afslogsdir)
1820 AC_SUBST(afslocaldir)
1821 AC_SUBST(afsbackupdir)
1822 AC_SUBST(afsbosconfigdir)
1823 AC_SUBST(afsdatadir)
1824
1825 if test "x$enable_kernel_module" = "xyes"; then
1826 ENABLE_KERNEL_MODULE=libafs
1827 fi
1828
1829 if test "x$enable_pthreaded_ubik" = "xyes"; then
1830 ENABLE_PTHREADED_UBIK=yes
1831 fi
1832
1833 AC_SUBST(VFSCK)
1834 AC_SUBST(AFS_SYSNAME)
1835 AC_SUBST(AFS_PARAM_COMMON)
1836 AC_SUBST(ENABLE_KERNEL_MODULE)
1837 AC_SUBST(ENABLE_PTHREADED_UBIK)
1838 AC_SUBST(LIB_AFSDB)
1839 AC_SUBST(LINUX_KERNEL_PATH)
1840 AC_SUBST(LINUX_KERNEL_BUILD)
1841 AC_SUBST(HOST_CPU)
1842 AC_SUBST(BSD_KERNEL_PATH)
1843 AC_SUBST(BSD_KERNEL_BUILD)
1844 AC_SUBST(LINUX_VERSION)
1845 AC_SUBST(MKAFS_OSTYPE)
1846 AC_SUBST(TOP_OBJDIR)
1847 AC_SUBST(TOP_SRCDIR)
1848 AC_SUBST(TOP_INCDIR)
1849 AC_SUBST(TOP_LIBDIR)
1850 AC_SUBST(DEST)
1851 AC_SUBST(DARWIN_INFOFILE)
1852 AC_SUBST(IRIX_BUILD_IP35)
1853 AC_SUBST(HTML_XSL)
1854 AC_SUBST(XSLTPROC)
1855 AC_SUBST(DOCBOOK2PDF)
1856 AC_SUBST(DOCBOOK_STYLESHEETS)
1857
1858 OPENAFS_FUSE
1859 OPENAFS_SWIG
1860
1861 TOP_SRCDIR="${srcdir}/src"
1862 dnl
1863 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1864 dnl
1865 case $TOP_SRCDIR in
1866         /*)
1867                 ;;
1868         *)
1869                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1870                 ;;
1871 esac
1872
1873 TOP_OBJDIR="${SRCDIR_PARENT}"
1874 TOP_INCDIR="${SRCDIR_PARENT}/include"
1875 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1876 if test "${DEST}x" = "x"; then
1877         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1878 fi
1879
1880 if test "x$with_crosstools_dir" != "x"; then
1881         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1882                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1883                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1884                 RXGEN_PATH=$with_crosstools_dir/rxgen
1885         else
1886                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1887                 exit 1
1888         fi
1889 else
1890         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1891         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1892         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1893 fi
1894 AC_SUBST(COMPILE_ET_PATH)
1895 AC_SUBST(CONFIGTOOL_PATH)
1896 AC_SUBST(RXGEN_PATH)
1897
1898 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1899 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1900 AC_SUBST(HELPER_SPLINT)
1901 AC_SUBST(HELPER_SPLINTCFG)
1902
1903 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1904
1905 dnl Check to see if crypt lives in a different library
1906 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1907 AC_SUBST(LIB_crypt)
1908
1909 dnl Check to see if the compiler support labels in structs
1910 AC_MSG_CHECKING(for label support in structs)
1911 AC_TRY_COMPILE([], [
1912 extern void osi_UFSOpen(void);
1913 struct labeltest {
1914    void (*open) (void);
1915 };
1916 struct labeltest struct_labeltest = {
1917    .open       = osi_UFSOpen,
1918 }
1919 ],
1920 [AC_MSG_RESULT(yes)
1921  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1922 ],
1923 [AC_MSG_RESULT(no)
1924 ])
1925
1926 AC_MSG_CHECKING([checking for dirfd])
1927 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1928 #ifdef HAVE_DIRENT_H
1929 #include <dirent.h>
1930 #endif
1931 ]],
1932         [[DIR *d = 0; dirfd(d);]])],
1933         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1934 if test "$ac_rk_have_dirfd" = "yes" ; then
1935         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1936 fi
1937 AC_MSG_RESULT($ac_rk_have_dirfd)
1938
1939 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1940 #ifdef HAVE_DIRENT_H
1941 #include <dirent.h>
1942 #endif])
1943
1944 dnl Eventually, this will look for the system one, or for OpenSSL
1945 LIB_hcrypto="-lafshcrypto"
1946 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1947 AC_SUBST(LIB_hcrypto)
1948 AC_SUBST(LDFLAGS_hcrypto)
1949
1950 dnl Check for UUID library
1951 AC_CHECK_HEADERS([uuid/uuid.h])
1952 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1953 AC_CHECK_FUNCS([uuid_generate])
1954 ])
1955
1956