acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN(OPENAFS_CONFIGURE_COMMON,[
   8
   9 AC_CANONICAL_HOST
  10 SRCDIR_PARENT=`pwd`
  11
  12 #BOZO_SAVE_CORES BOS_RESTRICTED_MODE BOS_NEW_CONFIG pam sia
  13 AC_ARG_WITH(afs-sysname,
  14 [  --with-afs-sysname=sys    use sys for the afs sysname]
  15 )
  16 AC_ARG_ENABLE( obsolete,
  17 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
  18 AC_ARG_ENABLE( insecure,
  19 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
  20 AC_ARG_ENABLE( afsdb,
  21 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
  22 AC_ARG_ENABLE( bos-restricted-mode,
  23 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
  24 AC_ARG_ENABLE( namei-fileserver,
  25 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
  26 AC_ARG_ENABLE( fast-restart,
  27 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
  28 AC_ARG_ENABLE( bitmap-later,
  29 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
  30 AC_ARG_ENABLE( full-vos-listvol-switch,
  31 [  --enable-full-vos-listvol-switch     enable vos full listvol switch for formatted output],, enable_full_vos_listvol_switch="no")
  32 AC_ARG_WITH(dux-kernel-headers,
  33 [  --with-dux-kernel-headers=path       use the kernel headers found at path(optional, defaults to first match in /usr/sys)]
  34 )
  35 AC_ARG_WITH(linux-kernel-headers,
  36 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux)]
  37 )
  38 AC_ARG_ENABLE(kernel-module,
  39 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
  40 )
  41 AC_ARG_ENABLE(redhat-buildsys,
  42 [  --enable-redhat-buildsys             enable compilation of the redhat build system kernel (defaults to disabled)],, enable_redhat_buildsys="no"
  43 )
  44 AC_ARG_ENABLE(transarc-paths,
  45 [  --enable-transarc-paths                      Use Transarc style paths like /usr/afs and /usr/vice],, enable_transarc_paths="no"
  46 )
  47 AC_ARG_ENABLE(tivoli-tsm,
  48 [  --enable-tivoli-tsm                  Enable use of the Tivoli TSM API libraries for butc support],, enable_tivoli_tsm="no"
  49 )
  50 AC_ARG_ENABLE(debug-kernel,
  51 [  --enable-debug-kernel                enable compilation of the kernel module with debugging information (defaults to disabled)],, enable_debug_kernel="no"
  52 )
  53
  54 dnl weird ass systems
  55 AC_AIX
  56 AC_ISC_POSIX
  57 AC_MINIX
  58
  59 dnl Various compiler setup.
  60 AC_TYPE_PID_T
  61 AC_TYPE_SIZE_T
  62 AC_TYPE_SIGNAL
  63
  64 dnl Checks for programs.
  65 AC_PROG_INSTALL
  66 AC_PROG_LN_S
  67 AC_PROG_RANLIB
  68 AC_PROG_YACC
  69 AM_PROG_LEX
  70
  71 OPENAFS_CHECK_BIGENDIAN
  72
  73 KERN_DEBUG_OPT=
  74 if test "x$enable_debug_kernel" = "xyes"; then
  75   KERN_DEBUG_OPT=-g
  76 fi
  77
  78 AC_MSG_CHECKING(your OS)
  79 system=$host
  80 case $system in
  81         *-linux*)
  82                 MKAFS_OSTYPE=LINUX
  83                 if test "x$enable_redhat_buildsys" = "xyes"; then
  84                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS)
  85                 fi
  86                 if test "x$enable_kernel_module" = "xyes"; then
  87                  if test "x$with_linux_kernel_headers" != "x"; then
  88                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
  89                  else
  90                    LINUX_KERNEL_PATH="/usr/src/linux"
  91                  fi
  92                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
  93                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
  94                   if test "x$linux_kvers" = "x"; then
  95                     if test -f "$LINUX_KERNEL_PATH/include/linux/version-up.h"; then
  96                       linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
  97                       if test "x$linux_kvers" = "x"; then
  98
  99                         AC_MSG_ERROR(Linux headers lack version definition [2])
 100                         exit 1
 101                       else
 102                         LINUX_VERSION="$linux_kvers"
 103                       fi
 104                     else
 105                       AC_MSG_ERROR(Linux headers lack version definition)
 106                       exit 1
 107                     fi
 108                   else
 109                     LINUX_VERSION="$linux_kvers"
 110                   fi
 111                  else
 112                     enable_kernel_module="no"
 113                  fi
 114                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
 115                      enable_kernel_module="no"
 116                  fi
 117                  if test "x$enable_kernel_module" = "xno"; then
 118                   if test "x$with_linux_kernel_headers" != "x"; then
 119                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 120                    exit 1
 121                   else
 122                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 123                   fi
 124                  fi
 125                 fi
 126                 AC_MSG_RESULT(linux)
 127                 if test "x$enable_kernel_module" = "xyes"; then
 128                  OMIT_FRAME_POINTER=
 129                  if test "x$enable_debug_kernel" = "xno"; then
 130                         OMIT_FRAME_POINTER=-fomit-frame-pointer
 131                  fi
 132                  AC_SUBST(OMIT_FRAME_POINTER)
 133                  ifdef([OPENAFS_CONFIGURE_LIBAFS],
 134                    [LINUX_BUILD_VNODE_FROM_INODE(src/config,afs)],
 135                    [LINUX_BUILD_VNODE_FROM_INODE(${srcdir}/src/config,src/afs/LINUX,${srcdir}/src/afs/LINUX)]
 136                  )
 137                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK
 138                  LINUX_FS_STRUCT_INODE_HAS_I_TRUNCATE_SEM
 139                  LINUX_FS_STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS
 140                  LINUX_FS_STRUCT_INODE_HAS_I_DEVICES
 141                  LINUX_INODE_SETATTR_RETURN_TYPE
 142                  LINUX_NEED_RHCONFIG
 143                  LINUX_WHICH_MODULES
 144                  if test "x$ac_cv_linux_func_inode_setattr_returns_int" = "xyes" ; then
 145                   AC_DEFINE(INODE_SETATTR_NOT_VOID)
 146                  fi
 147                  if test "x$ac_cv_linux_fs_struct_address_space_has_page_lock" = "xyes"; then
 148                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK)
 149                  fi
 150                  if test "x$ac_cv_linux_fs_struct_inode_has_i_truncate_sem" = "xyes"; then
 151                   AC_DEFINE(STRUCT_INODE_HAS_I_TRUNCATE_SEM)
 152                  fi
 153                  if test "x$ac_cv_linux_fs_struct_inode_has_i_devices" = "xyes"; then
 154                   AC_DEFINE(STRUCT_INODE_HAS_I_DEVICES)
 155                  fi
 156                  if test "x$ac_cv_linux_fs_struct_inode_has_i_dirty_data_buffers" = "xyes"; then
 157                   AC_DEFINE(STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS)
 158                  fi
 159                 :
 160                 fi
 161                 ;;
 162         *-solaris*)
 163                 MKAFS_OSTYPE=SOLARIS
 164                 AC_MSG_RESULT(sun4)
 165                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 166                 SOLARIS_PROC_HAS_P_COREFILE
 167                 ;;
 168         *-hpux*)
 169                 MKAFS_OSTYPE=HPUX
 170                 AC_MSG_RESULT(hp_ux)
 171                 ;;
 172         *-irix*)
 173                 if test -d /usr/include/sys/SN/SN1; then
 174                  IRIX_BUILD_IP35="IP35"
 175                 fi
 176                 MKAFS_OSTYPE=IRIX
 177                 AC_MSG_RESULT(sgi)
 178                 ;;
 179         *-aix*)
 180                 MKAFS_OSTYPE=AIX
 181                 AC_MSG_RESULT(rs_aix)
 182                 ;;
 183         *-osf*)
 184                 MKAFS_OSTYPE=DUX
 185                 AC_MSG_RESULT(alpha_dux)
 186                 if test "x$enable_kernel_module" = "xyes"; then
 187                  if test "x$with_dux_kernel_headers" != "x"; then
 188                    HEADER_RT=`ls ${with_dux_kernel_headers}/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 189                  else
 190                    HEADER_RT=`ls /usr/sys/*/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 191                  fi
 192                 fi
 193                 if test "$HEADER_RT" = "*" ; then
 194                         AC_MSG_ERROR([Need a configured kernel directory])
 195                 fi
 196                 AC_SUBST([HEADER_RT])
 197                 ;;
 198         *-darwin*)
 199                 MKAFS_OSTYPE=DARWIN
 200                 AC_MSG_RESULT(ppc_darwin)
 201                 ;;
 202         *-freebsd*)
 203                 MKAFS_OSTYPE=FBSD
 204                 AC_MSG_RESULT(i386_fbsd)
 205                 ;;
 206         *-netbsd*)
 207                 MKAFS_OSTYPE=NBSD
 208                 AC_MSG_RESULT(nbsd)
 209                 ;;
 210         *-openbsd*)
 211                 MKAFS_OSTYPE=OBSD
 212                 AC_MSG_RESULT(i386_obsd)
 213                 ;;
 214         *)
 215                 AC_MSG_RESULT($system)
 216                 ;;
 217 esac
 218 AC_SUBST(KERN_DEBUG_OPT)
 219
 220 if test "x$with_afs_sysname" != "x"; then
 221         AFS_SYSNAME="$with_afs_sysname"
 222 else
 223         AC_MSG_CHECKING(your AFS sysname)
 224         case $host in
 225                 i?86-*-freebsd4.2*)
 226                         AFS_SYSNAME="i386_fbsd_42"
 227                         ;;
 228                 i?86-*-freebsd4.3*)
 229                         AFS_SYSNAME="i386_fbsd_43"
 230                         ;;
 231                 i?86-*-freebsd4.4*)
 232                         AFS_SYSNAME="i386_fbsd_44"
 233                         ;;
 234                 i?86-*-freebsd4.5*)
 235                         AFS_SYSNAME="i386_fbsd_45"
 236                         ;;
 237                 i?86-*-netbsd*1.5*)
 238                         AFS_PARAM_COMMON=param.nbsd15.h
 239                         AFS_SYSNAME="i386_nbsd15"
 240                         ;;
 241                 alpha-*-netbsd*1.5*)
 242                         AFS_PARAM_COMMON=param.nbsd15.h
 243                         AFS_SYSNAME="alpha_nbsd15"
 244                         ;;
 245                 hppa*-hp-hpux11*)
 246                         AFS_SYSNAME="hp_ux110"
 247                         ;;
 248                 hppa*-hp-hpux10*)
 249                         AFS_SYSNAME="hp_ux102"
 250                         ;;
 251                 powerpc-apple-darwin1.2*)
 252                         AFS_SYSNAME="ppc_darwin_12"
 253                         ;;
 254                 powerpc-apple-darwin1.3*)
 255                         AFS_SYSNAME="ppc_darwin_13"
 256                         ;;
 257                 powerpc-apple-darwin1.4*)
 258                         AFS_SYSNAME="ppc_darwin_14"
 259                         ;;
 260                 powerpc-apple-darwin5.1*)
 261                         AFS_SYSNAME="ppc_darwin_14"
 262                         ;;
 263                 powerpc-apple-darwin5.2*)
 264                         AFS_SYSNAME="ppc_darwin_14"
 265                         ;;
 266                 powerpc-apple-darwin5.3*)
 267                         AFS_SYSNAME="ppc_darwin_14"
 268                         ;;
 269                 powerpc-apple-darwin5.4*)
 270                         AFS_SYSNAME="ppc_darwin_14"
 271                         ;;
 272                 sparc-sun-solaris2.5*)
 273                         AFS_SYSNAME="sun4x_55"
 274                         ;;
 275                 sparc-sun-solaris2.6)
 276                         AFS_SYSNAME="sun4x_56"
 277                         ;;
 278                 sparc-sun-solaris2.7)
 279                         AFS_SYSNAME="sun4x_57"
 280                         ;;
 281                 sparc-sun-solaris2.8)
 282                         AFS_SYSNAME="sun4x_58"
 283                         ;;
 284                 sparc-sun-solaris2.9)
 285                         AFS_SYSNAME="sun4x_59"
 286                         ;;
 287                 alpha*-dec-osf4.0*)
 288                         AFS_SYSNAME="alpha_dux40"
 289                         ;;
 290                 alpha*-dec-osf5.0*)
 291                         AFS_SYSNAME="alpha_dux50"
 292                         ;;
 293                 mips-sgi-irix6.5)
 294                         AFS_SYSNAME="sgi_65"
 295                         ;;
 296                 ia64-*-linux*)
 297                         AFS_SYSNAME="ia64_linuxXX"
 298                         ;;
 299                 powerpc-*-linux*)
 300                         AFS_SYSNAME="ppc_linuxXX"
 301                         ;;
 302                 alpha*-linux*)
 303                         AFS_SYSNAME="alpha_linux_XX"
 304                         ;;
 305                 s390-*-linux*)
 306                         AFS_SYSNAME="s390_linuxXX"
 307                         ;;
 308                 sparc-*-linux*)
 309                         AFS_SYSNAME="sparc_linuxXX"
 310                         ;;
 311                 sparc64-*-linux*)
 312                         AFS_SYSNAME="sparc64_linuxXX"
 313                         ;;
 314                 i?86-*-linux*)
 315                         AFS_SYSNAME="i386_linuxXX"
 316                         ;;
 317                 parisc-*-linux-gnu)
 318                         AFS_SYSNAME="parisc_linuxXX"
 319                         ;;
 320                 power*-ibm-aix4.2*)
 321                         AFS_SYSNAME="rs_aix42"
 322                         ;;
 323                 power*-ibm-aix4.3*)
 324                         AFS_SYSNAME="rs_aix42"
 325                         ;;
 326                 *)
 327                         AC_MSG_ERROR(An AFS sysname is required)
 328                         exit 1
 329                         ;;
 330         esac
 331         case $AFS_SYSNAME in
 332                 *_linux*)
 333                         AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $[]1 $[]2}'`
 334                         if test "x${AFS_SYSKVERS}" = "x"; then
 335                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 336                         fi
 337                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 338                         AFS_SYSNAME="$_AFS_SYSNAME"
 339                         ;;
 340         esac
 341         AC_MSG_RESULT($AFS_SYSNAME)
 342 fi
 343
 344 case $AFS_SYSNAME in
 345         *_darwin*)
 346                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 347                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 348                 ;;
 349 esac
 350 AC_CACHE_VAL(ac_cv_sockaddr_len,
 351 [
 352 AC_MSG_CHECKING([if struct sockaddr has sa_len field])
 353 AC_TRY_COMPILE( [#include <sys/types.h>
 354 #include <sys/socket.h>],
 355 [struct sockaddr *a;
 356 a->sa_len=0;], ac_cv_sockaddr_len=yes, ac_cv_sockaddr_len=no)
 357 AC_MSG_RESULT($ac_cv_sockaddr_len)])
 358 if test "$ac_cv_sockaddr_len" = "yes"; then
 359    AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN)
 360 fi
 361 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
 362         echo Skipping library tests because they confuse Irix.
 363 else
 364   AC_CHECK_FUNCS(socket)
 365
 366   if test "$ac_cv_func_socket" = no; then
 367     for lib in socket inet; do
 368         if test "$HAVE_SOCKET" != 1; then
 369                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET))
 370         fi
 371     done
 372   fi
 373
 374   AC_CHECK_FUNCS(connect)
 375
 376   if test "$ac_cv_func_connect" = no; then
 377     for lib in nsl; do
 378         if test "$HAVE_CONNECT" != 1; then
 379                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT))
 380         fi
 381     done
 382   fi
 383
 384   AC_CHECK_FUNCS(gethostbyname)
 385   if test "$ac_cv_func_gethostbyname" = no; then
 386         for lib in dns nsl resolv; do
 387           if test "$HAVE_GETHOSTBYNAME" != 1; then
 388             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME))
 389           fi
 390         done
 391   fi
 392
 393   AC_CHECK_FUNCS(res_search)
 394   if test "$ac_cv_func_res_search" = no; then
 395         for lib in dns nsl resolv; do
 396           if test "$HAVE_RES_SEARCH" != 1; then
 397             AC_CHECK_LIB(${lib}, res_search, LIBS="$LIBS -l$lib";HAVE_RES_SEARCH=1;AC_DEFINE(HAVE_RES_SEARCH))
 398           fi
 399         done
 400         if test "$HAVE_RES_SEARCH" = 1; then
 401           LIB_res_search="-l$lib"
 402         fi
 403   fi
 404 fi
 405
 406 PTHREAD_LIBS=error
 407 AC_CHECK_LIB(pthread, pthread_attr_init,
 408              PTHREAD_LIBS="-lpthread")
 409 if test "x$PTHREAD_LIBS" = xerror; then
 410         AC_CHECK_LIB(pthreads, pthread_attr_init,
 411                 PTHREAD_LIBS="-lpthreads")
 412 fi
 413 if test "x$PTHREAD_LIBS" = xerror; then
 414         AC_CHECK_LIB(c_r, pthread_attr_init,
 415                 PTHREAD_LIBS="-lc_r")
 416 fi
 417 if test "x$PTHREAD_LIBS" = xerror; then
 418         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
 419 fi
 420 if test "x$PTHREAD_LIBS" = xerror; then
 421         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
 422 fi
 423 AC_SUBST(PTHREAD_LIBS)
 424
 425 WITH_OBSOLETE=NO
 426 if test "$enable_obsolete" = "yes"; then
 427         WITH_OBSOLETE=YES
 428 fi
 429
 430 WITH_INSECURE=NO
 431 if test "$enable_insecure" = "yes"; then
 432         WITH_INSECURE=YES
 433 fi
 434
 435 # Fast restart
 436 if test "$enable_fast_restart" = "yes"; then
 437         AC_DEFINE(FAST_RESTART)
 438 fi
 439
 440 if test "$enable_bitmap_later" = "yes"; then
 441         AC_DEFINE(BITMAP_LATER)
 442 fi
 443
 444 if test "$enable_full_vos_listvol_switch" = "yes"; then
 445         AC_DEFINE(FULL_LISTVOL_SWITCH)
 446 fi
 447
 448 if test "$enable_bos_restricted_mode" = "yes"; then
 449         AC_DEFINE(BOS_RESTRICTED_MODE)
 450 fi
 451
 452 if test "$enable_namei_fileserver" = "yes"; then
 453         AC_DEFINE(AFS_NAMEI_ENV)
 454 fi
 455
 456 if test "$enable_afsdb" = "yes"; then
 457         LIB_AFSDB="$LIB_res_search"
 458         AC_DEFINE(AFS_AFSDB_ENV)
 459 fi
 460
 461 dnl check for tivoli
 462 AC_MSG_CHECKING(for tivoli tsm butc support)
 463 XBSA_CFLAGS=""
 464 if test "$enable_tivoli_tsm" = "yes"; then
 465         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
 466         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
 467
 468         if test -e "$XBSADIR1/xbsa.h"; then
 469                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
 470                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 471         elif test -e "$XBSADIR2/xbsa.h"; then
 472                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
 473                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 474         else
 475                 AC_MSG_RESULT([no, missing xbsa.h header file])
 476         fi
 477 else
 478         AC_MSG_RESULT([no])
 479 fi
 480 AC_SUBST(XBSA_CFLAGS)
 481
 482 dnl checks for header files.
 483 AC_HEADER_STDC
 484 AC_HEADER_SYS_WAIT
 485 AC_HEADER_DIRENT
 486 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
 487 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
 488 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h)
 489 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
 490 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h)
 491 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h)
 492
 493 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf re_comp re_exec)
 494 AC_CHECK_FUNCS(setprogname getprogname)
 495
 496 dnl Directory PATH handling
 497 if test "x$enable_transarc_paths" = "xyes"  ; then
 498     afsconfdir=${afsconfdir=/usr/afs/etc}
 499     viceetcdir=${viceetcdir=/usr/vice/etc}
 500     afskerneldir=${afskerneldir=${viceetcdir}}
 501     afssrvbindir=${afssrvbindir=/usr/afs/bin}
 502     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
 503     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
 504     afsdbdir=${afsdbdir=/usr/afs/db}
 505     afslogsdir=${afslogsdir=/usr/afs/logs}
 506     afslocaldir=${afslocaldir=/usr/afs/local}
 507     afsbackupdir=${afsbackupdir=/usr/afs/backup}
 508     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
 509 else
 510     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
 511     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
 512     afskerneldir=${afskerneldir='${libdir}/openafs'}
 513     afssrvbindir=${afssrvbindir='${bindir}'}
 514     afssrvsbindir=${afssrvsbindir='${sbindir}'}
 515     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
 516     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
 517     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
 518     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
 519     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
 520     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
 521 fi
 522 AC_SUBST(afsconfdir)
 523 AC_SUBST(viceetcdir)
 524 AC_SUBST(afskerneldir)
 525 AC_SUBST(afssrvbindir)
 526 AC_SUBST(afssrvsbindir)
 527 AC_SUBST(afssrvlibexecdir)
 528 AC_SUBST(afsdbdir)
 529 AC_SUBST(afslogsdir)
 530 AC_SUBST(afslocaldir)
 531 AC_SUBST(afsbackupdir)
 532 AC_SUBST(afsbosconfigdir)
 533
 534 if test "x$enable_kernel_module" = "xyes"; then
 535 ENABLE_KERNEL_MODULE=libafs
 536 fi
 537
 538 AC_SUBST(AFS_SYSNAME)
 539 AC_SUBST(AFS_PARAM_COMMON)
 540 AC_SUBST(ENABLE_KERNEL_MODULE)
 541 AC_SUBST(LIB_AFSDB)
 542 AC_SUBST(LINUX_KERNEL_PATH)
 543 AC_SUBST(LINUX_VERSION)
 544 AC_SUBST(MKAFS_OSTYPE)
 545 AC_SUBST(TOP_OBJDIR)
 546 AC_SUBST(TOP_SRCDIR)
 547 AC_SUBST(TOP_INCDIR)
 548 AC_SUBST(TOP_LIBDIR)
 549 AC_SUBST(DEST)
 550 AC_SUBST(WITH_OBSOLETE)
 551 AC_SUBST(WITH_INSECURE)
 552 AC_SUBST(DARWIN_INFOFILE)
 553 AC_SUBST(IRIX_BUILD_IP35)
 554
 555 OPENAFS_OSCONF
 556
 557 ])