acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #    define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 # define _FILE_OFFSET_BITS 64
  48 # define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 # include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])
  76 ])
  77
  78 dnl General feature options.
  79 AC_ARG_ENABLE([gtx],
  80     [AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools])])
  81
  82 AC_ARG_ENABLE([namei-fileserver],
  83     [AS_HELP_STRING([--enable-namei-fileserver],
  84         [force compilation of namei fileserver in preference to inode
  85          fileserver])],
  86     [],
  87     [enable_namei_fileserver="default"])
  88 AC_ARG_ENABLE([supergroups],
  89     [AS_HELP_STRING([--enable-supergroups],
  90         [enable support for nested pts groups])],
  91     [],
  92     [enable_supergroups="no"])
  93 AC_ARG_ENABLE([bitmap-later],
  94     [AS_HELP_STRING([--enable-bitmap-later],
  95         [enable fast startup of file server by not reading bitmap till
  96          needed])],
  97     [AS_IF([test x"$withval" = xyes],
  98         [AC_MSG_WARN([bitmap-later is only used by non-demand-attach
  99             fileservers.  Please migrate to demand-attach instead.])])],
 100     [enable_bitmap_later="no"])
 101 AC_ARG_ENABLE([unix-sockets],
 102     [AS_HELP_STRING([--disable-unix-sockets],
 103         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 104     [],
 105     [enable_unix_sockets="yes"])
 106 AC_ARG_ENABLE([tivoli-tsm],
 107     [AS_HELP_STRING([--enable-tivoli-tsm],
 108         [enable use of the Tivoli TSM API libraries for butc support])],
 109     [],
 110     [enable_tivoli_tsm="no"])
 111 AC_ARG_ENABLE([pthreaded-ubik],
 112     [AS_HELP_STRING([--disable-pthreaded-ubik],
 113         [disable installation of pthreaded ubik applications (defaults to
 114          enabled)])],
 115     [],
 116     [enable_pthreaded_ubik="yes"])
 117
 118 dnl Kernel module build options.
 119 AC_ARG_WITH([linux-kernel-headers],
 120     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 121         [use the kernel headers found at path (optional, defaults to
 122          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
 123          then /usr/src/linux-2.4, and lastly /usr/src/linux)])
 124 ])
 125 AC_ARG_WITH([linux-kernel-build],
 126     [AS_HELP_STRING([--with-linux-kernel-build=path],
 127         [use the kernel build found at path(optional, defaults to
 128         kernel headers path)]
 129 )])
 130 AC_ARG_WITH([bsd-kernel-headers],
 131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 132         [use the kernel headers found at path (optional, defaults to
 133          /usr/src/sys)])
 134 ])
 135 AC_ARG_WITH([bsd-kernel-build],
 136     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 137         [use the kernel build found at path (optional, defaults to
 138          KSRC/i386/compile/GENERIC)])
 139 ])
 140 AC_ARG_WITH([linux-kernel-packaging],
 141     [AS_HELP_STRING([--with-linux-kernel-packaging],
 142         [use standard naming conventions to aid Linux kernel build packaging
 143          (disables MPS, sets the kernel module name to openafs.ko, and
 144          installs kernel modules into the standard Linux location)])],
 145     [AC_SUBST([LINUX_KERNEL_PACKAGING], [yes])
 146      AC_SUBST([LINUX_LIBAFS_NAME], [openafs])],
 147     [AC_SUBST([LINUX_LIBAFS_NAME], [libafs])
 148 ])
 149 AC_ARG_ENABLE([kernel-module],
 150     [AS_HELP_STRING([--disable-kernel-module],
 151         [disable compilation of the kernel module (defaults to enabled)])],
 152     [],
 153     [enable_kernel_module="yes"])
 154 AC_ARG_ENABLE([redhat-buildsys],
 155     [AS_HELP_STRING([--enable-redhat-buildsys],
 156         [enable compilation of the redhat build system kernel (defaults to
 157          disabled)])],
 158     [],
 159     [enable_redhat_buildsys="no"])
 160
 161 dnl Installation locations.
 162 AC_ARG_ENABLE([transarc-paths],
 163     [AS_HELP_STRING([--enable-transarc-paths],
 164         [use Transarc style paths like /usr/afs and /usr/vice])],
 165     [],
 166     [enable_transarc_paths="no"])
 167
 168 dnl Deprecated crypto
 169 AC_ARG_ENABLE([kauth],
 170     [AS_HELP_STRING([--enable-kauth],
 171         [install the deprecated kauth server, pam modules, and utilities
 172          (defaults to disabled)])],
 173     [enable_pam="yes"],
 174     [enable_kauth="no"
 175      enable_pam="no"])
 176
 177 dnl Optimization and debugging flags.
 178 AC_ARG_ENABLE([strip-binaries],
 179     [AS_HELP_STRING([--disable-strip-binaries],
 180         [disable stripping of symbol information from binaries (defaults to
 181          enabled)])],
 182     [],
 183     [enable_strip_binaries="maybe"])
 184 AC_ARG_ENABLE([debug],
 185     [AS_HELP_STRING([--enable-debug],
 186         [enable compilation of the user space code with debugging information
 187          (defaults to disabled)])],
 188     [],
 189     [enable_debug="no"])
 190 AC_ARG_ENABLE([optimize],
 191     [AS_HELP_STRING([--disable-optimize],
 192         [disable optimization for compilation of the user space code (defaults
 193          to enabled)])],
 194     [],
 195     [enable_optimize="yes"])
 196 AC_ARG_ENABLE([warnings],
 197     [AS_HELP_STRING([--enable-warnings],
 198         [enable compilation warnings when building with gcc (defaults to
 199          disabled)])],
 200     [],
 201     [enable_warnings="no"])
 202 AC_ARG_ENABLE([checking],
 203     [AS_HELP_STRING([--enable-checking],
 204         [turn compilation warnings into errors when building with gcc (defaults
 205          to disabled)])],
 206     [enable_checking="$enableval"],
 207     [enable_checking="no"])
 208 AC_ARG_ENABLE([debug-locks],
 209     [AS_HELP_STRING([--enable-debug-locks],
 210         [turn on lock debugging assertions (defaults to disabled)])],
 211     [enable_debug_locks="$enableval"],
 212     [enable_debug_locks="no"])
 213 AC_ARG_ENABLE([debug-kernel],
 214     [AS_HELP_STRING([--enable-debug-kernel],
 215         [enable compilation of the kernel module with debugging information
 216          (defaults to disabled)])],
 217     [],
 218     [enable_debug_kernel="no"])
 219 AC_ARG_ENABLE([optimize-kernel],
 220     [AS_HELP_STRING([--disable-optimize-kernel],
 221         [disable compilation of the kernel module with optimization (defaults
 222          based on platform)])],
 223     [],
 224     [enable_optimize_kernel=""])
 225 AC_ARG_ENABLE([debug-lwp],
 226     [AS_HELP_STRING([--enable-debug-lwp],
 227         [enable compilation of the LWP code with debugging information
 228          (defaults to disabled)])],
 229     [],
 230     [enable_debug_lwp="no"])
 231 AC_ARG_ENABLE([optimize-lwp],
 232     [AS_HELP_STRING([--disable-optimize-lwp],
 233         [disable optimization for compilation of the LWP code (defaults to
 234          enabled)])],
 235     [],
 236     [enable_optimize_lwp="yes"])
 237 AC_ARG_ENABLE([debug-pam],
 238     [AS_HELP_STRING([--enable-debug-pam],
 239         [enable compilation of the PAM code with debugging information
 240          (defaults to disabled)])],
 241     [],
 242     [enable_debug_pam="no"])
 243 AC_ARG_ENABLE([optimize-pam],
 244     [AS_HELP_STRING([--disable-optimize-pam],
 245         [disable optimization for compilation of the PAM code (defaults to
 246          enabled)])],
 247     [],
 248     [enable_optimize_pam="yes"])
 249 AC_ARG_ENABLE([linux-syscall-probing],
 250     [AS_HELP_STRING([--enable-linux-syscall-probing],
 251         [enable Linux syscall probing (defaults to autodetect)])],
 252     [],
 253     [enable_linux_syscall_probing="maybe"])
 254 AC_ARG_WITH([crosstools-dir],
 255     [AS_HELP_STRING([--with-crosstools-dir=path],
 256         [use path for native versions of rxgen, compile_et and config])
 257 ])
 258
 259 AC_ARG_WITH([xslt-processor],
 260         AS_HELP_STRING([--with-xslt-processor=ARG],
 261         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 262         [XSLTPROC="$withval"],
 263         [AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo])])
 264
 265 AC_ARG_WITH([html-xsl],
 266         AS_HELP_STRING([--with-html-xsl],
 267         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 268         [HTML_XSL="$withval"],
 269         [HTML_XSL="html/chunk.xsl"])
 270
 271 AC_ARG_WITH([docbook2pdf],
 272         AS_HELP_STRING([--with-docbook2pdf=ARG],
 273         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 274         [DOCBOOK2PDF="$withval"],
 275         [AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo])])
 276
 277 AC_ARG_WITH([docbook-stylesheets],
 278         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 279         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 280         [DOCBOOK_STYLESHEETS="$withval"],
 281         [OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS],
 282                 [/usr/share/xml/docbook/stylesheet/nwalsh/current \
 283                  /usr/share/xml/docbook/stylesheet/nwalsh \
 284                  /usr/share/xml/docbook/xsl-stylesheets \
 285                  /usr/share/sgml/docbook/docbook-xsl-stylesheets \
 286                  /usr/share/sgml/docbook/xsl-stylesheets \
 287                  /usr/share/docbook-xsl \
 288                  /usr/share/sgml/docbkxsl \
 289                  /usr/local/share/xsl/docbook \
 290                  /sw/share/xml/xsl/docbook-xsl \
 291                  /opt/local/share/xsl/docbook-xsl],
 292                 [$HTML_XSL])
 293            AS_IF([test "x$DOCBOOK_STYLESHEETS" = "x"],
 294                 [AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 295            ])
 296         ])
 297
 298 AC_ARG_WITH([dot],
 299         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
 300         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
 301         [], [with_dot="maybe"])
 302
 303 enable_login="no"
 304
 305 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 306 dnl documentation build.
 307 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 308 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 309
 310 dnl Optionally generate graphs with doxygen.
 311 case "$with_dot" in
 312 maybe)
 313     AC_CHECK_PROGS([DOT], [dot])
 314     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
 315     ;;
 316 yes)
 317     HAVE_DOT="yes"
 318     ;;
 319 no)
 320     HAVE_DOT="no"
 321     ;;
 322 *)
 323     HAVE_DOT="yes"
 324     DOT_PATH=$with_dot
 325 esac
 326 AC_SUBST(HAVE_DOT)
 327 AC_SUBST(DOT_PATH)
 328
 329 dnl Checks for UNIX variants.
 330 AC_ISC_POSIX
 331
 332 dnl Various compiler setup.
 333 AC_TYPE_PID_T
 334 AC_TYPE_SIZE_T
 335
 336 dnl Checks for programs.
 337 AC_PROG_INSTALL
 338 AC_PROG_LN_S
 339 AC_PROG_RANLIB
 340 AC_PROG_YACC
 341 AM_PROG_LEX
 342 dnl if we are flex, be lex-compatible
 343 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 344
 345 OPENAFS_FORCE_ABS_INSTALL
 346 OPENAFS_CHECK_BIGENDIAN
 347 OPENAFS_PRINTF_TAKES_Z_LEN
 348
 349 AC_MSG_CHECKING(your OS)
 350 system=$host
 351 case $system in
 352         *-linux*)
 353
 354                 MKAFS_OSTYPE=LINUX
 355                 if test "x$enable_redhat_buildsys" = "xyes"; then
 356                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 357                 fi
 358                 if test "x$enable_kernel_module" = "xyes"; then
 359                  if test "x$with_linux_kernel_headers" != "x"; then
 360                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 361                  else
 362                    for utsdir in "/lib/modules/`uname -r`/build" \
 363                                  "/lib/modules/`uname -r`/source" \
 364                                  "/usr/src/linux-2.4" \
 365                                  "/usr/src/linux"; do
 366                      LINUX_KERNEL_PATH="$utsdir"
 367                      for utsfile in "include/generated/utsrelease.h" \
 368                                     "include/linux/utsrelease.h" \
 369                                     "include/linux/version.h" \
 370                                     "include/linux/version-up.h"; do
 371                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
 372                          break 2
 373                        fi
 374                      done
 375                    done
 376                  fi
 377                  if test "x$with_linux_kernel_build" != "x"; then
 378                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 379                  else
 380                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 381                  fi
 382                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 383                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 384                    LINUX_VERSION="$linux_kvers"
 385                  else
 386                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 387                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 388                      LINUX_VERSION="$linux_kvers"
 389                    else
 390                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 391                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 392                        if test "x$linux_kvers" = "x"; then
 393                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 394                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 395                            if test "x$linux_kvers" = "x"; then
 396                              AC_MSG_ERROR(Linux headers lack version definition [2])
 397                              exit 1
 398                            else
 399                              LINUX_VERSION="$linux_kvers"
 400                            fi
 401                          else
 402                            AC_MSG_ERROR(Linux headers lack version definition)
 403                            exit 1
 404                          fi
 405                        else
 406                          LINUX_VERSION="$linux_kvers"
 407                        fi
 408                      else
 409                        enable_kernel_module="no"
 410                      fi
 411                    fi
 412                  fi
 413                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 414                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 415                      enable_kernel_module="no"
 416                  fi
 417                  if test "x$enable_kernel_module" = "xno"; then
 418                   if test "x$with_linux_kernel_headers" != "x"; then
 419                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 420                    exit 1
 421                   else
 422                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 423                   fi
 424                  fi
 425                  dnl do we need to determine SUBARCH from autoconf.h
 426                  SUBARCH=default
 427                 fi
 428                 AC_MSG_RESULT(linux)
 429                 GUESS_LINUX_VERSION=
 430                 if test "x$enable_kernel_module" = "xyes"; then
 431                  GUESS_LINUX_VERSION=${LINUX_VERSION}
 432                 else
 433                  GUESS_LINUX_VERSION=`uname -r`
 434                 fi
 435                 case "$GUESS_LINUX_VERSION" in
 436                   2.2.*) AFS_SYSKVERS=22 ;;
 437                   2.4.*) AFS_SYSKVERS=24 ;;
 438                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
 439                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 440                 esac
 441                 ;;
 442         *-solaris*)
 443                 MKAFS_OSTYPE=SOLARIS
 444                 AC_MSG_RESULT(sun4)
 445                 AC_PATH_PROG(SOLARISCC, [cc], ,
 446                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 447                 if test "x$SOLARISCC" = "x" ; then
 448                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 449                 fi
 450                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 451                 SOLARIS_FS_HAS_FS_ROLLED
 452                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 453                 SOLARIS_HAVE_VN_RENAMEPATH
 454                 ;;
 455         *-sunos*)
 456                 MKAFS_OSTYPE=SUNOS
 457                 enable_kernel_module=no
 458                 AC_MSG_RESULT(sun4)
 459                 ;;
 460         *-hpux*)
 461                 MKAFS_OSTYPE=HPUX
 462                 AC_MSG_RESULT(hp_ux)
 463                 if test -f "/usr/old/usr/include/ndir.h"; then
 464                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 465                 fi
 466                 ;;
 467         *-irix*)
 468                 if test -d /usr/include/sys/SN/SN1; then
 469                  IRIX_BUILD_IP35="IP35"
 470                 fi
 471                 MKAFS_OSTYPE=IRIX
 472                 AC_MSG_RESULT(sgi)
 473                 ;;
 474         *-aix*)
 475                 MKAFS_OSTYPE=AIX
 476                 AC_MSG_RESULT(rs_aix)
 477                 ;;
 478         arm-*-darwin*)
 479                 MKAFS_OSTYPE=DARWIN
 480                 AC_MSG_RESULT(arm_darwin)
 481                 ;;
 482         powerpc-*-darwin*)
 483                 MKAFS_OSTYPE=DARWIN
 484                 AC_MSG_RESULT(ppc_darwin)
 485                 ;;
 486         i386-*-darwin*)
 487                 MKAFS_OSTYPE=DARWIN
 488                 AC_MSG_RESULT(x86_darwin)
 489                 ;;
 490         x86_64-*-darwin*)
 491                 MKAFS_OSTYPE=DARWIN
 492                 AC_MSG_RESULT(x86_darwin)
 493                 ;;
 494         i386-*-freebsd*)
 495                 MKAFS_OSTYPE=FBSD
 496                 AC_MSG_RESULT(i386_fbsd)
 497                 ;;
 498         x86_64-*-freebsd*)
 499                 MKAFS_OSTYPE=FBSD
 500                 AC_MSG_RESULT(amd64_fbsd)
 501                 ;;
 502         *-netbsd*)
 503                 MKAFS_OSTYPE=NBSD
 504                 AC_MSG_RESULT(nbsd)
 505                 ;;
 506         x86_64-*-openbsd*)
 507                 MKAFS_OSTYPE=OBSD
 508                 AC_MSG_RESULT(amd64_obsd)
 509                 ;;
 510         i386-*-openbsd*)
 511                 MKAFS_OSTYPE=OBSD
 512                 AC_MSG_RESULT(i386_obsd)
 513                 ;;
 514         *-dragonfly*)
 515                 MKAFS_OSTYPE=DFBSD
 516                 AC_MSG_RESULT(i386_dfbsd)
 517                 ;;
 518         *)
 519                 AC_MSG_RESULT($system)
 520                 ;;
 521 esac
 522
 523 if test "x$with_afs_sysname" != "x"; then
 524         AFS_SYSNAME="$with_afs_sysname"
 525 else
 526         AC_MSG_CHECKING(your AFS sysname)
 527         case $host in
 528                 i?86-*-openbsd?.?)
 529                         v=${host#*openbsd}
 530                         vM=${v%.*}
 531                         vm=${v#*.}
 532                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 533                         ;;
 534                 sparc64-*-openbsd?.?)
 535                         v=${host#*openbsd}
 536                         vM=${v%.*}
 537                         vm=${v#*.}
 538                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 539                         ;;
 540                 x86_64-*-openbsd?.?)
 541                         v=${host#*openbsd}
 542                         vM=${v%.*}
 543                         vm=${v#*.}
 544                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 545                         ;;
 546                 i?86-*-freebsd*.*)
 547                         v=${host#*freebsd}
 548                         vM=${v%.*}
 549                         vm=${v#*.}
 550                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 551                         ;;
 552                 x86_64-*-freebsd*.*)
 553                         v=${host#*freebsd}
 554                         vM=${v%.*}
 555                         vm=${v#*.}
 556                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 557                         ;;
 558                 i386-*-dragonfly?.*)
 559                         v=${host#*dragonfly}
 560                         vM=${v%.*}
 561                         vm=${v#*.}
 562                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 563                         ;;
 564                 i?86-*-netbsd*1.6[[M-Z]]*)
 565                         AFS_SYSNAME="i386_nbsd20"
 566                         ;;
 567                 powerpc-*-netbsd*1.6[[M-Z]]*)
 568                         AFS_SYSNAME="ppc_nbsd20"
 569                         ;;
 570                 *-*-netbsd*)
 571                         arch=${host%%-unknown*}
 572                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 573                                                -e 's/powerpc/ppc/g')
 574                         v=${host#*netbsd}
 575                         v=${v#*aout}
 576                         v=${v#*ecoff}
 577                         v=${v#*elf}
 578                         vM=${v%%.*}
 579                         vM=${vM%.*}
 580                         v=${v#*.}
 581                         vm=${v%%.*}
 582                         vm=${vm%.*}
 583                         vm=${vm%%[[_A-Z]]*}
 584                         if test $vm -eq 99 ; then
 585                                 vM=$((vM+1))
 586                         fi
 587                         if test $vM -gt 1 ; then
 588                                 vm=0
 589                         fi
 590                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 591                         ;;
 592                 hppa*-hp-hpux11.0*)
 593                         AFS_SYSNAME="hp_ux110"
 594                         ;;
 595                 hppa*-hp-hpux11.11)
 596                         AFS_SYSNAME="hp_ux11i"
 597                         ;;
 598                 hppa*-hp-hpux11.23)
 599                         AFS_SYSNAME="hp_ux1123"
 600                         ;;
 601                 ia64-hp-hpux11.22)
 602                         AFS_SYSNAME="ia64_hpux1122"
 603                         ;;
 604                 ia64-hp-hpux*)
 605                         AFS_SYSNAME="ia64_hpux1123"
 606                         ;;
 607                 hppa*-hp-hpux10*)
 608                         AFS_SYSNAME="hp_ux102"
 609                         ;;
 610                 powerpc-apple-darwin7*)
 611                         AFS_SYSNAME="ppc_darwin_70"
 612                         OSXSDK="macosx10.3"
 613                         ;;
 614                 powerpc-apple-darwin8.*)
 615                         AFS_SYSNAME="ppc_darwin_80"
 616                         OSXSDK="macosx10.4"
 617                         ;;
 618                 i386-apple-darwin8.*)
 619                         AFS_SYSNAME="x86_darwin_80"
 620                         OSXSDK="macosx10.4"
 621                         ;;
 622                 powerpc-apple-darwin9.*)
 623                         AFS_SYSNAME="ppc_darwin_90"
 624                         OSXSDK="macosx10.5"
 625                         ;;
 626                 i386-apple-darwin9.*)
 627                         AFS_SYSNAME="x86_darwin_90"
 628                         OSXSDK="macosx10.5"
 629                         ;;
 630                 i?86-apple-darwin10.*)
 631                         AFS_SYSNAME="x86_darwin_100"
 632                         OSXSDK="macosx10.6"
 633                         ;;
 634                 x86_64-apple-darwin10.*)
 635                         AFS_SYSNAME="x86_darwin_100"
 636                         OSXSDK="macosx10.6"
 637                         ;;
 638                 arm-apple-darwin10.*)
 639                         AFS_SYSNAME="arm_darwin_100"
 640                         OSXSDK="iphoneos4.0"
 641                         ;;
 642                 x86_64-apple-darwin11.*)
 643                         AFS_SYSNAME="x86_darwin_110"
 644                         OSXSDK="macosx10.7"
 645                         ;;
 646                 i?86-apple-darwin11.*)
 647                         AFS_SYSNAME="x86_darwin_110"
 648                         OSXSDK="macosx10.7"
 649                         ;;
 650                 x86_64-apple-darwin12.*)
 651                         AFS_SYSNAME="x86_darwin_120"
 652                         OSXSDK="macosx10.8"
 653                         ;;
 654                 i?86-apple-darwin12.*)
 655                         AFS_SYSNAME="x86_darwin_120"
 656                         OSXSDK="macosx10.8"
 657                         ;;
 658                 x86_64-apple-darwin13.*)
 659                         AFS_SYSNAME="x86_darwin_130"
 660                         OSXSDK="macosx10.9"
 661                         ;;
 662                 i?86-apple-darwin13.*)
 663                         AFS_SYSNAME="x86_darwin_130"
 664                         OSXSDK="macosx10.9"
 665                         ;;
 666                 x86_64-apple-darwin14.*)
 667                         AFS_SYSNAME="x86_darwin_140"
 668                         OSXSDK="macosx10.10"
 669                         ;;
 670                 i?86-apple-darwin14.*)
 671                         AFS_SYSNAME="x86_darwin_140"
 672                         OSXSDK="macosx10.10"
 673                         ;;
 674                 sparc-sun-solaris2.8)
 675                         AFS_SYSNAME="sun4x_58"
 676                         ;;
 677                 sparc-sun-solaris2.9)
 678                         AFS_SYSNAME="sun4x_59"
 679                         ;;
 680                 sparc-sun-solaris2.10)
 681                         AFS_SYSNAME="sun4x_510"
 682                         ;;
 683                 sparc-sun-solaris2.11)
 684                         AFS_SYSNAME="sun4x_511"
 685                         ;;
 686                 i386-pc-solaris2.8)
 687                         AFS_SYSNAME="sunx86_58"
 688                         ;;
 689                 i386-pc-solaris2.9)
 690                         AFS_SYSNAME="sunx86_59"
 691                         ;;
 692                 i386-pc-solaris2.10)
 693                         AFS_SYSNAME="sunx86_510"
 694                         ;;
 695                 i386-pc-solaris2.11)
 696                         AFS_SYSNAME="sunx86_511"
 697                         ;;
 698                 alpha*-dec-osf4.0*)
 699                         AFS_SYSNAME="alpha_dux40"
 700                         ;;
 701                 alpha*-dec-osf5.0*)
 702                         AFS_SYSNAME="alpha_dux50"
 703                         ;;
 704                 alpha*-dec-osf5.1*)
 705                         AFS_SYSNAME="alpha_dux51"
 706                         ;;
 707                 mips-sgi-irix6.5)
 708                         AFS_SYSNAME="sgi_65"
 709                         enable_pam="no"
 710                         ;;
 711                 ia64-*-linux*)
 712                         AFS_SYSNAME="ia64_linuxXX"
 713                         ;;
 714                 powerpc-*-linux*)
 715                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 716                         ;;
 717                 powerpc64-*-linux*)
 718                         AFS_SYSNAME="ppc64_linuxXX"
 719                         ;;
 720                 alpha*-linux*)
 721                         AFS_SYSNAME="alpha_linux_XX"
 722                         ;;
 723                 s390-*-linux*)
 724                         AFS_SYSNAME="s390_linuxXX"
 725                         ;;
 726                 s390x-*-linux*)
 727                         AFS_SYSNAME="s390x_linuxXX"
 728                         ;;
 729                 sparc-*-linux*)
 730                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 731                         ;;
 732                 sparc64-*-linux*)
 733                         AFS_SYSNAME="sparc64_linuxXX"
 734                         ;;
 735                 i?86-*-linux*)
 736                         AFS_SYSNAME="i386_linuxXX"
 737                         ;;
 738                 arm*-linux*)
 739                         AFS_SYSNAME="arm_linuxXX"
 740                         ;;
 741                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 742                         AFS_SYSNAME="parisc_linuxXX"
 743                         enable_pam="no"
 744                         ;;
 745                 power*-ibm-aix4.2*)
 746                         AFS_SYSNAME="rs_aix42"
 747                         enable_pam="no"
 748                         ;;
 749                 power*-ibm-aix4.3*)
 750                         AFS_SYSNAME="rs_aix42"
 751                         enable_pam="no"
 752                         ;;
 753                 power*-ibm-aix5.1*)
 754                         AFS_SYSNAME="rs_aix51"
 755                         enable_pam="no"
 756                         ;;
 757                 power*-ibm-aix5.2*)
 758                         AFS_SYSNAME="rs_aix52"
 759                         enable_pam="no"
 760                         ;;
 761                 power*-ibm-aix5.3*)
 762                         AFS_SYSNAME="rs_aix53"
 763                         enable_pam="no"
 764                         ;;
 765                 power*-ibm-aix6.1*)
 766                         AFS_SYSNAME="rs_aix61"
 767                         enable_pam="no"
 768                         ;;
 769                 x86_64-*-linux-gnu)
 770                         AFS_SYSNAME="amd64_linuxXX"
 771                         enable_pam="yes"
 772                         ;;
 773                 *)
 774                         AC_MSG_ERROR(An AFS sysname is required)
 775                         exit 1
 776                         ;;
 777         esac
 778         case $AFS_SYSNAME in
 779                 *_linux* | *_umlinux*)
 780                         if test "x${AFS_SYSKVERS}" = "x"; then
 781                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 782                         fi
 783                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 784                         AFS_SYSNAME="$_AFS_SYSNAME"
 785                         AC_TRY_KBUILD(
 786                          [],
 787                          [#ifndef CONFIG_USERMODE
 788                           #error not UML
 789                           #endif],
 790                          ac_cv_linux_is_uml=yes,)
 791                         if test "${ac_cv_linux_is_uml}" = yes; then
 792                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 793                         fi
 794                         AFS_SYSNAME="$_AFS_SYSNAME"
 795                         ;;
 796         esac
 797         AC_MSG_RESULT($AFS_SYSNAME)
 798 fi
 799
 800 case $AFS_SYSNAME in
 801         *_darwin*)
 802                 AC_CHECK_HEADERS(crt_externs.h)
 803                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 804                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 805                 AC_SUBST(OSXSDK)
 806                 ;;
 807 esac
 808
 809 dnl Some hosts have a separate common param file they should include.  Figure
 810 dnl out if we're on one of them now that we know the sysname.
 811 case $AFS_SYSNAME in
 812     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 813     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 814     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 815     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 816     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 817     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 818     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 819     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 820     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
 821     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 822     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 823     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 824     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 825     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 826     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 827     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 828     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 829     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 830     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 831     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 832     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 833     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 834     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 835     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 836     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 837     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 838     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 839     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
 840     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
 841     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
 842     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
 843     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
 844     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
 845     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 846     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 847     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 848 # Linux alpha adds an extra underscore for no good reason.
 849     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 850     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 851     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 852     *_fbsd_*)   AFS_PARAM_COMMON=param.generic_fbsd.h ;;
 853 esac
 854
 855 OPENAFS_OSCONF
 856
 857 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 858
 859                 # Add (sub-) architecture-specific paths needed by conftests
 860                 case $AFS_SYSNAME  in
 861                         *_umlinux26)
 862                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 863                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 864                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 865                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 866                 esac
 867
 868                 if test "x$enable_kernel_module" = "xyes"; then
 869                  if test "x$enable_debug_kernel" = "xno"; then
 870                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 871                  fi
 872                  OPENAFS_GCC_SUPPORTS_MARCH
 873                  AC_SUBST(P5PLUS_KOPTS)
 874                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 875                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 876                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 877                  OPENAFS_GCC_SUPPORTS_PIPE
 878                  AC_SUBST(LINUX_GCC_KOPTS)
 879
 880                  dnl Setup the kernel build environment
 881                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 882                  LINUX_KERNEL_COMPILE_WORKS
 883
 884                  dnl Check for header files
 885                  AC_CHECK_LINUX_HEADER([config.h])
 886                  AC_CHECK_LINUX_HEADER([completion.h])
 887                  AC_CHECK_LINUX_HEADER([exportfs.h])
 888                  AC_CHECK_LINUX_HEADER([freezer.h])
 889                  AC_CHECK_LINUX_HEADER([key-type.h])
 890                  AC_CHECK_LINUX_HEADER([semaphore.h])
 891                  AC_CHECK_LINUX_HEADER([seq_file.h])
 892
 893                  dnl Type existence checks
 894                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 895                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
 896
 897                  dnl Check for structure elements
 898                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 899                                        [write_begin], [fs.h])
 900                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 901                                        [backing-dev.h])
 902                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
 903                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 904                  AC_CHECK_LINUX_STRUCT([dentry], [d_u.d_alias], [dcache.h])
 905                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 906                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 907                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 908                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 909                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 910                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 911                  AC_CHECK_LINUX_STRUCT([file], [f_path], [fs.h])
 912                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 913                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
 914                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
 915                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 916                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 917                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
 918                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
 919                  AC_CHECK_LINUX_STRUCT([key_type], [match_preparse], [key-type.h])
 920                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
 921                  AC_CHECK_LINUX_STRUCT([msghdr], [msg_iter], [socket.h])
 922                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 923                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 924                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 925                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 926                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 927                                        [fs.h])
 928                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 929                                        [fs.h])
 930                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 931                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 932                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 933                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 934                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 935                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 936                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 937                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 938                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 939                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 940                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 941
 942                  dnl Check for typed structure elements
 943                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 944                                              [buf], [fs.h])
 945
 946                  dnl Function existence checks
 947
 948                  AC_CHECK_LINUX_FUNC([bdi_init],
 949                                      [#include <linux/backing-dev.h>],
 950                                      [bdi_init(NULL);])
 951                  AC_CHECK_LINUX_FUNC([PageChecked],
 952                                      [#include <linux/mm.h>
 953 #include <linux/page-flags.h>],
 954                                      [struct page *_page;
 955                                       int bchecked = PageChecked(_page);])
 956                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 957                                      [#include <linux/mm.h>
 958 #include <linux/page-flags.h>],
 959                                      [struct page *_page;
 960                                       int bchecked = PageFsMisc(_page);])
 961                  AC_CHECK_LINUX_FUNC([clear_inode],
 962                                      [#include <linux/fs.h>],
 963                                      [clear_inode(NULL);])
 964                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 965                                      [#include <linux/time.h>],
 966                                      [struct timespec s;
 967                                       s = current_kernel_time();])
 968                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 969                                      [#include <linux/fs.h>],
 970                                      [d_alloc_anon(NULL);])
 971                  AC_CHECK_LINUX_FUNC([d_count],
 972                                      [#include <linux/dcache.h>],
 973                                      [d_count(NULL);])
 974                  AC_CHECK_LINUX_FUNC([d_make_root],
 975                                      [#include <linux/fs.h>],
 976                                      [d_make_root(NULL);])
 977                  AC_CHECK_LINUX_FUNC([do_sync_read],
 978                                      [#include <linux/fs.h>],
 979                                      [do_sync_read(NULL, NULL, 0, NULL);])
 980                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 981                                      [#include <linux/sched.h>],
 982                                      [pid_t p; find_task_by_pid(p);])
 983                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 984                                      [#include <linux/fs.h>],
 985                                      [generic_file_aio_read(NULL,NULL,0,0);])
 986                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 987                                      [#include <linux/pagemap.h>],
 988                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 989                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 990                                      [#include <linux/list.h>],
 991                                      [hlist_unhashed(0);])
 992                  AC_CHECK_LINUX_FUNC([i_size_read],
 993                                      [#include <linux/fs.h>],
 994                                      [i_size_read(NULL);])
 995                  AC_CHECK_LINUX_FUNC([inode_setattr],
 996                                      [#include <linux/fs.h>],
 997                                      [inode_setattr(NULL, NULL);])
 998                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
 999                                      [#include <linux/fs.h>],
1000                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
1001                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
1002                                      [#include <linux/net.h>],
1003                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
1004                  AC_CHECK_LINUX_FUNC([page_follow_link],
1005                                      [#include <linux/fs.h>],
1006                                      [page_follow_link(0,0);])
1007                  AC_CHECK_LINUX_FUNC([page_offset],
1008                                      [#include <linux/pagemap.h>],
1009                                      [page_offset(NULL);])
1010                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
1011                                      [#include <linux/pagevec.h>],
1012                                      [__pagevec_lru_add_file(NULL);])
1013                  AC_CHECK_LINUX_FUNC([path_lookup],
1014                                      [#include <linux/fs.h>
1015                                       #include <linux/namei.h>],
1016                                      [path_lookup(NULL, 0, NULL);])
1017                  AC_CHECK_LINUX_FUNC([proc_create],
1018                                      [#include <linux/proc_fs.h>],
1019                                      [proc_create(NULL, 0, NULL, NULL);])
1020                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
1021                                      [#include <linux/rcupdate.h>],
1022                                      [rcu_read_lock();])
1023                  AC_CHECK_LINUX_FUNC([set_nlink],
1024                                      [#include <linux/fs.h>],
1025                                      [set_nlink(NULL, 1);])
1026                  AC_CHECK_LINUX_FUNC([sock_create_kern],
1027                                      [#include <linux/net.h>],
1028                                      [sock_create_kern(0, 0, 0, NULL);])
1029                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
1030                                      [#include <linux/splice.h>],
1031                                      [splice_direct_to_actor(NULL,NULL,NULL);])
1032                  AC_CHECK_LINUX_FUNC([svc_addr_in],
1033                                      [#include <linux/sunrpc/svc.h>],
1034                                      [svc_addr_in(NULL);])
1035                  AC_CHECK_LINUX_FUNC([zero_user_segments],
1036                                      [#include <linux/highmem.h>],
1037                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1038                  AC_CHECK_LINUX_FUNC([noop_fsync],
1039                                      [#include <linux/fs.h>],
1040                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1041                  AC_CHECK_LINUX_FUNC([kthread_run],
1042                                      [#include <linux/kernel.h>
1043                                       #include <linux/kthread.h>],
1044                                      [kthread_run(NULL, NULL, "test");])
1045
1046                  dnl Consequences - things which get set as a result of the
1047                  dnl                above tests
1048                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1049                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1050                                   [define to disable the nfs translator])])
1051
1052                  dnl Assorted more complex tests
1053                  LINUX_AIO_NONVECTOR
1054                  LINUX_EXPORTS_PROC_ROOT_FS
1055                  LINUX_KMEM_CACHE_INIT
1056                  LINUX_HAVE_KMEM_CACHE_T
1057                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1058                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1059                  LINUX_D_PATH_TAKES_STRUCT_PATH
1060                  LINUX_NEW_EXPORT_OPS
1061                  LINUX_INODE_SETATTR_RETURN_TYPE
1062                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1063                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1064                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1065                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1066                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1067                  LINUX_DOP_D_DELETE_TAKES_CONST
1068                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1069                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1070                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1071                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1072                  LINUX_AOP_WRITEBACK_CONTROL
1073                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1074                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1075                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1076                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1077                  LINUX_KERNEL_SOCK_CREATE
1078                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1079                  LINUX_NEED_RHCONFIG
1080                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1081                  LINUX_EXPORTS_TASKLIST_LOCK
1082                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1083                  LINUX_STATFS_TAKES_DENTRY
1084                  LINUX_REFRIGERATOR
1085                  LINUX_HAVE_TRY_TO_FREEZE
1086                  LINUX_LINUX_KEYRING_SUPPORT
1087                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1088                  LINUX_KEY_ALLOC_NEEDS_CRED
1089                  LINUX_INIT_WORK_HAS_DATA
1090                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1091                  LINUX_HAVE_DCACHE_LOCK
1092                  LINUX_D_COUNT_IS_INT
1093                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1094                  LINUX_IOP_CREATE_TAKES_UMODE_T
1095                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1096                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1097                  LINUX_DENTRY_OPEN_TAKES_PATH
1098                  LINUX_D_ALIAS_IS_HLIST
1099                  LINUX_HLIST_ITERATOR_NO_NODE
1100                  LINUX_IOP_I_CREATE_TAKES_BOOL
1101                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1102                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1103                  LINUX_D_INVALIDATE_IS_VOID
1104
1105                  dnl If we are guaranteed that keyrings will work - that is
1106                  dnl  a) The kernel has keyrings enabled
1107                  dnl  b) The code is new enough to give us a key_type_keyring
1108                  dnl then we just disable syscall probing unless we've been
1109                  dnl told otherwise
1110
1111                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1112                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1113                           [enable_linux_syscall_probing="no"],
1114                           [enable_linux_syscall_probing="yes"])
1115                  ])
1116
1117                  dnl Syscall probing needs a few tests of its own, and just
1118                  dnl won't work if the kernel doesn't export init_mm
1119                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1120                    LINUX_EXPORTS_INIT_MM
1121                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1122                      AC_MSG_ERROR(
1123                        [Can't do syscall probing without exported init_mm])
1124                    ])
1125                    LINUX_EXPORTS_SYS_CHDIR
1126                    LINUX_EXPORTS_SYS_OPEN
1127                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1128                              [define to enable syscall table probes])
1129                  ])
1130
1131                  dnl Packaging and SMP build
1132                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1133                    LINUX_WHICH_MODULES
1134                  else
1135                    AC_SUBST(MPS,'SP')
1136                  fi
1137
1138                  dnl Syscall probing
1139                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1140                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1141                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1142                    ])
1143                    ac_cv_linux_exports_sys_call_table=no
1144                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1145                      ac_cv_linux_exports_ia32_sys_call_table=yes
1146                    fi
1147                  else
1148                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1149                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1150                    LINUX_EXPORTS_SYS_CALL_TABLE
1151                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1152                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1153                          linux_syscall_method=none
1154                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1155                             linux_syscall_method=scan
1156                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1157                                linux_syscall_method=scan_with_kallsyms_address
1158                             fi
1159                          fi
1160                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1161                             linux_syscall_method=kallsyms_symbol
1162                          fi
1163                          if test "x$linux_syscall_method" = "xnone"; then
1164                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1165                             linux_syscall_method=scan
1166                          fi
1167                    fi
1168                  fi
1169                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1170                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1171                  fi
1172                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1173                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1174                  fi
1175                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1176                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1177                  else
1178                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1179                  fi
1180                 :
1181                 fi
1182 dnl Linux-only, but just enable always.
1183                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1184 esac
1185
1186 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1187     [ac_cv_sync_fetch_and_add],
1188     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1189                     [ac_cv_sync_fetch_and_add=yes],
1190                     [ac_cv_sync_fetch_and_add=no])
1191 ])
1192 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1193       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1194                 [define if your C compiler has __sync_add_and_fetch])])
1195
1196 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1197     [ac_cv_sockaddr_len],
1198     [AC_TRY_COMPILE( [#include <sys/types.h>
1199 #include <sys/socket.h>],
1200                      [struct sockaddr *a; a->sa_len=0;],
1201                      [ac_cv_sockaddr_len=yes],
1202                      [ac_cv_sockaddr_len=no])
1203 ])
1204 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1205       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1206                  [define if you struct sockaddr sa_len])])
1207
1208 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1209         echo Skipping library tests because they confuse Irix.
1210 else
1211   AC_SEARCH_LIBS([socket], [socket inet])
1212   AC_SEARCH_LIBS([connect], [nsl])
1213   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1214
1215   dnl darwin wants it, aix hates it
1216   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1217   AC_TRY_COMPILE([
1218   #include <stdlib.h>
1219   #include <stdio.h>
1220   #include <sys/types.h>
1221   #include <sys/socket.h>
1222   #include <netinet/in.h>
1223   #include <arpa/inet.h>
1224   #include <arpa/nameser.h>
1225   #include <arpa/nameser_compat.h>
1226   #include <resolv.h>
1227   ], [static int i; i = 0;],
1228   [AC_MSG_RESULT(yes)
1229    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1230   [AC_MSG_RESULT(no)
1231    ])
1232
1233   openafs_save_libs="$LIBS"
1234   AC_MSG_CHECKING([for res_search])
1235   AC_FUNC_RES_SEARCH
1236
1237   if test "$ac_cv_func_res_search" = no; then
1238       for lib in dns nsl resolv; do
1239         if test "$ac_cv_func_res_search" != yes; then
1240           LIBS="-l$lib $LIBS"
1241           AC_FUNC_RES_SEARCH
1242           LIBS="$openafs_save_libs"
1243         fi
1244       done
1245       if test "$ac_cv_func_res_search" = yes; then
1246         LIB_AFSDB="-l$lib"
1247         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1248         AC_MSG_RESULT([yes, in lib$lib])
1249       else
1250         AC_MSG_RESULT(no)
1251       fi
1252   else
1253     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1254     AC_MSG_RESULT(yes)
1255   fi
1256
1257 fi
1258 XLIBS="$LIB_AFSDB $XLIBS"
1259
1260 AC_CHECK_RESOLV_RETRANS
1261
1262 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1263     [ac_cv_setsockopt_iprecverr],
1264     [AC_TRY_COMPILE( [
1265 #include <sys/types.h>
1266 #include <sys/socket.h>
1267 #include <netinet/in.h>],
1268 [int on=1;
1269 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1270         [ac_cv_setsockopt_iprecverr=yes],
1271         [ac_cv_setsockopt_iprecverr=no])])
1272
1273 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1274       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1275                  [define if we can receive socket errors via IP_RECVERR])])
1276
1277 PTHREAD_LIBS=error
1278 if test "x$MKAFS_OSTYPE" = OBSD; then
1279         PTHREAD_LIBS="-pthread"
1280 fi
1281 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1282         PTHREAD_LIBS="-pthread"
1283 fi
1284 if test "x$PTHREAD_LIBS" = xerror; then
1285         AC_CHECK_LIB(pthread, pthread_attr_init,
1286                 PTHREAD_LIBS="-lpthread")
1287 fi
1288 if test "x$PTHREAD_LIBS" = xerror; then
1289         AC_CHECK_LIB(pthreads, pthread_attr_init,
1290                 PTHREAD_LIBS="-lpthreads")
1291 fi
1292 if test "x$PTHREAD_LIBS" = xerror; then
1293         AC_CHECK_LIB(c_r, pthread_attr_init,
1294                 PTHREAD_LIBS="-lc_r")
1295 fi
1296 if test "x$PTHREAD_LIBS" = xerror; then
1297         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1298 fi
1299 if test "x$PTHREAD_LIBS" = xerror; then
1300         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1301         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1302                 PTHREAD_LIBS="-lpthread")
1303 fi
1304 if test "x$PTHREAD_LIBS" = xerror; then
1305         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1306 fi
1307 AC_SUBST(PTHREAD_LIBS)
1308
1309 HOST_CPU="$host_cpu"
1310
1311 if test "x$with_bsd_kernel_headers" != "x"; then
1312         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1313 else
1314         BSD_KERNEL_PATH="/usr/src/sys"
1315 fi
1316
1317 if test "x$with_bsd_kernel_build" != "x"; then
1318         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1319 else
1320         case $AFS_SYSNAME in
1321                 *_fbsd_*)
1322                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1323                         ;;
1324                 *_nbsd*)
1325                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1326         esac
1327 fi
1328
1329 # Fast restart
1330 if test "$enable_supergroups" = "yes"; then
1331         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1332 fi
1333
1334 if test "$enable_bitmap_later" = "yes"; then
1335         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1336 fi
1337
1338 if test "$enable_unix_sockets" = "yes"; then
1339         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1340         USE_UNIX_SOCKETS="yes"
1341 else
1342         USE_UNIX_SOCKETS="no"
1343 fi
1344 AC_SUBST(USE_UNIX_SOCKETS)
1345
1346 if test "$enable_namei_fileserver" = "yes"; then
1347         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1348         VFSCK=""
1349 else
1350         if test "$enable_namei_fileserver" = "default"; then
1351                 case $host in
1352                         *-solaris2.10*)
1353                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1354                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1355                                 VFSCK=""
1356                                 ;;
1357                         *-solaris2.11*)
1358                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1359                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1360                                 VFSCK=""
1361                                 ;;
1362                         *)
1363                                 VFSCK="vfsck"
1364                                 ;;
1365                 esac
1366         else
1367                 VFSCK="vfsck"
1368         fi
1369 fi
1370
1371 dnl check for tivoli
1372 AC_MSG_CHECKING(for tivoli tsm butc support)
1373 XBSA_CFLAGS=""
1374 if test "$enable_tivoli_tsm" = "yes"; then
1375         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1376         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1377         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1378         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1379
1380         if test -r "$XBSADIR3/dsmapifp.h"; then
1381                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1382                 XBSA_XLIBS="-ldl"
1383                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1384         elif test -r "$XBSADIR4/dsmapifp.h"; then
1385                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1386                 XBSA_XLIBS="-ldl"
1387                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1388         elif test -r "$XBSADIR1/xbsa.h"; then
1389                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1390                 XBSA_XLIBS=""
1391                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1392         elif test -r "$XBSADIR2/xbsa.h"; then
1393                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1394                 XBSA_XLIBS=""
1395                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1396         else
1397                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1398         fi
1399 else
1400         AC_MSG_RESULT([no])
1401 fi
1402 AC_SUBST(XBSA_CFLAGS)
1403 AC_SUBST(XBSA_XLIBS)
1404
1405 dnl checks for header files.
1406 AC_HEADER_STDC
1407 AC_HEADER_SYS_WAIT
1408 AC_HEADER_DIRENT
1409 AC_CHECK_HEADERS([ \
1410                    arpa/inet.h \
1411                    arpa/nameser.h \
1412                    curses.h\
1413                    direct.h \
1414                    errno.h \
1415                    fcntl.h \
1416                    grp.h \
1417                    math.h \
1418                    mntent.h \
1419                    ncurses.h \
1420                    ncurses/ncurses.h \
1421                    netdb.h \
1422                    netinet/in.h \
1423                    pthread_np.h \
1424                    pwd.h \
1425                    regex.h \
1426                    security/pam_appl.h \
1427                    signal.h \
1428                    stdint.h \
1429                    stdio_ext.h \
1430                    stdlib.h \
1431                    string.h \
1432                    strings.h \
1433                    sys/bitypes.h \
1434                    sys/bswap.h \
1435                    sys/dk.h \
1436                    sys/fcntl.h \
1437                    sys/file.h \
1438                    sys/fs_types.h \
1439                    sys/fstyp.h \
1440                    sys/ioctl.h \
1441                    sys/ipc.h \
1442                    sys/lockf.h \
1443                    sys/map.h \
1444                    sys/mount.h \
1445                    sys/mntent.h \
1446                    sys/mnttab.h \
1447                    sys/pag.h \
1448                    sys/param.h \
1449                    sys/resource.h \
1450                    sys/select.h \
1451                    sys/statfs.h \
1452                    sys/statvfs.h \
1453                    sys/socket.h \
1454                    sys/sysctl.h \
1455                    sys/time.h \
1456                    sys/types.h \
1457                    sys/uio.h \
1458                    sys/un.h \
1459                    sys/vfs.h \
1460                    syslog.h \
1461                    termios.h \
1462                    time.h \
1463                    ucontext.h \
1464                    unistd.h \
1465                    windows.h \
1466                 ])
1467
1468 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1469 #ifdef HAVE_NETINET_IN_H
1470 # include <netinet/in.h>
1471 #endif])
1472
1473 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1474 #ifdef HAVE_SYS_SOCKET_H
1475 # include <sys/socket.h>
1476 #endif])
1477
1478 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1479 #ifdef HAVE_SYS_SOCKET_H
1480 # include <sys/socket.h>
1481 #endif
1482 #ifdef HAVE_NETINET_IN_H
1483 # include <netinet/in.h>
1484 #endif
1485 #ifdef HAVE_NET_IF_H
1486 # include <net/if.h>
1487 #endif])
1488
1489 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1490 #ifdef HAVE_SECURITY_PAM_APPL_H
1491 # include <security/pam_appl.h>
1492 #endif])
1493
1494 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1495
1496 AC_CHECK_TYPES([fsblkcnt_t],,,[
1497 #include <sys/types.h>
1498 #ifdef HAVE_SYS_BITYPES_H
1499 #include <sys/bitypes.h>
1500 #endif
1501 #ifdef HAVE_SYS_STATFS_H
1502 #include <sys/statfs.h>
1503 #endif
1504 #ifdef HAVE_SYS_STATVFS_H
1505 #include <sys/statvfs.h>
1506 #endif
1507 ])
1508
1509 dnl see what struct stat has for timestamps
1510 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1511
1512 dnl check for curses-lib
1513 AS_IF([test "x$enable_gtx" != "xno"],
1514       [save_LIBS=$LIBS
1515       AC_CHECK_LIB( [ncurses], [setupterm],
1516       [LIB_curses=-lncurses],
1517         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1518           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1519       ])
1520       LIBS=$save_LIBS
1521       AC_SUBST(LIB_curses)])
1522
1523 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1524
1525 if test "$enable_debug_locks" = yes; then
1526         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1527 fi
1528
1529 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1530         HAVE_PAM="YES"
1531 else
1532         HAVE_PAM="no"
1533 fi
1534 AC_SUBST(HAVE_PAM)
1535
1536 if test "$enable_login" = yes; then
1537         BUILD_LOGIN="yes"
1538 else
1539         BUILD_LOGIN="no"
1540 fi
1541 AC_SUBST(BUILD_LOGIN)
1542
1543 if test "$enable_kauth" = yes; then
1544         INSTALL_KAUTH="yes"
1545 else
1546         INSTALL_KAUTH="no"
1547 fi
1548 AC_SUBST(INSTALL_KAUTH)
1549
1550 AC_CHECK_FUNCS([ \
1551         arc4random \
1552         fcntl \
1553         fseeko64 \
1554         ftello64 \
1555         getcwd \
1556         getegid \
1557         geteuid \
1558         getgid \
1559         getuid \
1560         getrlimit \
1561         issetugid \
1562         mkstemp \
1563         poll \
1564         pread \
1565         preadv \
1566         preadv64 \
1567         pwrite \
1568         pwritev \
1569         pwritev64 \
1570         regcomp \
1571         regerror \
1572         regexec \
1573         setitimer \
1574         setvbuf \
1575         sigaction \
1576         strcasestr \
1577         strerror \
1578         sysconf \
1579         sysctl \
1580         tdestroy \
1581         timegm \
1582 ])
1583
1584 OPENAFS_ROKEN()
1585 OPENAFS_HCRYPTO()
1586 OPENAFS_C_ATTRIBUTE()
1587
1588 dnl Functions that Heimdal's libroken provides, but that we
1589 dnl haven't found a need for yet, and so haven't imported
1590 AC_CHECK_FUNCS([ \
1591         chown \
1592         fchown \
1593         gethostname \
1594         lstat \
1595         inet_aton \
1596         putenv \
1597         readv \
1598         setenv \
1599         strdup \
1600         strftime \
1601         strndup \
1602         strsep \
1603         unsetenv \
1604 ])
1605
1606 dnl Functions that are in objects that we always build from libroken
1607 AC_CHECK_FUNCS([ \
1608         asprintf \
1609         asnprintf \
1610         vasprintf \
1611         vasnprintf \
1612         vsnprintf \
1613         snprintf \
1614 ])
1615
1616 dnl Functions that we're going to try and get from libroken
1617 AC_REPLACE_FUNCS([ \
1618         daemon \
1619         ecalloc \
1620         emalloc \
1621         erealloc \
1622         err \
1623         errx \
1624         flock \
1625         freeaddrinfo \
1626         gai_strerror \
1627         getaddrinfo \
1628         getdtablesize \
1629         getnameinfo \
1630         getopt \
1631         getprogname \
1632         gettimeofday \
1633         inet_ntop \
1634         inet_pton \
1635         localtime_r \
1636         mkstemp \
1637         setenv \
1638         setprogname \
1639         strcasecmp \
1640         strlcat \
1641         strnlen \
1642         strlcpy \
1643         strsep \
1644         tdelete \
1645         tfind \
1646         tsearch \
1647         twalk \
1648         unsetenv \
1649         verr \
1650         verrx \
1651         vsyslog \
1652         vwarn \
1653         vwarnx \
1654         warn \
1655         warnx \
1656 ])
1657
1658 dnl Headers that we're going to try and get from libroken
1659 AC_CHECK_HEADERS([ \
1660         err.h \
1661         search.h \
1662 ])
1663
1664 AC_CHECK_DECLS([h_errno], [], [], [
1665 #include <sys/types.h>
1666 #ifdef HAVE_NETDB_H
1667 #include <netdb.h>
1668 #endif
1669 ])
1670
1671 AC_HEADER_TIME
1672
1673 ROKEN_HEADERS=
1674 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1675       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1676       [])
1677 AC_SUBST(ROKEN_HEADERS)
1678
1679 dnl Stuff that's harder ...
1680 AC_MSG_CHECKING([for bswap16])
1681 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1682 #ifdef HAVE_SYS_TYPES_H
1683 #include <sys/types.h>
1684 #endif
1685 #ifdef HAVE_SYS_BSWAP_H
1686 #include <sys/bswap.h>
1687 #endif
1688 ],
1689 [short a, b; b = bswap16(a); ])],
1690 [AC_MSG_RESULT(yes)
1691  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1692 ],
1693 [AC_MSG_RESULT(no)])
1694
1695 AC_MSG_CHECKING([for bswap32])
1696 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1697 #include <sys/types.h>
1698 #endif
1699 #ifdef HAVE_SYS_BSWAP_H
1700 #include <sys/bswap.h>
1701 #endif
1702 ],
1703 [int a, b; b = bswap32(a); ])],
1704 [AC_MSG_RESULT(yes)
1705  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1706 ],
1707 [AC_MSG_RESULT(no)])
1708
1709 case $AFS_SYSNAME in
1710 *hp_ux* | *hpux*)
1711    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1712    ;;
1713 *)
1714    AC_MSG_CHECKING([for positional I/O])
1715    if test "$ac_cv_func_pread" = "yes" && \
1716            test "$ac_cv_func_pwrite" = "yes"; then
1717       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1718       AC_MSG_RESULT(yes)
1719    else
1720      AC_MSG_RESULT(no)
1721    fi
1722    AC_MSG_CHECKING([for vectored positional I/O])
1723    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1724                "$ac_cv_func_pwritev" = "yes" -a \
1725                "$ac_cv_func_preadv64" = "yes" -a \
1726                "$ac_cv_func_pwritev64" = "yes"],
1727          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1728           AC_MSG_RESULT(yes)],
1729          [AC_MSG_RESULT(no)])
1730    ;;
1731 esac
1732
1733 AC_MSG_CHECKING([for POSIX regex library])
1734 if test "$ac_cv_header_regex_h" = "yes" && \
1735         test "$ac_cv_func_regcomp" = "yes" && \
1736         test "$ac_cv_func_regexec" = "yes" && \
1737         test "$ac_cv_func_regerror" = "yes"; then
1738     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1739     AC_MSG_RESULT(yes)
1740 else
1741     AC_MSG_RESULT(no)
1742 fi
1743
1744 dnl Look for "non-portable" pthreads functions.
1745 save_LIBS="$LIBS"
1746 LIBS="$LIBS $PTHREAD_LIBS"
1747 AC_CHECK_FUNCS([ \
1748         pthread_set_name_np \
1749         pthread_setname_np \
1750 ])
1751
1752 dnl Sadly, there are three different versions of pthread_setname_np.
1753 dnl Try to cater for all of them.
1754 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1755     AC_MSG_CHECKING([for signature of pthread_setname_np])
1756     AC_TRY_COMPILE([
1757 #include <pthread.h>
1758 #ifdef HAVE_PTHREAD_NP_H
1759 #include <pthread_np.h>
1760 #endif
1761 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1762         AC_MSG_RESULT([three arguments])
1763         pthread_setname_np_args=3], [
1764         AC_TRY_COMPILE([
1765 #include <pthread.h>
1766 #ifdef HAVE_PTHREAD_NP_H
1767 #include <pthread_np.h>
1768 #endif
1769 ], [pthread_setname_np(pthread_self(), "test")], [
1770             AC_MSG_RESULT([two arguments])
1771             pthread_setname_np_args=2], [
1772             AC_TRY_COMPILE([
1773 #include <pthread.h>
1774 #ifdef HAVE_PTHREAD_NP_H
1775 #include <pthread_np.h>
1776 #endif
1777 ], [pthread_setname_np("test")], [
1778                 AC_MSG_RESULT([one argument])
1779                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1780 ])
1781 ])
1782 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1783 fi
1784 LIBS="$save_LIBS"
1785
1786 openafs_cv_saved_CFLAGS="$CFLAGS"
1787 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1788
1789 AC_TYPE_SIGNAL
1790 OPENAFS_RETSIGTYPE
1791 AC_CHECK_SIZEOF(void *)
1792 AC_CHECK_SIZEOF(unsigned long long)
1793 AC_CHECK_SIZEOF(unsigned long)
1794 AC_CHECK_SIZEOF(unsigned int)
1795 AC_TYPE_INTPTR_T
1796 AC_TYPE_UINTPTR_T
1797 AC_TYPE_SSIZE_T
1798 AC_CHECK_TYPE([sig_atomic_t],[],
1799     [AC_DEFINE([sig_atomic_t], [int],
1800         [Define to int if <signal.h> does not define.])],
1801 [#include <sys/types.h>
1802 #include <signal.h>])
1803 AC_CHECK_TYPE([socklen_t],[],
1804     [AC_DEFINE([socklen_t], [int],
1805         [Define to int if <sys/socket.h> does not define.])],
1806 [#include <sys/types.h>
1807 #include <sys/socket.h>])
1808 AC_CHECK_TYPES(off64_t)
1809 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1810 AC_CHECK_TYPES([struct winsize], [], [], [
1811 #ifdef HAVE_TERMIOS_H
1812 # include <termios.h>
1813 #else
1814 # include <sys/termios.h>
1815 #endif
1816 #include <sys/ioctl.h>])
1817 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1818                 struct sockaddr_storage],
1819                [], [], [
1820 #include <sys/types.h>
1821 #include <sys/socket.h>
1822 ])
1823 AC_CHECK_TYPES([sa_family_t], [], [], [
1824 #include <sys/types.h>
1825 #include <sys/socket.h>
1826 ])
1827 AC_CHECK_TYPES([struct addrinfo], [], [], [
1828 #include <sys/types.h>
1829 #ifdef HAVE_NETDB_H
1830 #include <netdb.h>
1831 #endif
1832 ])
1833 AC_CHECK_TYPES([long long], [], [], [])
1834
1835 AC_SIZEOF_TYPE(long)
1836
1837 CFLAGS="$openafs_cv_saved_CFLAGS"
1838
1839 RRA_HEADER_PAM_CONST
1840
1841
1842 dnl Directory PATH handling
1843 if test "x$enable_transarc_paths" = "xyes"  ; then
1844     afsconfdir=${afsconfdir=/usr/afs/etc}
1845     viceetcdir=${viceetcdir=/usr/vice/etc}
1846     afskerneldir=${afskerneldir=${viceetcdir}}
1847     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1848     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1849     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1850     afsdbdir=${afsdbdir=/usr/afs/db}
1851     afslogsdir=${afslogsdir=/usr/afs/logs}
1852     afslocaldir=${afslocaldir=/usr/afs/local}
1853     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1854     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1855     afsdatadir=${afsdatadir=/usr/vice/etc}
1856 else
1857     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1858     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1859     afskerneldir=${afskerneldir='${libdir}/openafs'}
1860     afssrvbindir=${afssrvbindir='${bindir}'}
1861     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1862     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1863     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1864     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1865     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1866     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1867     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1868     afsdatadir=${afsdatadir='${datadir}/openafs'}
1869 fi
1870 AC_SUBST(afsconfdir)
1871 AC_SUBST(viceetcdir)
1872 AC_SUBST(afskerneldir)
1873 AC_SUBST(afssrvbindir)
1874 AC_SUBST(afssrvsbindir)
1875 AC_SUBST(afssrvlibexecdir)
1876 AC_SUBST(afsdbdir)
1877 AC_SUBST(afslogsdir)
1878 AC_SUBST(afslocaldir)
1879 AC_SUBST(afsbackupdir)
1880 AC_SUBST(afsbosconfigdir)
1881 AC_SUBST(afsdatadir)
1882
1883 if test "x$enable_kernel_module" = "xyes"; then
1884 ENABLE_KERNEL_MODULE=libafs
1885 fi
1886
1887 if test "x$enable_pthreaded_ubik" = "xyes"; then
1888 ENABLE_PTHREADED_UBIK=yes
1889 fi
1890
1891 AC_SUBST(VFSCK)
1892 AC_SUBST(AFS_SYSNAME)
1893 AC_SUBST(AFS_PARAM_COMMON)
1894 AC_SUBST(ENABLE_KERNEL_MODULE)
1895 AC_SUBST(ENABLE_PTHREADED_UBIK)
1896 AC_SUBST(LIB_AFSDB)
1897 AC_SUBST(LINUX_KERNEL_PATH)
1898 AC_SUBST(LINUX_KERNEL_BUILD)
1899 AC_SUBST(HOST_CPU)
1900 AC_SUBST(BSD_KERNEL_PATH)
1901 AC_SUBST(BSD_KERNEL_BUILD)
1902 AC_SUBST(LINUX_VERSION)
1903 AC_SUBST(MKAFS_OSTYPE)
1904 AC_SUBST(TOP_OBJDIR)
1905 AC_SUBST(TOP_SRCDIR)
1906 AC_SUBST(TOP_INCDIR)
1907 AC_SUBST(TOP_LIBDIR)
1908 AC_SUBST(DEST)
1909 AC_SUBST(DARWIN_INFOFILE)
1910 AC_SUBST(IRIX_BUILD_IP35)
1911 AC_SUBST(HTML_XSL)
1912 AC_SUBST(XSLTPROC)
1913 AC_SUBST(DOCBOOK2PDF)
1914 AC_SUBST(DOCBOOK_STYLESHEETS)
1915
1916 OPENAFS_FUSE
1917 OPENAFS_SWIG
1918
1919 TOP_SRCDIR="${srcdir}/src"
1920 dnl
1921 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1922 dnl
1923 case $TOP_SRCDIR in
1924         /*)
1925                 ;;
1926         *)
1927                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1928                 ;;
1929 esac
1930
1931 TOP_OBJDIR="${SRCDIR_PARENT}"
1932 TOP_INCDIR="${SRCDIR_PARENT}/include"
1933 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1934 if test "${DEST}x" = "x"; then
1935         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1936 fi
1937
1938 if test "x$with_crosstools_dir" != "x"; then
1939         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1940                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1941                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1942                 RXGEN_PATH=$with_crosstools_dir/rxgen
1943         else
1944                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1945                 exit 1
1946         fi
1947 else
1948         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1949         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1950         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1951 fi
1952 AC_SUBST(COMPILE_ET_PATH)
1953 AC_SUBST(CONFIGTOOL_PATH)
1954 AC_SUBST(RXGEN_PATH)
1955
1956 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1957 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1958 AC_SUBST(HELPER_SPLINT)
1959 AC_SUBST(HELPER_SPLINTCFG)
1960
1961 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1962
1963 dnl Check to see if crypt lives in a different library
1964 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1965 AC_SUBST(LIB_crypt)
1966
1967 dnl Check to see if the compiler support labels in structs
1968 AC_MSG_CHECKING(for label support in structs)
1969 AC_TRY_COMPILE([], [
1970 extern void osi_UFSOpen(void);
1971 struct labeltest {
1972    void (*open) (void);
1973 };
1974 struct labeltest struct_labeltest = {
1975    .open       = osi_UFSOpen,
1976 }
1977 ],
1978 [AC_MSG_RESULT(yes)
1979  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1980 ],
1981 [AC_MSG_RESULT(no)
1982 ])
1983
1984 AC_MSG_CHECKING([checking for dirfd])
1985 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1986 #ifdef HAVE_DIRENT_H
1987 #include <dirent.h>
1988 #endif
1989 ]],
1990         [[DIR *d = 0; dirfd(d);]])],
1991         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1992 if test "$ac_rk_have_dirfd" = "yes" ; then
1993         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1994 fi
1995 AC_MSG_RESULT($ac_rk_have_dirfd)
1996
1997 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1998 #ifdef HAVE_DIRENT_H
1999 #include <dirent.h>
2000 #endif])
2001
2002 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
2003 [#ifdef HAVE_SYS_RESOURCE_H
2004 #include <sys/resource.h>
2005 #endif])
2006
2007 dnl Check for UUID library
2008 AC_CHECK_HEADERS([uuid/uuid.h])
2009 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
2010 AC_CHECK_FUNCS([uuid_generate])
2011 ])
2012
2013