acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #   define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 #define _FILE_OFFSET_BITS 64
  48 #define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 #include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
  76
  77 dnl General feature options.
  78 AC_ARG_ENABLE([gtx],
  79     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
  80 AC_ARG_ENABLE([uss],
  81     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
  82 AC_ARG_ENABLE([namei-fileserver],
  83     [AS_HELP_STRING([--enable-namei-fileserver],
  84         [force compilation of namei fileserver in preference to inode
  85          fileserver])],
  86     ,
  87     [enable_namei_fileserver="default"])
  88 AC_ARG_ENABLE([supergroups],
  89     [AS_HELP_STRING([--enable-supergroups],
  90         [enable support for nested pts groups])],
  91     ,
  92     [enable_supergroups="no"])
  93 AC_ARG_ENABLE([bitmap-later],
  94     [AS_HELP_STRING([--enable-bitmap-later],
  95         [enable fast startup of file server by not reading bitmap till
  96          needed])],
  97     [AS_IF([test x"$withval" = xyes],
  98         [AC_MSG_WARN([bitmap-later is only used by non-demand-attach
  99             fileservers.  Please migrate to demand-attach instead.])])],
 100     [enable_bitmap_later="no"])
 101 AC_ARG_ENABLE([unix-sockets],
 102     [AS_HELP_STRING([--disable-unix-sockets],
 103         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 104     ,
 105     [enable_unix_sockets="yes"])
 106 AC_ARG_ENABLE([tivoli-tsm],
 107     [AS_HELP_STRING([--enable-tivoli-tsm],
 108         [enable use of the Tivoli TSM API libraries for butc support])],
 109     ,
 110     [enable_tivoli_tsm="no"])
 111 AC_ARG_ENABLE([pthreaded-ubik],
 112     [AS_HELP_STRING([--disable-pthreaded-ubik],
 113         [disable installation of pthreaded ubik applications (defaults to
 114          enabled)])],
 115     ,
 116     [enable_pthreaded_ubik="yes"])
 117
 118 dnl Kernel module build options.
 119 AC_ARG_WITH([linux-kernel-headers],
 120     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 121         [use the kernel headers found at path (optional, defaults to
 122          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
 123          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
 124 AC_ARG_WITH([linux-kernel-build],
 125     [AS_HELP_STRING([--with-linux-kernel-build=path],
 126         [use the kernel build found at path(optional, defaults to
 127         kernel headers path)])])
 128 AC_ARG_WITH([bsd-kernel-headers],
 129     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 130         [use the kernel headers found at path (optional, defaults to
 131          /usr/src/sys)])])
 132 AC_ARG_WITH([bsd-kernel-build],
 133     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 134         [use the kernel build found at path (optional, defaults to
 135          KSRC/i386/compile/GENERIC)])])
 136 AC_ARG_WITH([linux-kernel-packaging],
 137     [AS_HELP_STRING([--with-linux-kernel-packaging],
 138         [use standard naming conventions to aid Linux kernel build packaging
 139          (disables MPS, sets the kernel module name to openafs.ko, and
 140          installs kernel modules into the standard Linux location)])],
 141     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
 142      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
 143     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
 144 AC_ARG_ENABLE([kernel-module],
 145     [AS_HELP_STRING([--disable-kernel-module],
 146         [disable compilation of the kernel module (defaults to enabled)])],
 147     ,
 148     [enable_kernel_module="yes"])
 149 AC_ARG_ENABLE([redhat-buildsys],
 150     [AS_HELP_STRING([--enable-redhat-buildsys],
 151         [enable compilation of the redhat build system kernel (defaults to
 152          disabled)])],
 153     ,
 154     [enable_redhat_buildsys="no"])
 155
 156 dnl Installation locations.
 157 AC_ARG_ENABLE([transarc-paths],
 158     [AS_HELP_STRING([--enable-transarc-paths],
 159         [use Transarc style paths like /usr/afs and /usr/vice])],
 160     ,
 161     [enable_transarc_paths="no"])
 162
 163 dnl Deprecated crypto
 164 AC_ARG_ENABLE([kauth],
 165     [AS_HELP_STRING([--enable-kauth],
 166         [install the deprecated kauth server, pam modules, and utilities
 167          (defaults to disabled)])],
 168     [enable_pam="yes"],
 169     [enable_kauth="no"
 170      enable_pam="no"])
 171
 172 dnl Optimization and debugging flags.
 173 AC_ARG_ENABLE([strip-binaries],
 174     [AS_HELP_STRING([--disable-strip-binaries],
 175         [disable stripping of symbol information from binaries (defaults to
 176          enabled)])],
 177     ,
 178     [enable_strip_binaries="maybe"])
 179 AC_ARG_ENABLE([debug],
 180     [AS_HELP_STRING([--enable-debug],
 181         [enable compilation of the user space code with debugging information
 182          (defaults to disabled)])],
 183     ,
 184     [enable_debug="no"])
 185 AC_ARG_ENABLE([optimize],
 186     [AS_HELP_STRING([--disable-optimize],
 187         [disable optimization for compilation of the user space code (defaults
 188          to enabled)])],
 189     ,
 190     [enable_optimize="yes"])
 191 AC_ARG_ENABLE([warnings],
 192     [AS_HELP_STRING([--enable-warnings],
 193         [enable compilation warnings when building with gcc (defaults to
 194          disabled)])],
 195     ,
 196     [enable_warnings="no"])
 197 AC_ARG_ENABLE([checking],
 198     [AS_HELP_STRING([--enable-checking],
 199         [turn compilation warnings into errors when building with gcc (defaults
 200          to disabled)])],
 201     [enable_checking="$enableval"],
 202     [enable_checking="no"])
 203 AC_ARG_ENABLE([debug-locks],
 204     [AS_HELP_STRING([--enable-debug-locks],
 205         [turn on lock debugging assertions (defaults to disabled)])],
 206     [enable_debug_locks="$enableval"],
 207     [enable_debug_locks="no"])
 208 AC_ARG_ENABLE([debug-kernel],
 209     [AS_HELP_STRING([--enable-debug-kernel],
 210         [enable compilation of the kernel module with debugging information
 211          (defaults to disabled)])],
 212     ,
 213     [enable_debug_kernel="no"])
 214 AC_ARG_ENABLE([optimize-kernel],
 215     [AS_HELP_STRING([--disable-optimize-kernel],
 216         [disable compilation of the kernel module with optimization (defaults
 217          based on platform)])],
 218     ,
 219     [enable_optimize_kernel=""])
 220 AC_ARG_ENABLE([debug-lwp],
 221     [AS_HELP_STRING([--enable-debug-lwp],
 222         [enable compilation of the LWP code with debugging information
 223          (defaults to disabled)])],
 224     ,
 225     [enable_debug_lwp="no"])
 226 AC_ARG_ENABLE([optimize-lwp],
 227     [AS_HELP_STRING([--disable-optimize-lwp],
 228         [disable optimization for compilation of the LWP code (defaults to
 229          enabled)])],
 230     ,
 231     [enable_optimize_lwp="yes"])
 232 AC_ARG_ENABLE([debug-pam],
 233     [AS_HELP_STRING([--enable-debug-pam],
 234         [enable compilation of the PAM code with debugging information
 235          (defaults to disabled)])],
 236     ,
 237     [enable_debug_pam="no"])
 238 AC_ARG_ENABLE([optimize-pam],
 239     [AS_HELP_STRING([--disable-optimize-pam],
 240         [disable optimization for compilation of the PAM code (defaults to
 241          enabled)])],
 242     ,
 243     [enable_optimize_pam="yes"])
 244 AC_ARG_ENABLE([linux-syscall-probing],
 245     [AS_HELP_STRING([--enable-linux-syscall-probing],
 246         [enable Linux syscall probing (defaults to autodetect)])],
 247     ,
 248     [enable_linux_syscall_probing="maybe"])
 249 AC_ARG_WITH([crosstools-dir],
 250     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
 251
 252 AC_ARG_WITH([xslt-processor],
 253         AS_HELP_STRING([--with-xslt-processor=ARG],
 254         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 255         [XSLTPROC="$withval"],
 256         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
 257
 258 AC_ARG_WITH([html-xsl],
 259         AS_HELP_STRING([--with-html-xsl],
 260         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 261         [HTML_XSL="$withval"],
 262         [HTML_XSL="html/chunk.xsl"])
 263
 264 AC_ARG_WITH([docbook2pdf],
 265         AS_HELP_STRING([--with-docbook2pdf=ARG],
 266         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 267         [DOCBOOK2PDF="$withval"],
 268         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
 269
 270 AC_ARG_WITH([docbook-stylesheets],
 271         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 272         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 273         [DOCBOOK_STYLESHEETS="$withval"],
 274         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
 275         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
 276                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 277         fi)
 278
 279 AC_ARG_WITH([dot],
 280         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
 281         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
 282         [], [with_dot="maybe"])
 283
 284 enable_login="no"
 285
 286 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 287 dnl documentation build.
 288 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 289 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 290
 291 dnl Optionally generate graphs with doxygen.
 292 case "$with_dot" in
 293 maybe)
 294     AC_CHECK_PROGS([DOT], [dot])
 295     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
 296     ;;
 297 yes)
 298     HAVE_DOT="yes"
 299     ;;
 300 no)
 301     HAVE_DOT="no"
 302     ;;
 303 *)
 304     HAVE_DOT="yes"
 305     DOT_PATH=$with_dot
 306 esac
 307 AC_SUBST(HAVE_DOT)
 308 AC_SUBST(DOT_PATH)
 309
 310 dnl Checks for UNIX variants.
 311 AC_ISC_POSIX
 312
 313 dnl Various compiler setup.
 314 AC_TYPE_PID_T
 315 AC_TYPE_SIZE_T
 316
 317 dnl Checks for programs.
 318 AC_PROG_INSTALL
 319 AC_PROG_LN_S
 320 AC_PROG_RANLIB
 321 AC_PROG_YACC
 322 AM_PROG_LEX
 323 dnl if we are flex, be lex-compatible
 324 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 325
 326 OPENAFS_FORCE_ABS_INSTALL
 327 OPENAFS_CHECK_BIGENDIAN
 328 OPENAFS_PRINTF_TAKES_Z_LEN
 329
 330 AC_MSG_CHECKING(your OS)
 331 system=$host
 332 case $system in
 333         *-linux*)
 334
 335                 MKAFS_OSTYPE=LINUX
 336                 if test "x$enable_redhat_buildsys" = "xyes"; then
 337                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 338                 fi
 339                 if test "x$enable_kernel_module" = "xyes"; then
 340                  if test "x$with_linux_kernel_headers" != "x"; then
 341                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 342                  else
 343                    for utsdir in "/lib/modules/`uname -r`/build" \
 344                                  "/lib/modules/`uname -r`/source" \
 345                                  "/usr/src/linux-2.4" \
 346                                  "/usr/src/linux"; do
 347                      LINUX_KERNEL_PATH="$utsdir"
 348                      for utsfile in "include/generated/utsrelease.h" \
 349                                     "include/linux/utsrelease.h" \
 350                                     "include/linux/version.h" \
 351                                     "include/linux/version-up.h"; do
 352                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
 353                          break 2
 354                        fi
 355                      done
 356                    done
 357                  fi
 358                  if test "x$with_linux_kernel_build" != "x"; then
 359                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 360                  else
 361                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 362                  fi
 363                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 364                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 365                    LINUX_VERSION="$linux_kvers"
 366                  else
 367                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 368                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 369                      LINUX_VERSION="$linux_kvers"
 370                    else
 371                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 372                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 373                        if test "x$linux_kvers" = "x"; then
 374                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 375                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 376                            if test "x$linux_kvers" = "x"; then
 377                              AC_MSG_ERROR(Linux headers lack version definition [2])
 378                              exit 1
 379                            else
 380                              LINUX_VERSION="$linux_kvers"
 381                            fi
 382                          else
 383                            AC_MSG_ERROR(Linux headers lack version definition)
 384                            exit 1
 385                          fi
 386                        else
 387                          LINUX_VERSION="$linux_kvers"
 388                        fi
 389                      else
 390                        enable_kernel_module="no"
 391                      fi
 392                    fi
 393                  fi
 394                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 395                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 396                      enable_kernel_module="no"
 397                  fi
 398                  if test "x$enable_kernel_module" = "xno"; then
 399                   if test "x$with_linux_kernel_headers" != "x"; then
 400                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 401                    exit 1
 402                   else
 403                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 404                   fi
 405                  fi
 406                  dnl do we need to determine SUBARCH from autoconf.h
 407                  SUBARCH=default
 408                 fi
 409                 AC_MSG_RESULT(linux)
 410                 if test "x$enable_kernel_module" = "xyes"; then
 411                  case "$LINUX_VERSION" in
 412                   2.2.*) AFS_SYSKVERS=22 ;;
 413                   2.4.*) AFS_SYSKVERS=24 ;;
 414                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
 415                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 416                  esac
 417                 fi
 418                 ;;
 419         *-solaris*)
 420                 MKAFS_OSTYPE=SOLARIS
 421                 AC_MSG_RESULT(sun4)
 422                 AC_PATH_PROG(SOLARISCC, [cc], ,
 423                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 424                 if test "x$SOLARISCC" = "x" ; then
 425                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 426                 fi
 427                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 428                 SOLARIS_FS_HAS_FS_ROLLED
 429                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 430                 SOLARIS_HAVE_VN_RENAMEPATH
 431                 ;;
 432         *-sunos*)
 433                 MKAFS_OSTYPE=SUNOS
 434                 enable_kernel_module=no
 435                 AC_MSG_RESULT(sun4)
 436                 ;;
 437         *-hpux*)
 438                 MKAFS_OSTYPE=HPUX
 439                 AC_MSG_RESULT(hp_ux)
 440                 if test -f "/usr/old/usr/include/ndir.h"; then
 441                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 442                 fi
 443                 ;;
 444         *-irix*)
 445                 if test -d /usr/include/sys/SN/SN1; then
 446                  IRIX_BUILD_IP35="IP35"
 447                 fi
 448                 MKAFS_OSTYPE=IRIX
 449                 AC_MSG_RESULT(sgi)
 450                 ;;
 451         *-aix*)
 452                 MKAFS_OSTYPE=AIX
 453                 AC_MSG_RESULT(rs_aix)
 454                 ;;
 455         arm-*-darwin*)
 456                 MKAFS_OSTYPE=DARWIN
 457                 AC_MSG_RESULT(arm_darwin)
 458                 ;;
 459         powerpc-*-darwin*)
 460                 MKAFS_OSTYPE=DARWIN
 461                 AC_MSG_RESULT(ppc_darwin)
 462                 ;;
 463         i386-*-darwin*)
 464                 MKAFS_OSTYPE=DARWIN
 465                 AC_MSG_RESULT(x86_darwin)
 466                 ;;
 467         x86_64-*-darwin*)
 468                 MKAFS_OSTYPE=DARWIN
 469                 AC_MSG_RESULT(x86_darwin)
 470                 ;;
 471         i386-*-freebsd*)
 472                 MKAFS_OSTYPE=FBSD
 473                 AC_MSG_RESULT(i386_fbsd)
 474                 ;;
 475         x86_64-*-freebsd*)
 476                 MKAFS_OSTYPE=FBSD
 477                 AC_MSG_RESULT(amd64_fbsd)
 478                 ;;
 479         *-netbsd*)
 480                 MKAFS_OSTYPE=NBSD
 481                 AC_MSG_RESULT(nbsd)
 482                 ;;
 483         x86_64-*-openbsd*)
 484                 MKAFS_OSTYPE=OBSD
 485                 AC_MSG_RESULT(amd64_obsd)
 486                 ;;
 487         i386-*-openbsd*)
 488                 MKAFS_OSTYPE=OBSD
 489                 AC_MSG_RESULT(i386_obsd)
 490                 ;;
 491         *-dragonfly*)
 492                 MKAFS_OSTYPE=DFBSD
 493                 AC_MSG_RESULT(i386_dfbsd)
 494                 ;;
 495         *)
 496                 AC_MSG_RESULT($system)
 497                 ;;
 498 esac
 499
 500 if test "x$with_afs_sysname" != "x"; then
 501         AFS_SYSNAME="$with_afs_sysname"
 502 else
 503         AC_MSG_CHECKING(your AFS sysname)
 504         case $host in
 505                 i?86-*-openbsd?.?)
 506                         v=${host#*openbsd}
 507                         vM=${v%.*}
 508                         vm=${v#*.}
 509                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 510                         ;;
 511                 sparc64-*-openbsd?.?)
 512                         v=${host#*openbsd}
 513                         vM=${v%.*}
 514                         vm=${v#*.}
 515                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 516                         ;;
 517                 x86_64-*-openbsd?.?)
 518                         v=${host#*openbsd}
 519                         vM=${v%.*}
 520                         vm=${v#*.}
 521                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 522                         ;;
 523                 i?86-*-freebsd*.*)
 524                         v=${host#*freebsd}
 525                         vM=${v%.*}
 526                         vm=${v#*.}
 527                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 528                         ;;
 529                 x86_64-*-freebsd*.*)
 530                         v=${host#*freebsd}
 531                         vM=${v%.*}
 532                         vm=${v#*.}
 533                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 534                         ;;
 535                 i386-*-dragonfly?.*)
 536                         v=${host#*dragonfly}
 537                         vM=${v%.*}
 538                         vm=${v#*.}
 539                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 540                         ;;
 541                 i?86-*-netbsd*1.6[[M-Z]]*)
 542                         AFS_SYSNAME="i386_nbsd20"
 543                         ;;
 544                 powerpc-*-netbsd*1.6[[M-Z]]*)
 545                         AFS_SYSNAME="ppc_nbsd20"
 546                         ;;
 547                 *-*-netbsd*)
 548                         arch=${host%%-unknown*}
 549                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 550                                                -e 's/powerpc/ppc/g')
 551                         v=${host#*netbsd}
 552                         v=${v#*aout}
 553                         v=${v#*ecoff}
 554                         v=${v#*elf}
 555                         vM=${v%%.*}
 556                         vM=${vM%.*}
 557                         v=${v#*.}
 558                         vm=${v%%.*}
 559                         vm=${vm%.*}
 560                         vm=${vm%%[[_A-Z]]*}
 561                         if test $vm -eq 99 ; then
 562                                 vM=$((vM+1))
 563                         fi
 564                         if test $vM -gt 1 ; then
 565                                 vm=0
 566                         fi
 567                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 568                         ;;
 569                 hppa*-hp-hpux11.0*)
 570                         AFS_SYSNAME="hp_ux110"
 571                         ;;
 572                 hppa*-hp-hpux11.11)
 573                         AFS_SYSNAME="hp_ux11i"
 574                         ;;
 575                 hppa*-hp-hpux11.23)
 576                         AFS_SYSNAME="hp_ux1123"
 577                         ;;
 578                 ia64-hp-hpux11.22)
 579                         AFS_SYSNAME="ia64_hpux1122"
 580                         ;;
 581                 ia64-hp-hpux*)
 582                         AFS_SYSNAME="ia64_hpux1123"
 583                         ;;
 584                 hppa*-hp-hpux10*)
 585                         AFS_SYSNAME="hp_ux102"
 586                         ;;
 587                 powerpc-apple-darwin7*)
 588                         AFS_SYSNAME="ppc_darwin_70"
 589                         OSXSDK="macosx10.3"
 590                         ;;
 591                 powerpc-apple-darwin8.*)
 592                         AFS_SYSNAME="ppc_darwin_80"
 593                         OSXSDK="macosx10.4"
 594                         ;;
 595                 i386-apple-darwin8.*)
 596                         AFS_SYSNAME="x86_darwin_80"
 597                         OSXSDK="macosx10.4"
 598                         ;;
 599                 powerpc-apple-darwin9.*)
 600                         AFS_SYSNAME="ppc_darwin_90"
 601                         OSXSDK="macosx10.5"
 602                         ;;
 603                 i386-apple-darwin9.*)
 604                         AFS_SYSNAME="x86_darwin_90"
 605                         OSXSDK="macosx10.5"
 606                         ;;
 607                 i?86-apple-darwin10.*)
 608                         AFS_SYSNAME="x86_darwin_100"
 609                         OSXSDK="macosx10.6"
 610                         ;;
 611                 x86_64-apple-darwin10.*)
 612                         AFS_SYSNAME="x86_darwin_100"
 613                         OSXSDK="macosx10.6"
 614                         ;;
 615                 arm-apple-darwin10.*)
 616                         AFS_SYSNAME="arm_darwin_100"
 617                         OSXSDK="iphoneos4.0"
 618                         ;;
 619                 x86_64-apple-darwin11.*)
 620                         AFS_SYSNAME="x86_darwin_110"
 621                         OSXSDK="macosx10.7"
 622                         ;;
 623                 i?86-apple-darwin11.*)
 624                         AFS_SYSNAME="x86_darwin_110"
 625                         OSXSDK="macosx10.7"
 626                         ;;
 627                 x86_64-apple-darwin12.*)
 628                         AFS_SYSNAME="x86_darwin_120"
 629                         OSXSDK="macosx10.8"
 630                         ;;
 631                 i?86-apple-darwin12.*)
 632                         AFS_SYSNAME="x86_darwin_120"
 633                         OSXSDK="macosx10.8"
 634                         ;;
 635                 x86_64-apple-darwin13.*)
 636                         AFS_SYSNAME="x86_darwin_130"
 637                         OSXSDK="macosx10.9"
 638                         ;;
 639                 i?86-apple-darwin13.*)
 640                         AFS_SYSNAME="x86_darwin_130"
 641                         OSXSDK="macosx10.9"
 642                         ;;
 643                 x86_64-apple-darwin14.*)
 644                         AFS_SYSNAME="x86_darwin_140"
 645                         OSXSDK="macosx10.10"
 646                         ;;
 647                 i?86-apple-darwin14.*)
 648                         AFS_SYSNAME="x86_darwin_140"
 649                         OSXSDK="macosx10.10"
 650                         ;;
 651                 sparc-sun-solaris2.8)
 652                         AFS_SYSNAME="sun4x_58"
 653                         ;;
 654                 sparc-sun-solaris2.9)
 655                         AFS_SYSNAME="sun4x_59"
 656                         ;;
 657                 sparc-sun-solaris2.10)
 658                         AFS_SYSNAME="sun4x_510"
 659                         ;;
 660                 sparc-sun-solaris2.11)
 661                         AFS_SYSNAME="sun4x_511"
 662                         ;;
 663                 i386-pc-solaris2.8)
 664                         AFS_SYSNAME="sunx86_58"
 665                         ;;
 666                 i386-pc-solaris2.9)
 667                         AFS_SYSNAME="sunx86_59"
 668                         ;;
 669                 i386-pc-solaris2.10)
 670                         AFS_SYSNAME="sunx86_510"
 671                         ;;
 672                 i386-pc-solaris2.11)
 673                         AFS_SYSNAME="sunx86_511"
 674                         ;;
 675                 alpha*-dec-osf4.0*)
 676                         AFS_SYSNAME="alpha_dux40"
 677                         ;;
 678                 alpha*-dec-osf5.0*)
 679                         AFS_SYSNAME="alpha_dux50"
 680                         ;;
 681                 alpha*-dec-osf5.1*)
 682                         AFS_SYSNAME="alpha_dux51"
 683                         ;;
 684                 mips-sgi-irix6.5)
 685                         AFS_SYSNAME="sgi_65"
 686                         enable_pam="no"
 687                         ;;
 688                 ia64-*-linux*)
 689                         AFS_SYSNAME="ia64_linuxXX"
 690                         ;;
 691                 powerpc-*-linux*)
 692                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 693                         ;;
 694                 powerpc64-*-linux*)
 695                         AFS_SYSNAME="ppc64_linuxXX"
 696                         ;;
 697                 alpha*-linux*)
 698                         AFS_SYSNAME="alpha_linux_XX"
 699                         ;;
 700                 s390-*-linux*)
 701                         AFS_SYSNAME="s390_linuxXX"
 702                         ;;
 703                 s390x-*-linux*)
 704                         AFS_SYSNAME="s390x_linuxXX"
 705                         ;;
 706                 sparc-*-linux*)
 707                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 708                         ;;
 709                 sparc64-*-linux*)
 710                         AFS_SYSNAME="sparc64_linuxXX"
 711                         ;;
 712                 i?86-*-linux*)
 713                         AFS_SYSNAME="i386_linuxXX"
 714                         ;;
 715                 arm*-linux*)
 716                         AFS_SYSNAME="arm_linuxXX"
 717                         ;;
 718                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 719                         AFS_SYSNAME="parisc_linuxXX"
 720                         enable_pam="no"
 721                         ;;
 722                 power*-ibm-aix4.2*)
 723                         AFS_SYSNAME="rs_aix42"
 724                         enable_pam="no"
 725                         ;;
 726                 power*-ibm-aix4.3*)
 727                         AFS_SYSNAME="rs_aix42"
 728                         enable_pam="no"
 729                         ;;
 730                 power*-ibm-aix5.1*)
 731                         AFS_SYSNAME="rs_aix51"
 732                         enable_pam="no"
 733                         ;;
 734                 power*-ibm-aix5.2*)
 735                         AFS_SYSNAME="rs_aix52"
 736                         enable_pam="no"
 737                         ;;
 738                 power*-ibm-aix5.3*)
 739                         AFS_SYSNAME="rs_aix53"
 740                         enable_pam="no"
 741                         ;;
 742                 power*-ibm-aix6.1*)
 743                         AFS_SYSNAME="rs_aix61"
 744                         enable_pam="no"
 745                         ;;
 746                 x86_64-*-linux-gnu)
 747                         AFS_SYSNAME="amd64_linuxXX"
 748                         enable_pam="yes"
 749                         ;;
 750                 *)
 751                         AC_MSG_ERROR(An AFS sysname is required)
 752                         exit 1
 753                         ;;
 754         esac
 755         case $AFS_SYSNAME in
 756                 *_linux* | *_umlinux*)
 757                         if test "x${AFS_SYSKVERS}" = "x"; then
 758                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 759                         fi
 760                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 761                         AFS_SYSNAME="$_AFS_SYSNAME"
 762                         AC_TRY_KBUILD(
 763                          [],
 764                          [#ifndef CONFIG_USERMODE
 765                           #error not UML
 766                           #endif],
 767                          ac_cv_linux_is_uml=yes,)
 768                         if test "${ac_cv_linux_is_uml}" = yes; then
 769                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 770                         fi
 771                         AFS_SYSNAME="$_AFS_SYSNAME"
 772                         ;;
 773         esac
 774         AC_MSG_RESULT($AFS_SYSNAME)
 775 fi
 776
 777 case $AFS_SYSNAME in
 778         *_darwin*)
 779                 AC_CHECK_HEADERS(crt_externs.h)
 780                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 781                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 782                 AC_SUBST(OSXSDK)
 783                 ;;
 784 esac
 785
 786 dnl Some hosts have a separate common param file they should include.  Figure
 787 dnl out if we're on one of them now that we know the sysname.
 788 case $AFS_SYSNAME in
 789     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 790     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 791     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 792     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 793     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 794     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 795     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 796     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 797     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
 798     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 799     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 800     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 801     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 802     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 803     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 804     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 805     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 806     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 807     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 808     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 809     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 810     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 811     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 812     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 813     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 814     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 815     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 816     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
 817     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
 818     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
 819     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
 820     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
 821     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
 822     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 823     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 824     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 825 # Linux alpha adds an extra underscore for no good reason.
 826     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 827     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 828     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 829     *_fbsd_*)   AFS_PARAM_COMMON=param.generic_fbsd.h ;;
 830 esac
 831
 832 OPENAFS_OSCONF
 833
 834 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 835
 836                 # Add (sub-) architecture-specific paths needed by conftests
 837                 case $AFS_SYSNAME  in
 838                         *_umlinux26)
 839                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 840                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 841                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 842                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 843                 esac
 844
 845                 if test "x$enable_kernel_module" = "xyes"; then
 846                  if test "x$enable_debug_kernel" = "xno"; then
 847                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 848                  fi
 849                  OPENAFS_GCC_SUPPORTS_MARCH
 850                  AC_SUBST(P5PLUS_KOPTS)
 851                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 852                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 853                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 854                  OPENAFS_GCC_SUPPORTS_PIPE
 855                  AC_SUBST(LINUX_GCC_KOPTS)
 856
 857                  dnl Setup the kernel build environment
 858                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 859                  LINUX_KERNEL_COMPILE_WORKS
 860
 861                  dnl Check for header files
 862                  AC_CHECK_LINUX_HEADER([config.h])
 863                  AC_CHECK_LINUX_HEADER([completion.h])
 864                  AC_CHECK_LINUX_HEADER([exportfs.h])
 865                  AC_CHECK_LINUX_HEADER([freezer.h])
 866                  AC_CHECK_LINUX_HEADER([key-type.h])
 867                  AC_CHECK_LINUX_HEADER([semaphore.h])
 868                  AC_CHECK_LINUX_HEADER([seq_file.h])
 869
 870                  dnl Type existence checks
 871                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 872                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
 873
 874                  dnl Check for structure elements
 875                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 876                                        [write_begin], [fs.h])
 877                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 878                                        [backing-dev.h])
 879                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
 880                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 881                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 882                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 883                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 884                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 885                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 886                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 887                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 888                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
 889                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
 890                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 891                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 892                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
 893                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
 894                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
 895                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 896                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 897                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 898                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 899                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 900                                        [fs.h])
 901                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 902                                        [fs.h])
 903                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 904                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 905                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 906                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 907                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 908                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 909                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 910                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 911                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 912                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 913                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 914
 915                  dnl Check for typed structure elements
 916                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 917                                              [buf], [fs.h])
 918
 919                  dnl Function existence checks
 920
 921                  AC_CHECK_LINUX_FUNC([bdi_init],
 922                                      [#include <linux/backing-dev.h>],
 923                                      [bdi_init(NULL);])
 924                  AC_CHECK_LINUX_FUNC([PageChecked],
 925                                      [#include <linux/mm.h>
 926 #include <linux/page-flags.h>],
 927                                      [struct page *_page;
 928                                       int bchecked = PageChecked(_page);])
 929                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 930                                      [#include <linux/mm.h>
 931 #include <linux/page-flags.h>],
 932                                      [struct page *_page;
 933                                       int bchecked = PageFsMisc(_page);])
 934                  AC_CHECK_LINUX_FUNC([clear_inode],
 935                                      [#include <linux/fs.h>],
 936                                      [clear_inode(NULL);])
 937                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 938                                      [#include <linux/time.h>],
 939                                      [struct timespec s;
 940                                       s = current_kernel_time();])
 941                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 942                                      [#include <linux/fs.h>],
 943                                      [d_alloc_anon(NULL);])
 944                  AC_CHECK_LINUX_FUNC([d_count],
 945                                      [#include <linux/dcache.h>],
 946                                      [d_count(NULL);])
 947                  AC_CHECK_LINUX_FUNC([d_make_root],
 948                                      [#include <linux/fs.h>],
 949                                      [d_make_root(NULL);])
 950                  AC_CHECK_LINUX_FUNC([do_sync_read],
 951                                      [#include <linux/fs.h>],
 952                                      [do_sync_read(NULL, NULL, 0, NULL);])
 953                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 954                                      [#include <linux/sched.h>],
 955                                      [pid_t p; find_task_by_pid(p);])
 956                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 957                                      [#include <linux/fs.h>],
 958                                      [generic_file_aio_read(NULL,NULL,0,0);])
 959                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 960                                      [#include <linux/pagemap.h>],
 961                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 962                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 963                                      [#include <linux/list.h>],
 964                                      [hlist_unhashed(0);])
 965                  AC_CHECK_LINUX_FUNC([i_size_read],
 966                                      [#include <linux/fs.h>],
 967                                      [i_size_read(NULL);])
 968                  AC_CHECK_LINUX_FUNC([inode_setattr],
 969                                      [#include <linux/fs.h>],
 970                                      [inode_setattr(NULL, NULL);])
 971                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
 972                                      [#include <linux/fs.h>],
 973                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
 974                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
 975                                      [#include <linux/net.h>],
 976                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
 977                  AC_CHECK_LINUX_FUNC([page_follow_link],
 978                                      [#include <linux/fs.h>],
 979                                      [page_follow_link(0,0);])
 980                  AC_CHECK_LINUX_FUNC([page_offset],
 981                                      [#include <linux/pagemap.h>],
 982                                      [page_offset(NULL);])
 983                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
 984                                      [#include <linux/pagevec.h>],
 985                                      [__pagevec_lru_add_file(NULL);])
 986                  AC_CHECK_LINUX_FUNC([path_lookup],
 987                                      [#include <linux/fs.h>
 988                                       #include <linux/namei.h>],
 989                                      [path_lookup(NULL, 0, NULL);])
 990                  AC_CHECK_LINUX_FUNC([proc_create],
 991                                      [#include <linux/proc_fs.h>],
 992                                      [proc_create(NULL, 0, NULL, NULL);])
 993                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
 994                                      [#include <linux/rcupdate.h>],
 995                                      [rcu_read_lock();])
 996                  AC_CHECK_LINUX_FUNC([set_nlink],
 997                                      [#include <linux/fs.h>],
 998                                      [set_nlink(NULL, 1);])
 999                  AC_CHECK_LINUX_FUNC([sock_create_kern],
1000                                      [#include <linux/net.h>],
1001                                      [sock_create_kern(0, 0, 0, NULL);])
1002                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
1003                                      [#include <linux/splice.h>],
1004                                      [splice_direct_to_actor(NULL,NULL,NULL);])
1005                  AC_CHECK_LINUX_FUNC([svc_addr_in],
1006                                      [#include <linux/sunrpc/svc.h>],
1007                                      [svc_addr_in(NULL);])
1008                  AC_CHECK_LINUX_FUNC([zero_user_segments],
1009                                      [#include <linux/highmem.h>],
1010                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1011                  AC_CHECK_LINUX_FUNC([noop_fsync],
1012                                      [#include <linux/fs.h>],
1013                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1014                  AC_CHECK_LINUX_FUNC([kthread_run],
1015                                      [#include <linux/kernel.h>
1016                                       #include <linux/kthread.h>],
1017                                      [kthread_run(NULL, NULL, "test");])
1018
1019                  dnl Consequences - things which get set as a result of the
1020                  dnl                above tests
1021                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1022                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1023                                   [define to disable the nfs translator])])
1024
1025                  dnl Assorted more complex tests
1026                  LINUX_AIO_NONVECTOR
1027                  LINUX_EXPORTS_PROC_ROOT_FS
1028                  LINUX_KMEM_CACHE_INIT
1029                  LINUX_HAVE_KMEM_CACHE_T
1030                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1031                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1032                  LINUX_D_PATH_TAKES_STRUCT_PATH
1033                  LINUX_NEW_EXPORT_OPS
1034                  LINUX_INODE_SETATTR_RETURN_TYPE
1035                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1036                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1037                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1038                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1039                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1040                  LINUX_DOP_D_DELETE_TAKES_CONST
1041                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1042                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1043                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1044                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1045                  LINUX_AOP_WRITEBACK_CONTROL
1046                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1047                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1048                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1049                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1050                  LINUX_KERNEL_SOCK_CREATE
1051                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1052                  LINUX_NEED_RHCONFIG
1053                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1054                  LINUX_EXPORTS_TASKLIST_LOCK
1055                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1056                  LINUX_STATFS_TAKES_DENTRY
1057                  LINUX_REFRIGERATOR
1058                  LINUX_HAVE_TRY_TO_FREEZE
1059                  LINUX_LINUX_KEYRING_SUPPORT
1060                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1061                  LINUX_KEY_ALLOC_NEEDS_CRED
1062                  LINUX_INIT_WORK_HAS_DATA
1063                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1064                  LINUX_HAVE_DCACHE_LOCK
1065                  LINUX_D_COUNT_IS_INT
1066                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1067                  LINUX_IOP_CREATE_TAKES_UMODE_T
1068                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1069                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1070                  LINUX_DENTRY_OPEN_TAKES_PATH
1071                  LINUX_D_ALIAS_IS_HLIST
1072                  LINUX_HLIST_ITERATOR_NO_NODE
1073                  LINUX_IOP_I_CREATE_TAKES_BOOL
1074                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1075                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1076
1077                  dnl If we are guaranteed that keyrings will work - that is
1078                  dnl  a) The kernel has keyrings enabled
1079                  dnl  b) The code is new enough to give us a key_type_keyring
1080                  dnl then we just disable syscall probing unless we've been
1081                  dnl told otherwise
1082
1083                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1084                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1085                           [enable_linux_syscall_probing="no"],
1086                           [enable_linux_syscall_probing="yes"])
1087                  ])
1088
1089                  dnl Syscall probing needs a few tests of its own, and just
1090                  dnl won't work if the kernel doesn't export init_mm
1091                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1092                    LINUX_EXPORTS_INIT_MM
1093                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1094                      AC_MSG_ERROR(
1095                        [Can't do syscall probing without exported init_mm])
1096                    ])
1097                    LINUX_EXPORTS_SYS_CHDIR
1098                    LINUX_EXPORTS_SYS_OPEN
1099                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1100                              [define to enable syscall table probes])
1101                  ])
1102
1103                  dnl Packaging and SMP build
1104                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1105                    LINUX_WHICH_MODULES
1106                  else
1107                    AC_SUBST(MPS,'SP')
1108                  fi
1109
1110                  dnl Syscall probing
1111                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1112                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1113                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1114                    ])
1115                    ac_cv_linux_exports_sys_call_table=no
1116                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1117                      ac_cv_linux_exports_ia32_sys_call_table=yes
1118                    fi
1119                  else
1120                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1121                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1122                    LINUX_EXPORTS_SYS_CALL_TABLE
1123                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1124                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1125                          linux_syscall_method=none
1126                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1127                             linux_syscall_method=scan
1128                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1129                                linux_syscall_method=scan_with_kallsyms_address
1130                             fi
1131                          fi
1132                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1133                             linux_syscall_method=kallsyms_symbol
1134                          fi
1135                          if test "x$linux_syscall_method" = "xnone"; then
1136                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1137                             linux_syscall_method=scan
1138                          fi
1139                    fi
1140                  fi
1141                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1142                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1143                  fi
1144                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1145                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1146                  fi
1147                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1148                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1149                  else
1150                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1151                  fi
1152                 :
1153                 fi
1154 dnl Linux-only, but just enable always.
1155                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1156 esac
1157
1158 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1159     [ac_cv_sync_fetch_and_add],
1160     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1161                     [ac_cv_sync_fetch_and_add=yes],
1162                     [ac_cv_sync_fetch_and_add=no])
1163 ])
1164 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1165       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1166                 [define if your C compiler has __sync_add_and_fetch])])
1167
1168 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1169     [ac_cv_sockaddr_len],
1170     [AC_TRY_COMPILE( [#include <sys/types.h>
1171 #include <sys/socket.h>],
1172                      [struct sockaddr *a; a->sa_len=0;],
1173                      [ac_cv_sockaddr_len=yes],
1174                      [ac_cv_sockaddr_len=no])
1175 ])
1176 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1177       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1178                  [define if you struct sockaddr sa_len])])
1179
1180 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1181         echo Skipping library tests because they confuse Irix.
1182 else
1183   AC_SEARCH_LIBS([socket], [socket inet])
1184   AC_SEARCH_LIBS([connect], [nsl])
1185   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1186
1187   dnl darwin wants it, aix hates it
1188   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1189   AC_TRY_COMPILE([
1190   #include <stdlib.h>
1191   #include <stdio.h>
1192   #include <sys/types.h>
1193   #include <sys/socket.h>
1194   #include <netinet/in.h>
1195   #include <arpa/inet.h>
1196   #include <arpa/nameser.h>
1197   #include <arpa/nameser_compat.h>
1198   #include <resolv.h>
1199   ], [static int i; i = 0;],
1200   [AC_MSG_RESULT(yes)
1201    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1202   [AC_MSG_RESULT(no)
1203    ])
1204
1205   openafs_save_libs="$LIBS"
1206   AC_MSG_CHECKING([for res_search])
1207   AC_FUNC_RES_SEARCH
1208
1209   if test "$ac_cv_func_res_search" = no; then
1210       for lib in dns nsl resolv; do
1211         if test "$ac_cv_func_res_search" != yes; then
1212           LIBS="-l$lib $LIBS"
1213           AC_FUNC_RES_SEARCH
1214           LIBS="$openafs_save_libs"
1215         fi
1216       done
1217       if test "$ac_cv_func_res_search" = yes; then
1218         LIB_AFSDB="-l$lib"
1219         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1220         AC_MSG_RESULT([yes, in lib$lib])
1221       else
1222         AC_MSG_RESULT(no)
1223       fi
1224   else
1225     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1226     AC_MSG_RESULT(yes)
1227   fi
1228
1229 fi
1230 XLIBS="$LIB_AFSDB $XLIBS"
1231
1232 AC_CHECK_RESOLV_RETRANS
1233
1234 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1235     [ac_cv_setsockopt_iprecverr],
1236     [AC_TRY_COMPILE( [
1237 #include <sys/types.h>
1238 #include <sys/socket.h>
1239 #include <netinet/in.h>],
1240 [int on=1;
1241 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1242         [ac_cv_setsockopt_iprecverr=yes],
1243         [ac_cv_setsockopt_iprecverr=no])])
1244
1245 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1246       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1247                  [define if we can receive socket errors via IP_RECVERR])])
1248
1249 PTHREAD_LIBS=error
1250 if test "x$MKAFS_OSTYPE" = OBSD; then
1251         PTHREAD_LIBS="-pthread"
1252 fi
1253 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1254         PTHREAD_LIBS="-pthread"
1255 fi
1256 if test "x$PTHREAD_LIBS" = xerror; then
1257         AC_CHECK_LIB(pthread, pthread_attr_init,
1258                 PTHREAD_LIBS="-lpthread")
1259 fi
1260 if test "x$PTHREAD_LIBS" = xerror; then
1261         AC_CHECK_LIB(pthreads, pthread_attr_init,
1262                 PTHREAD_LIBS="-lpthreads")
1263 fi
1264 if test "x$PTHREAD_LIBS" = xerror; then
1265         AC_CHECK_LIB(c_r, pthread_attr_init,
1266                 PTHREAD_LIBS="-lc_r")
1267 fi
1268 if test "x$PTHREAD_LIBS" = xerror; then
1269         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1270 fi
1271 if test "x$PTHREAD_LIBS" = xerror; then
1272         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1273         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1274                 PTHREAD_LIBS="-lpthread")
1275 fi
1276 if test "x$PTHREAD_LIBS" = xerror; then
1277         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1278 fi
1279 AC_SUBST(PTHREAD_LIBS)
1280
1281 HOST_CPU="$host_cpu"
1282
1283 if test "x$with_bsd_kernel_headers" != "x"; then
1284         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1285 else
1286         BSD_KERNEL_PATH="/usr/src/sys"
1287 fi
1288
1289 if test "x$with_bsd_kernel_build" != "x"; then
1290         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1291 else
1292         case $AFS_SYSNAME in
1293                 *_fbsd_*)
1294                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1295                         ;;
1296                 *_nbsd*)
1297                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1298         esac
1299 fi
1300
1301 # Fast restart
1302 if test "$enable_supergroups" = "yes"; then
1303         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1304 fi
1305
1306 if test "$enable_bitmap_later" = "yes"; then
1307         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1308 fi
1309
1310 if test "$enable_unix_sockets" = "yes"; then
1311         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1312         USE_UNIX_SOCKETS="yes"
1313 else
1314         USE_UNIX_SOCKETS="no"
1315 fi
1316 AC_SUBST(USE_UNIX_SOCKETS)
1317
1318 if test "$enable_namei_fileserver" = "yes"; then
1319         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1320         VFSCK=""
1321 else
1322         if test "$enable_namei_fileserver" = "default"; then
1323                 case $host in
1324                         *-solaris2.10*)
1325                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1326                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1327                                 VFSCK=""
1328                                 ;;
1329                         *-solaris2.11*)
1330                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1331                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1332                                 VFSCK=""
1333                                 ;;
1334                         *)
1335                                 VFSCK="vfsck"
1336                                 ;;
1337                 esac
1338         else
1339                 VFSCK="vfsck"
1340         fi
1341 fi
1342
1343 dnl check for tivoli
1344 AC_MSG_CHECKING(for tivoli tsm butc support)
1345 XBSA_CFLAGS=""
1346 if test "$enable_tivoli_tsm" = "yes"; then
1347         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1348         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1349         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1350         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1351
1352         if test -r "$XBSADIR3/dsmapifp.h"; then
1353                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1354                 XBSA_XLIBS="-ldl"
1355                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1356         elif test -r "$XBSADIR4/dsmapifp.h"; then
1357                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1358                 XBSA_XLIBS="-ldl"
1359                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1360         elif test -r "$XBSADIR1/xbsa.h"; then
1361                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1362                 XBSA_XLIBS=""
1363                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1364         elif test -r "$XBSADIR2/xbsa.h"; then
1365                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1366                 XBSA_XLIBS=""
1367                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1368         else
1369                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1370         fi
1371 else
1372         AC_MSG_RESULT([no])
1373 fi
1374 AC_SUBST(XBSA_CFLAGS)
1375 AC_SUBST(XBSA_XLIBS)
1376
1377 dnl checks for header files.
1378 AC_HEADER_STDC
1379 AC_HEADER_SYS_WAIT
1380 AC_HEADER_DIRENT
1381 AC_CHECK_HEADERS([ \
1382                    arpa/inet.h \
1383                    arpa/nameser.h \
1384                    curses.h\
1385                    direct.h \
1386                    errno.h \
1387                    fcntl.h \
1388                    grp.h \
1389                    math.h \
1390                    mntent.h \
1391                    ncurses.h \
1392                    ncurses/ncurses.h \
1393                    netdb.h \
1394                    netinet/in.h \
1395                    pthread_np.h \
1396                    pwd.h \
1397                    regex.h \
1398                    security/pam_appl.h \
1399                    signal.h \
1400                    stdint.h \
1401                    stdio_ext.h \
1402                    stdlib.h \
1403                    string.h \
1404                    strings.h \
1405                    sys/bitypes.h \
1406                    sys/bswap.h \
1407                    sys/dk.h \
1408                    sys/fcntl.h \
1409                    sys/file.h \
1410                    sys/fs_types.h \
1411                    sys/fstyp.h \
1412                    sys/ioctl.h \
1413                    sys/ipc.h \
1414                    sys/lockf.h \
1415                    sys/map.h \
1416                    sys/mount.h \
1417                    sys/mntent.h \
1418                    sys/mnttab.h \
1419                    sys/pag.h \
1420                    sys/param.h \
1421                    sys/resource.h \
1422                    sys/select.h \
1423                    sys/statfs.h \
1424                    sys/statvfs.h \
1425                    sys/socket.h \
1426                    sys/sysctl.h \
1427                    sys/time.h \
1428                    sys/types.h \
1429                    sys/uio.h \
1430                    sys/un.h \
1431                    sys/vfs.h \
1432                    syslog.h \
1433                    termios.h \
1434                    time.h \
1435                    ucontext.h \
1436                    unistd.h \
1437                    windows.h \
1438                 ])
1439
1440 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1441 #ifdef HAVE_NETINET_IN_H
1442 # include <netinet/in.h>
1443 #endif])
1444
1445 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1446 #ifdef HAVE_SYS_SOCKET_H
1447 # include <sys/socket.h>
1448 #endif])
1449
1450 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1451 #ifdef HAVE_SYS_SOCKET_H
1452 # include <sys/socket.h>
1453 #endif
1454 #ifdef HAVE_NETINET_IN_H
1455 # include <netinet/in.h>
1456 #endif
1457 #ifdef HAVE_NET_IF_H
1458 # include <net/if.h>
1459 #endif])
1460
1461 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1462 #ifdef HAVE_SECURITY_PAM_APPL_H
1463 # include <security/pam_appl.h>
1464 #endif])
1465
1466 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1467
1468 AC_CHECK_TYPES([fsblkcnt_t],,,[
1469 #include <sys/types.h>
1470 #ifdef HAVE_SYS_BITYPES_H
1471 #include <sys/bitypes.h>
1472 #endif
1473 #ifdef HAVE_SYS_STATFS_H
1474 #include <sys/statfs.h>
1475 #endif
1476 #ifdef HAVE_SYS_STATVFS_H
1477 #include <sys/statvfs.h>
1478 #endif
1479 ])
1480
1481 dnl see what struct stat has for timestamps
1482 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1483
1484 dnl check for curses-lib
1485 AS_IF([test "x$enable_gtx" != "xno"],
1486       [save_LIBS=$LIBS
1487       AC_CHECK_LIB( [ncurses], [setupterm],
1488       [LIB_curses=-lncurses],
1489         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1490           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1491       ])
1492       LIBS=$save_LIBS
1493       AC_SUBST(LIB_curses)])
1494
1495 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1496
1497 if test "$enable_debug_locks" = yes; then
1498         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1499 fi
1500
1501 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1502         HAVE_PAM="YES"
1503 else
1504         HAVE_PAM="no"
1505 fi
1506 AC_SUBST(HAVE_PAM)
1507
1508 if test "$enable_login" = yes; then
1509         BUILD_LOGIN="yes"
1510 else
1511         BUILD_LOGIN="no"
1512 fi
1513 AC_SUBST(BUILD_LOGIN)
1514
1515 if test "$enable_uss" = yes; then
1516         BUILD_USS="yes"
1517 else
1518         BUILD_USS="no"
1519 fi
1520 AC_SUBST(BUILD_USS)
1521
1522 if test "$enable_kauth" = yes; then
1523         INSTALL_KAUTH="yes"
1524 else
1525         INSTALL_KAUTH="no"
1526 fi
1527 AC_SUBST(INSTALL_KAUTH)
1528
1529 AC_CHECK_FUNCS([ \
1530         arc4random \
1531         fcntl \
1532         fseeko64 \
1533         ftello64 \
1534         getcwd \
1535         getegid \
1536         geteuid \
1537         getgid \
1538         getuid \
1539         getrlimit \
1540         issetugid \
1541         mkstemp \
1542         poll \
1543         pread \
1544         preadv \
1545         preadv64 \
1546         pwrite \
1547         pwritev \
1548         pwritev64 \
1549         regcomp \
1550         regerror \
1551         regexec \
1552         setitimer \
1553         setvbuf \
1554         sigaction \
1555         strcasestr \
1556         strerror \
1557         sysconf \
1558         sysctl \
1559         tdestroy \
1560         timegm \
1561 ])
1562
1563 OPENAFS_ROKEN()
1564 OPENAFS_HCRYPTO()
1565 OPENAFS_C_ATTRIBUTE()
1566
1567 dnl Functions that Heimdal's libroken provides, but that we
1568 dnl haven't found a need for yet, and so haven't imported
1569 AC_CHECK_FUNCS([ \
1570         chown \
1571         fchown \
1572         gethostname \
1573         lstat \
1574         inet_aton \
1575         inet_ntop \
1576         inet_pton \
1577         putenv \
1578         readv \
1579         setenv \
1580         strdup \
1581         strftime \
1582         strndup \
1583         strsep \
1584         unsetenv \
1585 ])
1586
1587 dnl Functions that are in objects that we always build from libroken
1588 AC_CHECK_FUNCS([ \
1589         asprintf \
1590         asnprintf \
1591         vasprintf \
1592         vasnprintf \
1593         vsnprintf \
1594         snprintf \
1595 ])
1596
1597 dnl Functions that we're going to try and get from libroken
1598 AC_REPLACE_FUNCS([ \
1599         daemon \
1600         ecalloc \
1601         emalloc \
1602         erealloc \
1603         err \
1604         errx \
1605         flock \
1606         freeaddrinfo \
1607         gai_strerror \
1608         getaddrinfo \
1609         getdtablesize \
1610         getnameinfo \
1611         getopt \
1612         getprogname \
1613         gettimeofday \
1614         localtime_r \
1615         mkstemp \
1616         setenv \
1617         setprogname \
1618         strcasecmp \
1619         strlcat \
1620         strnlen \
1621         strlcpy \
1622         strsep \
1623         tdelete \
1624         tfind \
1625         tsearch \
1626         twalk \
1627         unsetenv \
1628         verr \
1629         verrx \
1630         vsyslog \
1631         vwarn \
1632         vwarnx \
1633         warn \
1634         warnx \
1635 ])
1636
1637 dnl Headers that we're going to try and get from libroken
1638 AC_CHECK_HEADERS([ \
1639         err.h \
1640         search.h \
1641 ])
1642
1643 AC_CHECK_DECLS([h_errno], [], [], [
1644 #include <sys/types.h>
1645 #ifdef HAVE_NETDB_H
1646 #include <netdb.h>
1647 #endif
1648 ])
1649
1650 AC_HEADER_TIME
1651
1652 ROKEN_HEADERS=
1653 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1654       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1655       [])
1656 AC_SUBST(ROKEN_HEADERS)
1657
1658 dnl Stuff that's harder ...
1659 AC_MSG_CHECKING([for bswap16])
1660 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1661 #ifdef HAVE_SYS_TYPES_H
1662 #include <sys/types.h>
1663 #endif
1664 #ifdef HAVE_SYS_BSWAP_H
1665 #include <sys/bswap.h>
1666 #endif
1667 ],
1668 [short a, b; b = bswap16(a); ])],
1669 [AC_MSG_RESULT(yes)
1670  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1671 ],
1672 [AC_MSG_RESULT(no)])
1673
1674 AC_MSG_CHECKING([for bswap32])
1675 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1676 #include <sys/types.h>
1677 #endif
1678 #ifdef HAVE_SYS_BSWAP_H
1679 #include <sys/bswap.h>
1680 #endif
1681 ],
1682 [int a, b; b = bswap32(a); ])],
1683 [AC_MSG_RESULT(yes)
1684  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1685 ],
1686 [AC_MSG_RESULT(no)])
1687
1688 case $AFS_SYSNAME in
1689 *hp_ux* | *hpux*)
1690    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1691    ;;
1692 *)
1693    AC_MSG_CHECKING([for positional I/O])
1694    if test "$ac_cv_func_pread" = "yes" && \
1695            test "$ac_cv_func_pwrite" = "yes"; then
1696       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1697       AC_MSG_RESULT(yes)
1698    else
1699      AC_MSG_RESULT(no)
1700    fi
1701    AC_MSG_CHECKING([for vectored positional I/O])
1702    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1703                "$ac_cv_func_pwritev" = "yes" -a \
1704                "$ac_cv_func_preadv64" = "yes" -a \
1705                "$ac_cv_func_pwritev64" = "yes"],
1706          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1707           AC_MSG_RESULT(yes)],
1708          [AC_MSG_RESULT(no)])
1709    ;;
1710 esac
1711
1712 AC_MSG_CHECKING([for POSIX regex library])
1713 if test "$ac_cv_header_regex_h" = "yes" && \
1714         test "$ac_cv_func_regcomp" = "yes" && \
1715         test "$ac_cv_func_regexec" = "yes" && \
1716         test "$ac_cv_func_regerror" = "yes"; then
1717     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1718     AC_MSG_RESULT(yes)
1719 else
1720     AC_MSG_RESULT(no)
1721 fi
1722
1723 dnl Look for "non-portable" pthreads functions.
1724 save_LIBS="$LIBS"
1725 LIBS="$LIBS $PTHREAD_LIBS"
1726 AC_CHECK_FUNCS([ \
1727         pthread_set_name_np \
1728         pthread_setname_np \
1729 ])
1730
1731 dnl Sadly, there are three different versions of pthread_setname_np.
1732 dnl Try to cater for all of them.
1733 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1734     AC_MSG_CHECKING([for signature of pthread_setname_np])
1735     AC_TRY_COMPILE([
1736 #include <pthread.h>
1737 #ifdef HAVE_PTHREAD_NP_H
1738 #include <pthread_np.h>
1739 #endif
1740 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1741         AC_MSG_RESULT([three arguments])
1742         pthread_setname_np_args=3], [
1743         AC_TRY_COMPILE([
1744 #include <pthread.h>
1745 #ifdef HAVE_PTHREAD_NP_H
1746 #include <pthread_np.h>
1747 #endif
1748 ], [pthread_setname_np(pthread_self(), "test")], [
1749             AC_MSG_RESULT([two arguments])
1750             pthread_setname_np_args=2], [
1751             AC_TRY_COMPILE([
1752 #include <pthread.h>
1753 #ifdef HAVE_PTHREAD_NP_H
1754 #include <pthread_np.h>
1755 #endif
1756 ], [pthread_setname_np("test")], [
1757                 AC_MSG_RESULT([one argument])
1758                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1759 ])
1760 ])
1761 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1762 fi
1763 LIBS="$save_LIBS"
1764
1765 openafs_cv_saved_CFLAGS="$CFLAGS"
1766 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1767
1768 AC_TYPE_SIGNAL
1769 OPENAFS_RETSIGTYPE
1770 AC_CHECK_SIZEOF(void *)
1771 AC_CHECK_SIZEOF(unsigned long long)
1772 AC_CHECK_SIZEOF(unsigned long)
1773 AC_CHECK_SIZEOF(unsigned int)
1774 AC_TYPE_INTPTR_T
1775 AC_TYPE_UINTPTR_T
1776 AC_TYPE_SSIZE_T
1777 AC_CHECK_TYPE([sig_atomic_t],[],
1778     [AC_DEFINE([sig_atomic_t], [int],
1779         [Define to int if <signal.h> does not define.])],
1780 [#include <sys/types.h>
1781 #include <signal.h>])
1782 AC_CHECK_TYPE([socklen_t],[],
1783     [AC_DEFINE([socklen_t], [int],
1784         [Define to int if <sys/socket.h> does not define.])],
1785 [#include <sys/types.h>
1786 #include <sys/socket.h>])
1787 AC_CHECK_TYPES(off64_t)
1788 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1789 AC_CHECK_TYPES([struct winsize], [], [], [
1790 #ifdef HAVE_TERMIOS_H
1791 # include <termios.h>
1792 #else
1793 # include <sys/termios.h>
1794 #endif
1795 #include <sys/ioctl.h>])
1796 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1797                 struct sockaddr_storage],
1798                [], [], [
1799 #include <sys/types.h>
1800 #include <sys/socket.h>
1801 ])
1802 AC_CHECK_TYPES([sa_family_t], [], [], [
1803 #include <sys/types.h>
1804 #include <sys/socket.h>
1805 ])
1806 AC_CHECK_TYPES([struct addrinfo], [], [], [
1807 #include <sys/types.h>
1808 #ifdef HAVE_NETDB_H
1809 #include <netdb.h>
1810 #endif
1811 ])
1812 AC_CHECK_TYPES([long long], [], [], [])
1813
1814 AC_SIZEOF_TYPE(long)
1815
1816 CFLAGS="$openafs_cv_saved_CFLAGS"
1817
1818 RRA_HEADER_PAM_CONST
1819
1820
1821 dnl Directory PATH handling
1822 if test "x$enable_transarc_paths" = "xyes"  ; then
1823     afsconfdir=${afsconfdir=/usr/afs/etc}
1824     viceetcdir=${viceetcdir=/usr/vice/etc}
1825     afskerneldir=${afskerneldir=${viceetcdir}}
1826     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1827     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1828     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1829     afsdbdir=${afsdbdir=/usr/afs/db}
1830     afslogsdir=${afslogsdir=/usr/afs/logs}
1831     afslocaldir=${afslocaldir=/usr/afs/local}
1832     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1833     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1834     afsdatadir=${afsdatadir=/usr/vice/etc}
1835 else
1836     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1837     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1838     afskerneldir=${afskerneldir='${libdir}/openafs'}
1839     afssrvbindir=${afssrvbindir='${bindir}'}
1840     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1841     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1842     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1843     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1844     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1845     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1846     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1847     afsdatadir=${afsdatadir='${datadir}/openafs'}
1848 fi
1849 AC_SUBST(afsconfdir)
1850 AC_SUBST(viceetcdir)
1851 AC_SUBST(afskerneldir)
1852 AC_SUBST(afssrvbindir)
1853 AC_SUBST(afssrvsbindir)
1854 AC_SUBST(afssrvlibexecdir)
1855 AC_SUBST(afsdbdir)
1856 AC_SUBST(afslogsdir)
1857 AC_SUBST(afslocaldir)
1858 AC_SUBST(afsbackupdir)
1859 AC_SUBST(afsbosconfigdir)
1860 AC_SUBST(afsdatadir)
1861
1862 if test "x$enable_kernel_module" = "xyes"; then
1863 ENABLE_KERNEL_MODULE=libafs
1864 fi
1865
1866 if test "x$enable_pthreaded_ubik" = "xyes"; then
1867 ENABLE_PTHREADED_UBIK=yes
1868 fi
1869
1870 AC_SUBST(VFSCK)
1871 AC_SUBST(AFS_SYSNAME)
1872 AC_SUBST(AFS_PARAM_COMMON)
1873 AC_SUBST(ENABLE_KERNEL_MODULE)
1874 AC_SUBST(ENABLE_PTHREADED_UBIK)
1875 AC_SUBST(LIB_AFSDB)
1876 AC_SUBST(LINUX_KERNEL_PATH)
1877 AC_SUBST(LINUX_KERNEL_BUILD)
1878 AC_SUBST(HOST_CPU)
1879 AC_SUBST(BSD_KERNEL_PATH)
1880 AC_SUBST(BSD_KERNEL_BUILD)
1881 AC_SUBST(LINUX_VERSION)
1882 AC_SUBST(MKAFS_OSTYPE)
1883 AC_SUBST(TOP_OBJDIR)
1884 AC_SUBST(TOP_SRCDIR)
1885 AC_SUBST(TOP_INCDIR)
1886 AC_SUBST(TOP_LIBDIR)
1887 AC_SUBST(DEST)
1888 AC_SUBST(DARWIN_INFOFILE)
1889 AC_SUBST(IRIX_BUILD_IP35)
1890 AC_SUBST(HTML_XSL)
1891 AC_SUBST(XSLTPROC)
1892 AC_SUBST(DOCBOOK2PDF)
1893 AC_SUBST(DOCBOOK_STYLESHEETS)
1894
1895 OPENAFS_FUSE
1896 OPENAFS_SWIG
1897
1898 TOP_SRCDIR="${srcdir}/src"
1899 dnl
1900 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1901 dnl
1902 case $TOP_SRCDIR in
1903         /*)
1904                 ;;
1905         *)
1906                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1907                 ;;
1908 esac
1909
1910 TOP_OBJDIR="${SRCDIR_PARENT}"
1911 TOP_INCDIR="${SRCDIR_PARENT}/include"
1912 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1913 if test "${DEST}x" = "x"; then
1914         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1915 fi
1916
1917 if test "x$with_crosstools_dir" != "x"; then
1918         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1919                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1920                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1921                 RXGEN_PATH=$with_crosstools_dir/rxgen
1922         else
1923                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1924                 exit 1
1925         fi
1926 else
1927         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1928         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1929         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1930 fi
1931 AC_SUBST(COMPILE_ET_PATH)
1932 AC_SUBST(CONFIGTOOL_PATH)
1933 AC_SUBST(RXGEN_PATH)
1934
1935 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1936 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1937 AC_SUBST(HELPER_SPLINT)
1938 AC_SUBST(HELPER_SPLINTCFG)
1939
1940 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1941
1942 dnl Check to see if crypt lives in a different library
1943 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1944 AC_SUBST(LIB_crypt)
1945
1946 dnl Check to see if the compiler support labels in structs
1947 AC_MSG_CHECKING(for label support in structs)
1948 AC_TRY_COMPILE([], [
1949 extern void osi_UFSOpen(void);
1950 struct labeltest {
1951    void (*open) (void);
1952 };
1953 struct labeltest struct_labeltest = {
1954    .open       = osi_UFSOpen,
1955 }
1956 ],
1957 [AC_MSG_RESULT(yes)
1958  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1959 ],
1960 [AC_MSG_RESULT(no)
1961 ])
1962
1963 AC_MSG_CHECKING([checking for dirfd])
1964 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1965 #ifdef HAVE_DIRENT_H
1966 #include <dirent.h>
1967 #endif
1968 ]],
1969         [[DIR *d = 0; dirfd(d);]])],
1970         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1971 if test "$ac_rk_have_dirfd" = "yes" ; then
1972         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1973 fi
1974 AC_MSG_RESULT($ac_rk_have_dirfd)
1975
1976 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1977 #ifdef HAVE_DIRENT_H
1978 #include <dirent.h>
1979 #endif])
1980
1981 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
1982 [#ifdef HAVE_SYS_RESOURCE_H
1983 #include <sys/resource.h>
1984 #endif])
1985
1986 dnl Check for UUID library
1987 AC_CHECK_HEADERS([uuid/uuid.h])
1988 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1989 AC_CHECK_FUNCS([uuid_generate])
1990 ])
1991
1992