acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #   define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 #define _FILE_OFFSET_BITS 64
  48 #define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 #include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
  76
  77 dnl General feature options.
  78 AC_ARG_ENABLE([gtx],
  79     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
  80 AC_ARG_ENABLE([uss],
  81     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
  82 AC_ARG_ENABLE([namei-fileserver],
  83     [AS_HELP_STRING([--enable-namei-fileserver],
  84         [force compilation of namei fileserver in preference to inode
  85          fileserver])],
  86     ,
  87     [enable_namei_fileserver="default"])
  88 AC_ARG_ENABLE([supergroups],
  89     [AS_HELP_STRING([--enable-supergroups],
  90         [enable support for nested pts groups])],
  91     ,
  92     [enable_supergroups="no"])
  93 AC_ARG_ENABLE([bitmap-later],
  94     [AS_HELP_STRING([--enable-bitmap-later],
  95         [enable fast startup of file server by not reading bitmap till
  96          needed])],
  97     ,
  98     [enable_bitmap_later="no"])
  99 AC_ARG_ENABLE([unix-sockets],
 100     [AS_HELP_STRING([--disable-unix-sockets],
 101         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 102     ,
 103     [enable_unix_sockets="yes"])
 104 AC_ARG_ENABLE([tivoli-tsm],
 105     [AS_HELP_STRING([--enable-tivoli-tsm],
 106         [enable use of the Tivoli TSM API libraries for butc support])],
 107     ,
 108     [enable_tivoli_tsm="no"])
 109 AC_ARG_ENABLE([pthreaded-ubik],
 110     [AS_HELP_STRING([--disable-pthreaded-ubik],
 111         [disable installation of pthreaded ubik applications (defaults to
 112          enabled)])],
 113     ,
 114     [enable_pthreaded_ubik="yes"])
 115
 116 dnl Kernel module build options.
 117 AC_ARG_WITH([linux-kernel-headers],
 118     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 119         [use the kernel headers found at path (optional, defaults to
 120          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
 121          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
 122 AC_ARG_WITH([linux-kernel-build],
 123     [AS_HELP_STRING([--with-linux-kernel-build=path],
 124         [use the kernel build found at path(optional, defaults to
 125         kernel headers path)])])
 126 AC_ARG_WITH([bsd-kernel-headers],
 127     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 128         [use the kernel headers found at path (optional, defaults to
 129          /usr/src/sys)])])
 130 AC_ARG_WITH([bsd-kernel-build],
 131     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 132         [use the kernel build found at path (optional, defaults to
 133          KSRC/i386/compile/GENERIC)])])
 134 AC_ARG_WITH([linux-kernel-packaging],
 135     [AS_HELP_STRING([--with-linux-kernel-packaging],
 136         [use standard naming conventions to aid Linux kernel build packaging
 137          (disables MPS, sets the kernel module name to openafs.ko, and
 138          installs kernel modules into the standard Linux location)])],
 139     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
 140      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
 141     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
 142 AC_ARG_ENABLE([kernel-module],
 143     [AS_HELP_STRING([--disable-kernel-module],
 144         [disable compilation of the kernel module (defaults to enabled)])],
 145     ,
 146     [enable_kernel_module="yes"])
 147 AC_ARG_ENABLE([redhat-buildsys],
 148     [AS_HELP_STRING([--enable-redhat-buildsys],
 149         [enable compilation of the redhat build system kernel (defaults to
 150          disabled)])],
 151     ,
 152     [enable_redhat_buildsys="no"])
 153
 154 dnl Installation locations.
 155 AC_ARG_ENABLE([transarc-paths],
 156     [AS_HELP_STRING([--enable-transarc-paths],
 157         [use Transarc style paths like /usr/afs and /usr/vice])],
 158     ,
 159     [enable_transarc_paths="no"])
 160
 161 dnl Deprecated crypto
 162 AC_ARG_ENABLE([kauth],
 163     [AS_HELP_STRING([--enable-kauth],
 164         [install the deprecated kauth server, pam modules, and utilities
 165          (defaults to disabled)])],
 166     [enable_pam="yes"],
 167     [enable_kauth="no"
 168      enable_pam="no"])
 169
 170 dnl Optimization and debugging flags.
 171 AC_ARG_ENABLE([strip-binaries],
 172     [AS_HELP_STRING([--disable-strip-binaries],
 173         [disable stripping of symbol information from binaries (defaults to
 174          enabled)])],
 175     ,
 176     [enable_strip_binaries="maybe"])
 177 AC_ARG_ENABLE([debug],
 178     [AS_HELP_STRING([--enable-debug],
 179         [enable compilation of the user space code with debugging information
 180          (defaults to disabled)])],
 181     ,
 182     [enable_debug="no"])
 183 AC_ARG_ENABLE([optimize],
 184     [AS_HELP_STRING([--disable-optimize],
 185         [disable optimization for compilation of the user space code (defaults
 186          to enabled)])],
 187     ,
 188     [enable_optimize="yes"])
 189 AC_ARG_ENABLE([warnings],
 190     [AS_HELP_STRING([--enable-warnings],
 191         [enable compilation warnings when building with gcc (defaults to
 192          disabled)])],
 193     ,
 194     [enable_warnings="no"])
 195 AC_ARG_ENABLE([checking],
 196     [AS_HELP_STRING([--enable-checking],
 197         [turn compilation warnings into errors when building with gcc (defaults
 198          to disabled)])],
 199     [enable_checking="$enableval"],
 200     [enable_checking="no"])
 201 AC_ARG_ENABLE([debug-locks],
 202     [AS_HELP_STRING([--enable-debug-locks],
 203         [turn on lock debugging assertions (defaults to disabled)])],
 204     [enable_debug_locks="$enableval"],
 205     [enable_debug_locks="no"])
 206 AC_ARG_ENABLE([debug-kernel],
 207     [AS_HELP_STRING([--enable-debug-kernel],
 208         [enable compilation of the kernel module with debugging information
 209          (defaults to disabled)])],
 210     ,
 211     [enable_debug_kernel="no"])
 212 AC_ARG_ENABLE([optimize-kernel],
 213     [AS_HELP_STRING([--disable-optimize-kernel],
 214         [disable compilation of the kernel module with optimization (defaults
 215          based on platform)])],
 216     ,
 217     [enable_optimize_kernel=""])
 218 AC_ARG_ENABLE([debug-lwp],
 219     [AS_HELP_STRING([--enable-debug-lwp],
 220         [enable compilation of the LWP code with debugging information
 221          (defaults to disabled)])],
 222     ,
 223     [enable_debug_lwp="no"])
 224 AC_ARG_ENABLE([optimize-lwp],
 225     [AS_HELP_STRING([--disable-optimize-lwp],
 226         [disable optimization for compilation of the LWP code (defaults to
 227          enabled)])],
 228     ,
 229     [enable_optimize_lwp="yes"])
 230 AC_ARG_ENABLE([debug-pam],
 231     [AS_HELP_STRING([--enable-debug-pam],
 232         [enable compilation of the PAM code with debugging information
 233          (defaults to disabled)])],
 234     ,
 235     [enable_debug_pam="no"])
 236 AC_ARG_ENABLE([optimize-pam],
 237     [AS_HELP_STRING([--disable-optimize-pam],
 238         [disable optimization for compilation of the PAM code (defaults to
 239          enabled)])],
 240     ,
 241     [enable_optimize_pam="yes"])
 242 AC_ARG_ENABLE([linux-syscall-probing],
 243     [AS_HELP_STRING([--enable-linux-syscall-probing],
 244         [enable Linux syscall probing (defaults to autodetect)])],
 245     ,
 246     [enable_linux_syscall_probing="maybe"])
 247 AC_ARG_WITH([crosstools-dir],
 248     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
 249
 250 AC_ARG_WITH([xslt-processor],
 251         AS_HELP_STRING([--with-xslt-processor=ARG],
 252         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 253         [XSLTPROC="$withval"],
 254         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
 255
 256 AC_ARG_WITH([html-xsl],
 257         AS_HELP_STRING([--with-html-xsl],
 258         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 259         [HTML_XSL="$withval"],
 260         [HTML_XSL="html/chunk.xsl"])
 261
 262 AC_ARG_WITH([docbook2pdf],
 263         AS_HELP_STRING([--with-docbook2pdf=ARG],
 264         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 265         [DOCBOOK2PDF="$withval"],
 266         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
 267
 268 AC_ARG_WITH([docbook-stylesheets],
 269         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 270         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 271         [DOCBOOK_STYLESHEETS="$withval"],
 272         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
 273         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
 274                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 275         fi)
 276
 277 AC_ARG_WITH([dot],
 278         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
 279         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
 280         [], [with_dot="maybe"])
 281
 282 enable_login="no"
 283
 284 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 285 dnl documentation build.
 286 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 287 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 288
 289 dnl Optionally generate graphs with doxygen.
 290 case "$with_dot" in
 291 maybe)
 292     AC_CHECK_PROGS([DOT], [dot])
 293     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
 294     ;;
 295 yes)
 296     HAVE_DOT="yes"
 297     ;;
 298 no)
 299     HAVE_DOT="no"
 300     ;;
 301 *)
 302     HAVE_DOT="yes"
 303     DOT_PATH=$with_dot
 304 esac
 305 AC_SUBST(HAVE_DOT)
 306 AC_SUBST(DOT_PATH)
 307
 308 dnl Checks for UNIX variants.
 309 AC_ISC_POSIX
 310
 311 dnl Various compiler setup.
 312 AC_TYPE_PID_T
 313 AC_TYPE_SIZE_T
 314
 315 dnl Checks for programs.
 316 AC_PROG_INSTALL
 317 AC_PROG_LN_S
 318 AC_PROG_RANLIB
 319 AC_PROG_YACC
 320 AM_PROG_LEX
 321 dnl if we are flex, be lex-compatible
 322 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 323
 324 OPENAFS_FORCE_ABS_INSTALL
 325 OPENAFS_CHECK_BIGENDIAN
 326 OPENAFS_PRINTF_TAKES_Z_LEN
 327
 328 AC_MSG_CHECKING(your OS)
 329 system=$host
 330 case $system in
 331         *-linux*)
 332
 333                 MKAFS_OSTYPE=LINUX
 334                 if test "x$enable_redhat_buildsys" = "xyes"; then
 335                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 336                 fi
 337                 if test "x$enable_kernel_module" = "xyes"; then
 338                  if test "x$with_linux_kernel_headers" != "x"; then
 339                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 340                  else
 341                    for utsdir in "/lib/modules/`uname -r`/build" \
 342                                  "/lib/modules/`uname -r`/source" \
 343                                  "/usr/src/linux-2.4" \
 344                                  "/usr/src/linux"; do
 345                      LINUX_KERNEL_PATH="$utsdir"
 346                      for utsfile in "include/generated/utsrelease.h" \
 347                                     "include/linux/utsrelease.h" \
 348                                     "include/linux/version.h" \
 349                                     "include/linux/version-up.h"; do
 350                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
 351                          break 2
 352                        fi
 353                      done
 354                    done
 355                  fi
 356                  if test "x$with_linux_kernel_build" != "x"; then
 357                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 358                  else
 359                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 360                  fi
 361                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 362                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 363                    LINUX_VERSION="$linux_kvers"
 364                  else
 365                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 366                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 367                      LINUX_VERSION="$linux_kvers"
 368                    else
 369                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 370                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 371                        if test "x$linux_kvers" = "x"; then
 372                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 373                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 374                            if test "x$linux_kvers" = "x"; then
 375                              AC_MSG_ERROR(Linux headers lack version definition [2])
 376                              exit 1
 377                            else
 378                              LINUX_VERSION="$linux_kvers"
 379                            fi
 380                          else
 381                            AC_MSG_ERROR(Linux headers lack version definition)
 382                            exit 1
 383                          fi
 384                        else
 385                          LINUX_VERSION="$linux_kvers"
 386                        fi
 387                      else
 388                        enable_kernel_module="no"
 389                      fi
 390                    fi
 391                  fi
 392                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 393                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 394                      enable_kernel_module="no"
 395                  fi
 396                  if test "x$enable_kernel_module" = "xno"; then
 397                   if test "x$with_linux_kernel_headers" != "x"; then
 398                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 399                    exit 1
 400                   else
 401                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 402                   fi
 403                  fi
 404                  dnl do we need to determine SUBARCH from autoconf.h
 405                  SUBARCH=default
 406                 fi
 407                 AC_MSG_RESULT(linux)
 408                 if test "x$enable_kernel_module" = "xyes"; then
 409                  case "$LINUX_VERSION" in
 410                   2.2.*) AFS_SYSKVERS=22 ;;
 411                   2.4.*) AFS_SYSKVERS=24 ;;
 412                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
 413                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 414                  esac
 415                 fi
 416                 ;;
 417         *-solaris*)
 418                 MKAFS_OSTYPE=SOLARIS
 419                 AC_MSG_RESULT(sun4)
 420                 AC_PATH_PROG(SOLARISCC, [cc], ,
 421                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 422                 if test "x$SOLARISCC" = "x" ; then
 423                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 424                 fi
 425                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 426                 SOLARIS_FS_HAS_FS_ROLLED
 427                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 428                 SOLARIS_HAVE_VN_RENAMEPATH
 429                 ;;
 430         *-sunos*)
 431                 MKAFS_OSTYPE=SUNOS
 432                 enable_kernel_module=no
 433                 AC_MSG_RESULT(sun4)
 434                 ;;
 435         *-hpux*)
 436                 MKAFS_OSTYPE=HPUX
 437                 AC_MSG_RESULT(hp_ux)
 438                 if test -f "/usr/old/usr/include/ndir.h"; then
 439                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 440                 fi
 441                 ;;
 442         *-irix*)
 443                 if test -d /usr/include/sys/SN/SN1; then
 444                  IRIX_BUILD_IP35="IP35"
 445                 fi
 446                 MKAFS_OSTYPE=IRIX
 447                 AC_MSG_RESULT(sgi)
 448                 ;;
 449         *-aix*)
 450                 MKAFS_OSTYPE=AIX
 451                 AC_MSG_RESULT(rs_aix)
 452                 ;;
 453         arm-*-darwin*)
 454                 MKAFS_OSTYPE=DARWIN
 455                 AC_MSG_RESULT(arm_darwin)
 456                 ;;
 457         powerpc-*-darwin*)
 458                 MKAFS_OSTYPE=DARWIN
 459                 AC_MSG_RESULT(ppc_darwin)
 460                 ;;
 461         i386-*-darwin*)
 462                 MKAFS_OSTYPE=DARWIN
 463                 AC_MSG_RESULT(x86_darwin)
 464                 ;;
 465         x86_64-*-darwin*)
 466                 MKAFS_OSTYPE=DARWIN
 467                 AC_MSG_RESULT(x86_darwin)
 468                 ;;
 469         i386-*-freebsd*)
 470                 MKAFS_OSTYPE=FBSD
 471                 AC_MSG_RESULT(i386_fbsd)
 472                 ;;
 473         x86_64-*-freebsd*)
 474                 MKAFS_OSTYPE=FBSD
 475                 AC_MSG_RESULT(amd64_fbsd)
 476                 ;;
 477         *-netbsd*)
 478                 MKAFS_OSTYPE=NBSD
 479                 AC_MSG_RESULT(nbsd)
 480                 ;;
 481         x86_64-*-openbsd*)
 482                 MKAFS_OSTYPE=OBSD
 483                 AC_MSG_RESULT(amd64_obsd)
 484                 ;;
 485         i386-*-openbsd*)
 486                 MKAFS_OSTYPE=OBSD
 487                 AC_MSG_RESULT(i386_obsd)
 488                 ;;
 489         *-dragonfly*)
 490                 MKAFS_OSTYPE=DFBSD
 491                 AC_MSG_RESULT(i386_dfbsd)
 492                 ;;
 493         *)
 494                 AC_MSG_RESULT($system)
 495                 ;;
 496 esac
 497
 498 if test "x$with_afs_sysname" != "x"; then
 499         AFS_SYSNAME="$with_afs_sysname"
 500 else
 501         AC_MSG_CHECKING(your AFS sysname)
 502         case $host in
 503                 i?86-*-openbsd?.?)
 504                         v=${host#*openbsd}
 505                         vM=${v%.*}
 506                         vm=${v#*.}
 507                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 508                         ;;
 509                 sparc64-*-openbsd?.?)
 510                         v=${host#*openbsd}
 511                         vM=${v%.*}
 512                         vm=${v#*.}
 513                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 514                         ;;
 515                 x86_64-*-openbsd?.?)
 516                         v=${host#*openbsd}
 517                         vM=${v%.*}
 518                         vm=${v#*.}
 519                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 520                         ;;
 521                 i?86-*-freebsd*.*)
 522                         v=${host#*freebsd}
 523                         vM=${v%.*}
 524                         vm=${v#*.}
 525                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 526                         ;;
 527                 x86_64-*-freebsd*.*)
 528                         v=${host#*freebsd}
 529                         vM=${v%.*}
 530                         vm=${v#*.}
 531                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 532                         ;;
 533                 i386-*-dragonfly?.*)
 534                         v=${host#*dragonfly}
 535                         vM=${v%.*}
 536                         vm=${v#*.}
 537                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 538                         ;;
 539                 i?86-*-netbsd*1.6[[M-Z]]*)
 540                         AFS_SYSNAME="i386_nbsd20"
 541                         ;;
 542                 powerpc-*-netbsd*1.6[[M-Z]]*)
 543                         AFS_SYSNAME="ppc_nbsd20"
 544                         ;;
 545                 *-*-netbsd*)
 546                         arch=${host%%-unknown*}
 547                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 548                                                -e 's/powerpc/ppc/g')
 549                         v=${host#*netbsd}
 550                         v=${v#*aout}
 551                         v=${v#*ecoff}
 552                         v=${v#*elf}
 553                         vM=${v%%.*}
 554                         vM=${vM%.*}
 555                         v=${v#*.}
 556                         vm=${v%%.*}
 557                         vm=${vm%.*}
 558                         vm=${vm%%[[_A-Z]]*}
 559                         if test $vm -eq 99 ; then
 560                                 vM=$((vM+1))
 561                         fi
 562                         if test $vM -gt 1 ; then
 563                                 vm=0
 564                         fi
 565                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 566                         ;;
 567                 hppa*-hp-hpux11.0*)
 568                         AFS_SYSNAME="hp_ux110"
 569                         ;;
 570                 hppa*-hp-hpux11.11)
 571                         AFS_SYSNAME="hp_ux11i"
 572                         ;;
 573                 hppa*-hp-hpux11.23)
 574                         AFS_SYSNAME="hp_ux1123"
 575                         ;;
 576                 ia64-hp-hpux11.22)
 577                         AFS_SYSNAME="ia64_hpux1122"
 578                         ;;
 579                 ia64-hp-hpux*)
 580                         AFS_SYSNAME="ia64_hpux1123"
 581                         ;;
 582                 hppa*-hp-hpux10*)
 583                         AFS_SYSNAME="hp_ux102"
 584                         ;;
 585                 powerpc-apple-darwin7*)
 586                         AFS_SYSNAME="ppc_darwin_70"
 587                         OSXSDK="macosx10.3"
 588                         ;;
 589                 powerpc-apple-darwin8.*)
 590                         AFS_SYSNAME="ppc_darwin_80"
 591                         OSXSDK="macosx10.4"
 592                         ;;
 593                 i386-apple-darwin8.*)
 594                         AFS_SYSNAME="x86_darwin_80"
 595                         OSXSDK="macosx10.4"
 596                         ;;
 597                 powerpc-apple-darwin9.*)
 598                         AFS_SYSNAME="ppc_darwin_90"
 599                         OSXSDK="macosx10.5"
 600                         ;;
 601                 i386-apple-darwin9.*)
 602                         AFS_SYSNAME="x86_darwin_90"
 603                         OSXSDK="macosx10.5"
 604                         ;;
 605                 i?86-apple-darwin10.*)
 606                         AFS_SYSNAME="x86_darwin_100"
 607                         OSXSDK="macosx10.6"
 608                         ;;
 609                 x86_64-apple-darwin10.*)
 610                         AFS_SYSNAME="x86_darwin_100"
 611                         OSXSDK="macosx10.6"
 612                         ;;
 613                 arm-apple-darwin10.*)
 614                         AFS_SYSNAME="arm_darwin_100"
 615                         OSXSDK="iphoneos4.0"
 616                         ;;
 617                 x86_64-apple-darwin11.*)
 618                         AFS_SYSNAME="x86_darwin_110"
 619                         OSXSDK="macosx10.7"
 620                         ;;
 621                 i?86-apple-darwin11.*)
 622                         AFS_SYSNAME="x86_darwin_110"
 623                         OSXSDK="macosx10.7"
 624                         ;;
 625                 x86_64-apple-darwin12.*)
 626                         AFS_SYSNAME="x86_darwin_120"
 627                         OSXSDK="macosx10.8"
 628                         ;;
 629                 i?86-apple-darwin12.*)
 630                         AFS_SYSNAME="x86_darwin_120"
 631                         OSXSDK="macosx10.8"
 632                         ;;
 633                 x86_64-apple-darwin13.*)
 634                         AFS_SYSNAME="x86_darwin_130"
 635                         OSXSDK="macosx10.9"
 636                         ;;
 637                 i?86-apple-darwin13.*)
 638                         AFS_SYSNAME="x86_darwin_130"
 639                         OSXSDK="macosx10.9"
 640                         ;;
 641                 sparc-sun-solaris2.8)
 642                         AFS_SYSNAME="sun4x_58"
 643                         ;;
 644                 sparc-sun-solaris2.9)
 645                         AFS_SYSNAME="sun4x_59"
 646                         ;;
 647                 sparc-sun-solaris2.10)
 648                         AFS_SYSNAME="sun4x_510"
 649                         ;;
 650                 sparc-sun-solaris2.11)
 651                         AFS_SYSNAME="sun4x_511"
 652                         ;;
 653                 i386-pc-solaris2.8)
 654                         AFS_SYSNAME="sunx86_58"
 655                         ;;
 656                 i386-pc-solaris2.9)
 657                         AFS_SYSNAME="sunx86_59"
 658                         ;;
 659                 i386-pc-solaris2.10)
 660                         AFS_SYSNAME="sunx86_510"
 661                         ;;
 662                 i386-pc-solaris2.11)
 663                         AFS_SYSNAME="sunx86_511"
 664                         ;;
 665                 alpha*-dec-osf4.0*)
 666                         AFS_SYSNAME="alpha_dux40"
 667                         ;;
 668                 alpha*-dec-osf5.0*)
 669                         AFS_SYSNAME="alpha_dux50"
 670                         ;;
 671                 alpha*-dec-osf5.1*)
 672                         AFS_SYSNAME="alpha_dux51"
 673                         ;;
 674                 mips-sgi-irix6.5)
 675                         AFS_SYSNAME="sgi_65"
 676                         enable_pam="no"
 677                         ;;
 678                 ia64-*-linux*)
 679                         AFS_SYSNAME="ia64_linuxXX"
 680                         ;;
 681                 powerpc-*-linux*)
 682                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 683                         ;;
 684                 powerpc64-*-linux*)
 685                         AFS_SYSNAME="ppc64_linuxXX"
 686                         ;;
 687                 alpha*-linux*)
 688                         AFS_SYSNAME="alpha_linux_XX"
 689                         ;;
 690                 s390-*-linux*)
 691                         AFS_SYSNAME="s390_linuxXX"
 692                         ;;
 693                 s390x-*-linux*)
 694                         AFS_SYSNAME="s390x_linuxXX"
 695                         ;;
 696                 sparc-*-linux*)
 697                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 698                         ;;
 699                 sparc64-*-linux*)
 700                         AFS_SYSNAME="sparc64_linuxXX"
 701                         ;;
 702                 i?86-*-linux*)
 703                         AFS_SYSNAME="i386_linuxXX"
 704                         ;;
 705                 arm*-linux*)
 706                         AFS_SYSNAME="arm_linuxXX"
 707                         ;;
 708                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 709                         AFS_SYSNAME="parisc_linuxXX"
 710                         enable_pam="no"
 711                         ;;
 712                 power*-ibm-aix4.2*)
 713                         AFS_SYSNAME="rs_aix42"
 714                         enable_pam="no"
 715                         ;;
 716                 power*-ibm-aix4.3*)
 717                         AFS_SYSNAME="rs_aix42"
 718                         enable_pam="no"
 719                         ;;
 720                 power*-ibm-aix5.1*)
 721                         AFS_SYSNAME="rs_aix51"
 722                         enable_pam="no"
 723                         ;;
 724                 power*-ibm-aix5.2*)
 725                         AFS_SYSNAME="rs_aix52"
 726                         enable_pam="no"
 727                         ;;
 728                 power*-ibm-aix5.3*)
 729                         AFS_SYSNAME="rs_aix53"
 730                         enable_pam="no"
 731                         ;;
 732                 power*-ibm-aix6.1*)
 733                         AFS_SYSNAME="rs_aix61"
 734                         enable_pam="no"
 735                         ;;
 736                 x86_64-*-linux-gnu)
 737                         AFS_SYSNAME="amd64_linuxXX"
 738                         enable_pam="yes"
 739                         ;;
 740                 *)
 741                         AC_MSG_ERROR(An AFS sysname is required)
 742                         exit 1
 743                         ;;
 744         esac
 745         case $AFS_SYSNAME in
 746                 *_linux* | *_umlinux*)
 747                         if test "x${AFS_SYSKVERS}" = "x"; then
 748                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 749                         fi
 750                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 751                         AFS_SYSNAME="$_AFS_SYSNAME"
 752                         AC_TRY_KBUILD(
 753                          [],
 754                          [#ifndef CONFIG_USERMODE
 755                           #error not UML
 756                           #endif],
 757                          ac_cv_linux_is_uml=yes,)
 758                         if test "${ac_cv_linux_is_uml}" = yes; then
 759                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 760                         fi
 761                         AFS_SYSNAME="$_AFS_SYSNAME"
 762                         ;;
 763         esac
 764         AC_MSG_RESULT($AFS_SYSNAME)
 765 fi
 766
 767 case $AFS_SYSNAME in
 768         *_darwin*)
 769                 AC_CHECK_HEADERS(crt_externs.h)
 770                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 771                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 772                 AC_SUBST(OSXSDK)
 773                 ;;
 774 esac
 775
 776 dnl Some hosts have a separate common param file they should include.  Figure
 777 dnl out if we're on one of them now that we know the sysname.
 778 case $AFS_SYSNAME in
 779     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 780     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 781     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 782     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 783     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 784     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 785     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 786     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 787     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
 788     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 789     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 790     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 791     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 792     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 793     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 794     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 795     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 796     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 797     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 798     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 799     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 800     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 801     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 802     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 803     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 804     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 805     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 806     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
 807     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
 808     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
 809     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
 810     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
 811     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
 812     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 813     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 814     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 815 # Linux alpha adds an extra underscore for no good reason.
 816     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 817     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 818     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 819     *_fbsd_*)   AFS_PARAM_COMMON=param.generic_fbsd.h ;;
 820 esac
 821
 822 OPENAFS_OSCONF
 823
 824 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 825
 826                 # Add (sub-) architecture-specific paths needed by conftests
 827                 case $AFS_SYSNAME  in
 828                         *_umlinux26)
 829                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 830                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 831                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 832                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 833                 esac
 834
 835                 if test "x$enable_kernel_module" = "xyes"; then
 836                  if test "x$enable_debug_kernel" = "xno"; then
 837                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 838                  fi
 839                  OPENAFS_GCC_SUPPORTS_MARCH
 840                  AC_SUBST(P5PLUS_KOPTS)
 841                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 842                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 843                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 844                  OPENAFS_GCC_SUPPORTS_PIPE
 845                  AC_SUBST(LINUX_GCC_KOPTS)
 846
 847                  dnl Setup the kernel build environment
 848                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 849                  LINUX_KERNEL_COMPILE_WORKS
 850
 851                  dnl Check for header files
 852                  AC_CHECK_LINUX_HEADER([config.h])
 853                  AC_CHECK_LINUX_HEADER([completion.h])
 854                  AC_CHECK_LINUX_HEADER([exportfs.h])
 855                  AC_CHECK_LINUX_HEADER([freezer.h])
 856                  AC_CHECK_LINUX_HEADER([key-type.h])
 857                  AC_CHECK_LINUX_HEADER([semaphore.h])
 858                  AC_CHECK_LINUX_HEADER([seq_file.h])
 859
 860                  dnl Type existence checks
 861                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 862                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
 863
 864                  dnl Check for structure elements
 865                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 866                                        [write_begin], [fs.h])
 867                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 868                                        [backing-dev.h])
 869                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
 870                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 871                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 872                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 873                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 874                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 875                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 876                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 877                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 878                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
 879                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
 880                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 881                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 882                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
 883                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
 884                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
 885                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 886                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 887                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 888                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 889                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 890                                        [fs.h])
 891                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 892                                        [fs.h])
 893                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 894                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 895                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 896                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 897                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 898                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 899                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 900                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 901                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 902                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 903                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 904
 905                  dnl Check for typed structure elements
 906                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 907                                              [buf], [fs.h])
 908
 909                  dnl Function existence checks
 910
 911                  AC_CHECK_LINUX_FUNC([bdi_init],
 912                                      [#include <linux/backing-dev.h>],
 913                                      [bdi_init(NULL);])
 914                  AC_CHECK_LINUX_FUNC([PageChecked],
 915                                      [#include <linux/mm.h>
 916 #include <linux/page-flags.h>],
 917                                      [struct page *_page;
 918                                       int bchecked = PageChecked(_page);])
 919                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 920                                      [#include <linux/mm.h>
 921 #include <linux/page-flags.h>],
 922                                      [struct page *_page;
 923                                       int bchecked = PageFsMisc(_page);])
 924                  AC_CHECK_LINUX_FUNC([clear_inode],
 925                                      [#include <linux/fs.h>],
 926                                      [clear_inode(NULL);])
 927                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 928                                      [#include <linux/time.h>],
 929                                      [struct timespec s;
 930                                       s = current_kernel_time();])
 931                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 932                                      [#include <linux/fs.h>],
 933                                      [d_alloc_anon(NULL);])
 934                  AC_CHECK_LINUX_FUNC([d_count],
 935                                      [#include <linux/dcache.h>],
 936                                      [d_count(NULL);])
 937                  AC_CHECK_LINUX_FUNC([d_make_root],
 938                                      [#include <linux/fs.h>],
 939                                      [d_make_root(NULL);])
 940                  AC_CHECK_LINUX_FUNC([do_sync_read],
 941                                      [#include <linux/fs.h>],
 942                                      [do_sync_read(NULL, NULL, 0, NULL);])
 943                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 944                                      [#include <linux/sched.h>],
 945                                      [pid_t p; find_task_by_pid(p);])
 946                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 947                                      [#include <linux/fs.h>],
 948                                      [generic_file_aio_read(NULL,NULL,0,0);])
 949                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 950                                      [#include <linux/pagemap.h>],
 951                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 952                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 953                                      [#include <linux/list.h>],
 954                                      [hlist_unhashed(0);])
 955                  AC_CHECK_LINUX_FUNC([i_size_read],
 956                                      [#include <linux/fs.h>],
 957                                      [i_size_read(NULL);])
 958                  AC_CHECK_LINUX_FUNC([inode_setattr],
 959                                      [#include <linux/fs.h>],
 960                                      [inode_setattr(NULL, NULL);])
 961                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
 962                                      [#include <linux/fs.h>],
 963                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
 964                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
 965                                      [#include <linux/net.h>],
 966                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
 967                  AC_CHECK_LINUX_FUNC([page_follow_link],
 968                                      [#include <linux/fs.h>],
 969                                      [page_follow_link(0,0);])
 970                  AC_CHECK_LINUX_FUNC([page_offset],
 971                                      [#include <linux/pagemap.h>],
 972                                      [page_offset(NULL);])
 973                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
 974                                      [#include <linux/pagevec.h>],
 975                                      [__pagevec_lru_add_file(NULL);])
 976                  AC_CHECK_LINUX_FUNC([path_lookup],
 977                                      [#include <linux/fs.h>
 978                                       #include <linux/namei.h>],
 979                                      [path_lookup(NULL, 0, NULL);])
 980                  AC_CHECK_LINUX_FUNC([proc_create],
 981                                      [#include <linux/proc_fs.h>],
 982                                      [proc_create(NULL, 0, NULL, NULL);])
 983                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
 984                                      [#include <linux/rcupdate.h>],
 985                                      [rcu_read_lock();])
 986                  AC_CHECK_LINUX_FUNC([set_nlink],
 987                                      [#include <linux/fs.h>],
 988                                      [set_nlink(NULL, 1);])
 989                  AC_CHECK_LINUX_FUNC([sock_create_kern],
 990                                      [#include <linux/net.h>],
 991                                      [sock_create_kern(0, 0, 0, NULL);])
 992                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
 993                                      [#include <linux/splice.h>],
 994                                      [splice_direct_to_actor(NULL,NULL,NULL);])
 995                  AC_CHECK_LINUX_FUNC([svc_addr_in],
 996                                      [#include <linux/sunrpc/svc.h>],
 997                                      [svc_addr_in(NULL);])
 998                  AC_CHECK_LINUX_FUNC([zero_user_segments],
 999                                      [#include <linux/highmem.h>],
1000                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1001                  AC_CHECK_LINUX_FUNC([noop_fsync],
1002                                      [#include <linux/fs.h>],
1003                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1004                  AC_CHECK_LINUX_FUNC([kthread_run],
1005                                      [#include <linux/kernel.h>
1006                                       #include <linux/kthread.h>],
1007                                      [kthread_run(NULL, NULL, "test");])
1008
1009                  dnl Consequences - things which get set as a result of the
1010                  dnl                above tests
1011                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1012                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1013                                   [define to disable the nfs translator])])
1014
1015                  dnl Assorted more complex tests
1016                  LINUX_AIO_NONVECTOR
1017                  LINUX_EXPORTS_PROC_ROOT_FS
1018                  LINUX_KMEM_CACHE_INIT
1019                  LINUX_HAVE_KMEM_CACHE_T
1020                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1021                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1022                  LINUX_D_PATH_TAKES_STRUCT_PATH
1023                  LINUX_NEW_EXPORT_OPS
1024                  LINUX_INODE_SETATTR_RETURN_TYPE
1025                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1026                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1027                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1028                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1029                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1030                  LINUX_DOP_D_DELETE_TAKES_CONST
1031                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1032                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1033                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1034                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1035                  LINUX_AOP_WRITEBACK_CONTROL
1036                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1037                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1038                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1039                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1040                  LINUX_KERNEL_SOCK_CREATE
1041                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1042                  LINUX_NEED_RHCONFIG
1043                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1044                  LINUX_EXPORTS_TASKLIST_LOCK
1045                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1046                  LINUX_STATFS_TAKES_DENTRY
1047                  LINUX_REFRIGERATOR
1048                  LINUX_HAVE_TRY_TO_FREEZE
1049                  LINUX_LINUX_KEYRING_SUPPORT
1050                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1051                  LINUX_KEY_ALLOC_NEEDS_CRED
1052                  LINUX_INIT_WORK_HAS_DATA
1053                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1054                  LINUX_HAVE_DCACHE_LOCK
1055                  LINUX_D_COUNT_IS_INT
1056                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1057                  LINUX_IOP_CREATE_TAKES_UMODE_T
1058                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1059                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1060                  LINUX_DENTRY_OPEN_TAKES_PATH
1061                  LINUX_D_ALIAS_IS_HLIST
1062                  LINUX_HLIST_ITERATOR_NO_NODE
1063                  LINUX_IOP_I_CREATE_TAKES_BOOL
1064                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1065                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1066
1067                  dnl If we are guaranteed that keyrings will work - that is
1068                  dnl  a) The kernel has keyrings enabled
1069                  dnl  b) The code is new enough to give us a key_type_keyring
1070                  dnl then we just disable syscall probing unless we've been
1071                  dnl told otherwise
1072
1073                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1074                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1075                           [enable_linux_syscall_probing="no"],
1076                           [enable_linux_syscall_probing="yes"])
1077                  ])
1078
1079                  dnl Syscall probing needs a few tests of its own, and just
1080                  dnl won't work if the kernel doesn't export init_mm
1081                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1082                    LINUX_EXPORTS_INIT_MM
1083                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1084                      AC_MSG_ERROR(
1085                        [Can't do syscall probing without exported init_mm])
1086                    ])
1087                    LINUX_EXPORTS_SYS_CHDIR
1088                    LINUX_EXPORTS_SYS_OPEN
1089                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1090                              [define to enable syscall table probes])
1091                  ])
1092
1093                  dnl Packaging and SMP build
1094                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1095                    LINUX_WHICH_MODULES
1096                  else
1097                    AC_SUBST(MPS,'SP')
1098                  fi
1099
1100                  dnl Syscall probing
1101                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1102                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1103                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1104                    ])
1105                    ac_cv_linux_exports_sys_call_table=no
1106                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1107                      ac_cv_linux_exports_ia32_sys_call_table=yes
1108                    fi
1109                  else
1110                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1111                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1112                    LINUX_EXPORTS_SYS_CALL_TABLE
1113                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1114                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1115                          linux_syscall_method=none
1116                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1117                             linux_syscall_method=scan
1118                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1119                                linux_syscall_method=scan_with_kallsyms_address
1120                             fi
1121                          fi
1122                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1123                             linux_syscall_method=kallsyms_symbol
1124                          fi
1125                          if test "x$linux_syscall_method" = "xnone"; then
1126                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1127                             linux_syscall_method=scan
1128                          fi
1129                    fi
1130                  fi
1131                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1132                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1133                  fi
1134                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1135                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1136                  fi
1137                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1138                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1139                  else
1140                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1141                  fi
1142                 :
1143                 fi
1144 dnl Linux-only, but just enable always.
1145                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1146 esac
1147
1148 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1149     [ac_cv_sync_fetch_and_add],
1150     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1151                     [ac_cv_sync_fetch_and_add=yes],
1152                     [ac_cv_sync_fetch_and_add=no])
1153 ])
1154 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1155       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1156                 [define if your C compiler has __sync_add_and_fetch])])
1157
1158 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1159     [ac_cv_sockaddr_len],
1160     [AC_TRY_COMPILE( [#include <sys/types.h>
1161 #include <sys/socket.h>],
1162                      [struct sockaddr *a; a->sa_len=0;],
1163                      [ac_cv_sockaddr_len=yes],
1164                      [ac_cv_sockaddr_len=no])
1165 ])
1166 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1167       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1168                  [define if you struct sockaddr sa_len])])
1169
1170 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1171         echo Skipping library tests because they confuse Irix.
1172 else
1173   AC_SEARCH_LIBS([socket], [socket inet])
1174   AC_SEARCH_LIBS([connect], [nsl])
1175   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1176
1177   dnl darwin wants it, aix hates it
1178   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1179   AC_TRY_COMPILE([
1180   #include <stdlib.h>
1181   #include <stdio.h>
1182   #include <sys/types.h>
1183   #include <sys/socket.h>
1184   #include <netinet/in.h>
1185   #include <arpa/inet.h>
1186   #include <arpa/nameser.h>
1187   #include <arpa/nameser_compat.h>
1188   #include <resolv.h>
1189   ], [static int i; i = 0;],
1190   [AC_MSG_RESULT(yes)
1191    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1192   [AC_MSG_RESULT(no)
1193    ])
1194
1195   openafs_save_libs="$LIBS"
1196   AC_MSG_CHECKING([for res_search])
1197   AC_FUNC_RES_SEARCH
1198
1199   if test "$ac_cv_func_res_search" = no; then
1200       for lib in dns nsl resolv; do
1201         if test "$ac_cv_func_res_search" != yes; then
1202           LIBS="-l$lib $LIBS"
1203           AC_FUNC_RES_SEARCH
1204           LIBS="$openafs_save_libs"
1205         fi
1206       done
1207       if test "$ac_cv_func_res_search" = yes; then
1208         LIB_AFSDB="-l$lib"
1209         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1210         AC_MSG_RESULT([yes, in lib$lib])
1211       else
1212         AC_MSG_RESULT(no)
1213       fi
1214   else
1215     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1216     AC_MSG_RESULT(yes)
1217   fi
1218
1219 fi
1220 XLIBS="$LIB_AFSDB $XLIBS"
1221
1222 AC_CHECK_RESOLV_RETRANS
1223
1224 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1225     [ac_cv_setsockopt_iprecverr],
1226     [AC_TRY_COMPILE( [
1227 #include <sys/types.h>
1228 #include <sys/socket.h>
1229 #include <netinet/in.h>],
1230 [int on=1;
1231 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1232         [ac_cv_setsockopt_iprecverr=yes],
1233         [ac_cv_setsockopt_iprecverr=no])])
1234
1235 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1236       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1237                  [define if we can receive socket errors via IP_RECVERR])])
1238
1239 PTHREAD_LIBS=error
1240 if test "x$MKAFS_OSTYPE" = OBSD; then
1241         PTHREAD_LIBS="-pthread"
1242 fi
1243 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1244         PTHREAD_LIBS="-pthread"
1245 fi
1246 if test "x$PTHREAD_LIBS" = xerror; then
1247         AC_CHECK_LIB(pthread, pthread_attr_init,
1248                 PTHREAD_LIBS="-lpthread")
1249 fi
1250 if test "x$PTHREAD_LIBS" = xerror; then
1251         AC_CHECK_LIB(pthreads, pthread_attr_init,
1252                 PTHREAD_LIBS="-lpthreads")
1253 fi
1254 if test "x$PTHREAD_LIBS" = xerror; then
1255         AC_CHECK_LIB(c_r, pthread_attr_init,
1256                 PTHREAD_LIBS="-lc_r")
1257 fi
1258 if test "x$PTHREAD_LIBS" = xerror; then
1259         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1260 fi
1261 if test "x$PTHREAD_LIBS" = xerror; then
1262         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1263         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1264                 PTHREAD_LIBS="-lpthread")
1265 fi
1266 if test "x$PTHREAD_LIBS" = xerror; then
1267         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1268 fi
1269 AC_SUBST(PTHREAD_LIBS)
1270
1271 HOST_CPU="$host_cpu"
1272
1273 if test "x$with_bsd_kernel_headers" != "x"; then
1274         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1275 else
1276         BSD_KERNEL_PATH="/usr/src/sys"
1277 fi
1278
1279 if test "x$with_bsd_kernel_build" != "x"; then
1280         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1281 else
1282         case $AFS_SYSNAME in
1283                 *_fbsd_*)
1284                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1285                         ;;
1286                 *_nbsd*)
1287                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1288         esac
1289 fi
1290
1291 # Fast restart
1292 if test "$enable_supergroups" = "yes"; then
1293         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1294 fi
1295
1296 if test "$enable_bitmap_later" = "yes"; then
1297         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1298 fi
1299
1300 if test "$enable_unix_sockets" = "yes"; then
1301         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1302         USE_UNIX_SOCKETS="yes"
1303 else
1304         USE_UNIX_SOCKETS="no"
1305 fi
1306 AC_SUBST(USE_UNIX_SOCKETS)
1307
1308 if test "$enable_namei_fileserver" = "yes"; then
1309         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1310         VFSCK=""
1311 else
1312         if test "$enable_namei_fileserver" = "default"; then
1313                 case $host in
1314                         *-solaris2.10*)
1315                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1316                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1317                                 VFSCK=""
1318                                 ;;
1319                         *-solaris2.11*)
1320                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1321                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1322                                 VFSCK=""
1323                                 ;;
1324                         *)
1325                                 VFSCK="vfsck"
1326                                 ;;
1327                 esac
1328         else
1329                 VFSCK="vfsck"
1330         fi
1331 fi
1332
1333 dnl check for tivoli
1334 AC_MSG_CHECKING(for tivoli tsm butc support)
1335 XBSA_CFLAGS=""
1336 if test "$enable_tivoli_tsm" = "yes"; then
1337         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1338         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1339         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1340         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1341
1342         if test -r "$XBSADIR3/dsmapifp.h"; then
1343                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1344                 XBSA_XLIBS="-ldl"
1345                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1346         elif test -r "$XBSADIR4/dsmapifp.h"; then
1347                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1348                 XBSA_XLIBS="-ldl"
1349                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1350         elif test -r "$XBSADIR1/xbsa.h"; then
1351                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1352                 XBSA_XLIBS=""
1353                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1354         elif test -r "$XBSADIR2/xbsa.h"; then
1355                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1356                 XBSA_XLIBS=""
1357                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1358         else
1359                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1360         fi
1361 else
1362         AC_MSG_RESULT([no])
1363 fi
1364 AC_SUBST(XBSA_CFLAGS)
1365 AC_SUBST(XBSA_XLIBS)
1366
1367 dnl checks for header files.
1368 AC_HEADER_STDC
1369 AC_HEADER_SYS_WAIT
1370 AC_HEADER_DIRENT
1371 AC_CHECK_HEADERS([ \
1372                    arpa/inet.h \
1373                    arpa/nameser.h \
1374                    curses.h\
1375                    direct.h \
1376                    errno.h \
1377                    fcntl.h \
1378                    grp.h \
1379                    math.h \
1380                    mntent.h \
1381                    ncurses.h \
1382                    ncurses/ncurses.h \
1383                    netdb.h \
1384                    netinet/in.h \
1385                    pthread_np.h \
1386                    pwd.h \
1387                    regex.h \
1388                    security/pam_appl.h \
1389                    signal.h \
1390                    stdint.h \
1391                    stdio_ext.h \
1392                    stdlib.h \
1393                    string.h \
1394                    strings.h \
1395                    sys/bitypes.h \
1396                    sys/bswap.h \
1397                    sys/dk.h \
1398                    sys/fcntl.h \
1399                    sys/file.h \
1400                    sys/fs_types.h \
1401                    sys/fstyp.h \
1402                    sys/ioctl.h \
1403                    sys/ipc.h \
1404                    sys/lockf.h \
1405                    sys/map.h \
1406                    sys/mount.h \
1407                    sys/mntent.h \
1408                    sys/mnttab.h \
1409                    sys/pag.h \
1410                    sys/param.h \
1411                    sys/resource.h \
1412                    sys/select.h \
1413                    sys/statfs.h \
1414                    sys/statvfs.h \
1415                    sys/socket.h \
1416                    sys/sysctl.h \
1417                    sys/time.h \
1418                    sys/types.h \
1419                    sys/uio.h \
1420                    sys/un.h \
1421                    sys/vfs.h \
1422                    syslog.h \
1423                    termios.h \
1424                    time.h \
1425                    ucontext.h \
1426                    unistd.h \
1427                    windows.h \
1428                 ])
1429
1430 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1431 #ifdef HAVE_NETINET_IN_H
1432 # include <netinet/in.h>
1433 #endif])
1434
1435 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1436 #ifdef HAVE_SYS_SOCKET_H
1437 # include <sys/socket.h>
1438 #endif])
1439
1440 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1441 #ifdef HAVE_SYS_SOCKET_H
1442 # include <sys/socket.h>
1443 #endif
1444 #ifdef HAVE_NETINET_IN_H
1445 # include <netinet/in.h>
1446 #endif
1447 #ifdef HAVE_NET_IF_H
1448 # include <net/if.h>
1449 #endif])
1450
1451 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1452 #ifdef HAVE_SECURITY_PAM_APPL_H
1453 # include <security/pam_appl.h>
1454 #endif])
1455
1456 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1457
1458 AC_CHECK_TYPES([fsblkcnt_t],,,[
1459 #include <sys/types.h>
1460 #ifdef HAVE_SYS_BITYPES_H
1461 #include <sys/bitypes.h>
1462 #endif
1463 #ifdef HAVE_SYS_STATFS_H
1464 #include <sys/statfs.h>
1465 #endif
1466 #ifdef HAVE_SYS_STATVFS_H
1467 #include <sys/statvfs.h>
1468 #endif
1469 ])
1470
1471 dnl see what struct stat has for timestamps
1472 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1473
1474 dnl check for curses-lib
1475 AS_IF([test "x$enable_gtx" != "xno"],
1476       [save_LIBS=$LIBS
1477       AC_CHECK_LIB( [ncurses], [setupterm],
1478       [LIB_curses=-lncurses],
1479         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1480           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1481       ])
1482       LIBS=$save_LIBS
1483       AC_SUBST(LIB_curses)])
1484
1485 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1486
1487 if test "$enable_debug_locks" = yes; then
1488         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1489 fi
1490
1491 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1492         HAVE_PAM="YES"
1493 else
1494         HAVE_PAM="no"
1495 fi
1496 AC_SUBST(HAVE_PAM)
1497
1498 if test "$enable_login" = yes; then
1499         BUILD_LOGIN="yes"
1500 else
1501         BUILD_LOGIN="no"
1502 fi
1503 AC_SUBST(BUILD_LOGIN)
1504
1505 if test "$enable_uss" = yes; then
1506         BUILD_USS="yes"
1507 else
1508         BUILD_USS="no"
1509 fi
1510 AC_SUBST(BUILD_USS)
1511
1512 if test "$enable_kauth" = yes; then
1513         INSTALL_KAUTH="yes"
1514 else
1515         INSTALL_KAUTH="no"
1516 fi
1517 AC_SUBST(INSTALL_KAUTH)
1518
1519 AC_CHECK_FUNCS([ \
1520         arc4random \
1521         fcntl \
1522         fseeko64 \
1523         ftello64 \
1524         getcwd \
1525         getegid \
1526         geteuid \
1527         getgid \
1528         getuid \
1529         getrlimit \
1530         issetugid \
1531         mkstemp \
1532         poll \
1533         pread \
1534         preadv \
1535         preadv64 \
1536         pwrite \
1537         pwritev \
1538         pwritev64 \
1539         regcomp \
1540         regerror \
1541         regexec \
1542         setitimer \
1543         setvbuf \
1544         sigaction \
1545         strcasestr \
1546         strerror \
1547         sysconf \
1548         sysctl \
1549         tdestroy \
1550         timegm \
1551 ])
1552
1553 OPENAFS_ROKEN()
1554 OPENAFS_HCRYPTO()
1555 OPENAFS_C_ATTRIBUTE()
1556
1557 dnl Functions that Heimdal's libroken provides, but that we
1558 dnl haven't found a need for yet, and so haven't imported
1559 AC_CHECK_FUNCS([ \
1560         chown \
1561         fchown \
1562         gethostname \
1563         lstat \
1564         inet_aton \
1565         inet_ntop \
1566         inet_pton \
1567         putenv \
1568         readv \
1569         setenv \
1570         strdup \
1571         strftime \
1572         strndup \
1573         strsep \
1574         unsetenv \
1575 ])
1576
1577 dnl Functions that are in objects that we always build from libroken
1578 AC_CHECK_FUNCS([ \
1579         asprintf \
1580         asnprintf \
1581         vasprintf \
1582         vasnprintf \
1583         vsnprintf \
1584         snprintf \
1585 ])
1586
1587 dnl Functions that we're going to try and get from libroken
1588 AC_REPLACE_FUNCS([ \
1589         daemon \
1590         ecalloc \
1591         emalloc \
1592         erealloc \
1593         err \
1594         errx \
1595         flock \
1596         freeaddrinfo \
1597         gai_strerror \
1598         getaddrinfo \
1599         getdtablesize \
1600         getnameinfo \
1601         getopt \
1602         getprogname \
1603         gettimeofday \
1604         localtime_r \
1605         mkstemp \
1606         setenv \
1607         setprogname \
1608         strcasecmp \
1609         strlcat \
1610         strnlen \
1611         strlcpy \
1612         strsep \
1613         tdelete \
1614         tfind \
1615         tsearch \
1616         twalk \
1617         unsetenv \
1618         verr \
1619         verrx \
1620         vsyslog \
1621         vwarn \
1622         vwarnx \
1623         warn \
1624         warnx \
1625 ])
1626
1627 dnl Headers that we're going to try and get from libroken
1628 AC_CHECK_HEADERS([ \
1629         err.h \
1630         search.h \
1631 ])
1632
1633 AC_CHECK_DECLS([h_errno], [], [], [
1634 #include <sys/types.h>
1635 #ifdef HAVE_NETDB_H
1636 #include <netdb.h>
1637 #endif
1638 ])
1639
1640 AC_HEADER_TIME
1641
1642 ROKEN_HEADERS=
1643 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1644       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1645       [])
1646 AC_SUBST(ROKEN_HEADERS)
1647
1648 dnl Stuff that's harder ...
1649 AC_MSG_CHECKING([for bswap16])
1650 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1651 #ifdef HAVE_SYS_TYPES_H
1652 #include <sys/types.h>
1653 #endif
1654 #ifdef HAVE_SYS_BSWAP_H
1655 #include <sys/bswap.h>
1656 #endif
1657 ],
1658 [short a, b; b = bswap16(a); ])],
1659 [AC_MSG_RESULT(yes)
1660  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1661 ],
1662 [AC_MSG_RESULT(no)])
1663
1664 AC_MSG_CHECKING([for bswap32])
1665 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1666 #include <sys/types.h>
1667 #endif
1668 #ifdef HAVE_SYS_BSWAP_H
1669 #include <sys/bswap.h>
1670 #endif
1671 ],
1672 [int a, b; b = bswap32(a); ])],
1673 [AC_MSG_RESULT(yes)
1674  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1675 ],
1676 [AC_MSG_RESULT(no)])
1677
1678 case $AFS_SYSNAME in
1679 *hp_ux* | *hpux*)
1680    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1681    ;;
1682 *)
1683    AC_MSG_CHECKING([for positional I/O])
1684    if test "$ac_cv_func_pread" = "yes" && \
1685            test "$ac_cv_func_pwrite" = "yes"; then
1686       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1687       AC_MSG_RESULT(yes)
1688    else
1689      AC_MSG_RESULT(no)
1690    fi
1691    AC_MSG_CHECKING([for vectored positional I/O])
1692    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1693                "$ac_cv_func_pwritev" = "yes" -a \
1694                "$ac_cv_func_preadv64" = "yes" -a \
1695                "$ac_cv_func_pwritev64" = "yes"],
1696          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1697           AC_MSG_RESULT(yes)],
1698          [AC_MSG_RESULT(no)])
1699    ;;
1700 esac
1701
1702 AC_MSG_CHECKING([for POSIX regex library])
1703 if test "$ac_cv_header_regex_h" = "yes" && \
1704         test "$ac_cv_func_regcomp" = "yes" && \
1705         test "$ac_cv_func_regexec" = "yes" && \
1706         test "$ac_cv_func_regerror" = "yes"; then
1707     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1708     AC_MSG_RESULT(yes)
1709 else
1710     AC_MSG_RESULT(no)
1711 fi
1712
1713 dnl Look for "non-portable" pthreads functions.
1714 save_LIBS="$LIBS"
1715 LIBS="$LIBS $PTHREAD_LIBS"
1716 AC_CHECK_FUNCS([ \
1717         pthread_set_name_np \
1718         pthread_setname_np \
1719 ])
1720
1721 dnl Sadly, there are three different versions of pthread_setname_np.
1722 dnl Try to cater for all of them.
1723 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1724     AC_MSG_CHECKING([for signature of pthread_setname_np])
1725     AC_TRY_COMPILE([
1726 #include <pthread.h>
1727 #ifdef HAVE_PTHREAD_NP_H
1728 #include <pthread_np.h>
1729 #endif
1730 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1731         AC_MSG_RESULT([three arguments])
1732         pthread_setname_np_args=3], [
1733         AC_TRY_COMPILE([
1734 #include <pthread.h>
1735 #ifdef HAVE_PTHREAD_NP_H
1736 #include <pthread_np.h>
1737 #endif
1738 ], [pthread_setname_np(pthread_self(), "test")], [
1739             AC_MSG_RESULT([two arguments])
1740             pthread_setname_np_args=2], [
1741             AC_TRY_COMPILE([
1742 #include <pthread.h>
1743 #ifdef HAVE_PTHREAD_NP_H
1744 #include <pthread_np.h>
1745 #endif
1746 ], [pthread_setname_np("test")], [
1747                 AC_MSG_RESULT([one argument])
1748                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1749 ])
1750 ])
1751 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1752 fi
1753 LIBS="$save_LIBS"
1754
1755 openafs_cv_saved_CFLAGS="$CFLAGS"
1756 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1757
1758 AC_TYPE_SIGNAL
1759 OPENAFS_RETSIGTYPE
1760 AC_CHECK_SIZEOF(void *)
1761 AC_CHECK_SIZEOF(unsigned long long)
1762 AC_CHECK_SIZEOF(unsigned long)
1763 AC_CHECK_SIZEOF(unsigned int)
1764 AC_TYPE_INTPTR_T
1765 AC_TYPE_UINTPTR_T
1766 AC_TYPE_SSIZE_T
1767 AC_CHECK_TYPE([sig_atomic_t],[],
1768     [AC_DEFINE([sig_atomic_t], [int],
1769         [Define to int if <signal.h> does not define.])],
1770 [#include <sys/types.h>
1771 #include <signal.h>])
1772 AC_CHECK_TYPE([socklen_t],[],
1773     [AC_DEFINE([socklen_t], [int],
1774         [Define to int if <sys/socket.h> does not define.])],
1775 [#include <sys/types.h>
1776 #include <sys/socket.h>])
1777 AC_CHECK_TYPES(off64_t)
1778 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1779 AC_CHECK_TYPES([struct winsize], [], [], [
1780 #ifdef HAVE_TERMIOS_H
1781 # include <termios.h>
1782 #else
1783 # include <sys/termios.h>
1784 #endif
1785 #include <sys/ioctl.h>])
1786 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1787                 struct sockaddr_storage],
1788                [], [], [
1789 #include <sys/types.h>
1790 #include <sys/socket.h>
1791 ])
1792 AC_CHECK_TYPES([sa_family_t], [], [], [
1793 #include <sys/types.h>
1794 #include <sys/socket.h>
1795 ])
1796 AC_CHECK_TYPES([struct addrinfo], [], [], [
1797 #include <sys/types.h>
1798 #ifdef HAVE_NETDB_H
1799 #include <netdb.h>
1800 #endif
1801 ])
1802 AC_CHECK_TYPES([long long], [], [], [])
1803
1804 AC_SIZEOF_TYPE(long)
1805
1806 CFLAGS="$openafs_cv_saved_CFLAGS"
1807
1808 RRA_HEADER_PAM_CONST
1809
1810
1811 dnl Directory PATH handling
1812 if test "x$enable_transarc_paths" = "xyes"  ; then
1813     afsconfdir=${afsconfdir=/usr/afs/etc}
1814     viceetcdir=${viceetcdir=/usr/vice/etc}
1815     afskerneldir=${afskerneldir=${viceetcdir}}
1816     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1817     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1818     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1819     afsdbdir=${afsdbdir=/usr/afs/db}
1820     afslogsdir=${afslogsdir=/usr/afs/logs}
1821     afslocaldir=${afslocaldir=/usr/afs/local}
1822     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1823     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1824     afsdatadir=${afsdatadir=/usr/vice/etc}
1825 else
1826     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1827     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1828     afskerneldir=${afskerneldir='${libdir}/openafs'}
1829     afssrvbindir=${afssrvbindir='${bindir}'}
1830     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1831     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1832     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1833     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1834     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1835     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1836     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1837     afsdatadir=${afsdatadir='${datadir}/openafs'}
1838 fi
1839 AC_SUBST(afsconfdir)
1840 AC_SUBST(viceetcdir)
1841 AC_SUBST(afskerneldir)
1842 AC_SUBST(afssrvbindir)
1843 AC_SUBST(afssrvsbindir)
1844 AC_SUBST(afssrvlibexecdir)
1845 AC_SUBST(afsdbdir)
1846 AC_SUBST(afslogsdir)
1847 AC_SUBST(afslocaldir)
1848 AC_SUBST(afsbackupdir)
1849 AC_SUBST(afsbosconfigdir)
1850 AC_SUBST(afsdatadir)
1851
1852 if test "x$enable_kernel_module" = "xyes"; then
1853 ENABLE_KERNEL_MODULE=libafs
1854 fi
1855
1856 if test "x$enable_pthreaded_ubik" = "xyes"; then
1857 ENABLE_PTHREADED_UBIK=yes
1858 fi
1859
1860 AC_SUBST(VFSCK)
1861 AC_SUBST(AFS_SYSNAME)
1862 AC_SUBST(AFS_PARAM_COMMON)
1863 AC_SUBST(ENABLE_KERNEL_MODULE)
1864 AC_SUBST(ENABLE_PTHREADED_UBIK)
1865 AC_SUBST(LIB_AFSDB)
1866 AC_SUBST(LINUX_KERNEL_PATH)
1867 AC_SUBST(LINUX_KERNEL_BUILD)
1868 AC_SUBST(HOST_CPU)
1869 AC_SUBST(BSD_KERNEL_PATH)
1870 AC_SUBST(BSD_KERNEL_BUILD)
1871 AC_SUBST(LINUX_VERSION)
1872 AC_SUBST(MKAFS_OSTYPE)
1873 AC_SUBST(TOP_OBJDIR)
1874 AC_SUBST(TOP_SRCDIR)
1875 AC_SUBST(TOP_INCDIR)
1876 AC_SUBST(TOP_LIBDIR)
1877 AC_SUBST(DEST)
1878 AC_SUBST(DARWIN_INFOFILE)
1879 AC_SUBST(IRIX_BUILD_IP35)
1880 AC_SUBST(HTML_XSL)
1881 AC_SUBST(XSLTPROC)
1882 AC_SUBST(DOCBOOK2PDF)
1883 AC_SUBST(DOCBOOK_STYLESHEETS)
1884
1885 OPENAFS_FUSE
1886 OPENAFS_SWIG
1887
1888 TOP_SRCDIR="${srcdir}/src"
1889 dnl
1890 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1891 dnl
1892 case $TOP_SRCDIR in
1893         /*)
1894                 ;;
1895         *)
1896                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1897                 ;;
1898 esac
1899
1900 TOP_OBJDIR="${SRCDIR_PARENT}"
1901 TOP_INCDIR="${SRCDIR_PARENT}/include"
1902 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1903 if test "${DEST}x" = "x"; then
1904         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1905 fi
1906
1907 if test "x$with_crosstools_dir" != "x"; then
1908         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1909                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1910                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1911                 RXGEN_PATH=$with_crosstools_dir/rxgen
1912         else
1913                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1914                 exit 1
1915         fi
1916 else
1917         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1918         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1919         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1920 fi
1921 AC_SUBST(COMPILE_ET_PATH)
1922 AC_SUBST(CONFIGTOOL_PATH)
1923 AC_SUBST(RXGEN_PATH)
1924
1925 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1926 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1927 AC_SUBST(HELPER_SPLINT)
1928 AC_SUBST(HELPER_SPLINTCFG)
1929
1930 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1931
1932 dnl Check to see if crypt lives in a different library
1933 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1934 AC_SUBST(LIB_crypt)
1935
1936 dnl Check to see if the compiler support labels in structs
1937 AC_MSG_CHECKING(for label support in structs)
1938 AC_TRY_COMPILE([], [
1939 extern void osi_UFSOpen(void);
1940 struct labeltest {
1941    void (*open) (void);
1942 };
1943 struct labeltest struct_labeltest = {
1944    .open       = osi_UFSOpen,
1945 }
1946 ],
1947 [AC_MSG_RESULT(yes)
1948  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1949 ],
1950 [AC_MSG_RESULT(no)
1951 ])
1952
1953 AC_MSG_CHECKING([checking for dirfd])
1954 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1955 #ifdef HAVE_DIRENT_H
1956 #include <dirent.h>
1957 #endif
1958 ]],
1959         [[DIR *d = 0; dirfd(d);]])],
1960         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1961 if test "$ac_rk_have_dirfd" = "yes" ; then
1962         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1963 fi
1964 AC_MSG_RESULT($ac_rk_have_dirfd)
1965
1966 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1967 #ifdef HAVE_DIRENT_H
1968 #include <dirent.h>
1969 #endif])
1970
1971 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
1972 [#ifdef HAVE_SYS_RESOURCE_H
1973 #include <sys/resource.h>
1974 #endif])
1975
1976 dnl Check for UUID library
1977 AC_CHECK_HEADERS([uuid/uuid.h])
1978 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1979 AC_CHECK_FUNCS([uuid_generate])
1980 ])
1981
1982