acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #   define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 #define _FILE_OFFSET_BITS 64
  48 #define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 #include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
  76
  77 dnl General feature options.
  78 AC_ARG_ENABLE([pam],
  79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
  80     ,
  81     [enable_pam="yes"])
  82 AC_ARG_ENABLE([gtx],
  83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
  84 AC_ARG_ENABLE([uss],
  85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
  86 AC_ARG_ENABLE([namei-fileserver],
  87     [AS_HELP_STRING([--enable-namei-fileserver],
  88         [force compilation of namei fileserver in preference to inode
  89          fileserver])],
  90     ,
  91     [enable_namei_fileserver="default"])
  92 AC_ARG_ENABLE([supergroups],
  93     [AS_HELP_STRING([--enable-supergroups],
  94         [enable support for nested pts groups])],
  95     ,
  96     [enable_supergroups="no"])
  97 AC_ARG_ENABLE([bitmap-later],
  98     [AS_HELP_STRING([--enable-bitmap-later],
  99         [enable fast startup of file server by not reading bitmap till
 100          needed])],
 101     ,
 102     [enable_bitmap_later="no"])
 103 AC_ARG_ENABLE([unix-sockets],
 104     [AS_HELP_STRING([--disable-unix-sockets],
 105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 106     ,
 107     [enable_unix_sockets="yes"])
 108 AC_ARG_ENABLE([tivoli-tsm],
 109     [AS_HELP_STRING([--enable-tivoli-tsm],
 110         [enable use of the Tivoli TSM API libraries for butc support])],
 111     ,
 112     [enable_tivoli_tsm="no"])
 113 AC_ARG_ENABLE([pthreaded-ubik],
 114     [AS_HELP_STRING([--enable-pthreaded-ubik],
 115         [enable installation of pthreaded ubik applications (defaults to
 116          disabled)])],
 117     ,
 118     [enable_pthreaded_ubik="no"])
 119
 120 dnl Kernel module build options.
 121 AC_ARG_WITH([linux-kernel-headers],
 122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 123         [use the kernel headers found at path (optional, defaults to
 124          /usr/src/linux-2.4, then /usr/src/linux)])])
 125 AC_ARG_WITH([linux-kernel-build],
 126     [AS_HELP_STRING([--with-linux-kernel-build=path],
 127         [use the kernel build found at path(optional, defaults to
 128         /usr/src/linux-2.4, then /usr/src/linux)])])
 129 AC_ARG_WITH([bsd-kernel-headers],
 130     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 131         [use the kernel headers found at path (optional, defaults to
 132          /usr/src/sys)])])
 133 AC_ARG_WITH([bsd-kernel-build],
 134     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 135         [use the kernel build found at path (optional, defaults to
 136          KSRC/i386/compile/GENERIC)])])
 137 AC_ARG_WITH([linux-kernel-packaging],
 138     [AS_HELP_STRING([--with-linux-kernel-packaging],
 139         [use standard naming conventions to aid Linux kernel build packaging
 140          (disables MPS, sets the kernel module name to openafs.ko, and
 141          installs kernel modules into the standard Linux location)])],
 142     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
 143      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
 144     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
 145 AC_ARG_ENABLE([kernel-module],
 146     [AS_HELP_STRING([--disable-kernel-module],
 147         [disable compilation of the kernel module (defaults to enabled)])],
 148     ,
 149     [enable_kernel_module="yes"])
 150 AC_ARG_ENABLE([redhat-buildsys],
 151     [AS_HELP_STRING([--enable-redhat-buildsys],
 152         [enable compilation of the redhat build system kernel (defaults to
 153          disabled)])],
 154     ,
 155     [enable_redhat_buildsys="no"])
 156
 157 dnl Installation locations.
 158 AC_ARG_ENABLE([transarc-paths],
 159     [AS_HELP_STRING([--enable-transarc-paths],
 160         [use Transarc style paths like /usr/afs and /usr/vice])],
 161     ,
 162     [enable_transarc_paths="no"])
 163
 164 dnl Optimization and debugging flags.
 165 AC_ARG_ENABLE([strip-binaries],
 166     [AS_HELP_STRING([--disable-strip-binaries],
 167         [disable stripping of symbol information from binaries (defaults to
 168          enabled)])],
 169     ,
 170     [enable_strip_binaries="maybe"])
 171 AC_ARG_ENABLE([debug],
 172     [AS_HELP_STRING([--enable-debug],
 173         [enable compilation of the user space code with debugging information
 174          (defaults to disabled)])],
 175     ,
 176     [enable_debug="no"])
 177 AC_ARG_ENABLE([optimize],
 178     [AS_HELP_STRING([--disable-optimize],
 179         [disable optimization for compilation of the user space code (defaults
 180          to enabled)])],
 181     ,
 182     [enable_optimize="yes"])
 183 AC_ARG_ENABLE([warnings],
 184     [AS_HELP_STRING([--enable-warnings],
 185         [enable compilation warnings when building with gcc (defaults to
 186          disabled)])],
 187     ,
 188     [enable_warnings="no"])
 189 AC_ARG_ENABLE([checking],
 190     [AS_HELP_STRING([--enable-checking],
 191         [turn compilation warnings into errors when building with gcc (defaults
 192          to disabled)])],
 193     [enable_checking="$enableval"],
 194     [enable_checking="no"])
 195 AC_ARG_ENABLE([debug-kernel],
 196     [AS_HELP_STRING([--enable-debug-kernel],
 197         [enable compilation of the kernel module with debugging information
 198          (defaults to disabled)])],
 199     ,
 200     [enable_debug_kernel="no"])
 201 AC_ARG_ENABLE([optimize-kernel],
 202     [AS_HELP_STRING([--disable-optimize-kernel],
 203         [disable compilation of the kernel module with optimization (defaults
 204          based on platform)])],
 205     ,
 206     [enable_optimize_kernel=""])
 207 AC_ARG_ENABLE([debug-lwp],
 208     [AS_HELP_STRING([--enable-debug-lwp],
 209         [enable compilation of the LWP code with debugging information
 210          (defaults to disabled)])],
 211     ,
 212     [enable_debug_lwp="no"])
 213 AC_ARG_ENABLE([optimize-lwp],
 214     [AS_HELP_STRING([--disable-optimize-lwp],
 215         [disable optimization for compilation of the LWP code (defaults to
 216          enabled)])],
 217     ,
 218     [enable_optimize_lwp="yes"])
 219 AC_ARG_ENABLE([debug-pam],
 220     [AS_HELP_STRING([--enable-debug-pam],
 221         [enable compilation of the PAM code with debugging information
 222          (defaults to disabled)])],
 223     ,
 224     [enable_debug_pam="no"])
 225 AC_ARG_ENABLE([optimize-pam],
 226     [AS_HELP_STRING([--disable-optimize-pam],
 227         [disable optimization for compilation of the PAM code (defaults to
 228          enabled)])],
 229     ,
 230     [enable_optimize_pam="yes"])
 231 AC_ARG_ENABLE([linux-syscall-probing],
 232     [AS_HELP_STRING([--enable-linux-syscall-probing],
 233         [enable Linux syscall probing (defaults to autodetect)])],
 234     ,
 235     [enable_linux_syscall_probing="maybe"])
 236 AC_ARG_WITH([crosstools-dir],
 237     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
 238
 239 AC_ARG_WITH([xslt-processor],
 240         AS_HELP_STRING([--with-xslt-processor=ARG],
 241         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 242         [XSLTPROC="$withval"],
 243         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
 244
 245 AC_ARG_WITH([html-xsl],
 246         AS_HELP_STRING([--with-html-xsl],
 247         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 248         [HTML_XSL="$withval"],
 249         [HTML_XSL="html/chunk.xsl"])
 250
 251 AC_ARG_WITH([docbook2pdf],
 252         AS_HELP_STRING([--with-docbook2pdf=ARG],
 253         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 254         [DOCBOOK2PDF="$withval"],
 255         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
 256
 257 AC_ARG_WITH([docbook-stylesheets],
 258         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 259         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 260         [DOCBOOK_STYLESHEETS="$withval"],
 261         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
 262         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
 263                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 264         fi)
 265
 266 enable_login="no"
 267
 268 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 269 dnl documentation build.
 270 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 271
 272 dnl weird ass systems
 273 dnl AC_AIX
 274 AC_ISC_POSIX
 275 dnl AC_MINIX
 276
 277 dnl Various compiler setup.
 278 AC_TYPE_PID_T
 279 AC_TYPE_SIZE_T
 280
 281 dnl Checks for programs.
 282 AC_PROG_INSTALL
 283 AC_PROG_LN_S
 284 AC_PROG_RANLIB
 285 AC_PROG_YACC
 286 AM_PROG_LEX
 287 dnl if we are flex, be lex-compatible
 288 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 289
 290 OPENAFS_FORCE_ABS_INSTALL
 291 OPENAFS_CHECK_BIGENDIAN
 292 OPENAFS_PRINTF_TAKES_Z_LEN
 293
 294 AC_MSG_CHECKING(your OS)
 295 system=$host
 296 case $system in
 297         *-linux*)
 298
 299                 MKAFS_OSTYPE=LINUX
 300                 if test "x$enable_redhat_buildsys" = "xyes"; then
 301                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 302                 fi
 303                 if test "x$enable_kernel_module" = "xyes"; then
 304                  if test "x$with_linux_kernel_headers" != "x"; then
 305                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 306                  else
 307                    LINUX_KERNEL_PATH="/lib/modules/`uname -r`/source"
 308                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 309                      LINUX_KERNEL_PATH="/lib/modules/`uname -r`/build"
 310                    fi
 311                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 312                      LINUX_KERNEL_PATH="/usr/src/linux-2.4"
 313                    fi
 314                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 315                      LINUX_KERNEL_PATH="/usr/src/linux"
 316                    fi
 317                  fi
 318                  if test "x$with_linux_kernel_build" != "x"; then
 319                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 320                  else
 321                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 322                  fi
 323                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 324                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 325                    LINUX_VERSION="$linux_kvers"
 326                  else
 327                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 328                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 329                      LINUX_VERSION="$linux_kvers"
 330                    else
 331                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 332                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 333                        if test "x$linux_kvers" = "x"; then
 334                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 335                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 336                            if test "x$linux_kvers" = "x"; then
 337                              AC_MSG_ERROR(Linux headers lack version definition [2])
 338                              exit 1
 339                            else
 340                              LINUX_VERSION="$linux_kvers"
 341                            fi
 342                          else
 343                            AC_MSG_ERROR(Linux headers lack version definition)
 344                            exit 1
 345                          fi
 346                        else
 347                          LINUX_VERSION="$linux_kvers"
 348                        fi
 349                      else
 350                        enable_kernel_module="no"
 351                      fi
 352                    fi
 353                  fi
 354                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 355                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 356                      enable_kernel_module="no"
 357                  fi
 358                  if test "x$enable_kernel_module" = "xno"; then
 359                   if test "x$with_linux_kernel_headers" != "x"; then
 360                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 361                    exit 1
 362                   else
 363                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 364                   fi
 365                  fi
 366                  dnl do we need to determine SUBARCH from autoconf.h
 367                  SUBARCH=default
 368                 fi
 369                 AC_MSG_RESULT(linux)
 370                 if test "x$enable_kernel_module" = "xyes"; then
 371                  case "$LINUX_VERSION" in
 372                   2.2.*) AFS_SYSKVERS=22 ;;
 373                   2.4.*) AFS_SYSKVERS=24 ;;
 374                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
 375                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 376                  esac
 377                 fi
 378                 ;;
 379         *-solaris*)
 380                 MKAFS_OSTYPE=SOLARIS
 381                 AC_MSG_RESULT(sun4)
 382                 AC_PATH_PROG(SOLARISCC, [cc], ,
 383                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 384                 if test "x$SOLARISCC" = "x" ; then
 385                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 386                 fi
 387                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 388                 SOLARIS_FS_HAS_FS_ROLLED
 389                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 390                 ;;
 391         *-sunos*)
 392                 MKAFS_OSTYPE=SUNOS
 393                 enable_kernel_module=no
 394                 AC_MSG_RESULT(sun4)
 395                 ;;
 396         *-hpux*)
 397                 MKAFS_OSTYPE=HPUX
 398                 AC_MSG_RESULT(hp_ux)
 399                 if test -f "/usr/old/usr/include/ndir.h"; then
 400                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 401                 fi
 402                 ;;
 403         *-irix*)
 404                 if test -d /usr/include/sys/SN/SN1; then
 405                  IRIX_BUILD_IP35="IP35"
 406                 fi
 407                 MKAFS_OSTYPE=IRIX
 408                 AC_MSG_RESULT(sgi)
 409                 ;;
 410         *-aix*)
 411                 MKAFS_OSTYPE=AIX
 412                 AC_MSG_RESULT(rs_aix)
 413                 ;;
 414         arm-*-darwin*)
 415                 MKAFS_OSTYPE=DARWIN
 416                 AC_MSG_RESULT(arm_darwin)
 417                 ;;
 418         powerpc-*-darwin*)
 419                 MKAFS_OSTYPE=DARWIN
 420                 AC_MSG_RESULT(ppc_darwin)
 421                 ;;
 422         i386-*-darwin*)
 423                 MKAFS_OSTYPE=DARWIN
 424                 AC_MSG_RESULT(x86_darwin)
 425                 ;;
 426         x86_64-*-darwin*)
 427                 MKAFS_OSTYPE=DARWIN
 428                 AC_MSG_RESULT(x86_darwin)
 429                 ;;
 430         i386-*-freebsd*)
 431                 MKAFS_OSTYPE=FBSD
 432                 AC_MSG_RESULT(i386_fbsd)
 433                 ;;
 434         x86_64-*-freebsd*)
 435                 MKAFS_OSTYPE=FBSD
 436                 AC_MSG_RESULT(amd64_fbsd)
 437                 ;;
 438         *-netbsd*)
 439                 MKAFS_OSTYPE=NBSD
 440                 AC_MSG_RESULT(nbsd)
 441                 ;;
 442         x86_64-*-openbsd*)
 443                 MKAFS_OSTYPE=OBSD
 444                 AC_MSG_RESULT(amd64_obsd)
 445                 ;;
 446         i386-*-openbsd*)
 447                 MKAFS_OSTYPE=OBSD
 448                 AC_MSG_RESULT(i386_obsd)
 449                 ;;
 450         *-dragonfly*)
 451                 MKAFS_OSTYPE=DFBSD
 452                 AC_MSG_RESULT(i386_dfbsd)
 453                 ;;
 454         *)
 455                 AC_MSG_RESULT($system)
 456                 ;;
 457 esac
 458
 459 if test "x$with_afs_sysname" != "x"; then
 460         AFS_SYSNAME="$with_afs_sysname"
 461 else
 462         AC_MSG_CHECKING(your AFS sysname)
 463         case $host in
 464                 i?86-*-openbsd?.?)
 465                         v=${host#*openbsd}
 466                         vM=${v%.*}
 467                         vm=${v#*.}
 468                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 469                         ;;
 470                 sparc64-*-openbsd?.?)
 471                         v=${host#*openbsd}
 472                         vM=${v%.*}
 473                         vm=${v#*.}
 474                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 475                         ;;
 476                 x86_64-*-openbsd?.?)
 477                         v=${host#*openbsd}
 478                         vM=${v%.*}
 479                         vm=${v#*.}
 480                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 481                         ;;
 482                 i?86-*-freebsd*.*)
 483                         v=${host#*freebsd}
 484                         vM=${v%.*}
 485                         vm=${v#*.}
 486                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 487                         ;;
 488                 x86_64-*-freebsd*.*)
 489                         v=${host#*freebsd}
 490                         vM=${v%.*}
 491                         vm=${v#*.}
 492                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 493                         ;;
 494                 i386-*-dragonfly?.*)
 495                         v=${host#*dragonfly}
 496                         vM=${v%.*}
 497                         vm=${v#*.}
 498                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 499                         ;;
 500                 i?86-*-netbsd*1.6[[M-Z]]*)
 501                         AFS_SYSNAME="i386_nbsd20"
 502                         ;;
 503                 powerpc-*-netbsd*1.6[[M-Z]]*)
 504                         AFS_SYSNAME="ppc_nbsd20"
 505                         ;;
 506                 *-*-netbsd*)
 507                         arch=${host%%-unknown*}
 508                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 509                                                -e 's/powerpc/ppc/g')
 510                         v=${host#*netbsd}
 511                         v=${v#*aout}
 512                         v=${v#*ecoff}
 513                         v=${v#*elf}
 514                         vM=${v%%.*}
 515                         vM=${vM%.*}
 516                         v=${v#*.}
 517                         vm=${v%%.*}
 518                         vm=${vm%.*}
 519                         vm=${vm%%[[_A-Z]]*}
 520                         if test $vm -eq 99 ; then
 521                                 vM=$((vM+1))
 522                         fi
 523                         if test $vM -gt 1 ; then
 524                                 vm=0
 525                         fi
 526                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 527                         ;;
 528                 hppa*-hp-hpux11.0*)
 529                         AFS_SYSNAME="hp_ux110"
 530                         ;;
 531                 hppa*-hp-hpux11.11)
 532                         AFS_SYSNAME="hp_ux11i"
 533                         ;;
 534                 hppa*-hp-hpux11.23)
 535                         AFS_SYSNAME="hp_ux1123"
 536                         ;;
 537                 ia64-hp-hpux11.22)
 538                         AFS_SYSNAME="ia64_hpux1122"
 539                         ;;
 540                 ia64-hp-hpux*)
 541                         AFS_SYSNAME="ia64_hpux1123"
 542                         ;;
 543                 hppa*-hp-hpux10*)
 544                         AFS_SYSNAME="hp_ux102"
 545                         ;;
 546                 powerpc-apple-darwin7*)
 547                         AFS_SYSNAME="ppc_darwin_70"
 548                         OSXSDK="macosx10.3"
 549                         ;;
 550                 powerpc-apple-darwin8.*)
 551                         AFS_SYSNAME="ppc_darwin_80"
 552                         OSXSDK="macosx10.4"
 553                         ;;
 554                 i386-apple-darwin8.*)
 555                         AFS_SYSNAME="x86_darwin_80"
 556                         OSXSDK="macosx10.4"
 557                         ;;
 558                 powerpc-apple-darwin9.*)
 559                         AFS_SYSNAME="ppc_darwin_90"
 560                         OSXSDK="macosx10.5"
 561                         ;;
 562                 i386-apple-darwin9.*)
 563                         AFS_SYSNAME="x86_darwin_90"
 564                         OSXSDK="macosx10.5"
 565                         ;;
 566                 i?86-apple-darwin10.*)
 567                         AFS_SYSNAME="x86_darwin_100"
 568                         OSXSDK="macosx10.6"
 569                         ;;
 570                 x86_64-apple-darwin10.*)
 571                         AFS_SYSNAME="x86_darwin_100"
 572                         OSXSDK="macosx10.6"
 573                         ;;
 574                 arm-apple-darwin10.*)
 575                         AFS_SYSNAME="arm_darwin_100"
 576                         OSXSDK="iphoneos4.0"
 577                         ;;
 578                 x86_64-apple-darwin11.*)
 579                         AFS_SYSNAME="x86_darwin_110"
 580                         OSXSDK="macosx10.7"
 581                         ;;
 582                 i?86-apple-darwin11.*)
 583                         AFS_SYSNAME="x86_darwin_110"
 584                         OSXSDK="macosx10.7"
 585                         ;;
 586                 x86_64-apple-darwin12.*)
 587                         AFS_SYSNAME="x86_darwin_120"
 588                         OSXSDK="macosx10.8"
 589                         ;;
 590                 i?86-apple-darwin12.*)
 591                         AFS_SYSNAME="x86_darwin_120"
 592                         OSXSDK="macosx10.8"
 593                         ;;
 594                 sparc-sun-solaris2.8)
 595                         AFS_SYSNAME="sun4x_58"
 596                         ;;
 597                 sparc-sun-solaris2.9)
 598                         AFS_SYSNAME="sun4x_59"
 599                         ;;
 600                 sparc-sun-solaris2.10)
 601                         AFS_SYSNAME="sun4x_510"
 602                         ;;
 603                 sparc-sun-solaris2.11)
 604                         AFS_SYSNAME="sun4x_511"
 605                         ;;
 606                 i386-pc-solaris2.8)
 607                         AFS_SYSNAME="sunx86_58"
 608                         ;;
 609                 i386-pc-solaris2.9)
 610                         AFS_SYSNAME="sunx86_59"
 611                         ;;
 612                 i386-pc-solaris2.10)
 613                         AFS_SYSNAME="sunx86_510"
 614                         ;;
 615                 i386-pc-solaris2.11)
 616                         AFS_SYSNAME="sunx86_511"
 617                         ;;
 618                 alpha*-dec-osf4.0*)
 619                         AFS_SYSNAME="alpha_dux40"
 620                         ;;
 621                 alpha*-dec-osf5.0*)
 622                         AFS_SYSNAME="alpha_dux50"
 623                         ;;
 624                 alpha*-dec-osf5.1*)
 625                         AFS_SYSNAME="alpha_dux51"
 626                         ;;
 627                 mips-sgi-irix6.5)
 628                         AFS_SYSNAME="sgi_65"
 629                         ;;
 630                 ia64-*-linux*)
 631                         AFS_SYSNAME="ia64_linuxXX"
 632                         ;;
 633                 powerpc-*-linux*)
 634                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 635                         ;;
 636                 powerpc64-*-linux*)
 637                         AFS_SYSNAME="ppc64_linuxXX"
 638                         ;;
 639                 alpha*-linux*)
 640                         AFS_SYSNAME="alpha_linux_XX"
 641                         ;;
 642                 s390-*-linux*)
 643                         AFS_SYSNAME="s390_linuxXX"
 644                         ;;
 645                 s390x-*-linux*)
 646                         AFS_SYSNAME="s390x_linuxXX"
 647                         ;;
 648                 sparc-*-linux*)
 649                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 650                         ;;
 651                 sparc64-*-linux*)
 652                         AFS_SYSNAME="sparc64_linuxXX"
 653                         ;;
 654                 i?86-*-linux*)
 655                         AFS_SYSNAME="i386_linuxXX"
 656                         ;;
 657                 arm*-linux*)
 658                         AFS_SYSNAME="arm_linuxXX"
 659                         ;;
 660                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 661                         AFS_SYSNAME="parisc_linuxXX"
 662                         enable_pam="no"
 663                         ;;
 664                 power*-ibm-aix4.2*)
 665                         AFS_SYSNAME="rs_aix42"
 666                         enable_pam="no"
 667                         ;;
 668                 power*-ibm-aix4.3*)
 669                         AFS_SYSNAME="rs_aix42"
 670                         enable_pam="no"
 671                         ;;
 672                 power*-ibm-aix5.1*)
 673                         AFS_SYSNAME="rs_aix51"
 674                         enable_pam="no"
 675                         ;;
 676                 power*-ibm-aix5.2*)
 677                         AFS_SYSNAME="rs_aix52"
 678                         enable_pam="no"
 679                         ;;
 680                 power*-ibm-aix5.3*)
 681                         AFS_SYSNAME="rs_aix53"
 682                         enable_pam="no"
 683                         ;;
 684                 power*-ibm-aix6.1*)
 685                         AFS_SYSNAME="rs_aix61"
 686                         enable_pam="no"
 687                         ;;
 688                 x86_64-*-linux-gnu)
 689                         AFS_SYSNAME="amd64_linuxXX"
 690                         enable_pam="yes"
 691                         ;;
 692                 *)
 693                         AC_MSG_ERROR(An AFS sysname is required)
 694                         exit 1
 695                         ;;
 696         esac
 697         case $AFS_SYSNAME in
 698                 *_linux* | *_umlinux*)
 699                         if test "x${AFS_SYSKVERS}" = "x"; then
 700                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 701                         fi
 702                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 703                         AFS_SYSNAME="$_AFS_SYSNAME"
 704                         AC_TRY_KBUILD(
 705                          [],
 706                          [#ifndef CONFIG_USERMODE
 707                           #error not UML
 708                           #endif],
 709                          ac_cv_linux_is_uml=yes,)
 710                         if test "${ac_cv_linux_is_uml}" = yes; then
 711                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 712                         fi
 713                         AFS_SYSNAME="$_AFS_SYSNAME"
 714                         ;;
 715         esac
 716         AC_MSG_RESULT($AFS_SYSNAME)
 717 fi
 718
 719 case $AFS_SYSNAME in
 720         *_darwin*)
 721                 AC_CHECK_HEADERS(crt_externs.h)
 722                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 723                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 724                 AC_SUBST(OSXSDK)
 725                 ;;
 726 esac
 727
 728 dnl Some hosts have a separate common param file they should include.  Figure
 729 dnl out if we're on one of them now that we know the sysname.
 730 case $AFS_SYSNAME in
 731     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 732     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 733     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 734     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 735     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 736     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 737     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 738     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 739     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 740     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 741     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 742     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 743     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 744     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 745     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 746     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 747     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 748     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 749     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 750     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 751     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 752     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 753     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 754     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 755     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 756     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 757     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 758     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 759     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 760 # Linux alpha adds an extra underscore for no good reason.
 761     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 762     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 763     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 764 esac
 765
 766 OPENAFS_OSCONF
 767
 768 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 769
 770                 # Add (sub-) architecture-specific paths needed by conftests
 771                 case $AFS_SYSNAME  in
 772                         *_umlinux26)
 773                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 774                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 775                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 776                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 777                 esac
 778
 779                 if test "x$enable_kernel_module" = "xyes"; then
 780                  if test "x$enable_debug_kernel" = "xno"; then
 781                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 782                  fi
 783                  OPENAFS_GCC_SUPPORTS_MARCH
 784                  AC_SUBST(P5PLUS_KOPTS)
 785                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 786                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 787                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 788                  OPENAFS_GCC_SUPPORTS_PIPE
 789                  AC_SUBST(LINUX_GCC_KOPTS)
 790
 791                  dnl Setup the kernel build environment
 792                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 793                  LINUX_KERNEL_COMPILE_WORKS
 794
 795                  dnl Check for header files
 796                  AC_CHECK_LINUX_HEADER([config.h])
 797                  AC_CHECK_LINUX_HEADER([completion.h])
 798                  AC_CHECK_LINUX_HEADER([exportfs.h])
 799                  AC_CHECK_LINUX_HEADER([freezer.h])
 800                  AC_CHECK_LINUX_HEADER([key-type.h])
 801                  AC_CHECK_LINUX_HEADER([semaphore.h])
 802                  AC_CHECK_LINUX_HEADER([seq_file.h])
 803
 804                  dnl Type existence checks
 805                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 806
 807                  dnl Check for structure elements
 808                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 809                                        [write_begin], [fs.h])
 810                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 811                                        [backing-dev.h])
 812                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 813                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 814                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 815                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 816                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 817                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 818                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 819                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 820                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 821                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 822                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 823                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 824                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 825                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 826                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 827                                        [fs.h])
 828                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 829                                        [fs.h])
 830                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 831                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 832                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 833                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 834                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 835                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 836                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 837                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 838                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 839                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 840                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 841
 842                  dnl Check for typed structure elements
 843                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 844                                              [buf], [fs.h])
 845
 846                  dnl Function existence checks
 847
 848                  AC_CHECK_LINUX_FUNC([bdi_init],
 849                                      [#include <linux/backing-dev.h>],
 850                                      [bdi_init(NULL);])
 851                  AC_CHECK_LINUX_FUNC([PageChecked],
 852                                      [#include <linux/mm.h>
 853 #include <linux/page-flags.h>],
 854                                      [struct page *_page;
 855                                       int bchecked = PageChecked(_page);])
 856                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 857                                      [#include <linux/mm.h>
 858 #include <linux/page-flags.h>],
 859                                      [struct page *_page;
 860                                       int bchecked = PageFsMisc(_page);])
 861                  AC_CHECK_LINUX_FUNC([clear_inode],
 862                                      [#include <linux/fs.h>],
 863                                      [clear_inode(NULL);])
 864                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 865                                      [#include <linux/time.h>],
 866                                      [struct timespec s;
 867                                       s = current_kernel_time();])
 868                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 869                                      [#include <linux/fs.h>],
 870                                      [d_alloc_anon(NULL);])
 871                  AC_CHECK_LINUX_FUNC([d_make_root],
 872                                      [#include <linux/fs.h>],
 873                                      [d_make_root(NULL);])
 874                  AC_CHECK_LINUX_FUNC([do_sync_read],
 875                                      [#include <linux/fs.h>],
 876                                      [do_sync_read(NULL, NULL, 0, NULL);])
 877                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 878                                      [#include <linux/sched.h>],
 879                                      [pid_t p; find_task_by_pid(p);])
 880                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 881                                      [#include <linux/fs.h>],
 882                                      [generic_file_aio_read(NULL,NULL,0,0);])
 883                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 884                                      [#include <linux/pagemap.h>],
 885                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 886                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 887                                      [#include <linux/list.h>],
 888                                      [hlist_unhashed(0);])
 889                  AC_CHECK_LINUX_FUNC([i_size_read],
 890                                      [#include <linux/fs.h>],
 891                                      [i_size_read(NULL);])
 892                  AC_CHECK_LINUX_FUNC([inode_setattr],
 893                                      [#include <linux/fs.h>],
 894                                      [inode_setattr(NULL, NULL);])
 895                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
 896                                      [#include <linux/net.h>],
 897                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
 898                  AC_CHECK_LINUX_FUNC([page_follow_link],
 899                                      [#include <linux/fs.h>],
 900                                      [page_follow_link(0,0);])
 901                  AC_CHECK_LINUX_FUNC([page_offset],
 902                                      [#include <linux/pagemap.h>],
 903                                      [page_offset(NULL);])
 904                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
 905                                      [#include <linux/pagevec.h>],
 906                                      [__pagevec_lru_add_file(NULL);])
 907                  AC_CHECK_LINUX_FUNC([path_lookup],
 908                                      [#include <linux/fs.h>
 909                                       #include <linux/namei.h>],
 910                                      [path_lookup(NULL, 0, NULL);])
 911                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
 912                                      [#include <linux/rcupdate.h>],
 913                                      [rcu_read_lock();])
 914                  AC_CHECK_LINUX_FUNC([set_nlink],
 915                                      [#include <linux/fs.h>],
 916                                      [set_nlink(NULL, 1);])
 917                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
 918                                      [#include <linux/splice.h>],
 919                                      [splice_direct_to_actor(NULL,NULL,NULL);])
 920                  AC_CHECK_LINUX_FUNC([svc_addr_in],
 921                                      [#include <linux/sunrpc/svc.h>],
 922                                      [svc_addr_in(NULL);])
 923                  AC_CHECK_LINUX_FUNC([zero_user_segments],
 924                                      [#include <linux/highmem.h>],
 925                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
 926                  AC_CHECK_LINUX_FUNC([noop_fsync],
 927                                      [#include <linux/fs.h>],
 928                                      [void *address = &noop_fsync; printk("%p\n", address)];)
 929                  AC_CHECK_LINUX_FUNC([kthread_run],
 930                                      [#include <linux/kernel.h>
 931                                       #include <linux/kthread.h>],
 932                                      [kthread_run(NULL, NULL, "test");])
 933
 934                  dnl Consequences - things which get set as a result of the
 935                  dnl                above tests
 936                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
 937                        [AC_DEFINE([AFS_NONFSTRANS], 1,
 938                                   [define to disable the nfs translator])])
 939
 940                  dnl Assorted more complex tests
 941                  LINUX_AIO_NONVECTOR
 942                  LINUX_EXPORTS_PROC_ROOT_FS
 943                  LINUX_KMEM_CACHE_INIT
 944                  LINUX_HAVE_KMEM_CACHE_T
 945                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
 946                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
 947                  LINUX_D_PATH_TAKES_STRUCT_PATH
 948                  LINUX_NEW_EXPORT_OPS
 949                  LINUX_INODE_SETATTR_RETURN_TYPE
 950                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
 951                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
 952                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
 953                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
 954                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
 955                  LINUX_DOP_D_DELETE_TAKES_CONST
 956                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
 957                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
 958                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
 959                  LINUX_FOP_F_FSYNC_TAKES_RANGE
 960                  LINUX_AOP_WRITEBACK_CONTROL
 961                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
 962                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
 963                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
 964                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
 965                  LINUX_KERNEL_SOCK_CREATE
 966                  LINUX_EXPORTS_KEY_TYPE_KEYRING
 967                  LINUX_NEED_RHCONFIG
 968                  LINUX_RECALC_SIGPENDING_ARG_TYPE
 969                  LINUX_EXPORTS_TASKLIST_LOCK
 970                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
 971                  LINUX_STATFS_TAKES_DENTRY
 972                  LINUX_REFRIGERATOR
 973                  LINUX_HAVE_TRY_TO_FREEZE
 974                  LINUX_LINUX_KEYRING_SUPPORT
 975                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
 976                  LINUX_KEY_ALLOC_NEEDS_CRED
 977                  LINUX_INIT_WORK_HAS_DATA
 978                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
 979                  LINUX_HAVE_DCACHE_LOCK
 980                  LINUX_D_COUNT_IS_INT
 981                  LINUX_IOP_MKDIR_TAKES_UMODE_T
 982                  LINUX_IOP_CREATE_TAKES_UMODE_T
 983                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
 984                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
 985                  LINUX_DENTRY_OPEN_TAKES_PATH
 986                  LINUX_D_ALIAS_IS_HLIST
 987                  LINUX_IOP_I_CREATE_TAKES_BOOL
 988                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
 989                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
 990
 991                  dnl If we are guaranteed that keyrings will work - that is
 992                  dnl  a) The kernel has keyrings enabled
 993                  dnl  b) The code is new enough to give us a key_type_keyring
 994                  dnl then we just disable syscall probing unless we've been
 995                  dnl told otherwise
 996
 997                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
 998                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
 999                           [enable_linux_syscall_probing="no"],
1000                           [enable_linux_syscall_probing="yes"])
1001                  ])
1002
1003                  dnl Syscall probing needs a few tests of its own, and just
1004                  dnl won't work if the kernel doesn't export init_mm
1005                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1006                    LINUX_EXPORTS_INIT_MM
1007                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1008                      AC_MSG_ERROR(
1009                        [Can't do syscall probing without exported init_mm])
1010                    ])
1011                    LINUX_EXPORTS_SYS_CHDIR
1012                    LINUX_EXPORTS_SYS_OPEN
1013                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1014                              [define to enable syscall table probes])
1015                  ])
1016
1017                  dnl Packaging and SMP build
1018                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1019                    LINUX_WHICH_MODULES
1020                  else
1021                    AC_SUBST(MPS,'SP')
1022                  fi
1023
1024                  dnl Syscall probing
1025                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1026                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1027                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1028                    ])
1029                    ac_cv_linux_exports_sys_call_table=no
1030                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1031                      ac_cv_linux_exports_ia32_sys_call_table=yes
1032                    fi
1033                  else
1034                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1035                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1036                    LINUX_EXPORTS_SYS_CALL_TABLE
1037                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1038                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1039                          linux_syscall_method=none
1040                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1041                             linux_syscall_method=scan
1042                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1043                                linux_syscall_method=scan_with_kallsyms_address
1044                             fi
1045                          fi
1046                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1047                             linux_syscall_method=kallsyms_symbol
1048                          fi
1049                          if test "x$linux_syscall_method" = "xnone"; then
1050                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1051                             linux_syscall_method=scan
1052                          fi
1053                    fi
1054                  fi
1055                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1056                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1057                  fi
1058                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1059                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1060                  fi
1061                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1062                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1063                  else
1064                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1065                  fi
1066                 :
1067                 fi
1068 dnl Linux-only, but just enable always.
1069                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1070 esac
1071
1072 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1073     [ac_cv_sync_fetch_and_add],
1074     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1075                     [ac_cv_sync_fetch_and_add=yes],
1076                     [ac_cv_sync_fetch_and_add=no])
1077 ])
1078 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1079       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1080                 [define if your C compiler has __sync_add_and_fetch])])
1081
1082 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1083     [ac_cv_sockaddr_len],
1084     [AC_TRY_COMPILE( [#include <sys/types.h>
1085 #include <sys/socket.h>],
1086                      [struct sockaddr *a; a->sa_len=0;],
1087                      [ac_cv_sockaddr_len=yes],
1088                      [ac_cv_sockaddr_len=no])
1089 ])
1090 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1091       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1092                  [define if you struct sockaddr sa_len])])
1093
1094 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1095         echo Skipping library tests because they confuse Irix.
1096 else
1097   AC_SEARCH_LIBS([socket], [socket inet])
1098   AC_SEARCH_LIBS([connect], [nsl])
1099   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1100
1101   dnl darwin wants it, aix hates it
1102   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1103   AC_TRY_COMPILE([
1104   #include <stdlib.h>
1105   #include <stdio.h>
1106   #include <sys/types.h>
1107   #include <sys/socket.h>
1108   #include <netinet/in.h>
1109   #include <arpa/inet.h>
1110   #include <arpa/nameser.h>
1111   #include <arpa/nameser_compat.h>
1112   #include <resolv.h>
1113   ], [static int i; i = 0;],
1114   [AC_MSG_RESULT(yes)
1115    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1116   [AC_MSG_RESULT(no)
1117    ])
1118
1119   openafs_save_libs="$LIBS"
1120   AC_MSG_CHECKING([for res_search])
1121   AC_FUNC_RES_SEARCH
1122
1123   if test "$ac_cv_func_res_search" = no; then
1124       for lib in dns nsl resolv; do
1125         if test "$ac_cv_func_res_search" != yes; then
1126           LIBS="-l$lib $LIBS"
1127           AC_FUNC_RES_SEARCH
1128           LIBS="$openafs_save_libs"
1129         fi
1130       done
1131       if test "$ac_cv_func_res_search" = yes; then
1132         LIB_AFSDB="-l$lib"
1133         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1134         AC_MSG_RESULT([yes, in lib$lib])
1135       else
1136         AC_MSG_RESULT(no)
1137       fi
1138   else
1139     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1140     AC_MSG_RESULT(yes)
1141   fi
1142
1143 fi
1144 XLIBS="$LIB_AFSDB $XLIBS"
1145
1146 AC_CHECK_RESOLV_RETRANS
1147
1148 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1149     [ac_cv_setsockopt_iprecverr],
1150     [AC_TRY_COMPILE( [
1151 #include <sys/types.h>
1152 #include <sys/socket.h>
1153 #include <netinet/in.h>],
1154 [int on=1;
1155 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1156         [ac_cv_setsockopt_iprecverr=yes],
1157         [ac_cv_setsockopt_iprecverr=no])])
1158
1159 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1160       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1161                  [define if we can receive socket errors via IP_RECVERR])])
1162
1163 PTHREAD_LIBS=error
1164 if test "x$MKAFS_OSTYPE" = OBSD; then
1165         PTHREAD_LIBS="-pthread"
1166 fi
1167 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1168         PTHREAD_LIBS="-pthread"
1169 fi
1170 if test "x$PTHREAD_LIBS" = xerror; then
1171         AC_CHECK_LIB(pthread, pthread_attr_init,
1172                 PTHREAD_LIBS="-lpthread")
1173 fi
1174 if test "x$PTHREAD_LIBS" = xerror; then
1175         AC_CHECK_LIB(pthreads, pthread_attr_init,
1176                 PTHREAD_LIBS="-lpthreads")
1177 fi
1178 if test "x$PTHREAD_LIBS" = xerror; then
1179         AC_CHECK_LIB(c_r, pthread_attr_init,
1180                 PTHREAD_LIBS="-lc_r")
1181 fi
1182 if test "x$PTHREAD_LIBS" = xerror; then
1183         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1184 fi
1185 if test "x$PTHREAD_LIBS" = xerror; then
1186         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1187         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1188                 PTHREAD_LIBS="-lpthread")
1189 fi
1190 if test "x$PTHREAD_LIBS" = xerror; then
1191         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1192 fi
1193 AC_SUBST(PTHREAD_LIBS)
1194
1195 HOST_CPU="$host_cpu"
1196
1197 if test "x$with_bsd_kernel_headers" != "x"; then
1198         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1199 else
1200         BSD_KERNEL_PATH="/usr/src/sys"
1201 fi
1202
1203 if test "x$with_bsd_kernel_build" != "x"; then
1204         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1205 else
1206         case $AFS_SYSNAME in
1207                 *_fbsd_*)
1208                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1209                         ;;
1210                 *_nbsd*)
1211                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1212         esac
1213 fi
1214
1215 # Fast restart
1216 if test "$enable_supergroups" = "yes"; then
1217         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1218 fi
1219
1220 if test "$enable_bitmap_later" = "yes"; then
1221         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1222 fi
1223
1224 if test "$enable_unix_sockets" = "yes"; then
1225         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1226         USE_UNIX_SOCKETS="yes"
1227 else
1228         USE_UNIX_SOCKETS="no"
1229 fi
1230 AC_SUBST(USE_UNIX_SOCKETS)
1231
1232 if test "$enable_namei_fileserver" = "yes"; then
1233         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1234         VFSCK=""
1235 else
1236         if test "$enable_namei_fileserver" = "default"; then
1237                 case $host in
1238                         *-solaris2.10*)
1239                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1240                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1241                                 VFSCK=""
1242                                 ;;
1243                         *-solaris2.11*)
1244                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1245                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1246                                 VFSCK=""
1247                                 ;;
1248                         *)
1249                                 VFSCK="vfsck"
1250                                 ;;
1251                 esac
1252         else
1253                 VFSCK="vfsck"
1254         fi
1255 fi
1256
1257 dnl check for tivoli
1258 AC_MSG_CHECKING(for tivoli tsm butc support)
1259 XBSA_CFLAGS=""
1260 if test "$enable_tivoli_tsm" = "yes"; then
1261         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1262         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1263         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1264         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1265
1266         if test -r "$XBSADIR3/dsmapifp.h"; then
1267                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1268                 XBSA_XLIBS="-ldl"
1269                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1270         elif test -r "$XBSADIR4/dsmapifp.h"; then
1271                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1272                 XBSA_XLIBS="-ldl"
1273                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1274         elif test -r "$XBSADIR1/xbsa.h"; then
1275                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1276                 XBSA_XLIBS=""
1277                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1278         elif test -r "$XBSADIR2/xbsa.h"; then
1279                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1280                 XBSA_XLIBS=""
1281                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1282         else
1283                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1284         fi
1285 else
1286         AC_MSG_RESULT([no])
1287 fi
1288 AC_SUBST(XBSA_CFLAGS)
1289 AC_SUBST(XBSA_XLIBS)
1290
1291 dnl checks for header files.
1292 AC_HEADER_STDC
1293 AC_HEADER_SYS_WAIT
1294 AC_HEADER_DIRENT
1295 AC_CHECK_HEADERS([ \
1296                    arpa/inet.h \
1297                    arpa/nameser.h \
1298                    curses.h\
1299                    direct.h \
1300                    et/com_err.h \
1301                    errno.h \
1302                    fcntl.h \
1303                    grp.h \
1304                    math.h \
1305                    mntent.h \
1306                    ncurses.h \
1307                    netdb.h \
1308                    netinet/in.h \
1309                    pthread_np.h \
1310                    pwd.h \
1311                    regex.h \
1312                    security/pam_appl.h \
1313                    signal.h \
1314                    stdint.h \
1315                    stdio_ext.h \
1316                    stdlib.h \
1317                    string.h \
1318                    strings.h \
1319                    sys/bitypes.h \
1320                    sys/bswap.h \
1321                    sys/dk.h \
1322                    sys/fcntl.h \
1323                    sys/file.h \
1324                    sys/fs_types.h \
1325                    sys/fstyp.h \
1326                    sys/ioctl.h \
1327                    sys/ipc.h \
1328                    sys/lockf.h \
1329                    sys/map.h \
1330                    sys/mount.h \
1331                    sys/mntent.h \
1332                    sys/mnttab.h \
1333                    sys/pag.h \
1334                    sys/param.h \
1335                    sys/resource.h \
1336                    sys/select.h \
1337                    sys/statfs.h \
1338                    sys/statvfs.h \
1339                    sys/socket.h \
1340                    sys/sysctl.h \
1341                    sys/time.h \
1342                    sys/types.h \
1343                    sys/uio.h \
1344                    sys/un.h \
1345                    sys/vfs.h \
1346                    syslog.h \
1347                    termios.h \
1348                    time.h \
1349                    ucontext.h \
1350                    unistd.h \
1351                    windows.h \
1352                 ])
1353
1354 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1355 #ifdef HAVE_NETINET_IN_H
1356 # include <netinet/in.h>
1357 #endif])
1358
1359 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1360 #ifdef HAVE_SYS_SOCKET_H
1361 # include <sys/socket.h>
1362 #endif])
1363
1364 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1365 #ifdef HAVE_SYS_SOCKET_H
1366 # include <sys/socket.h>
1367 #endif
1368 #ifdef HAVE_NETINET_IN_H
1369 # include <netinet/in.h>
1370 #endif
1371 #ifdef HAVE_NET_IF_H
1372 # include <net/if.h>
1373 #endif])
1374
1375 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1376 #ifdef HAVE_SECURITY_PAM_APPL_H
1377 # include <security/pam_appl.h>
1378 #endif])
1379
1380 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1381
1382 AC_CHECK_TYPES([fsblkcnt_t],,,[
1383 #include <sys/types.h>
1384 #ifdef HAVE_SYS_BITYPES_H
1385 #include <sys/bitypes.h>
1386 #endif
1387 #ifdef HAVE_SYS_STATFS_H
1388 #include <sys/statfs.h>
1389 #endif
1390 #ifdef HAVE_SYS_STATVFS_H
1391 #include <sys/statvfs.h>
1392 #endif
1393 ])
1394
1395 dnl see what struct stat has for timestamps
1396 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1397
1398 dnl check for curses-lib
1399 AS_IF([test "x$enable_gtx" != "xno"],
1400       [save_LIBS=$LIBS
1401       AC_CHECK_LIB( [ncurses], [setupterm],
1402       [LIB_curses=-lncurses],
1403         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1404           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1405       ])
1406       LIBS=$save_LIBS
1407       AC_SUBST(LIB_curses)])
1408
1409 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1410
1411 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1412 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1413         case $AFS_SYSNAME in
1414         sgi_*)
1415                 HAVE_PAM="no"
1416                 ;;
1417         *)
1418                 HAVE_PAM="yes"
1419                 ;;
1420         esac
1421 else
1422         HAVE_PAM="no"
1423 fi
1424 AC_SUBST(HAVE_PAM)
1425
1426 if test "$enable_login" = yes; then
1427         BUILD_LOGIN="yes"
1428 else
1429         BUILD_LOGIN="no"
1430 fi
1431 AC_SUBST(BUILD_LOGIN)
1432
1433 if test "$enable_uss" = yes; then
1434         BUILD_USS="yes"
1435 else
1436         BUILD_USS="no"
1437 fi
1438 AC_SUBST(BUILD_USS)
1439
1440 AC_CHECK_FUNCS([ \
1441         arc4random \
1442         fcntl \
1443         fseeko64 \
1444         ftello64 \
1445         getcwd \
1446         getegid \
1447         geteuid \
1448         getgid \
1449         getuid \
1450         getrlimit \
1451         issetugid \
1452         mkstemp \
1453         pread \
1454         preadv \
1455         preadv64 \
1456         pwrite \
1457         pwritev \
1458         pwritev64 \
1459         regcomp \
1460         regerror \
1461         regexec \
1462         setitimer \
1463         setvbuf \
1464         sigaction \
1465         strcasestr \
1466         strerror \
1467         sysconf \
1468         sysctl \
1469         tdestroy \
1470         timegm \
1471 ])
1472
1473 OPENAFS_ROKEN()
1474 OPENAFS_C_ATTRIBUTE()
1475
1476 dnl Functions that Heimdal's libroken provides, but that we
1477 dnl haven't found a need for yet, and so haven't imported
1478 AC_CHECK_FUNCS([ \
1479         chown \
1480         fchown \
1481         gethostname \
1482         lstat \
1483         inet_aton \
1484         inet_ntop \
1485         inet_pton \
1486         putenv \
1487         readv \
1488         setenv \
1489         strdup \
1490         strftime \
1491         strndup \
1492         strsep \
1493         unsetenv \
1494 ])
1495
1496 dnl Functions that are in objects that we always build from libroken
1497 AC_CHECK_FUNCS([ \
1498         asprintf \
1499         asnprintf \
1500         vasprintf \
1501         vasnprintf \
1502         vsnprintf \
1503         snprintf \
1504 ])
1505
1506 dnl Functions that we're going to try and get from libroken
1507 AC_REPLACE_FUNCS([ \
1508         daemon \
1509         ecalloc \
1510         emalloc \
1511         erealloc \
1512         err \
1513         errx \
1514         flock \
1515         getdtablesize \
1516         getopt \
1517         getprogname \
1518         gettimeofday \
1519         localtime_r \
1520         mkstemp \
1521         setenv \
1522         setprogname \
1523         strcasecmp \
1524         strlcat \
1525         strnlen \
1526         strlcpy \
1527         strsep \
1528         tdelete \
1529         tfind \
1530         tsearch \
1531         twalk \
1532         unsetenv \
1533         verr \
1534         verrx \
1535         vsyslog \
1536         vwarn \
1537         vwarnx \
1538         warn \
1539         warnx \
1540 ])
1541
1542 dnl Headers that we're going to try and get from libroken
1543 AC_CHECK_HEADERS([ \
1544         err.h \
1545         search.h \
1546 ])
1547
1548 AC_CHECK_DECLS([h_errno], [], [], [
1549 #include <sys/types.h>
1550 #ifdef HAVE_NETDB_H
1551 #include <netdb.h>
1552 #endif
1553 ])
1554
1555 AC_HEADER_TIME
1556
1557 ROKEN_HEADERS=
1558 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1559       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1560       [])
1561 AC_SUBST(ROKEN_HEADERS)
1562
1563 dnl Stuff that's harder ...
1564 AC_MSG_CHECKING([for bswap16])
1565 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1566 #ifdef HAVE_SYS_TYPES_H
1567 #include <sys/types.h>
1568 #endif
1569 #ifdef HAVE_SYS_BSWAP_H
1570 #include <sys/bswap.h>
1571 #endif
1572 ],
1573 [short a, b; b = bswap16(a); ])],
1574 [AC_MSG_RESULT(yes)
1575  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1576 ],
1577 [AC_MSG_RESULT(no)])
1578
1579 AC_MSG_CHECKING([for bswap32])
1580 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1581 #include <sys/types.h>
1582 #endif
1583 #ifdef HAVE_SYS_BSWAP_H
1584 #include <sys/bswap.h>
1585 #endif
1586 ],
1587 [int a, b; b = bswap32(a); ])],
1588 [AC_MSG_RESULT(yes)
1589  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1590 ],
1591 [AC_MSG_RESULT(no)])
1592
1593 case $AFS_SYSNAME in
1594 *hp_ux* | *hpux*)
1595    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1596    ;;
1597 *)
1598    AC_MSG_CHECKING([for positional I/O])
1599    if test "$ac_cv_func_pread" = "yes" && \
1600            test "$ac_cv_func_pwrite" = "yes"; then
1601       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1602       AC_MSG_RESULT(yes)
1603    else
1604      AC_MSG_RESULT(no)
1605    fi
1606    AC_MSG_CHECKING([for vectored positional I/O])
1607    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1608                "$ac_cv_func_pwritev" = "yes" -a \
1609                "$ac_cv_func_preadv64" = "yes" -a \
1610                "$ac_cv_func_pwritev64" = "yes"],
1611          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1612           AC_MSG_RESULT(yes)],
1613          [AC_MSG_RESULT(no)])
1614    ;;
1615 esac
1616
1617 AC_MSG_CHECKING([for POSIX regex library])
1618 if test "$ac_cv_header_regex_h" = "yes" && \
1619         test "$ac_cv_func_regcomp" = "yes" && \
1620         test "$ac_cv_func_regexec" = "yes" && \
1621         test "$ac_cv_func_regerror" = "yes"; then
1622     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1623     AC_MSG_RESULT(yes)
1624 else
1625     AC_MSG_RESULT(no)
1626 fi
1627
1628 dnl Look for "non-portable" pthreads functions.
1629 save_LIBS="$LIBS"
1630 LIBS="$LIBS $PTHREAD_LIBS"
1631 AC_CHECK_FUNCS([ \
1632         pthread_set_name_np \
1633         pthread_setname_np \
1634 ])
1635
1636 dnl Sadly, there are three different versions of pthread_setname_np.
1637 dnl Try to cater for all of them.
1638 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1639     AC_MSG_CHECKING([for signature of pthread_setname_np])
1640     AC_TRY_COMPILE([
1641 #include <pthread.h>
1642 #ifdef HAVE_PTHREAD_NP_H
1643 #include <pthread_np.h>
1644 #endif
1645 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1646         AC_MSG_RESULT([three arguments])
1647         pthread_setname_np_args=3], [
1648         AC_TRY_COMPILE([
1649 #include <pthread.h>
1650 #ifdef HAVE_PTHREAD_NP_H
1651 #include <pthread_np.h>
1652 #endif
1653 ], [pthread_setname_np(pthread_self(), "test")], [
1654             AC_MSG_RESULT([two arguments])
1655             pthread_setname_np_args=2], [
1656             AC_TRY_COMPILE([
1657 #include <pthread.h>
1658 #ifdef HAVE_PTHREAD_NP_H
1659 #include <pthread_np.h>
1660 #endif
1661 ], [pthread_setname_np("test")], [
1662                 AC_MSG_RESULT([one argument])
1663                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1664 ])
1665 ])
1666 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1667 fi
1668 LIBS="$save_LIBS"
1669
1670 openafs_cv_saved_CFLAGS="$CFLAGS"
1671 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1672
1673 AC_TYPE_SIGNAL
1674 OPENAFS_RETSIGTYPE
1675 AC_CHECK_SIZEOF(void *)
1676 AC_CHECK_SIZEOF(unsigned long long)
1677 AC_CHECK_SIZEOF(unsigned long)
1678 AC_CHECK_SIZEOF(unsigned int)
1679 AC_TYPE_INTPTR_T
1680 AC_TYPE_UINTPTR_T
1681 AC_TYPE_SSIZE_T
1682 AC_CHECK_TYPE([sig_atomic_t],[],
1683     [AC_DEFINE([sig_atomic_t], [int],
1684         [Define to int if <signal.h> does not define.])],
1685 [#include <sys/types.h>
1686 #include <signal.h>])
1687 AC_CHECK_TYPE([socklen_t],[],
1688     [AC_DEFINE([socklen_t], [int],
1689         [Define to int if <sys/socket.h> does not define.])],
1690 [#include <sys/types.h>
1691 #include <sys/socket.h>])
1692 AC_CHECK_TYPES(off64_t)
1693 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1694 AC_CHECK_TYPES([struct winsize], [], [], [
1695 #ifdef HAVE_TERMIOS_H
1696 # include <termios.h>
1697 #else
1698 # include <sys/termios.h>
1699 #endif
1700 #include <sys/ioctl.h>])
1701 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1702                 struct sockaddr_storage],
1703                [], [], [
1704 #include <sys/types.h>
1705 #include <sys/socket.h>
1706 ])
1707 AC_CHECK_TYPES([sa_family_t], [], [], [
1708 #include <sys/types.h>
1709 #include <sys/socket.h>
1710 ])
1711 AC_CHECK_TYPES([struct addrinfo], [], [], [
1712 #include <sys/types.h>
1713 #ifdef HAVE_NETDB_H
1714 #include <netdb.h>
1715 #endif
1716 ])
1717 AC_CHECK_TYPES([long long], [], [], [])
1718
1719 AC_SIZEOF_TYPE(long)
1720
1721 CFLAGS="$openafs_cv_saved_CFLAGS"
1722
1723 RRA_HEADER_PAM_CONST
1724
1725
1726 dnl Directory PATH handling
1727 if test "x$enable_transarc_paths" = "xyes"  ; then
1728     afsconfdir=${afsconfdir=/usr/afs/etc}
1729     viceetcdir=${viceetcdir=/usr/vice/etc}
1730     afskerneldir=${afskerneldir=${viceetcdir}}
1731     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1732     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1733     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1734     afsdbdir=${afsdbdir=/usr/afs/db}
1735     afslogsdir=${afslogsdir=/usr/afs/logs}
1736     afslocaldir=${afslocaldir=/usr/afs/local}
1737     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1738     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1739     afsdatadir=${afsdatadir=/usr/vice/etc}
1740 else
1741     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1742     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1743     afskerneldir=${afskerneldir='${libdir}/openafs'}
1744     afssrvbindir=${afssrvbindir='${bindir}'}
1745     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1746     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1747     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1748     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1749     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1750     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1751     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1752     afsdatadir=${afsdatadir='${datadir}/openafs'}
1753 fi
1754 AC_SUBST(afsconfdir)
1755 AC_SUBST(viceetcdir)
1756 AC_SUBST(afskerneldir)
1757 AC_SUBST(afssrvbindir)
1758 AC_SUBST(afssrvsbindir)
1759 AC_SUBST(afssrvlibexecdir)
1760 AC_SUBST(afsdbdir)
1761 AC_SUBST(afslogsdir)
1762 AC_SUBST(afslocaldir)
1763 AC_SUBST(afsbackupdir)
1764 AC_SUBST(afsbosconfigdir)
1765 AC_SUBST(afsdatadir)
1766
1767 if test "x$enable_kernel_module" = "xyes"; then
1768 ENABLE_KERNEL_MODULE=libafs
1769 fi
1770
1771 if test "x$enable_pthreaded_ubik" = "xyes"; then
1772 ENABLE_PTHREADED_UBIK=yes
1773 fi
1774
1775 AC_SUBST(VFSCK)
1776 AC_SUBST(AFS_SYSNAME)
1777 AC_SUBST(AFS_PARAM_COMMON)
1778 AC_SUBST(ENABLE_KERNEL_MODULE)
1779 AC_SUBST(ENABLE_PTHREADED_UBIK)
1780 AC_SUBST(LIB_AFSDB)
1781 AC_SUBST(LINUX_KERNEL_PATH)
1782 AC_SUBST(LINUX_KERNEL_BUILD)
1783 AC_SUBST(HOST_CPU)
1784 AC_SUBST(BSD_KERNEL_PATH)
1785 AC_SUBST(BSD_KERNEL_BUILD)
1786 AC_SUBST(LINUX_VERSION)
1787 AC_SUBST(MKAFS_OSTYPE)
1788 AC_SUBST(TOP_OBJDIR)
1789 AC_SUBST(TOP_SRCDIR)
1790 AC_SUBST(TOP_INCDIR)
1791 AC_SUBST(TOP_LIBDIR)
1792 AC_SUBST(DEST)
1793 AC_SUBST(DARWIN_INFOFILE)
1794 AC_SUBST(IRIX_BUILD_IP35)
1795 AC_SUBST(HTML_XSL)
1796 AC_SUBST(XSLTPROC)
1797 AC_SUBST(DOCBOOK2PDF)
1798 AC_SUBST(DOCBOOK_STYLESHEETS)
1799
1800 OPENAFS_FUSE
1801 OPENAFS_SWIG
1802
1803 TOP_SRCDIR="${srcdir}/src"
1804 dnl
1805 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1806 dnl
1807 case $TOP_SRCDIR in
1808         /*)
1809                 ;;
1810         *)
1811                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1812                 ;;
1813 esac
1814
1815 TOP_OBJDIR="${SRCDIR_PARENT}"
1816 TOP_INCDIR="${SRCDIR_PARENT}/include"
1817 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1818 if test "${DEST}x" = "x"; then
1819         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1820 fi
1821
1822 if test "x$with_crosstools_dir" != "x"; then
1823         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1824                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1825                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1826                 RXGEN_PATH=$with_crosstools_dir/rxgen
1827         else
1828                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1829                 exit 1
1830         fi
1831 else
1832         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1833         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1834         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1835 fi
1836 AC_SUBST(COMPILE_ET_PATH)
1837 AC_SUBST(CONFIGTOOL_PATH)
1838 AC_SUBST(RXGEN_PATH)
1839
1840 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1841 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1842 AC_SUBST(HELPER_SPLINT)
1843 AC_SUBST(HELPER_SPLINTCFG)
1844
1845 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1846
1847 dnl Check to see if crypt lives in a different library
1848 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1849 AC_SUBST(LIB_crypt)
1850
1851 dnl Check to see if the compiler support labels in structs
1852 AC_MSG_CHECKING(for label support in structs)
1853 AC_TRY_COMPILE([], [
1854 extern void osi_UFSOpen(void);
1855 struct labeltest {
1856    void (*open) (void);
1857 };
1858 struct labeltest struct_labeltest = {
1859    .open       = osi_UFSOpen,
1860 }
1861 ],
1862 [AC_MSG_RESULT(yes)
1863  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1864 ],
1865 [AC_MSG_RESULT(no)
1866 ])
1867
1868 AC_MSG_CHECKING([checking for dirfd])
1869 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1870 #ifdef HAVE_DIRENT_H
1871 #include <dirent.h>
1872 #endif
1873 ]],
1874         [[DIR *d = 0; dirfd(d);]])],
1875         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1876 if test "$ac_rk_have_dirfd" = "yes" ; then
1877         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1878 fi
1879 AC_MSG_RESULT($ac_rk_have_dirfd)
1880
1881 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1882 #ifdef HAVE_DIRENT_H
1883 #include <dirent.h>
1884 #endif])
1885
1886 dnl Eventually, this will look for the system one, or for OpenSSL
1887 LIB_hcrypto="-lafshcrypto"
1888 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1889 AC_SUBST(LIB_hcrypto)
1890 AC_SUBST(LDFLAGS_hcrypto)
1891
1892 dnl Check for UUID library
1893 AC_CHECK_HEADERS([uuid/uuid.h])
1894 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1895 AC_CHECK_FUNCS([uuid_generate])
1896 ])
1897
1898
1899 AC_DEFUN([SUMMARY], [
1900     # Print a configuration summary
1901 echo
1902 echo "**************************************"
1903 echo configure summary
1904 echo
1905 AS_IF([test $LIB_curses],[
1906 echo "LIB_curses :                $LIB_curses" ],[
1907 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1908 ])
1909 echo
1910 echo "**************************************"
1911 ])