ec180e134ae40fa5bec9cc4206fc2f1c5fb7eeb1
[openafs.git] / src / cf / summary.m4
1 dnl
2 dnl configure summary
3 dnl
4 dnl
5 dnl OPENAFS_SUMMARY_CHECK_NAME
6 dnl
7 dnl Check whether namei fileserver is enabled for this platform/configure options.
8 dnl When namei is enabled with a configure option, the AFS_NAMEI_ENV will be defined
9 dnl for the test program. AFS_NAMEI_ENV can also be defined in the platform and sysname
10 dnl param headers for this platform. Avoid including the afs/afs_sysnames.h header since
11 dnl it has not been installed to the `include/afs' system directory yet (and is not
12 dnl needed for this namei check).
13 dnl
14 dnl Note that, if set, AFS_PARAM_COMMON is the header filename, including the .h suffix.
15 dnl
16 AC_DEFUN([OPENAFS_SUMMARY_CHECK_NAMEI],
17   [AC_CACHE_CHECK([whether namei fileserver is enabled], [openafs_cv_summary_check_namei],
18     [rm -f conftestparam.h; touch conftestparam.h;  # automatically cleaned up by configure
19     AS_IF([test "x${AFS_PARAM_COMMON}" != "x" && test -f "src/config/${AFS_PARAM_COMMON}"],
20       [grep -v '#include <afs/afs_sysnames.h>' "src/config/${AFS_PARAM_COMMON}" >> conftestparam.h])
21     AS_IF([test "x${AFS_SYSNAME}" != "x" && test -f "src/config/param.${AFS_SYSNAME}.h"],
22       [grep -v '#include <afs/afs_sysnames.h>' "src/config/param.${AFS_SYSNAME}.h" >> conftestparam.h])
23     AC_COMPILE_IFELSE(
24       [AC_LANG_PROGRAM([[
25 #define IGNORE_STDS_H
26 #include "conftestparam.h"
27         ]], [[
28 #ifndef AFS_NAMEI_ENV
29     namei_disabled
30 #endif
31         ]])],
32       [openafs_cv_summary_check_namei="yes"],
33       [openafs_cv_summary_check_namei="no"])
34   ])
35 ])
36 dnl
37 dnl OPENAFS_SUMMARY
38 dnl
39 dnl Print the configure summary.
40 dnl
41 AC_DEFUN([OPENAFS_SUMMARY],[
42   AS_IF([test "x${LIB_curses}" = "x"],
43     [summary_build_scout="no"],
44     [summary_build_scout="yes"])
45   AS_IF([test "x${DOCBOOK_STYLESHEETS}" = "x"],
46     [summary_docbook_stylesheets="no"],
47     [summary_docbook_stylesheets="yes"])
48
49   cat <<EOF
50 ***************************************************************
51 configure summary
52
53   version : ${VERSION}
54   sysname : ${AFS_SYSNAME}
55
56 debug:
57   userspace              : ${enable_debug}
58   kernel                 : ${enable_debug_kernel}
59
60 options:
61   transarc paths         : ${enable_transarc_paths}
62   namei fileserver       : ${openafs_cv_summary_check_namei}
63   use unix sockets       : ${USE_UNIX_SOCKETS}
64   ptserver supergroups   : ${enable_supergroups}
65   pthreaded ubik         : ${enable_pthreaded_ubik}
66   install kauth          : ${INSTALL_KAUTH}
67   docbook stylesheets    : ${summary_docbook_stylesheets}
68
69 build:
70   scout/afsmonitor       : ${summary_build_scout}
71   pam                    : ${HAVE_PAM}
72   login                  : ${BUILD_LOGIN}
73   uss                    : ${BUILD_USS}
74
75 libraries:
76   krb5    : ${KRB5_LIBS}
77   curses  : ${LIB_curses}
78   afsdb   : ${LIB_AFSDB}
79   crypt   : ${LIB_crypt}
80   hcrypto : ${LIB_hcrypto}
81   intl    : ${LIB_libintl}
82 ***************************************************************
83 EOF
84 ])