acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #   define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 #define _FILE_OFFSET_BITS 64
  48 #define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 #include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
  76
  77 dnl General feature options.
  78 AC_ARG_ENABLE([pam],
  79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
  80     ,
  81     [enable_pam="yes"])
  82 AC_ARG_ENABLE([gtx],
  83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
  84 AC_ARG_ENABLE([uss],
  85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
  86 AC_ARG_ENABLE([namei-fileserver],
  87     [AS_HELP_STRING([--enable-namei-fileserver],
  88         [force compilation of namei fileserver in preference to inode
  89          fileserver])],
  90     ,
  91     [enable_namei_fileserver="default"])
  92 AC_ARG_ENABLE([supergroups],
  93     [AS_HELP_STRING([--enable-supergroups],
  94         [enable support for nested pts groups])],
  95     ,
  96     [enable_supergroups="no"])
  97 AC_ARG_ENABLE([bitmap-later],
  98     [AS_HELP_STRING([--enable-bitmap-later],
  99         [enable fast startup of file server by not reading bitmap till
 100          needed])],
 101     ,
 102     [enable_bitmap_later="no"])
 103 AC_ARG_ENABLE([unix-sockets],
 104     [AS_HELP_STRING([--disable-unix-sockets],
 105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 106     ,
 107     [enable_unix_sockets="yes"])
 108 AC_ARG_ENABLE([tivoli-tsm],
 109     [AS_HELP_STRING([--enable-tivoli-tsm],
 110         [enable use of the Tivoli TSM API libraries for butc support])],
 111     ,
 112     [enable_tivoli_tsm="no"])
 113 AC_ARG_ENABLE([pthreaded-ubik],
 114     [AS_HELP_STRING([--enable-pthreaded-ubik],
 115         [enable installation of pthreaded ubik applications (defaults to
 116          disabled)])],
 117     ,
 118     [enable_pthreaded_ubik="no"])
 119
 120 dnl Kernel module build options.
 121 AC_ARG_WITH([linux-kernel-headers],
 122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 123         [use the kernel headers found at path (optional, defaults to
 124          /usr/src/linux-2.4, then /usr/src/linux)])])
 125 AC_ARG_WITH([linux-kernel-build],
 126     [AS_HELP_STRING([--with-linux-kernel-build=path],
 127         [use the kernel build found at path(optional, defaults to
 128         /usr/src/linux-2.4, then /usr/src/linux)])])
 129 AC_ARG_WITH([bsd-kernel-headers],
 130     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 131         [use the kernel headers found at path (optional, defaults to
 132          /usr/src/sys)])])
 133 AC_ARG_WITH([bsd-kernel-build],
 134     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 135         [use the kernel build found at path (optional, defaults to
 136          KSRC/i386/compile/GENERIC)])])
 137 AC_ARG_WITH([linux-kernel-packaging],
 138     [AS_HELP_STRING([--with-linux-kernel-packaging],
 139         [use standard naming conventions to aid Linux kernel build packaging
 140          (disables MPS, sets the kernel module name to openafs.ko, and
 141          installs kernel modules into the standard Linux location)])],
 142     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
 143      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
 144     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
 145 AC_ARG_ENABLE([kernel-module],
 146     [AS_HELP_STRING([--disable-kernel-module],
 147         [disable compilation of the kernel module (defaults to enabled)])],
 148     ,
 149     [enable_kernel_module="yes"])
 150 AC_ARG_ENABLE([redhat-buildsys],
 151     [AS_HELP_STRING([--enable-redhat-buildsys],
 152         [enable compilation of the redhat build system kernel (defaults to
 153          disabled)])],
 154     ,
 155     [enable_redhat_buildsys="no"])
 156
 157 dnl Installation locations.
 158 AC_ARG_ENABLE([transarc-paths],
 159     [AS_HELP_STRING([--enable-transarc-paths],
 160         [use Transarc style paths like /usr/afs and /usr/vice])],
 161     ,
 162     [enable_transarc_paths="no"])
 163
 164 dnl Optimization and debugging flags.
 165 AC_ARG_ENABLE([strip-binaries],
 166     [AS_HELP_STRING([--disable-strip-binaries],
 167         [disable stripping of symbol information from binaries (defaults to
 168          enabled)])],
 169     ,
 170     [enable_strip_binaries="maybe"])
 171 AC_ARG_ENABLE([debug],
 172     [AS_HELP_STRING([--enable-debug],
 173         [enable compilation of the user space code with debugging information
 174          (defaults to disabled)])],
 175     ,
 176     [enable_debug="no"])
 177 AC_ARG_ENABLE([optimize],
 178     [AS_HELP_STRING([--disable-optimize],
 179         [disable optimization for compilation of the user space code (defaults
 180          to enabled)])],
 181     ,
 182     [enable_optimize="yes"])
 183 AC_ARG_ENABLE([warnings],
 184     [AS_HELP_STRING([--enable-warnings],
 185         [enable compilation warnings when building with gcc (defaults to
 186          disabled)])],
 187     ,
 188     [enable_warnings="no"])
 189 AC_ARG_ENABLE([checking],
 190     [AS_HELP_STRING([--enable-checking],
 191         [turn compilation warnings into errors when building with gcc (defaults
 192          to disabled)])],
 193     [enable_checking="$enableval"],
 194     [enable_checking="no"])
 195 AC_ARG_ENABLE([debug-kernel],
 196     [AS_HELP_STRING([--enable-debug-kernel],
 197         [enable compilation of the kernel module with debugging information
 198          (defaults to disabled)])],
 199     ,
 200     [enable_debug_kernel="no"])
 201 AC_ARG_ENABLE([optimize-kernel],
 202     [AS_HELP_STRING([--disable-optimize-kernel],
 203         [disable compilation of the kernel module with optimization (defaults
 204          based on platform)])],
 205     ,
 206     [enable_optimize_kernel=""])
 207 AC_ARG_ENABLE([debug-lwp],
 208     [AS_HELP_STRING([--enable-debug-lwp],
 209         [enable compilation of the LWP code with debugging information
 210          (defaults to disabled)])],
 211     ,
 212     [enable_debug_lwp="no"])
 213 AC_ARG_ENABLE([optimize-lwp],
 214     [AS_HELP_STRING([--disable-optimize-lwp],
 215         [disable optimization for compilation of the LWP code (defaults to
 216          enabled)])],
 217     ,
 218     [enable_optimize_lwp="yes"])
 219 AC_ARG_ENABLE([debug-pam],
 220     [AS_HELP_STRING([--enable-debug-pam],
 221         [enable compilation of the PAM code with debugging information
 222          (defaults to disabled)])],
 223     ,
 224     [enable_debug_pam="no"])
 225 AC_ARG_ENABLE([optimize-pam],
 226     [AS_HELP_STRING([--disable-optimize-pam],
 227         [disable optimization for compilation of the PAM code (defaults to
 228          enabled)])],
 229     ,
 230     [enable_optimize_pam="yes"])
 231 AC_ARG_ENABLE([linux-syscall-probing],
 232     [AS_HELP_STRING([--enable-linux-syscall-probing],
 233         [enable Linux syscall probing (defaults to autodetect)])],
 234     ,
 235     [enable_linux_syscall_probing="maybe"])
 236 AC_ARG_WITH([crosstools-dir],
 237     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
 238
 239 AC_ARG_WITH([xslt-processor],
 240         AS_HELP_STRING([--with-xslt-processor=ARG],
 241         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 242         [XSLTPROC="$withval"],
 243         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
 244
 245 AC_ARG_WITH([html-xsl],
 246         AS_HELP_STRING([--with-html-xsl],
 247         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 248         [HTML_XSL="$withval"],
 249         [HTML_XSL="html/chunk.xsl"])
 250
 251 AC_ARG_WITH([docbook2pdf],
 252         AS_HELP_STRING([--with-docbook2pdf=ARG],
 253         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 254         [DOCBOOK2PDF="$withval"],
 255         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
 256
 257 AC_ARG_WITH([docbook-stylesheets],
 258         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 259         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 260         [DOCBOOK_STYLESHEETS="$withval"],
 261         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
 262         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
 263                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 264         fi)
 265
 266 enable_login="no"
 267
 268 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 269 dnl documentation build.
 270 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 271
 272 dnl weird ass systems
 273 dnl AC_AIX
 274 AC_ISC_POSIX
 275 dnl AC_MINIX
 276
 277 dnl Various compiler setup.
 278 AC_TYPE_PID_T
 279 AC_TYPE_SIZE_T
 280
 281 dnl Checks for programs.
 282 AC_PROG_INSTALL
 283 AC_PROG_LN_S
 284 AC_PROG_RANLIB
 285 AC_PROG_YACC
 286 AM_PROG_LEX
 287 dnl if we are flex, be lex-compatible
 288 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 289
 290 OPENAFS_FORCE_ABS_INSTALL
 291 OPENAFS_CHECK_BIGENDIAN
 292 OPENAFS_PRINTF_TAKES_Z_LEN
 293
 294 AC_MSG_CHECKING(your OS)
 295 system=$host
 296 case $system in
 297         *-linux*)
 298
 299                 MKAFS_OSTYPE=LINUX
 300                 if test "x$enable_redhat_buildsys" = "xyes"; then
 301                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 302                 fi
 303                 if test "x$enable_kernel_module" = "xyes"; then
 304                  if test "x$with_linux_kernel_headers" != "x"; then
 305                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 306                  else
 307                    LINUX_KERNEL_PATH="/lib/modules/`uname -r`/source"
 308                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 309                      LINUX_KERNEL_PATH="/lib/modules/`uname -r`/build"
 310                    fi
 311                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 312                      LINUX_KERNEL_PATH="/usr/src/linux-2.4"
 313                    fi
 314                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 315                      LINUX_KERNEL_PATH="/usr/src/linux"
 316                    fi
 317                  fi
 318                  if test "x$with_linux_kernel_build" != "x"; then
 319                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 320                  else
 321                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 322                  fi
 323                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 324                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 325                    LINUX_VERSION="$linux_kvers"
 326                  else
 327                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 328                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 329                      LINUX_VERSION="$linux_kvers"
 330                    else
 331                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 332                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 333                        if test "x$linux_kvers" = "x"; then
 334                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 335                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 336                            if test "x$linux_kvers" = "x"; then
 337                              AC_MSG_ERROR(Linux headers lack version definition [2])
 338                              exit 1
 339                            else
 340                              LINUX_VERSION="$linux_kvers"
 341                            fi
 342                          else
 343                            AC_MSG_ERROR(Linux headers lack version definition)
 344                            exit 1
 345                          fi
 346                        else
 347                          LINUX_VERSION="$linux_kvers"
 348                        fi
 349                      else
 350                        enable_kernel_module="no"
 351                      fi
 352                    fi
 353                  fi
 354                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 355                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 356                      enable_kernel_module="no"
 357                  fi
 358                  if test "x$enable_kernel_module" = "xno"; then
 359                   if test "x$with_linux_kernel_headers" != "x"; then
 360                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 361                    exit 1
 362                   else
 363                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 364                   fi
 365                  fi
 366                  dnl do we need to determine SUBARCH from autoconf.h
 367                  SUBARCH=default
 368                 fi
 369                 AC_MSG_RESULT(linux)
 370                 if test "x$enable_kernel_module" = "xyes"; then
 371                  case "$LINUX_VERSION" in
 372                   2.2.*) AFS_SYSKVERS=22 ;;
 373                   2.4.*) AFS_SYSKVERS=24 ;;
 374                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
 375                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 376                  esac
 377                 fi
 378                 ;;
 379         *-solaris*)
 380                 MKAFS_OSTYPE=SOLARIS
 381                 AC_MSG_RESULT(sun4)
 382                 AC_PATH_PROG(SOLARISCC, [cc], ,
 383                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 384                 if test "x$SOLARISCC" = "x" ; then
 385                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 386                 fi
 387                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 388                 SOLARIS_FS_HAS_FS_ROLLED
 389                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 390                 ;;
 391         *-sunos*)
 392                 MKAFS_OSTYPE=SUNOS
 393                 enable_kernel_module=no
 394                 AC_MSG_RESULT(sun4)
 395                 ;;
 396         *-hpux*)
 397                 MKAFS_OSTYPE=HPUX
 398                 AC_MSG_RESULT(hp_ux)
 399                 if test -f "/usr/old/usr/include/ndir.h"; then
 400                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 401                 fi
 402                 ;;
 403         *-irix*)
 404                 if test -d /usr/include/sys/SN/SN1; then
 405                  IRIX_BUILD_IP35="IP35"
 406                 fi
 407                 MKAFS_OSTYPE=IRIX
 408                 AC_MSG_RESULT(sgi)
 409                 ;;
 410         *-aix*)
 411                 MKAFS_OSTYPE=AIX
 412                 AC_MSG_RESULT(rs_aix)
 413                 ;;
 414         arm-*-darwin*)
 415                 MKAFS_OSTYPE=DARWIN
 416                 AC_MSG_RESULT(arm_darwin)
 417                 ;;
 418         powerpc-*-darwin*)
 419                 MKAFS_OSTYPE=DARWIN
 420                 AC_MSG_RESULT(ppc_darwin)
 421                 ;;
 422         i386-*-darwin*)
 423                 MKAFS_OSTYPE=DARWIN
 424                 AC_MSG_RESULT(x86_darwin)
 425                 ;;
 426         x86_64-*-darwin*)
 427                 MKAFS_OSTYPE=DARWIN
 428                 AC_MSG_RESULT(x86_darwin)
 429                 ;;
 430         i386-*-freebsd*)
 431                 MKAFS_OSTYPE=FBSD
 432                 AC_MSG_RESULT(i386_fbsd)
 433                 ;;
 434         x86_64-*-freebsd*)
 435                 MKAFS_OSTYPE=FBSD
 436                 AC_MSG_RESULT(amd64_fbsd)
 437                 ;;
 438         *-netbsd*)
 439                 MKAFS_OSTYPE=NBSD
 440                 AC_MSG_RESULT(nbsd)
 441                 ;;
 442         x86_64-*-openbsd*)
 443                 MKAFS_OSTYPE=OBSD
 444                 AC_MSG_RESULT(amd64_obsd)
 445                 ;;
 446         i386-*-openbsd*)
 447                 MKAFS_OSTYPE=OBSD
 448                 AC_MSG_RESULT(i386_obsd)
 449                 ;;
 450         *-dragonfly*)
 451                 MKAFS_OSTYPE=DFBSD
 452                 AC_MSG_RESULT(i386_dfbsd)
 453                 ;;
 454         *)
 455                 AC_MSG_RESULT($system)
 456                 ;;
 457 esac
 458
 459 if test "x$with_afs_sysname" != "x"; then
 460         AFS_SYSNAME="$with_afs_sysname"
 461 else
 462         AC_MSG_CHECKING(your AFS sysname)
 463         case $host in
 464                 i?86-*-openbsd?.?)
 465                         v=${host#*openbsd}
 466                         vM=${v%.*}
 467                         vm=${v#*.}
 468                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 469                         ;;
 470                 sparc64-*-openbsd?.?)
 471                         v=${host#*openbsd}
 472                         vM=${v%.*}
 473                         vm=${v#*.}
 474                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 475                         ;;
 476                 x86_64-*-openbsd?.?)
 477                         v=${host#*openbsd}
 478                         vM=${v%.*}
 479                         vm=${v#*.}
 480                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 481                         ;;
 482                 i?86-*-freebsd*.*)
 483                         v=${host#*freebsd}
 484                         vM=${v%.*}
 485                         vm=${v#*.}
 486                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 487                         ;;
 488                 x86_64-*-freebsd*.*)
 489                         v=${host#*freebsd}
 490                         vM=${v%.*}
 491                         vm=${v#*.}
 492                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 493                         ;;
 494                 i386-*-dragonfly?.*)
 495                         v=${host#*dragonfly}
 496                         vM=${v%.*}
 497                         vm=${v#*.}
 498                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 499                         ;;
 500                 i?86-*-netbsd*1.6[[M-Z]]*)
 501                         AFS_SYSNAME="i386_nbsd20"
 502                         ;;
 503                 powerpc-*-netbsd*1.6[[M-Z]]*)
 504                         AFS_SYSNAME="ppc_nbsd20"
 505                         ;;
 506                 *-*-netbsd*)
 507                         arch=${host%%-unknown*}
 508                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 509                                                -e 's/powerpc/ppc/g')
 510                         v=${host#*netbsd}
 511                         v=${v#*aout}
 512                         v=${v#*ecoff}
 513                         v=${v#*elf}
 514                         vM=${v%%.*}
 515                         vM=${vM%.*}
 516                         v=${v#*.}
 517                         vm=${v%%.*}
 518                         vm=${vm%.*}
 519                         vm=${vm%%[[_A-Z]]*}
 520                         if test $vm -eq 99 ; then
 521                                 vM=$((vM+1))
 522                         fi
 523                         if test $vM -gt 1 ; then
 524                                 vm=0
 525                         fi
 526                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 527                         ;;
 528                 hppa*-hp-hpux11.0*)
 529                         AFS_SYSNAME="hp_ux110"
 530                         ;;
 531                 hppa*-hp-hpux11.11)
 532                         AFS_SYSNAME="hp_ux11i"
 533                         ;;
 534                 hppa*-hp-hpux11.23)
 535                         AFS_SYSNAME="hp_ux1123"
 536                         ;;
 537                 ia64-hp-hpux11.22)
 538                         AFS_SYSNAME="ia64_hpux1122"
 539                         ;;
 540                 ia64-hp-hpux*)
 541                         AFS_SYSNAME="ia64_hpux1123"
 542                         ;;
 543                 hppa*-hp-hpux10*)
 544                         AFS_SYSNAME="hp_ux102"
 545                         ;;
 546                 powerpc-apple-darwin7*)
 547                         AFS_SYSNAME="ppc_darwin_70"
 548                         OSXSDK="macosx10.3"
 549                         ;;
 550                 powerpc-apple-darwin8.*)
 551                         AFS_SYSNAME="ppc_darwin_80"
 552                         OSXSDK="macosx10.4"
 553                         ;;
 554                 i386-apple-darwin8.*)
 555                         AFS_SYSNAME="x86_darwin_80"
 556                         OSXSDK="macosx10.4"
 557                         ;;
 558                 powerpc-apple-darwin9.*)
 559                         AFS_SYSNAME="ppc_darwin_90"
 560                         OSXSDK="macosx10.5"
 561                         ;;
 562                 i386-apple-darwin9.*)
 563                         AFS_SYSNAME="x86_darwin_90"
 564                         OSXSDK="macosx10.5"
 565                         ;;
 566                 i?86-apple-darwin10.*)
 567                         AFS_SYSNAME="x86_darwin_100"
 568                         OSXSDK="macosx10.6"
 569                         ;;
 570                 x86_64-apple-darwin10.*)
 571                         AFS_SYSNAME="x86_darwin_100"
 572                         OSXSDK="macosx10.6"
 573                         ;;
 574                 arm-apple-darwin10.*)
 575                         AFS_SYSNAME="arm_darwin_100"
 576                         OSXSDK="iphoneos4.0"
 577                         ;;
 578                 x86_64-apple-darwin11.*)
 579                         AFS_SYSNAME="x86_darwin_110"
 580                         OSXSDK="macosx10.7"
 581                         ;;
 582                 i?86-apple-darwin11.*)
 583                         AFS_SYSNAME="x86_darwin_110"
 584                         OSXSDK="macosx10.7"
 585                         ;;
 586                 x86_64-apple-darwin12.*)
 587                         AFS_SYSNAME="x86_darwin_120"
 588                         OSXSDK="macosx10.8"
 589                         ;;
 590                 i?86-apple-darwin12.*)
 591                         AFS_SYSNAME="x86_darwin_120"
 592                         OSXSDK="macosx10.8"
 593                         ;;
 594                 sparc-sun-solaris2.8)
 595                         AFS_SYSNAME="sun4x_58"
 596                         ;;
 597                 sparc-sun-solaris2.9)
 598                         AFS_SYSNAME="sun4x_59"
 599                         ;;
 600                 sparc-sun-solaris2.10)
 601                         AFS_SYSNAME="sun4x_510"
 602                         ;;
 603                 sparc-sun-solaris2.11)
 604                         AFS_SYSNAME="sun4x_511"
 605                         ;;
 606                 i386-pc-solaris2.8)
 607                         AFS_SYSNAME="sunx86_58"
 608                         ;;
 609                 i386-pc-solaris2.9)
 610                         AFS_SYSNAME="sunx86_59"
 611                         ;;
 612                 i386-pc-solaris2.10)
 613                         AFS_SYSNAME="sunx86_510"
 614                         ;;
 615                 i386-pc-solaris2.11)
 616                         AFS_SYSNAME="sunx86_511"
 617                         ;;
 618                 alpha*-dec-osf4.0*)
 619                         AFS_SYSNAME="alpha_dux40"
 620                         ;;
 621                 alpha*-dec-osf5.0*)
 622                         AFS_SYSNAME="alpha_dux50"
 623                         ;;
 624                 alpha*-dec-osf5.1*)
 625                         AFS_SYSNAME="alpha_dux51"
 626                         ;;
 627                 mips-sgi-irix6.5)
 628                         AFS_SYSNAME="sgi_65"
 629                         ;;
 630                 ia64-*-linux*)
 631                         AFS_SYSNAME="ia64_linuxXX"
 632                         ;;
 633                 powerpc-*-linux*)
 634                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 635                         ;;
 636                 powerpc64-*-linux*)
 637                         AFS_SYSNAME="ppc64_linuxXX"
 638                         ;;
 639                 alpha*-linux*)
 640                         AFS_SYSNAME="alpha_linux_XX"
 641                         ;;
 642                 s390-*-linux*)
 643                         AFS_SYSNAME="s390_linuxXX"
 644                         ;;
 645                 s390x-*-linux*)
 646                         AFS_SYSNAME="s390x_linuxXX"
 647                         ;;
 648                 sparc-*-linux*)
 649                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 650                         ;;
 651                 sparc64-*-linux*)
 652                         AFS_SYSNAME="sparc64_linuxXX"
 653                         ;;
 654                 i?86-*-linux*)
 655                         AFS_SYSNAME="i386_linuxXX"
 656                         ;;
 657                 arm*-linux*)
 658                         AFS_SYSNAME="arm_linuxXX"
 659                         ;;
 660                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 661                         AFS_SYSNAME="parisc_linuxXX"
 662                         enable_pam="no"
 663                         ;;
 664                 power*-ibm-aix4.2*)
 665                         AFS_SYSNAME="rs_aix42"
 666                         enable_pam="no"
 667                         ;;
 668                 power*-ibm-aix4.3*)
 669                         AFS_SYSNAME="rs_aix42"
 670                         enable_pam="no"
 671                         ;;
 672                 power*-ibm-aix5.1*)
 673                         AFS_SYSNAME="rs_aix51"
 674                         enable_pam="no"
 675                         ;;
 676                 power*-ibm-aix5.2*)
 677                         AFS_SYSNAME="rs_aix52"
 678                         enable_pam="no"
 679                         ;;
 680                 power*-ibm-aix5.3*)
 681                         AFS_SYSNAME="rs_aix53"
 682                         enable_pam="no"
 683                         ;;
 684                 power*-ibm-aix6.1*)
 685                         AFS_SYSNAME="rs_aix61"
 686                         enable_pam="no"
 687                         ;;
 688                 x86_64-*-linux-gnu)
 689                         AFS_SYSNAME="amd64_linuxXX"
 690                         enable_pam="yes"
 691                         ;;
 692                 *)
 693                         AC_MSG_ERROR(An AFS sysname is required)
 694                         exit 1
 695                         ;;
 696         esac
 697         case $AFS_SYSNAME in
 698                 *_linux* | *_umlinux*)
 699                         if test "x${AFS_SYSKVERS}" = "x"; then
 700                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 701                         fi
 702                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 703                         AFS_SYSNAME="$_AFS_SYSNAME"
 704                         AC_TRY_KBUILD(
 705                          [],
 706                          [#ifndef CONFIG_USERMODE
 707                           #error not UML
 708                           #endif],
 709                          ac_cv_linux_is_uml=yes,)
 710                         if test "${ac_cv_linux_is_uml}" = yes; then
 711                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 712                         fi
 713                         AFS_SYSNAME="$_AFS_SYSNAME"
 714                         ;;
 715         esac
 716         AC_MSG_RESULT($AFS_SYSNAME)
 717 fi
 718
 719 case $AFS_SYSNAME in
 720         *_darwin*)
 721                 AC_CHECK_HEADERS(crt_externs.h)
 722                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 723                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 724                 AC_SUBST(OSXSDK)
 725                 ;;
 726 esac
 727
 728 dnl Some hosts have a separate common param file they should include.  Figure
 729 dnl out if we're on one of them now that we know the sysname.
 730 case $AFS_SYSNAME in
 731     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 732     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 733     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 734     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 735     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 736     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 737     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 738     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 739     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 740     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 741     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 742     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 743     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 744     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 745     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 746     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 747     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 748     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 749     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 750     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 751     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 752     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 753     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 754     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 755     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 756     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 757     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 758     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 759     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 760 # Linux alpha adds an extra underscore for no good reason.
 761     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 762     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 763     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 764 esac
 765
 766 OPENAFS_OSCONF
 767
 768 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 769
 770                 # Add (sub-) architecture-specific paths needed by conftests
 771                 case $AFS_SYSNAME  in
 772                         *_umlinux26)
 773                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 774                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 775                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 776                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 777                 esac
 778
 779                 if test "x$enable_kernel_module" = "xyes"; then
 780                  if test "x$enable_debug_kernel" = "xno"; then
 781                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 782                  fi
 783                  OPENAFS_GCC_SUPPORTS_MARCH
 784                  AC_SUBST(P5PLUS_KOPTS)
 785                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 786                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 787                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 788                  OPENAFS_GCC_SUPPORTS_PIPE
 789                  AC_SUBST(LINUX_GCC_KOPTS)
 790
 791                  dnl Setup the kernel build environment
 792                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 793                  LINUX_KERNEL_COMPILE_WORKS
 794
 795                  dnl Check for header files
 796                  AC_CHECK_LINUX_HEADER([config.h])
 797                  AC_CHECK_LINUX_HEADER([completion.h])
 798                  AC_CHECK_LINUX_HEADER([exportfs.h])
 799                  AC_CHECK_LINUX_HEADER([freezer.h])
 800                  AC_CHECK_LINUX_HEADER([key-type.h])
 801                  AC_CHECK_LINUX_HEADER([semaphore.h])
 802                  AC_CHECK_LINUX_HEADER([seq_file.h])
 803
 804                  dnl Type existence checks
 805                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 806
 807                  dnl Check for structure elements
 808                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 809                                        [write_begin], [fs.h])
 810                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 811                                        [backing-dev.h])
 812                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 813                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 814                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 815                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 816                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 817                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 818                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 819                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 820                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 821                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 822                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 823                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 824                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 825                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 826                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 827                                        [fs.h])
 828                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 829                                        [fs.h])
 830                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 831                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 832                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 833                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 834                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 835                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 836                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 837                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 838                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 839                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 840                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 841
 842                  dnl Check for typed structure elements
 843                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 844                                              [buf], [fs.h])
 845
 846                  dnl Function existence checks
 847
 848                  AC_CHECK_LINUX_FUNC([bdi_init],
 849                                      [#include <linux/backing-dev.h>],
 850                                      [bdi_init(NULL);])
 851                  AC_CHECK_LINUX_FUNC([PageChecked],
 852                                      [#include <linux/mm.h>
 853 #include <linux/page-flags.h>],
 854                                      [struct page *_page;
 855                                       int bchecked = PageChecked(_page);])
 856                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 857                                      [#include <linux/mm.h>
 858 #include <linux/page-flags.h>],
 859                                      [struct page *_page;
 860                                       int bchecked = PageFsMisc(_page);])
 861                  AC_CHECK_LINUX_FUNC([clear_inode],
 862                                      [#include <linux/fs.h>],
 863                                      [clear_inode(NULL);])
 864                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 865                                      [#include <linux/time.h>],
 866                                      [struct timespec s;
 867                                       s = current_kernel_time();])
 868                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 869                                      [#include <linux/fs.h>],
 870                                      [d_alloc_anon(NULL);])
 871                  AC_CHECK_LINUX_FUNC([d_make_root],
 872                                      [#include <linux/fs.h>],
 873                                      [d_make_root(NULL);])
 874                  AC_CHECK_LINUX_FUNC([do_sync_read],
 875                                      [#include <linux/fs.h>],
 876                                      [do_sync_read(NULL, NULL, 0, NULL);])
 877                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 878                                      [#include <linux/sched.h>],
 879                                      [pid_t p; find_task_by_pid(p);])
 880                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 881                                      [#include <linux/fs.h>],
 882                                      [generic_file_aio_read(NULL,NULL,0,0);])
 883                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 884                                      [#include <linux/pagemap.h>],
 885                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 886                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 887                                      [#include <linux/list.h>],
 888                                      [hlist_unhashed(0);])
 889                  AC_CHECK_LINUX_FUNC([i_size_read],
 890                                      [#include <linux/fs.h>],
 891                                      [i_size_read(NULL);])
 892                  AC_CHECK_LINUX_FUNC([inode_setattr],
 893                                      [#include <linux/fs.h>],
 894                                      [inode_setattr(NULL, NULL);])
 895                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
 896                                      [#include <linux/net.h>],
 897                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
 898                  AC_CHECK_LINUX_FUNC([page_follow_link],
 899                                      [#include <linux/fs.h>],
 900                                      [page_follow_link(0,0);])
 901                  AC_CHECK_LINUX_FUNC([page_offset],
 902                                      [#include <linux/pagemap.h>],
 903                                      [page_offset(NULL);])
 904                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
 905                                      [#include <linux/pagevec.h>],
 906                                      [__pagevec_lru_add_file(NULL);])
 907                  AC_CHECK_LINUX_FUNC([path_lookup],
 908                                      [#include <linux/fs.h>
 909                                       #include <linux/namei.h>],
 910                                      [path_lookup(NULL, 0, NULL);])
 911                  AC_CHECK_LINUX_FUNC([putname],
 912                                      [#include <linux/fs.h>
 913                                       #include <linux/namei.h>],
 914                                      [putname(NULL);])
 915                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
 916                                      [#include <linux/rcupdate.h>],
 917                                      [rcu_read_lock();])
 918                  AC_CHECK_LINUX_FUNC([set_nlink],
 919                                      [#include <linux/fs.h>],
 920                                      [set_nlink(NULL, 1);])
 921                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
 922                                      [#include <linux/splice.h>],
 923                                      [splice_direct_to_actor(NULL,NULL,NULL);])
 924                  AC_CHECK_LINUX_FUNC([svc_addr_in],
 925                                      [#include <linux/sunrpc/svc.h>],
 926                                      [svc_addr_in(NULL);])
 927                  AC_CHECK_LINUX_FUNC([zero_user_segments],
 928                                      [#include <linux/highmem.h>],
 929                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
 930                  AC_CHECK_LINUX_FUNC([noop_fsync],
 931                                      [#include <linux/fs.h>],
 932                                      [void *address = &noop_fsync; printk("%p\n", address)];)
 933                  AC_CHECK_LINUX_FUNC([kthread_run],
 934                                      [#include <linux/kernel.h>
 935                                       #include <linux/kthread.h>],
 936                                      [kthread_run(NULL, NULL, "test");])
 937
 938                  dnl Consequences - things which get set as a result of the
 939                  dnl                above tests
 940                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
 941                        [AC_DEFINE([AFS_NONFSTRANS], 1,
 942                                   [define to disable the nfs translator])])
 943
 944                  dnl Assorted more complex tests
 945                  LINUX_AIO_NONVECTOR
 946                  LINUX_EXPORTS_PROC_ROOT_FS
 947                  LINUX_KMEM_CACHE_INIT
 948                  LINUX_HAVE_KMEM_CACHE_T
 949                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
 950                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
 951                  LINUX_D_PATH_TAKES_STRUCT_PATH
 952                  LINUX_NEW_EXPORT_OPS
 953                  LINUX_INODE_SETATTR_RETURN_TYPE
 954                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
 955                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
 956                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
 957                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
 958                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
 959                  LINUX_DOP_D_DELETE_TAKES_CONST
 960                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
 961                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
 962                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
 963                  LINUX_FOP_F_FSYNC_TAKES_RANGE
 964                  LINUX_AOP_WRITEBACK_CONTROL
 965                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
 966                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
 967                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
 968                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
 969                  LINUX_KERNEL_SOCK_CREATE
 970                  LINUX_EXPORTS_KEY_TYPE_KEYRING
 971                  LINUX_NEED_RHCONFIG
 972                  LINUX_RECALC_SIGPENDING_ARG_TYPE
 973                  LINUX_EXPORTS_TASKLIST_LOCK
 974                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
 975                  LINUX_STATFS_TAKES_DENTRY
 976                  LINUX_REFRIGERATOR
 977                  LINUX_HAVE_TRY_TO_FREEZE
 978                  LINUX_LINUX_KEYRING_SUPPORT
 979                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
 980                  LINUX_KEY_ALLOC_NEEDS_CRED
 981                  LINUX_INIT_WORK_HAS_DATA
 982                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
 983                  LINUX_HAVE_DCACHE_LOCK
 984                  LINUX_D_COUNT_IS_INT
 985                  LINUX_IOP_MKDIR_TAKES_UMODE_T
 986                  LINUX_IOP_CREATE_TAKES_UMODE_T
 987                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
 988                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
 989                  LINUX_DENTRY_OPEN_TAKES_PATH
 990                  LINUX_D_ALIAS_IS_HLIST
 991                  LINUX_IOP_I_CREATE_TAKES_BOOL
 992                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
 993                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
 994
 995                  dnl If we are guaranteed that keyrings will work - that is
 996                  dnl  a) The kernel has keyrings enabled
 997                  dnl  b) The code is new enough to give us a key_type_keyring
 998                  dnl then we just disable syscall probing unless we've been
 999                  dnl told otherwise
1000
1001                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1002                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1003                           [enable_linux_syscall_probing="no"],
1004                           [enable_linux_syscall_probing="yes"])
1005                  ])
1006
1007                  dnl Syscall probing needs a few tests of its own, and just
1008                  dnl won't work if the kernel doesn't export init_mm
1009                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1010                    LINUX_EXPORTS_INIT_MM
1011                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1012                      AC_MSG_ERROR(
1013                        [Can't do syscall probing without exported init_mm])
1014                    ])
1015                    LINUX_EXPORTS_SYS_CHDIR
1016                    LINUX_EXPORTS_SYS_OPEN
1017                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1018                              [define to enable syscall table probes])
1019                  ])
1020
1021                  dnl Packaging and SMP build
1022                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1023                    LINUX_WHICH_MODULES
1024                  else
1025                    AC_SUBST(MPS,'SP')
1026                  fi
1027
1028                  dnl Syscall probing
1029                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1030                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1031                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1032                    ])
1033                    ac_cv_linux_exports_sys_call_table=no
1034                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1035                      ac_cv_linux_exports_ia32_sys_call_table=yes
1036                    fi
1037                  else
1038                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1039                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1040                    LINUX_EXPORTS_SYS_CALL_TABLE
1041                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1042                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1043                          linux_syscall_method=none
1044                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1045                             linux_syscall_method=scan
1046                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1047                                linux_syscall_method=scan_with_kallsyms_address
1048                             fi
1049                          fi
1050                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1051                             linux_syscall_method=kallsyms_symbol
1052                          fi
1053                          if test "x$linux_syscall_method" = "xnone"; then
1054                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1055                             linux_syscall_method=scan
1056                          fi
1057                    fi
1058                  fi
1059                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1060                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1061                  fi
1062                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1063                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1064                  fi
1065                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1066                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1067                  else
1068                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1069                  fi
1070                 :
1071                 fi
1072 dnl Linux-only, but just enable always.
1073                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1074 esac
1075
1076 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1077     [ac_cv_sync_fetch_and_add],
1078     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1079                     [ac_cv_sync_fetch_and_add=yes],
1080                     [ac_cv_sync_fetch_and_add=no])
1081 ])
1082 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1083       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1084                 [define if your C compiler has __sync_add_and_fetch])])
1085
1086 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1087     [ac_cv_sockaddr_len],
1088     [AC_TRY_COMPILE( [#include <sys/types.h>
1089 #include <sys/socket.h>],
1090                      [struct sockaddr *a; a->sa_len=0;],
1091                      [ac_cv_sockaddr_len=yes],
1092                      [ac_cv_sockaddr_len=no])
1093 ])
1094 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1095       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1096                  [define if you struct sockaddr sa_len])])
1097
1098 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1099         echo Skipping library tests because they confuse Irix.
1100 else
1101   AC_SEARCH_LIBS([socket], [socket inet])
1102   AC_SEARCH_LIBS([connect], [nsl])
1103   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1104
1105   dnl darwin wants it, aix hates it
1106   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1107   AC_TRY_COMPILE([
1108   #include <stdlib.h>
1109   #include <stdio.h>
1110   #include <sys/types.h>
1111   #include <sys/socket.h>
1112   #include <netinet/in.h>
1113   #include <arpa/inet.h>
1114   #include <arpa/nameser.h>
1115   #include <arpa/nameser_compat.h>
1116   #include <resolv.h>
1117   ], [static int i; i = 0;],
1118   [AC_MSG_RESULT(yes)
1119    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1120   [AC_MSG_RESULT(no)
1121    ])
1122
1123   openafs_save_libs="$LIBS"
1124   AC_MSG_CHECKING([for res_search])
1125   AC_FUNC_RES_SEARCH
1126
1127   if test "$ac_cv_func_res_search" = no; then
1128       for lib in dns nsl resolv; do
1129         if test "$ac_cv_func_res_search" != yes; then
1130           LIBS="-l$lib $LIBS"
1131           AC_FUNC_RES_SEARCH
1132           LIBS="$openafs_save_libs"
1133         fi
1134       done
1135       if test "$ac_cv_func_res_search" = yes; then
1136         LIB_AFSDB="-l$lib"
1137         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1138         AC_MSG_RESULT([yes, in lib$lib])
1139       else
1140         AC_MSG_RESULT(no)
1141       fi
1142   else
1143     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1144     AC_MSG_RESULT(yes)
1145   fi
1146
1147 fi
1148 XLIBS="$LIB_AFSDB $XLIBS"
1149
1150 AC_CHECK_RESOLV_RETRANS
1151
1152 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1153     [ac_cv_setsockopt_iprecverr],
1154     [AC_TRY_COMPILE( [
1155 #include <sys/types.h>
1156 #include <sys/socket.h>
1157 #include <netinet/in.h>],
1158 [int on=1;
1159 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1160         [ac_cv_setsockopt_iprecverr=yes],
1161         [ac_cv_setsockopt_iprecverr=no])])
1162
1163 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1164       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1165                  [define if we can receive socket errors via IP_RECVERR])])
1166
1167 PTHREAD_LIBS=error
1168 if test "x$MKAFS_OSTYPE" = OBSD; then
1169         PTHREAD_LIBS="-pthread"
1170 fi
1171 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1172         PTHREAD_LIBS="-pthread"
1173 fi
1174 if test "x$PTHREAD_LIBS" = xerror; then
1175         AC_CHECK_LIB(pthread, pthread_attr_init,
1176                 PTHREAD_LIBS="-lpthread")
1177 fi
1178 if test "x$PTHREAD_LIBS" = xerror; then
1179         AC_CHECK_LIB(pthreads, pthread_attr_init,
1180                 PTHREAD_LIBS="-lpthreads")
1181 fi
1182 if test "x$PTHREAD_LIBS" = xerror; then
1183         AC_CHECK_LIB(c_r, pthread_attr_init,
1184                 PTHREAD_LIBS="-lc_r")
1185 fi
1186 if test "x$PTHREAD_LIBS" = xerror; then
1187         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1188 fi
1189 if test "x$PTHREAD_LIBS" = xerror; then
1190         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1191         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1192                 PTHREAD_LIBS="-lpthread")
1193 fi
1194 if test "x$PTHREAD_LIBS" = xerror; then
1195         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1196 fi
1197 AC_SUBST(PTHREAD_LIBS)
1198
1199 HOST_CPU="$host_cpu"
1200
1201 if test "x$with_bsd_kernel_headers" != "x"; then
1202         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1203 else
1204         BSD_KERNEL_PATH="/usr/src/sys"
1205 fi
1206
1207 if test "x$with_bsd_kernel_build" != "x"; then
1208         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1209 else
1210         case $AFS_SYSNAME in
1211                 *_fbsd_*)
1212                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1213                         ;;
1214                 *_nbsd*)
1215                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1216         esac
1217 fi
1218
1219 # Fast restart
1220 if test "$enable_supergroups" = "yes"; then
1221         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1222 fi
1223
1224 if test "$enable_bitmap_later" = "yes"; then
1225         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1226 fi
1227
1228 if test "$enable_unix_sockets" = "yes"; then
1229         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1230         USE_UNIX_SOCKETS="yes"
1231 else
1232         USE_UNIX_SOCKETS="no"
1233 fi
1234 AC_SUBST(USE_UNIX_SOCKETS)
1235
1236 if test "$enable_namei_fileserver" = "yes"; then
1237         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1238         VFSCK=""
1239 else
1240         if test "$enable_namei_fileserver" = "default"; then
1241                 case $host in
1242                         *-solaris2.10*)
1243                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1244                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1245                                 VFSCK=""
1246                                 ;;
1247                         *-solaris2.11*)
1248                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1249                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1250                                 VFSCK=""
1251                                 ;;
1252                         *)
1253                                 VFSCK="vfsck"
1254                                 ;;
1255                 esac
1256         else
1257                 VFSCK="vfsck"
1258         fi
1259 fi
1260
1261 dnl check for tivoli
1262 AC_MSG_CHECKING(for tivoli tsm butc support)
1263 XBSA_CFLAGS=""
1264 if test "$enable_tivoli_tsm" = "yes"; then
1265         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1266         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1267         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1268         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1269
1270         if test -r "$XBSADIR3/dsmapifp.h"; then
1271                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1272                 XBSA_XLIBS="-ldl"
1273                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1274         elif test -r "$XBSADIR4/dsmapifp.h"; then
1275                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1276                 XBSA_XLIBS="-ldl"
1277                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1278         elif test -r "$XBSADIR1/xbsa.h"; then
1279                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1280                 XBSA_XLIBS=""
1281                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1282         elif test -r "$XBSADIR2/xbsa.h"; then
1283                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1284                 XBSA_XLIBS=""
1285                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1286         else
1287                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1288         fi
1289 else
1290         AC_MSG_RESULT([no])
1291 fi
1292 AC_SUBST(XBSA_CFLAGS)
1293 AC_SUBST(XBSA_XLIBS)
1294
1295 dnl checks for header files.
1296 AC_HEADER_STDC
1297 AC_HEADER_SYS_WAIT
1298 AC_HEADER_DIRENT
1299 AC_CHECK_HEADERS([ \
1300                    arpa/inet.h \
1301                    arpa/nameser.h \
1302                    curses.h\
1303                    direct.h \
1304                    et/com_err.h \
1305                    errno.h \
1306                    fcntl.h \
1307                    grp.h \
1308                    math.h \
1309                    mntent.h \
1310                    ncurses.h \
1311                    netdb.h \
1312                    netinet/in.h \
1313                    pthread_np.h \
1314                    pwd.h \
1315                    regex.h \
1316                    security/pam_appl.h \
1317                    signal.h \
1318                    stdint.h \
1319                    stdio_ext.h \
1320                    stdlib.h \
1321                    string.h \
1322                    strings.h \
1323                    sys/bitypes.h \
1324                    sys/bswap.h \
1325                    sys/dk.h \
1326                    sys/fcntl.h \
1327                    sys/file.h \
1328                    sys/fs_types.h \
1329                    sys/fstyp.h \
1330                    sys/ioctl.h \
1331                    sys/ipc.h \
1332                    sys/lockf.h \
1333                    sys/map.h \
1334                    sys/mount.h \
1335                    sys/mntent.h \
1336                    sys/mnttab.h \
1337                    sys/pag.h \
1338                    sys/param.h \
1339                    sys/resource.h \
1340                    sys/select.h \
1341                    sys/statfs.h \
1342                    sys/statvfs.h \
1343                    sys/socket.h \
1344                    sys/sysctl.h \
1345                    sys/time.h \
1346                    sys/types.h \
1347                    sys/uio.h \
1348                    sys/un.h \
1349                    sys/vfs.h \
1350                    syslog.h \
1351                    termios.h \
1352                    time.h \
1353                    ucontext.h \
1354                    unistd.h \
1355                    windows.h \
1356                 ])
1357
1358 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1359 #ifdef HAVE_NETINET_IN_H
1360 # include <netinet/in.h>
1361 #endif])
1362
1363 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1364 #ifdef HAVE_SYS_SOCKET_H
1365 # include <sys/socket.h>
1366 #endif])
1367
1368 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1369 #ifdef HAVE_SYS_SOCKET_H
1370 # include <sys/socket.h>
1371 #endif
1372 #ifdef HAVE_NETINET_IN_H
1373 # include <netinet/in.h>
1374 #endif
1375 #ifdef HAVE_NET_IF_H
1376 # include <net/if.h>
1377 #endif])
1378
1379 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1380 #ifdef HAVE_SECURITY_PAM_APPL_H
1381 # include <security/pam_appl.h>
1382 #endif])
1383
1384 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1385
1386 AC_CHECK_TYPES([fsblkcnt_t],,,[
1387 #include <sys/types.h>
1388 #ifdef HAVE_SYS_BITYPES_H
1389 #include <sys/bitypes.h>
1390 #endif
1391 #ifdef HAVE_SYS_STATFS_H
1392 #include <sys/statfs.h>
1393 #endif
1394 #ifdef HAVE_SYS_STATVFS_H
1395 #include <sys/statvfs.h>
1396 #endif
1397 ])
1398
1399 dnl see what struct stat has for timestamps
1400 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1401
1402 dnl check for curses-lib
1403 AS_IF([test "x$enable_gtx" != "xno"],
1404       [save_LIBS=$LIBS
1405       AC_CHECK_LIB( [ncurses], [setupterm],
1406       [LIB_curses=-lncurses],
1407         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1408           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1409       ])
1410       LIBS=$save_LIBS
1411       AC_SUBST(LIB_curses)])
1412
1413 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1414
1415 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1416 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1417         case $AFS_SYSNAME in
1418         sgi_*)
1419                 HAVE_PAM="no"
1420                 ;;
1421         *)
1422                 HAVE_PAM="yes"
1423                 ;;
1424         esac
1425 else
1426         HAVE_PAM="no"
1427 fi
1428 AC_SUBST(HAVE_PAM)
1429
1430 if test "$enable_login" = yes; then
1431         BUILD_LOGIN="yes"
1432 else
1433         BUILD_LOGIN="no"
1434 fi
1435 AC_SUBST(BUILD_LOGIN)
1436
1437 if test "$enable_uss" = yes; then
1438         BUILD_USS="yes"
1439 else
1440         BUILD_USS="no"
1441 fi
1442 AC_SUBST(BUILD_USS)
1443
1444 AC_CHECK_FUNCS([ \
1445         arc4random \
1446         fcntl \
1447         fseeko64 \
1448         ftello64 \
1449         getcwd \
1450         getegid \
1451         geteuid \
1452         getgid \
1453         getuid \
1454         getrlimit \
1455         issetugid \
1456         mkstemp \
1457         pread \
1458         preadv \
1459         preadv64 \
1460         pwrite \
1461         pwritev \
1462         pwritev64 \
1463         regcomp \
1464         regerror \
1465         regexec \
1466         setitimer \
1467         setvbuf \
1468         sigaction \
1469         strcasestr \
1470         strerror \
1471         sysconf \
1472         sysctl \
1473         tdestroy \
1474         timegm \
1475 ])
1476
1477 OPENAFS_ROKEN()
1478 OPENAFS_C_ATTRIBUTE()
1479
1480 dnl Functions that Heimdal's libroken provides, but that we
1481 dnl haven't found a need for yet, and so haven't imported
1482 AC_CHECK_FUNCS([ \
1483         chown \
1484         fchown \
1485         gethostname \
1486         lstat \
1487         inet_aton \
1488         inet_ntop \
1489         inet_pton \
1490         putenv \
1491         readv \
1492         setenv \
1493         strdup \
1494         strftime \
1495         strndup \
1496         strsep \
1497         unsetenv \
1498 ])
1499
1500 dnl Functions that are in objects that we always build from libroken
1501 AC_CHECK_FUNCS([ \
1502         asprintf \
1503         asnprintf \
1504         vasprintf \
1505         vasnprintf \
1506         vsnprintf \
1507         snprintf \
1508 ])
1509
1510 dnl Functions that we're going to try and get from libroken
1511 AC_REPLACE_FUNCS([ \
1512         daemon \
1513         ecalloc \
1514         emalloc \
1515         erealloc \
1516         err \
1517         errx \
1518         flock \
1519         getdtablesize \
1520         getopt \
1521         getprogname \
1522         gettimeofday \
1523         localtime_r \
1524         mkstemp \
1525         setenv \
1526         setprogname \
1527         strcasecmp \
1528         strlcat \
1529         strnlen \
1530         strlcpy \
1531         strsep \
1532         tdelete \
1533         tfind \
1534         tsearch \
1535         twalk \
1536         unsetenv \
1537         verr \
1538         verrx \
1539         vsyslog \
1540         vwarn \
1541         vwarnx \
1542         warn \
1543         warnx \
1544 ])
1545
1546 dnl Headers that we're going to try and get from libroken
1547 AC_CHECK_HEADERS([ \
1548         err.h \
1549         search.h \
1550 ])
1551
1552 AC_CHECK_DECLS([h_errno], [], [], [
1553 #include <sys/types.h>
1554 #ifdef HAVE_NETDB_H
1555 #include <netdb.h>
1556 #endif
1557 ])
1558
1559 AC_HEADER_TIME
1560
1561 ROKEN_HEADERS=
1562 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1563       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1564       [])
1565 AC_SUBST(ROKEN_HEADERS)
1566
1567 dnl Stuff that's harder ...
1568 AC_MSG_CHECKING([for bswap16])
1569 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1570 #ifdef HAVE_SYS_TYPES_H
1571 #include <sys/types.h>
1572 #endif
1573 #ifdef HAVE_SYS_BSWAP_H
1574 #include <sys/bswap.h>
1575 #endif
1576 ],
1577 [short a, b; b = bswap16(a); ])],
1578 [AC_MSG_RESULT(yes)
1579  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1580 ],
1581 [AC_MSG_RESULT(no)])
1582
1583 AC_MSG_CHECKING([for bswap32])
1584 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1585 #include <sys/types.h>
1586 #endif
1587 #ifdef HAVE_SYS_BSWAP_H
1588 #include <sys/bswap.h>
1589 #endif
1590 ],
1591 [int a, b; b = bswap32(a); ])],
1592 [AC_MSG_RESULT(yes)
1593  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1594 ],
1595 [AC_MSG_RESULT(no)])
1596
1597 case $AFS_SYSNAME in
1598 *hp_ux* | *hpux*)
1599    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1600    ;;
1601 *)
1602    AC_MSG_CHECKING([for positional I/O])
1603    if test "$ac_cv_func_pread" = "yes" && \
1604            test "$ac_cv_func_pwrite" = "yes"; then
1605       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1606       AC_MSG_RESULT(yes)
1607    else
1608      AC_MSG_RESULT(no)
1609    fi
1610    AC_MSG_CHECKING([for vectored positional I/O])
1611    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1612                "$ac_cv_func_pwritev" = "yes" -a \
1613                "$ac_cv_func_preadv64" = "yes" -a \
1614                "$ac_cv_func_pwritev64" = "yes"],
1615          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1616           AC_MSG_RESULT(yes)],
1617          [AC_MSG_RESULT(no)])
1618    ;;
1619 esac
1620
1621 AC_MSG_CHECKING([for POSIX regex library])
1622 if test "$ac_cv_header_regex_h" = "yes" && \
1623         test "$ac_cv_func_regcomp" = "yes" && \
1624         test "$ac_cv_func_regexec" = "yes" && \
1625         test "$ac_cv_func_regerror" = "yes"; then
1626     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1627     AC_MSG_RESULT(yes)
1628 else
1629     AC_MSG_RESULT(no)
1630 fi
1631
1632 dnl Look for "non-portable" pthreads functions.
1633 save_LIBS="$LIBS"
1634 LIBS="$LIBS $PTHREAD_LIBS"
1635 AC_CHECK_FUNCS([ \
1636         pthread_set_name_np \
1637         pthread_setname_np \
1638 ])
1639
1640 dnl Sadly, there are three different versions of pthread_setname_np.
1641 dnl Try to cater for all of them.
1642 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1643     AC_MSG_CHECKING([for signature of pthread_setname_np])
1644     AC_TRY_COMPILE([
1645 #include <pthread.h>
1646 #ifdef HAVE_PTHREAD_NP_H
1647 #include <pthread_np.h>
1648 #endif
1649 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1650         AC_MSG_RESULT([three arguments])
1651         pthread_setname_np_args=3], [
1652         AC_TRY_COMPILE([
1653 #include <pthread.h>
1654 #ifdef HAVE_PTHREAD_NP_H
1655 #include <pthread_np.h>
1656 #endif
1657 ], [pthread_setname_np(pthread_self(), "test")], [
1658             AC_MSG_RESULT([two arguments])
1659             pthread_setname_np_args=2], [
1660             AC_TRY_COMPILE([
1661 #include <pthread.h>
1662 #ifdef HAVE_PTHREAD_NP_H
1663 #include <pthread_np.h>
1664 #endif
1665 ], [pthread_setname_np("test")], [
1666                 AC_MSG_RESULT([one argument])
1667                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1668 ])
1669 ])
1670 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1671 fi
1672 LIBS="$save_LIBS"
1673
1674 openafs_cv_saved_CFLAGS="$CFLAGS"
1675 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1676
1677 AC_TYPE_SIGNAL
1678 OPENAFS_RETSIGTYPE
1679 AC_CHECK_SIZEOF(void *)
1680 AC_CHECK_SIZEOF(unsigned long long)
1681 AC_CHECK_SIZEOF(unsigned long)
1682 AC_CHECK_SIZEOF(unsigned int)
1683 AC_TYPE_INTPTR_T
1684 AC_TYPE_UINTPTR_T
1685 AC_TYPE_SSIZE_T
1686 AC_CHECK_TYPE([sig_atomic_t],[],
1687     [AC_DEFINE([sig_atomic_t], [int],
1688         [Define to int if <signal.h> does not define.])],
1689 [#include <sys/types.h>
1690 #include <signal.h>])
1691 AC_CHECK_TYPE([socklen_t],[],
1692     [AC_DEFINE([socklen_t], [int],
1693         [Define to int if <sys/socket.h> does not define.])],
1694 [#include <sys/types.h>
1695 #include <sys/socket.h>])
1696 AC_CHECK_TYPES(off64_t)
1697 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1698 AC_CHECK_TYPES([struct winsize], [], [], [
1699 #ifdef HAVE_TERMIOS_H
1700 # include <termios.h>
1701 #else
1702 # include <sys/termios.h>
1703 #endif
1704 #include <sys/ioctl.h>])
1705 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1706                 struct sockaddr_storage],
1707                [], [], [
1708 #include <sys/types.h>
1709 #include <sys/socket.h>
1710 ])
1711 AC_CHECK_TYPES([sa_family_t], [], [], [
1712 #include <sys/types.h>
1713 #include <sys/socket.h>
1714 ])
1715 AC_CHECK_TYPES([struct addrinfo], [], [], [
1716 #include <sys/types.h>
1717 #ifdef HAVE_NETDB_H
1718 #include <netdb.h>
1719 #endif
1720 ])
1721 AC_CHECK_TYPES([long long], [], [], [])
1722
1723 AC_SIZEOF_TYPE(long)
1724
1725 CFLAGS="$openafs_cv_saved_CFLAGS"
1726
1727 RRA_HEADER_PAM_CONST
1728
1729
1730 dnl Directory PATH handling
1731 if test "x$enable_transarc_paths" = "xyes"  ; then
1732     afsconfdir=${afsconfdir=/usr/afs/etc}
1733     viceetcdir=${viceetcdir=/usr/vice/etc}
1734     afskerneldir=${afskerneldir=${viceetcdir}}
1735     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1736     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1737     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1738     afsdbdir=${afsdbdir=/usr/afs/db}
1739     afslogsdir=${afslogsdir=/usr/afs/logs}
1740     afslocaldir=${afslocaldir=/usr/afs/local}
1741     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1742     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1743     afsdatadir=${afsdatadir=/usr/vice/etc}
1744 else
1745     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1746     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1747     afskerneldir=${afskerneldir='${libdir}/openafs'}
1748     afssrvbindir=${afssrvbindir='${bindir}'}
1749     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1750     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1751     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1752     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1753     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1754     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1755     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1756     afsdatadir=${afsdatadir='${datadir}/openafs'}
1757 fi
1758 AC_SUBST(afsconfdir)
1759 AC_SUBST(viceetcdir)
1760 AC_SUBST(afskerneldir)
1761 AC_SUBST(afssrvbindir)
1762 AC_SUBST(afssrvsbindir)
1763 AC_SUBST(afssrvlibexecdir)
1764 AC_SUBST(afsdbdir)
1765 AC_SUBST(afslogsdir)
1766 AC_SUBST(afslocaldir)
1767 AC_SUBST(afsbackupdir)
1768 AC_SUBST(afsbosconfigdir)
1769 AC_SUBST(afsdatadir)
1770
1771 if test "x$enable_kernel_module" = "xyes"; then
1772 ENABLE_KERNEL_MODULE=libafs
1773 fi
1774
1775 if test "x$enable_pthreaded_ubik" = "xyes"; then
1776 ENABLE_PTHREADED_UBIK=yes
1777 fi
1778
1779 AC_SUBST(VFSCK)
1780 AC_SUBST(AFS_SYSNAME)
1781 AC_SUBST(AFS_PARAM_COMMON)
1782 AC_SUBST(ENABLE_KERNEL_MODULE)
1783 AC_SUBST(ENABLE_PTHREADED_UBIK)
1784 AC_SUBST(LIB_AFSDB)
1785 AC_SUBST(LINUX_KERNEL_PATH)
1786 AC_SUBST(LINUX_KERNEL_BUILD)
1787 AC_SUBST(HOST_CPU)
1788 AC_SUBST(BSD_KERNEL_PATH)
1789 AC_SUBST(BSD_KERNEL_BUILD)
1790 AC_SUBST(LINUX_VERSION)
1791 AC_SUBST(MKAFS_OSTYPE)
1792 AC_SUBST(TOP_OBJDIR)
1793 AC_SUBST(TOP_SRCDIR)
1794 AC_SUBST(TOP_INCDIR)
1795 AC_SUBST(TOP_LIBDIR)
1796 AC_SUBST(DEST)
1797 AC_SUBST(DARWIN_INFOFILE)
1798 AC_SUBST(IRIX_BUILD_IP35)
1799 AC_SUBST(HTML_XSL)
1800 AC_SUBST(XSLTPROC)
1801 AC_SUBST(DOCBOOK2PDF)
1802 AC_SUBST(DOCBOOK_STYLESHEETS)
1803
1804 OPENAFS_FUSE
1805 OPENAFS_SWIG
1806
1807 TOP_SRCDIR="${srcdir}/src"
1808 dnl
1809 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1810 dnl
1811 case $TOP_SRCDIR in
1812         /*)
1813                 ;;
1814         *)
1815                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1816                 ;;
1817 esac
1818
1819 TOP_OBJDIR="${SRCDIR_PARENT}"
1820 TOP_INCDIR="${SRCDIR_PARENT}/include"
1821 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1822 if test "${DEST}x" = "x"; then
1823         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1824 fi
1825
1826 if test "x$with_crosstools_dir" != "x"; then
1827         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1828                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1829                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1830                 RXGEN_PATH=$with_crosstools_dir/rxgen
1831         else
1832                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1833                 exit 1
1834         fi
1835 else
1836         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1837         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1838         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1839 fi
1840 AC_SUBST(COMPILE_ET_PATH)
1841 AC_SUBST(CONFIGTOOL_PATH)
1842 AC_SUBST(RXGEN_PATH)
1843
1844 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1845 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1846 AC_SUBST(HELPER_SPLINT)
1847 AC_SUBST(HELPER_SPLINTCFG)
1848
1849 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1850
1851 dnl Check to see if crypt lives in a different library
1852 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1853 AC_SUBST(LIB_crypt)
1854
1855 dnl Check to see if the compiler support labels in structs
1856 AC_MSG_CHECKING(for label support in structs)
1857 AC_TRY_COMPILE([], [
1858 extern void osi_UFSOpen(void);
1859 struct labeltest {
1860    void (*open) (void);
1861 };
1862 struct labeltest struct_labeltest = {
1863    .open       = osi_UFSOpen,
1864 }
1865 ],
1866 [AC_MSG_RESULT(yes)
1867  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1868 ],
1869 [AC_MSG_RESULT(no)
1870 ])
1871
1872 AC_MSG_CHECKING([checking for dirfd])
1873 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1874 #ifdef HAVE_DIRENT_H
1875 #include <dirent.h>
1876 #endif
1877 ]],
1878         [[DIR *d = 0; dirfd(d);]])],
1879         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1880 if test "$ac_rk_have_dirfd" = "yes" ; then
1881         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1882 fi
1883 AC_MSG_RESULT($ac_rk_have_dirfd)
1884
1885 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1886 #ifdef HAVE_DIRENT_H
1887 #include <dirent.h>
1888 #endif])
1889
1890 dnl Eventually, this will look for the system one, or for OpenSSL
1891 LIB_hcrypto="-lafshcrypto"
1892 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1893 AC_SUBST(LIB_hcrypto)
1894 AC_SUBST(LDFLAGS_hcrypto)
1895
1896 dnl Check for UUID library
1897 AC_CHECK_HEADERS([uuid/uuid.h])
1898 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1899 AC_CHECK_FUNCS([uuid_generate])
1900 ])
1901
1902
1903 AC_DEFUN([SUMMARY], [
1904     # Print a configuration summary
1905 echo
1906 echo "**************************************"
1907 echo configure summary
1908 echo
1909 AS_IF([test $LIB_curses],[
1910 echo "LIB_curses :                $LIB_curses" ],[
1911 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1912 ])
1913 echo
1914 echo "**************************************"
1915 ])