acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN(OPENAFS_CONFIGURE_COMMON,[
   8
   9 AC_CANONICAL_HOST
  10 SRCDIR_PARENT=`pwd`
  11
  12 #BOZO_SAVE_CORES pam sia
  13 AC_ARG_WITH(afs-sysname,
  14 [  --with-afs-sysname=sys    use sys for the afs sysname]
  15 )
  16 AC_ARG_ENABLE( obsolete,
  17 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
  18 AC_ARG_ENABLE( insecure,
  19 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
  20 AC_ARG_ENABLE( afsdb,
  21 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
  22 AC_ARG_ENABLE( pam,
  23 [  --disable-pam                        disable PAM support],, enable_pam="yes")
  24 AC_ARG_ENABLE( bos-restricted-mode,
  25 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
  26 AC_ARG_ENABLE( bos-new-config,
  27 [  --enable-bos-new-config              enable bosserver pickup of BosConfig.new on restarts],, enable_bos_new_config="no")
  28 AC_ARG_ENABLE( largefile-fileserver,
  29 [  --enable-largefile-fileserver        enable large file support in fileserver],, enable_largefile_fileserver="no")
  30 AC_ARG_ENABLE( namei-fileserver,
  31 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
  32 AC_ARG_ENABLE( supergroups,
  33 [  --enable-supergroups                 enable support for nested pts groups],, enable_supergroups="no")
  34 AC_ARG_ENABLE( fast-restart,
  35 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
  36 AC_ARG_ENABLE( bitmap-later,
  37 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
  38 AC_ARG_ENABLE( full-vos-listvol-switch,
  39 [  --disable-full-vos-listvol-switch    disable vos full listvol switch for formatted output],, enable_full_vos_listvol_switch="yes")
  40 AC_ARG_WITH(dux-kernel-headers,
  41 [  --with-dux-kernel-headers=path       use the kernel headers found at path(optional, defaults to first match in /usr/sys)]
  42 )
  43 AC_ARG_WITH(linux-kernel-headers,
  44 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux)]
  45 )
  46 AC_ARG_WITH(bsd-kernel-headers,
  47 [  --with-bsd-kernel-headers=path       use the kernel headers found at path(optional, defaults to /usr/src/sys)]
  48 )
  49 AC_ARG_WITH(bsd-kernel-build,
  50 [  --with-bsd-kernel-build=path         use the kernel build found at path(optional, defaults to KSRC/i386/compile/GENERIC)]
  51 )
  52 AC_ARG_ENABLE(kernel-module,
  53 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
  54 )
  55 AC_ARG_ENABLE(redhat-buildsys,
  56 [  --enable-redhat-buildsys             enable compilation of the redhat build system kernel (defaults to disabled)],, enable_redhat_buildsys="no"
  57 )
  58 AC_ARG_ENABLE(transarc-paths,
  59 [  --enable-transarc-paths                      Use Transarc style paths like /usr/afs and /usr/vice],, enable_transarc_paths="no"
  60 )
  61 AC_ARG_ENABLE(tivoli-tsm,
  62 [  --enable-tivoli-tsm                  Enable use of the Tivoli TSM API libraries for butc support],, enable_tivoli_tsm="no"
  63 )
  64 AC_ARG_ENABLE(debug-kernel,
  65 [  --enable-debug-kernel                enable compilation of the kernel module with debugging information (defaults to disabled)],, enable_debug_kernel="no"
  66 )
  67 AC_ARG_ENABLE(optimize-kernel,
  68 [  --disable-optimize-kernel            disable compilation of the kernel module with optimization (defaults based on platform)],, enable_optimize_kernel="yes"
  69 )
  70 AC_ARG_ENABLE(debug,
  71 [  --enable-debug                       enable compilation of the user space code with debugging information (defaults to disabled)],, enable_debug="no"
  72 )
  73 AC_ARG_ENABLE(optimize,
  74 [  --disable-optimize                   disable optimization for compilation of the user space code (defaults to enabled)],, enable_optimize="yes"
  75 )
  76 AC_ARG_ENABLE(debug-lwp,
  77 [  --enable-debug-lwp                   enable compilation of the LWP code with debugging information (defaults to disabled)],, enable_debug_lwp="no"
  78 )
  79 AC_ARG_ENABLE(optimize-lwp,
  80 [  --disable-optimize-lwp               disable optimization for compilation of the LWP code (defaults to enabled)],, enable_optimize_lwp="yes"
  81 )
  82
  83 enable_login="no"
  84
  85 dnl weird ass systems
  86 AC_AIX
  87 AC_ISC_POSIX
  88 AC_MINIX
  89
  90 dnl Various compiler setup.
  91 AC_TYPE_PID_T
  92 AC_TYPE_SIZE_T
  93 AC_TYPE_SIGNAL
  94 COMPILER_HAS_FUNCTION_MACRO
  95
  96 dnl Checks for programs.
  97 AC_PROG_INSTALL
  98 AC_PROG_LN_S
  99 AC_PROG_RANLIB
 100 AC_PROG_YACC
 101 AM_PROG_LEX
 102
 103 OPENAFS_CHECK_BIGENDIAN
 104
 105 AC_MSG_CHECKING(your OS)
 106 system=$host
 107 case $system in
 108         *-linux*)
 109                 MKAFS_OSTYPE=LINUX
 110                 if test "x$enable_redhat_buildsys" = "xyes"; then
 111                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 112                 fi
 113                 if test "x$enable_kernel_module" = "xyes"; then
 114                  if test "x$with_linux_kernel_headers" != "x"; then
 115                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 116                  else
 117                    LINUX_KERNEL_PATH="/usr/src/linux-2.4"
 118                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 119                      LINUX_KERNEL_PATH="/usr/src/linux"
 120                    fi
 121                  fi
 122                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 123                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 124                   if test "x$linux_kvers" = "x"; then
 125                     if test -f "$LINUX_KERNEL_PATH/include/linux/version-up.h"; then
 126                       linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 127                       if test "x$linux_kvers" = "x"; then
 128
 129                         AC_MSG_ERROR(Linux headers lack version definition [2])
 130                         exit 1
 131                       else
 132                         LINUX_VERSION="$linux_kvers"
 133                       fi
 134                     else
 135                       AC_MSG_ERROR(Linux headers lack version definition)
 136                       exit 1
 137                     fi
 138                   else
 139                     LINUX_VERSION="$linux_kvers"
 140                   fi
 141                  else
 142                     enable_kernel_module="no"
 143                  fi
 144                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
 145                      enable_kernel_module="no"
 146                  fi
 147                  if test "x$enable_kernel_module" = "xno"; then
 148                   if test "x$with_linux_kernel_headers" != "x"; then
 149                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 150                    exit 1
 151                   else
 152                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 153                   fi
 154                  fi
 155                  dnl do we need to determine SUBARCH from autoconf.h
 156                  SUBARCH=default
 157                 fi
 158                 AC_MSG_RESULT(linux)
 159                 if test "x$enable_kernel_module" = "xyes"; then
 160                  if test "x$enable_debug_kernel" = "xno"; then
 161                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 162                  fi
 163                  OPENAFS_GCC_SUPPORTS_MARCH
 164                  AC_SUBST(P5PLUS_KOPTS)
 165                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 166                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 167                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 168                  OPENAFS_GCC_SUPPORTS_PIPE
 169                  AC_SUBST(LINUX_GCC_KOPTS)
 170                  ifdef([OPENAFS_CONFIGURE_LIBAFS],
 171                    [LINUX_BUILD_VNODE_FROM_INODE(src/config,afs)],
 172                    [LINUX_BUILD_VNODE_FROM_INODE(${srcdir}/src/config,src/afs/LINUX,${srcdir}/src/afs/LINUX)]
 173                  )
 174                  LINUX_COMPLETION_H_EXISTS
 175                  LINUX_DEFINES_FOR_EACH_PROCESS
 176                  LINUX_DEFINES_PREV_TASK
 177                  LINUX_EXPORTS_TASKLIST_LOCK
 178                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK
 179                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_GFP_MASK
 180                  LINUX_FS_STRUCT_INODE_HAS_I_ALLOC_SEM
 181                  LINUX_FS_STRUCT_INODE_HAS_I_TRUNCATE_SEM
 182                  LINUX_FS_STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS
 183                  LINUX_FS_STRUCT_INODE_HAS_I_DEVICES
 184                  LINUX_INODE_SETATTR_RETURN_TYPE
 185                  LINUX_KERNEL_LINUX_SYSCALL_H
 186                  LINUX_NEED_RHCONFIG
 187                  LINUX_RECALC_SIGPENDING_ARG_TYPE
 188                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_PARENT
 189                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_REAL_PARENT
 190                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIG
 191                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGHAND
 192                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGMASK_LOCK
 193                  LINUX_WHICH_MODULES
 194                  if test "x$ac_cv_linux_config_modversions" = "xno"; then
 195                    AC_MSG_WARN([Cannot determine sys_call_table status. assuming it's exported])
 196                    ac_cv_linux_exports_sys_call_table=yes
 197                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
 198                      ac_cv_linux_exports_ia32_sys_call_table=yes
 199                    fi
 200                  else
 201                    LINUX_EXPORTS_INIT_MM
 202                    LINUX_EXPORTS_KALLSYMS_ADDRESS
 203                    LINUX_EXPORTS_KALLSYMS_SYMBOL
 204                    LINUX_EXPORTS_SYS_CALL_TABLE
 205                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
 206                    LINUX_EXPORTS_SYS_CHDIR
 207                    LINUX_EXPORTS_SYS_CLOSE
 208                    LINUX_EXPORTS_SYS_WAIT4
 209                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
 210                          linux_syscall_method=none
 211                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
 212                             linux_syscall_method=scan
 213                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
 214                                linux_syscall_method=scan_with_kallsyms_address
 215                             fi
 216                          fi
 217                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
 218                             linux_syscall_method=kallsyms_symbol
 219                          fi
 220                          if test "x$linux_syscall_method" = "xnone"; then
 221                         AC_MSG_ERROR([no available sys_call_table access method])
 222                          fi
 223                    fi
 224                  fi
 225                  if test "x$ac_cv_linux_exports_sys_chdir" = "xyes" ; then
 226                   AC_DEFINE(EXPORTED_SYS_CHDIR, 1, [define if your linux kernel exports sys_chdir])
 227                  fi
 228                  if test "x$ac_cv_linux_exports_sys_close" = "xyes" ; then
 229                   AC_DEFINE(EXPORTED_SYS_CLOSE, 1, [define if your linux kernel exports sys_close])
 230                  fi
 231                  if test "x$ac_cv_linux_exports_sys_wait4" = "xyes" ; then
 232                   AC_DEFINE(EXPORTED_SYS_WAIT4, 1, [define if your linux kernel exports sys_wait4])
 233                  fi
 234                  if test "x$ac_cv_linux_exports_tasklist_lock" = "xyes" ; then
 235                   AC_DEFINE(EXPORTED_TASKLIST_LOCK, 1, [define if your linux kernel exports tasklist_lock])
 236                  fi
 237                  if test "x$ac_cv_linux_exports_sys_call_table" = "xyes"; then
 238                   AC_DEFINE(EXPORTED_SYS_CALL_TABLE)
 239                  fi
 240                  if test "x$ac_cv_linux_exports_ia32_sys_call_table" = "xyes"; then
 241                   AC_DEFINE(EXPORTED_IA32_SYS_CALL_TABLE)
 242                  fi
 243                  if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
 244                   AC_DEFINE(EXPORTED_KALLSYMS_SYMBOL)
 245                  fi
 246                  if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
 247                   AC_DEFINE(EXPORTED_KALLSYMS_ADDRESS)
 248                  fi
 249                  if test "x$ac_cv_linux_completion_h_exists" = "xyes" ; then
 250                   AC_DEFINE(COMPLETION_H_EXISTS, 1, [define if completion_h exists])
 251                  fi
 252                  if test "x$ac_cv_linux_defines_for_each_process" = "xyes" ; then
 253                   AC_DEFINE(DEFINED_FOR_EACH_PROCESS, 1, [define if for_each_process defined])
 254                  fi
 255                  if test "x$ac_cv_linux_defines_prev_task" = "xyes" ; then
 256                   AC_DEFINE(DEFINED_PREV_TASK, 1, [define if prev_task defined])
 257                  fi
 258                  if test "x$ac_cv_linux_func_inode_setattr_returns_int" = "xyes" ; then
 259                   AC_DEFINE(INODE_SETATTR_NOT_VOID, 1, [define if your setattr return return non-void])
 260                  fi
 261                  if test "x$ac_cv_linux_fs_struct_address_space_has_page_lock" = "xyes"; then
 262                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK, 1, [define if your struct address_space has page_lock])
 263                  fi
 264                  if test "x$ac_cv_linux_fs_struct_address_space_has_gfp_mask" = "xyes"; then
 265                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_GFP_MASK, 1, [define if your struct address_space has gfp_mask])
 266                  fi
 267                  if test "x$ac_cv_linux_fs_struct_inode_has_i_truncate_sem" = "xyes"; then
 268                   AC_DEFINE(STRUCT_INODE_HAS_I_TRUNCATE_SEM, 1, [define if your struct inode has truncate_sem])
 269                  fi
 270                  if test "x$ac_cv_linux_fs_struct_inode_has_i_alloc_sem" = "xyes"; then
 271                   AC_DEFINE(STRUCT_INODE_HAS_I_ALLOC_SEM, 1, [define if your struct inode has alloc_sem])
 272                  fi
 273                  if test "x$ac_cv_linux_fs_struct_inode_has_i_devices" = "xyes"; then
 274                   AC_DEFINE(STRUCT_INODE_HAS_I_DEVICES, 1, [define if you struct inode has i_devices])
 275                  fi
 276                  if test "x$ac_cv_linux_fs_struct_inode_has_i_dirty_data_buffers" = "xyes"; then
 277                   AC_DEFINE(STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS, 1, [define if your struct inode has data_buffers])
 278                  fi
 279                  if test "x$ac_cv_linux_func_recalc_sigpending_takes_void" = "xyes"; then
 280                   AC_DEFINE(RECALC_SIGPENDING_TAKES_VOID, 1, [define if your recalc_sigpending takes void])
 281                  fi
 282                  if test "x$ac_linux_syscall" = "xyes" ; then
 283                   AC_DEFINE(HAVE_KERNEL_LINUX_SYSCALL_H, 1, [define if your linux kernel has linux/syscall.h])
 284                  fi
 285                  if test "x$ac_cv_linux_sched_struct_task_struct_has_parent" = "xyes"; then
 286                   AC_DEFINE(STRUCT_TASK_STRUCT_HAS_PARENT, 1, [define if your struct task_struct has parent])
 287                  fi
 288                  if test "x$ac_cv_linux_sched_struct_task_struct_has_real_parent" = "xyes"; then
 289                   AC_DEFINE(STRUCT_TASK_STRUCT_HAS_REAL_PARENT, 1, [define if your struct task_struct has real_parent])
 290                  fi
 291                  if test "x$ac_cv_linux_sched_struct_task_struct_has_sigmask_lock" = "xyes"; then
 292                   AC_DEFINE(STRUCT_TASK_STRUCT_HAS_SIGMASK_LOCK, 1, [define if your struct task_struct has sigmask_lock])
 293                  fi
 294                  if test "x$ac_cv_linux_sched_struct_task_struct_has_sighand" = "xyes"; then
 295                   AC_DEFINE(STRUCT_TASK_STRUCT_HAS_SIGHAND, 1, [define if your struct task_struct has sighand])
 296                  fi
 297                  if test "x$ac_cv_linux_sched_struct_task_struct_has_sig" = "xyes"; then
 298                   AC_DEFINE(STRUCT_TASK_STRUCT_HAS_SIG, 1, [define if your struct task_struct has sig])
 299                  fi
 300                 :
 301                 fi
 302                 ;;
 303         *-solaris*)
 304                 MKAFS_OSTYPE=SOLARIS
 305                 AC_MSG_RESULT(sun4)
 306                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 307                 SOLARIS_PROC_HAS_P_COREFILE
 308                 SOLARIS_FS_HAS_FS_ROLLED
 309                 ;;
 310         *-sunos*)
 311                 MKAFS_OSTYPE=SUNOS
 312                 enable_kernel_module=no
 313                 AC_MSG_RESULT(sun4)
 314                 ;;
 315         *-hpux*)
 316                 MKAFS_OSTYPE=HPUX
 317                 AC_MSG_RESULT(hp_ux)
 318                 ;;
 319         *-irix*)
 320                 if test -d /usr/include/sys/SN/SN1; then
 321                  IRIX_BUILD_IP35="IP35"
 322                 fi
 323                 MKAFS_OSTYPE=IRIX
 324                 AC_MSG_RESULT(sgi)
 325                 ;;
 326         *-aix*)
 327                 MKAFS_OSTYPE=AIX
 328                 AC_MSG_RESULT(rs_aix)
 329                 ;;
 330         *-osf*)
 331                 MKAFS_OSTYPE=DUX
 332                 AC_MSG_RESULT(alpha_dux)
 333                 if test "x$enable_kernel_module" = "xyes"; then
 334                  if test "x$with_dux_kernel_headers" != "x"; then
 335                    HEADER_RT=`ls ${with_dux_kernel_headers}/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 336                  else
 337                    HEADER_RT=`ls /usr/sys/*/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 338                  fi
 339                 fi
 340                 if test "$HEADER_RT" = "*" ; then
 341                         AC_MSG_ERROR([Need a configured kernel directory])
 342                 fi
 343                 AC_SUBST([HEADER_RT])
 344                 ;;
 345         *-darwin*)
 346                 MKAFS_OSTYPE=DARWIN
 347                 AC_MSG_RESULT(ppc_darwin)
 348                 ;;
 349         *-freebsd*)
 350                 MKAFS_OSTYPE=FBSD
 351                 AC_MSG_RESULT(i386_fbsd)
 352                 ;;
 353         *-netbsd*)
 354                 MKAFS_OSTYPE=NBSD
 355                 AC_MSG_RESULT(nbsd)
 356                 ;;
 357         *-openbsd*)
 358                 MKAFS_OSTYPE=OBSD
 359                 AC_MSG_RESULT(i386_obsd)
 360                 ;;
 361         *)
 362                 AC_MSG_RESULT($system)
 363                 ;;
 364 esac
 365
 366 if test "x$with_afs_sysname" != "x"; then
 367         AFS_SYSNAME="$with_afs_sysname"
 368 else
 369         AC_MSG_CHECKING(your AFS sysname)
 370         case $host in
 371                 i?86-*-openbsd3.1)
 372                         AFS_SYSNAME="i386_obsd31"
 373                         ;;
 374                 i?86-*-openbsd3.2)
 375                         AFS_SYSNAME="i386_obsd32"
 376                         ;;
 377                 i?86-*-openbsd3.3)
 378                         AFS_SYSNAME="i386_obsd33"
 379                         ;;
 380                 i?86-*-openbsd3.4)
 381                         AFS_SYSNAME="i386_obsd34"
 382                         ;;
 383                 i?86-*-openbsd3.5)
 384                         AFS_SYSNAME="i386_obsd35"
 385                         ;;
 386                 i?86-*-freebsd4.2*)
 387                         AFS_SYSNAME="i386_fbsd_42"
 388                         ;;
 389                 i?86-*-freebsd4.3*)
 390                         AFS_SYSNAME="i386_fbsd_43"
 391                         ;;
 392                 i?86-*-freebsd4.4*)
 393                         AFS_SYSNAME="i386_fbsd_44"
 394                         ;;
 395                 i?86-*-freebsd4.5*)
 396                         AFS_SYSNAME="i386_fbsd_45"
 397                         ;;
 398                 i?86-*-freebsd4.6*)
 399                         AFS_SYSNAME="i386_fbsd_46"
 400                         ;;
 401                 i?86-*-freebsd4.7*)
 402                         AFS_SYSNAME="i386_fbsd_47"
 403                         ;;
 404                 i?86-*-freebsd5.0*)
 405                         AFS_SYSNAME="i386_fbsd_50"
 406                         ;;
 407                 i?86-*-freebsd5.1*)
 408                         AFS_SYSNAME="i386_fbsd_51"
 409                         ;;
 410                 i?86-*-freebsd5.2*)
 411                         AFS_SYSNAME="i386_fbsd_52"
 412                         ;;
 413                 i?86-*-netbsd*1.5*)
 414                         AFS_PARAM_COMMON=param.nbsd15.h
 415                         AFS_SYSNAME="i386_nbsd15"
 416                         ;;
 417                 alpha-*-netbsd*1.5*)
 418                         AFS_PARAM_COMMON=param.nbsd15.h
 419                         AFS_SYSNAME="alpha_nbsd15"
 420                         ;;
 421                 i?86-*-netbsd*1.6[[M-Z]]*)
 422                         AFS_PARAM_COMMON=param.nbsd20.h
 423                         AFS_SYSNAME="i386_nbsd20"
 424                         ;;
 425                 powerpc-*-netbsd*1.6[[M-Z]]*)
 426                         AFS_PARAM_COMMON=param.nbsd20.h
 427                         AFS_SYSNAME="ppc_nbsd20"
 428                         ;;
 429                 i?86-*-netbsd*2.0*)
 430                         AFS_PARAM_COMMON=param.nbsd20.h
 431                         AFS_SYSNAME="i386_nbsd20"
 432                         ;;
 433                 powerpc-*-netbsd*2.0*)
 434                         AFS_PARAM_COMMON=param.nbsd20.h
 435                         AFS_SYSNAME="ppc_nbsd20"
 436                         ;;
 437                 i?86-*-netbsd*1.6*)
 438                         AFS_PARAM_COMMON=param.nbsd16.h
 439                         AFS_SYSNAME="i386_nbsd16"
 440                         ;;
 441                 alpha-*-netbsd*1.6*)
 442                         AFS_PARAM_COMMON=param.nbsd16.h
 443                         AFS_SYSNAME="alpha_nbsd16"
 444                         ;;
 445                 powerpc-*-netbsd*1.6*)
 446                         AFS_PARAM_COMMON=param.nbsd16.h
 447                         AFS_SYSNAME="ppc_nbsd16"
 448                         ;;
 449                 hppa*-hp-hpux11.0*)
 450                         AFS_SYSNAME="hp_ux110"
 451                         ;;
 452                 hppa*-hp-hpux11.11)
 453                         AFS_SYSNAME="hp_ux11i"
 454                         ;;
 455                 ia64-hp-hpux11.22)
 456                         AFS_SYSNAME="ia64_hpux1122"
 457                         ;;
 458                 ia64-hp-hpux*)
 459                         AFS_SYSNAME="ia64_hpux1123"
 460                         ;;
 461                 hppa*-hp-hpux10*)
 462                         AFS_SYSNAME="hp_ux102"
 463                         ;;
 464                 powerpc-apple-darwin1.2*)
 465                         AFS_SYSNAME="ppc_darwin_12"
 466                         ;;
 467                 powerpc-apple-darwin1.3*)
 468                         AFS_SYSNAME="ppc_darwin_13"
 469                         ;;
 470                 powerpc-apple-darwin1.4*)
 471                         AFS_SYSNAME="ppc_darwin_14"
 472                         ;;
 473                 powerpc-apple-darwin5.1*)
 474                         AFS_SYSNAME="ppc_darwin_14"
 475                         ;;
 476                 powerpc-apple-darwin5.2*)
 477                         AFS_SYSNAME="ppc_darwin_14"
 478                         ;;
 479                 powerpc-apple-darwin5.3*)
 480                         AFS_SYSNAME="ppc_darwin_14"
 481                         ;;
 482                 powerpc-apple-darwin5.4*)
 483                         AFS_SYSNAME="ppc_darwin_14"
 484                         ;;
 485                 powerpc-apple-darwin5.5*)
 486                         AFS_SYSNAME="ppc_darwin_14"
 487                         ;;
 488                 powerpc-apple-darwin6.0*)
 489                         AFS_SYSNAME="ppc_darwin_60"
 490                         ;;
 491                 powerpc-apple-darwin6.1*)
 492                         AFS_SYSNAME="ppc_darwin_60"
 493                         ;;
 494                 powerpc-apple-darwin6.2*)
 495                         AFS_SYSNAME="ppc_darwin_60"
 496                         ;;
 497                 powerpc-apple-darwin6.3*)
 498                         AFS_SYSNAME="ppc_darwin_60"
 499                         ;;
 500                 powerpc-apple-darwin6.4*)
 501                         AFS_SYSNAME="ppc_darwin_60"
 502                         ;;
 503                 powerpc-apple-darwin6.5*)
 504                         AFS_SYSNAME="ppc_darwin_60"
 505                         ;;
 506                 powerpc-apple-darwin7.0*)
 507                         AFS_SYSNAME="ppc_darwin_70"
 508                         ;;
 509                 powerpc-apple-darwin7.1*)
 510                         AFS_SYSNAME="ppc_darwin_70"
 511                         ;;
 512                 powerpc-apple-darwin7.2*)
 513                         AFS_SYSNAME="ppc_darwin_70"
 514                         ;;
 515                 powerpc-apple-darwin7.3*)
 516                         AFS_SYSNAME="ppc_darwin_70"
 517                         ;;
 518                 sparc-sun-solaris2.5*)
 519                         AFS_SYSNAME="sun4x_55"
 520                         enable_login="yes"
 521                         ;;
 522                 sparc-sun-solaris2.6)
 523                         AFS_SYSNAME="sun4x_56"
 524                         ;;
 525                 sparc-sun-solaris2.7)
 526                         AFS_SYSNAME="sun4x_57"
 527                         ;;
 528                 sparc-sun-solaris2.8)
 529                         AFS_SYSNAME="sun4x_58"
 530                         ;;
 531                 sparc-sun-solaris2.9)
 532                         AFS_SYSNAME="sun4x_59"
 533                         ;;
 534                 sparc-sun-sunos4*)
 535                         AFS_SYSNAME="sun4_413"
 536                         enable_login="yes"
 537                         ;;
 538                 i386-pc-solaris2.7)
 539                         AFS_SYSNAME="sunx86_57"
 540                         ;;
 541                 i386-pc-solaris2.8)
 542                         AFS_SYSNAME="sunx86_58"
 543                         ;;
 544                 i386-pc-solaris2.9)
 545                         AFS_SYSNAME="sunx86_59"
 546                         ;;
 547                 alpha*-dec-osf4.0*)
 548                         AFS_SYSNAME="alpha_dux40"
 549                         ;;
 550                 alpha*-dec-osf5.0*)
 551                         AFS_SYSNAME="alpha_dux50"
 552                         ;;
 553                 alpha*-dec-osf5.1*)
 554                         AFS_SYSNAME="alpha_dux51"
 555                         ;;
 556                 mips-sgi-irix6.5)
 557                         AFS_SYSNAME="sgi_65"
 558                         ;;
 559                 ia64-*-linux*)
 560                         AFS_SYSNAME="ia64_linuxXX"
 561                         ;;
 562                 powerpc-*-linux*)
 563                         AFS_SYSNAME="ppc_linuxXX"
 564                         ;;
 565                 powerpc64-*-linux*)
 566                         AFS_SYSNAME="ppc64_linuxXX"
 567                         ;;
 568                 alpha*-linux*)
 569                         AFS_SYSNAME="alpha_linux_XX"
 570                         ;;
 571                 s390-*-linux*)
 572                         AFS_SYSNAME="s390_linuxXX"
 573                         ;;
 574                 sparc-*-linux*)
 575                         AFS_SYSNAME="sparc_linuxXX"
 576                         ;;
 577                 sparc64-*-linux*)
 578                         AFS_SYSNAME="sparc64_linuxXX"
 579                         ;;
 580                 i?86-*-linux*)
 581                         AFS_SYSNAME="i386_linuxXX"
 582                         ;;
 583                 parisc-*-linux-gnu)
 584                         AFS_SYSNAME="parisc_linuxXX"
 585                         enable_pam="no"
 586                         ;;
 587                 power*-ibm-aix4.2*)
 588                         AFS_SYSNAME="rs_aix42"
 589                         ;;
 590                 power*-ibm-aix4.3*)
 591                         AFS_SYSNAME="rs_aix42"
 592                         ;;
 593                 power*-ibm-aix5.1*)
 594                         AFS_SYSNAME="rs_aix51"
 595                         ;;
 596                 power*-ibm-aix5.2*)
 597                         AFS_SYSNAME="rs_aix52"
 598                         ;;
 599                 x86_64-*-linux-gnu)
 600                         AFS_SYSNAME="amd64_linuxXX"
 601                         enable_pam="no"
 602                         ;;
 603                 *)
 604                         AC_MSG_ERROR(An AFS sysname is required)
 605                         exit 1
 606                         ;;
 607         esac
 608         case $AFS_SYSNAME in
 609                 *_linux*)
 610                         AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $[]1 $[]2}'`
 611                         if test "x${AFS_SYSKVERS}" = "x"; then
 612                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 613                         fi
 614                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 615                         AFS_SYSNAME="$_AFS_SYSNAME"
 616                         save_CPPFLAGS="$CPPFLAGS"
 617                         CPPFLAGS="-I${LINUX_KERNEL_PATH}/include $CPPFLAGS"
 618                         AC_TRY_COMPILE(
 619                          [#include <linux/autoconf.h>],
 620                          [#ifndef CONFIG_USERMODE
 621                           #error not UML
 622                           #endif],
 623                          ac_cv_linux_is_uml=yes,)
 624                         if test "${ac_cv_linux_is_uml}" = yes; then
 625                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 626                         fi
 627                         CPPFLAGS="$save_CPPFLAGS"
 628                         AFS_SYSNAME="$_AFS_SYSNAME"
 629                         ;;
 630         esac
 631         AC_MSG_RESULT($AFS_SYSNAME)
 632 fi
 633
 634 # KDUMP64 defaults to KDUMP for systems without a separate kdump64
 635 KDUMP64='${KDUMP}'
 636 KDUMP=kdump
 637 case $AFS_SYSNAME in
 638         sgi_6?)
 639                 KDUMP=kdump.IP20;;
 640         sun4x_5[[789]] | hp_ux11*)
 641                 KDUMP=kdump32
 642                 KDUMP64=kdump64;;
 643         *linux*)
 644                 KDUMP='kdump-${LINUX_VERSION}';;
 645 esac
 646 AC_SUBST(KDUMP)
 647 AC_SUBST(KDUMP64)
 648
 649 case $AFS_SYSNAME in
 650         *_darwin*)
 651                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 652                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 653                 dnl the test below fails on darwin, even if the CPPFLAGS below
 654                 dnl are added. the headers from Kernel.Framework must be used
 655                 dnl when KERNEL is defined.
 656
 657                 dnl really, such a thing isn't guaranteed to work on any
 658                 dnl platform until the kernel cflags from MakefileProto are
 659                 dnl known to configure
 660                 AC_DEFINE(HAVE_STRUCT_BUF, 1, [define if you have a struct buf])
 661                 ;;
 662         *)
 663 AC_MSG_CHECKING(for definition of struct buf)
 664 dnl save_CPPFLAGS="$CPPFLAGS"
 665 dnl CPPFLAGS="$CPPFLAGS -DKERNEL -D_KERNEL -D__KERNEL -D__KERNEL__"
 666 AC_CACHE_VAL(ac_cv_have_struct_buf, [
 667         ac_cv_have_struct_buf=no
 668         AC_TRY_COMPILE(
 669                 [#include <sys/buf.h>],
 670                 [struct buf x;
 671                 printf("%d\n", sizeof(x));],
 672                 ac_cv_have_struct_buf=yes,)
 673         ]
 674 )
 675 dnl CPPFLAGS="$save_CPPFLAGS"
 676 AC_MSG_RESULT($ac_cv_have_struct_buf)
 677 if test "$ac_cv_have_struct_buf" = yes; then
 678         AC_DEFINE(HAVE_STRUCT_BUF, 1, [define if you have a struct buf])
 679 fi
 680 ;;
 681 esac
 682
 683
 684 AC_CACHE_VAL(ac_cv_sockaddr_len,
 685 [
 686 AC_MSG_CHECKING([if struct sockaddr has sa_len field])
 687 AC_TRY_COMPILE( [#include <sys/types.h>
 688 #include <sys/socket.h>],
 689 [struct sockaddr *a;
 690 a->sa_len=0;], ac_cv_sockaddr_len=yes, ac_cv_sockaddr_len=no)
 691 AC_MSG_RESULT($ac_cv_sockaddr_len)])
 692 if test "$ac_cv_sockaddr_len" = "yes"; then
 693    AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1, [define if you struct sockaddr sa_len])
 694 fi
 695 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
 696         echo Skipping library tests because they confuse Irix.
 697 else
 698   AC_CHECK_FUNCS(socket)
 699
 700   if test "$ac_cv_func_socket" = no; then
 701     for lib in socket inet; do
 702         if test "$HAVE_SOCKET" != 1; then
 703                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET, 1, [define if you have socket]))
 704         fi
 705     done
 706   fi
 707
 708   AC_CHECK_FUNCS(connect)
 709
 710   if test "$ac_cv_func_connect" = no; then
 711     for lib in nsl; do
 712         if test "$HAVE_CONNECT" != 1; then
 713                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT, 1, [define if you have connect]))
 714         fi
 715     done
 716   fi
 717
 718   AC_CHECK_FUNCS(gethostbyname)
 719   if test "$ac_cv_func_gethostbyname" = no; then
 720         for lib in dns nsl resolv; do
 721           if test "$HAVE_GETHOSTBYNAME" != 1; then
 722             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME, 1, [define if you have gethostbyname]))
 723           fi
 724         done
 725   fi
 726
 727   dnl darwin wants it, aix hates it
 728   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
 729   AC_TRY_COMPILE([
 730   #include <stdlib.h>
 731   #include <stdio.h>
 732   #include <sys/types.h>
 733   #include <sys/socket.h>
 734   #include <netinet/in.h>
 735   #include <arpa/inet.h>
 736   #include <arpa/nameser.h>
 737   #include <arpa/nameser_compat.h>
 738   #include <resolv.h>
 739   ], [static int i; i = 0;],
 740   [AC_MSG_RESULT(yes)
 741    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H)],
 742   [AC_MSG_RESULT(no)
 743    ])
 744
 745   openafs_save_libs="$LIBS"
 746   AC_MSG_CHECKING([for res_search])
 747   AC_FUNC_RES_SEARCH
 748
 749   if test "$ac_cv_func_res_search" = no; then
 750       for lib in dns nsl resolv; do
 751         if test "$ac_cv_func_res_search" != yes; then
 752           LIBS="-l$lib $LIBS"
 753           AC_FUNC_RES_SEARCH
 754           LIBS="$openafs_save_libs"
 755         fi
 756       done
 757       if test "$ac_cv_func_res_search" = yes; then
 758         LIB_res_search="-l$lib"
 759         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
 760         AC_MSG_RESULT([yes, in lib$lib])
 761       else
 762         AC_MSG_RESULT(no)
 763       fi
 764   else
 765     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
 766     AC_MSG_RESULT(yes)
 767   fi
 768
 769 fi
 770
 771 PTHREAD_LIBS=error
 772 AC_CHECK_LIB(pthread, pthread_attr_init,
 773              PTHREAD_LIBS="-lpthread")
 774 if test "x$PTHREAD_LIBS" = xerror; then
 775         AC_CHECK_LIB(pthreads, pthread_attr_init,
 776                 PTHREAD_LIBS="-lpthreads")
 777 fi
 778 if test "x$PTHREAD_LIBS" = xerror; then
 779         AC_CHECK_LIB(c_r, pthread_attr_init,
 780                 PTHREAD_LIBS="-lc_r")
 781 fi
 782 if test "x$PTHREAD_LIBS" = xerror; then
 783         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
 784 fi
 785 if test "x$PTHREAD_LIBS" = xerror; then
 786         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
 787 fi
 788 AC_SUBST(PTHREAD_LIBS)
 789
 790 WITH_OBSOLETE=NO
 791 if test "$enable_obsolete" = "yes"; then
 792         WITH_OBSOLETE=YES
 793 fi
 794
 795 WITH_INSECURE=NO
 796 if test "$enable_insecure" = "yes"; then
 797         WITH_INSECURE=YES
 798 fi
 799
 800 if test "x$with_bsd_kernel_headers" != "x"; then
 801         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
 802 else
 803         BSD_KERNEL_PATH="/usr/src/sys"
 804 fi
 805
 806 if test "x$with_bsd_kernel_build" != "x"; then
 807         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
 808 else
 809         case $AFS_SYSNAME in
 810                 i386_fbsd_4?)
 811                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/compile/GENERIC"
 812                         ;;
 813                 i386_fbsd_5?)
 814                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/i386/compile/GENERIC"
 815                         ;;
 816         esac
 817 fi
 818
 819 # Fast restart
 820 if test "$enable_supergroups" = "yes"; then
 821         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
 822 fi
 823
 824 if test "$enable_fast_restart" = "yes"; then
 825         AC_DEFINE(FAST_RESTART, 1, [define if you want to have fast restart])
 826 fi
 827
 828 if test "$enable_bitmap_later" = "yes"; then
 829         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
 830 fi
 831
 832 if test "$enable_full_vos_listvol_switch" = "yes"; then
 833         AC_DEFINE(FULL_LISTVOL_SWITCH, 1, [define if you want to want listvol switch])
 834 fi
 835
 836 if test "$enable_bos_restricted_mode" = "yes"; then
 837         AC_DEFINE(BOS_RESTRICTED_MODE, 1, [define if you want to want bos restricted mode])
 838 fi
 839
 840 if test "$enable_bos_new_config" = "yes"; then
 841         AC_DEFINE(BOS_NEW_CONFIG, 1, [define if you want to enable automatic renaming of BosConfig.new to BosConfig at startup])
 842 fi
 843
 844 if test "$enable_largefile_fileserver" = "yes"; then
 845         AC_DEFINE(AFS_LARGEFILE_ENV, 1, [define if you want large file fileserver])
 846 fi
 847
 848 if test "$enable_namei_fileserver" = "yes"; then
 849         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
 850 fi
 851
 852 if test "$enable_afsdb" = "yes"; then
 853         LIB_AFSDB="$LIB_res_search"
 854         AC_DEFINE(AFS_AFSDB_ENV, 1, [define if you want to want search afsdb rr])
 855 fi
 856
 857 dnl check for tivoli
 858 AC_MSG_CHECKING(for tivoli tsm butc support)
 859 XBSA_CFLAGS=""
 860 if test "$enable_tivoli_tsm" = "yes"; then
 861         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
 862         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
 863
 864         if test -e "$XBSADIR1/xbsa.h"; then
 865                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
 866                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 867         elif test -e "$XBSADIR2/xbsa.h"; then
 868                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
 869                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 870         else
 871                 AC_MSG_RESULT([no, missing xbsa.h header file])
 872         fi
 873 else
 874         AC_MSG_RESULT([no])
 875 fi
 876 AC_SUBST(XBSA_CFLAGS)
 877
 878 dnl checks for header files.
 879 AC_HEADER_STDC
 880 AC_HEADER_SYS_WAIT
 881 AC_HEADER_DIRENT
 882 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
 883 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
 884 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h sys/fstyp.h)
 885 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
 886 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h sys/user.h)
 887 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h ucontext.h regex.h)
 888
 889 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
 890         HAVE_PAM="yes"
 891 else
 892         HAVE_PAM="no"
 893 fi
 894 AC_SUBST(HAVE_PAM)
 895
 896 if test "$enable_login" = yes; then
 897         BUILD_LOGIN="yes"
 898 else
 899         BUILD_LOGIN="no"
 900 fi
 901 AC_SUBST(BUILD_LOGIN)
 902
 903 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf strlcat strlcpy re_comp re_exec)
 904 AC_CHECK_FUNCS(setprogname getprogname sigaction mkstemp vsnprintf strerror)
 905
 906 AC_CHECK_FUNCS(regcomp regexec regerror)
 907 AC_MSG_CHECKING([for POSIX regex library])
 908 if test "$ac_cv_header_regex_h" = "yes" && \
 909         test "$ac_cv_func_regcomp" = "yes" && \
 910         test "$ac_cv_func_regexec" = "yes" && \
 911         test "$ac_cv_func_regerror" = "yes"; then
 912     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
 913     AC_MSG_RESULT(yes)
 914 else
 915     AC_MSG_RESULT(no)
 916 fi
 917
 918 AC_CHECK_TYPE(ssize_t, int)
 919 AC_SIZEOF_TYPE(long)
 920
 921 AC_CHECK_FUNCS(timegm)
 922
 923 dnl Directory PATH handling
 924 if test "x$enable_transarc_paths" = "xyes"  ; then
 925     afsconfdir=${afsconfdir=/usr/afs/etc}
 926     viceetcdir=${viceetcdir=/usr/vice/etc}
 927     afskerneldir=${afskerneldir=${viceetcdir}}
 928     afssrvbindir=${afssrvbindir=/usr/afs/bin}
 929     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
 930     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
 931     afsdbdir=${afsdbdir=/usr/afs/db}
 932     afslogsdir=${afslogsdir=/usr/afs/logs}
 933     afslocaldir=${afslocaldir=/usr/afs/local}
 934     afsbackupdir=${afsbackupdir=/usr/afs/backup}
 935     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
 936 else
 937     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
 938     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
 939     afskerneldir=${afskerneldir='${libdir}/openafs'}
 940     afssrvbindir=${afssrvbindir='${bindir}'}
 941     afssrvsbindir=${afssrvsbindir='${sbindir}'}
 942     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
 943     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
 944     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
 945     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
 946     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
 947     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
 948 fi
 949 AC_SUBST(afsconfdir)
 950 AC_SUBST(viceetcdir)
 951 AC_SUBST(afskerneldir)
 952 AC_SUBST(afssrvbindir)
 953 AC_SUBST(afssrvsbindir)
 954 AC_SUBST(afssrvlibexecdir)
 955 AC_SUBST(afsdbdir)
 956 AC_SUBST(afslogsdir)
 957 AC_SUBST(afslocaldir)
 958 AC_SUBST(afsbackupdir)
 959 AC_SUBST(afsbosconfigdir)
 960
 961 if test "x$enable_kernel_module" = "xyes"; then
 962 ENABLE_KERNEL_MODULE=libafs
 963 fi
 964
 965 AC_SUBST(AFS_SYSNAME)
 966 AC_SUBST(AFS_PARAM_COMMON)
 967 AC_SUBST(ENABLE_KERNEL_MODULE)
 968 AC_SUBST(LIB_AFSDB)
 969 AC_SUBST(LINUX_KERNEL_PATH)
 970 AC_SUBST(BSD_KERNEL_PATH)
 971 AC_SUBST(BSD_KERNEL_BUILD)
 972 AC_SUBST(LINUX_VERSION)
 973 AC_SUBST(MKAFS_OSTYPE)
 974 AC_SUBST(TOP_OBJDIR)
 975 AC_SUBST(TOP_SRCDIR)
 976 AC_SUBST(TOP_INCDIR)
 977 AC_SUBST(TOP_LIBDIR)
 978 AC_SUBST(DEST)
 979 AC_SUBST(WITH_OBSOLETE)
 980 AC_SUBST(WITH_INSECURE)
 981 AC_SUBST(DARWIN_INFOFILE)
 982 AC_SUBST(IRIX_BUILD_IP35)
 983
 984 OPENAFS_OSCONF
 985
 986 TOP_SRCDIR="${srcdir}/src"
 987 dnl
 988 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
 989 dnl
 990 case $TOP_SRCDIR in
 991         /*)
 992                 ;;
 993         *)
 994                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
 995                 ;;
 996 esac
 997
 998 TOP_OBJDIR="${SRCDIR_PARENT}"
 999 TOP_INCDIR="${SRCDIR_PARENT}/include"
1000 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1001 if test "${DEST}x" = "x"; then
1002         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1003 fi
1004
1005 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1006 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1007 AC_SUBST(HELPER_SPLINT)
1008 AC_SUBST(HELPER_SPLINTCFG)
1009
1010
1011 ])