acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN(OPENAFS_CONFIGURE_COMMON,[
   8
   9 AC_CANONICAL_HOST
  10 SRCDIR_PARENT=`pwd`
  11
  12 #BOZO_SAVE_CORES BOS_RESTRICTED_MODE BOS_NEW_CONFIG pam sia
  13 AC_ARG_WITH(afs-sysname,
  14 [  --with-afs-sysname=sys    use sys for the afs sysname]
  15 )
  16 AC_ARG_ENABLE( obsolete,
  17 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
  18 AC_ARG_ENABLE( insecure,
  19 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
  20 AC_ARG_ENABLE( afsdb,
  21 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
  22 AC_ARG_ENABLE( bos-restricted-mode,
  23 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
  24 AC_ARG_ENABLE( namei-fileserver,
  25 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
  26 AC_ARG_ENABLE( fast-restart,
  27 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
  28 AC_ARG_ENABLE( bitmap-later,
  29 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
  30 AC_ARG_ENABLE( full-vos-listvol-switch,
  31 [  --enable-full-vos-listvol-switch     enable vos full listvol switch for formatted output],, enable_full_vos_listvol_switch="no")
  32 AC_ARG_WITH(dux-kernel-headers,
  33 [  --with-dux-kernel-headers=path       use the kernel headers found at path(optional, defaults to first match in /usr/sys)]
  34 )
  35 AC_ARG_WITH(linux-kernel-headers,
  36 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux)]
  37 )
  38 AC_ARG_ENABLE(kernel-module,
  39 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
  40 )
  41 AC_ARG_ENABLE(redhat-buildsys,
  42 [  --enable-redhat-buildsys             enable compilation of the redhat build system kernel (defaults to disabled)],, enable_redhat_buildsys="no"
  43 )
  44 AC_ARG_ENABLE(transarc-paths,
  45 [  --enable-transarc-paths                      Use Transarc style paths like /usr/afs and /usr/vice],, enable_transarc_paths="no"
  46 )
  47 AC_ARG_ENABLE(tivoli-tsm,
  48 [  --enable-tivoli-tsm                  Enable use of the Tivoli TSM API libraries for butc support],, enable_tivoli_tsm="no"
  49 )
  50 AC_ARG_ENABLE(debug-kernel,
  51 [  --enable-debug-kernel                enable compilation of the kernel module with debugging information (defaults to disabled)],, enable_debug_kernel="no"
  52 )
  53
  54 dnl weird ass systems
  55 AC_AIX
  56 AC_ISC_POSIX
  57 AC_MINIX
  58
  59 dnl Various compiler setup.
  60 AC_TYPE_PID_T
  61 AC_TYPE_SIZE_T
  62 AC_TYPE_SIGNAL
  63
  64 dnl Checks for programs.
  65 AC_PROG_INSTALL
  66 AC_PROG_LN_S
  67 AC_PROG_RANLIB
  68 AC_PROG_YACC
  69 AM_PROG_LEX
  70
  71 OPENAFS_CHECK_BIGENDIAN
  72
  73 KERN_DEBUG_OPT=
  74 if test "x$enable_debug_kernel" = "xyes"; then
  75   KERN_DEBUG_OPT=-g
  76 fi
  77
  78 AC_MSG_CHECKING(your OS)
  79 system=$host
  80 case $system in
  81         *-linux*)
  82                 MKAFS_OSTYPE=LINUX
  83                 if test "x$enable_redhat_buildsys" = "xyes"; then
  84                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS)
  85                 fi
  86                 if test "x$enable_kernel_module" = "xyes"; then
  87                  if test "x$with_linux_kernel_headers" != "x"; then
  88                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
  89                  else
  90                    LINUX_KERNEL_PATH="/usr/src/linux"
  91                  fi
  92                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
  93                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
  94                   if test "x$linux_kvers" = "x"; then
  95                     if test -f "$LINUX_KERNEL_PATH/include/linux/version-up.h"; then
  96                       linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
  97                       if test "x$linux_kvers" = "x"; then
  98
  99                         AC_MSG_ERROR(Linux headers lack version definition [2])
 100                         exit 1
 101                       else
 102                         LINUX_VERSION="$linux_kvers"
 103                       fi
 104                     else
 105                       AC_MSG_ERROR(Linux headers lack version definition)
 106                       exit 1
 107                     fi
 108                   else
 109                     LINUX_VERSION="$linux_kvers"
 110                   fi
 111                  else
 112                     enable_kernel_module="no"
 113                  fi
 114                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
 115                      enable_kernel_module="no"
 116                  fi
 117                  if test "x$enable_kernel_module" = "xno"; then
 118                   if test "x$with_linux_kernel_headers" != "x"; then
 119                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 120                    exit 1
 121                   else
 122                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 123                   fi
 124                  fi
 125                 fi
 126                 AC_MSG_RESULT(linux)
 127                 if test "x$enable_kernel_module" = "xyes"; then
 128                  OMIT_FRAME_POINTER=
 129                  if test "x$enable_debug_kernel" = "xno"; then
 130                         OMIT_FRAME_POINTER=-fomit-frame-pointer
 131                  fi
 132                  AC_SUBST(OMIT_FRAME_POINTER)
 133                  ifdef([OPENAFS_CONFIGURE_LIBAFS],
 134                    [LINUX_BUILD_VNODE_FROM_INODE(src/config,afs)],
 135                    [LINUX_BUILD_VNODE_FROM_INODE(${srcdir}/src/config,src/afs/LINUX,${srcdir}/src/afs/LINUX)]
 136                  )
 137                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK
 138                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_GFP_MASK
 139                  LINUX_FS_STRUCT_INODE_HAS_I_TRUNCATE_SEM
 140                  LINUX_FS_STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS
 141                  LINUX_FS_STRUCT_INODE_HAS_I_DEVICES
 142                  LINUX_INODE_SETATTR_RETURN_TYPE
 143                  LINUX_NEED_RHCONFIG
 144                  LINUX_WHICH_MODULES
 145                  if test "x$ac_cv_linux_func_inode_setattr_returns_int" = "xyes" ; then
 146                   AC_DEFINE(INODE_SETATTR_NOT_VOID)
 147                  fi
 148                  if test "x$ac_cv_linux_fs_struct_address_space_has_page_lock" = "xyes"; then
 149                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK)
 150                  fi
 151                  if test "x$ac_cv_linux_fs_struct_address_space_has_gfp_mask" = "xyes"; then
 152                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_GFP_MASK)
 153                  fi
 154                  if test "x$ac_cv_linux_fs_struct_inode_has_i_truncate_sem" = "xyes"; then
 155                   AC_DEFINE(STRUCT_INODE_HAS_I_TRUNCATE_SEM)
 156                  fi
 157                  if test "x$ac_cv_linux_fs_struct_inode_has_i_devices" = "xyes"; then
 158                   AC_DEFINE(STRUCT_INODE_HAS_I_DEVICES)
 159                  fi
 160                  if test "x$ac_cv_linux_fs_struct_inode_has_i_dirty_data_buffers" = "xyes"; then
 161                   AC_DEFINE(STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS)
 162                  fi
 163                 :
 164                 fi
 165                 ;;
 166         *-solaris*)
 167                 MKAFS_OSTYPE=SOLARIS
 168                 AC_MSG_RESULT(sun4)
 169                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 170                 SOLARIS_PROC_HAS_P_COREFILE
 171                 ;;
 172         *-hpux*)
 173                 MKAFS_OSTYPE=HPUX
 174                 AC_MSG_RESULT(hp_ux)
 175                 ;;
 176         *-irix*)
 177                 if test -d /usr/include/sys/SN/SN1; then
 178                  IRIX_BUILD_IP35="IP35"
 179                 fi
 180                 MKAFS_OSTYPE=IRIX
 181                 AC_MSG_RESULT(sgi)
 182                 ;;
 183         *-aix*)
 184                 MKAFS_OSTYPE=AIX
 185                 AC_MSG_RESULT(rs_aix)
 186                 ;;
 187         *-osf*)
 188                 MKAFS_OSTYPE=DUX
 189                 AC_MSG_RESULT(alpha_dux)
 190                 if test "x$enable_kernel_module" = "xyes"; then
 191                  if test "x$with_dux_kernel_headers" != "x"; then
 192                    HEADER_RT=`ls ${with_dux_kernel_headers}/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 193                  else
 194                    HEADER_RT=`ls /usr/sys/*/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 195                  fi
 196                 fi
 197                 if test "$HEADER_RT" = "*" ; then
 198                         AC_MSG_ERROR([Need a configured kernel directory])
 199                 fi
 200                 AC_SUBST([HEADER_RT])
 201                 ;;
 202         *-darwin*)
 203                 MKAFS_OSTYPE=DARWIN
 204                 AC_MSG_RESULT(ppc_darwin)
 205                 ;;
 206         *-freebsd*)
 207                 MKAFS_OSTYPE=FBSD
 208                 AC_MSG_RESULT(i386_fbsd)
 209                 ;;
 210         *-netbsd*)
 211                 MKAFS_OSTYPE=NBSD
 212                 AC_MSG_RESULT(nbsd)
 213                 ;;
 214         *-openbsd*)
 215                 MKAFS_OSTYPE=OBSD
 216                 AC_MSG_RESULT(i386_obsd)
 217                 ;;
 218         *)
 219                 AC_MSG_RESULT($system)
 220                 ;;
 221 esac
 222 AC_SUBST(KERN_DEBUG_OPT)
 223
 224 if test "x$with_afs_sysname" != "x"; then
 225         AFS_SYSNAME="$with_afs_sysname"
 226 else
 227         AC_MSG_CHECKING(your AFS sysname)
 228         case $host in
 229                 i?86-*-freebsd4.2*)
 230                         AFS_SYSNAME="i386_fbsd_42"
 231                         ;;
 232                 i?86-*-freebsd4.3*)
 233                         AFS_SYSNAME="i386_fbsd_43"
 234                         ;;
 235                 i?86-*-freebsd4.4*)
 236                         AFS_SYSNAME="i386_fbsd_44"
 237                         ;;
 238                 i?86-*-freebsd4.5*)
 239                         AFS_SYSNAME="i386_fbsd_45"
 240                         ;;
 241                 i?86-*-freebsd4.6*)
 242                         AFS_SYSNAME="i386_fbsd_46"
 243                         ;;
 244                 i?86-*-netbsd*1.5*)
 245                         AFS_PARAM_COMMON=param.nbsd15.h
 246                         AFS_SYSNAME="i386_nbsd15"
 247                         ;;
 248                 alpha-*-netbsd*1.5*)
 249                         AFS_PARAM_COMMON=param.nbsd15.h
 250                         AFS_SYSNAME="alpha_nbsd15"
 251                         ;;
 252                 i?86-*-netbsd*1.6*)
 253                         AFS_PARAM_COMMON=param.nbsd16.h
 254                         AFS_SYSNAME="i386_nbsd16"
 255                         ;;
 256                 alpha-*-netbsd*1.6*)
 257                         AFS_PARAM_COMMON=param.nbsd16.h
 258                         AFS_SYSNAME="alpha_nbsd16"
 259                         ;;
 260                 hppa*-hp-hpux11*)
 261                         AFS_SYSNAME="hp_ux110"
 262                         ;;
 263                 hppa*-hp-hpux10*)
 264                         AFS_SYSNAME="hp_ux102"
 265                         ;;
 266                 powerpc-apple-darwin1.2*)
 267                         AFS_SYSNAME="ppc_darwin_12"
 268                         ;;
 269                 powerpc-apple-darwin1.3*)
 270                         AFS_SYSNAME="ppc_darwin_13"
 271                         ;;
 272                 powerpc-apple-darwin1.4*)
 273                         AFS_SYSNAME="ppc_darwin_14"
 274                         ;;
 275                 powerpc-apple-darwin5.1*)
 276                         AFS_SYSNAME="ppc_darwin_14"
 277                         ;;
 278                 powerpc-apple-darwin5.2*)
 279                         AFS_SYSNAME="ppc_darwin_14"
 280                         ;;
 281                 powerpc-apple-darwin5.3*)
 282                         AFS_SYSNAME="ppc_darwin_14"
 283                         ;;
 284                 powerpc-apple-darwin5.4*)
 285                         AFS_SYSNAME="ppc_darwin_14"
 286                         ;;
 287                 powerpc-apple-darwin5.5*)
 288                         AFS_SYSNAME="ppc_darwin_14"
 289                         ;;
 290                 sparc-sun-solaris2.5*)
 291                         AFS_SYSNAME="sun4x_55"
 292                         ;;
 293                 sparc-sun-solaris2.6)
 294                         AFS_SYSNAME="sun4x_56"
 295                         ;;
 296                 sparc-sun-solaris2.7)
 297                         AFS_SYSNAME="sun4x_57"
 298                         ;;
 299                 sparc-sun-solaris2.8)
 300                         AFS_SYSNAME="sun4x_58"
 301                         ;;
 302                 sparc-sun-solaris2.9)
 303                         AFS_SYSNAME="sun4x_59"
 304                         ;;
 305                 i386-pc-solaris2.7)
 306                         AFS_SYSNAME="sunx86_57"
 307                         ;;
 308                 i386-pc-solaris2.8)
 309                         AFS_SYSNAME="sunx86_58"
 310                         ;;
 311                 i386-pc-solaris2.9)
 312                         AFS_SYSNAME="sunx86_59"
 313                         ;;
 314                 alpha*-dec-osf4.0*)
 315                         AFS_SYSNAME="alpha_dux40"
 316                         ;;
 317                 alpha*-dec-osf5.0*)
 318                         AFS_SYSNAME="alpha_dux50"
 319                         ;;
 320                 mips-sgi-irix6.5)
 321                         AFS_SYSNAME="sgi_65"
 322                         ;;
 323                 ia64-*-linux*)
 324                         AFS_SYSNAME="ia64_linuxXX"
 325                         ;;
 326                 powerpc-*-linux*)
 327                         AFS_SYSNAME="ppc_linuxXX"
 328                         ;;
 329                 alpha*-linux*)
 330                         AFS_SYSNAME="alpha_linux_XX"
 331                         ;;
 332                 s390-*-linux*)
 333                         AFS_SYSNAME="s390_linuxXX"
 334                         ;;
 335                 sparc-*-linux*)
 336                         AFS_SYSNAME="sparc_linuxXX"
 337                         ;;
 338                 sparc64-*-linux*)
 339                         AFS_SYSNAME="sparc64_linuxXX"
 340                         ;;
 341                 i?86-*-linux*)
 342                         AFS_SYSNAME="i386_linuxXX"
 343                         ;;
 344                 parisc-*-linux-gnu)
 345                         AFS_SYSNAME="parisc_linuxXX"
 346                         ;;
 347                 power*-ibm-aix4.2*)
 348                         AFS_SYSNAME="rs_aix42"
 349                         ;;
 350                 power*-ibm-aix4.3*)
 351                         AFS_SYSNAME="rs_aix42"
 352                         ;;
 353                 *)
 354                         AC_MSG_ERROR(An AFS sysname is required)
 355                         exit 1
 356                         ;;
 357         esac
 358         case $AFS_SYSNAME in
 359                 *_linux*)
 360                         AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $[]1 $[]2}'`
 361                         if test "x${AFS_SYSKVERS}" = "x"; then
 362                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 363                         fi
 364                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 365                         AFS_SYSNAME="$_AFS_SYSNAME"
 366                         ;;
 367         esac
 368         AC_MSG_RESULT($AFS_SYSNAME)
 369 fi
 370
 371 case $AFS_SYSNAME in
 372         *_darwin*)
 373                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 374                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 375                 ;;
 376 esac
 377 AC_CACHE_VAL(ac_cv_sockaddr_len,
 378 [
 379 AC_MSG_CHECKING([if struct sockaddr has sa_len field])
 380 AC_TRY_COMPILE( [#include <sys/types.h>
 381 #include <sys/socket.h>],
 382 [struct sockaddr *a;
 383 a->sa_len=0;], ac_cv_sockaddr_len=yes, ac_cv_sockaddr_len=no)
 384 AC_MSG_RESULT($ac_cv_sockaddr_len)])
 385 if test "$ac_cv_sockaddr_len" = "yes"; then
 386    AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN)
 387 fi
 388 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
 389         echo Skipping library tests because they confuse Irix.
 390 else
 391   AC_CHECK_FUNCS(socket)
 392
 393   if test "$ac_cv_func_socket" = no; then
 394     for lib in socket inet; do
 395         if test "$HAVE_SOCKET" != 1; then
 396                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET))
 397         fi
 398     done
 399   fi
 400
 401   AC_CHECK_FUNCS(connect)
 402
 403   if test "$ac_cv_func_connect" = no; then
 404     for lib in nsl; do
 405         if test "$HAVE_CONNECT" != 1; then
 406                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT))
 407         fi
 408     done
 409   fi
 410
 411   AC_CHECK_FUNCS(gethostbyname)
 412   if test "$ac_cv_func_gethostbyname" = no; then
 413         for lib in dns nsl resolv; do
 414           if test "$HAVE_GETHOSTBYNAME" != 1; then
 415             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME))
 416           fi
 417         done
 418   fi
 419
 420   AC_CHECK_FUNCS(res_search)
 421   if test "$ac_cv_func_res_search" = no; then
 422         for lib in dns nsl resolv; do
 423           if test "$HAVE_RES_SEARCH" != 1; then
 424             AC_CHECK_LIB(${lib}, res_search, LIBS="$LIBS -l$lib";HAVE_RES_SEARCH=1;AC_DEFINE(HAVE_RES_SEARCH))
 425           fi
 426         done
 427         if test "$HAVE_RES_SEARCH" = 1; then
 428           LIB_res_search="-l$lib"
 429         fi
 430   fi
 431 fi
 432
 433 PTHREAD_LIBS=error
 434 AC_CHECK_LIB(pthread, pthread_attr_init,
 435              PTHREAD_LIBS="-lpthread")
 436 if test "x$PTHREAD_LIBS" = xerror; then
 437         AC_CHECK_LIB(pthreads, pthread_attr_init,
 438                 PTHREAD_LIBS="-lpthreads")
 439 fi
 440 if test "x$PTHREAD_LIBS" = xerror; then
 441         AC_CHECK_LIB(c_r, pthread_attr_init,
 442                 PTHREAD_LIBS="-lc_r")
 443 fi
 444 if test "x$PTHREAD_LIBS" = xerror; then
 445         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
 446 fi
 447 if test "x$PTHREAD_LIBS" = xerror; then
 448         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
 449 fi
 450 AC_SUBST(PTHREAD_LIBS)
 451
 452 WITH_OBSOLETE=NO
 453 if test "$enable_obsolete" = "yes"; then
 454         WITH_OBSOLETE=YES
 455 fi
 456
 457 WITH_INSECURE=NO
 458 if test "$enable_insecure" = "yes"; then
 459         WITH_INSECURE=YES
 460 fi
 461
 462 # Fast restart
 463 if test "$enable_fast_restart" = "yes"; then
 464         AC_DEFINE(FAST_RESTART)
 465 fi
 466
 467 if test "$enable_bitmap_later" = "yes"; then
 468         AC_DEFINE(BITMAP_LATER)
 469 fi
 470
 471 if test "$enable_full_vos_listvol_switch" = "yes"; then
 472         AC_DEFINE(FULL_LISTVOL_SWITCH)
 473 fi
 474
 475 if test "$enable_bos_restricted_mode" = "yes"; then
 476         AC_DEFINE(BOS_RESTRICTED_MODE)
 477 fi
 478
 479 if test "$enable_namei_fileserver" = "yes"; then
 480         AC_DEFINE(AFS_NAMEI_ENV)
 481 fi
 482
 483 if test "$enable_afsdb" = "yes"; then
 484         LIB_AFSDB="$LIB_res_search"
 485         AC_DEFINE(AFS_AFSDB_ENV)
 486 fi
 487
 488 dnl check for tivoli
 489 AC_MSG_CHECKING(for tivoli tsm butc support)
 490 XBSA_CFLAGS=""
 491 if test "$enable_tivoli_tsm" = "yes"; then
 492         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
 493         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
 494
 495         if test -e "$XBSADIR1/xbsa.h"; then
 496                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
 497                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 498         elif test -e "$XBSADIR2/xbsa.h"; then
 499                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
 500                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 501         else
 502                 AC_MSG_RESULT([no, missing xbsa.h header file])
 503         fi
 504 else
 505         AC_MSG_RESULT([no])
 506 fi
 507 AC_SUBST(XBSA_CFLAGS)
 508
 509 dnl checks for header files.
 510 AC_HEADER_STDC
 511 AC_HEADER_SYS_WAIT
 512 AC_HEADER_DIRENT
 513 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
 514 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
 515 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h)
 516 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
 517 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h)
 518 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h)
 519
 520 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf re_comp re_exec)
 521 AC_CHECK_FUNCS(setprogname getprogname)
 522
 523 dnl Directory PATH handling
 524 if test "x$enable_transarc_paths" = "xyes"  ; then
 525     afsconfdir=${afsconfdir=/usr/afs/etc}
 526     viceetcdir=${viceetcdir=/usr/vice/etc}
 527     afskerneldir=${afskerneldir=${viceetcdir}}
 528     afssrvbindir=${afssrvbindir=/usr/afs/bin}
 529     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
 530     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
 531     afsdbdir=${afsdbdir=/usr/afs/db}
 532     afslogsdir=${afslogsdir=/usr/afs/logs}
 533     afslocaldir=${afslocaldir=/usr/afs/local}
 534     afsbackupdir=${afsbackupdir=/usr/afs/backup}
 535     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
 536 else
 537     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
 538     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
 539     afskerneldir=${afskerneldir='${libdir}/openafs'}
 540     afssrvbindir=${afssrvbindir='${bindir}'}
 541     afssrvsbindir=${afssrvsbindir='${sbindir}'}
 542     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
 543     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
 544     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
 545     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
 546     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
 547     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
 548 fi
 549 AC_SUBST(afsconfdir)
 550 AC_SUBST(viceetcdir)
 551 AC_SUBST(afskerneldir)
 552 AC_SUBST(afssrvbindir)
 553 AC_SUBST(afssrvsbindir)
 554 AC_SUBST(afssrvlibexecdir)
 555 AC_SUBST(afsdbdir)
 556 AC_SUBST(afslogsdir)
 557 AC_SUBST(afslocaldir)
 558 AC_SUBST(afsbackupdir)
 559 AC_SUBST(afsbosconfigdir)
 560
 561 if test "x$enable_kernel_module" = "xyes"; then
 562 ENABLE_KERNEL_MODULE=libafs
 563 fi
 564
 565 AC_SUBST(AFS_SYSNAME)
 566 AC_SUBST(AFS_PARAM_COMMON)
 567 AC_SUBST(ENABLE_KERNEL_MODULE)
 568 AC_SUBST(LIB_AFSDB)
 569 AC_SUBST(LINUX_KERNEL_PATH)
 570 AC_SUBST(LINUX_VERSION)
 571 AC_SUBST(MKAFS_OSTYPE)
 572 AC_SUBST(TOP_OBJDIR)
 573 AC_SUBST(TOP_SRCDIR)
 574 AC_SUBST(TOP_INCDIR)
 575 AC_SUBST(TOP_LIBDIR)
 576 AC_SUBST(DEST)
 577 AC_SUBST(WITH_OBSOLETE)
 578 AC_SUBST(WITH_INSECURE)
 579 AC_SUBST(DARWIN_INFOFILE)
 580 AC_SUBST(IRIX_BUILD_IP35)
 581
 582 OPENAFS_OSCONF
 583
 584 ])