vlserver: --enable-ubik-read-while-write configure option
[openafs.git] / src / cf / summary.m4
1 dnl
2 dnl configure summary
3 dnl
4 dnl
5 dnl OPENAFS_SUMMARY_CHECK_NAME
6 dnl
7 dnl Check whether namei fileserver is enabled for this platform/configure options.
8 dnl When namei is enabled with a configure option, the AFS_NAMEI_ENV will be defined
9 dnl for the test program. AFS_NAMEI_ENV can also be defined in the platform and sysname
10 dnl param headers for this platform. Avoid including the afs/afs_sysnames.h header since
11 dnl it has not been installed to the `include/afs' system directory yet (and is not
12 dnl needed for this namei check).
13 dnl
14 dnl Note that, if set, AFS_PARAM_COMMON is the header filename, including the .h suffix.
15 dnl
16 AC_DEFUN([OPENAFS_SUMMARY_CHECK_NAMEI],
17   [AC_CACHE_CHECK([whether namei fileserver is enabled], [openafs_cv_summary_check_namei],
18     [rm -f conftestparam.h; touch conftestparam.h;  # automatically cleaned up by configure
19     AS_IF([test "x${AFS_PARAM_COMMON}" != "x" && test -f "src/config/${AFS_PARAM_COMMON}"],
20       [grep -v '#include <afs/afs_sysnames.h>' "src/config/${AFS_PARAM_COMMON}" >> conftestparam.h])
21     AS_IF([test "x${AFS_SYSNAME}" != "x" && test -f "src/config/param.${AFS_SYSNAME}.h"],
22       [grep -v '#include <afs/afs_sysnames.h>' "src/config/param.${AFS_SYSNAME}.h" >> conftestparam.h])
23     AC_COMPILE_IFELSE(
24       [AC_LANG_PROGRAM([[
25 #define IGNORE_STDS_H
26 #include "conftestparam.h"
27         ]], [[
28 #ifndef AFS_NAMEI_ENV
29     namei_disabled
30 #endif
31         ]])],
32       [openafs_cv_summary_check_namei="yes"],
33       [openafs_cv_summary_check_namei="no"])
34   ])
35 ])
36 dnl
37 dnl OPENAFS_SUMMARY
38 dnl
39 dnl Print the configure summary.
40 dnl
41 AC_DEFUN([OPENAFS_SUMMARY],[
42   AS_IF([test "x${LIB_curses}" = "x"],
43     [summary_build_scout="no"],
44     [summary_build_scout="yes"])
45   AS_IF([test "x${DOCBOOK_STYLESHEETS}" = "x"],
46     [summary_docbook_stylesheets="no"],
47     [summary_docbook_stylesheets="yes"])
48   AS_IF([test "x${DOXYGEN}" = "x"],
49     [summary_doxygen="no"],
50     [summary_doxygen="yes"])
51   AS_IF([test "${summary_doxygen}" = "yes" -a "${HAVE_DOT}" = "yes"],
52     [summary_doxygen_graphs="yes"],
53     [summary_doxygen_graphs="no"])
54
55   cat <<EOF
56 ***************************************************************
57 OpenAFS configure summary
58
59   version : ${VERSION}
60   sysname : ${AFS_SYSNAME}
61
62 debug:
63   userspace              : ${enable_debug}
64   kernel                 : ${enable_debug_kernel}
65 options:
66   transarc paths         : ${enable_transarc_paths}
67   namei fileserver       : ${openafs_cv_summary_check_namei}
68   use unix sockets       : ${USE_UNIX_SOCKETS}
69   ptserver supergroups   : ${enable_supergroups}
70   pthreaded ubik         : ${enable_pthreaded_ubik}
71   install kauth          : ${INSTALL_KAUTH}
72   ubik read while write  : ${enable_ubik_read_while_write}
73 build:
74   scout/afsmonitor       : ${summary_build_scout}
75   pam                    : ${HAVE_PAM}
76   login                  : ${BUILD_LOGIN}
77   uss                    : ${BUILD_USS}
78 doc generation:
79   docbook stylesheets    : ${summary_docbook_stylesheets}
80   doxygen                : ${summary_doxygen}
81   doxygen graphs         : ${summary_doxygen_graphs}
82 libraries:
83   krb5    : ${KRB5_LIBS}
84   curses  : ${LIB_curses}
85   afsdb   : ${LIB_AFSDB}
86   crypt   : ${LIB_crypt}
87   hcrypto : ${LIB_hcrypto}
88   intl    : ${LIB_libintl}
89 ***************************************************************
90 EOF
91 ])