acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #   define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 #define _FILE_OFFSET_BITS 64
  48 #define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 #include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
  76
  77 dnl General feature options.
  78 AC_ARG_ENABLE([pam],
  79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
  80     ,
  81     [enable_pam="yes"])
  82 AC_ARG_ENABLE([gtx],
  83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
  84 AC_ARG_ENABLE([uss],
  85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
  86 AC_ARG_ENABLE([namei-fileserver],
  87     [AS_HELP_STRING([--enable-namei-fileserver],
  88         [force compilation of namei fileserver in preference to inode
  89          fileserver])],
  90     ,
  91     [enable_namei_fileserver="default"])
  92 AC_ARG_ENABLE([supergroups],
  93     [AS_HELP_STRING([--enable-supergroups],
  94         [enable support for nested pts groups])],
  95     ,
  96     [enable_supergroups="no"])
  97 AC_ARG_ENABLE([bitmap-later],
  98     [AS_HELP_STRING([--enable-bitmap-later],
  99         [enable fast startup of file server by not reading bitmap till
 100          needed])],
 101     ,
 102     [enable_bitmap_later="no"])
 103 AC_ARG_ENABLE([unix-sockets],
 104     [AS_HELP_STRING([--disable-unix-sockets],
 105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 106     ,
 107     [enable_unix_sockets="yes"])
 108 AC_ARG_ENABLE([tivoli-tsm],
 109     [AS_HELP_STRING([--enable-tivoli-tsm],
 110         [enable use of the Tivoli TSM API libraries for butc support])],
 111     ,
 112     [enable_tivoli_tsm="no"])
 113 AC_ARG_ENABLE([pthreaded-ubik],
 114     [AS_HELP_STRING([--enable-pthreaded-ubik],
 115         [enable installation of pthreaded ubik applications (defaults to
 116          disabled)])],
 117     ,
 118     [enable_pthreaded_ubik="no"])
 119
 120 dnl Kernel module build options.
 121 AC_ARG_WITH([linux-kernel-headers],
 122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 123         [use the kernel headers found at path (optional, defaults to
 124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
 125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
 126 AC_ARG_WITH([linux-kernel-build],
 127     [AS_HELP_STRING([--with-linux-kernel-build=path],
 128         [use the kernel build found at path(optional, defaults to
 129         kernel headers path)])])
 130 AC_ARG_WITH([bsd-kernel-headers],
 131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 132         [use the kernel headers found at path (optional, defaults to
 133          /usr/src/sys)])])
 134 AC_ARG_WITH([bsd-kernel-build],
 135     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 136         [use the kernel build found at path (optional, defaults to
 137          KSRC/i386/compile/GENERIC)])])
 138 AC_ARG_WITH([linux-kernel-packaging],
 139     [AS_HELP_STRING([--with-linux-kernel-packaging],
 140         [use standard naming conventions to aid Linux kernel build packaging
 141          (disables MPS, sets the kernel module name to openafs.ko, and
 142          installs kernel modules into the standard Linux location)])],
 143     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
 144      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
 145     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
 146 AC_ARG_ENABLE([kernel-module],
 147     [AS_HELP_STRING([--disable-kernel-module],
 148         [disable compilation of the kernel module (defaults to enabled)])],
 149     ,
 150     [enable_kernel_module="yes"])
 151 AC_ARG_ENABLE([redhat-buildsys],
 152     [AS_HELP_STRING([--enable-redhat-buildsys],
 153         [enable compilation of the redhat build system kernel (defaults to
 154          disabled)])],
 155     ,
 156     [enable_redhat_buildsys="no"])
 157
 158 dnl Installation locations.
 159 AC_ARG_ENABLE([transarc-paths],
 160     [AS_HELP_STRING([--enable-transarc-paths],
 161         [use Transarc style paths like /usr/afs and /usr/vice])],
 162     ,
 163     [enable_transarc_paths="no"])
 164
 165 dnl Deprecated crypto
 166 AC_ARG_ENABLE([kauth],
 167     [AS_HELP_STRING([--disable-kauth],
 168         [do not install the deprecated kauth server and utilities (defaults to
 169          enabled)])],
 170     ,
 171     [enable_kauth="yes"])
 172
 173 dnl Optimization and debugging flags.
 174 AC_ARG_ENABLE([strip-binaries],
 175     [AS_HELP_STRING([--disable-strip-binaries],
 176         [disable stripping of symbol information from binaries (defaults to
 177          enabled)])],
 178     ,
 179     [enable_strip_binaries="maybe"])
 180 AC_ARG_ENABLE([debug],
 181     [AS_HELP_STRING([--enable-debug],
 182         [enable compilation of the user space code with debugging information
 183          (defaults to disabled)])],
 184     ,
 185     [enable_debug="no"])
 186 AC_ARG_ENABLE([optimize],
 187     [AS_HELP_STRING([--disable-optimize],
 188         [disable optimization for compilation of the user space code (defaults
 189          to enabled)])],
 190     ,
 191     [enable_optimize="yes"])
 192 AC_ARG_ENABLE([warnings],
 193     [AS_HELP_STRING([--enable-warnings],
 194         [enable compilation warnings when building with gcc (defaults to
 195          disabled)])],
 196     ,
 197     [enable_warnings="no"])
 198 AC_ARG_ENABLE([checking],
 199     [AS_HELP_STRING([--enable-checking],
 200         [turn compilation warnings into errors when building with gcc (defaults
 201          to disabled)])],
 202     [enable_checking="$enableval"],
 203     [enable_checking="no"])
 204 AC_ARG_ENABLE([debug-locks],
 205     [AS_HELP_STRING([--enable-debug-locks],
 206         [turn on lock debugging assertions (defaults to disabled)])],
 207     [enable_debug_locks="$enableval"],
 208     [enable_debug_locks="no"])
 209 AC_ARG_ENABLE([debug-kernel],
 210     [AS_HELP_STRING([--enable-debug-kernel],
 211         [enable compilation of the kernel module with debugging information
 212          (defaults to disabled)])],
 213     ,
 214     [enable_debug_kernel="no"])
 215 AC_ARG_ENABLE([optimize-kernel],
 216     [AS_HELP_STRING([--disable-optimize-kernel],
 217         [disable compilation of the kernel module with optimization (defaults
 218          based on platform)])],
 219     ,
 220     [enable_optimize_kernel=""])
 221 AC_ARG_ENABLE([debug-lwp],
 222     [AS_HELP_STRING([--enable-debug-lwp],
 223         [enable compilation of the LWP code with debugging information
 224          (defaults to disabled)])],
 225     ,
 226     [enable_debug_lwp="no"])
 227 AC_ARG_ENABLE([optimize-lwp],
 228     [AS_HELP_STRING([--disable-optimize-lwp],
 229         [disable optimization for compilation of the LWP code (defaults to
 230          enabled)])],
 231     ,
 232     [enable_optimize_lwp="yes"])
 233 AC_ARG_ENABLE([debug-pam],
 234     [AS_HELP_STRING([--enable-debug-pam],
 235         [enable compilation of the PAM code with debugging information
 236          (defaults to disabled)])],
 237     ,
 238     [enable_debug_pam="no"])
 239 AC_ARG_ENABLE([optimize-pam],
 240     [AS_HELP_STRING([--disable-optimize-pam],
 241         [disable optimization for compilation of the PAM code (defaults to
 242          enabled)])],
 243     ,
 244     [enable_optimize_pam="yes"])
 245 AC_ARG_ENABLE([linux-syscall-probing],
 246     [AS_HELP_STRING([--enable-linux-syscall-probing],
 247         [enable Linux syscall probing (defaults to autodetect)])],
 248     ,
 249     [enable_linux_syscall_probing="maybe"])
 250 AC_ARG_WITH([crosstools-dir],
 251     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
 252
 253 AC_ARG_WITH([xslt-processor],
 254         AS_HELP_STRING([--with-xslt-processor=ARG],
 255         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 256         [XSLTPROC="$withval"],
 257         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
 258
 259 AC_ARG_WITH([html-xsl],
 260         AS_HELP_STRING([--with-html-xsl],
 261         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 262         [HTML_XSL="$withval"],
 263         [HTML_XSL="html/chunk.xsl"])
 264
 265 AC_ARG_WITH([docbook2pdf],
 266         AS_HELP_STRING([--with-docbook2pdf=ARG],
 267         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 268         [DOCBOOK2PDF="$withval"],
 269         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
 270
 271 AC_ARG_WITH([docbook-stylesheets],
 272         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 273         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 274         [DOCBOOK_STYLESHEETS="$withval"],
 275         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
 276         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
 277                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 278         fi)
 279
 280 enable_login="no"
 281
 282 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 283 dnl documentation build.
 284 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 285
 286 dnl weird ass systems
 287 dnl AC_AIX
 288 AC_ISC_POSIX
 289 dnl AC_MINIX
 290
 291 dnl Various compiler setup.
 292 AC_TYPE_PID_T
 293 AC_TYPE_SIZE_T
 294
 295 dnl Checks for programs.
 296 AC_PROG_INSTALL
 297 AC_PROG_LN_S
 298 AC_PROG_RANLIB
 299 AC_PROG_YACC
 300 AM_PROG_LEX
 301 dnl if we are flex, be lex-compatible
 302 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 303
 304 OPENAFS_FORCE_ABS_INSTALL
 305 OPENAFS_CHECK_BIGENDIAN
 306 OPENAFS_PRINTF_TAKES_Z_LEN
 307
 308 AC_MSG_CHECKING(your OS)
 309 system=$host
 310 case $system in
 311         *-linux*)
 312
 313                 MKAFS_OSTYPE=LINUX
 314                 if test "x$enable_redhat_buildsys" = "xyes"; then
 315                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 316                 fi
 317                 if test "x$enable_kernel_module" = "xyes"; then
 318                  if test "x$with_linux_kernel_headers" != "x"; then
 319                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 320                  else
 321                    for utsdir in "/lib/modules/`uname -r`/build" \
 322                                  "/lib/modules/`uname -r`/source" \
 323                                  "/usr/src/linux-2.4" \
 324                                  "/usr/src/linux"; do
 325                      LINUX_KERNEL_PATH="$utsdir"
 326                      for utsfile in "include/generated/utsrelease.h" \
 327                                     "include/linux/utsrelease.h" \
 328                                     "include/linux/version.h" \
 329                                     "include/linux/version-up.h"; do
 330                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
 331                          break 2
 332                        fi
 333                      done
 334                    done
 335                  fi
 336                  if test "x$with_linux_kernel_build" != "x"; then
 337                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 338                  else
 339                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 340                  fi
 341                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 342                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 343                    LINUX_VERSION="$linux_kvers"
 344                  else
 345                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 346                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 347                      LINUX_VERSION="$linux_kvers"
 348                    else
 349                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 350                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 351                        if test "x$linux_kvers" = "x"; then
 352                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 353                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 354                            if test "x$linux_kvers" = "x"; then
 355                              AC_MSG_ERROR(Linux headers lack version definition [2])
 356                              exit 1
 357                            else
 358                              LINUX_VERSION="$linux_kvers"
 359                            fi
 360                          else
 361                            AC_MSG_ERROR(Linux headers lack version definition)
 362                            exit 1
 363                          fi
 364                        else
 365                          LINUX_VERSION="$linux_kvers"
 366                        fi
 367                      else
 368                        enable_kernel_module="no"
 369                      fi
 370                    fi
 371                  fi
 372                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 373                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 374                      enable_kernel_module="no"
 375                  fi
 376                  if test "x$enable_kernel_module" = "xno"; then
 377                   if test "x$with_linux_kernel_headers" != "x"; then
 378                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 379                    exit 1
 380                   else
 381                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 382                   fi
 383                  fi
 384                  dnl do we need to determine SUBARCH from autoconf.h
 385                  SUBARCH=default
 386                 fi
 387                 AC_MSG_RESULT(linux)
 388                 if test "x$enable_kernel_module" = "xyes"; then
 389                  case "$LINUX_VERSION" in
 390                   2.2.*) AFS_SYSKVERS=22 ;;
 391                   2.4.*) AFS_SYSKVERS=24 ;;
 392                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
 393                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 394                  esac
 395                 fi
 396                 ;;
 397         *-solaris*)
 398                 MKAFS_OSTYPE=SOLARIS
 399                 AC_MSG_RESULT(sun4)
 400                 AC_PATH_PROG(SOLARISCC, [cc], ,
 401                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 402                 if test "x$SOLARISCC" = "x" ; then
 403                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 404                 fi
 405                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 406                 SOLARIS_FS_HAS_FS_ROLLED
 407                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 408                 ;;
 409         *-sunos*)
 410                 MKAFS_OSTYPE=SUNOS
 411                 enable_kernel_module=no
 412                 AC_MSG_RESULT(sun4)
 413                 ;;
 414         *-hpux*)
 415                 MKAFS_OSTYPE=HPUX
 416                 AC_MSG_RESULT(hp_ux)
 417                 if test -f "/usr/old/usr/include/ndir.h"; then
 418                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 419                 fi
 420                 ;;
 421         *-irix*)
 422                 if test -d /usr/include/sys/SN/SN1; then
 423                  IRIX_BUILD_IP35="IP35"
 424                 fi
 425                 MKAFS_OSTYPE=IRIX
 426                 AC_MSG_RESULT(sgi)
 427                 ;;
 428         *-aix*)
 429                 MKAFS_OSTYPE=AIX
 430                 AC_MSG_RESULT(rs_aix)
 431                 ;;
 432         arm-*-darwin*)
 433                 MKAFS_OSTYPE=DARWIN
 434                 AC_MSG_RESULT(arm_darwin)
 435                 ;;
 436         powerpc-*-darwin*)
 437                 MKAFS_OSTYPE=DARWIN
 438                 AC_MSG_RESULT(ppc_darwin)
 439                 ;;
 440         i386-*-darwin*)
 441                 MKAFS_OSTYPE=DARWIN
 442                 AC_MSG_RESULT(x86_darwin)
 443                 ;;
 444         x86_64-*-darwin*)
 445                 MKAFS_OSTYPE=DARWIN
 446                 AC_MSG_RESULT(x86_darwin)
 447                 ;;
 448         i386-*-freebsd*)
 449                 MKAFS_OSTYPE=FBSD
 450                 AC_MSG_RESULT(i386_fbsd)
 451                 ;;
 452         x86_64-*-freebsd*)
 453                 MKAFS_OSTYPE=FBSD
 454                 AC_MSG_RESULT(amd64_fbsd)
 455                 ;;
 456         *-netbsd*)
 457                 MKAFS_OSTYPE=NBSD
 458                 AC_MSG_RESULT(nbsd)
 459                 ;;
 460         x86_64-*-openbsd*)
 461                 MKAFS_OSTYPE=OBSD
 462                 AC_MSG_RESULT(amd64_obsd)
 463                 ;;
 464         i386-*-openbsd*)
 465                 MKAFS_OSTYPE=OBSD
 466                 AC_MSG_RESULT(i386_obsd)
 467                 ;;
 468         *-dragonfly*)
 469                 MKAFS_OSTYPE=DFBSD
 470                 AC_MSG_RESULT(i386_dfbsd)
 471                 ;;
 472         *)
 473                 AC_MSG_RESULT($system)
 474                 ;;
 475 esac
 476
 477 if test "x$with_afs_sysname" != "x"; then
 478         AFS_SYSNAME="$with_afs_sysname"
 479 else
 480         AC_MSG_CHECKING(your AFS sysname)
 481         case $host in
 482                 i?86-*-openbsd?.?)
 483                         v=${host#*openbsd}
 484                         vM=${v%.*}
 485                         vm=${v#*.}
 486                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 487                         ;;
 488                 sparc64-*-openbsd?.?)
 489                         v=${host#*openbsd}
 490                         vM=${v%.*}
 491                         vm=${v#*.}
 492                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 493                         ;;
 494                 x86_64-*-openbsd?.?)
 495                         v=${host#*openbsd}
 496                         vM=${v%.*}
 497                         vm=${v#*.}
 498                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 499                         ;;
 500                 i?86-*-freebsd*.*)
 501                         v=${host#*freebsd}
 502                         vM=${v%.*}
 503                         vm=${v#*.}
 504                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 505                         ;;
 506                 x86_64-*-freebsd*.*)
 507                         v=${host#*freebsd}
 508                         vM=${v%.*}
 509                         vm=${v#*.}
 510                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 511                         ;;
 512                 i386-*-dragonfly?.*)
 513                         v=${host#*dragonfly}
 514                         vM=${v%.*}
 515                         vm=${v#*.}
 516                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 517                         ;;
 518                 i?86-*-netbsd*1.6[[M-Z]]*)
 519                         AFS_SYSNAME="i386_nbsd20"
 520                         ;;
 521                 powerpc-*-netbsd*1.6[[M-Z]]*)
 522                         AFS_SYSNAME="ppc_nbsd20"
 523                         ;;
 524                 *-*-netbsd*)
 525                         arch=${host%%-unknown*}
 526                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 527                                                -e 's/powerpc/ppc/g')
 528                         v=${host#*netbsd}
 529                         v=${v#*aout}
 530                         v=${v#*ecoff}
 531                         v=${v#*elf}
 532                         vM=${v%%.*}
 533                         vM=${vM%.*}
 534                         v=${v#*.}
 535                         vm=${v%%.*}
 536                         vm=${vm%.*}
 537                         vm=${vm%%[[_A-Z]]*}
 538                         if test $vm -eq 99 ; then
 539                                 vM=$((vM+1))
 540                         fi
 541                         if test $vM -gt 1 ; then
 542                                 vm=0
 543                         fi
 544                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 545                         ;;
 546                 hppa*-hp-hpux11.0*)
 547                         AFS_SYSNAME="hp_ux110"
 548                         ;;
 549                 hppa*-hp-hpux11.11)
 550                         AFS_SYSNAME="hp_ux11i"
 551                         ;;
 552                 hppa*-hp-hpux11.23)
 553                         AFS_SYSNAME="hp_ux1123"
 554                         ;;
 555                 ia64-hp-hpux11.22)
 556                         AFS_SYSNAME="ia64_hpux1122"
 557                         ;;
 558                 ia64-hp-hpux*)
 559                         AFS_SYSNAME="ia64_hpux1123"
 560                         ;;
 561                 hppa*-hp-hpux10*)
 562                         AFS_SYSNAME="hp_ux102"
 563                         ;;
 564                 powerpc-apple-darwin7*)
 565                         AFS_SYSNAME="ppc_darwin_70"
 566                         OSXSDK="macosx10.3"
 567                         ;;
 568                 powerpc-apple-darwin8.*)
 569                         AFS_SYSNAME="ppc_darwin_80"
 570                         OSXSDK="macosx10.4"
 571                         ;;
 572                 i386-apple-darwin8.*)
 573                         AFS_SYSNAME="x86_darwin_80"
 574                         OSXSDK="macosx10.4"
 575                         ;;
 576                 powerpc-apple-darwin9.*)
 577                         AFS_SYSNAME="ppc_darwin_90"
 578                         OSXSDK="macosx10.5"
 579                         ;;
 580                 i386-apple-darwin9.*)
 581                         AFS_SYSNAME="x86_darwin_90"
 582                         OSXSDK="macosx10.5"
 583                         ;;
 584                 i?86-apple-darwin10.*)
 585                         AFS_SYSNAME="x86_darwin_100"
 586                         OSXSDK="macosx10.6"
 587                         ;;
 588                 x86_64-apple-darwin10.*)
 589                         AFS_SYSNAME="x86_darwin_100"
 590                         OSXSDK="macosx10.6"
 591                         ;;
 592                 arm-apple-darwin10.*)
 593                         AFS_SYSNAME="arm_darwin_100"
 594                         OSXSDK="iphoneos4.0"
 595                         ;;
 596                 x86_64-apple-darwin11.*)
 597                         AFS_SYSNAME="x86_darwin_110"
 598                         OSXSDK="macosx10.7"
 599                         ;;
 600                 i?86-apple-darwin11.*)
 601                         AFS_SYSNAME="x86_darwin_110"
 602                         OSXSDK="macosx10.7"
 603                         ;;
 604                 x86_64-apple-darwin12.*)
 605                         AFS_SYSNAME="x86_darwin_120"
 606                         OSXSDK="macosx10.8"
 607                         ;;
 608                 i?86-apple-darwin12.*)
 609                         AFS_SYSNAME="x86_darwin_120"
 610                         OSXSDK="macosx10.8"
 611                         ;;
 612                 sparc-sun-solaris2.8)
 613                         AFS_SYSNAME="sun4x_58"
 614                         ;;
 615                 sparc-sun-solaris2.9)
 616                         AFS_SYSNAME="sun4x_59"
 617                         ;;
 618                 sparc-sun-solaris2.10)
 619                         AFS_SYSNAME="sun4x_510"
 620                         ;;
 621                 sparc-sun-solaris2.11)
 622                         AFS_SYSNAME="sun4x_511"
 623                         ;;
 624                 i386-pc-solaris2.8)
 625                         AFS_SYSNAME="sunx86_58"
 626                         ;;
 627                 i386-pc-solaris2.9)
 628                         AFS_SYSNAME="sunx86_59"
 629                         ;;
 630                 i386-pc-solaris2.10)
 631                         AFS_SYSNAME="sunx86_510"
 632                         ;;
 633                 i386-pc-solaris2.11)
 634                         AFS_SYSNAME="sunx86_511"
 635                         ;;
 636                 alpha*-dec-osf4.0*)
 637                         AFS_SYSNAME="alpha_dux40"
 638                         ;;
 639                 alpha*-dec-osf5.0*)
 640                         AFS_SYSNAME="alpha_dux50"
 641                         ;;
 642                 alpha*-dec-osf5.1*)
 643                         AFS_SYSNAME="alpha_dux51"
 644                         ;;
 645                 mips-sgi-irix6.5)
 646                         AFS_SYSNAME="sgi_65"
 647                         ;;
 648                 ia64-*-linux*)
 649                         AFS_SYSNAME="ia64_linuxXX"
 650                         ;;
 651                 powerpc-*-linux*)
 652                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 653                         ;;
 654                 powerpc64-*-linux*)
 655                         AFS_SYSNAME="ppc64_linuxXX"
 656                         ;;
 657                 alpha*-linux*)
 658                         AFS_SYSNAME="alpha_linux_XX"
 659                         ;;
 660                 s390-*-linux*)
 661                         AFS_SYSNAME="s390_linuxXX"
 662                         ;;
 663                 s390x-*-linux*)
 664                         AFS_SYSNAME="s390x_linuxXX"
 665                         ;;
 666                 sparc-*-linux*)
 667                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 668                         ;;
 669                 sparc64-*-linux*)
 670                         AFS_SYSNAME="sparc64_linuxXX"
 671                         ;;
 672                 i?86-*-linux*)
 673                         AFS_SYSNAME="i386_linuxXX"
 674                         ;;
 675                 arm*-linux*)
 676                         AFS_SYSNAME="arm_linuxXX"
 677                         ;;
 678                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 679                         AFS_SYSNAME="parisc_linuxXX"
 680                         enable_pam="no"
 681                         ;;
 682                 power*-ibm-aix4.2*)
 683                         AFS_SYSNAME="rs_aix42"
 684                         enable_pam="no"
 685                         ;;
 686                 power*-ibm-aix4.3*)
 687                         AFS_SYSNAME="rs_aix42"
 688                         enable_pam="no"
 689                         ;;
 690                 power*-ibm-aix5.1*)
 691                         AFS_SYSNAME="rs_aix51"
 692                         enable_pam="no"
 693                         ;;
 694                 power*-ibm-aix5.2*)
 695                         AFS_SYSNAME="rs_aix52"
 696                         enable_pam="no"
 697                         ;;
 698                 power*-ibm-aix5.3*)
 699                         AFS_SYSNAME="rs_aix53"
 700                         enable_pam="no"
 701                         ;;
 702                 power*-ibm-aix6.1*)
 703                         AFS_SYSNAME="rs_aix61"
 704                         enable_pam="no"
 705                         ;;
 706                 x86_64-*-linux-gnu)
 707                         AFS_SYSNAME="amd64_linuxXX"
 708                         enable_pam="yes"
 709                         ;;
 710                 *)
 711                         AC_MSG_ERROR(An AFS sysname is required)
 712                         exit 1
 713                         ;;
 714         esac
 715         case $AFS_SYSNAME in
 716                 *_linux* | *_umlinux*)
 717                         if test "x${AFS_SYSKVERS}" = "x"; then
 718                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 719                         fi
 720                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 721                         AFS_SYSNAME="$_AFS_SYSNAME"
 722                         AC_TRY_KBUILD(
 723                          [],
 724                          [#ifndef CONFIG_USERMODE
 725                           #error not UML
 726                           #endif],
 727                          ac_cv_linux_is_uml=yes,)
 728                         if test "${ac_cv_linux_is_uml}" = yes; then
 729                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 730                         fi
 731                         AFS_SYSNAME="$_AFS_SYSNAME"
 732                         ;;
 733         esac
 734         AC_MSG_RESULT($AFS_SYSNAME)
 735 fi
 736
 737 case $AFS_SYSNAME in
 738         *_darwin*)
 739                 AC_CHECK_HEADERS(crt_externs.h)
 740                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 741                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 742                 AC_SUBST(OSXSDK)
 743                 ;;
 744 esac
 745
 746 dnl Some hosts have a separate common param file they should include.  Figure
 747 dnl out if we're on one of them now that we know the sysname.
 748 case $AFS_SYSNAME in
 749     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 750     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 751     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 752     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 753     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 754     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 755     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 756     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 757     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 758     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 759     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 760     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 761     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 762     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 763     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 764     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 765     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 766     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 767     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 768     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 769     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 770     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 771     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 772     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 773     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 774     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 775     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 776     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 777     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 778 # Linux alpha adds an extra underscore for no good reason.
 779     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 780     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 781     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 782 esac
 783
 784 OPENAFS_OSCONF
 785
 786 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 787
 788                 # Add (sub-) architecture-specific paths needed by conftests
 789                 case $AFS_SYSNAME  in
 790                         *_umlinux26)
 791                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 792                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 793                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 794                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 795                 esac
 796
 797                 if test "x$enable_kernel_module" = "xyes"; then
 798                  if test "x$enable_debug_kernel" = "xno"; then
 799                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 800                  fi
 801                  OPENAFS_GCC_SUPPORTS_MARCH
 802                  AC_SUBST(P5PLUS_KOPTS)
 803                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 804                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 805                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 806                  OPENAFS_GCC_SUPPORTS_PIPE
 807                  AC_SUBST(LINUX_GCC_KOPTS)
 808
 809                  dnl Setup the kernel build environment
 810                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 811                  LINUX_KERNEL_COMPILE_WORKS
 812
 813                  dnl Check for header files
 814                  AC_CHECK_LINUX_HEADER([config.h])
 815                  AC_CHECK_LINUX_HEADER([completion.h])
 816                  AC_CHECK_LINUX_HEADER([exportfs.h])
 817                  AC_CHECK_LINUX_HEADER([freezer.h])
 818                  AC_CHECK_LINUX_HEADER([key-type.h])
 819                  AC_CHECK_LINUX_HEADER([semaphore.h])
 820                  AC_CHECK_LINUX_HEADER([seq_file.h])
 821
 822                  dnl Type existence checks
 823                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 824
 825                  dnl Check for structure elements
 826                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 827                                        [write_begin], [fs.h])
 828                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 829                                        [backing-dev.h])
 830                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 831                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 832                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 833                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 834                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 835                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 836                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 837                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 838                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 839                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 840                  AC_CHECK_LINUX_STRUCT([filename], [name], [fs.h])
 841                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
 842                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 843                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 844                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 845                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 846                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 847                                        [fs.h])
 848                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 849                                        [fs.h])
 850                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 851                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 852                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 853                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 854                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 855                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 856                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 857                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 858                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 859                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 860                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 861
 862                  dnl Check for typed structure elements
 863                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 864                                              [buf], [fs.h])
 865
 866                  dnl Function existence checks
 867
 868                  AC_CHECK_LINUX_FUNC([bdi_init],
 869                                      [#include <linux/backing-dev.h>],
 870                                      [bdi_init(NULL);])
 871                  AC_CHECK_LINUX_FUNC([PageChecked],
 872                                      [#include <linux/mm.h>
 873 #include <linux/page-flags.h>],
 874                                      [struct page *_page;
 875                                       int bchecked = PageChecked(_page);])
 876                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 877                                      [#include <linux/mm.h>
 878 #include <linux/page-flags.h>],
 879                                      [struct page *_page;
 880                                       int bchecked = PageFsMisc(_page);])
 881                  AC_CHECK_LINUX_FUNC([clear_inode],
 882                                      [#include <linux/fs.h>],
 883                                      [clear_inode(NULL);])
 884                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 885                                      [#include <linux/time.h>],
 886                                      [struct timespec s;
 887                                       s = current_kernel_time();])
 888                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 889                                      [#include <linux/fs.h>],
 890                                      [d_alloc_anon(NULL);])
 891                  AC_CHECK_LINUX_FUNC([d_make_root],
 892                                      [#include <linux/fs.h>],
 893                                      [d_make_root(NULL);])
 894                  AC_CHECK_LINUX_FUNC([do_sync_read],
 895                                      [#include <linux/fs.h>],
 896                                      [do_sync_read(NULL, NULL, 0, NULL);])
 897                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 898                                      [#include <linux/sched.h>],
 899                                      [pid_t p; find_task_by_pid(p);])
 900                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 901                                      [#include <linux/fs.h>],
 902                                      [generic_file_aio_read(NULL,NULL,0,0);])
 903                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 904                                      [#include <linux/pagemap.h>],
 905                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 906                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 907                                      [#include <linux/list.h>],
 908                                      [hlist_unhashed(0);])
 909                  AC_CHECK_LINUX_FUNC([i_size_read],
 910                                      [#include <linux/fs.h>],
 911                                      [i_size_read(NULL);])
 912                  AC_CHECK_LINUX_FUNC([inode_setattr],
 913                                      [#include <linux/fs.h>],
 914                                      [inode_setattr(NULL, NULL);])
 915                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
 916                                      [#include <linux/net.h>],
 917                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
 918                  AC_CHECK_LINUX_FUNC([page_follow_link],
 919                                      [#include <linux/fs.h>],
 920                                      [page_follow_link(0,0);])
 921                  AC_CHECK_LINUX_FUNC([page_offset],
 922                                      [#include <linux/pagemap.h>],
 923                                      [page_offset(NULL);])
 924                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
 925                                      [#include <linux/pagevec.h>],
 926                                      [__pagevec_lru_add_file(NULL);])
 927                  AC_CHECK_LINUX_FUNC([path_lookup],
 928                                      [#include <linux/fs.h>
 929                                       #include <linux/namei.h>],
 930                                      [path_lookup(NULL, 0, NULL);])
 931                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
 932                                      [#include <linux/rcupdate.h>],
 933                                      [rcu_read_lock();])
 934                  AC_CHECK_LINUX_FUNC([set_nlink],
 935                                      [#include <linux/fs.h>],
 936                                      [set_nlink(NULL, 1);])
 937                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
 938                                      [#include <linux/splice.h>],
 939                                      [splice_direct_to_actor(NULL,NULL,NULL);])
 940                  AC_CHECK_LINUX_FUNC([svc_addr_in],
 941                                      [#include <linux/sunrpc/svc.h>],
 942                                      [svc_addr_in(NULL);])
 943                  AC_CHECK_LINUX_FUNC([zero_user_segments],
 944                                      [#include <linux/highmem.h>],
 945                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
 946                  AC_CHECK_LINUX_FUNC([noop_fsync],
 947                                      [#include <linux/fs.h>],
 948                                      [void *address = &noop_fsync; printk("%p\n", address)];)
 949                  AC_CHECK_LINUX_FUNC([kthread_run],
 950                                      [#include <linux/kernel.h>
 951                                       #include <linux/kthread.h>],
 952                                      [kthread_run(NULL, NULL, "test");])
 953
 954                  dnl Consequences - things which get set as a result of the
 955                  dnl                above tests
 956                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
 957                        [AC_DEFINE([AFS_NONFSTRANS], 1,
 958                                   [define to disable the nfs translator])])
 959
 960                  dnl Assorted more complex tests
 961                  LINUX_AIO_NONVECTOR
 962                  LINUX_EXPORTS_PROC_ROOT_FS
 963                  LINUX_KMEM_CACHE_INIT
 964                  LINUX_HAVE_KMEM_CACHE_T
 965                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
 966                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
 967                  LINUX_D_PATH_TAKES_STRUCT_PATH
 968                  LINUX_NEW_EXPORT_OPS
 969                  LINUX_INODE_SETATTR_RETURN_TYPE
 970                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
 971                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
 972                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
 973                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
 974                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
 975                  LINUX_DOP_D_DELETE_TAKES_CONST
 976                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
 977                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
 978                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
 979                  LINUX_FOP_F_FSYNC_TAKES_RANGE
 980                  LINUX_AOP_WRITEBACK_CONTROL
 981                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
 982                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
 983                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
 984                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
 985                  LINUX_KERNEL_SOCK_CREATE
 986                  LINUX_EXPORTS_KEY_TYPE_KEYRING
 987                  LINUX_NEED_RHCONFIG
 988                  LINUX_RECALC_SIGPENDING_ARG_TYPE
 989                  LINUX_EXPORTS_TASKLIST_LOCK
 990                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
 991                  LINUX_STATFS_TAKES_DENTRY
 992                  LINUX_REFRIGERATOR
 993                  LINUX_HAVE_TRY_TO_FREEZE
 994                  LINUX_LINUX_KEYRING_SUPPORT
 995                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
 996                  LINUX_KEY_ALLOC_NEEDS_CRED
 997                  LINUX_INIT_WORK_HAS_DATA
 998                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
 999                  LINUX_HAVE_DCACHE_LOCK
1000                  LINUX_D_COUNT_IS_INT
1001                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1002                  LINUX_IOP_CREATE_TAKES_UMODE_T
1003                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1004                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1005                  LINUX_DENTRY_OPEN_TAKES_PATH
1006                  LINUX_D_ALIAS_IS_HLIST
1007                  LINUX_IOP_I_CREATE_TAKES_BOOL
1008                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1009                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1010
1011                  dnl If we are guaranteed that keyrings will work - that is
1012                  dnl  a) The kernel has keyrings enabled
1013                  dnl  b) The code is new enough to give us a key_type_keyring
1014                  dnl then we just disable syscall probing unless we've been
1015                  dnl told otherwise
1016
1017                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1018                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1019                           [enable_linux_syscall_probing="no"],
1020                           [enable_linux_syscall_probing="yes"])
1021                  ])
1022
1023                  dnl Syscall probing needs a few tests of its own, and just
1024                  dnl won't work if the kernel doesn't export init_mm
1025                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1026                    LINUX_EXPORTS_INIT_MM
1027                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1028                      AC_MSG_ERROR(
1029                        [Can't do syscall probing without exported init_mm])
1030                    ])
1031                    LINUX_EXPORTS_SYS_CHDIR
1032                    LINUX_EXPORTS_SYS_OPEN
1033                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1034                              [define to enable syscall table probes])
1035                  ])
1036
1037                  dnl Packaging and SMP build
1038                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1039                    LINUX_WHICH_MODULES
1040                  else
1041                    AC_SUBST(MPS,'SP')
1042                  fi
1043
1044                  dnl Syscall probing
1045                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1046                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1047                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1048                    ])
1049                    ac_cv_linux_exports_sys_call_table=no
1050                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1051                      ac_cv_linux_exports_ia32_sys_call_table=yes
1052                    fi
1053                  else
1054                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1055                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1056                    LINUX_EXPORTS_SYS_CALL_TABLE
1057                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1058                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1059                          linux_syscall_method=none
1060                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1061                             linux_syscall_method=scan
1062                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1063                                linux_syscall_method=scan_with_kallsyms_address
1064                             fi
1065                          fi
1066                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1067                             linux_syscall_method=kallsyms_symbol
1068                          fi
1069                          if test "x$linux_syscall_method" = "xnone"; then
1070                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1071                             linux_syscall_method=scan
1072                          fi
1073                    fi
1074                  fi
1075                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1076                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1077                  fi
1078                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1079                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1080                  fi
1081                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1082                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1083                  else
1084                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1085                  fi
1086                 :
1087                 fi
1088 dnl Linux-only, but just enable always.
1089                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1090 esac
1091
1092 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1093     [ac_cv_sync_fetch_and_add],
1094     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1095                     [ac_cv_sync_fetch_and_add=yes],
1096                     [ac_cv_sync_fetch_and_add=no])
1097 ])
1098 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1099       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1100                 [define if your C compiler has __sync_add_and_fetch])])
1101
1102 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1103     [ac_cv_sockaddr_len],
1104     [AC_TRY_COMPILE( [#include <sys/types.h>
1105 #include <sys/socket.h>],
1106                      [struct sockaddr *a; a->sa_len=0;],
1107                      [ac_cv_sockaddr_len=yes],
1108                      [ac_cv_sockaddr_len=no])
1109 ])
1110 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1111       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1112                  [define if you struct sockaddr sa_len])])
1113
1114 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1115         echo Skipping library tests because they confuse Irix.
1116 else
1117   AC_SEARCH_LIBS([socket], [socket inet])
1118   AC_SEARCH_LIBS([connect], [nsl])
1119   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1120
1121   dnl darwin wants it, aix hates it
1122   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1123   AC_TRY_COMPILE([
1124   #include <stdlib.h>
1125   #include <stdio.h>
1126   #include <sys/types.h>
1127   #include <sys/socket.h>
1128   #include <netinet/in.h>
1129   #include <arpa/inet.h>
1130   #include <arpa/nameser.h>
1131   #include <arpa/nameser_compat.h>
1132   #include <resolv.h>
1133   ], [static int i; i = 0;],
1134   [AC_MSG_RESULT(yes)
1135    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1136   [AC_MSG_RESULT(no)
1137    ])
1138
1139   openafs_save_libs="$LIBS"
1140   AC_MSG_CHECKING([for res_search])
1141   AC_FUNC_RES_SEARCH
1142
1143   if test "$ac_cv_func_res_search" = no; then
1144       for lib in dns nsl resolv; do
1145         if test "$ac_cv_func_res_search" != yes; then
1146           LIBS="-l$lib $LIBS"
1147           AC_FUNC_RES_SEARCH
1148           LIBS="$openafs_save_libs"
1149         fi
1150       done
1151       if test "$ac_cv_func_res_search" = yes; then
1152         LIB_AFSDB="-l$lib"
1153         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1154         AC_MSG_RESULT([yes, in lib$lib])
1155       else
1156         AC_MSG_RESULT(no)
1157       fi
1158   else
1159     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1160     AC_MSG_RESULT(yes)
1161   fi
1162
1163 fi
1164 XLIBS="$LIB_AFSDB $XLIBS"
1165
1166 AC_CHECK_RESOLV_RETRANS
1167
1168 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1169     [ac_cv_setsockopt_iprecverr],
1170     [AC_TRY_COMPILE( [
1171 #include <sys/types.h>
1172 #include <sys/socket.h>
1173 #include <netinet/in.h>],
1174 [int on=1;
1175 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1176         [ac_cv_setsockopt_iprecverr=yes],
1177         [ac_cv_setsockopt_iprecverr=no])])
1178
1179 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1180       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1181                  [define if we can receive socket errors via IP_RECVERR])])
1182
1183 PTHREAD_LIBS=error
1184 if test "x$MKAFS_OSTYPE" = OBSD; then
1185         PTHREAD_LIBS="-pthread"
1186 fi
1187 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1188         PTHREAD_LIBS="-pthread"
1189 fi
1190 if test "x$PTHREAD_LIBS" = xerror; then
1191         AC_CHECK_LIB(pthread, pthread_attr_init,
1192                 PTHREAD_LIBS="-lpthread")
1193 fi
1194 if test "x$PTHREAD_LIBS" = xerror; then
1195         AC_CHECK_LIB(pthreads, pthread_attr_init,
1196                 PTHREAD_LIBS="-lpthreads")
1197 fi
1198 if test "x$PTHREAD_LIBS" = xerror; then
1199         AC_CHECK_LIB(c_r, pthread_attr_init,
1200                 PTHREAD_LIBS="-lc_r")
1201 fi
1202 if test "x$PTHREAD_LIBS" = xerror; then
1203         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1204 fi
1205 if test "x$PTHREAD_LIBS" = xerror; then
1206         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1207         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1208                 PTHREAD_LIBS="-lpthread")
1209 fi
1210 if test "x$PTHREAD_LIBS" = xerror; then
1211         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1212 fi
1213 AC_SUBST(PTHREAD_LIBS)
1214
1215 HOST_CPU="$host_cpu"
1216
1217 if test "x$with_bsd_kernel_headers" != "x"; then
1218         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1219 else
1220         BSD_KERNEL_PATH="/usr/src/sys"
1221 fi
1222
1223 if test "x$with_bsd_kernel_build" != "x"; then
1224         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1225 else
1226         case $AFS_SYSNAME in
1227                 *_fbsd_*)
1228                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1229                         ;;
1230                 *_nbsd*)
1231                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1232         esac
1233 fi
1234
1235 # Fast restart
1236 if test "$enable_supergroups" = "yes"; then
1237         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1238 fi
1239
1240 if test "$enable_bitmap_later" = "yes"; then
1241         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1242 fi
1243
1244 if test "$enable_unix_sockets" = "yes"; then
1245         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1246         USE_UNIX_SOCKETS="yes"
1247 else
1248         USE_UNIX_SOCKETS="no"
1249 fi
1250 AC_SUBST(USE_UNIX_SOCKETS)
1251
1252 if test "$enable_namei_fileserver" = "yes"; then
1253         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1254         VFSCK=""
1255 else
1256         if test "$enable_namei_fileserver" = "default"; then
1257                 case $host in
1258                         *-solaris2.10*)
1259                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1260                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1261                                 VFSCK=""
1262                                 ;;
1263                         *-solaris2.11*)
1264                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1265                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1266                                 VFSCK=""
1267                                 ;;
1268                         *)
1269                                 VFSCK="vfsck"
1270                                 ;;
1271                 esac
1272         else
1273                 VFSCK="vfsck"
1274         fi
1275 fi
1276
1277 dnl check for tivoli
1278 AC_MSG_CHECKING(for tivoli tsm butc support)
1279 XBSA_CFLAGS=""
1280 if test "$enable_tivoli_tsm" = "yes"; then
1281         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1282         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1283         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1284         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1285
1286         if test -r "$XBSADIR3/dsmapifp.h"; then
1287                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1288                 XBSA_XLIBS="-ldl"
1289                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1290         elif test -r "$XBSADIR4/dsmapifp.h"; then
1291                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1292                 XBSA_XLIBS="-ldl"
1293                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1294         elif test -r "$XBSADIR1/xbsa.h"; then
1295                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1296                 XBSA_XLIBS=""
1297                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1298         elif test -r "$XBSADIR2/xbsa.h"; then
1299                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1300                 XBSA_XLIBS=""
1301                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1302         else
1303                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1304         fi
1305 else
1306         AC_MSG_RESULT([no])
1307 fi
1308 AC_SUBST(XBSA_CFLAGS)
1309 AC_SUBST(XBSA_XLIBS)
1310
1311 dnl checks for header files.
1312 AC_HEADER_STDC
1313 AC_HEADER_SYS_WAIT
1314 AC_HEADER_DIRENT
1315 AC_CHECK_HEADERS([ \
1316                    arpa/inet.h \
1317                    arpa/nameser.h \
1318                    curses.h\
1319                    direct.h \
1320                    et/com_err.h \
1321                    errno.h \
1322                    fcntl.h \
1323                    grp.h \
1324                    math.h \
1325                    mntent.h \
1326                    ncurses.h \
1327                    netdb.h \
1328                    netinet/in.h \
1329                    pthread_np.h \
1330                    pwd.h \
1331                    regex.h \
1332                    security/pam_appl.h \
1333                    signal.h \
1334                    stdint.h \
1335                    stdio_ext.h \
1336                    stdlib.h \
1337                    string.h \
1338                    strings.h \
1339                    sys/bitypes.h \
1340                    sys/bswap.h \
1341                    sys/dk.h \
1342                    sys/fcntl.h \
1343                    sys/file.h \
1344                    sys/fs_types.h \
1345                    sys/fstyp.h \
1346                    sys/ioctl.h \
1347                    sys/ipc.h \
1348                    sys/lockf.h \
1349                    sys/map.h \
1350                    sys/mount.h \
1351                    sys/mntent.h \
1352                    sys/mnttab.h \
1353                    sys/pag.h \
1354                    sys/param.h \
1355                    sys/resource.h \
1356                    sys/select.h \
1357                    sys/statfs.h \
1358                    sys/statvfs.h \
1359                    sys/socket.h \
1360                    sys/sysctl.h \
1361                    sys/time.h \
1362                    sys/types.h \
1363                    sys/uio.h \
1364                    sys/un.h \
1365                    sys/vfs.h \
1366                    syslog.h \
1367                    termios.h \
1368                    time.h \
1369                    ucontext.h \
1370                    unistd.h \
1371                    windows.h \
1372                 ])
1373
1374 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1375 #ifdef HAVE_NETINET_IN_H
1376 # include <netinet/in.h>
1377 #endif])
1378
1379 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1380 #ifdef HAVE_SYS_SOCKET_H
1381 # include <sys/socket.h>
1382 #endif])
1383
1384 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1385 #ifdef HAVE_SYS_SOCKET_H
1386 # include <sys/socket.h>
1387 #endif
1388 #ifdef HAVE_NETINET_IN_H
1389 # include <netinet/in.h>
1390 #endif
1391 #ifdef HAVE_NET_IF_H
1392 # include <net/if.h>
1393 #endif])
1394
1395 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1396 #ifdef HAVE_SECURITY_PAM_APPL_H
1397 # include <security/pam_appl.h>
1398 #endif])
1399
1400 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1401
1402 AC_CHECK_TYPES([fsblkcnt_t],,,[
1403 #include <sys/types.h>
1404 #ifdef HAVE_SYS_BITYPES_H
1405 #include <sys/bitypes.h>
1406 #endif
1407 #ifdef HAVE_SYS_STATFS_H
1408 #include <sys/statfs.h>
1409 #endif
1410 #ifdef HAVE_SYS_STATVFS_H
1411 #include <sys/statvfs.h>
1412 #endif
1413 ])
1414
1415 dnl see what struct stat has for timestamps
1416 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1417
1418 dnl check for curses-lib
1419 AS_IF([test "x$enable_gtx" != "xno"],
1420       [save_LIBS=$LIBS
1421       AC_CHECK_LIB( [ncurses], [setupterm],
1422       [LIB_curses=-lncurses],
1423         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1424           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1425       ])
1426       LIBS=$save_LIBS
1427       AC_SUBST(LIB_curses)])
1428
1429 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1430
1431 if test "$enable_debug_locks" = yes; then
1432         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1433 fi
1434
1435 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1436 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1437         case $AFS_SYSNAME in
1438         sgi_*)
1439                 HAVE_PAM="no"
1440                 ;;
1441         *)
1442                 HAVE_PAM="yes"
1443                 ;;
1444         esac
1445 else
1446         HAVE_PAM="no"
1447 fi
1448 AC_SUBST(HAVE_PAM)
1449
1450 if test "$enable_login" = yes; then
1451         BUILD_LOGIN="yes"
1452 else
1453         BUILD_LOGIN="no"
1454 fi
1455 AC_SUBST(BUILD_LOGIN)
1456
1457 if test "$enable_uss" = yes; then
1458         BUILD_USS="yes"
1459 else
1460         BUILD_USS="no"
1461 fi
1462 AC_SUBST(BUILD_USS)
1463
1464 if test "$enable_kauth" = yes; then
1465         INSTALL_KAUTH="yes"
1466 else
1467         INSTALL_KAUTH="no"
1468 fi
1469 AC_SUBST(INSTALL_KAUTH)
1470
1471 AC_CHECK_FUNCS([ \
1472         arc4random \
1473         fcntl \
1474         fseeko64 \
1475         ftello64 \
1476         getcwd \
1477         getegid \
1478         geteuid \
1479         getgid \
1480         getuid \
1481         getrlimit \
1482         issetugid \
1483         mkstemp \
1484         poll \
1485         pread \
1486         preadv \
1487         preadv64 \
1488         pwrite \
1489         pwritev \
1490         pwritev64 \
1491         regcomp \
1492         regerror \
1493         regexec \
1494         setitimer \
1495         setvbuf \
1496         sigaction \
1497         strcasestr \
1498         strerror \
1499         sysconf \
1500         sysctl \
1501         tdestroy \
1502         timegm \
1503 ])
1504
1505 OPENAFS_ROKEN()
1506 OPENAFS_C_ATTRIBUTE()
1507
1508 dnl Functions that Heimdal's libroken provides, but that we
1509 dnl haven't found a need for yet, and so haven't imported
1510 AC_CHECK_FUNCS([ \
1511         chown \
1512         fchown \
1513         gethostname \
1514         lstat \
1515         inet_aton \
1516         inet_ntop \
1517         inet_pton \
1518         putenv \
1519         readv \
1520         setenv \
1521         strdup \
1522         strftime \
1523         strndup \
1524         strsep \
1525         unsetenv \
1526 ])
1527
1528 dnl Functions that are in objects that we always build from libroken
1529 AC_CHECK_FUNCS([ \
1530         asprintf \
1531         asnprintf \
1532         vasprintf \
1533         vasnprintf \
1534         vsnprintf \
1535         snprintf \
1536 ])
1537
1538 dnl Functions that we're going to try and get from libroken
1539 AC_REPLACE_FUNCS([ \
1540         daemon \
1541         ecalloc \
1542         emalloc \
1543         erealloc \
1544         err \
1545         errx \
1546         flock \
1547         getdtablesize \
1548         getopt \
1549         getprogname \
1550         gettimeofday \
1551         localtime_r \
1552         mkstemp \
1553         setenv \
1554         setprogname \
1555         strcasecmp \
1556         strlcat \
1557         strnlen \
1558         strlcpy \
1559         strsep \
1560         tdelete \
1561         tfind \
1562         tsearch \
1563         twalk \
1564         unsetenv \
1565         verr \
1566         verrx \
1567         vsyslog \
1568         vwarn \
1569         vwarnx \
1570         warn \
1571         warnx \
1572 ])
1573
1574 dnl Headers that we're going to try and get from libroken
1575 AC_CHECK_HEADERS([ \
1576         err.h \
1577         search.h \
1578 ])
1579
1580 AC_CHECK_DECLS([h_errno], [], [], [
1581 #include <sys/types.h>
1582 #ifdef HAVE_NETDB_H
1583 #include <netdb.h>
1584 #endif
1585 ])
1586
1587 AC_HEADER_TIME
1588
1589 ROKEN_HEADERS=
1590 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1591       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1592       [])
1593 AC_SUBST(ROKEN_HEADERS)
1594
1595 dnl Stuff that's harder ...
1596 AC_MSG_CHECKING([for bswap16])
1597 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1598 #ifdef HAVE_SYS_TYPES_H
1599 #include <sys/types.h>
1600 #endif
1601 #ifdef HAVE_SYS_BSWAP_H
1602 #include <sys/bswap.h>
1603 #endif
1604 ],
1605 [short a, b; b = bswap16(a); ])],
1606 [AC_MSG_RESULT(yes)
1607  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1608 ],
1609 [AC_MSG_RESULT(no)])
1610
1611 AC_MSG_CHECKING([for bswap32])
1612 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1613 #include <sys/types.h>
1614 #endif
1615 #ifdef HAVE_SYS_BSWAP_H
1616 #include <sys/bswap.h>
1617 #endif
1618 ],
1619 [int a, b; b = bswap32(a); ])],
1620 [AC_MSG_RESULT(yes)
1621  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1622 ],
1623 [AC_MSG_RESULT(no)])
1624
1625 case $AFS_SYSNAME in
1626 *hp_ux* | *hpux*)
1627    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1628    ;;
1629 *)
1630    AC_MSG_CHECKING([for positional I/O])
1631    if test "$ac_cv_func_pread" = "yes" && \
1632            test "$ac_cv_func_pwrite" = "yes"; then
1633       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1634       AC_MSG_RESULT(yes)
1635    else
1636      AC_MSG_RESULT(no)
1637    fi
1638    AC_MSG_CHECKING([for vectored positional I/O])
1639    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1640                "$ac_cv_func_pwritev" = "yes" -a \
1641                "$ac_cv_func_preadv64" = "yes" -a \
1642                "$ac_cv_func_pwritev64" = "yes"],
1643          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1644           AC_MSG_RESULT(yes)],
1645          [AC_MSG_RESULT(no)])
1646    ;;
1647 esac
1648
1649 AC_MSG_CHECKING([for POSIX regex library])
1650 if test "$ac_cv_header_regex_h" = "yes" && \
1651         test "$ac_cv_func_regcomp" = "yes" && \
1652         test "$ac_cv_func_regexec" = "yes" && \
1653         test "$ac_cv_func_regerror" = "yes"; then
1654     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1655     AC_MSG_RESULT(yes)
1656 else
1657     AC_MSG_RESULT(no)
1658 fi
1659
1660 dnl Look for "non-portable" pthreads functions.
1661 save_LIBS="$LIBS"
1662 LIBS="$LIBS $PTHREAD_LIBS"
1663 AC_CHECK_FUNCS([ \
1664         pthread_set_name_np \
1665         pthread_setname_np \
1666 ])
1667
1668 dnl Sadly, there are three different versions of pthread_setname_np.
1669 dnl Try to cater for all of them.
1670 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1671     AC_MSG_CHECKING([for signature of pthread_setname_np])
1672     AC_TRY_COMPILE([
1673 #include <pthread.h>
1674 #ifdef HAVE_PTHREAD_NP_H
1675 #include <pthread_np.h>
1676 #endif
1677 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1678         AC_MSG_RESULT([three arguments])
1679         pthread_setname_np_args=3], [
1680         AC_TRY_COMPILE([
1681 #include <pthread.h>
1682 #ifdef HAVE_PTHREAD_NP_H
1683 #include <pthread_np.h>
1684 #endif
1685 ], [pthread_setname_np(pthread_self(), "test")], [
1686             AC_MSG_RESULT([two arguments])
1687             pthread_setname_np_args=2], [
1688             AC_TRY_COMPILE([
1689 #include <pthread.h>
1690 #ifdef HAVE_PTHREAD_NP_H
1691 #include <pthread_np.h>
1692 #endif
1693 ], [pthread_setname_np("test")], [
1694                 AC_MSG_RESULT([one argument])
1695                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1696 ])
1697 ])
1698 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1699 fi
1700 LIBS="$save_LIBS"
1701
1702 openafs_cv_saved_CFLAGS="$CFLAGS"
1703 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1704
1705 AC_TYPE_SIGNAL
1706 OPENAFS_RETSIGTYPE
1707 AC_CHECK_SIZEOF(void *)
1708 AC_CHECK_SIZEOF(unsigned long long)
1709 AC_CHECK_SIZEOF(unsigned long)
1710 AC_CHECK_SIZEOF(unsigned int)
1711 AC_TYPE_INTPTR_T
1712 AC_TYPE_UINTPTR_T
1713 AC_TYPE_SSIZE_T
1714 AC_CHECK_TYPE([sig_atomic_t],[],
1715     [AC_DEFINE([sig_atomic_t], [int],
1716         [Define to int if <signal.h> does not define.])],
1717 [#include <sys/types.h>
1718 #include <signal.h>])
1719 AC_CHECK_TYPE([socklen_t],[],
1720     [AC_DEFINE([socklen_t], [int],
1721         [Define to int if <sys/socket.h> does not define.])],
1722 [#include <sys/types.h>
1723 #include <sys/socket.h>])
1724 AC_CHECK_TYPES(off64_t)
1725 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1726 AC_CHECK_TYPES([struct winsize], [], [], [
1727 #ifdef HAVE_TERMIOS_H
1728 # include <termios.h>
1729 #else
1730 # include <sys/termios.h>
1731 #endif
1732 #include <sys/ioctl.h>])
1733 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1734                 struct sockaddr_storage],
1735                [], [], [
1736 #include <sys/types.h>
1737 #include <sys/socket.h>
1738 ])
1739 AC_CHECK_TYPES([sa_family_t], [], [], [
1740 #include <sys/types.h>
1741 #include <sys/socket.h>
1742 ])
1743 AC_CHECK_TYPES([struct addrinfo], [], [], [
1744 #include <sys/types.h>
1745 #ifdef HAVE_NETDB_H
1746 #include <netdb.h>
1747 #endif
1748 ])
1749 AC_CHECK_TYPES([long long], [], [], [])
1750
1751 AC_SIZEOF_TYPE(long)
1752
1753 CFLAGS="$openafs_cv_saved_CFLAGS"
1754
1755 RRA_HEADER_PAM_CONST
1756
1757
1758 dnl Directory PATH handling
1759 if test "x$enable_transarc_paths" = "xyes"  ; then
1760     afsconfdir=${afsconfdir=/usr/afs/etc}
1761     viceetcdir=${viceetcdir=/usr/vice/etc}
1762     afskerneldir=${afskerneldir=${viceetcdir}}
1763     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1764     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1765     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1766     afsdbdir=${afsdbdir=/usr/afs/db}
1767     afslogsdir=${afslogsdir=/usr/afs/logs}
1768     afslocaldir=${afslocaldir=/usr/afs/local}
1769     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1770     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1771     afsdatadir=${afsdatadir=/usr/vice/etc}
1772 else
1773     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1774     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1775     afskerneldir=${afskerneldir='${libdir}/openafs'}
1776     afssrvbindir=${afssrvbindir='${bindir}'}
1777     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1778     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1779     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1780     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1781     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1782     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1783     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1784     afsdatadir=${afsdatadir='${datadir}/openafs'}
1785 fi
1786 AC_SUBST(afsconfdir)
1787 AC_SUBST(viceetcdir)
1788 AC_SUBST(afskerneldir)
1789 AC_SUBST(afssrvbindir)
1790 AC_SUBST(afssrvsbindir)
1791 AC_SUBST(afssrvlibexecdir)
1792 AC_SUBST(afsdbdir)
1793 AC_SUBST(afslogsdir)
1794 AC_SUBST(afslocaldir)
1795 AC_SUBST(afsbackupdir)
1796 AC_SUBST(afsbosconfigdir)
1797 AC_SUBST(afsdatadir)
1798
1799 if test "x$enable_kernel_module" = "xyes"; then
1800 ENABLE_KERNEL_MODULE=libafs
1801 fi
1802
1803 if test "x$enable_pthreaded_ubik" = "xyes"; then
1804 ENABLE_PTHREADED_UBIK=yes
1805 fi
1806
1807 AC_SUBST(VFSCK)
1808 AC_SUBST(AFS_SYSNAME)
1809 AC_SUBST(AFS_PARAM_COMMON)
1810 AC_SUBST(ENABLE_KERNEL_MODULE)
1811 AC_SUBST(ENABLE_PTHREADED_UBIK)
1812 AC_SUBST(LIB_AFSDB)
1813 AC_SUBST(LINUX_KERNEL_PATH)
1814 AC_SUBST(LINUX_KERNEL_BUILD)
1815 AC_SUBST(HOST_CPU)
1816 AC_SUBST(BSD_KERNEL_PATH)
1817 AC_SUBST(BSD_KERNEL_BUILD)
1818 AC_SUBST(LINUX_VERSION)
1819 AC_SUBST(MKAFS_OSTYPE)
1820 AC_SUBST(TOP_OBJDIR)
1821 AC_SUBST(TOP_SRCDIR)
1822 AC_SUBST(TOP_INCDIR)
1823 AC_SUBST(TOP_LIBDIR)
1824 AC_SUBST(DEST)
1825 AC_SUBST(DARWIN_INFOFILE)
1826 AC_SUBST(IRIX_BUILD_IP35)
1827 AC_SUBST(HTML_XSL)
1828 AC_SUBST(XSLTPROC)
1829 AC_SUBST(DOCBOOK2PDF)
1830 AC_SUBST(DOCBOOK_STYLESHEETS)
1831
1832 OPENAFS_FUSE
1833 OPENAFS_SWIG
1834
1835 TOP_SRCDIR="${srcdir}/src"
1836 dnl
1837 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1838 dnl
1839 case $TOP_SRCDIR in
1840         /*)
1841                 ;;
1842         *)
1843                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1844                 ;;
1845 esac
1846
1847 TOP_OBJDIR="${SRCDIR_PARENT}"
1848 TOP_INCDIR="${SRCDIR_PARENT}/include"
1849 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1850 if test "${DEST}x" = "x"; then
1851         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1852 fi
1853
1854 if test "x$with_crosstools_dir" != "x"; then
1855         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1856                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1857                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1858                 RXGEN_PATH=$with_crosstools_dir/rxgen
1859         else
1860                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1861                 exit 1
1862         fi
1863 else
1864         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1865         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1866         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1867 fi
1868 AC_SUBST(COMPILE_ET_PATH)
1869 AC_SUBST(CONFIGTOOL_PATH)
1870 AC_SUBST(RXGEN_PATH)
1871
1872 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1873 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1874 AC_SUBST(HELPER_SPLINT)
1875 AC_SUBST(HELPER_SPLINTCFG)
1876
1877 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1878
1879 dnl Check to see if crypt lives in a different library
1880 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1881 AC_SUBST(LIB_crypt)
1882
1883 dnl Check to see if the compiler support labels in structs
1884 AC_MSG_CHECKING(for label support in structs)
1885 AC_TRY_COMPILE([], [
1886 extern void osi_UFSOpen(void);
1887 struct labeltest {
1888    void (*open) (void);
1889 };
1890 struct labeltest struct_labeltest = {
1891    .open       = osi_UFSOpen,
1892 }
1893 ],
1894 [AC_MSG_RESULT(yes)
1895  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1896 ],
1897 [AC_MSG_RESULT(no)
1898 ])
1899
1900 AC_MSG_CHECKING([checking for dirfd])
1901 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1902 #ifdef HAVE_DIRENT_H
1903 #include <dirent.h>
1904 #endif
1905 ]],
1906         [[DIR *d = 0; dirfd(d);]])],
1907         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1908 if test "$ac_rk_have_dirfd" = "yes" ; then
1909         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1910 fi
1911 AC_MSG_RESULT($ac_rk_have_dirfd)
1912
1913 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1914 #ifdef HAVE_DIRENT_H
1915 #include <dirent.h>
1916 #endif])
1917
1918 dnl Eventually, this will look for the system one, or for OpenSSL
1919 LIB_hcrypto="-lafshcrypto"
1920 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1921 AC_SUBST(LIB_hcrypto)
1922 AC_SUBST(LDFLAGS_hcrypto)
1923
1924 dnl Check for UUID library
1925 AC_CHECK_HEADERS([uuid/uuid.h])
1926 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1927 AC_CHECK_FUNCS([uuid_generate])
1928 ])
1929
1930
1931 AC_DEFUN([SUMMARY], [
1932     # Print a configuration summary
1933 echo
1934 echo "**************************************"
1935 echo configure summary
1936 echo
1937 AS_IF([test $LIB_curses],[
1938 echo "LIB_curses :                $LIB_curses" ],[
1939 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1940 ])
1941 echo
1942 echo "**************************************"
1943 ])