darwin-build-updates-20010910
[openafs.git] / configure.in
1 AC_INIT(src/config/stds.h)
2 AM_INIT_AUTOMAKE(openafs,devel)
3 AC_CANONICAL_HOST
4 AC_CONFIG_HEADER(src/config/afsconfig.h)
5
6 #BOZO_SAVE_CORES BOS_RESTRICTED_MODE BOS_NEW_CONFIG pam sia
7 AC_ARG_WITH(afs-sysname,
8 [  --with-afs-sysname=sys    use sys for the afs sysname]
9 )
10 AC_ARG_ENABLE( obsolete,
11 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
12 AC_ARG_ENABLE( insecure,
13 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
14 AC_ARG_ENABLE( afsdb,
15 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
16 AC_ARG_ENABLE( bos-restricted-mode,
17 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
18 AC_ARG_ENABLE( namei-fileserver,
19 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
20 AC_ARG_ENABLE( fast-restart,
21 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
22 AC_ARG_ENABLE( bitmap-later,
23 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
24 AC_ARG_ENABLE( full-vos-listvol-switch,
25 [  --enable-full-vos-listvol-switch     enable vos full listvol switch for formatted output],, enable_full_vos_listvol_switch="no")
26 AC_ARG_WITH(dux-kernel-headers,
27 [  --with-dux-kernel-headers=path       use the kernel headers found at path(optional, defaults to first match in /usr/sys)]
28 )
29 AC_ARG_WITH(linux-kernel-headers,
30 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux)]
31 )
32 AC_ARG_ENABLE(kernel-module,
33 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
34 )
35 AC_ARG_ENABLE(redhat-buildsys,
36 [  --enable-redhat-buildsys             enable compilation of the redhat build system kernel (defaults to disabled)],, enable_redhat_buildsys="no"
37 )
38 AC_ARG_ENABLE(transarc-paths,
39 [  --enable-transarc-paths                      Use Transarc style paths like /usr/afs and /usr/vice],, enable_transarc_paths="no"
40 )
41
42 AC_PROG_CC
43
44 dnl weird ass systems
45 AC_AIX
46 AC_ISC_POSIX
47 AC_MINIX
48
49 dnl Various compiler setup.
50 AC_C_INLINE
51 AC_C_CONST
52 AC_TYPE_PID_T
53 AC_TYPE_SIZE_T
54 AC_TYPE_SIGNAL
55
56 dnl Checks for programs.
57 AC_PROG_INSTALL
58 AC_PROG_LN_S
59 AC_PROG_RANLIB
60 AC_PROG_YACC
61 AM_PROG_LEX
62
63 OPENAFS_CHECK_BIGENDIAN
64
65 AC_MSG_CHECKING(your OS)
66 system=$host
67 case $system in
68         *-linux*)
69                 MKAFS_OSTYPE=LINUX
70                 if test "x$enable_redhat_buildsys" = "xyes"; then
71                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS)
72                 fi
73                 if test "x$enable_kernel_module" = "xyes"; then
74                  if test "x$with_linux_kernel_headers" != "x"; then
75                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
76                  else
77                    LINUX_KERNEL_PATH="/usr/src/linux"
78                  fi
79                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
80                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $2 }'|tail -1`
81                   if test "x$linux_kvers" = "x"; then
82                     if test -f "$LINUX_KERNEL_PATH/include/linux/version-up.h"; then
83                       linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $2 }'|tail -1`
84                       if test "x$linux_kvers" = "x"; then
85
86                         AC_MSG_ERROR(Linux headers lack version definition [2])
87                         exit 1
88                       else
89                         LINUX_VERSION="$linux_kvers"
90                       fi
91                     else
92                       AC_MSG_ERROR(Linux headers lack version definition)
93                       exit 1
94                     fi
95                   else
96                     LINUX_VERSION="$linux_kvers"
97                   fi
98                  else
99                     enable_kernel_module="no"
100                  fi
101                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
102                      enable_kernel_module="no"
103                  fi
104                  if test "x$enable_kernel_module" = "xno"; then
105                   if test "x$with_linux_kernel_headers" != "x"; then
106                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
107                    exit 1
108                   else
109                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
110                   fi
111                  fi
112                 fi
113                 AC_MSG_RESULT(linux)
114                 if test "x$enable_kernel_module" = "xyes"; then
115                  LINUX_FS_STRUCT_INODE_HAS_I_BYTES
116                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK
117                  LINUX_FS_STRUCT_INODE_HAS_I_CDEV
118                  LINUX_FS_STRUCT_INODE_HAS_I_TRUNCATE_SEM
119                  LINUX_FS_STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS
120                  LINUX_FS_STRUCT_INODE_HAS_I_MAPPING_OVERLOAD
121                  LINUX_INODE_SETATTR_RETURN_TYPE
122                  LINUX_NEED_RHCONFIG
123                  LINUX_WHICH_MODULES
124                  if test "x$ac_cv_linux_func_inode_setattr_returns_int" = "xyes" ; then
125                   AC_DEFINE(INODE_SETATTR_NOT_VOID)
126                  fi
127                  if test "x$ac_cv_linux_fs_struct_inode_has_i_dirty_data_buffers" = "xyes"; then 
128                   AC_DEFINE(STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS)
129                  fi
130                  if test "x$ac_cv_linux_fs_struct_inode_has_i_mapping_overload" = "xyes"; then 
131                   AC_DEFINE(STRUCT_INODE_HAS_I_MAPPING_OVERLOAD)
132                  fi
133                  if test "x$ac_cv_linux_fs_struct_inode_has_i_cdev" = "xyes"; then 
134                   AC_DEFINE(STRUCT_INODE_HAS_I_CDEV)
135                  fi
136                  if test "x$ac_cv_linux_fs_struct_inode_has_i_truncate_sem" = "xyes"; then 
137                   AC_DEFINE(STRUCT_INODE_HAS_I_TRUNCATE_SEM)
138                  fi
139                  if test "x$ac_cv_linux_fs_struct_inode_has_i_bytes" = "xyes"; then 
140                   AC_DEFINE(STRUCT_INODE_HAS_I_BYTES)
141                  fi
142                  if test "x$ac_cv_linux_fs_struct_address_space_has_page_lock" = "xyes"; then 
143                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK)
144                  fi
145                 :
146                 fi
147                 ;;
148         *-solaris*)
149                 MKAFS_OSTYPE=SOLARIS
150                 AC_MSG_RESULT(sun4)
151                 SOLARIS_UFSVFS_HAS_DQRWLOCK
152                 ;;
153         *-hpux*)
154                 MKAFS_OSTYPE=HPUX
155                 AC_MSG_RESULT(hp_ux)
156                 ;;
157         *-irix*)
158                 MKAFS_OSTYPE=IRIX
159                 AC_MSG_RESULT(sgi)
160                 ;;
161         *-aix*)
162                 MKAFS_OSTYPE=AIX
163                 AC_MSG_RESULT(rs_aix)
164                 ;;
165         *-osf*)
166                 MKAFS_OSTYPE=DUX
167                 AC_MSG_RESULT(alpha_dux)
168                 if test "x$enable_kernel_module" = "xyes"; then
169                  if test "x$with_dux_kernel_headers" != "x"; then
170                    HEADER_RT=`ls ${with_dux_kernel_headers}/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
171                  else
172                    HEADER_RT=`ls /usr/sys/*/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
173                  fi
174                 fi
175                 if test "$HEADER_RT" = "*" ; then
176                         AC_MSG_ERROR([Need a configured kernel directory])
177                 fi
178                 AC_SUBST([HEADER_RT])
179                 ;;
180         *-darwin*)
181                 MKAFS_OSTYPE=DARWIN
182                 AC_MSG_RESULT(ppc_darwin)
183                 ;;
184         *-freebsd*)
185                 MKAFS_OSTYPE=FBSD
186                 AC_MSG_RESULT(i386_fbsd)
187                 ;;
188         *)
189                 AC_MSG_RESULT($system)
190                 ;;
191 esac
192
193 if test "x$with_afs_sysname" != "x"; then
194         AFS_SYSNAME="$with_afs_sysname"
195 else
196         AC_MSG_CHECKING(your AFS sysname)
197         case $host in
198                 i?86-*-freebsd4.2*)
199                         AFS_SYSNAME="i386_fbsd_42"
200                         ;;
201                 hppa*-hp-hpux11*)
202                         AFS_SYSNAME="hp_ux110"
203                         ;;
204                 hppa*-hp-hpux10*)
205                         AFS_SYSNAME="hp_ux102"
206                         ;;
207                 powerpc-apple-darwin1.2*)
208                         AFS_SYSNAME="ppc_darwin_12"
209                         DARWIN_PLIST=src/afsd/afs.${AFS_SYSNAME}.plist
210                         ;;
211                 powerpc-apple-darwin1.3*)
212                         AFS_SYSNAME="ppc_darwin_13"
213                         DARWIN_PLIST=src/afsd/afs.${AFS_SYSNAME}.plist
214                         ;;
215                 powerpc-apple-darwin1.4*)
216                         AFS_SYSNAME="ppc_darwin_14"
217                         DARWIN_PLIST=src/afsd/afs.${AFS_SYSNAME}.plist
218                         ;;
219                 sparc-sun-solaris2.5*)
220                         AFS_SYSNAME="sun4x_55"
221                         ;;
222                 sparc-sun-solaris2.6)
223                         AFS_SYSNAME="sun4x_56"
224                         ;;
225                 sparc-sun-solaris2.7)
226                         AFS_SYSNAME="sun4x_57"
227                         ;;
228                 sparc-sun-solaris2.8)
229                         AFS_SYSNAME="sun4x_58"
230                         ;;
231                 alpha*-dec-osf4.0*)
232                         AFS_SYSNAME="alpha_dux40"
233                         ;;
234                 alpha*-dec-osf5.0*)
235                         AFS_SYSNAME="alpha_dux50"
236                         ;;
237                 mips-sgi-irix6.5)
238                         AFS_SYSNAME="sgi_65"
239                         ;;
240                 ia64-*-linux*)
241                         AFS_SYSNAME="ia64_linuxXX"
242                         ;;
243                 powerpc-*-linux*)
244                         AFS_SYSNAME="ppc_linuxXX"
245                         ;;
246                 alpha*-linux*)
247                         AFS_SYSNAME="alpha_linux_XX"
248                         ;;
249                 s390-*-linux*)
250                         AFS_SYSNAME="s390_linuxXX"
251                         ;;
252                 sparc-*-linux*)
253                         AFS_SYSNAME="sparc_linuxXX"
254                         ;;
255                 sparc64-*-linux*)
256                         AFS_SYSNAME="sparc64_linuxXX"
257                         ;;
258                 i?86-*-linux*)
259                         AFS_SYSNAME="i386_linuxXX"
260                         ;;
261                 power*-ibm-aix4.2*)
262                         AFS_SYSNAME="rs_aix42"
263                         ;;
264                 power*-ibm-aix4.3*)
265                         AFS_SYSNAME="rs_aix42"
266                         ;;
267                 *)
268                         AC_MSG_ERROR(An AFS sysname is required)
269                         exit 1
270                         ;;
271         esac
272         case $AFS_SYSNAME in
273                 *_linux*)
274                         AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $1 $2}'`
275                         if test "x${AFS_SYSKVERS}" = "x"; then
276                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
277                         fi
278                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
279                         AFS_SYSNAME="$_AFS_SYSNAME"
280                         ;;
281         esac
282         AC_MSG_RESULT($AFS_SYSNAME)
283 fi
284
285
286 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
287         echo Skipping library tests because they confuse Irix.
288 else
289   AC_CHECK_FUNCS(socket)
290
291   if test "$ac_cv_func_socket" = no; then
292     for lib in socket inet; do
293         if test "$HAVE_SOCKET" != 1; then
294                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET))
295         fi
296     done
297   fi
298   
299   AC_CHECK_FUNCS(connect)       
300
301   if test "$ac_cv_func_connect" = no; then
302     for lib in nsl; do
303         if test "$HAVE_CONNECT" != 1; then
304                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT))
305         fi
306     done
307   fi
308
309   AC_CHECK_FUNCS(gethostbyname)
310   if test "$ac_cv_func_gethostbyname" = no; then
311         for lib in dns nsl resolv; do
312           if test "$HAVE_GETHOSTBYNAME" != 1; then
313             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME))
314           fi
315         done    
316   fi    
317
318   AC_CHECK_FUNCS(res_search)
319   if test "$ac_cv_func_res_search" = no; then
320         for lib in dns nsl resolv; do
321           if test "$HAVE_RES_SEARCH" != 1; then
322             AC_CHECK_LIB(${lib}, res_search, LIBS="$LIBS -l$lib";HAVE_RES_SEARCH=1;AC_DEFINE(HAVE_RES_SEARCH))
323           fi
324         done    
325         if test "$HAVE_RES_SEARCH" = 1; then
326           LIB_res_search="-l$lib"       
327         fi
328   fi    
329 fi
330
331 PTHREAD_LIBS=error
332 AC_CHECK_LIB(pthread, pthread_attr_init,
333              PTHREAD_LIBS="-lpthread")
334 if test "x$PTHREAD_LIBS" = xerror; then
335         AC_CHECK_LIB(pthreads, pthread_attr_init,
336                 PTHREAD_LIBS="-lpthreads")
337 fi
338 if test "x$PTHREAD_LIBS" = xerror; then
339         AC_CHECK_LIB(c_r, pthread_attr_init,
340                 PTHREAD_LIBS="-lc_r")
341 fi
342 if test "x$PTHREAD_LIBS" = xerror; then
343         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
344 fi
345 if test "x$PTHREAD_LIBS" = xerror; then
346         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
347 fi
348 AC_SUBST(PTHREAD_LIBS)
349
350 WITH_OBSOLETE=NO
351 if test "$enable_obsolete" = "yes"; then
352         WITH_OBSOLETE=YES
353 fi
354
355 WITH_INSECURE=NO
356 if test "$enable_insecure" = "yes"; then
357         WITH_INSECURE=YES
358 fi
359
360 # Fast restart
361 if test "$enable_fast_restart" = "yes"; then
362         AC_DEFINE(FAST_RESTART)
363 fi
364
365 if test "$enable_bitmap_later" = "yes"; then
366         AC_DEFINE(BITMAP_LATER)
367 fi
368
369 if test "$enable_full_vos_listvol_switch" = "yes"; then
370         AC_DEFINE(FULL_LISTVOL_SWITCH)
371 fi
372
373 if test "$enable_bos_restricted_mode" = "yes"; then
374         AC_DEFINE(BOS_RESTRICTED_MODE)
375 fi
376
377 if test "$enable_namei_fileserver" = "yes"; then
378         AC_DEFINE(AFS_NAMEI_ENV)
379 fi
380
381 if test "$enable_afsdb" = "yes"; then
382         LIB_AFSDB="$LIB_res_search"
383         AC_DEFINE(AFS_AFSDB_ENV)
384 fi
385
386 SRCDIR_PARENT=`pwd`
387 TOP_SRCDIR="${SRCDIR_PARENT}/src"
388 TOP_INCDIR="${SRCDIR_PARENT}/include"
389 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
390 DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
391
392 dnl checks for header files.
393 AC_HEADER_STDC
394 AC_HEADER_SYS_WAIT
395 AC_HEADER_DIRENT
396 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
397 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
398 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h)
399 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
400 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h)
401 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h)
402
403 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf re_comp re_exec)
404
405 dnl Directory PATH handling
406 if test "x$enable_transarc_paths" = "xyes"  ; then 
407     afsconfdir=${afsconfdir=/usr/afs/etc}
408     viceetcdir=${viceetcdir=/usr/vice/etc}
409     afskerneldir=${afskerneldir=${viceetcdir}}
410     afssrvbindir=${afssrvbindir=/usr/afs/bin}
411     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
412     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
413     afsdbdir=${afsdbdir=/usr/afs/db}
414     afslogsdir=${afslogsdir=/usr/afs/logs}
415     afslocaldir=${afslocaldir=/usr/afs/local}
416     afsbackupdir=${afsbackupdir=/usr/afs/backup}
417     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
418     else 
419     afsconfdir=${afsconfdir=$sysconfdir/openafs/server}
420     viceetcdir=${viceetcdir=$sysconfdir/openafs}
421     afskerneldir=${afskerneldir=$libdir/openafs}
422     afssrvbindir=${afssrvbindir=$bindir}
423     afssrvsbindir=${afssrvsbindir=$sbindir}
424     afssrvlibexecdir=${afssrvlibexecdir=$libexecdir/openafs}
425     afsdbdir=${afsdbdir=$localstatedir/openafs/db}
426     afslogsdir=${afslogsdir=$localstatedir/openafs/logs}
427     afslocaldir=${afslocaldir=$localstatedir/openafs}
428     afsbackupdir=${afsbackupdir=$localstatedir/openafs/backup}
429     afsbosconfigdir=${afsbosconfigdir=$sysconfdir/openafs}
430
431 fi
432 AC_SUBST(afsconfdir)
433 AC_SUBST(viceetcdir)
434 AC_SUBST(afskerneldir)
435 AC_SUBST(afssrvbindir)
436 AC_SUBST(afssrvsbindir)
437 AC_SUBST(afssrvlibexecdir)
438 AC_SUBST(afsdbdir)
439 AC_SUBST(afslogsdir)
440 AC_SUBST(afslocaldir)
441 AC_SUBST(afsbackupdir)
442 AC_SUBST(afsbosconfigdir)
443
444 if test "x$enable_kernel_module" = "xyes"; then
445 ENABLE_KERNEL_MODULE=libafs
446 fi
447
448 AC_SUBST(AFS_SYSNAME)
449 AC_SUBST(ENABLE_KERNEL_MODULE)
450 AC_SUBST(LIB_AFSDB)
451 AC_SUBST(LINUX_KERNEL_PATH)
452 AC_SUBST(LINUX_VERSION)
453 AC_SUBST(MKAFS_OSTYPE)
454 AC_SUBST(TOP_SRCDIR)
455 AC_SUBST(TOP_INCDIR)
456 AC_SUBST(TOP_LIBDIR)
457 AC_SUBST(DEST)
458 AC_SUBST(WITH_OBSOLETE)
459 AC_SUBST(WITH_INSECURE)
460
461 AC_OUTPUT(             \
462 Makefile               \
463 src/afs/Makefile \
464 src/afsd/Makefile \
465 ${DARWIN_PLIST} \
466 src/afsmonitor/Makefile \
467 src/afsweb/Makefile \
468 src/audit/Makefile \
469 src/auth/test/Makefile \
470 src/auth/Makefile \
471 src/bozo/test/Makefile \
472 src/bozo/Makefile \
473 src/bu_utils/Makefile \
474 src/bubasics/Makefile \
475 src/bucoord/Makefile \
476 src/budb/Makefile \
477 src/butc/Makefile \
478 src/butm/Makefile \
479 src/cmd/test/Makefile \
480 src/cmd/Makefile \
481 src/comerr/test/Makefile \
482 src/comerr/Makefile \
483 src/config/Makefile \
484 src/config/Makefile.version-NOCML \
485 src/config/Makefile.${AFS_SYSNAME} \
486 src/dauth/Makefile \
487 src/des/test/Makefile \
488 src/des/Makefile \
489 src/des_stub/Makefile \
490 src/dir/test/Makefile \
491 src/dir/Makefile \
492 src/export/Makefile \
493 src/finale/Makefile \
494 src/fsint/Makefile \
495 src/fsprobe/Makefile \
496 src/ftpd43+/Makefile \
497 src/gtx/Makefile \
498 src/inetd/Makefile \
499 src/kauth/test/Makefile \
500 src/kauth/Makefile \
501 src/libacl/test/Makefile \
502 src/libacl/Makefile \
503 src/libadmin/adminutil/Makefile \
504 src/libadmin/Makefile \
505 src/libadmin/bos/Makefile \
506 src/libadmin/cfg/test/Makefile \
507 src/libadmin/cfg/Makefile \
508 src/libadmin/client/Makefile \
509 src/libadmin/kas/Makefile \
510 src/libadmin/pts/Makefile \
511 src/libadmin/samples/Makefile \
512 src/libadmin/test/Makefile \
513 src/libadmin/vos/Makefile \
514 src/libafs/MakefileProto.${MKAFS_OSTYPE} \
515 src/libafsauthent/Makefile \
516 src/libafsrpc/Makefile \
517 src/libuafs/MakefileProto.${MKAFS_OSTYPE} \
518 src/log/test/Makefile \
519 src/log/Makefile \
520 src/login/Makefile \
521 src/lwp/test/Makefile \
522 src/lwp/Makefile \
523 src/mpp/Makefile \
524 src/ntp/Makefile \
525 src/null/Makefile \
526 src/package/Makefile \
527 src/pam/Makefile \
528 src/pinstall/test/Makefile \
529 src/pinstall/Makefile \
530 src/procmgmt/Makefile \
531 src/procmgmt/test/Makefile \
532 src/ptserver/Makefile \
533 src/rcp/Makefile \
534 src/rlogind/Makefile \
535 src/rsh/Makefile \
536 src/rx/Makefile \
537 src/rx/bulk.example/Makefile \
538 src/rx/bulktest/Makefile \
539 src/rx/multi.example/Makefile \
540 src/rx/simple.example/Makefile \
541 src/rx/test/Makefile \
542 src/rxdebug/Makefile \
543 src/rxgen/Makefile \
544 src/rxkad/Makefile \
545 src/rxkad/test/Makefile \
546 src/rxstat/Makefile \
547 src/scout/Makefile \
548 src/sgistuff/Makefile \
549 src/sia/Makefile \
550 src/sys/Makefile \
551 src/tbutc/Makefile \
552 src/tsm41/Makefile \
553 src/tviced/Makefile \
554 src/ubik/Makefile \
555 src/update/Makefile \
556 src/usd/test/Makefile \
557 src/usd/Makefile \
558 src/uss/Makefile \
559 src/util/Makefile \
560 src/util/test/Makefile \
561 src/venus/test/Makefile \
562 src/venus/Makefile \
563 src/vfsck/Makefile \
564 src/viced/Makefile \
565 src/vlserver/Makefile \
566 src/vol/Makefile \
567 src/vol/test/Makefile \
568 src/volser/Makefile \
569 src/wsadmin.src/Makefile \
570 src/xstat/Makefile \
571 )