src/cf/linux-test1.m4

   1 # AC_TRY_KBUILD26([INCLUDES], [FUNCTION-BODY],
   2 #                 [ACTION-IF-SUCCESS], [ACTION-IF-FAILURE])
   3 #
   4 AC_DEFUN([AC_TRY_KBUILD26], [
   5   rm -fr conftest.dir
   6   if mkdir conftest.dir; then
   7   cd conftest.dir
   8     cat >Makefile <<_ACEOF
   9 CFLAGS += $CPPFLAGS
  10
  11 obj-m += conftest.o
  12 _ACEOF
  13     cat >conftest.c <<\_ACEOF
  14 $1
  15
  16 void conftest(void)
  17 {
  18 $2
  19 }
  20 _ACEOF
  21     cd ..
  22   fi
  23   AS_IF(AC_RUN_LOG([make -C $LINUX_KERNEL_PATH M=`pwd`/conftest.dir modules > /dev/null]),
  24       [$3], [$4])
  25   rm -fr conftest.dir])
  26
  27
  28 # AC_TRY_KBUILD24([INCLUDES], [FUNCTION-BODY],
  29 #                 [ACTION-IF-SUCCESS], [ACTION-IF-FAILURE])
  30 #
  31 AC_DEFUN([AC_TRY_KBUILD24], [
  32   ac_save_CPPFLAGS="$CPPFLAGS"
  33   CPPFLAGS="-I$LINUX_KERNEL_PATH/include -D__KERNEL__ $CPPFLAGS"
  34   AC_TRY_COMPILE([$1], [$2], [$3], [$4])
  35   CPPFLAGS="$ac_save_CPPFLAGS"])
  36
  37
  38 # AC_TRY_KBUILD([INCLUDES], [FUNCTION-BODY],
  39 #               [ACTION-IF-SUCCESS], [ACTION-IF-FAILURE])
  40 #
  41 AC_DEFUN([AC_TRY_KBUILD], [
  42   if test -f $LINUX_KERNEL_PATH/scripts/Makefile.build; then
  43     AC_TRY_KBUILD26([$1], [$2], [$3], [$4])
  44   else
  45     AC_TRY_KBUILD24([$1], [$2], [$3], [$4])
  46   fi])