74fc77619ff1cb0123617f10e4a736367643d0ac
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #    define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 # define _FILE_OFFSET_BITS 64
48 # define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 # include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])
76 ])
77
78 dnl General feature options.
79 AC_ARG_ENABLE([gtx],
80     [AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools])])
81
82 AC_ARG_ENABLE([namei-fileserver],
83     [AS_HELP_STRING([--enable-namei-fileserver],
84         [force compilation of namei fileserver in preference to inode
85          fileserver])],
86     [],
87     [enable_namei_fileserver="default"])
88 AC_ARG_ENABLE([supergroups],
89     [AS_HELP_STRING([--enable-supergroups],
90         [enable support for nested pts groups])],
91     [],
92     [enable_supergroups="no"])
93 AC_ARG_ENABLE([bitmap-later],
94     [AS_HELP_STRING([--enable-bitmap-later],
95         [enable fast startup of file server by not reading bitmap till
96          needed])],
97     [AS_IF([test x"$withval" = xyes],
98         [AC_MSG_WARN([bitmap-later is only used by non-demand-attach
99             fileservers.  Please migrate to demand-attach instead.])])],
100     [enable_bitmap_later="no"])
101 AC_ARG_ENABLE([unix-sockets],
102     [AS_HELP_STRING([--disable-unix-sockets],
103         [disable use of unix domain sockets for fssync (defaults to enabled)])],
104     [],
105     [enable_unix_sockets="yes"])
106 AC_ARG_ENABLE([tivoli-tsm],
107     [AS_HELP_STRING([--enable-tivoli-tsm],
108         [enable use of the Tivoli TSM API libraries for butc support])],
109     [],
110     [enable_tivoli_tsm="no"])
111 AC_ARG_ENABLE([pthreaded-ubik],
112     [AS_HELP_STRING([--disable-pthreaded-ubik],
113         [disable installation of pthreaded ubik applications (defaults to
114          enabled)])],
115     [],
116     [enable_pthreaded_ubik="yes"])
117
118 dnl Kernel module build options.
119 AC_ARG_WITH([linux-kernel-headers],
120     [AS_HELP_STRING([--with-linux-kernel-headers=path],
121         [use the kernel headers found at path (optional, defaults to
122          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
123          then /usr/src/linux-2.4, and lastly /usr/src/linux)])
124 ])
125 AC_ARG_WITH([linux-kernel-build],
126     [AS_HELP_STRING([--with-linux-kernel-build=path],
127         [use the kernel build found at path(optional, defaults to
128         kernel headers path)]
129 )])
130 AC_ARG_WITH([bsd-kernel-headers],
131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
132         [use the kernel headers found at path (optional, defaults to
133          /usr/src/sys)])
134 ])
135 AC_ARG_WITH([bsd-kernel-build],
136     [AS_HELP_STRING([--with-bsd-kernel-build=path],
137         [use the kernel build found at path (optional, defaults to
138          KSRC/i386/compile/GENERIC)])
139 ])
140 AC_ARG_WITH([linux-kernel-packaging],
141     [AS_HELP_STRING([--with-linux-kernel-packaging],
142         [use standard naming conventions to aid Linux kernel build packaging
143          (disables MPS, sets the kernel module name to openafs.ko, and
144          installs kernel modules into the standard Linux location)])],
145     [AC_SUBST([LINUX_KERNEL_PACKAGING], [yes])
146      AC_SUBST([LINUX_LIBAFS_NAME], [openafs])],
147     [AC_SUBST([LINUX_LIBAFS_NAME], [libafs])
148 ])
149 AC_ARG_ENABLE([kernel-module],
150     [AS_HELP_STRING([--disable-kernel-module],
151         [disable compilation of the kernel module (defaults to enabled)])],
152     [],
153     [enable_kernel_module="yes"])
154 AC_ARG_ENABLE([redhat-buildsys],
155     [AS_HELP_STRING([--enable-redhat-buildsys],
156         [enable compilation of the redhat build system kernel (defaults to
157          disabled)])],
158     [],
159     [enable_redhat_buildsys="no"])
160
161 dnl Installation locations.
162 AC_ARG_ENABLE([transarc-paths],
163     [AS_HELP_STRING([--enable-transarc-paths],
164         [use Transarc style paths like /usr/afs and /usr/vice])],
165     [],
166     [enable_transarc_paths="no"])
167
168 dnl Deprecated crypto
169 AC_ARG_ENABLE([kauth],
170     [AS_HELP_STRING([--enable-kauth],
171         [install the deprecated kauth server, pam modules, and utilities
172          (defaults to disabled)])],
173     [enable_pam="yes"],
174     [enable_kauth="no"
175      enable_pam="no"])
176
177 dnl Optimization and debugging flags.
178 AC_ARG_ENABLE([strip-binaries],
179     [AS_HELP_STRING([--disable-strip-binaries],
180         [disable stripping of symbol information from binaries (defaults to
181          enabled)])],
182     [],
183     [enable_strip_binaries="maybe"])
184 AC_ARG_ENABLE([debug],
185     [AS_HELP_STRING([--enable-debug],
186         [enable compilation of the user space code with debugging information
187          (defaults to disabled)])],
188     [],
189     [enable_debug="no"])
190 AC_ARG_ENABLE([optimize],
191     [AS_HELP_STRING([--disable-optimize],
192         [disable optimization for compilation of the user space code (defaults
193          to enabled)])],
194     [],
195     [enable_optimize="yes"])
196 AC_ARG_ENABLE([warnings],
197     [AS_HELP_STRING([--enable-warnings],
198         [enable compilation warnings when building with gcc (defaults to
199          disabled)])],
200     [],
201     [enable_warnings="no"])
202 AC_ARG_ENABLE([checking],
203     [AS_HELP_STRING([--enable-checking],
204         [turn compilation warnings into errors when building with gcc (defaults
205          to disabled)])],
206     [enable_checking="$enableval"],
207     [enable_checking="no"])
208 AC_ARG_ENABLE([debug-locks],
209     [AS_HELP_STRING([--enable-debug-locks],
210         [turn on lock debugging assertions (defaults to disabled)])],
211     [enable_debug_locks="$enableval"],
212     [enable_debug_locks="no"])
213 AC_ARG_ENABLE([debug-kernel],
214     [AS_HELP_STRING([--enable-debug-kernel],
215         [enable compilation of the kernel module with debugging information
216          (defaults to disabled)])],
217     [],
218     [enable_debug_kernel="no"])
219 AC_ARG_ENABLE([optimize-kernel],
220     [AS_HELP_STRING([--disable-optimize-kernel],
221         [disable compilation of the kernel module with optimization (defaults
222          based on platform)])],
223     [],
224     [enable_optimize_kernel=""])
225 AC_ARG_ENABLE([debug-lwp],
226     [AS_HELP_STRING([--enable-debug-lwp],
227         [enable compilation of the LWP code with debugging information
228          (defaults to disabled)])],
229     [],
230     [enable_debug_lwp="no"])
231 AC_ARG_ENABLE([optimize-lwp],
232     [AS_HELP_STRING([--disable-optimize-lwp],
233         [disable optimization for compilation of the LWP code (defaults to
234          enabled)])],
235     [],
236     [enable_optimize_lwp="yes"])
237 AC_ARG_ENABLE([debug-pam],
238     [AS_HELP_STRING([--enable-debug-pam],
239         [enable compilation of the PAM code with debugging information
240          (defaults to disabled)])],
241     [],
242     [enable_debug_pam="no"])
243 AC_ARG_ENABLE([optimize-pam],
244     [AS_HELP_STRING([--disable-optimize-pam],
245         [disable optimization for compilation of the PAM code (defaults to
246          enabled)])],
247     [],
248     [enable_optimize_pam="yes"])
249 AC_ARG_ENABLE([linux-syscall-probing],
250     [AS_HELP_STRING([--enable-linux-syscall-probing],
251         [enable Linux syscall probing (defaults to autodetect)])],
252     [],
253     [enable_linux_syscall_probing="maybe"])
254 AC_ARG_ENABLE([linux-d_splice_alias-extra-iput],
255     [AS_HELP_STRING([--enable-linux-d_splice_alias-extra-iput],
256         [Linux has introduced an incompatible behavior change in the
257          d_splice_alias function with no reliable way to determine which
258          behavior will be produced.  If Linux commit
259          51486b900ee92856b977eacfc5bfbe6565028070 (or equivalent) has been
260          applied to your kernel, disable this option.  If that commit is
261          not present in your kernel, enable this option.  We apologize
262          that you are required to know this about your running kernel.])],
263     [],
264     [case $system in
265     *-linux*)
266         AS_IF([test "x$LOGNAME" != "xbuildslave" &&
267             test "x$LOGNAME" != "xbuildbot"],
268             [AC_ERROR([Linux users must specify either
269                 --enable-linux-d_splice_alias-extra-iput or
270                 --disable-linux-d_splice_alias-extra-iput])],
271             [enable_linux_d_splice_alias_extra_iput="no"])
272      esac
273     ])
274 AC_ARG_WITH([crosstools-dir],
275     [AS_HELP_STRING([--with-crosstools-dir=path],
276         [use path for native versions of rxgen, compile_et and config])
277 ])
278
279 AC_ARG_WITH([xslt-processor],
280         AS_HELP_STRING([--with-xslt-processor=ARG],
281         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
282         [XSLTPROC="$withval"],
283         [AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo])])
284
285 AC_ARG_WITH([html-xsl],
286         AS_HELP_STRING([--with-html-xsl],
287         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
288         [HTML_XSL="$withval"],
289         [HTML_XSL="html/chunk.xsl"])
290
291 AC_ARG_WITH([docbook2pdf],
292         AS_HELP_STRING([--with-docbook2pdf=ARG],
293         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
294         [DOCBOOK2PDF="$withval"],
295         [AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo])])
296
297 AC_ARG_WITH([docbook-stylesheets],
298         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
299         [location of DocBook stylesheets (default is to search a set of likely paths)]),
300         [DOCBOOK_STYLESHEETS="$withval"],
301         [OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS],
302                 [/usr/share/xml/docbook/stylesheet/nwalsh/current \
303                  /usr/share/xml/docbook/stylesheet/nwalsh \
304                  /usr/share/xml/docbook/xsl-stylesheets \
305                  /usr/share/sgml/docbook/docbook-xsl-stylesheets \
306                  /usr/share/sgml/docbook/xsl-stylesheets \
307                  /usr/share/docbook-xsl \
308                  /usr/share/sgml/docbkxsl \
309                  /usr/local/share/xsl/docbook \
310                  /sw/share/xml/xsl/docbook-xsl \
311                  /opt/local/share/xsl/docbook-xsl],
312                 [$HTML_XSL])
313            AS_IF([test "x$DOCBOOK_STYLESHEETS" = "x"],
314                 [AC_WARN([Docbook stylesheets not found; some documentation can't be built])
315            ])
316         ])
317
318 AC_ARG_WITH([dot],
319         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
320         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
321         [], [with_dot="maybe"])
322
323 enable_login="no"
324
325 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
326 dnl documentation build.
327 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
328 AC_CHECK_PROGS([DOXYGEN], [doxygen])
329
330 dnl Optionally generate graphs with doxygen.
331 case "$with_dot" in
332 maybe)
333     AC_CHECK_PROGS([DOT], [dot])
334     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
335     ;;
336 yes)
337     HAVE_DOT="yes"
338     ;;
339 no)
340     HAVE_DOT="no"
341     ;;
342 *)
343     HAVE_DOT="yes"
344     DOT_PATH=$with_dot
345 esac
346 AC_SUBST(HAVE_DOT)
347 AC_SUBST(DOT_PATH)
348
349 dnl Checks for UNIX variants.
350 AC_ISC_POSIX
351
352 dnl Various compiler setup.
353 AC_TYPE_PID_T
354 AC_TYPE_SIZE_T
355
356 dnl Checks for programs.
357 AC_PROG_INSTALL
358 AC_PROG_LN_S
359 AC_PROG_RANLIB
360 AC_PROG_YACC
361 AM_PROG_LEX
362 dnl if we are flex, be lex-compatible
363 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
364
365 OPENAFS_FORCE_ABS_INSTALL
366 OPENAFS_CHECK_BIGENDIAN
367 OPENAFS_PRINTF_TAKES_Z_LEN
368
369 AC_MSG_CHECKING(your OS)
370 system=$host
371 case $system in
372         *-linux*)
373
374                 MKAFS_OSTYPE=LINUX
375                 if test "x$enable_redhat_buildsys" = "xyes"; then
376                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
377                 fi
378                 if test "x$enable_kernel_module" = "xyes"; then
379                  if test "x$with_linux_kernel_headers" != "x"; then
380                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
381                  else
382                    for utsdir in "/lib/modules/`uname -r`/build" \
383                                  "/lib/modules/`uname -r`/source" \
384                                  "/usr/src/linux-2.4" \
385                                  "/usr/src/linux"; do
386                      LINUX_KERNEL_PATH="$utsdir"
387                      for utsfile in "include/generated/utsrelease.h" \
388                                     "include/linux/utsrelease.h" \
389                                     "include/linux/version.h" \
390                                     "include/linux/version-up.h"; do
391                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
392                          break 2
393                        fi
394                      done
395                    done
396                  fi
397                  if test "x$with_linux_kernel_build" != "x"; then
398                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
399                  else
400                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
401                  fi
402                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
403                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
404                    LINUX_VERSION="$linux_kvers"
405                  else
406                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
407                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
408                      LINUX_VERSION="$linux_kvers"
409                    else
410                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
411                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
412                        if test "x$linux_kvers" = "x"; then
413                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
414                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
415                            if test "x$linux_kvers" = "x"; then
416                              AC_MSG_ERROR(Linux headers lack version definition [2])
417                              exit 1
418                            else
419                              LINUX_VERSION="$linux_kvers"
420                            fi
421                          else
422                            AC_MSG_ERROR(Linux headers lack version definition)
423                            exit 1
424                          fi
425                        else
426                          LINUX_VERSION="$linux_kvers"
427                        fi
428                      else
429                        enable_kernel_module="no"
430                      fi
431                    fi
432                  fi
433                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
434                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
435                      enable_kernel_module="no"
436                  fi
437                  if test "x$enable_kernel_module" = "xno"; then
438                   if test "x$with_linux_kernel_headers" != "x"; then
439                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
440                    exit 1
441                   else
442                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
443                   fi
444                  fi
445                  dnl do we need to determine SUBARCH from autoconf.h
446                  SUBARCH=default
447                 fi
448                 AC_MSG_RESULT(linux)
449                 GUESS_LINUX_VERSION=
450                 if test "x$enable_kernel_module" = "xyes"; then
451                  GUESS_LINUX_VERSION=${LINUX_VERSION}
452                 else
453                  GUESS_LINUX_VERSION=`uname -r`
454                 fi
455                 case "$GUESS_LINUX_VERSION" in
456                   2.2.*) AFS_SYSKVERS=22 ;;
457                   2.4.*) AFS_SYSKVERS=24 ;;
458                   [2.6.* | [3-9]* | [1-2][0-9]*]) AFS_SYSKVERS=26 ;;
459                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
460                 esac
461                 ;;
462         *-solaris*)
463                 MKAFS_OSTYPE=SOLARIS
464                 AC_MSG_RESULT(sun4)
465                 AC_PATH_PROG(SOLARISCC, [cc], ,
466                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
467                 if test "x$SOLARISCC" = "x" ; then
468                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
469                 fi
470                 SOLARIS_UFSVFS_HAS_DQRWLOCK
471                 SOLARIS_FS_HAS_FS_ROLLED
472                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
473                 SOLARIS_HAVE_VN_RENAMEPATH
474                 ;;
475         *-sunos*)
476                 MKAFS_OSTYPE=SUNOS
477                 enable_kernel_module=no
478                 AC_MSG_RESULT(sun4)
479                 ;;
480         *-hpux*)
481                 MKAFS_OSTYPE=HPUX
482                 AC_MSG_RESULT(hp_ux)
483                 if test -f "/usr/old/usr/include/ndir.h"; then
484                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
485                 fi
486                 ;;
487         *-irix*)
488                 if test -d /usr/include/sys/SN/SN1; then
489                  IRIX_BUILD_IP35="IP35"
490                 fi
491                 MKAFS_OSTYPE=IRIX
492                 AC_MSG_RESULT(sgi)
493                 ;;
494         *-aix*)
495                 MKAFS_OSTYPE=AIX
496                 AC_MSG_RESULT(rs_aix)
497                 ;;
498         arm-*-darwin*)
499                 MKAFS_OSTYPE=DARWIN
500                 AC_MSG_RESULT(arm_darwin)
501                 ;;
502         powerpc-*-darwin*)
503                 MKAFS_OSTYPE=DARWIN
504                 AC_MSG_RESULT(ppc_darwin)
505                 ;;
506         i386-*-darwin*)
507                 MKAFS_OSTYPE=DARWIN
508                 AC_MSG_RESULT(x86_darwin)
509                 ;;
510         x86_64-*-darwin*)
511                 MKAFS_OSTYPE=DARWIN
512                 AC_MSG_RESULT(x86_darwin)
513                 ;;
514         i386-*-freebsd*)
515                 MKAFS_OSTYPE=FBSD
516                 AC_MSG_RESULT(i386_fbsd)
517                 ;;
518         x86_64-*-freebsd*)
519                 MKAFS_OSTYPE=FBSD
520                 AC_MSG_RESULT(amd64_fbsd)
521                 ;;
522         *-netbsd*)
523                 MKAFS_OSTYPE=NBSD
524                 AC_MSG_RESULT(nbsd)
525                 ;;
526         x86_64-*-openbsd*)
527                 MKAFS_OSTYPE=OBSD
528                 AC_MSG_RESULT(amd64_obsd)
529                 ;;
530         i386-*-openbsd*)
531                 MKAFS_OSTYPE=OBSD
532                 AC_MSG_RESULT(i386_obsd)
533                 ;;
534         *-dragonfly*)
535                 MKAFS_OSTYPE=DFBSD
536                 AC_MSG_RESULT(i386_dfbsd)
537                 ;;
538         *)
539                 AC_MSG_RESULT($system)
540                 ;;
541 esac
542
543 if test "x$with_afs_sysname" != "x"; then
544         AFS_SYSNAME="$with_afs_sysname"
545 else
546         AC_MSG_CHECKING(your AFS sysname)
547         case $host in
548                 i?86-*-openbsd?.?)
549                         v=${host#*openbsd}
550                         vM=${v%.*}
551                         vm=${v#*.}
552                         AFS_SYSNAME="i386_obsd${vM}${vm}"
553                         ;;
554                 sparc64-*-openbsd?.?)
555                         v=${host#*openbsd}
556                         vM=${v%.*}
557                         vm=${v#*.}
558                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
559                         ;;
560                 x86_64-*-openbsd?.?)
561                         v=${host#*openbsd}
562                         vM=${v%.*}
563                         vm=${v#*.}
564                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
565                         ;;
566                 i?86-*-freebsd*.*)
567                         v=${host#*freebsd}
568                         vM=${v%.*}
569                         vm=${v#*.}
570                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
571                         ;;
572                 x86_64-*-freebsd*.*)
573                         v=${host#*freebsd}
574                         vM=${v%.*}
575                         vm=${v#*.}
576                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
577                         ;;
578                 i386-*-dragonfly?.*)
579                         v=${host#*dragonfly}
580                         vM=${v%.*}
581                         vm=${v#*.}
582                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
583                         ;;
584                 i?86-*-netbsd*1.6[[M-Z]]*)
585                         AFS_SYSNAME="i386_nbsd20"
586                         ;;
587                 powerpc-*-netbsd*1.6[[M-Z]]*)
588                         AFS_SYSNAME="ppc_nbsd20"
589                         ;;
590                 *-*-netbsd*)
591                         arch=${host%%-unknown*}
592                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
593                                                -e 's/powerpc/ppc/g')
594                         v=${host#*netbsd}
595                         v=${v#*aout}
596                         v=${v#*ecoff}
597                         v=${v#*elf}
598                         vM=${v%%.*}
599                         vM=${vM%.*}
600                         v=${v#*.}
601                         vm=${v%%.*}
602                         vm=${vm%.*}
603                         vm=${vm%%[[_A-Z]]*}
604                         if test $vm -eq 99 ; then
605                                 vM=$((vM+1))
606                         fi
607                         if test $vM -gt 1 ; then
608                                 vm=0
609                         fi
610                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
611                         ;;
612                 hppa*-hp-hpux11.0*)
613                         AFS_SYSNAME="hp_ux110"
614                         ;;
615                 hppa*-hp-hpux11.11)
616                         AFS_SYSNAME="hp_ux11i"
617                         ;;
618                 hppa*-hp-hpux11.23)
619                         AFS_SYSNAME="hp_ux1123"
620                         ;;
621                 ia64-hp-hpux11.22)
622                         AFS_SYSNAME="ia64_hpux1122"
623                         ;;
624                 ia64-hp-hpux*)
625                         AFS_SYSNAME="ia64_hpux1123"
626                         ;;
627                 hppa*-hp-hpux10*)
628                         AFS_SYSNAME="hp_ux102"
629                         ;;
630                 powerpc-apple-darwin7*)
631                         AFS_SYSNAME="ppc_darwin_70"
632                         OSXSDK="macosx10.3"
633                         ;;
634                 powerpc-apple-darwin8.*)
635                         AFS_SYSNAME="ppc_darwin_80"
636                         OSXSDK="macosx10.4"
637                         ;;
638                 i386-apple-darwin8.*)
639                         AFS_SYSNAME="x86_darwin_80"
640                         OSXSDK="macosx10.4"
641                         ;;
642                 powerpc-apple-darwin9.*)
643                         AFS_SYSNAME="ppc_darwin_90"
644                         OSXSDK="macosx10.5"
645                         ;;
646                 i386-apple-darwin9.*)
647                         AFS_SYSNAME="x86_darwin_90"
648                         OSXSDK="macosx10.5"
649                         ;;
650                 i?86-apple-darwin10.*)
651                         AFS_SYSNAME="x86_darwin_100"
652                         OSXSDK="macosx10.6"
653                         ;;
654                 x86_64-apple-darwin10.*)
655                         AFS_SYSNAME="x86_darwin_100"
656                         OSXSDK="macosx10.6"
657                         ;;
658                 arm-apple-darwin10.*)
659                         AFS_SYSNAME="arm_darwin_100"
660                         OSXSDK="iphoneos4.0"
661                         ;;
662                 x86_64-apple-darwin11.*)
663                         AFS_SYSNAME="x86_darwin_110"
664                         OSXSDK="macosx10.7"
665                         ;;
666                 i?86-apple-darwin11.*)
667                         AFS_SYSNAME="x86_darwin_110"
668                         OSXSDK="macosx10.7"
669                         ;;
670                 x86_64-apple-darwin12.*)
671                         AFS_SYSNAME="x86_darwin_120"
672                         OSXSDK="macosx10.8"
673                         ;;
674                 i?86-apple-darwin12.*)
675                         AFS_SYSNAME="x86_darwin_120"
676                         OSXSDK="macosx10.8"
677                         ;;
678                 x86_64-apple-darwin13.*)
679                         AFS_SYSNAME="x86_darwin_130"
680                         OSXSDK="macosx10.9"
681                         ;;
682                 i?86-apple-darwin13.*)
683                         AFS_SYSNAME="x86_darwin_130"
684                         OSXSDK="macosx10.9"
685                         ;;
686                 x86_64-apple-darwin14.*)
687                         AFS_SYSNAME="x86_darwin_140"
688                         OSXSDK="macosx10.10"
689                         ;;
690                 i?86-apple-darwin14.*)
691                         AFS_SYSNAME="x86_darwin_140"
692                         OSXSDK="macosx10.10"
693                         ;;
694                 sparc-sun-solaris2.8)
695                         AFS_SYSNAME="sun4x_58"
696                         ;;
697                 sparc-sun-solaris2.9)
698                         AFS_SYSNAME="sun4x_59"
699                         ;;
700                 sparc-sun-solaris2.10)
701                         AFS_SYSNAME="sun4x_510"
702                         ;;
703                 sparc-sun-solaris2.11)
704                         AFS_SYSNAME="sun4x_511"
705                         ;;
706                 i386-pc-solaris2.8)
707                         AFS_SYSNAME="sunx86_58"
708                         ;;
709                 i386-pc-solaris2.9)
710                         AFS_SYSNAME="sunx86_59"
711                         ;;
712                 i386-pc-solaris2.10)
713                         AFS_SYSNAME="sunx86_510"
714                         ;;
715                 i386-pc-solaris2.11)
716                         AFS_SYSNAME="sunx86_511"
717                         ;;
718                 alpha*-dec-osf4.0*)
719                         AFS_SYSNAME="alpha_dux40"
720                         ;;
721                 alpha*-dec-osf5.0*)
722                         AFS_SYSNAME="alpha_dux50"
723                         ;;
724                 alpha*-dec-osf5.1*)
725                         AFS_SYSNAME="alpha_dux51"
726                         ;;
727                 mips-sgi-irix6.5)
728                         AFS_SYSNAME="sgi_65"
729                         enable_pam="no"
730                         ;;
731                 ia64-*-linux*)
732                         AFS_SYSNAME="ia64_linuxXX"
733                         ;;
734                 powerpc-*-linux*)
735                         AFS_SYSNAME="`/bin/arch`_linuxXX"
736                         ;;
737                 powerpc64-*-linux*)
738                         AFS_SYSNAME="ppc64_linuxXX"
739                         ;;
740                 alpha*-linux*)
741                         AFS_SYSNAME="alpha_linux_XX"
742                         ;;
743                 s390-*-linux*)
744                         AFS_SYSNAME="s390_linuxXX"
745                         ;;
746                 s390x-*-linux*)
747                         AFS_SYSNAME="s390x_linuxXX"
748                         ;;
749                 sparc-*-linux*)
750                         AFS_SYSNAME="`/bin/arch`_linuxXX"
751                         ;;
752                 sparc64-*-linux*)
753                         AFS_SYSNAME="sparc64_linuxXX"
754                         ;;
755                 i?86-*-linux*)
756                         AFS_SYSNAME="i386_linuxXX"
757                         ;;
758                 arm*-linux*)
759                         AFS_SYSNAME="arm_linuxXX"
760                         ;;
761                 parisc-*-linux-gnu|hppa-*-linux-gnu)
762                         AFS_SYSNAME="parisc_linuxXX"
763                         enable_pam="no"
764                         ;;
765                 power*-ibm-aix4.2*)
766                         AFS_SYSNAME="rs_aix42"
767                         enable_pam="no"
768                         ;;
769                 power*-ibm-aix4.3*)
770                         AFS_SYSNAME="rs_aix42"
771                         enable_pam="no"
772                         ;;
773                 power*-ibm-aix5.1*)
774                         AFS_SYSNAME="rs_aix51"
775                         enable_pam="no"
776                         ;;
777                 power*-ibm-aix5.2*)
778                         AFS_SYSNAME="rs_aix52"
779                         enable_pam="no"
780                         ;;
781                 power*-ibm-aix5.3*)
782                         AFS_SYSNAME="rs_aix53"
783                         enable_pam="no"
784                         ;;
785                 power*-ibm-aix6.1*)
786                         AFS_SYSNAME="rs_aix61"
787                         enable_pam="no"
788                         ;;
789                 x86_64-*-linux-gnu)
790                         AFS_SYSNAME="amd64_linuxXX"
791                         enable_pam="yes"
792                         ;;
793                 *)
794                         AC_MSG_ERROR(An AFS sysname is required)
795                         exit 1
796                         ;;
797         esac
798         case $AFS_SYSNAME in
799                 *_linux* | *_umlinux*)
800                         if test "x${AFS_SYSKVERS}" = "x"; then
801                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
802                         fi
803                         if test "x${AFS_SYSKVERS}" = "x24" ||
804                                 test "x${AFS_SYSKVERS}" = "x22"; then
805                             AC_MSG_ERROR([Linux 2.4.x and older are no longer supported by OpenAFS.  Please use an OpenAFS 1.6.x release on those systems.])
806                         fi
807                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
808                         AFS_SYSNAME="$_AFS_SYSNAME"
809                         AC_TRY_KBUILD(
810                          [],
811                          [#ifndef CONFIG_USERMODE
812                           #error not UML
813                           #endif],
814                          ac_cv_linux_is_uml=yes,)
815                         if test "${ac_cv_linux_is_uml}" = yes; then
816                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
817                         fi
818                         AFS_SYSNAME="$_AFS_SYSNAME"
819                         ;;
820         esac
821         AC_MSG_RESULT($AFS_SYSNAME)
822 fi
823
824 case $AFS_SYSNAME in
825         *_darwin*)
826                 AC_CHECK_HEADERS(crt_externs.h)
827                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
828                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
829                 AC_SUBST(OSXSDK)
830                 ;;
831 esac
832
833 dnl Some hosts have a separate common param file they should include.  Figure
834 dnl out if we're on one of them now that we know the sysname.
835 case $AFS_SYSNAME in
836     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
837     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
838     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
839     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
840     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
841     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
842     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
843     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
844     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
845     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
846     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
847     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
848     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
849     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
850     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
851     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
852     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
853     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
854     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
855     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
856     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
857     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
858     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
859     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
860     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
861     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
862     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
863     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
864     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
865     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
866     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
867     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
868     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
869     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
870 # Linux alpha adds an extra underscore for no good reason.
871     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
872     *_fbsd_*)   AFS_PARAM_COMMON=param.generic_fbsd.h ;;
873 esac
874
875 OPENAFS_OSCONF
876
877 case $AFS_SYSNAME in *_linux* | *_umlinux*)
878
879                 # Add (sub-) architecture-specific paths needed by conftests
880                 case $AFS_SYSNAME  in
881                         *_umlinux26)
882                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
883                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
884                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
885                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
886                 esac
887
888                 if test "x$enable_kernel_module" = "xyes"; then
889                  if test "x$enable_debug_kernel" = "xno"; then
890                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
891                  fi
892                  OPENAFS_GCC_SUPPORTS_MARCH
893                  AC_SUBST(P5PLUS_KOPTS)
894                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
895                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
896                  OPENAFS_GCC_SUPPORTS_NO_COMMON
897                  OPENAFS_GCC_SUPPORTS_PIPE
898                  AC_SUBST(LINUX_GCC_KOPTS)
899
900                  dnl Setup the kernel build environment
901                  LINUX_KBUILD_USES_EXTRA_CFLAGS
902                  LINUX_KERNEL_COMPILE_WORKS
903
904                  dnl Check for header files
905                  AC_CHECK_LINUX_HEADER([config.h])
906                  AC_CHECK_LINUX_HEADER([completion.h])
907                  AC_CHECK_LINUX_HEADER([exportfs.h])
908                  AC_CHECK_LINUX_HEADER([freezer.h])
909                  AC_CHECK_LINUX_HEADER([key-type.h])
910                  AC_CHECK_LINUX_HEADER([semaphore.h])
911                  AC_CHECK_LINUX_HEADER([seq_file.h])
912
913                  dnl Type existence checks
914                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
915                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
916
917                  dnl Check for structure elements
918                  AC_CHECK_LINUX_STRUCT([address_space], [backing_dev_info], [fs.h])
919                  AC_CHECK_LINUX_STRUCT([address_space_operations],
920                                        [write_begin], [fs.h])
921                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
922                                        [backing-dev.h])
923                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
924                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
925                  AC_CHECK_LINUX_STRUCT([dentry], [d_u.d_alias], [dcache.h])
926                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
927                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
928                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
929                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
930                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
931                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
932                  AC_CHECK_LINUX_STRUCT([file], [f_path], [fs.h])
933                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
934                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
935                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
936                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
937                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
938                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
939                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
940                  AC_CHECK_LINUX_STRUCT([key_type], [match_preparse], [key-type.h])
941                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
942                  AC_CHECK_LINUX_STRUCT([msghdr], [msg_iter], [socket.h])
943                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
944                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
945                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
946                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
947                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
948                                        [fs.h])
949                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
950                                        [fs.h])
951                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
952                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
953                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
954                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
955                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
956                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
957                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
958                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
959                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
960                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
961                  AC_CHECK_LINUX_STRUCT([task_struct], [total_link_count], [sched.h])
962                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
963
964                  dnl Check for typed structure elements
965                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
966                                              [buf], [fs.h])
967
968                  dnl Function existence checks
969
970                  AC_CHECK_LINUX_FUNC([__vfs_read],
971                                      [#include <linux/fs.h>],
972                                      [__vfs_read(NULL, NULL, 0, NULL);])
973                  AC_CHECK_LINUX_FUNC([bdi_init],
974                                      [#include <linux/backing-dev.h>],
975                                      [bdi_init(NULL);])
976                  AC_CHECK_LINUX_FUNC([PageChecked],
977                                      [#include <linux/mm.h>
978 #include <linux/page-flags.h>],
979                                      [struct page *_page;
980                                       int bchecked = PageChecked(_page);])
981                  AC_CHECK_LINUX_FUNC([PageFsMisc],
982                                      [#include <linux/mm.h>
983 #include <linux/page-flags.h>],
984                                      [struct page *_page;
985                                       int bchecked = PageFsMisc(_page);])
986                  AC_CHECK_LINUX_FUNC([clear_inode],
987                                      [#include <linux/fs.h>],
988                                      [clear_inode(NULL);])
989                  AC_CHECK_LINUX_FUNC([current_kernel_time],
990                                      [#include <linux/time.h>],
991                                      [struct timespec s;
992                                       s = current_kernel_time();])
993                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
994                                      [#include <linux/fs.h>],
995                                      [d_alloc_anon(NULL);])
996                  AC_CHECK_LINUX_FUNC([d_count],
997                                      [#include <linux/dcache.h>],
998                                      [d_count(NULL);])
999                  AC_CHECK_LINUX_FUNC([d_make_root],
1000                                      [#include <linux/fs.h>],
1001                                      [d_make_root(NULL);])
1002                  AC_CHECK_LINUX_FUNC([do_sync_read],
1003                                      [#include <linux/fs.h>],
1004                                      [do_sync_read(NULL, NULL, 0, NULL);])
1005                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
1006                                      [#include <linux/sched.h>],
1007                                      [pid_t p; find_task_by_pid(p);])
1008                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
1009                                      [#include <linux/fs.h>],
1010                                      [generic_file_aio_read(NULL,NULL,0,0);])
1011                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
1012                                      [#include <linux/pagemap.h>],
1013                                      [grab_cache_page_write_begin(NULL, 0, 0);])
1014                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
1015                                      [#include <linux/list.h>],
1016                                      [hlist_unhashed(0);])
1017                  AC_CHECK_LINUX_FUNC([ihold],
1018                                      [#include <linux/fs.h>],
1019                                      [ihold(NULL);])
1020                  AC_CHECK_LINUX_FUNC([i_size_read],
1021                                      [#include <linux/fs.h>],
1022                                      [i_size_read(NULL);])
1023                  AC_CHECK_LINUX_FUNC([inode_setattr],
1024                                      [#include <linux/fs.h>],
1025                                      [inode_setattr(NULL, NULL);])
1026                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
1027                                      [#include <linux/fs.h>],
1028                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
1029                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
1030                                      [#include <linux/net.h>],
1031                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
1032                  AC_CHECK_LINUX_FUNC([page_follow_link],
1033                                      [#include <linux/fs.h>],
1034                                      [page_follow_link(0,0);])
1035                  AC_CHECK_LINUX_FUNC([page_offset],
1036                                      [#include <linux/pagemap.h>],
1037                                      [page_offset(NULL);])
1038                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
1039                                      [#include <linux/pagevec.h>],
1040                                      [__pagevec_lru_add_file(NULL);])
1041                  AC_CHECK_LINUX_FUNC([path_lookup],
1042                                      [#include <linux/fs.h>
1043                                       #include <linux/namei.h>],
1044                                      [path_lookup(NULL, 0, NULL);])
1045                  AC_CHECK_LINUX_FUNC([proc_create],
1046                                      [#include <linux/proc_fs.h>],
1047                                      [proc_create(NULL, 0, NULL, NULL);])
1048                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
1049                                      [#include <linux/rcupdate.h>],
1050                                      [rcu_read_lock();])
1051                  AC_CHECK_LINUX_FUNC([set_nlink],
1052                                      [#include <linux/fs.h>],
1053                                      [set_nlink(NULL, 1);])
1054                  AC_CHECK_LINUX_FUNC([sock_create_kern],
1055                                      [#include <linux/net.h>],
1056                                      [sock_create_kern(0, 0, 0, NULL);])
1057                  AC_CHECK_LINUX_FUNC([sock_create_kern_ns],
1058                                      [#include <linux/net.h>],
1059                                      [sock_create_kern(NULL, 0, 0, 0, NULL);])
1060                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
1061                                      [#include <linux/splice.h>],
1062                                      [splice_direct_to_actor(NULL,NULL,NULL);])
1063                  AC_CHECK_LINUX_FUNC([svc_addr_in],
1064                                      [#include <linux/sunrpc/svc.h>],
1065                                      [svc_addr_in(NULL);])
1066                  AC_CHECK_LINUX_FUNC([zero_user_segments],
1067                                      [#include <linux/highmem.h>],
1068                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1069                  AC_CHECK_LINUX_FUNC([noop_fsync],
1070                                      [#include <linux/fs.h>],
1071                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1072                  AC_CHECK_LINUX_FUNC([kthread_run],
1073                                      [#include <linux/kernel.h>
1074                                       #include <linux/kthread.h>],
1075                                      [kthread_run(NULL, NULL, "test");])
1076
1077                  dnl Consequences - things which get set as a result of the
1078                  dnl                above tests
1079                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1080                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1081                                   [define to disable the nfs translator])])
1082
1083                  dnl Assorted more complex tests
1084                  LINUX_AIO_NONVECTOR
1085                  LINUX_EXPORTS_PROC_ROOT_FS
1086                  LINUX_KMEM_CACHE_INIT
1087                  LINUX_HAVE_KMEM_CACHE_T
1088                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1089                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1090                  LINUX_D_PATH_TAKES_STRUCT_PATH
1091                  LINUX_NEW_EXPORT_OPS
1092                  LINUX_INODE_SETATTR_RETURN_TYPE
1093                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1094                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1095                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1096                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1097                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1098                  LINUX_DOP_D_DELETE_TAKES_CONST
1099                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1100                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1101                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1102                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1103                  LINUX_AOP_WRITEBACK_CONTROL
1104                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1105                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1106                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1107                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1108                  LINUX_KERNEL_SOCK_CREATE
1109                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1110                  LINUX_NEED_RHCONFIG
1111                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1112                  LINUX_EXPORTS_TASKLIST_LOCK
1113                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1114                  LINUX_STATFS_TAKES_DENTRY
1115                  LINUX_REFRIGERATOR
1116                  LINUX_HAVE_TRY_TO_FREEZE
1117                  LINUX_LINUX_KEYRING_SUPPORT
1118                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1119                  LINUX_KEY_ALLOC_NEEDS_CRED
1120                  LINUX_INIT_WORK_HAS_DATA
1121                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1122                  LINUX_HAVE_DCACHE_LOCK
1123                  LINUX_D_COUNT_IS_INT
1124                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1125                  LINUX_IOP_CREATE_TAKES_UMODE_T
1126                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1127                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1128                  LINUX_DENTRY_OPEN_TAKES_PATH
1129                  LINUX_D_ALIAS_IS_HLIST
1130                  LINUX_HLIST_ITERATOR_NO_NODE
1131                  LINUX_IOP_I_CREATE_TAKES_BOOL
1132                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1133                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1134                  LINUX_D_INVALIDATE_IS_VOID
1135
1136                  dnl If we are guaranteed that keyrings will work - that is
1137                  dnl  a) The kernel has keyrings enabled
1138                  dnl  b) The code is new enough to give us a key_type_keyring
1139                  dnl then we just disable syscall probing unless we've been
1140                  dnl told otherwise
1141
1142                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1143                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1144                           [enable_linux_syscall_probing="no"],
1145                           [enable_linux_syscall_probing="yes"])
1146                  ])
1147
1148                  dnl Syscall probing needs a few tests of its own, and just
1149                  dnl won't work if the kernel doesn't export init_mm
1150                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1151                    LINUX_EXPORTS_INIT_MM
1152                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1153                      AC_MSG_ERROR(
1154                        [Can't do syscall probing without exported init_mm])
1155                    ])
1156                    LINUX_EXPORTS_SYS_CHDIR
1157                    LINUX_EXPORTS_SYS_OPEN
1158                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1159                              [define to enable syscall table probes])
1160                  ])
1161
1162                  dnl Packaging and SMP build
1163                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1164                    LINUX_WHICH_MODULES
1165                  else
1166                    AC_SUBST(MPS,'SP')
1167                  fi
1168
1169                  dnl Syscall probing
1170                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1171                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1172                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1173                    ])
1174                    ac_cv_linux_exports_sys_call_table=no
1175                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1176                      ac_cv_linux_exports_ia32_sys_call_table=yes
1177                    fi
1178                  else
1179                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1180                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1181                    LINUX_EXPORTS_SYS_CALL_TABLE
1182                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1183                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1184                          linux_syscall_method=none
1185                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1186                             linux_syscall_method=scan
1187                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1188                                linux_syscall_method=scan_with_kallsyms_address
1189                             fi
1190                          fi
1191                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1192                             linux_syscall_method=kallsyms_symbol
1193                          fi
1194                          if test "x$linux_syscall_method" = "xnone"; then
1195                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1196                             linux_syscall_method=scan
1197                          fi
1198                    fi
1199                  fi
1200                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1201                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1202                  fi
1203                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1204                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1205                  fi
1206                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1207                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1208                  else
1209                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1210                  fi
1211                 :
1212                 fi
1213                 if test "x$enable_linux_d_splice_alias_extra_iput" = xyes; then
1214                     AC_DEFINE(D_SPLICE_ALIAS_LEAK_ON_ERROR, 1, [for internal use])
1215                 fi
1216 dnl Linux-only, but just enable always.
1217                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1218 esac
1219
1220 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1221     [ac_cv_sync_fetch_and_add],
1222     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1223                     [ac_cv_sync_fetch_and_add=yes],
1224                     [ac_cv_sync_fetch_and_add=no])
1225 ])
1226 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1227       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1228                 [define if your C compiler has __sync_add_and_fetch])])
1229
1230 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1231     [ac_cv_sockaddr_len],
1232     [AC_TRY_COMPILE( [#include <sys/types.h>
1233 #include <sys/socket.h>],
1234                      [struct sockaddr *a; a->sa_len=0;],
1235                      [ac_cv_sockaddr_len=yes],
1236                      [ac_cv_sockaddr_len=no])
1237 ])
1238 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1239       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1240                  [define if you struct sockaddr sa_len])])
1241
1242 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1243         echo Skipping library tests because they confuse Irix.
1244 else
1245   AC_SEARCH_LIBS([socket], [socket inet])
1246   AC_SEARCH_LIBS([connect], [nsl])
1247   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1248
1249   dnl darwin wants it, aix hates it
1250   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1251   AC_TRY_COMPILE([
1252   #include <stdlib.h>
1253   #include <stdio.h>
1254   #include <sys/types.h>
1255   #include <sys/socket.h>
1256   #include <netinet/in.h>
1257   #include <arpa/inet.h>
1258   #include <arpa/nameser.h>
1259   #include <arpa/nameser_compat.h>
1260   #include <resolv.h>
1261   ], [static int i; i = 0;],
1262   [AC_MSG_RESULT(yes)
1263    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1264   [AC_MSG_RESULT(no)
1265    ])
1266
1267   openafs_save_libs="$LIBS"
1268   AC_MSG_CHECKING([for res_search])
1269   AC_FUNC_RES_SEARCH
1270
1271   if test "$ac_cv_func_res_search" = no; then
1272       for lib in dns nsl resolv; do
1273         if test "$ac_cv_func_res_search" != yes; then
1274           LIBS="-l$lib $LIBS"
1275           AC_FUNC_RES_SEARCH
1276           LIBS="$openafs_save_libs"
1277         fi
1278       done    
1279       if test "$ac_cv_func_res_search" = yes; then
1280         LIB_AFSDB="-l$lib"
1281         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1282         AC_MSG_RESULT([yes, in lib$lib])
1283       else
1284         AC_MSG_RESULT(no)
1285       fi
1286   else
1287     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1288     AC_MSG_RESULT(yes)
1289   fi
1290   
1291 fi
1292 XLIBS="$LIB_AFSDB $XLIBS"
1293
1294 AC_CHECK_RESOLV_RETRANS
1295
1296 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1297     [ac_cv_setsockopt_iprecverr],
1298     [AC_TRY_COMPILE( [
1299 #include <sys/types.h>
1300 #include <sys/socket.h>
1301 #include <netinet/in.h>],
1302 [int on=1;
1303 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1304         [ac_cv_setsockopt_iprecverr=yes],
1305         [ac_cv_setsockopt_iprecverr=no])])
1306
1307 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1308       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1309                  [define if we can receive socket errors via IP_RECVERR])])
1310
1311 PTHREAD_LIBS=error
1312 if test "x$MKAFS_OSTYPE" = OBSD; then
1313         PTHREAD_LIBS="-pthread"
1314 fi
1315 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1316         PTHREAD_LIBS="-pthread"
1317 fi
1318 if test "x$PTHREAD_LIBS" = xerror; then
1319         AC_CHECK_LIB(pthread, pthread_attr_init,
1320                 PTHREAD_LIBS="-lpthread")
1321 fi
1322 if test "x$PTHREAD_LIBS" = xerror; then
1323         AC_CHECK_LIB(pthreads, pthread_attr_init,
1324                 PTHREAD_LIBS="-lpthreads")
1325 fi
1326 if test "x$PTHREAD_LIBS" = xerror; then
1327         AC_CHECK_LIB(c_r, pthread_attr_init,
1328                 PTHREAD_LIBS="-lc_r")
1329 fi
1330 if test "x$PTHREAD_LIBS" = xerror; then
1331         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1332 fi
1333 if test "x$PTHREAD_LIBS" = xerror; then
1334         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1335         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1336                 PTHREAD_LIBS="-lpthread")
1337 fi
1338 if test "x$PTHREAD_LIBS" = xerror; then
1339         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1340 fi
1341 AC_SUBST(PTHREAD_LIBS)
1342
1343 HOST_CPU="$host_cpu"
1344
1345 if test "x$with_bsd_kernel_headers" != "x"; then
1346         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1347 else
1348         BSD_KERNEL_PATH="/usr/src/sys"
1349 fi
1350
1351 if test "x$with_bsd_kernel_build" != "x"; then
1352         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1353 else
1354         case $AFS_SYSNAME in
1355                 *_fbsd_*)
1356                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1357                         ;;
1358                 *_nbsd*)
1359                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1360         esac
1361 fi
1362
1363 # Fast restart
1364 if test "$enable_supergroups" = "yes"; then
1365         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1366 fi
1367
1368 if test "$enable_bitmap_later" = "yes"; then
1369         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1370 fi
1371
1372 if test "$enable_unix_sockets" = "yes"; then
1373         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1374         USE_UNIX_SOCKETS="yes"
1375 else
1376         USE_UNIX_SOCKETS="no"
1377 fi
1378 AC_SUBST(USE_UNIX_SOCKETS)
1379
1380 if test "$enable_namei_fileserver" = "yes"; then
1381         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1382         VFSCK=""
1383 else
1384         if test "$enable_namei_fileserver" = "default"; then
1385                 case $host in
1386                         *-solaris2.10*)
1387                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1388                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1389                                 VFSCK=""
1390                                 ;;
1391                         *-solaris2.11*)
1392                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1393                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1394                                 VFSCK=""
1395                                 ;;
1396                         *)
1397                                 VFSCK="vfsck"
1398                                 ;;
1399                 esac
1400         else
1401                 VFSCK="vfsck"
1402         fi
1403 fi
1404
1405 dnl check for tivoli
1406 AC_MSG_CHECKING(for tivoli tsm butc support)
1407 XBSA_CFLAGS=""
1408 if test "$enable_tivoli_tsm" = "yes"; then
1409         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1410         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1411         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1412         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1413
1414         if test -r "$XBSADIR3/dsmapifp.h"; then
1415                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1416                 XBSA_XLIBS="-ldl"
1417                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1418         elif test -r "$XBSADIR4/dsmapifp.h"; then
1419                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1420                 XBSA_XLIBS="-ldl"
1421                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1422         elif test -r "$XBSADIR1/xbsa.h"; then
1423                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1424                 XBSA_XLIBS=""
1425                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1426         elif test -r "$XBSADIR2/xbsa.h"; then
1427                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1428                 XBSA_XLIBS=""
1429                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1430         else
1431                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1432         fi
1433 else
1434         AC_MSG_RESULT([no])
1435 fi
1436 AC_SUBST(XBSA_CFLAGS)
1437 AC_SUBST(XBSA_XLIBS) 
1438
1439 dnl checks for header files.
1440 AC_HEADER_STDC
1441 AC_HEADER_SYS_WAIT
1442 AC_HEADER_DIRENT
1443 AC_CHECK_HEADERS([ \
1444                    arpa/inet.h \
1445                    arpa/nameser.h \
1446                    curses.h\
1447                    direct.h \
1448                    errno.h \
1449                    fcntl.h \
1450                    grp.h \
1451                    math.h \
1452                    mntent.h \
1453                    ncurses.h \
1454                    ncurses/ncurses.h \
1455                    netdb.h \
1456                    netinet/in.h \
1457                    pthread_np.h \
1458                    pwd.h \
1459                    regex.h \
1460                    security/pam_appl.h \
1461                    signal.h \
1462                    stdint.h \
1463                    stdio_ext.h \
1464                    stdlib.h \
1465                    string.h \
1466                    strings.h \
1467                    sys/bitypes.h \
1468                    sys/bswap.h \
1469                    sys/dk.h \
1470                    sys/fcntl.h \
1471                    sys/file.h \
1472                    sys/fs_types.h \
1473                    sys/fstyp.h \
1474                    sys/ioctl.h \
1475                    sys/ipc.h \
1476                    sys/lockf.h \
1477                    sys/map.h \
1478                    sys/mount.h \
1479                    sys/mntent.h \
1480                    sys/mnttab.h \
1481                    sys/pag.h \
1482                    sys/param.h \
1483                    sys/resource.h \
1484                    sys/select.h \
1485                    sys/statfs.h \
1486                    sys/statvfs.h \
1487                    sys/socket.h \
1488                    sys/sysctl.h \
1489                    sys/time.h \
1490                    sys/types.h \
1491                    sys/uio.h \
1492                    sys/un.h \
1493                    sys/vfs.h \
1494                    syslog.h \
1495                    termios.h \
1496                    time.h \
1497                    ucontext.h \
1498                    unistd.h \
1499                    windows.h \
1500                 ])
1501
1502 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1503 #ifdef HAVE_NETINET_IN_H
1504 # include <netinet/in.h>
1505 #endif])
1506
1507 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1508 #ifdef HAVE_SYS_SOCKET_H
1509 # include <sys/socket.h>
1510 #endif])
1511
1512 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1513 #ifdef HAVE_SYS_SOCKET_H
1514 # include <sys/socket.h>
1515 #endif
1516 #ifdef HAVE_NETINET_IN_H
1517 # include <netinet/in.h>
1518 #endif
1519 #ifdef HAVE_NET_IF_H
1520 # include <net/if.h>
1521 #endif])
1522
1523 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1524 #ifdef HAVE_SECURITY_PAM_APPL_H
1525 # include <security/pam_appl.h>
1526 #endif])
1527
1528 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1529
1530 AC_CHECK_TYPES([fsblkcnt_t],,,[
1531 #include <sys/types.h>
1532 #ifdef HAVE_SYS_BITYPES_H
1533 #include <sys/bitypes.h>
1534 #endif
1535 #ifdef HAVE_SYS_STATFS_H
1536 #include <sys/statfs.h>
1537 #endif
1538 #ifdef HAVE_SYS_STATVFS_H
1539 #include <sys/statvfs.h>
1540 #endif
1541 ])
1542
1543 dnl see what struct stat has for timestamps
1544 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1545
1546 dnl check for curses-lib
1547 AS_IF([test "x$enable_gtx" != "xno"],
1548       [save_LIBS=$LIBS
1549       AC_CHECK_LIB( [ncurses], [setupterm],
1550       [LIB_curses=-lncurses],
1551         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1552           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1553       ])
1554       LIBS=$save_LIBS
1555       AC_SUBST(LIB_curses)])
1556         
1557 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1558
1559 if test "$enable_debug_locks" = yes; then
1560         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1561 fi
1562
1563 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1564         HAVE_PAM="YES"
1565 else
1566         HAVE_PAM="no"
1567 fi
1568 AC_SUBST(HAVE_PAM)
1569
1570 if test "$enable_login" = yes; then
1571         BUILD_LOGIN="yes"
1572 else
1573         BUILD_LOGIN="no"
1574 fi
1575 AC_SUBST(BUILD_LOGIN)
1576
1577 if test "$enable_kauth" = yes; then
1578         INSTALL_KAUTH="yes"
1579 else
1580         INSTALL_KAUTH="no"
1581 fi
1582 AC_SUBST(INSTALL_KAUTH)
1583
1584 AC_CHECK_FUNCS([ \
1585         arc4random \
1586         fcntl \
1587         fseeko64 \
1588         ftello64 \
1589         getcwd \
1590         getegid \
1591         geteuid \
1592         getgid \
1593         getuid \
1594         getrlimit \
1595         issetugid \
1596         mkstemp \
1597         poll \
1598         pread \
1599         preadv \
1600         preadv64 \
1601         pwrite \
1602         pwritev \
1603         pwritev64 \
1604         regcomp \
1605         regerror \
1606         regexec \
1607         setitimer \
1608         setvbuf \
1609         sigaction \
1610         strcasestr \
1611         strerror \
1612         sysconf \
1613         sysctl \
1614         tdestroy \
1615         timegm \
1616 ])
1617
1618 OPENAFS_ROKEN()
1619 OPENAFS_HCRYPTO()
1620 OPENAFS_C_ATTRIBUTE()
1621
1622 dnl Functions that Heimdal's libroken provides, but that we
1623 dnl haven't found a need for yet, and so haven't imported
1624 AC_CHECK_FUNCS([ \
1625         chown \
1626         fchown \
1627         gethostname \
1628         lstat \
1629         inet_aton \
1630         putenv \
1631         readv \
1632         setenv \
1633         strdup \
1634         strftime \
1635         strndup \
1636         strsep \
1637         unsetenv \
1638 ])
1639
1640 dnl Functions that are in objects that we always build from libroken
1641 AC_CHECK_FUNCS([ \
1642         asprintf \
1643         asnprintf \
1644         vasprintf \
1645         vasnprintf \
1646         vsnprintf \
1647         snprintf \
1648 ])
1649
1650 dnl Functions that we're going to try and get from libroken
1651 AC_REPLACE_FUNCS([ \
1652         daemon \
1653         ecalloc \
1654         emalloc \
1655         erealloc \
1656         err \
1657         errx \
1658         flock \
1659         freeaddrinfo \
1660         gai_strerror \
1661         getaddrinfo \
1662         getdtablesize \
1663         getnameinfo \
1664         getopt \
1665         getprogname \
1666         gettimeofday \
1667         inet_ntop \
1668         inet_pton \
1669         localtime_r \
1670         mkstemp \
1671         setenv \
1672         setprogname \
1673         strcasecmp \
1674         strlcat \
1675         strnlen \
1676         strlcpy \
1677         strsep \
1678         tdelete \
1679         tfind \
1680         tsearch \
1681         twalk \
1682         unsetenv \
1683         verr \
1684         verrx \
1685         vsyslog \
1686         vwarn \
1687         vwarnx \
1688         warn \
1689         warnx \
1690 ])
1691
1692 dnl Headers that we're going to try and get from libroken
1693 AC_CHECK_HEADERS([ \
1694         err.h \
1695         search.h \
1696 ])
1697
1698 AC_CHECK_DECLS([h_errno], [], [], [
1699 #include <sys/types.h>
1700 #ifdef HAVE_NETDB_H
1701 #include <netdb.h>
1702 #endif
1703 ])
1704
1705 AC_HEADER_TIME
1706
1707 ROKEN_HEADERS=
1708 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1709       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1710       [])
1711 AC_SUBST(ROKEN_HEADERS)
1712
1713 dnl Stuff that's harder ...
1714 AC_MSG_CHECKING([for bswap16])
1715 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1716 #ifdef HAVE_SYS_TYPES_H
1717 #include <sys/types.h>
1718 #endif
1719 #ifdef HAVE_SYS_BSWAP_H
1720 #include <sys/bswap.h>
1721 #endif
1722 ],
1723 [short a, b; b = bswap16(a); ])],
1724 [AC_MSG_RESULT(yes)
1725  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1726 ],
1727 [AC_MSG_RESULT(no)])
1728
1729 AC_MSG_CHECKING([for bswap32])
1730 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1731 #include <sys/types.h>
1732 #endif
1733 #ifdef HAVE_SYS_BSWAP_H
1734 #include <sys/bswap.h>
1735 #endif
1736 ],
1737 [int a, b; b = bswap32(a); ])],
1738 [AC_MSG_RESULT(yes)
1739  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1740 ],
1741 [AC_MSG_RESULT(no)])
1742
1743 case $AFS_SYSNAME in
1744 *hp_ux* | *hpux*)
1745    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1746    ;;
1747 *)
1748    AC_MSG_CHECKING([for positional I/O])
1749    if test "$ac_cv_func_pread" = "yes" && \
1750            test "$ac_cv_func_pwrite" = "yes"; then
1751       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1752       AC_MSG_RESULT(yes)
1753    else
1754      AC_MSG_RESULT(no)
1755    fi
1756    AC_MSG_CHECKING([for vectored positional I/O])
1757    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1758                "$ac_cv_func_pwritev" = "yes" -a \
1759                "$ac_cv_func_preadv64" = "yes" -a \
1760                "$ac_cv_func_pwritev64" = "yes"],
1761          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1762           AC_MSG_RESULT(yes)],
1763          [AC_MSG_RESULT(no)])
1764    ;;
1765 esac
1766
1767 AC_MSG_CHECKING([for POSIX regex library])
1768 if test "$ac_cv_header_regex_h" = "yes" && \
1769         test "$ac_cv_func_regcomp" = "yes" && \
1770         test "$ac_cv_func_regexec" = "yes" && \
1771         test "$ac_cv_func_regerror" = "yes"; then
1772     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1773     AC_MSG_RESULT(yes)
1774 else
1775     AC_MSG_RESULT(no)
1776 fi
1777
1778 dnl Look for "non-portable" pthreads functions.
1779 save_LIBS="$LIBS"
1780 LIBS="$LIBS $PTHREAD_LIBS"
1781 AC_CHECK_FUNCS([ \
1782         pthread_set_name_np \
1783         pthread_setname_np \
1784 ])
1785
1786 dnl Sadly, there are three different versions of pthread_setname_np.
1787 dnl Try to cater for all of them.
1788 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1789     AC_MSG_CHECKING([for signature of pthread_setname_np])
1790     AC_TRY_COMPILE([
1791 #include <pthread.h>
1792 #ifdef HAVE_PTHREAD_NP_H
1793 #include <pthread_np.h>
1794 #endif
1795 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1796         AC_MSG_RESULT([three arguments])
1797         pthread_setname_np_args=3], [
1798         AC_TRY_COMPILE([
1799 #include <pthread.h>
1800 #ifdef HAVE_PTHREAD_NP_H
1801 #include <pthread_np.h>
1802 #endif
1803 ], [pthread_setname_np(pthread_self(), "test")], [
1804             AC_MSG_RESULT([two arguments])
1805             pthread_setname_np_args=2], [
1806             AC_TRY_COMPILE([
1807 #include <pthread.h>
1808 #ifdef HAVE_PTHREAD_NP_H
1809 #include <pthread_np.h>
1810 #endif
1811 ], [pthread_setname_np("test")], [
1812                 AC_MSG_RESULT([one argument])
1813                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1814 ])
1815 ])
1816 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1817 fi
1818 LIBS="$save_LIBS"
1819
1820 openafs_cv_saved_CFLAGS="$CFLAGS"
1821 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1822
1823 AC_TYPE_SIGNAL
1824 OPENAFS_RETSIGTYPE
1825 AC_CHECK_SIZEOF(void *)
1826 AC_CHECK_SIZEOF(unsigned long long)
1827 AC_CHECK_SIZEOF(unsigned long)
1828 AC_CHECK_SIZEOF(unsigned int)
1829 AC_TYPE_INTPTR_T
1830 AC_TYPE_UINTPTR_T
1831 AC_TYPE_SSIZE_T
1832 AC_CHECK_TYPE([sig_atomic_t],[],
1833     [AC_DEFINE([sig_atomic_t], [int],
1834         [Define to int if <signal.h> does not define.])],
1835 [#include <sys/types.h>
1836 #include <signal.h>])
1837 AC_CHECK_TYPE([socklen_t],[],
1838     [AC_DEFINE([socklen_t], [int],
1839         [Define to int if <sys/socket.h> does not define.])],
1840 [#include <sys/types.h>
1841 #include <sys/socket.h>])
1842 AC_CHECK_TYPES(off64_t)
1843 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1844 AC_CHECK_TYPES([struct winsize], [], [], [
1845 #ifdef HAVE_TERMIOS_H
1846 # include <termios.h>
1847 #else
1848 # include <sys/termios.h>
1849 #endif
1850 #include <sys/ioctl.h>])
1851 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1852                 struct sockaddr_storage],
1853                [], [], [
1854 #include <sys/types.h>
1855 #include <sys/socket.h>
1856 ])
1857 AC_CHECK_TYPES([sa_family_t], [], [], [
1858 #include <sys/types.h>
1859 #include <sys/socket.h>
1860 ])
1861 AC_CHECK_TYPES([struct addrinfo], [], [], [
1862 #include <sys/types.h>
1863 #ifdef HAVE_NETDB_H
1864 #include <netdb.h>
1865 #endif
1866 ])
1867 AC_CHECK_TYPES([long long], [], [], [])
1868
1869 AC_SIZEOF_TYPE(long)
1870
1871 CFLAGS="$openafs_cv_saved_CFLAGS"
1872
1873 RRA_HEADER_PAM_CONST
1874
1875
1876 dnl Directory PATH handling
1877 if test "x$enable_transarc_paths" = "xyes"  ; then 
1878     afsconfdir=${afsconfdir=/usr/afs/etc}
1879     viceetcdir=${viceetcdir=/usr/vice/etc}
1880     afskerneldir=${afskerneldir=${viceetcdir}}
1881     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1882     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1883     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1884     afsdbdir=${afsdbdir=/usr/afs/db}
1885     afslogsdir=${afslogsdir=/usr/afs/logs}
1886     afslocaldir=${afslocaldir=/usr/afs/local}
1887     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1888     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1889     afsdatadir=${afsdatadir=/usr/vice/etc}
1890 else 
1891     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1892     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1893     afskerneldir=${afskerneldir='${libdir}/openafs'}
1894     afssrvbindir=${afssrvbindir='${bindir}'}
1895     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1896     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1897     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1898     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1899     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1900     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1901     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1902     afsdatadir=${afsdatadir='${datadir}/openafs'}
1903 fi
1904 AC_SUBST(afsconfdir)
1905 AC_SUBST(viceetcdir)
1906 AC_SUBST(afskerneldir)
1907 AC_SUBST(afssrvbindir)
1908 AC_SUBST(afssrvsbindir)
1909 AC_SUBST(afssrvlibexecdir)
1910 AC_SUBST(afsdbdir)
1911 AC_SUBST(afslogsdir)
1912 AC_SUBST(afslocaldir)
1913 AC_SUBST(afsbackupdir)
1914 AC_SUBST(afsbosconfigdir)
1915 AC_SUBST(afsdatadir)
1916
1917 if test "x$enable_kernel_module" = "xyes"; then
1918 ENABLE_KERNEL_MODULE=libafs
1919 fi
1920
1921 if test "x$enable_pthreaded_ubik" = "xyes"; then
1922 ENABLE_PTHREADED_UBIK=yes
1923 fi
1924
1925 AC_SUBST(VFSCK)
1926 AC_SUBST(AFS_SYSNAME)
1927 AC_SUBST(AFS_PARAM_COMMON)
1928 AC_SUBST(ENABLE_KERNEL_MODULE)
1929 AC_SUBST(ENABLE_PTHREADED_UBIK)
1930 AC_SUBST(LIB_AFSDB)
1931 AC_SUBST(LINUX_KERNEL_PATH)
1932 AC_SUBST(LINUX_KERNEL_BUILD)
1933 AC_SUBST(HOST_CPU)
1934 AC_SUBST(BSD_KERNEL_PATH)
1935 AC_SUBST(BSD_KERNEL_BUILD)
1936 AC_SUBST(LINUX_VERSION)
1937 AC_SUBST(MKAFS_OSTYPE)
1938 AC_SUBST(TOP_OBJDIR)
1939 AC_SUBST(TOP_SRCDIR)
1940 AC_SUBST(TOP_INCDIR)
1941 AC_SUBST(TOP_LIBDIR)
1942 AC_SUBST(DEST)
1943 AC_SUBST(DARWIN_INFOFILE)
1944 AC_SUBST(IRIX_BUILD_IP35)
1945 AC_SUBST(HTML_XSL)
1946 AC_SUBST(XSLTPROC)
1947 AC_SUBST(DOCBOOK2PDF)
1948 AC_SUBST(DOCBOOK_STYLESHEETS)
1949
1950 OPENAFS_FUSE
1951 OPENAFS_SWIG
1952
1953 TOP_SRCDIR="${srcdir}/src"
1954 dnl
1955 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1956 dnl
1957 case $TOP_SRCDIR in
1958         /*)
1959                 ;;
1960         *)
1961                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1962                 ;;
1963 esac
1964
1965 TOP_OBJDIR="${SRCDIR_PARENT}"
1966 TOP_INCDIR="${SRCDIR_PARENT}/include"
1967 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1968 if test "${DEST}x" = "x"; then
1969         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1970 fi
1971
1972 if test "x$with_crosstools_dir" != "x"; then
1973         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1974                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1975                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1976                 RXGEN_PATH=$with_crosstools_dir/rxgen
1977         else
1978                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1979                 exit 1
1980         fi
1981 else
1982         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1983         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1984         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1985 fi
1986 AC_SUBST(COMPILE_ET_PATH)
1987 AC_SUBST(CONFIGTOOL_PATH)
1988 AC_SUBST(RXGEN_PATH)
1989
1990 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1991 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1992 AC_SUBST(HELPER_SPLINT)
1993 AC_SUBST(HELPER_SPLINTCFG)
1994
1995 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1996
1997 dnl Check to see if crypt lives in a different library
1998 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1999 AC_SUBST(LIB_crypt)
2000
2001 dnl Check to see if the compiler support labels in structs
2002 AC_MSG_CHECKING(for label support in structs)
2003 AC_TRY_COMPILE([], [
2004 extern void osi_UFSOpen(void);
2005 struct labeltest {
2006    void (*open) (void);
2007 };
2008 struct labeltest struct_labeltest = {
2009    .open       = osi_UFSOpen,
2010 }
2011 ],
2012 [AC_MSG_RESULT(yes)
2013  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
2014 ],
2015 [AC_MSG_RESULT(no)
2016 ])
2017
2018 AC_MSG_CHECKING([checking for dirfd])
2019 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
2020 #ifdef HAVE_DIRENT_H
2021 #include <dirent.h>
2022 #endif
2023 ]],
2024         [[DIR *d = 0; dirfd(d);]])],
2025         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
2026 if test "$ac_rk_have_dirfd" = "yes" ; then
2027         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
2028 fi
2029 AC_MSG_RESULT($ac_rk_have_dirfd)
2030
2031 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
2032 #ifdef HAVE_DIRENT_H
2033 #include <dirent.h>
2034 #endif])
2035
2036 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
2037 [#ifdef HAVE_SYS_RESOURCE_H
2038 #include <sys/resource.h>
2039 #endif])
2040
2041 dnl Check for UUID library
2042 AC_CHECK_HEADERS([uuid/uuid.h])
2043 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
2044 AC_CHECK_FUNCS([uuid_generate])
2045 ])
2046
2047