acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN(OPENAFS_CONFIGURE_COMMON,[
   8
   9 AC_CANONICAL_HOST
  10 SRCDIR_PARENT=`pwd`
  11
  12 #BOZO_SAVE_CORES BOS_RESTRICTED_MODE BOS_NEW_CONFIG pam sia
  13 AC_ARG_WITH(afs-sysname,
  14 [  --with-afs-sysname=sys    use sys for the afs sysname]
  15 )
  16 AC_ARG_ENABLE( obsolete,
  17 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
  18 AC_ARG_ENABLE( insecure,
  19 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
  20 AC_ARG_ENABLE( afsdb,
  21 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
  22 AC_ARG_ENABLE( bos-restricted-mode,
  23 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
  24 AC_ARG_ENABLE( namei-fileserver,
  25 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
  26 AC_ARG_ENABLE( fast-restart,
  27 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
  28 AC_ARG_ENABLE( bitmap-later,
  29 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
  30 AC_ARG_ENABLE( full-vos-listvol-switch,
  31 [  --enable-full-vos-listvol-switch     enable vos full listvol switch for formatted output],, enable_full_vos_listvol_switch="no")
  32 AC_ARG_WITH(dux-kernel-headers,
  33 [  --with-dux-kernel-headers=path       use the kernel headers found at path(optional, defaults to first match in /usr/sys)]
  34 )
  35 AC_ARG_WITH(linux-kernel-headers,
  36 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux)]
  37 )
  38 AC_ARG_ENABLE(kernel-module,
  39 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
  40 )
  41 AC_ARG_ENABLE(redhat-buildsys,
  42 [  --enable-redhat-buildsys             enable compilation of the redhat build system kernel (defaults to disabled)],, enable_redhat_buildsys="no"
  43 )
  44 AC_ARG_ENABLE(transarc-paths,
  45 [  --enable-transarc-paths                      Use Transarc style paths like /usr/afs and /usr/vice],, enable_transarc_paths="no"
  46 )
  47 AC_ARG_ENABLE(tivoli-tsm,
  48 [  --enable-tivoli-tsm                  Enable use of the Tivoli TSM API libraries for butc support],, enable_tivoli_tsm="no"
  49 )
  50
  51 dnl weird ass systems
  52 AC_AIX
  53 AC_ISC_POSIX
  54 AC_MINIX
  55
  56 dnl Various compiler setup.
  57 AC_C_INLINE
  58 AC_C_CONST
  59 AC_PROG_CC
  60 AC_TYPE_PID_T
  61 AC_TYPE_SIZE_T
  62 AC_TYPE_SIGNAL
  63
  64 dnl Checks for programs.
  65 AC_PROG_INSTALL
  66 AC_PROG_LN_S
  67 AC_PROG_RANLIB
  68 AC_PROG_YACC
  69 AM_PROG_LEX
  70
  71 OPENAFS_CHECK_BIGENDIAN
  72
  73 AC_MSG_CHECKING(your OS)
  74 system=$host
  75 case $system in
  76         *-linux*)
  77                 MKAFS_OSTYPE=LINUX
  78                 if test "x$enable_redhat_buildsys" = "xyes"; then
  79                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS)
  80                 fi
  81                 if test "x$enable_kernel_module" = "xyes"; then
  82                  if test "x$with_linux_kernel_headers" != "x"; then
  83                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
  84                  else
  85                    LINUX_KERNEL_PATH="/usr/src/linux"
  86                  fi
  87                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
  88                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
  89                   if test "x$linux_kvers" = "x"; then
  90                     if test -f "$LINUX_KERNEL_PATH/include/linux/version-up.h"; then
  91                       linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
  92                       if test "x$linux_kvers" = "x"; then
  93
  94                         AC_MSG_ERROR(Linux headers lack version definition [2])
  95                         exit 1
  96                       else
  97                         LINUX_VERSION="$linux_kvers"
  98                       fi
  99                     else
 100                       AC_MSG_ERROR(Linux headers lack version definition)
 101                       exit 1
 102                     fi
 103                   else
 104                     LINUX_VERSION="$linux_kvers"
 105                   fi
 106                  else
 107                     enable_kernel_module="no"
 108                  fi
 109                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
 110                      enable_kernel_module="no"
 111                  fi
 112                  if test "x$enable_kernel_module" = "xno"; then
 113                   if test "x$with_linux_kernel_headers" != "x"; then
 114                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 115                    exit 1
 116                   else
 117                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 118                   fi
 119                  fi
 120                 fi
 121                 AC_MSG_RESULT(linux)
 122                 if test "x$enable_kernel_module" = "xyes"; then
 123                  ifdef([OPENAFS_CONFIGURE_LIBAFS],
 124                    [LINUX_BUILD_VNODE_FROM_INODE(src/config,afs)],
 125                    [LINUX_BUILD_VNODE_FROM_INODE(${srcdir}/src/config,src/afs/LINUX,${srcdir}/src/afs/LINUX)]
 126                  )
 127                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK
 128                  LINUX_FS_STRUCT_INODE_HAS_I_TRUNCATE_SEM
 129                  LINUX_FS_STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS
 130                  LINUX_FS_STRUCT_INODE_HAS_I_DEVICES
 131                  LINUX_INODE_SETATTR_RETURN_TYPE
 132                  LINUX_NEED_RHCONFIG
 133                  LINUX_WHICH_MODULES
 134                  if test "x$ac_cv_linux_func_inode_setattr_returns_int" = "xyes" ; then
 135                   AC_DEFINE(INODE_SETATTR_NOT_VOID)
 136                  fi
 137                  if test "x$ac_cv_linux_fs_struct_address_space_has_page_lock" = "xyes"; then
 138                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK)
 139                  fi
 140                  if test "x$ac_cv_linux_fs_struct_inode_has_i_truncate_sem" = "xyes"; then
 141                   AC_DEFINE(STRUCT_INODE_HAS_I_TRUNCATE_SEM)
 142                  fi
 143                  if test "x$ac_cv_linux_fs_struct_inode_has_i_devices" = "xyes"; then
 144                   AC_DEFINE(STRUCT_INODE_HAS_I_DEVICES)
 145                  fi
 146                  if test "x$ac_cv_linux_fs_struct_inode_has_i_dirty_data_buffers" = "xyes"; then
 147                   AC_DEFINE(STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS)
 148                  fi
 149                 :
 150                 fi
 151                 ;;
 152         *-solaris*)
 153                 MKAFS_OSTYPE=SOLARIS
 154                 AC_MSG_RESULT(sun4)
 155                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 156                 ;;
 157         *-hpux*)
 158                 MKAFS_OSTYPE=HPUX
 159                 AC_MSG_RESULT(hp_ux)
 160                 ;;
 161         *-irix*)
 162                 if test -d /usr/include/sys/SN/SN1; then
 163                  IRIX_BUILD_IP35="IP35"
 164                 fi
 165                 MKAFS_OSTYPE=IRIX
 166                 AC_MSG_RESULT(sgi)
 167                 ;;
 168         *-aix*)
 169                 MKAFS_OSTYPE=AIX
 170                 AC_MSG_RESULT(rs_aix)
 171                 ;;
 172         *-osf*)
 173                 MKAFS_OSTYPE=DUX
 174                 AC_MSG_RESULT(alpha_dux)
 175                 if test "x$enable_kernel_module" = "xyes"; then
 176                  if test "x$with_dux_kernel_headers" != "x"; then
 177                    HEADER_RT=`ls ${with_dux_kernel_headers}/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 178                  else
 179                    HEADER_RT=`ls /usr/sys/*/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 180                  fi
 181                 fi
 182                 if test "$HEADER_RT" = "*" ; then
 183                         AC_MSG_ERROR([Need a configured kernel directory])
 184                 fi
 185                 AC_SUBST([HEADER_RT])
 186                 ;;
 187         *-darwin*)
 188                 MKAFS_OSTYPE=DARWIN
 189                 AC_MSG_RESULT(ppc_darwin)
 190                 ;;
 191         *-freebsd*)
 192                 MKAFS_OSTYPE=FBSD
 193                 AC_MSG_RESULT(i386_fbsd)
 194                 ;;
 195         *-netbsd*)
 196                 MKAFS_OSTYPE=NBSD
 197                 AC_MSG_RESULT(nbsd)
 198                 ;;
 199         *-openbsd*)
 200                 MKAFS_OSTYPE=OBSD
 201                 AC_MSG_RESULT(i386_obsd)
 202                 ;;
 203         *)
 204                 AC_MSG_RESULT($system)
 205                 ;;
 206 esac
 207
 208 if test "x$with_afs_sysname" != "x"; then
 209         AFS_SYSNAME="$with_afs_sysname"
 210 else
 211         AC_MSG_CHECKING(your AFS sysname)
 212         case $host in
 213                 i?86-*-freebsd4.2*)
 214                         AFS_SYSNAME="i386_fbsd_42"
 215                         ;;
 216                 i?86-*-netbsd*1.5*)
 217                         AFS_PARAM_COMMON=param.nbsd15.h
 218                         AFS_SYSNAME="i386_nbsd15"
 219                         ;;
 220                 alpha-*-netbsd*1.5*)
 221                         AFS_PARAM_COMMON=param.nbsd15.h
 222                         AFS_SYSNAME="alpha_nbsd15"
 223                         ;;
 224                 hppa*-hp-hpux11*)
 225                         AFS_SYSNAME="hp_ux110"
 226                         ;;
 227                 hppa*-hp-hpux10*)
 228                         AFS_SYSNAME="hp_ux102"
 229                         ;;
 230                 powerpc-apple-darwin1.2*)
 231                         AFS_SYSNAME="ppc_darwin_12"
 232                         ;;
 233                 powerpc-apple-darwin1.3*)
 234                         AFS_SYSNAME="ppc_darwin_13"
 235                         ;;
 236                 powerpc-apple-darwin1.4*)
 237                         AFS_SYSNAME="ppc_darwin_14"
 238                         ;;
 239                 powerpc-apple-darwin5.1*)
 240                         AFS_SYSNAME="ppc_darwin_14"
 241                         ;;
 242                 powerpc-apple-darwin5.2*)
 243                         AFS_SYSNAME="ppc_darwin_14"
 244                         ;;
 245                 sparc-sun-solaris2.5*)
 246                         AFS_SYSNAME="sun4x_55"
 247                         ;;
 248                 sparc-sun-solaris2.6)
 249                         AFS_SYSNAME="sun4x_56"
 250                         ;;
 251                 sparc-sun-solaris2.7)
 252                         AFS_SYSNAME="sun4x_57"
 253                         ;;
 254                 sparc-sun-solaris2.8)
 255                         AFS_SYSNAME="sun4x_58"
 256                         ;;
 257                 sparc-sun-solaris2.9)
 258                         AFS_SYSNAME="sun4x_59"
 259                         ;;
 260                 alpha*-dec-osf4.0*)
 261                         AFS_SYSNAME="alpha_dux40"
 262                         ;;
 263                 alpha*-dec-osf5.0*)
 264                         AFS_SYSNAME="alpha_dux50"
 265                         ;;
 266                 mips-sgi-irix6.5)
 267                         AFS_SYSNAME="sgi_65"
 268                         ;;
 269                 ia64-*-linux*)
 270                         AFS_SYSNAME="ia64_linuxXX"
 271                         ;;
 272                 powerpc-*-linux*)
 273                         AFS_SYSNAME="ppc_linuxXX"
 274                         ;;
 275                 alpha*-linux*)
 276                         AFS_SYSNAME="alpha_linux_XX"
 277                         ;;
 278                 s390-*-linux*)
 279                         AFS_SYSNAME="s390_linuxXX"
 280                         ;;
 281                 sparc-*-linux*)
 282                         AFS_SYSNAME="sparc_linuxXX"
 283                         ;;
 284                 sparc64-*-linux*)
 285                         AFS_SYSNAME="sparc64_linuxXX"
 286                         ;;
 287                 i?86-*-linux*)
 288                         AFS_SYSNAME="i386_linuxXX"
 289                         ;;
 290                 parisc-*-linux-gnu)
 291                         AFS_SYSNAME="parisc_linuxXX"
 292                         ;;
 293                 power*-ibm-aix4.2*)
 294                         AFS_SYSNAME="rs_aix42"
 295                         ;;
 296                 power*-ibm-aix4.3*)
 297                         AFS_SYSNAME="rs_aix42"
 298                         ;;
 299                 *)
 300                         AC_MSG_ERROR(An AFS sysname is required)
 301                         exit 1
 302                         ;;
 303         esac
 304         case $AFS_SYSNAME in
 305                 *_linux*)
 306                         AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $[]1 $[]2}'`
 307                         if test "x${AFS_SYSKVERS}" = "x"; then
 308                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 309                         fi
 310                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 311                         AFS_SYSNAME="$_AFS_SYSNAME"
 312                         ;;
 313         esac
 314         AC_MSG_RESULT($AFS_SYSNAME)
 315 fi
 316
 317 case $AFS_SYSNAME in
 318         *_darwin*)
 319                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 320                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 321                 ;;
 322 esac
 323
 324 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
 325         echo Skipping library tests because they confuse Irix.
 326 else
 327   AC_CHECK_FUNCS(socket)
 328
 329   if test "$ac_cv_func_socket" = no; then
 330     for lib in socket inet; do
 331         if test "$HAVE_SOCKET" != 1; then
 332                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET))
 333         fi
 334     done
 335   fi
 336
 337   AC_CHECK_FUNCS(connect)
 338
 339   if test "$ac_cv_func_connect" = no; then
 340     for lib in nsl; do
 341         if test "$HAVE_CONNECT" != 1; then
 342                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT))
 343         fi
 344     done
 345   fi
 346
 347   AC_CHECK_FUNCS(gethostbyname)
 348   if test "$ac_cv_func_gethostbyname" = no; then
 349         for lib in dns nsl resolv; do
 350           if test "$HAVE_GETHOSTBYNAME" != 1; then
 351             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME))
 352           fi
 353         done
 354   fi
 355
 356   AC_CHECK_FUNCS(res_search)
 357   if test "$ac_cv_func_res_search" = no; then
 358         for lib in dns nsl resolv; do
 359           if test "$HAVE_RES_SEARCH" != 1; then
 360             AC_CHECK_LIB(${lib}, res_search, LIBS="$LIBS -l$lib";HAVE_RES_SEARCH=1;AC_DEFINE(HAVE_RES_SEARCH))
 361           fi
 362         done
 363         if test "$HAVE_RES_SEARCH" = 1; then
 364           LIB_res_search="-l$lib"
 365         fi
 366   fi
 367 fi
 368
 369 PTHREAD_LIBS=error
 370 AC_CHECK_LIB(pthread, pthread_attr_init,
 371              PTHREAD_LIBS="-lpthread")
 372 if test "x$PTHREAD_LIBS" = xerror; then
 373         AC_CHECK_LIB(pthreads, pthread_attr_init,
 374                 PTHREAD_LIBS="-lpthreads")
 375 fi
 376 if test "x$PTHREAD_LIBS" = xerror; then
 377         AC_CHECK_LIB(c_r, pthread_attr_init,
 378                 PTHREAD_LIBS="-lc_r")
 379 fi
 380 if test "x$PTHREAD_LIBS" = xerror; then
 381         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
 382 fi
 383 if test "x$PTHREAD_LIBS" = xerror; then
 384         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
 385 fi
 386 AC_SUBST(PTHREAD_LIBS)
 387
 388 WITH_OBSOLETE=NO
 389 if test "$enable_obsolete" = "yes"; then
 390         WITH_OBSOLETE=YES
 391 fi
 392
 393 WITH_INSECURE=NO
 394 if test "$enable_insecure" = "yes"; then
 395         WITH_INSECURE=YES
 396 fi
 397
 398 # Fast restart
 399 if test "$enable_fast_restart" = "yes"; then
 400         AC_DEFINE(FAST_RESTART)
 401 fi
 402
 403 if test "$enable_bitmap_later" = "yes"; then
 404         AC_DEFINE(BITMAP_LATER)
 405 fi
 406
 407 if test "$enable_full_vos_listvol_switch" = "yes"; then
 408         AC_DEFINE(FULL_LISTVOL_SWITCH)
 409 fi
 410
 411 if test "$enable_bos_restricted_mode" = "yes"; then
 412         AC_DEFINE(BOS_RESTRICTED_MODE)
 413 fi
 414
 415 if test "$enable_namei_fileserver" = "yes"; then
 416         AC_DEFINE(AFS_NAMEI_ENV)
 417 fi
 418
 419 if test "$enable_afsdb" = "yes"; then
 420         LIB_AFSDB="$LIB_res_search"
 421         AC_DEFINE(AFS_AFSDB_ENV)
 422 fi
 423
 424 dnl check for tivoli
 425 AC_MSG_CHECKING(for tivoli tsm butc support)
 426 XBSA_CFLAGS=""
 427 if test "$enable_tivoli_tsm" = "yes"; then
 428         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
 429         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
 430
 431         if test -e "$XBSADIR1/xbsa.h"; then
 432                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
 433                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 434         elif test -e "$XBSADIR2/xbsa.h"; then
 435                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
 436                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 437         else
 438                 AC_MSG_RESULT([no, missing xbsa.h header file])
 439         fi
 440 else
 441         AC_MSG_RESULT([no])
 442 fi
 443 AC_SUBST(XBSA_CFLAGS)
 444
 445 dnl checks for header files.
 446 AC_HEADER_STDC
 447 AC_HEADER_SYS_WAIT
 448 AC_HEADER_DIRENT
 449 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
 450 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
 451 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h)
 452 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
 453 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h)
 454 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h)
 455
 456 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf re_comp re_exec)
 457
 458 dnl Directory PATH handling
 459 if test "x$enable_transarc_paths" = "xyes"  ; then
 460     afsconfdir=${afsconfdir=/usr/afs/etc}
 461     viceetcdir=${viceetcdir=/usr/vice/etc}
 462     afskerneldir=${afskerneldir=${viceetcdir}}
 463     afssrvbindir=${afssrvbindir=/usr/afs/bin}
 464     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
 465     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
 466     afsdbdir=${afsdbdir=/usr/afs/db}
 467     afslogsdir=${afslogsdir=/usr/afs/logs}
 468     afslocaldir=${afslocaldir=/usr/afs/local}
 469     afsbackupdir=${afsbackupdir=/usr/afs/backup}
 470     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
 471 else
 472     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
 473     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
 474     afskerneldir=${afskerneldir='${libdir}/openafs'}
 475     afssrvbindir=${afssrvbindir='${bindir}'}
 476     afssrvsbindir=${afssrvsbindir='${sbindir}'}
 477     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
 478     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
 479     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
 480     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
 481     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
 482     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
 483 fi
 484 AC_SUBST(afsconfdir)
 485 AC_SUBST(viceetcdir)
 486 AC_SUBST(afskerneldir)
 487 AC_SUBST(afssrvbindir)
 488 AC_SUBST(afssrvsbindir)
 489 AC_SUBST(afssrvlibexecdir)
 490 AC_SUBST(afsdbdir)
 491 AC_SUBST(afslogsdir)
 492 AC_SUBST(afslocaldir)
 493 AC_SUBST(afsbackupdir)
 494 AC_SUBST(afsbosconfigdir)
 495
 496 if test "x$enable_kernel_module" = "xyes"; then
 497 ENABLE_KERNEL_MODULE=libafs
 498 fi
 499
 500 AC_SUBST(AFS_SYSNAME)
 501 AC_SUBST(AFS_PARAM_COMMON)
 502 AC_SUBST(ENABLE_KERNEL_MODULE)
 503 AC_SUBST(LIB_AFSDB)
 504 AC_SUBST(LINUX_KERNEL_PATH)
 505 AC_SUBST(LINUX_VERSION)
 506 AC_SUBST(MKAFS_OSTYPE)
 507 AC_SUBST(TOP_OBJDIR)
 508 AC_SUBST(TOP_SRCDIR)
 509 AC_SUBST(TOP_INCDIR)
 510 AC_SUBST(TOP_LIBDIR)
 511 AC_SUBST(DEST)
 512 AC_SUBST(WITH_OBSOLETE)
 513 AC_SUBST(WITH_INSECURE)
 514 AC_SUBST(DARWIN_INFOFILE)
 515 AC_SUBST(IRIX_BUILD_IP35)
 516
 517 OPENAFS_OSCONF
 518
 519 ])