acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8
   9 AC_CANONICAL_HOST
  10 SRCDIR_PARENT=`pwd`
  11
  12 #BOZO_SAVE_CORES pam sia
  13 AC_ARG_WITH(afs-sysname,
  14 [  --with-afs-sysname=sys    use sys for the afs sysname]
  15 )
  16 AC_ARG_ENABLE( obsolete,
  17 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
  18 AC_ARG_ENABLE( insecure,
  19 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
  20 AC_ARG_ENABLE( afsdb,
  21 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
  22 AC_ARG_ENABLE( pam,
  23 [  --disable-pam                        disable PAM support],, enable_pam="yes")
  24 AC_ARG_ENABLE( bos-restricted-mode,
  25 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
  26 AC_ARG_ENABLE( bos-new-config,
  27 [  --enable-bos-new-config              enable bosserver pickup of BosConfig.new on restarts],, enable_bos_new_config="no")
  28 AC_ARG_ENABLE( largefile-fileserver,
  29 [  --enable-largefile-fileserver        enable large file support in fileserver],, enable_largefile_fileserver="no")
  30 AC_ARG_ENABLE( namei-fileserver,
  31 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
  32 AC_ARG_ENABLE( supergroups,
  33 [  --enable-supergroups                 enable support for nested pts groups],, enable_supergroups="no")
  34 AC_ARG_ENABLE( fast-restart,
  35 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
  36 AC_ARG_ENABLE( bitmap-later,
  37 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
  38 AC_ARG_ENABLE( full-vos-listvol-switch,
  39 [  --disable-full-vos-listvol-switch    disable vos full listvol switch for formatted output],, enable_full_vos_listvol_switch="yes")
  40 AC_ARG_WITH(dux-kernel-headers,
  41 [  --with-dux-kernel-headers=path       use the kernel headers found at path(optional, defaults to first match in /usr/sys)]
  42 )
  43 AC_ARG_WITH(linux-kernel-headers,
  44 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux-2.4, then /usr/src/linux)]
  45 )
  46 AC_ARG_WITH(bsd-kernel-headers,
  47 [  --with-bsd-kernel-headers=path       use the kernel headers found at path(optional, defaults to /usr/src/sys)]
  48 )
  49 AC_ARG_WITH(bsd-kernel-build,
  50 [  --with-bsd-kernel-build=path         use the kernel build found at path(optional, defaults to KSRC/i386/compile/GENERIC)]
  51 )
  52 AC_ARG_ENABLE(kernel-module,
  53 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
  54 )
  55 AC_ARG_ENABLE(redhat-buildsys,
  56 [  --enable-redhat-buildsys             enable compilation of the redhat build system kernel (defaults to disabled)],, enable_redhat_buildsys="no"
  57 )
  58 AC_ARG_ENABLE(transarc-paths,
  59 [  --enable-transarc-paths                      Use Transarc style paths like /usr/afs and /usr/vice],, enable_transarc_paths="no"
  60 )
  61 AC_ARG_ENABLE(tivoli-tsm,
  62 [  --enable-tivoli-tsm                  Enable use of the Tivoli TSM API libraries for butc support],, enable_tivoli_tsm="no"
  63 )
  64 AC_ARG_ENABLE(debug-kernel,
  65 [  --enable-debug-kernel                enable compilation of the kernel module with debugging information (defaults to disabled)],, enable_debug_kernel="no"
  66 )
  67 AC_ARG_ENABLE(optimize-kernel,
  68 [  --disable-optimize-kernel            disable compilation of the kernel module with optimization (defaults based on platform)],, enable_optimize_kernel="yes"
  69 )
  70 AC_ARG_ENABLE(debug,
  71 [  --enable-debug                       enable compilation of the user space code with debugging information (defaults to disabled)],, enable_debug="no"
  72 )
  73 AC_ARG_ENABLE(optimize,
  74 [  --disable-optimize                   disable optimization for compilation of the user space code (defaults to enabled)],, enable_optimize="yes"
  75 )
  76 AC_ARG_ENABLE(debug-lwp,
  77 [  --enable-debug-lwp                   enable compilation of the LWP code with debugging information (defaults to disabled)],, enable_debug_lwp="no"
  78 )
  79 AC_ARG_ENABLE(optimize-lwp,
  80 [  --disable-optimize-lwp               disable optimization for compilation of the LWP code (defaults to enabled)],, enable_optimize_lwp="yes"
  81 )
  82
  83 enable_login="no"
  84
  85 dnl weird ass systems
  86 AC_AIX
  87 AC_ISC_POSIX
  88 AC_MINIX
  89
  90 dnl Various compiler setup.
  91 AC_TYPE_PID_T
  92 AC_TYPE_SIZE_T
  93 AC_TYPE_SIGNAL
  94 COMPILER_HAS_FUNCTION_MACRO
  95
  96 dnl Checks for programs.
  97 AC_PROG_INSTALL
  98 AC_PROG_LN_S
  99 AC_PROG_RANLIB
 100 AC_PROG_YACC
 101 AM_PROG_LEX
 102
 103 OPENAFS_CHECK_BIGENDIAN
 104
 105 AC_MSG_CHECKING(your OS)
 106 system=$host
 107 case $system in
 108         *-linux*)
 109
 110                 MKAFS_OSTYPE=LINUX
 111                 if test "x$enable_redhat_buildsys" = "xyes"; then
 112                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 113                 fi
 114                 if test "x$enable_kernel_module" = "xyes"; then
 115                  if test "x$with_linux_kernel_headers" != "x"; then
 116                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 117                  else
 118                    LINUX_KERNEL_PATH="/usr/src/linux-2.4"
 119                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 120                      LINUX_KERNEL_PATH="/usr/src/linux"
 121                    fi
 122                  fi
 123                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 124                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 125                   if test "x$linux_kvers" = "x"; then
 126                     if test -f "$LINUX_KERNEL_PATH/include/linux/version-up.h"; then
 127                       linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 128                       if test "x$linux_kvers" = "x"; then
 129
 130                         AC_MSG_ERROR(Linux headers lack version definition [2])
 131                         exit 1
 132                       else
 133                         LINUX_VERSION="$linux_kvers"
 134                       fi
 135                     else
 136                       AC_MSG_ERROR(Linux headers lack version definition)
 137                       exit 1
 138                     fi
 139                   else
 140                     LINUX_VERSION="$linux_kvers"
 141                   fi
 142                  else
 143                     enable_kernel_module="no"
 144                  fi
 145                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
 146                      enable_kernel_module="no"
 147                  fi
 148                  if test "x$enable_kernel_module" = "xno"; then
 149                   if test "x$with_linux_kernel_headers" != "x"; then
 150                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 151                    exit 1
 152                   else
 153                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 154                   fi
 155                  fi
 156                  dnl do we need to determine SUBARCH from autoconf.h
 157                  SUBARCH=default
 158                 fi
 159                 AC_MSG_RESULT(linux)
 160                 if test "x$enable_kernel_module" = "xyes"; then
 161                  AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $[]1 $[]2}'`
 162                  if test "x${AFS_SYSKVERS}" = "x"; then
 163                   AC_MSG_ERROR(Couldn't guess your Linux version [2])
 164                  fi
 165                 fi
 166                 ;;
 167         *-solaris*)
 168                 MKAFS_OSTYPE=SOLARIS
 169                 AC_MSG_RESULT(sun4)
 170                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 171                 SOLARIS_PROC_HAS_P_COREFILE
 172                 SOLARIS_FS_HAS_FS_ROLLED
 173                 ;;
 174         *-sunos*)
 175                 MKAFS_OSTYPE=SUNOS
 176                 enable_kernel_module=no
 177                 AC_MSG_RESULT(sun4)
 178                 ;;
 179         *-hpux*)
 180                 MKAFS_OSTYPE=HPUX
 181                 AC_MSG_RESULT(hp_ux)
 182                 ;;
 183         *-irix*)
 184                 if test -d /usr/include/sys/SN/SN1; then
 185                  IRIX_BUILD_IP35="IP35"
 186                 fi
 187                 MKAFS_OSTYPE=IRIX
 188                 AC_MSG_RESULT(sgi)
 189                 ;;
 190         *-aix*)
 191                 MKAFS_OSTYPE=AIX
 192                 AC_MSG_RESULT(rs_aix)
 193                 ;;
 194         *-osf*)
 195                 MKAFS_OSTYPE=DUX
 196                 AC_MSG_RESULT(alpha_dux)
 197                 if test "x$enable_kernel_module" = "xyes"; then
 198                  if test "x$with_dux_kernel_headers" != "x"; then
 199                    HEADER_RT=`ls ${with_dux_kernel_headers}/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 200                  else
 201                    HEADER_RT=`ls /usr/sys/*/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 202                  fi
 203                 fi
 204                 if test "$HEADER_RT" = "*" ; then
 205                         AC_MSG_ERROR([Need a configured kernel directory])
 206                 fi
 207                 AC_SUBST([HEADER_RT])
 208                 ;;
 209         *-darwin*)
 210                 MKAFS_OSTYPE=DARWIN
 211                 AC_MSG_RESULT(ppc_darwin)
 212                 ;;
 213         *-freebsd*)
 214                 MKAFS_OSTYPE=FBSD
 215                 AC_MSG_RESULT(i386_fbsd)
 216                 ;;
 217         *-netbsd*)
 218                 MKAFS_OSTYPE=NBSD
 219                 AC_MSG_RESULT(nbsd)
 220                 ;;
 221         *-openbsd*)
 222                 MKAFS_OSTYPE=OBSD
 223                 AC_MSG_RESULT(i386_obsd)
 224                 ;;
 225         *)
 226                 AC_MSG_RESULT($system)
 227                 ;;
 228 esac
 229
 230 if test "x$with_afs_sysname" != "x"; then
 231         AFS_SYSNAME="$with_afs_sysname"
 232 else
 233         AC_MSG_CHECKING(your AFS sysname)
 234         case $host in
 235                 i?86-*-openbsd3.1)
 236                         AFS_SYSNAME="i386_obsd31"
 237                         ;;
 238                 i?86-*-openbsd3.2)
 239                         AFS_SYSNAME="i386_obsd32"
 240                         ;;
 241                 i?86-*-openbsd3.3)
 242                         AFS_SYSNAME="i386_obsd33"
 243                         ;;
 244                 i?86-*-openbsd3.4)
 245                         AFS_SYSNAME="i386_obsd34"
 246                         ;;
 247                 i?86-*-openbsd3.5)
 248                         AFS_SYSNAME="i386_obsd35"
 249                         ;;
 250                 i?86-*-openbsd3.6)
 251                         AFS_SYSNAME="i386_obsd36"
 252                         ;;
 253                 i?86-*-freebsd4.2*)
 254                         AFS_SYSNAME="i386_fbsd_42"
 255                         ;;
 256                 i?86-*-freebsd4.3*)
 257                         AFS_SYSNAME="i386_fbsd_43"
 258                         ;;
 259                 i?86-*-freebsd4.4*)
 260                         AFS_SYSNAME="i386_fbsd_44"
 261                         ;;
 262                 i?86-*-freebsd4.5*)
 263                         AFS_SYSNAME="i386_fbsd_45"
 264                         ;;
 265                 i?86-*-freebsd4.6*)
 266                         AFS_SYSNAME="i386_fbsd_46"
 267                         ;;
 268                 i?86-*-freebsd4.7*)
 269                         AFS_SYSNAME="i386_fbsd_47"
 270                         ;;
 271                 i?86-*-freebsd5.0*)
 272                         AFS_SYSNAME="i386_fbsd_50"
 273                         ;;
 274                 i?86-*-freebsd5.1*)
 275                         AFS_SYSNAME="i386_fbsd_51"
 276                         ;;
 277                 i?86-*-freebsd5.2*)
 278                         AFS_SYSNAME="i386_fbsd_52"
 279                         ;;
 280                 i?86-*-freebsd5.3*)
 281                         AFS_SYSNAME="i386_fbsd_53"
 282                         ;;
 283                 i?86-*-netbsd*1.5*)
 284                         AFS_PARAM_COMMON=param.nbsd15.h
 285                         AFS_SYSNAME="i386_nbsd15"
 286                         ;;
 287                 alpha-*-netbsd*1.5*)
 288                         AFS_PARAM_COMMON=param.nbsd15.h
 289                         AFS_SYSNAME="alpha_nbsd15"
 290                         ;;
 291                 i?86-*-netbsd*1.6[[M-Z]]*)
 292                         AFS_PARAM_COMMON=param.nbsd20.h
 293                         AFS_SYSNAME="i386_nbsd20"
 294                         ;;
 295                 powerpc-*-netbsd*1.6[[M-Z]]*)
 296                         AFS_PARAM_COMMON=param.nbsd20.h
 297                         AFS_SYSNAME="ppc_nbsd20"
 298                         ;;
 299                 i?86-*-netbsd*2.0*)
 300                         AFS_PARAM_COMMON=param.nbsd20.h
 301                         AFS_SYSNAME="i386_nbsd20"
 302                         ;;
 303                 powerpc-*-netbsd*2.0*)
 304                         AFS_PARAM_COMMON=param.nbsd20.h
 305                         AFS_SYSNAME="ppc_nbsd20"
 306                         ;;
 307                 i?86-*-netbsd*1.6*)
 308                         AFS_PARAM_COMMON=param.nbsd16.h
 309                         AFS_SYSNAME="i386_nbsd16"
 310                         ;;
 311                 alpha-*-netbsd*1.6*)
 312                         AFS_PARAM_COMMON=param.nbsd16.h
 313                         AFS_SYSNAME="alpha_nbsd16"
 314                         ;;
 315                 powerpc-*-netbsd*1.6*)
 316                         AFS_PARAM_COMMON=param.nbsd16.h
 317                         AFS_SYSNAME="ppc_nbsd16"
 318                         ;;
 319                 i?86-*-netbsd*2.99*)
 320                         AFS_PARAM_COMMON=param.nbsd21.h
 321                         AFS_SYSNAME="i386_nbsd21"
 322                         ;;
 323                 hppa*-hp-hpux11.0*)
 324                         AFS_SYSNAME="hp_ux110"
 325                         ;;
 326                 hppa*-hp-hpux11.11)
 327                         AFS_SYSNAME="hp_ux11i"
 328                         ;;
 329                 ia64-hp-hpux11.22)
 330                         AFS_SYSNAME="ia64_hpux1122"
 331                         ;;
 332                 ia64-hp-hpux*)
 333                         AFS_SYSNAME="ia64_hpux1123"
 334                         ;;
 335                 hppa*-hp-hpux10*)
 336                         AFS_SYSNAME="hp_ux102"
 337                         ;;
 338                 powerpc-apple-darwin1.2*)
 339                         AFS_SYSNAME="ppc_darwin_12"
 340                         ;;
 341                 powerpc-apple-darwin1.3*)
 342                         AFS_SYSNAME="ppc_darwin_13"
 343                         ;;
 344                 powerpc-apple-darwin1.4*)
 345                         AFS_SYSNAME="ppc_darwin_14"
 346                         ;;
 347                 powerpc-apple-darwin5.1*)
 348                         AFS_SYSNAME="ppc_darwin_14"
 349                         ;;
 350                 powerpc-apple-darwin5.2*)
 351                         AFS_SYSNAME="ppc_darwin_14"
 352                         ;;
 353                 powerpc-apple-darwin5.3*)
 354                         AFS_SYSNAME="ppc_darwin_14"
 355                         ;;
 356                 powerpc-apple-darwin5.4*)
 357                         AFS_SYSNAME="ppc_darwin_14"
 358                         ;;
 359                 powerpc-apple-darwin5.5*)
 360                         AFS_SYSNAME="ppc_darwin_14"
 361                         ;;
 362                 powerpc-apple-darwin6.0*)
 363                         AFS_SYSNAME="ppc_darwin_60"
 364                         ;;
 365                 powerpc-apple-darwin6.1*)
 366                         AFS_SYSNAME="ppc_darwin_60"
 367                         ;;
 368                 powerpc-apple-darwin6.2*)
 369                         AFS_SYSNAME="ppc_darwin_60"
 370                         ;;
 371                 powerpc-apple-darwin6.3*)
 372                         AFS_SYSNAME="ppc_darwin_60"
 373                         ;;
 374                 powerpc-apple-darwin6.4*)
 375                         AFS_SYSNAME="ppc_darwin_60"
 376                         ;;
 377                 powerpc-apple-darwin6.5*)
 378                         AFS_SYSNAME="ppc_darwin_60"
 379                         ;;
 380                 powerpc-apple-darwin7.0*)
 381                         AFS_SYSNAME="ppc_darwin_70"
 382                         ;;
 383                 powerpc-apple-darwin7.1*)
 384                         AFS_SYSNAME="ppc_darwin_70"
 385                         ;;
 386                 powerpc-apple-darwin7.2*)
 387                         AFS_SYSNAME="ppc_darwin_70"
 388                         ;;
 389                 powerpc-apple-darwin7.3*)
 390                         AFS_SYSNAME="ppc_darwin_70"
 391                         ;;
 392                 powerpc-apple-darwin7.4*)
 393                         AFS_SYSNAME="ppc_darwin_70"
 394                         ;;
 395                 powerpc-apple-darwin7.5*)
 396                         AFS_SYSNAME="ppc_darwin_70"
 397                         ;;
 398                 sparc-sun-solaris2.5*)
 399                         AFS_SYSNAME="sun4x_55"
 400                         enable_login="yes"
 401                         ;;
 402                 sparc-sun-solaris2.6)
 403                         AFS_SYSNAME="sun4x_56"
 404                         ;;
 405                 sparc-sun-solaris2.7)
 406                         AFS_SYSNAME="sun4x_57"
 407                         ;;
 408                 sparc-sun-solaris2.8)
 409                         AFS_SYSNAME="sun4x_58"
 410                         ;;
 411                 sparc-sun-solaris2.9)
 412                         AFS_SYSNAME="sun4x_59"
 413                         ;;
 414                 sparc-sun-solaris2.10)
 415                         AFS_SYSNAME="sun4x_510"
 416                         ;;
 417                 sparc-sun-sunos4*)
 418                         AFS_SYSNAME="sun4_413"
 419                         enable_login="yes"
 420                         ;;
 421                 i386-pc-solaris2.7)
 422                         AFS_SYSNAME="sunx86_57"
 423                         ;;
 424                 i386-pc-solaris2.8)
 425                         AFS_SYSNAME="sunx86_58"
 426                         ;;
 427                 i386-pc-solaris2.9)
 428                         AFS_SYSNAME="sunx86_59"
 429                         ;;
 430                 i386-pc-solaris2.10)
 431                         AFS_SYSNAME="sunx86_510"
 432                         ;;
 433                 alpha*-dec-osf4.0*)
 434                         AFS_SYSNAME="alpha_dux40"
 435                         ;;
 436                 alpha*-dec-osf5.0*)
 437                         AFS_SYSNAME="alpha_dux50"
 438                         ;;
 439                 alpha*-dec-osf5.1*)
 440                         AFS_SYSNAME="alpha_dux51"
 441                         ;;
 442                 mips-sgi-irix6.5)
 443                         AFS_SYSNAME="sgi_65"
 444                         ;;
 445                 ia64-*-linux*)
 446                         AFS_SYSNAME="ia64_linuxXX"
 447                         ;;
 448                 powerpc-*-linux*)
 449                         AFS_SYSNAME="ppc_linuxXX"
 450                         ;;
 451                 powerpc64-*-linux*)
 452                         AFS_SYSNAME="ppc64_linuxXX"
 453                         ;;
 454                 alpha*-linux*)
 455                         AFS_SYSNAME="alpha_linux_XX"
 456                         ;;
 457                 s390-*-linux*)
 458                         AFS_SYSNAME="s390_linuxXX"
 459                         ;;
 460                 s390x-*-linux*)
 461                         AFS_SYSNAME="s390x_linuxXX"
 462                         ;;
 463                 sparc-*-linux*)
 464                         AFS_SYSNAME="sparc_linuxXX"
 465                         ;;
 466                 sparc64-*-linux*)
 467                         AFS_SYSNAME="sparc64_linuxXX"
 468                         ;;
 469                 i?86-*-linux*)
 470                         AFS_SYSNAME="i386_linuxXX"
 471                         ;;
 472                 parisc-*-linux-gnu)
 473                         AFS_SYSNAME="parisc_linuxXX"
 474                         enable_pam="no"
 475                         ;;
 476                 power*-ibm-aix4.2*)
 477                         AFS_SYSNAME="rs_aix42"
 478                         enable_pam="no"
 479                         ;;
 480                 power*-ibm-aix4.3*)
 481                         AFS_SYSNAME="rs_aix42"
 482                         enable_pam="no"
 483                         ;;
 484                 power*-ibm-aix5.1*)
 485                         AFS_SYSNAME="rs_aix51"
 486                         enable_pam="no"
 487                         ;;
 488                 power*-ibm-aix5.2*)
 489                         AFS_SYSNAME="rs_aix52"
 490                         enable_pam="no"
 491                         ;;
 492                 x86_64-*-linux-gnu)
 493                         AFS_SYSNAME="amd64_linuxXX"
 494                         enable_pam="no"
 495                         ;;
 496                 *)
 497                         AC_MSG_ERROR(An AFS sysname is required)
 498                         exit 1
 499                         ;;
 500         esac
 501         case $AFS_SYSNAME in
 502                 *_linux* | *_umlinux*)
 503                         if test "x${AFS_SYSKVERS}" = "x"; then
 504                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 505                         fi
 506                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 507                         AFS_SYSNAME="$_AFS_SYSNAME"
 508                         save_CPPFLAGS="$CPPFLAGS"
 509                         CPPFLAGS="-I${LINUX_KERNEL_PATH}/include $CPPFLAGS"
 510                         AC_TRY_COMPILE(
 511                          [#include <linux/autoconf.h>],
 512                          [#ifndef CONFIG_USERMODE
 513                           #error not UML
 514                           #endif],
 515                          ac_cv_linux_is_uml=yes,)
 516                         if test "${ac_cv_linux_is_uml}" = yes; then
 517                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 518                         fi
 519                         CPPFLAGS="$save_CPPFLAGS"
 520                         AFS_SYSNAME="$_AFS_SYSNAME"
 521                         ;;
 522         esac
 523         AC_MSG_RESULT($AFS_SYSNAME)
 524 fi
 525
 526 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 527
 528                 # Add (sub-) architecture-specific paths needed by conftests
 529                 case $AFS_SYSNAME  in
 530                         *_umlinux26)
 531                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 532                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 533                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 534                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 535                 esac
 536
 537                 if test "x$enable_kernel_module" = "xyes"; then
 538                  if test "x$enable_debug_kernel" = "xno"; then
 539                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 540                  fi
 541                  OPENAFS_GCC_SUPPORTS_MARCH
 542                  AC_SUBST(P5PLUS_KOPTS)
 543                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 544                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 545                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 546                  OPENAFS_GCC_SUPPORTS_PIPE
 547                  AC_SUBST(LINUX_GCC_KOPTS)
 548                  ifdef([OPENAFS_CONFIGURE_LIBAFS],
 549                    [LINUX_BUILD_VNODE_FROM_INODE(src/config,afs)],
 550                    [LINUX_BUILD_VNODE_FROM_INODE(${srcdir}/src/config,src/afs/LINUX,${srcdir}/src/afs/LINUX)]
 551                  )
 552                  LINUX_COMPLETION_H_EXISTS
 553                  LINUX_DEFINES_FOR_EACH_PROCESS
 554                  LINUX_DEFINES_PREV_TASK
 555                  LINUX_EXPORTS_TASKLIST_LOCK
 556                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK
 557                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_GFP_MASK
 558                  LINUX_FS_STRUCT_INODE_HAS_I_ALLOC_SEM
 559                  LINUX_FS_STRUCT_INODE_HAS_I_TRUNCATE_SEM
 560                  LINUX_FS_STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS
 561                  LINUX_FS_STRUCT_INODE_HAS_I_DEVICES
 562                  LINUX_FS_STRUCT_INODE_HAS_I_SECURITY
 563                  LINUX_INODE_SETATTR_RETURN_TYPE
 564                  LINUX_WRITE_INODE_RETURN_TYPE
 565                  LINUX_IOP_NAMEIDATA
 566                  LINUX_AOP_WRITEBACK_CONTROL
 567                  LINUX_KERNEL_LINUX_SYSCALL_H
 568                  LINUX_KERNEL_SELINUX
 569                  LINUX_KERNEL_SOCK_CREATE
 570                  LINUX_KERNEL_PAGE_FOLLOW_LINK
 571                  LINUX_NEED_RHCONFIG
 572                  LINUX_RECALC_SIGPENDING_ARG_TYPE
 573                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_PARENT
 574                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_REAL_PARENT
 575                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIG
 576                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGHAND
 577                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGMASK_LOCK
 578                  LINUX_WHICH_MODULES
 579                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
 580                    AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
 581                    ac_cv_linux_exports_sys_call_table=no
 582                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
 583                      ac_cv_linux_exports_ia32_sys_call_table=yes
 584                    fi
 585                  else
 586                    LINUX_EXPORTS_INIT_MM
 587                    LINUX_EXPORTS_KALLSYMS_ADDRESS
 588                    LINUX_EXPORTS_KALLSYMS_SYMBOL
 589                    LINUX_EXPORTS_SYS_CALL_TABLE
 590                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
 591                    LINUX_EXPORTS_SYS_CHDIR
 592                    LINUX_EXPORTS_SYS_CLOSE
 593                    LINUX_EXPORTS_SYS_WAIT4
 594                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
 595                          linux_syscall_method=none
 596                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
 597                             linux_syscall_method=scan
 598                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
 599                                linux_syscall_method=scan_with_kallsyms_address
 600                             fi
 601                          fi
 602                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
 603                             linux_syscall_method=kallsyms_symbol
 604                          fi
 605                          if test "x$linux_syscall_method" = "xnone"; then
 606                         AC_MSG_ERROR([no available sys_call_table access method])
 607                          fi
 608                    fi
 609                  fi
 610                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
 611                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
 612                  fi
 613                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
 614                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
 615                  fi
 616                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
 617                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
 618                  fi
 619                  if test "x$ac_cv_linux_exports_sys_chdir" = "xyes" ; then
 620                   AC_DEFINE(EXPORTED_SYS_CHDIR, 1, [define if your linux kernel exports sys_chdir])
 621                  fi
 622                  if test "x$ac_cv_linux_exports_sys_close" = "xyes" ; then
 623                   AC_DEFINE(EXPORTED_SYS_CLOSE, 1, [define if your linux kernel exports sys_close])
 624                  fi
 625                  if test "x$ac_cv_linux_exports_sys_wait4" = "xyes" ; then
 626                   AC_DEFINE(EXPORTED_SYS_WAIT4, 1, [define if your linux kernel exports sys_wait4])
 627                  fi
 628                  if test "x$ac_cv_linux_exports_tasklist_lock" = "xyes" ; then
 629                   AC_DEFINE(EXPORTED_TASKLIST_LOCK, 1, [define if your linux kernel exports tasklist_lock])
 630                  fi
 631                  if test "x$ac_cv_linux_exports_sys_call_table" = "xyes"; then
 632                   AC_DEFINE(EXPORTED_SYS_CALL_TABLE)
 633                  fi
 634                  if test "x$ac_cv_linux_exports_ia32_sys_call_table" = "xyes"; then
 635                   AC_DEFINE(EXPORTED_IA32_SYS_CALL_TABLE)
 636                  fi
 637                  if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
 638                   AC_DEFINE(EXPORTED_KALLSYMS_SYMBOL)
 639                  fi
 640                  if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
 641                   AC_DEFINE(EXPORTED_KALLSYMS_ADDRESS)
 642                  fi
 643                  if test "x$ac_cv_linux_completion_h_exists" = "xyes" ; then
 644                   AC_DEFINE(COMPLETION_H_EXISTS, 1, [define if completion_h exists])
 645                  fi
 646                  if test "x$ac_cv_linux_defines_for_each_process" = "xyes" ; then
 647                   AC_DEFINE(DEFINED_FOR_EACH_PROCESS, 1, [define if for_each_process defined])
 648                  fi
 649                  if test "x$ac_cv_linux_defines_prev_task" = "xyes" ; then
 650                   AC_DEFINE(DEFINED_PREV_TASK, 1, [define if prev_task defined])
 651                  fi
 652                  if test "x$ac_cv_linux_func_inode_setattr_returns_int" = "xyes" ; then
 653                   AC_DEFINE(INODE_SETATTR_NOT_VOID, 1, [define if your setattr return return non-void])
 654                  fi
 655                  if test "x$ac_cv_linux_func_write_inode_returns_int" = "xyes" ; then
 656                   AC_DEFINE(WRITE_INODE_NOT_VOID, 1, [define if your sops.write_inode returns non-void])
 657                  fi
 658                  if test "x$ac_cv_linux_fs_struct_address_space_has_page_lock" = "xyes"; then
 659                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK, 1, [define if your struct address_space has page_lock])
 660                  fi
 661                  if test "x$ac_cv_linux_fs_struct_address_space_has_gfp_mask" = "xyes"; then
 662                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_GFP_MASK, 1, [define if your struct address_space has gfp_mask])
 663                  fi
 664                  if test "x$ac_cv_linux_fs_struct_inode_has_i_truncate_sem" = "xyes"; then
 665                   AC_DEFINE(STRUCT_INODE_HAS_I_TRUNCATE_SEM, 1, [define if your struct inode has truncate_sem])
 666                  fi
 667                  if test "x$ac_cv_linux_fs_struct_inode_has_i_alloc_sem" = "xyes"; then
 668                   AC_DEFINE(STRUCT_INODE_HAS_I_ALLOC_SEM, 1, [define if your struct inode has alloc_sem])
 669                  fi
 670                  if test "x$ac_cv_linux_fs_struct_inode_has_i_devices" = "xyes"; then
 671                   AC_DEFINE(STRUCT_INODE_HAS_I_DEVICES, 1, [define if you struct inode has i_devices])
 672                  fi
 673                  if test "x$ac_cv_linux_fs_struct_inode_has_i_security" = "xyes"; then
 674                   AC_DEFINE(STRUCT_INODE_HAS_I_SECURITY, 1, [define if you struct inode has i_security])
 675                  fi
 676                  if test "x$ac_cv_linux_fs_struct_inode_has_i_dirty_data_buffers" = "xyes"; then
 677                   AC_DEFINE(STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS, 1, [define if your struct inode has data_buffers])
 678                  fi
 679                  if test "x$ac_cv_linux_func_recalc_sigpending_takes_void" = "xyes"; then
 680                   AC_DEFINE(RECALC_SIGPENDING_TAKES_VOID, 1, [define if your recalc_sigpending takes void])
 681                  fi
 682                  if test "x$ac_cv_linux_kernel_is_selinux" = "xyes" ; then
 683                   AC_DEFINE(LINUX_KERNEL_IS_SELINUX, 1, [define if your linux kernel uses SELinux features])
 684                  fi
 685                  if test "x$ac_cv_linux_kernel_sock_create_v" = "xyes" ; then
 686                   AC_DEFINE(LINUX_KERNEL_SOCK_CREATE_V, 1, [define if your linux kernel uses 5 arguments for sock_create])
 687                  fi
 688                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" ; then
 689                   AC_DEFINE(HAVE_KERNEL_PAGE_FOLLOW_LINK, 1, [define if your linux kernel provides page_follow_link])
 690                  fi
 691                  if test "x$ac_linux_syscall" = "xyes" ; then
 692                   AC_DEFINE(HAVE_KERNEL_LINUX_SYSCALL_H, 1, [define if your linux kernel has linux/syscall.h])
 693                  fi
 694                  if test "x$ac_cv_linux_sched_struct_task_struct_has_parent" = "xyes"; then
 695                   AC_DEFINE(STRUCT_TASK_STRUCT_HAS_PARENT, 1, [define if your struct task_struct has parent])
 696                  fi
 697                  if test "x$ac_cv_linux_sched_struct_task_struct_has_real_parent" = "xyes"; then
 698                   AC_DEFINE(STRUCT_TASK_STRUCT_HAS_REAL_PARENT, 1, [define if your struct task_struct has real_parent])
 699                  fi
 700                  if test "x$ac_cv_linux_sched_struct_task_struct_has_sigmask_lock" = "xyes"; then
 701                   AC_DEFINE(STRUCT_TASK_STRUCT_HAS_SIGMASK_LOCK, 1, [define if your struct task_struct has sigmask_lock])
 702                  fi
 703                  if test "x$ac_cv_linux_sched_struct_task_struct_has_sighand" = "xyes"; then
 704                   AC_DEFINE(STRUCT_TASK_STRUCT_HAS_SIGHAND, 1, [define if your struct task_struct has sighand])
 705                  fi
 706                  if test "x$ac_cv_linux_sched_struct_task_struct_has_sig" = "xyes"; then
 707                   AC_DEFINE(STRUCT_TASK_STRUCT_HAS_SIG, 1, [define if your struct task_struct has sig])
 708                  fi
 709                 :
 710                 fi
 711 esac
 712
 713 case $AFS_SYSNAME in
 714         *_darwin*)
 715                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 716                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 717                 dnl the test below fails on darwin, even if the CPPFLAGS below
 718                 dnl are added. the headers from Kernel.Framework must be used
 719                 dnl when KERNEL is defined.
 720
 721                 dnl really, such a thing isn't guaranteed to work on any
 722                 dnl platform until the kernel cflags from MakefileProto are
 723                 dnl known to configure
 724                 AC_DEFINE(HAVE_STRUCT_BUF, 1, [define if you have a struct buf])
 725                 ;;
 726         *)
 727 AC_MSG_CHECKING(for definition of struct buf)
 728 dnl save_CPPFLAGS="$CPPFLAGS"
 729 dnl CPPFLAGS="$CPPFLAGS -DKERNEL -D_KERNEL -D__KERNEL -D__KERNEL__"
 730 AC_CACHE_VAL(ac_cv_have_struct_buf, [
 731         ac_cv_have_struct_buf=no
 732         AC_TRY_COMPILE(
 733                 [#include <sys/buf.h>],
 734                 [struct buf x;
 735                 printf("%d\n", sizeof(x));],
 736                 ac_cv_have_struct_buf=yes,)
 737         ]
 738 )
 739 dnl CPPFLAGS="$save_CPPFLAGS"
 740 AC_MSG_RESULT($ac_cv_have_struct_buf)
 741 if test "$ac_cv_have_struct_buf" = yes; then
 742         AC_DEFINE(HAVE_STRUCT_BUF, 1, [define if you have a struct buf])
 743 fi
 744 ;;
 745 esac
 746
 747
 748 AC_CACHE_VAL(ac_cv_sockaddr_len,
 749 [
 750 AC_MSG_CHECKING([if struct sockaddr has sa_len field])
 751 AC_TRY_COMPILE( [#include <sys/types.h>
 752 #include <sys/socket.h>],
 753 [struct sockaddr *a;
 754 a->sa_len=0;], ac_cv_sockaddr_len=yes, ac_cv_sockaddr_len=no)
 755 AC_MSG_RESULT($ac_cv_sockaddr_len)])
 756 if test "$ac_cv_sockaddr_len" = "yes"; then
 757    AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1, [define if you struct sockaddr sa_len])
 758 fi
 759 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
 760         echo Skipping library tests because they confuse Irix.
 761 else
 762   AC_CHECK_FUNCS(socket)
 763
 764   if test "$ac_cv_func_socket" = no; then
 765     for lib in socket inet; do
 766         if test "$HAVE_SOCKET" != 1; then
 767                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET, 1, [define if you have socket]))
 768         fi
 769     done
 770   fi
 771
 772   AC_CHECK_FUNCS(connect)
 773
 774   if test "$ac_cv_func_connect" = no; then
 775     for lib in nsl; do
 776         if test "$HAVE_CONNECT" != 1; then
 777                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT, 1, [define if you have connect]))
 778         fi
 779     done
 780   fi
 781
 782   AC_CHECK_FUNCS(gethostbyname)
 783   if test "$ac_cv_func_gethostbyname" = no; then
 784         for lib in dns nsl resolv; do
 785           if test "$HAVE_GETHOSTBYNAME" != 1; then
 786             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME, 1, [define if you have gethostbyname]))
 787           fi
 788         done
 789   fi
 790
 791   dnl darwin wants it, aix hates it
 792   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
 793   AC_TRY_COMPILE([
 794   #include <stdlib.h>
 795   #include <stdio.h>
 796   #include <sys/types.h>
 797   #include <sys/socket.h>
 798   #include <netinet/in.h>
 799   #include <arpa/inet.h>
 800   #include <arpa/nameser.h>
 801   #include <arpa/nameser_compat.h>
 802   #include <resolv.h>
 803   ], [static int i; i = 0;],
 804   [AC_MSG_RESULT(yes)
 805    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H)],
 806   [AC_MSG_RESULT(no)
 807    ])
 808
 809   openafs_save_libs="$LIBS"
 810   AC_MSG_CHECKING([for res_search])
 811   AC_FUNC_RES_SEARCH
 812
 813   if test "$ac_cv_func_res_search" = no; then
 814       for lib in dns nsl resolv; do
 815         if test "$ac_cv_func_res_search" != yes; then
 816           LIBS="-l$lib $LIBS"
 817           AC_FUNC_RES_SEARCH
 818           LIBS="$openafs_save_libs"
 819         fi
 820       done
 821       if test "$ac_cv_func_res_search" = yes; then
 822         LIB_res_search="-l$lib"
 823         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
 824         AC_MSG_RESULT([yes, in lib$lib])
 825       else
 826         AC_MSG_RESULT(no)
 827       fi
 828   else
 829     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
 830     AC_MSG_RESULT(yes)
 831   fi
 832
 833 fi
 834
 835 PTHREAD_LIBS=error
 836 AC_CHECK_LIB(pthread, pthread_attr_init,
 837              PTHREAD_LIBS="-lpthread")
 838 if test "x$PTHREAD_LIBS" = xerror; then
 839         AC_CHECK_LIB(pthreads, pthread_attr_init,
 840                 PTHREAD_LIBS="-lpthreads")
 841 fi
 842 if test "x$PTHREAD_LIBS" = xerror; then
 843         AC_CHECK_LIB(c_r, pthread_attr_init,
 844                 PTHREAD_LIBS="-lc_r")
 845 fi
 846 if test "x$PTHREAD_LIBS" = xerror; then
 847         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
 848 fi
 849 if test "x$PTHREAD_LIBS" = xerror; then
 850         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
 851 fi
 852 AC_SUBST(PTHREAD_LIBS)
 853
 854 WITH_OBSOLETE=NO
 855 if test "$enable_obsolete" = "yes"; then
 856         WITH_OBSOLETE=YES
 857 fi
 858
 859 WITH_INSECURE=NO
 860 if test "$enable_insecure" = "yes"; then
 861         WITH_INSECURE=YES
 862 fi
 863
 864 if test "x$with_bsd_kernel_headers" != "x"; then
 865         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
 866 else
 867         BSD_KERNEL_PATH="/usr/src/sys"
 868 fi
 869
 870 if test "x$with_bsd_kernel_build" != "x"; then
 871         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
 872 else
 873         case $AFS_SYSNAME in
 874                 i386_fbsd_4?)
 875                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/compile/GENERIC"
 876                         ;;
 877                 i386_fbsd_5?)
 878                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/i386/compile/GENERIC"
 879                         ;;
 880         esac
 881 fi
 882
 883 # Fast restart
 884 if test "$enable_supergroups" = "yes"; then
 885         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
 886 fi
 887
 888 if test "$enable_fast_restart" = "yes"; then
 889         AC_DEFINE(FAST_RESTART, 1, [define if you want to have fast restart])
 890 fi
 891
 892 if test "$enable_bitmap_later" = "yes"; then
 893         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
 894 fi
 895
 896 if test "$enable_full_vos_listvol_switch" = "yes"; then
 897         AC_DEFINE(FULL_LISTVOL_SWITCH, 1, [define if you want to want listvol switch])
 898 fi
 899
 900 if test "$enable_bos_restricted_mode" = "yes"; then
 901         AC_DEFINE(BOS_RESTRICTED_MODE, 1, [define if you want to want bos restricted mode])
 902 fi
 903
 904 if test "$enable_bos_new_config" = "yes"; then
 905         AC_DEFINE(BOS_NEW_CONFIG, 1, [define if you want to enable automatic renaming of BosConfig.new to BosConfig at startup])
 906 fi
 907
 908 if test "$enable_largefile_fileserver" = "yes"; then
 909         AC_DEFINE(AFS_LARGEFILE_ENV, 1, [define if you want large file fileserver])
 910 fi
 911
 912 if test "$enable_namei_fileserver" = "yes"; then
 913         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
 914 fi
 915
 916 if test "$enable_afsdb" = "yes"; then
 917         LIB_AFSDB="$LIB_res_search"
 918         AC_DEFINE(AFS_AFSDB_ENV, 1, [define if you want to want search afsdb rr])
 919 fi
 920
 921 dnl check for tivoli
 922 AC_MSG_CHECKING(for tivoli tsm butc support)
 923 XBSA_CFLAGS=""
 924 if test "$enable_tivoli_tsm" = "yes"; then
 925         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
 926         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
 927
 928         if test -e "$XBSADIR1/xbsa.h"; then
 929                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
 930                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 931         elif test -e "$XBSADIR2/xbsa.h"; then
 932                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
 933                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 934         else
 935                 AC_MSG_RESULT([no, missing xbsa.h header file])
 936         fi
 937 else
 938         AC_MSG_RESULT([no])
 939 fi
 940 AC_SUBST(XBSA_CFLAGS)
 941
 942 dnl checks for header files.
 943 AC_HEADER_STDC
 944 AC_HEADER_SYS_WAIT
 945 AC_HEADER_DIRENT
 946 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
 947 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
 948 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h sys/fstyp.h)
 949 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
 950 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h sys/user.h)
 951 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h ucontext.h regex.h)
 952
 953 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
 954         HAVE_PAM="yes"
 955 else
 956         HAVE_PAM="no"
 957 fi
 958 AC_SUBST(HAVE_PAM)
 959
 960 if test "$enable_login" = yes; then
 961         BUILD_LOGIN="yes"
 962 else
 963         BUILD_LOGIN="no"
 964 fi
 965 AC_SUBST(BUILD_LOGIN)
 966
 967 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf strlcat strlcpy re_comp re_exec)
 968 AC_CHECK_FUNCS(setprogname getprogname sigaction mkstemp vsnprintf strerror)
 969
 970 AC_CHECK_FUNCS(regcomp regexec regerror)
 971 AC_MSG_CHECKING([for POSIX regex library])
 972 if test "$ac_cv_header_regex_h" = "yes" && \
 973         test "$ac_cv_func_regcomp" = "yes" && \
 974         test "$ac_cv_func_regexec" = "yes" && \
 975         test "$ac_cv_func_regerror" = "yes"; then
 976     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
 977     AC_MSG_RESULT(yes)
 978 else
 979     AC_MSG_RESULT(no)
 980 fi
 981
 982 AC_CHECK_TYPE(ssize_t, int)
 983 AC_SIZEOF_TYPE(long)
 984
 985 AC_CHECK_FUNCS(timegm)
 986
 987 dnl Directory PATH handling
 988 if test "x$enable_transarc_paths" = "xyes"  ; then
 989     afsconfdir=${afsconfdir=/usr/afs/etc}
 990     viceetcdir=${viceetcdir=/usr/vice/etc}
 991     afskerneldir=${afskerneldir=${viceetcdir}}
 992     afssrvbindir=${afssrvbindir=/usr/afs/bin}
 993     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
 994     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
 995     afsdbdir=${afsdbdir=/usr/afs/db}
 996     afslogsdir=${afslogsdir=/usr/afs/logs}
 997     afslocaldir=${afslocaldir=/usr/afs/local}
 998     afsbackupdir=${afsbackupdir=/usr/afs/backup}
 999     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1000 else
1001     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1002     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1003     afskerneldir=${afskerneldir='${libdir}/openafs'}
1004     afssrvbindir=${afssrvbindir='${bindir}'}
1005     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1006     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1007     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1008     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1009     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1010     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1011     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1012 fi
1013 AC_SUBST(afsconfdir)
1014 AC_SUBST(viceetcdir)
1015 AC_SUBST(afskerneldir)
1016 AC_SUBST(afssrvbindir)
1017 AC_SUBST(afssrvsbindir)
1018 AC_SUBST(afssrvlibexecdir)
1019 AC_SUBST(afsdbdir)
1020 AC_SUBST(afslogsdir)
1021 AC_SUBST(afslocaldir)
1022 AC_SUBST(afsbackupdir)
1023 AC_SUBST(afsbosconfigdir)
1024
1025 if test "x$enable_kernel_module" = "xyes"; then
1026 ENABLE_KERNEL_MODULE=libafs
1027 fi
1028
1029 AC_SUBST(AFS_SYSNAME)
1030 AC_SUBST(AFS_PARAM_COMMON)
1031 AC_SUBST(ENABLE_KERNEL_MODULE)
1032 AC_SUBST(LIB_AFSDB)
1033 AC_SUBST(LINUX_KERNEL_PATH)
1034 AC_SUBST(BSD_KERNEL_PATH)
1035 AC_SUBST(BSD_KERNEL_BUILD)
1036 AC_SUBST(LINUX_VERSION)
1037 AC_SUBST(MKAFS_OSTYPE)
1038 AC_SUBST(TOP_OBJDIR)
1039 AC_SUBST(TOP_SRCDIR)
1040 AC_SUBST(TOP_INCDIR)
1041 AC_SUBST(TOP_LIBDIR)
1042 AC_SUBST(DEST)
1043 AC_SUBST(WITH_OBSOLETE)
1044 AC_SUBST(WITH_INSECURE)
1045 AC_SUBST(DARWIN_INFOFILE)
1046 AC_SUBST(IRIX_BUILD_IP35)
1047
1048 OPENAFS_OSCONF
1049
1050 TOP_SRCDIR="${srcdir}/src"
1051 dnl
1052 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1053 dnl
1054 case $TOP_SRCDIR in
1055         /*)
1056                 ;;
1057         *)
1058                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1059                 ;;
1060 esac
1061
1062 TOP_OBJDIR="${SRCDIR_PARENT}"
1063 TOP_INCDIR="${SRCDIR_PARENT}/include"
1064 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1065 if test "${DEST}x" = "x"; then
1066         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1067 fi
1068
1069 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1070 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1071 AC_SUBST(HELPER_SPLINT)
1072 AC_SUBST(HELPER_SPLINTCFG)
1073
1074
1075 ])