6f81d512681ec15425d28445c8853cfde910ba85
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN(OPENAFS_CONFIGURE_COMMON,[
8
9 AC_CANONICAL_HOST
10 SRCDIR_PARENT=`pwd`
11
12 #BOZO_SAVE_CORES BOS_RESTRICTED_MODE BOS_NEW_CONFIG pam sia
13 AC_ARG_WITH(afs-sysname,
14 [  --with-afs-sysname=sys    use sys for the afs sysname]
15 )
16 AC_ARG_ENABLE( obsolete,
17 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
18 AC_ARG_ENABLE( insecure,
19 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
20 AC_ARG_ENABLE( afsdb,
21 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
22 AC_ARG_ENABLE( bos-restricted-mode,
23 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
24 AC_ARG_ENABLE( namei-fileserver,
25 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
26 AC_ARG_ENABLE( fast-restart,
27 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
28 AC_ARG_ENABLE( bitmap-later,
29 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
30 AC_ARG_ENABLE( full-vos-listvol-switch,
31 [  --enable-full-vos-listvol-switch     enable vos full listvol switch for formatted output],, enable_full_vos_listvol_switch="no")
32 AC_ARG_WITH(dux-kernel-headers,
33 [  --with-dux-kernel-headers=path       use the kernel headers found at path(optional, defaults to first match in /usr/sys)]
34 )
35 AC_ARG_WITH(linux-kernel-headers,
36 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux)]
37 )
38 AC_ARG_ENABLE(kernel-module,
39 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
40 )
41 AC_ARG_ENABLE(redhat-buildsys,
42 [  --enable-redhat-buildsys             enable compilation of the redhat build system kernel (defaults to disabled)],, enable_redhat_buildsys="no"
43 )
44 AC_ARG_ENABLE(transarc-paths,
45 [  --enable-transarc-paths                      Use Transarc style paths like /usr/afs and /usr/vice],, enable_transarc_paths="no"
46 )
47 AC_ARG_ENABLE(tivoli-tsm,
48 [  --enable-tivoli-tsm                  Enable use of the Tivoli TSM API libraries for butc support],, enable_tivoli_tsm="no"
49 )
50 AC_ARG_ENABLE(debug-kernel,
51 [  --enable-debug-kernel                enable compilation of the kernel module with debugging information (defaults to disabled)],, enable_debug_kernel="no"
52 )
53
54 dnl weird ass systems
55 AC_AIX
56 AC_ISC_POSIX
57 AC_MINIX
58
59 dnl Various compiler setup.
60 AC_TYPE_PID_T
61 AC_TYPE_SIZE_T
62 AC_TYPE_SIGNAL
63
64 dnl Checks for programs.
65 AC_PROG_INSTALL
66 AC_PROG_LN_S
67 AC_PROG_RANLIB
68 AC_PROG_YACC
69 AM_PROG_LEX
70
71 OPENAFS_CHECK_BIGENDIAN
72
73 KERN_DEBUG_OPT=
74 if test "x$enable_debug_kernel" = "xyes"; then
75   KERN_DEBUG_OPT=-g
76 fi
77
78 AC_MSG_CHECKING(your OS)
79 system=$host
80 case $system in
81         *-linux*)
82                 MKAFS_OSTYPE=LINUX
83                 if test "x$enable_redhat_buildsys" = "xyes"; then
84                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS)
85                 fi
86                 if test "x$enable_kernel_module" = "xyes"; then
87                  if test "x$with_linux_kernel_headers" != "x"; then
88                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
89                  else
90                    LINUX_KERNEL_PATH="/usr/src/linux"
91                  fi
92                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
93                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
94                   if test "x$linux_kvers" = "x"; then
95                     if test -f "$LINUX_KERNEL_PATH/include/linux/version-up.h"; then
96                       linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
97                       if test "x$linux_kvers" = "x"; then
98
99                         AC_MSG_ERROR(Linux headers lack version definition [2])
100                         exit 1
101                       else
102                         LINUX_VERSION="$linux_kvers"
103                       fi
104                     else
105                       AC_MSG_ERROR(Linux headers lack version definition)
106                       exit 1
107                     fi
108                   else
109                     LINUX_VERSION="$linux_kvers"
110                   fi
111                  else
112                     enable_kernel_module="no"
113                  fi
114                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
115                      enable_kernel_module="no"
116                  fi
117                  if test "x$enable_kernel_module" = "xno"; then
118                   if test "x$with_linux_kernel_headers" != "x"; then
119                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
120                    exit 1
121                   else
122                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
123                   fi
124                  fi
125                 fi
126                 AC_MSG_RESULT(linux)
127                 if test "x$enable_kernel_module" = "xyes"; then
128                  OMIT_FRAME_POINTER=
129                  if test "x$enable_debug_kernel" = "xno"; then
130                         OMIT_FRAME_POINTER=-fomit-frame-pointer
131                  fi
132                  AC_SUBST(OMIT_FRAME_POINTER)
133                  ifdef([OPENAFS_CONFIGURE_LIBAFS],
134                    [LINUX_BUILD_VNODE_FROM_INODE(src/config,afs)],
135                    [LINUX_BUILD_VNODE_FROM_INODE(${srcdir}/src/config,src/afs/LINUX,${srcdir}/src/afs/LINUX)]
136                  )
137                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK
138                  LINUX_FS_STRUCT_INODE_HAS_I_TRUNCATE_SEM
139                  LINUX_FS_STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS
140                  LINUX_FS_STRUCT_INODE_HAS_I_DEVICES
141                  LINUX_INODE_SETATTR_RETURN_TYPE
142                  LINUX_NEED_RHCONFIG
143                  LINUX_WHICH_MODULES
144                  if test "x$ac_cv_linux_func_inode_setattr_returns_int" = "xyes" ; then
145                   AC_DEFINE(INODE_SETATTR_NOT_VOID)
146                  fi
147                  if test "x$ac_cv_linux_fs_struct_address_space_has_page_lock" = "xyes"; then 
148                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK)
149                  fi
150                  if test "x$ac_cv_linux_fs_struct_inode_has_i_truncate_sem" = "xyes"; then 
151                   AC_DEFINE(STRUCT_INODE_HAS_I_TRUNCATE_SEM)
152                  fi
153                  if test "x$ac_cv_linux_fs_struct_inode_has_i_devices" = "xyes"; then 
154                   AC_DEFINE(STRUCT_INODE_HAS_I_DEVICES)
155                  fi
156                  if test "x$ac_cv_linux_fs_struct_inode_has_i_dirty_data_buffers" = "xyes"; then 
157                   AC_DEFINE(STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS)
158                  fi
159                 :
160                 fi
161                 ;;
162         *-solaris*)
163                 MKAFS_OSTYPE=SOLARIS
164                 AC_MSG_RESULT(sun4)
165                 SOLARIS_UFSVFS_HAS_DQRWLOCK
166                 SOLARIS_PROC_HAS_P_COREFILE
167                 ;;
168         *-hpux*)
169                 MKAFS_OSTYPE=HPUX
170                 AC_MSG_RESULT(hp_ux)
171                 ;;
172         *-irix*)
173                 if test -d /usr/include/sys/SN/SN1; then
174                  IRIX_BUILD_IP35="IP35"
175                 fi
176                 MKAFS_OSTYPE=IRIX
177                 AC_MSG_RESULT(sgi)
178                 ;;
179         *-aix*)
180                 MKAFS_OSTYPE=AIX
181                 AC_MSG_RESULT(rs_aix)
182                 ;;
183         *-osf*)
184                 MKAFS_OSTYPE=DUX
185                 AC_MSG_RESULT(alpha_dux)
186                 if test "x$enable_kernel_module" = "xyes"; then
187                  if test "x$with_dux_kernel_headers" != "x"; then
188                    HEADER_RT=`ls ${with_dux_kernel_headers}/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
189                  else
190                    HEADER_RT=`ls /usr/sys/*/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
191                  fi
192                 fi
193                 if test "$HEADER_RT" = "*" ; then
194                         AC_MSG_ERROR([Need a configured kernel directory])
195                 fi
196                 AC_SUBST([HEADER_RT])
197                 ;;
198         *-darwin*)
199                 MKAFS_OSTYPE=DARWIN
200                 AC_MSG_RESULT(ppc_darwin)
201                 ;;
202         *-freebsd*)
203                 MKAFS_OSTYPE=FBSD
204                 AC_MSG_RESULT(i386_fbsd)
205                 ;;
206         *-netbsd*)
207                 MKAFS_OSTYPE=NBSD
208                 AC_MSG_RESULT(nbsd)
209                 ;;
210         *-openbsd*)
211                 MKAFS_OSTYPE=OBSD
212                 AC_MSG_RESULT(i386_obsd)
213                 ;;
214         *)
215                 AC_MSG_RESULT($system)
216                 ;;
217 esac
218 AC_SUBST(KERN_DEBUG_OPT)
219
220 if test "x$with_afs_sysname" != "x"; then
221         AFS_SYSNAME="$with_afs_sysname"
222 else
223         AC_MSG_CHECKING(your AFS sysname)
224         case $host in
225                 i?86-*-freebsd4.2*)
226                         AFS_SYSNAME="i386_fbsd_42"
227                         ;;
228                 i?86-*-freebsd4.3*)
229                         AFS_SYSNAME="i386_fbsd_43"
230                         ;;
231                 i?86-*-freebsd4.4*)
232                         AFS_SYSNAME="i386_fbsd_44"
233                         ;;
234                 i?86-*-freebsd4.5*)
235                         AFS_SYSNAME="i386_fbsd_45"
236                         ;;
237                 i?86-*-netbsd*1.5*)
238                         AFS_PARAM_COMMON=param.nbsd15.h
239                         AFS_SYSNAME="i386_nbsd15"
240                         ;;
241                 alpha-*-netbsd*1.5*)
242                         AFS_PARAM_COMMON=param.nbsd15.h
243                         AFS_SYSNAME="alpha_nbsd15"
244                         ;;
245                 hppa*-hp-hpux11*)
246                         AFS_SYSNAME="hp_ux110"
247                         ;;
248                 hppa*-hp-hpux10*)
249                         AFS_SYSNAME="hp_ux102"
250                         ;;
251                 powerpc-apple-darwin1.2*)
252                         AFS_SYSNAME="ppc_darwin_12"
253                         ;;
254                 powerpc-apple-darwin1.3*)
255                         AFS_SYSNAME="ppc_darwin_13"
256                         ;;
257                 powerpc-apple-darwin1.4*)
258                         AFS_SYSNAME="ppc_darwin_14"
259                         ;;
260                 powerpc-apple-darwin5.1*)
261                         AFS_SYSNAME="ppc_darwin_14"
262                         ;;
263                 powerpc-apple-darwin5.2*)
264                         AFS_SYSNAME="ppc_darwin_14"
265                         ;;
266                 powerpc-apple-darwin5.3*)
267                         AFS_SYSNAME="ppc_darwin_14"
268                         ;;
269                 powerpc-apple-darwin5.4*)
270                         AFS_SYSNAME="ppc_darwin_14"
271                         ;;
272                 powerpc-apple-darwin5.5*)
273                         AFS_SYSNAME="ppc_darwin_14"
274                         ;;
275                 sparc-sun-solaris2.5*)
276                         AFS_SYSNAME="sun4x_55"
277                         ;;
278                 sparc-sun-solaris2.6)
279                         AFS_SYSNAME="sun4x_56"
280                         ;;
281                 sparc-sun-solaris2.7)
282                         AFS_SYSNAME="sun4x_57"
283                         ;;
284                 sparc-sun-solaris2.8)
285                         AFS_SYSNAME="sun4x_58"
286                         ;;
287                 sparc-sun-solaris2.9)
288                         AFS_SYSNAME="sun4x_59"
289                         ;;
290                 alpha*-dec-osf4.0*)
291                         AFS_SYSNAME="alpha_dux40"
292                         ;;
293                 alpha*-dec-osf5.0*)
294                         AFS_SYSNAME="alpha_dux50"
295                         ;;
296                 mips-sgi-irix6.5)
297                         AFS_SYSNAME="sgi_65"
298                         ;;
299                 ia64-*-linux*)
300                         AFS_SYSNAME="ia64_linuxXX"
301                         ;;
302                 powerpc-*-linux*)
303                         AFS_SYSNAME="ppc_linuxXX"
304                         ;;
305                 alpha*-linux*)
306                         AFS_SYSNAME="alpha_linux_XX"
307                         ;;
308                 s390-*-linux*)
309                         AFS_SYSNAME="s390_linuxXX"
310                         ;;
311                 sparc-*-linux*)
312                         AFS_SYSNAME="sparc_linuxXX"
313                         ;;
314                 sparc64-*-linux*)
315                         AFS_SYSNAME="sparc64_linuxXX"
316                         ;;
317                 i?86-*-linux*)
318                         AFS_SYSNAME="i386_linuxXX"
319                         ;;
320                 parisc-*-linux-gnu)
321                         AFS_SYSNAME="parisc_linuxXX"
322                         ;;
323                 power*-ibm-aix4.2*)
324                         AFS_SYSNAME="rs_aix42"
325                         ;;
326                 power*-ibm-aix4.3*)
327                         AFS_SYSNAME="rs_aix42"
328                         ;;
329                 *)
330                         AC_MSG_ERROR(An AFS sysname is required)
331                         exit 1
332                         ;;
333         esac
334         case $AFS_SYSNAME in
335                 *_linux*)
336                         AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $[]1 $[]2}'`
337                         if test "x${AFS_SYSKVERS}" = "x"; then
338                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
339                         fi
340                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
341                         AFS_SYSNAME="$_AFS_SYSNAME"
342                         ;;
343         esac
344         AC_MSG_RESULT($AFS_SYSNAME)
345 fi
346
347 case $AFS_SYSNAME in
348         *_darwin*)
349                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
350                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
351                 ;;
352 esac
353 AC_CACHE_VAL(ac_cv_sockaddr_len,
354 [
355 AC_MSG_CHECKING([if struct sockaddr has sa_len field])
356 AC_TRY_COMPILE( [#include <sys/types.h>
357 #include <sys/socket.h>],
358 [struct sockaddr *a;
359 a->sa_len=0;], ac_cv_sockaddr_len=yes, ac_cv_sockaddr_len=no)
360 AC_MSG_RESULT($ac_cv_sockaddr_len)])
361 if test "$ac_cv_sockaddr_len" = "yes"; then
362    AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN)
363 fi
364 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
365         echo Skipping library tests because they confuse Irix.
366 else
367   AC_CHECK_FUNCS(socket)
368
369   if test "$ac_cv_func_socket" = no; then
370     for lib in socket inet; do
371         if test "$HAVE_SOCKET" != 1; then
372                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET))
373         fi
374     done
375   fi
376   
377   AC_CHECK_FUNCS(connect)       
378
379   if test "$ac_cv_func_connect" = no; then
380     for lib in nsl; do
381         if test "$HAVE_CONNECT" != 1; then
382                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT))
383         fi
384     done
385   fi
386
387   AC_CHECK_FUNCS(gethostbyname)
388   if test "$ac_cv_func_gethostbyname" = no; then
389         for lib in dns nsl resolv; do
390           if test "$HAVE_GETHOSTBYNAME" != 1; then
391             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME))
392           fi
393         done    
394   fi    
395
396   AC_CHECK_FUNCS(res_search)
397   if test "$ac_cv_func_res_search" = no; then
398         for lib in dns nsl resolv; do
399           if test "$HAVE_RES_SEARCH" != 1; then
400             AC_CHECK_LIB(${lib}, res_search, LIBS="$LIBS -l$lib";HAVE_RES_SEARCH=1;AC_DEFINE(HAVE_RES_SEARCH))
401           fi
402         done    
403         if test "$HAVE_RES_SEARCH" = 1; then
404           LIB_res_search="-l$lib"       
405         fi
406   fi    
407 fi
408
409 PTHREAD_LIBS=error
410 AC_CHECK_LIB(pthread, pthread_attr_init,
411              PTHREAD_LIBS="-lpthread")
412 if test "x$PTHREAD_LIBS" = xerror; then
413         AC_CHECK_LIB(pthreads, pthread_attr_init,
414                 PTHREAD_LIBS="-lpthreads")
415 fi
416 if test "x$PTHREAD_LIBS" = xerror; then
417         AC_CHECK_LIB(c_r, pthread_attr_init,
418                 PTHREAD_LIBS="-lc_r")
419 fi
420 if test "x$PTHREAD_LIBS" = xerror; then
421         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
422 fi
423 if test "x$PTHREAD_LIBS" = xerror; then
424         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
425 fi
426 AC_SUBST(PTHREAD_LIBS)
427
428 WITH_OBSOLETE=NO
429 if test "$enable_obsolete" = "yes"; then
430         WITH_OBSOLETE=YES
431 fi
432
433 WITH_INSECURE=NO
434 if test "$enable_insecure" = "yes"; then
435         WITH_INSECURE=YES
436 fi
437
438 # Fast restart
439 if test "$enable_fast_restart" = "yes"; then
440         AC_DEFINE(FAST_RESTART)
441 fi
442
443 if test "$enable_bitmap_later" = "yes"; then
444         AC_DEFINE(BITMAP_LATER)
445 fi
446
447 if test "$enable_full_vos_listvol_switch" = "yes"; then
448         AC_DEFINE(FULL_LISTVOL_SWITCH)
449 fi
450
451 if test "$enable_bos_restricted_mode" = "yes"; then
452         AC_DEFINE(BOS_RESTRICTED_MODE)
453 fi
454
455 if test "$enable_namei_fileserver" = "yes"; then
456         AC_DEFINE(AFS_NAMEI_ENV)
457 fi
458
459 if test "$enable_afsdb" = "yes"; then
460         LIB_AFSDB="$LIB_res_search"
461         AC_DEFINE(AFS_AFSDB_ENV)
462 fi
463
464 dnl check for tivoli
465 AC_MSG_CHECKING(for tivoli tsm butc support)
466 XBSA_CFLAGS=""
467 if test "$enable_tivoli_tsm" = "yes"; then
468         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
469         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
470
471         if test -e "$XBSADIR1/xbsa.h"; then
472                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
473                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
474         elif test -e "$XBSADIR2/xbsa.h"; then
475                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
476                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
477         else
478                 AC_MSG_RESULT([no, missing xbsa.h header file])
479         fi
480 else
481         AC_MSG_RESULT([no])
482 fi
483 AC_SUBST(XBSA_CFLAGS)
484
485 dnl checks for header files.
486 AC_HEADER_STDC
487 AC_HEADER_SYS_WAIT
488 AC_HEADER_DIRENT
489 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
490 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
491 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h)
492 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
493 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h)
494 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h)
495
496 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf re_comp re_exec)
497 AC_CHECK_FUNCS(setprogname getprogname)
498
499 dnl Directory PATH handling
500 if test "x$enable_transarc_paths" = "xyes"  ; then 
501     afsconfdir=${afsconfdir=/usr/afs/etc}
502     viceetcdir=${viceetcdir=/usr/vice/etc}
503     afskerneldir=${afskerneldir=${viceetcdir}}
504     afssrvbindir=${afssrvbindir=/usr/afs/bin}
505     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
506     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
507     afsdbdir=${afsdbdir=/usr/afs/db}
508     afslogsdir=${afslogsdir=/usr/afs/logs}
509     afslocaldir=${afslocaldir=/usr/afs/local}
510     afsbackupdir=${afsbackupdir=/usr/afs/backup}
511     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
512 else 
513     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
514     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
515     afskerneldir=${afskerneldir='${libdir}/openafs'}
516     afssrvbindir=${afssrvbindir='${bindir}'}
517     afssrvsbindir=${afssrvsbindir='${sbindir}'}
518     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
519     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
520     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
521     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
522     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
523     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
524 fi
525 AC_SUBST(afsconfdir)
526 AC_SUBST(viceetcdir)
527 AC_SUBST(afskerneldir)
528 AC_SUBST(afssrvbindir)
529 AC_SUBST(afssrvsbindir)
530 AC_SUBST(afssrvlibexecdir)
531 AC_SUBST(afsdbdir)
532 AC_SUBST(afslogsdir)
533 AC_SUBST(afslocaldir)
534 AC_SUBST(afsbackupdir)
535 AC_SUBST(afsbosconfigdir)
536
537 if test "x$enable_kernel_module" = "xyes"; then
538 ENABLE_KERNEL_MODULE=libafs
539 fi
540
541 AC_SUBST(AFS_SYSNAME)
542 AC_SUBST(AFS_PARAM_COMMON)
543 AC_SUBST(ENABLE_KERNEL_MODULE)
544 AC_SUBST(LIB_AFSDB)
545 AC_SUBST(LINUX_KERNEL_PATH)
546 AC_SUBST(LINUX_VERSION)
547 AC_SUBST(MKAFS_OSTYPE)
548 AC_SUBST(TOP_OBJDIR)
549 AC_SUBST(TOP_SRCDIR)
550 AC_SUBST(TOP_INCDIR)
551 AC_SUBST(TOP_LIBDIR)
552 AC_SUBST(DEST)
553 AC_SUBST(WITH_OBSOLETE)
554 AC_SUBST(WITH_INSECURE)
555 AC_SUBST(DARWIN_INFOFILE)
556 AC_SUBST(IRIX_BUILD_IP35)
557
558 OPENAFS_OSCONF
559
560 ])