man-page-fs-updates-20070817
[openafs.git] / doc / man-pages / generate-html
1 #!/usr/bin/perl -w
2 package OpenAFS::HTML;
3
4 use strict;
5 use vars qw(@ISA);
6
7 use Pod::Simple::Search;
8 @ISA = qw(Pod::Simple::HTML);
9
10 # Add a link back to the index page to the top and bottom of each generated
11 # page.
12 #
13 # The hideous approach we have to use is because, unless we create a
14 # Pod::Simple::HTML object and then rebless it, the html_header_after_title
15 # and html_footer subs are placed in the OpenAFS::HTML package.  That means we
16 # can't override them in a subclass and still call the SUPER version since
17 # we'll be overwriting the SUPER version, and there aren't other good
18 # opportunities to change the default values that I can see.
19 sub new {
20     my $class = shift;
21     my $self = Pod::Simple::HTML->new (@_);
22     bless ($self, 'OpenAFS::HTML');
23     my $link = '<p class="indexlink"><a href="../index.html">'
24         . 'Back to Index</a></p>' . "\n";
25     my $after = $self->html_header_after_title;
26     $self->html_header_after_title ($after . $link);
27     my $end = $self->html_footer;
28     $self->html_footer ($link . $end);
29     return $self;
30 }
31
32 sub do_man_link {
33     my ($self, $token) = @_;
34     my $page = $token->attr ('to');
35     my ($name, $section) = ($page =~ /^([^\(]+)\((\d+)\)$/);
36     return unless $name;
37     my @url = ('..', $section, $name);
38     return join ('/', map { $self->pagepath_url_escape ($_) } @url)
39         . $Pod::Simple::HTML::HTML_EXTENSION;
40 }
41
42 # Underscore isn't allowed in man page names in Pod::Simple 3.04, so links
43 # like L<fs_setacl(8)> show up as POD links.  Discover that case and dispatch
44 # everything else to the standard do_pod_link implementation.
45 sub do_pod_link {
46     my ($self, $token) = @_;
47     my $target = $token->attr ('to');
48     if ($target && $target =~ /^([^\s\(]+)\((\d+)\)$/) {
49         return $self->do_man_link ($token);
50     } else {
51         return $self->SUPER::do_pod_link ($token);
52     }
53 }
54
55 sub VERSION () { '1.1' }
56
57 $Pod::Simple::HTML::Tagmap{'item-bullet'} = '<li><p>';
58 $Pod::Simple::HTML::Tagmap{'/item-bullet'} = '</p></li>';
59 $Pod::Simple::HTML::Tagmap{'item-number'} = '<li><p>';
60 $Pod::Simple::HTML::Tagmap{'/item-number'} = '</p></li>';
61
62 package main;
63
64 use strict;
65
66 use File::Copy;
67 use Pod::Simple::HTMLBatch;
68
69 our $HEADER = <<'EOH';
70 <html>
71 <head>
72   <title>OpenAFS Reference Manual</title>
73   <link rel="stylesheet" title="style" type="text/css" href="style.css" media="all">
74 </head>
75 <body class='contentspage'>
76 <h1>OpenAFS Reference Manual</h1>
77 EOH
78
79 our %HEADINGS = (1 => 'User Commands',
80                  5 => 'Configuration and Data Files',
81                  8 => 'Administrator Commands');
82
83 # Scan all of the POD files and build a list of section, name, and short
84 # description, returning that as an array.
85 sub scan_names {
86     my @index;
87     for my $dir (qw(pod1 pod5 pod8)) {
88         my $section = $dir;
89         $section =~ s/^pod//;
90         opendir (D, $dir) or die "Cannot open $dir: $!\n";
91         for my $file (sort grep { !/^\./ && !/CVS/ } readdir D) {
92             open (F, "$dir/$file") or die "Cannot open $dir/$file: $!\n";
93             my ($name, $desc);
94             local $_;
95             while (<F>) {
96                 last if /^=head1/ && !/^=head1\s+NAME\b/;
97                 next unless /\s+-\s+/;
98                 ($name, $desc) = split (/\s+-\s+/, $_, 2);
99             }
100             unless ($name) {
101                 warn "$dir/$file: cannot find NAME section, skipping\n";
102             }
103             my $page = $file;
104             $page =~ s/\.pod$//;
105             push (@index, [ $section, $name, $page, $desc ]);
106         }
107         closedir D;
108     }
109     return @index;
110 }
111
112 unless (-d 'html') {
113     mkdir ('html', 0755) or die "Cannot create html directory: $!\n";
114 }
115 for my $dir (qw(pod1 pod5 pod8)) {
116     my $section = $dir;
117     $section =~ s/^pod//;
118     mkdir ("html/$section", 0755) unless -d "html/$section";
119
120     my $conv = Pod::Simple::HTMLBatch->new;
121     $conv->verbose (0);
122     $conv->index (undef);
123     $conv->contents_file (undef);
124     $conv->add_css ('../style.css', 1);
125     $conv->css_flurry (0);
126     $conv->javascript_flurry (0);
127     $conv->html_render_class ('OpenAFS::HTML');
128     $conv->batch_convert ($dir, "html/$section");
129 }
130 copy ('style.css', 'html/style.css') or die "Cannot copy style.css: $!\n";
131
132 open (INDEX, '> html/index.html')
133     or die "Cannot create html/index.html: $!\n";
134 print INDEX $HEADER;
135 print INDEX "<table>\n";
136 my @index = scan_names;
137 my $current;
138 for my $entry (@index) {
139     my ($section, $name, $page, $desc) = @$entry;
140     for ($name, $desc) {
141         s/&/&gt;/g;
142         s/</&lt;/g;
143         s/>/&gt;/g;
144     }
145     if (!$current || $section != $current) {
146         print INDEX qq(<tr><td>&nbsp;</td></tr>\n);
147         print INDEX qq(<tr class="heading"><th colspan="2">);
148         print INDEX qq($HEADINGS{$section}</th></tr>\n);
149         $current = $section;
150     }
151     print INDEX qq(<tr><td><a href="$section/$page.html">$name</a></td>);
152     print INDEX qq(<td>$desc</td></tr>\n);
153 }
154 print INDEX "</table>\n</body>\n</html>\n";