acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #   define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 #define _FILE_OFFSET_BITS 64
  48 #define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 #include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
  76
  77 dnl General feature options.
  78 AC_ARG_ENABLE([pam],
  79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
  80     ,
  81     [enable_pam="yes"])
  82 AC_ARG_ENABLE([gtx],
  83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
  84 AC_ARG_ENABLE([uss],
  85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
  86 AC_ARG_ENABLE([namei-fileserver],
  87     [AS_HELP_STRING([--enable-namei-fileserver],
  88         [force compilation of namei fileserver in preference to inode
  89          fileserver])],
  90     ,
  91     [enable_namei_fileserver="default"])
  92 AC_ARG_ENABLE([supergroups],
  93     [AS_HELP_STRING([--enable-supergroups],
  94         [enable support for nested pts groups])],
  95     ,
  96     [enable_supergroups="no"])
  97 AC_ARG_ENABLE([bitmap-later],
  98     [AS_HELP_STRING([--enable-bitmap-later],
  99         [enable fast startup of file server by not reading bitmap till
 100          needed])],
 101     ,
 102     [enable_bitmap_later="no"])
 103 AC_ARG_ENABLE([unix-sockets],
 104     [AS_HELP_STRING([--disable-unix-sockets],
 105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 106     ,
 107     [enable_unix_sockets="yes"])
 108 AC_ARG_ENABLE([tivoli-tsm],
 109     [AS_HELP_STRING([--enable-tivoli-tsm],
 110         [enable use of the Tivoli TSM API libraries for butc support])],
 111     ,
 112     [enable_tivoli_tsm="no"])
 113 AC_ARG_ENABLE([pthreaded-ubik],
 114     [AS_HELP_STRING([--enable-pthreaded-ubik],
 115         [enable installation of pthreaded ubik applications (defaults to
 116          disabled)])],
 117     ,
 118     [enable_pthreaded_ubik="no"])
 119
 120 dnl Kernel module build options.
 121 AC_ARG_WITH([linux-kernel-headers],
 122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 123         [use the kernel headers found at path (optional, defaults to
 124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
 125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
 126 AC_ARG_WITH([linux-kernel-build],
 127     [AS_HELP_STRING([--with-linux-kernel-build=path],
 128         [use the kernel build found at path(optional, defaults to
 129         kernel headers path)])])
 130 AC_ARG_WITH([bsd-kernel-headers],
 131     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 132         [use the kernel headers found at path (optional, defaults to
 133          /usr/src/sys)])])
 134 AC_ARG_WITH([bsd-kernel-build],
 135     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 136         [use the kernel build found at path (optional, defaults to
 137          KSRC/i386/compile/GENERIC)])])
 138 AC_ARG_WITH([linux-kernel-packaging],
 139     [AS_HELP_STRING([--with-linux-kernel-packaging],
 140         [use standard naming conventions to aid Linux kernel build packaging
 141          (disables MPS, sets the kernel module name to openafs.ko, and
 142          installs kernel modules into the standard Linux location)])],
 143     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
 144      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
 145     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
 146 AC_ARG_ENABLE([kernel-module],
 147     [AS_HELP_STRING([--disable-kernel-module],
 148         [disable compilation of the kernel module (defaults to enabled)])],
 149     ,
 150     [enable_kernel_module="yes"])
 151 AC_ARG_ENABLE([redhat-buildsys],
 152     [AS_HELP_STRING([--enable-redhat-buildsys],
 153         [enable compilation of the redhat build system kernel (defaults to
 154          disabled)])],
 155     ,
 156     [enable_redhat_buildsys="no"])
 157
 158 dnl Installation locations.
 159 AC_ARG_ENABLE([transarc-paths],
 160     [AS_HELP_STRING([--enable-transarc-paths],
 161         [use Transarc style paths like /usr/afs and /usr/vice])],
 162     ,
 163     [enable_transarc_paths="no"])
 164
 165 dnl Deprecated crypto
 166 AC_ARG_ENABLE([kauth],
 167     [AS_HELP_STRING([--disable-kauth],
 168         [do not install the deprecated kauth server and utilities (defaults to
 169          enabled)])],
 170     ,
 171     [enable_kauth="yes"])
 172
 173 dnl Optimization and debugging flags.
 174 AC_ARG_ENABLE([strip-binaries],
 175     [AS_HELP_STRING([--disable-strip-binaries],
 176         [disable stripping of symbol information from binaries (defaults to
 177          enabled)])],
 178     ,
 179     [enable_strip_binaries="maybe"])
 180 AC_ARG_ENABLE([debug],
 181     [AS_HELP_STRING([--enable-debug],
 182         [enable compilation of the user space code with debugging information
 183          (defaults to disabled)])],
 184     ,
 185     [enable_debug="no"])
 186 AC_ARG_ENABLE([optimize],
 187     [AS_HELP_STRING([--disable-optimize],
 188         [disable optimization for compilation of the user space code (defaults
 189          to enabled)])],
 190     ,
 191     [enable_optimize="yes"])
 192 AC_ARG_ENABLE([warnings],
 193     [AS_HELP_STRING([--enable-warnings],
 194         [enable compilation warnings when building with gcc (defaults to
 195          disabled)])],
 196     ,
 197     [enable_warnings="no"])
 198 AC_ARG_ENABLE([checking],
 199     [AS_HELP_STRING([--enable-checking],
 200         [turn compilation warnings into errors when building with gcc (defaults
 201          to disabled)])],
 202     [enable_checking="$enableval"],
 203     [enable_checking="no"])
 204 AC_ARG_ENABLE([debug-locks],
 205     [AS_HELP_STRING([--enable-debug-locks],
 206         [turn on lock debugging assertions (defaults to disabled)])],
 207     [enable_debug_locks="$enableval"],
 208     [enable_debug_locks="no"])
 209 AC_ARG_ENABLE([debug-kernel],
 210     [AS_HELP_STRING([--enable-debug-kernel],
 211         [enable compilation of the kernel module with debugging information
 212          (defaults to disabled)])],
 213     ,
 214     [enable_debug_kernel="no"])
 215 AC_ARG_ENABLE([optimize-kernel],
 216     [AS_HELP_STRING([--disable-optimize-kernel],
 217         [disable compilation of the kernel module with optimization (defaults
 218          based on platform)])],
 219     ,
 220     [enable_optimize_kernel=""])
 221 AC_ARG_ENABLE([debug-lwp],
 222     [AS_HELP_STRING([--enable-debug-lwp],
 223         [enable compilation of the LWP code with debugging information
 224          (defaults to disabled)])],
 225     ,
 226     [enable_debug_lwp="no"])
 227 AC_ARG_ENABLE([optimize-lwp],
 228     [AS_HELP_STRING([--disable-optimize-lwp],
 229         [disable optimization for compilation of the LWP code (defaults to
 230          enabled)])],
 231     ,
 232     [enable_optimize_lwp="yes"])
 233 AC_ARG_ENABLE([debug-pam],
 234     [AS_HELP_STRING([--enable-debug-pam],
 235         [enable compilation of the PAM code with debugging information
 236          (defaults to disabled)])],
 237     ,
 238     [enable_debug_pam="no"])
 239 AC_ARG_ENABLE([optimize-pam],
 240     [AS_HELP_STRING([--disable-optimize-pam],
 241         [disable optimization for compilation of the PAM code (defaults to
 242          enabled)])],
 243     ,
 244     [enable_optimize_pam="yes"])
 245 AC_ARG_ENABLE([linux-syscall-probing],
 246     [AS_HELP_STRING([--enable-linux-syscall-probing],
 247         [enable Linux syscall probing (defaults to autodetect)])],
 248     ,
 249     [enable_linux_syscall_probing="maybe"])
 250 AC_ARG_WITH([crosstools-dir],
 251     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
 252
 253 AC_ARG_WITH([xslt-processor],
 254         AS_HELP_STRING([--with-xslt-processor=ARG],
 255         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 256         [XSLTPROC="$withval"],
 257         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
 258
 259 AC_ARG_WITH([html-xsl],
 260         AS_HELP_STRING([--with-html-xsl],
 261         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 262         [HTML_XSL="$withval"],
 263         [HTML_XSL="html/chunk.xsl"])
 264
 265 AC_ARG_WITH([docbook2pdf],
 266         AS_HELP_STRING([--with-docbook2pdf=ARG],
 267         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 268         [DOCBOOK2PDF="$withval"],
 269         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
 270
 271 AC_ARG_WITH([docbook-stylesheets],
 272         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 273         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 274         [DOCBOOK_STYLESHEETS="$withval"],
 275         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
 276         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
 277                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 278         fi)
 279
 280 enable_login="no"
 281
 282 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 283 dnl documentation build.
 284 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 285
 286 dnl weird ass systems
 287 dnl AC_AIX
 288 AC_ISC_POSIX
 289 dnl AC_MINIX
 290
 291 dnl Various compiler setup.
 292 AC_TYPE_PID_T
 293 AC_TYPE_SIZE_T
 294
 295 dnl Checks for programs.
 296 AC_PROG_INSTALL
 297 AC_PROG_LN_S
 298 AC_PROG_RANLIB
 299 AC_PROG_YACC
 300 AM_PROG_LEX
 301 dnl if we are flex, be lex-compatible
 302 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 303
 304 OPENAFS_FORCE_ABS_INSTALL
 305 OPENAFS_CHECK_BIGENDIAN
 306 OPENAFS_PRINTF_TAKES_Z_LEN
 307
 308 AC_MSG_CHECKING(your OS)
 309 system=$host
 310 case $system in
 311         *-linux*)
 312
 313                 MKAFS_OSTYPE=LINUX
 314                 if test "x$enable_redhat_buildsys" = "xyes"; then
 315                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 316                 fi
 317                 if test "x$enable_kernel_module" = "xyes"; then
 318                  if test "x$with_linux_kernel_headers" != "x"; then
 319                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 320                  else
 321                    for utsdir in "/lib/modules/`uname -r`/build" \
 322                                  "/lib/modules/`uname -r`/source" \
 323                                  "/usr/src/linux-2.4" \
 324                                  "/usr/src/linux"; do
 325                      LINUX_KERNEL_PATH="$utsdir"
 326                      for utsfile in "include/generated/utsrelease.h" \
 327                                     "include/linux/utsrelease.h" \
 328                                     "include/linux/version.h" \
 329                                     "include/linux/version-up.h"; do
 330                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
 331                          break 2
 332                        fi
 333                      done
 334                    done
 335                  fi
 336                  if test "x$with_linux_kernel_build" != "x"; then
 337                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 338                  else
 339                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 340                  fi
 341                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 342                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 343                    LINUX_VERSION="$linux_kvers"
 344                  else
 345                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 346                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 347                      LINUX_VERSION="$linux_kvers"
 348                    else
 349                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 350                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 351                        if test "x$linux_kvers" = "x"; then
 352                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 353                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 354                            if test "x$linux_kvers" = "x"; then
 355                              AC_MSG_ERROR(Linux headers lack version definition [2])
 356                              exit 1
 357                            else
 358                              LINUX_VERSION="$linux_kvers"
 359                            fi
 360                          else
 361                            AC_MSG_ERROR(Linux headers lack version definition)
 362                            exit 1
 363                          fi
 364                        else
 365                          LINUX_VERSION="$linux_kvers"
 366                        fi
 367                      else
 368                        enable_kernel_module="no"
 369                      fi
 370                    fi
 371                  fi
 372                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 373                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 374                      enable_kernel_module="no"
 375                  fi
 376                  if test "x$enable_kernel_module" = "xno"; then
 377                   if test "x$with_linux_kernel_headers" != "x"; then
 378                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 379                    exit 1
 380                   else
 381                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 382                   fi
 383                  fi
 384                  dnl do we need to determine SUBARCH from autoconf.h
 385                  SUBARCH=default
 386                 fi
 387                 AC_MSG_RESULT(linux)
 388                 if test "x$enable_kernel_module" = "xyes"; then
 389                  case "$LINUX_VERSION" in
 390                   2.2.*) AFS_SYSKVERS=22 ;;
 391                   2.4.*) AFS_SYSKVERS=24 ;;
 392                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
 393                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 394                  esac
 395                 fi
 396                 ;;
 397         *-solaris*)
 398                 MKAFS_OSTYPE=SOLARIS
 399                 AC_MSG_RESULT(sun4)
 400                 AC_PATH_PROG(SOLARISCC, [cc], ,
 401                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 402                 if test "x$SOLARISCC" = "x" ; then
 403                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 404                 fi
 405                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 406                 SOLARIS_FS_HAS_FS_ROLLED
 407                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 408                 SOLARIS_HAVE_VN_RENAMEPATH
 409                 ;;
 410         *-sunos*)
 411                 MKAFS_OSTYPE=SUNOS
 412                 enable_kernel_module=no
 413                 AC_MSG_RESULT(sun4)
 414                 ;;
 415         *-hpux*)
 416                 MKAFS_OSTYPE=HPUX
 417                 AC_MSG_RESULT(hp_ux)
 418                 if test -f "/usr/old/usr/include/ndir.h"; then
 419                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 420                 fi
 421                 ;;
 422         *-irix*)
 423                 if test -d /usr/include/sys/SN/SN1; then
 424                  IRIX_BUILD_IP35="IP35"
 425                 fi
 426                 MKAFS_OSTYPE=IRIX
 427                 AC_MSG_RESULT(sgi)
 428                 ;;
 429         *-aix*)
 430                 MKAFS_OSTYPE=AIX
 431                 AC_MSG_RESULT(rs_aix)
 432                 ;;
 433         arm-*-darwin*)
 434                 MKAFS_OSTYPE=DARWIN
 435                 AC_MSG_RESULT(arm_darwin)
 436                 ;;
 437         powerpc-*-darwin*)
 438                 MKAFS_OSTYPE=DARWIN
 439                 AC_MSG_RESULT(ppc_darwin)
 440                 ;;
 441         i386-*-darwin*)
 442                 MKAFS_OSTYPE=DARWIN
 443                 AC_MSG_RESULT(x86_darwin)
 444                 ;;
 445         x86_64-*-darwin*)
 446                 MKAFS_OSTYPE=DARWIN
 447                 AC_MSG_RESULT(x86_darwin)
 448                 ;;
 449         i386-*-freebsd*)
 450                 MKAFS_OSTYPE=FBSD
 451                 AC_MSG_RESULT(i386_fbsd)
 452                 ;;
 453         x86_64-*-freebsd*)
 454                 MKAFS_OSTYPE=FBSD
 455                 AC_MSG_RESULT(amd64_fbsd)
 456                 ;;
 457         *-netbsd*)
 458                 MKAFS_OSTYPE=NBSD
 459                 AC_MSG_RESULT(nbsd)
 460                 ;;
 461         x86_64-*-openbsd*)
 462                 MKAFS_OSTYPE=OBSD
 463                 AC_MSG_RESULT(amd64_obsd)
 464                 ;;
 465         i386-*-openbsd*)
 466                 MKAFS_OSTYPE=OBSD
 467                 AC_MSG_RESULT(i386_obsd)
 468                 ;;
 469         *-dragonfly*)
 470                 MKAFS_OSTYPE=DFBSD
 471                 AC_MSG_RESULT(i386_dfbsd)
 472                 ;;
 473         *)
 474                 AC_MSG_RESULT($system)
 475                 ;;
 476 esac
 477
 478 if test "x$with_afs_sysname" != "x"; then
 479         AFS_SYSNAME="$with_afs_sysname"
 480 else
 481         AC_MSG_CHECKING(your AFS sysname)
 482         case $host in
 483                 i?86-*-openbsd?.?)
 484                         v=${host#*openbsd}
 485                         vM=${v%.*}
 486                         vm=${v#*.}
 487                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 488                         ;;
 489                 sparc64-*-openbsd?.?)
 490                         v=${host#*openbsd}
 491                         vM=${v%.*}
 492                         vm=${v#*.}
 493                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 494                         ;;
 495                 x86_64-*-openbsd?.?)
 496                         v=${host#*openbsd}
 497                         vM=${v%.*}
 498                         vm=${v#*.}
 499                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 500                         ;;
 501                 i?86-*-freebsd*.*)
 502                         v=${host#*freebsd}
 503                         vM=${v%.*}
 504                         vm=${v#*.}
 505                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 506                         ;;
 507                 x86_64-*-freebsd*.*)
 508                         v=${host#*freebsd}
 509                         vM=${v%.*}
 510                         vm=${v#*.}
 511                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 512                         ;;
 513                 i386-*-dragonfly?.*)
 514                         v=${host#*dragonfly}
 515                         vM=${v%.*}
 516                         vm=${v#*.}
 517                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 518                         ;;
 519                 i?86-*-netbsd*1.6[[M-Z]]*)
 520                         AFS_SYSNAME="i386_nbsd20"
 521                         ;;
 522                 powerpc-*-netbsd*1.6[[M-Z]]*)
 523                         AFS_SYSNAME="ppc_nbsd20"
 524                         ;;
 525                 *-*-netbsd*)
 526                         arch=${host%%-unknown*}
 527                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 528                                                -e 's/powerpc/ppc/g')
 529                         v=${host#*netbsd}
 530                         v=${v#*aout}
 531                         v=${v#*ecoff}
 532                         v=${v#*elf}
 533                         vM=${v%%.*}
 534                         vM=${vM%.*}
 535                         v=${v#*.}
 536                         vm=${v%%.*}
 537                         vm=${vm%.*}
 538                         vm=${vm%%[[_A-Z]]*}
 539                         if test $vm -eq 99 ; then
 540                                 vM=$((vM+1))
 541                         fi
 542                         if test $vM -gt 1 ; then
 543                                 vm=0
 544                         fi
 545                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 546                         ;;
 547                 hppa*-hp-hpux11.0*)
 548                         AFS_SYSNAME="hp_ux110"
 549                         ;;
 550                 hppa*-hp-hpux11.11)
 551                         AFS_SYSNAME="hp_ux11i"
 552                         ;;
 553                 hppa*-hp-hpux11.23)
 554                         AFS_SYSNAME="hp_ux1123"
 555                         ;;
 556                 ia64-hp-hpux11.22)
 557                         AFS_SYSNAME="ia64_hpux1122"
 558                         ;;
 559                 ia64-hp-hpux*)
 560                         AFS_SYSNAME="ia64_hpux1123"
 561                         ;;
 562                 hppa*-hp-hpux10*)
 563                         AFS_SYSNAME="hp_ux102"
 564                         ;;
 565                 powerpc-apple-darwin7*)
 566                         AFS_SYSNAME="ppc_darwin_70"
 567                         OSXSDK="macosx10.3"
 568                         ;;
 569                 powerpc-apple-darwin8.*)
 570                         AFS_SYSNAME="ppc_darwin_80"
 571                         OSXSDK="macosx10.4"
 572                         ;;
 573                 i386-apple-darwin8.*)
 574                         AFS_SYSNAME="x86_darwin_80"
 575                         OSXSDK="macosx10.4"
 576                         ;;
 577                 powerpc-apple-darwin9.*)
 578                         AFS_SYSNAME="ppc_darwin_90"
 579                         OSXSDK="macosx10.5"
 580                         ;;
 581                 i386-apple-darwin9.*)
 582                         AFS_SYSNAME="x86_darwin_90"
 583                         OSXSDK="macosx10.5"
 584                         ;;
 585                 i?86-apple-darwin10.*)
 586                         AFS_SYSNAME="x86_darwin_100"
 587                         OSXSDK="macosx10.6"
 588                         ;;
 589                 x86_64-apple-darwin10.*)
 590                         AFS_SYSNAME="x86_darwin_100"
 591                         OSXSDK="macosx10.6"
 592                         ;;
 593                 arm-apple-darwin10.*)
 594                         AFS_SYSNAME="arm_darwin_100"
 595                         OSXSDK="iphoneos4.0"
 596                         ;;
 597                 x86_64-apple-darwin11.*)
 598                         AFS_SYSNAME="x86_darwin_110"
 599                         OSXSDK="macosx10.7"
 600                         ;;
 601                 i?86-apple-darwin11.*)
 602                         AFS_SYSNAME="x86_darwin_110"
 603                         OSXSDK="macosx10.7"
 604                         ;;
 605                 x86_64-apple-darwin12.*)
 606                         AFS_SYSNAME="x86_darwin_120"
 607                         OSXSDK="macosx10.8"
 608                         ;;
 609                 i?86-apple-darwin12.*)
 610                         AFS_SYSNAME="x86_darwin_120"
 611                         OSXSDK="macosx10.8"
 612                         ;;
 613                 sparc-sun-solaris2.8)
 614                         AFS_SYSNAME="sun4x_58"
 615                         ;;
 616                 sparc-sun-solaris2.9)
 617                         AFS_SYSNAME="sun4x_59"
 618                         ;;
 619                 sparc-sun-solaris2.10)
 620                         AFS_SYSNAME="sun4x_510"
 621                         ;;
 622                 sparc-sun-solaris2.11)
 623                         AFS_SYSNAME="sun4x_511"
 624                         ;;
 625                 i386-pc-solaris2.8)
 626                         AFS_SYSNAME="sunx86_58"
 627                         ;;
 628                 i386-pc-solaris2.9)
 629                         AFS_SYSNAME="sunx86_59"
 630                         ;;
 631                 i386-pc-solaris2.10)
 632                         AFS_SYSNAME="sunx86_510"
 633                         ;;
 634                 i386-pc-solaris2.11)
 635                         AFS_SYSNAME="sunx86_511"
 636                         ;;
 637                 alpha*-dec-osf4.0*)
 638                         AFS_SYSNAME="alpha_dux40"
 639                         ;;
 640                 alpha*-dec-osf5.0*)
 641                         AFS_SYSNAME="alpha_dux50"
 642                         ;;
 643                 alpha*-dec-osf5.1*)
 644                         AFS_SYSNAME="alpha_dux51"
 645                         ;;
 646                 mips-sgi-irix6.5)
 647                         AFS_SYSNAME="sgi_65"
 648                         ;;
 649                 ia64-*-linux*)
 650                         AFS_SYSNAME="ia64_linuxXX"
 651                         ;;
 652                 powerpc-*-linux*)
 653                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 654                         ;;
 655                 powerpc64-*-linux*)
 656                         AFS_SYSNAME="ppc64_linuxXX"
 657                         ;;
 658                 alpha*-linux*)
 659                         AFS_SYSNAME="alpha_linux_XX"
 660                         ;;
 661                 s390-*-linux*)
 662                         AFS_SYSNAME="s390_linuxXX"
 663                         ;;
 664                 s390x-*-linux*)
 665                         AFS_SYSNAME="s390x_linuxXX"
 666                         ;;
 667                 sparc-*-linux*)
 668                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 669                         ;;
 670                 sparc64-*-linux*)
 671                         AFS_SYSNAME="sparc64_linuxXX"
 672                         ;;
 673                 i?86-*-linux*)
 674                         AFS_SYSNAME="i386_linuxXX"
 675                         ;;
 676                 arm*-linux*)
 677                         AFS_SYSNAME="arm_linuxXX"
 678                         ;;
 679                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 680                         AFS_SYSNAME="parisc_linuxXX"
 681                         enable_pam="no"
 682                         ;;
 683                 power*-ibm-aix4.2*)
 684                         AFS_SYSNAME="rs_aix42"
 685                         enable_pam="no"
 686                         ;;
 687                 power*-ibm-aix4.3*)
 688                         AFS_SYSNAME="rs_aix42"
 689                         enable_pam="no"
 690                         ;;
 691                 power*-ibm-aix5.1*)
 692                         AFS_SYSNAME="rs_aix51"
 693                         enable_pam="no"
 694                         ;;
 695                 power*-ibm-aix5.2*)
 696                         AFS_SYSNAME="rs_aix52"
 697                         enable_pam="no"
 698                         ;;
 699                 power*-ibm-aix5.3*)
 700                         AFS_SYSNAME="rs_aix53"
 701                         enable_pam="no"
 702                         ;;
 703                 power*-ibm-aix6.1*)
 704                         AFS_SYSNAME="rs_aix61"
 705                         enable_pam="no"
 706                         ;;
 707                 x86_64-*-linux-gnu)
 708                         AFS_SYSNAME="amd64_linuxXX"
 709                         enable_pam="yes"
 710                         ;;
 711                 *)
 712                         AC_MSG_ERROR(An AFS sysname is required)
 713                         exit 1
 714                         ;;
 715         esac
 716         case $AFS_SYSNAME in
 717                 *_linux* | *_umlinux*)
 718                         if test "x${AFS_SYSKVERS}" = "x"; then
 719                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 720                         fi
 721                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 722                         AFS_SYSNAME="$_AFS_SYSNAME"
 723                         AC_TRY_KBUILD(
 724                          [],
 725                          [#ifndef CONFIG_USERMODE
 726                           #error not UML
 727                           #endif],
 728                          ac_cv_linux_is_uml=yes,)
 729                         if test "${ac_cv_linux_is_uml}" = yes; then
 730                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 731                         fi
 732                         AFS_SYSNAME="$_AFS_SYSNAME"
 733                         ;;
 734         esac
 735         AC_MSG_RESULT($AFS_SYSNAME)
 736 fi
 737
 738 case $AFS_SYSNAME in
 739         *_darwin*)
 740                 AC_CHECK_HEADERS(crt_externs.h)
 741                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 742                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 743                 AC_SUBST(OSXSDK)
 744                 ;;
 745 esac
 746
 747 dnl Some hosts have a separate common param file they should include.  Figure
 748 dnl out if we're on one of them now that we know the sysname.
 749 case $AFS_SYSNAME in
 750     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 751     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 752     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 753     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 754     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 755     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 756     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 757     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 758     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
 759     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 760     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 761     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 762     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 763     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 764     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 765     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 766     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 767     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 768     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 769     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 770     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 771     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 772     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 773     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 774     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 775     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 776     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 777     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
 778     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
 779     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
 780     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
 781     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
 782     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 783     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 784     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 785 # Linux alpha adds an extra underscore for no good reason.
 786     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 787     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 788     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 789 esac
 790
 791 OPENAFS_OSCONF
 792
 793 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 794
 795                 # Add (sub-) architecture-specific paths needed by conftests
 796                 case $AFS_SYSNAME  in
 797                         *_umlinux26)
 798                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 799                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 800                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 801                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 802                 esac
 803
 804                 if test "x$enable_kernel_module" = "xyes"; then
 805                  if test "x$enable_debug_kernel" = "xno"; then
 806                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 807                  fi
 808                  OPENAFS_GCC_SUPPORTS_MARCH
 809                  AC_SUBST(P5PLUS_KOPTS)
 810                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 811                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 812                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 813                  OPENAFS_GCC_SUPPORTS_PIPE
 814                  AC_SUBST(LINUX_GCC_KOPTS)
 815
 816                  dnl Setup the kernel build environment
 817                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 818                  LINUX_KERNEL_COMPILE_WORKS
 819
 820                  dnl Check for header files
 821                  AC_CHECK_LINUX_HEADER([config.h])
 822                  AC_CHECK_LINUX_HEADER([completion.h])
 823                  AC_CHECK_LINUX_HEADER([exportfs.h])
 824                  AC_CHECK_LINUX_HEADER([freezer.h])
 825                  AC_CHECK_LINUX_HEADER([key-type.h])
 826                  AC_CHECK_LINUX_HEADER([semaphore.h])
 827                  AC_CHECK_LINUX_HEADER([seq_file.h])
 828
 829                  dnl Type existence checks
 830                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 831                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
 832
 833                  dnl Check for structure elements
 834                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 835                                        [write_begin], [fs.h])
 836                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 837                                        [backing-dev.h])
 838                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
 839                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 840                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 841                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 842                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 843                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 844                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 845                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 846                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 847                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
 848                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 849                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 850                  AC_CHECK_LINUX_STRUCT([filename], [name], [fs.h])
 851                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
 852                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
 853                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
 854                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 855                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 856                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 857                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 858                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 859                                        [fs.h])
 860                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 861                                        [fs.h])
 862                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 863                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 864                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 865                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 866                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 867                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 868                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 869                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 870                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 871                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 872                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 873
 874                  dnl Check for typed structure elements
 875                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 876                                              [buf], [fs.h])
 877
 878                  dnl Function existence checks
 879
 880                  AC_CHECK_LINUX_FUNC([bdi_init],
 881                                      [#include <linux/backing-dev.h>],
 882                                      [bdi_init(NULL);])
 883                  AC_CHECK_LINUX_FUNC([PageChecked],
 884                                      [#include <linux/mm.h>
 885 #include <linux/page-flags.h>],
 886                                      [struct page *_page;
 887                                       int bchecked = PageChecked(_page);])
 888                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 889                                      [#include <linux/mm.h>
 890 #include <linux/page-flags.h>],
 891                                      [struct page *_page;
 892                                       int bchecked = PageFsMisc(_page);])
 893                  AC_CHECK_LINUX_FUNC([clear_inode],
 894                                      [#include <linux/fs.h>],
 895                                      [clear_inode(NULL);])
 896                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 897                                      [#include <linux/time.h>],
 898                                      [struct timespec s;
 899                                       s = current_kernel_time();])
 900                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 901                                      [#include <linux/fs.h>],
 902                                      [d_alloc_anon(NULL);])
 903                  AC_CHECK_LINUX_FUNC([d_count],
 904                                      [#include <linux/dcache.h>],
 905                                      [d_count(NULL);])
 906                  AC_CHECK_LINUX_FUNC([d_make_root],
 907                                      [#include <linux/fs.h>],
 908                                      [d_make_root(NULL);])
 909                  AC_CHECK_LINUX_FUNC([do_sync_read],
 910                                      [#include <linux/fs.h>],
 911                                      [do_sync_read(NULL, NULL, 0, NULL);])
 912                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 913                                      [#include <linux/sched.h>],
 914                                      [pid_t p; find_task_by_pid(p);])
 915                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 916                                      [#include <linux/fs.h>],
 917                                      [generic_file_aio_read(NULL,NULL,0,0);])
 918                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 919                                      [#include <linux/pagemap.h>],
 920                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 921                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 922                                      [#include <linux/list.h>],
 923                                      [hlist_unhashed(0);])
 924                  AC_CHECK_LINUX_FUNC([i_size_read],
 925                                      [#include <linux/fs.h>],
 926                                      [i_size_read(NULL);])
 927                  AC_CHECK_LINUX_FUNC([inode_setattr],
 928                                      [#include <linux/fs.h>],
 929                                      [inode_setattr(NULL, NULL);])
 930                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
 931                                      [#include <linux/net.h>],
 932                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
 933                  AC_CHECK_LINUX_FUNC([page_follow_link],
 934                                      [#include <linux/fs.h>],
 935                                      [page_follow_link(0,0);])
 936                  AC_CHECK_LINUX_FUNC([page_offset],
 937                                      [#include <linux/pagemap.h>],
 938                                      [page_offset(NULL);])
 939                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
 940                                      [#include <linux/pagevec.h>],
 941                                      [__pagevec_lru_add_file(NULL);])
 942                  AC_CHECK_LINUX_FUNC([path_lookup],
 943                                      [#include <linux/fs.h>
 944                                       #include <linux/namei.h>],
 945                                      [path_lookup(NULL, 0, NULL);])
 946                  AC_CHECK_LINUX_FUNC([proc_create],
 947                                      [#include <linux/proc_fs.h>],
 948                                      [proc_create(NULL, 0, NULL, NULL);])
 949                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
 950                                      [#include <linux/rcupdate.h>],
 951                                      [rcu_read_lock();])
 952                  AC_CHECK_LINUX_FUNC([set_nlink],
 953                                      [#include <linux/fs.h>],
 954                                      [set_nlink(NULL, 1);])
 955                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
 956                                      [#include <linux/splice.h>],
 957                                      [splice_direct_to_actor(NULL,NULL,NULL);])
 958                  AC_CHECK_LINUX_FUNC([svc_addr_in],
 959                                      [#include <linux/sunrpc/svc.h>],
 960                                      [svc_addr_in(NULL);])
 961                  AC_CHECK_LINUX_FUNC([zero_user_segments],
 962                                      [#include <linux/highmem.h>],
 963                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
 964                  AC_CHECK_LINUX_FUNC([noop_fsync],
 965                                      [#include <linux/fs.h>],
 966                                      [void *address = &noop_fsync; printk("%p\n", address)];)
 967                  AC_CHECK_LINUX_FUNC([kthread_run],
 968                                      [#include <linux/kernel.h>
 969                                       #include <linux/kthread.h>],
 970                                      [kthread_run(NULL, NULL, "test");])
 971
 972                  dnl Consequences - things which get set as a result of the
 973                  dnl                above tests
 974                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
 975                        [AC_DEFINE([AFS_NONFSTRANS], 1,
 976                                   [define to disable the nfs translator])])
 977
 978                  dnl Assorted more complex tests
 979                  LINUX_AIO_NONVECTOR
 980                  LINUX_EXPORTS_PROC_ROOT_FS
 981                  LINUX_KMEM_CACHE_INIT
 982                  LINUX_HAVE_KMEM_CACHE_T
 983                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
 984                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
 985                  LINUX_D_PATH_TAKES_STRUCT_PATH
 986                  LINUX_NEW_EXPORT_OPS
 987                  LINUX_INODE_SETATTR_RETURN_TYPE
 988                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
 989                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
 990                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
 991                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
 992                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
 993                  LINUX_DOP_D_DELETE_TAKES_CONST
 994                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
 995                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
 996                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
 997                  LINUX_FOP_F_FSYNC_TAKES_RANGE
 998                  LINUX_AOP_WRITEBACK_CONTROL
 999                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1000                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1001                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1002                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1003                  LINUX_KERNEL_SOCK_CREATE
1004                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1005                  LINUX_NEED_RHCONFIG
1006                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1007                  LINUX_EXPORTS_TASKLIST_LOCK
1008                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1009                  LINUX_STATFS_TAKES_DENTRY
1010                  LINUX_REFRIGERATOR
1011                  LINUX_HAVE_TRY_TO_FREEZE
1012                  LINUX_LINUX_KEYRING_SUPPORT
1013                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1014                  LINUX_KEY_ALLOC_NEEDS_CRED
1015                  LINUX_STRUCT_KEY_UID_IS_KUID_T
1016                  LINUX_INIT_WORK_HAS_DATA
1017                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1018                  LINUX_HAVE_DCACHE_LOCK
1019                  LINUX_D_COUNT_IS_INT
1020                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1021                  LINUX_IOP_CREATE_TAKES_UMODE_T
1022                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1023                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1024                  LINUX_DENTRY_OPEN_TAKES_PATH
1025                  LINUX_D_ALIAS_IS_HLIST
1026                  LINUX_HLIST_ITERATOR_NO_NODE
1027                  LINUX_IOP_I_CREATE_TAKES_BOOL
1028                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1029                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1030
1031                  dnl If we are guaranteed that keyrings will work - that is
1032                  dnl  a) The kernel has keyrings enabled
1033                  dnl  b) The code is new enough to give us a key_type_keyring
1034                  dnl then we just disable syscall probing unless we've been
1035                  dnl told otherwise
1036
1037                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1038                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1039                           [enable_linux_syscall_probing="no"],
1040                           [enable_linux_syscall_probing="yes"])
1041                  ])
1042
1043                  dnl Syscall probing needs a few tests of its own, and just
1044                  dnl won't work if the kernel doesn't export init_mm
1045                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1046                    LINUX_EXPORTS_INIT_MM
1047                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1048                      AC_MSG_ERROR(
1049                        [Can't do syscall probing without exported init_mm])
1050                    ])
1051                    LINUX_EXPORTS_SYS_CHDIR
1052                    LINUX_EXPORTS_SYS_OPEN
1053                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1054                              [define to enable syscall table probes])
1055                  ])
1056
1057                  dnl Packaging and SMP build
1058                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1059                    LINUX_WHICH_MODULES
1060                  else
1061                    AC_SUBST(MPS,'SP')
1062                  fi
1063
1064                  dnl Syscall probing
1065                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1066                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1067                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1068                    ])
1069                    ac_cv_linux_exports_sys_call_table=no
1070                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1071                      ac_cv_linux_exports_ia32_sys_call_table=yes
1072                    fi
1073                  else
1074                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1075                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1076                    LINUX_EXPORTS_SYS_CALL_TABLE
1077                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1078                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1079                          linux_syscall_method=none
1080                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1081                             linux_syscall_method=scan
1082                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1083                                linux_syscall_method=scan_with_kallsyms_address
1084                             fi
1085                          fi
1086                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1087                             linux_syscall_method=kallsyms_symbol
1088                          fi
1089                          if test "x$linux_syscall_method" = "xnone"; then
1090                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1091                             linux_syscall_method=scan
1092                          fi
1093                    fi
1094                  fi
1095                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1096                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1097                  fi
1098                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1099                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1100                  fi
1101                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1102                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1103                  else
1104                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1105                  fi
1106                 :
1107                 fi
1108 dnl Linux-only, but just enable always.
1109                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1110 esac
1111
1112 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1113     [ac_cv_sync_fetch_and_add],
1114     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1115                     [ac_cv_sync_fetch_and_add=yes],
1116                     [ac_cv_sync_fetch_and_add=no])
1117 ])
1118 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1119       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1120                 [define if your C compiler has __sync_add_and_fetch])])
1121
1122 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1123     [ac_cv_sockaddr_len],
1124     [AC_TRY_COMPILE( [#include <sys/types.h>
1125 #include <sys/socket.h>],
1126                      [struct sockaddr *a; a->sa_len=0;],
1127                      [ac_cv_sockaddr_len=yes],
1128                      [ac_cv_sockaddr_len=no])
1129 ])
1130 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1131       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1132                  [define if you struct sockaddr sa_len])])
1133
1134 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1135         echo Skipping library tests because they confuse Irix.
1136 else
1137   AC_SEARCH_LIBS([socket], [socket inet])
1138   AC_SEARCH_LIBS([connect], [nsl])
1139   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1140
1141   dnl darwin wants it, aix hates it
1142   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1143   AC_TRY_COMPILE([
1144   #include <stdlib.h>
1145   #include <stdio.h>
1146   #include <sys/types.h>
1147   #include <sys/socket.h>
1148   #include <netinet/in.h>
1149   #include <arpa/inet.h>
1150   #include <arpa/nameser.h>
1151   #include <arpa/nameser_compat.h>
1152   #include <resolv.h>
1153   ], [static int i; i = 0;],
1154   [AC_MSG_RESULT(yes)
1155    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1156   [AC_MSG_RESULT(no)
1157    ])
1158
1159   openafs_save_libs="$LIBS"
1160   AC_MSG_CHECKING([for res_search])
1161   AC_FUNC_RES_SEARCH
1162
1163   if test "$ac_cv_func_res_search" = no; then
1164       for lib in dns nsl resolv; do
1165         if test "$ac_cv_func_res_search" != yes; then
1166           LIBS="-l$lib $LIBS"
1167           AC_FUNC_RES_SEARCH
1168           LIBS="$openafs_save_libs"
1169         fi
1170       done
1171       if test "$ac_cv_func_res_search" = yes; then
1172         LIB_AFSDB="-l$lib"
1173         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1174         AC_MSG_RESULT([yes, in lib$lib])
1175       else
1176         AC_MSG_RESULT(no)
1177       fi
1178   else
1179     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1180     AC_MSG_RESULT(yes)
1181   fi
1182
1183 fi
1184 XLIBS="$LIB_AFSDB $XLIBS"
1185
1186 AC_CHECK_RESOLV_RETRANS
1187
1188 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1189     [ac_cv_setsockopt_iprecverr],
1190     [AC_TRY_COMPILE( [
1191 #include <sys/types.h>
1192 #include <sys/socket.h>
1193 #include <netinet/in.h>],
1194 [int on=1;
1195 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1196         [ac_cv_setsockopt_iprecverr=yes],
1197         [ac_cv_setsockopt_iprecverr=no])])
1198
1199 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1200       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1201                  [define if we can receive socket errors via IP_RECVERR])])
1202
1203 PTHREAD_LIBS=error
1204 if test "x$MKAFS_OSTYPE" = OBSD; then
1205         PTHREAD_LIBS="-pthread"
1206 fi
1207 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1208         PTHREAD_LIBS="-pthread"
1209 fi
1210 if test "x$PTHREAD_LIBS" = xerror; then
1211         AC_CHECK_LIB(pthread, pthread_attr_init,
1212                 PTHREAD_LIBS="-lpthread")
1213 fi
1214 if test "x$PTHREAD_LIBS" = xerror; then
1215         AC_CHECK_LIB(pthreads, pthread_attr_init,
1216                 PTHREAD_LIBS="-lpthreads")
1217 fi
1218 if test "x$PTHREAD_LIBS" = xerror; then
1219         AC_CHECK_LIB(c_r, pthread_attr_init,
1220                 PTHREAD_LIBS="-lc_r")
1221 fi
1222 if test "x$PTHREAD_LIBS" = xerror; then
1223         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1224 fi
1225 if test "x$PTHREAD_LIBS" = xerror; then
1226         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1227         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1228                 PTHREAD_LIBS="-lpthread")
1229 fi
1230 if test "x$PTHREAD_LIBS" = xerror; then
1231         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1232 fi
1233 AC_SUBST(PTHREAD_LIBS)
1234
1235 HOST_CPU="$host_cpu"
1236
1237 if test "x$with_bsd_kernel_headers" != "x"; then
1238         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1239 else
1240         BSD_KERNEL_PATH="/usr/src/sys"
1241 fi
1242
1243 if test "x$with_bsd_kernel_build" != "x"; then
1244         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1245 else
1246         case $AFS_SYSNAME in
1247                 *_fbsd_*)
1248                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1249                         ;;
1250                 *_nbsd*)
1251                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1252         esac
1253 fi
1254
1255 # Fast restart
1256 if test "$enable_supergroups" = "yes"; then
1257         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1258 fi
1259
1260 if test "$enable_bitmap_later" = "yes"; then
1261         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1262 fi
1263
1264 if test "$enable_unix_sockets" = "yes"; then
1265         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1266         USE_UNIX_SOCKETS="yes"
1267 else
1268         USE_UNIX_SOCKETS="no"
1269 fi
1270 AC_SUBST(USE_UNIX_SOCKETS)
1271
1272 if test "$enable_namei_fileserver" = "yes"; then
1273         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1274         VFSCK=""
1275 else
1276         if test "$enable_namei_fileserver" = "default"; then
1277                 case $host in
1278                         *-solaris2.10*)
1279                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1280                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1281                                 VFSCK=""
1282                                 ;;
1283                         *-solaris2.11*)
1284                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1285                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1286                                 VFSCK=""
1287                                 ;;
1288                         *)
1289                                 VFSCK="vfsck"
1290                                 ;;
1291                 esac
1292         else
1293                 VFSCK="vfsck"
1294         fi
1295 fi
1296
1297 dnl check for tivoli
1298 AC_MSG_CHECKING(for tivoli tsm butc support)
1299 XBSA_CFLAGS=""
1300 if test "$enable_tivoli_tsm" = "yes"; then
1301         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1302         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1303         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1304         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1305
1306         if test -r "$XBSADIR3/dsmapifp.h"; then
1307                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1308                 XBSA_XLIBS="-ldl"
1309                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1310         elif test -r "$XBSADIR4/dsmapifp.h"; then
1311                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1312                 XBSA_XLIBS="-ldl"
1313                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1314         elif test -r "$XBSADIR1/xbsa.h"; then
1315                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1316                 XBSA_XLIBS=""
1317                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1318         elif test -r "$XBSADIR2/xbsa.h"; then
1319                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1320                 XBSA_XLIBS=""
1321                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1322         else
1323                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1324         fi
1325 else
1326         AC_MSG_RESULT([no])
1327 fi
1328 AC_SUBST(XBSA_CFLAGS)
1329 AC_SUBST(XBSA_XLIBS)
1330
1331 dnl checks for header files.
1332 AC_HEADER_STDC
1333 AC_HEADER_SYS_WAIT
1334 AC_HEADER_DIRENT
1335 AC_CHECK_HEADERS([ \
1336                    arpa/inet.h \
1337                    arpa/nameser.h \
1338                    curses.h\
1339                    direct.h \
1340                    errno.h \
1341                    fcntl.h \
1342                    grp.h \
1343                    math.h \
1344                    mntent.h \
1345                    ncurses.h \
1346                    ncurses/ncurses.h \
1347                    netdb.h \
1348                    netinet/in.h \
1349                    pthread_np.h \
1350                    pwd.h \
1351                    regex.h \
1352                    security/pam_appl.h \
1353                    signal.h \
1354                    stdint.h \
1355                    stdio_ext.h \
1356                    stdlib.h \
1357                    string.h \
1358                    strings.h \
1359                    sys/bitypes.h \
1360                    sys/bswap.h \
1361                    sys/dk.h \
1362                    sys/fcntl.h \
1363                    sys/file.h \
1364                    sys/fs_types.h \
1365                    sys/fstyp.h \
1366                    sys/ioctl.h \
1367                    sys/ipc.h \
1368                    sys/lockf.h \
1369                    sys/map.h \
1370                    sys/mount.h \
1371                    sys/mntent.h \
1372                    sys/mnttab.h \
1373                    sys/pag.h \
1374                    sys/param.h \
1375                    sys/resource.h \
1376                    sys/select.h \
1377                    sys/statfs.h \
1378                    sys/statvfs.h \
1379                    sys/socket.h \
1380                    sys/sysctl.h \
1381                    sys/time.h \
1382                    sys/types.h \
1383                    sys/uio.h \
1384                    sys/un.h \
1385                    sys/vfs.h \
1386                    syslog.h \
1387                    termios.h \
1388                    time.h \
1389                    ucontext.h \
1390                    unistd.h \
1391                    windows.h \
1392                 ])
1393
1394 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1395 #ifdef HAVE_NETINET_IN_H
1396 # include <netinet/in.h>
1397 #endif])
1398
1399 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1400 #ifdef HAVE_SYS_SOCKET_H
1401 # include <sys/socket.h>
1402 #endif])
1403
1404 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1405 #ifdef HAVE_SYS_SOCKET_H
1406 # include <sys/socket.h>
1407 #endif
1408 #ifdef HAVE_NETINET_IN_H
1409 # include <netinet/in.h>
1410 #endif
1411 #ifdef HAVE_NET_IF_H
1412 # include <net/if.h>
1413 #endif])
1414
1415 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1416 #ifdef HAVE_SECURITY_PAM_APPL_H
1417 # include <security/pam_appl.h>
1418 #endif])
1419
1420 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1421
1422 AC_CHECK_TYPES([fsblkcnt_t],,,[
1423 #include <sys/types.h>
1424 #ifdef HAVE_SYS_BITYPES_H
1425 #include <sys/bitypes.h>
1426 #endif
1427 #ifdef HAVE_SYS_STATFS_H
1428 #include <sys/statfs.h>
1429 #endif
1430 #ifdef HAVE_SYS_STATVFS_H
1431 #include <sys/statvfs.h>
1432 #endif
1433 ])
1434
1435 dnl see what struct stat has for timestamps
1436 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1437
1438 dnl check for curses-lib
1439 AS_IF([test "x$enable_gtx" != "xno"],
1440       [save_LIBS=$LIBS
1441       AC_CHECK_LIB( [ncurses], [setupterm],
1442       [LIB_curses=-lncurses],
1443         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1444           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1445       ])
1446       LIBS=$save_LIBS
1447       AC_SUBST(LIB_curses)])
1448
1449 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1450
1451 if test "$enable_debug_locks" = yes; then
1452         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1453 fi
1454
1455 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1456 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1457         case $AFS_SYSNAME in
1458         sgi_*)
1459                 HAVE_PAM="no"
1460                 ;;
1461         *)
1462                 HAVE_PAM="yes"
1463                 ;;
1464         esac
1465 else
1466         HAVE_PAM="no"
1467 fi
1468 AC_SUBST(HAVE_PAM)
1469
1470 if test "$enable_login" = yes; then
1471         BUILD_LOGIN="yes"
1472 else
1473         BUILD_LOGIN="no"
1474 fi
1475 AC_SUBST(BUILD_LOGIN)
1476
1477 if test "$enable_uss" = yes; then
1478         BUILD_USS="yes"
1479 else
1480         BUILD_USS="no"
1481 fi
1482 AC_SUBST(BUILD_USS)
1483
1484 if test "$enable_kauth" = yes; then
1485         INSTALL_KAUTH="yes"
1486 else
1487         INSTALL_KAUTH="no"
1488 fi
1489 AC_SUBST(INSTALL_KAUTH)
1490
1491 AC_CHECK_FUNCS([ \
1492         arc4random \
1493         fcntl \
1494         fseeko64 \
1495         ftello64 \
1496         getcwd \
1497         getegid \
1498         geteuid \
1499         getgid \
1500         getuid \
1501         getrlimit \
1502         issetugid \
1503         mkstemp \
1504         poll \
1505         pread \
1506         preadv \
1507         preadv64 \
1508         pwrite \
1509         pwritev \
1510         pwritev64 \
1511         regcomp \
1512         regerror \
1513         regexec \
1514         setitimer \
1515         setvbuf \
1516         sigaction \
1517         strcasestr \
1518         strerror \
1519         sysconf \
1520         sysctl \
1521         tdestroy \
1522         timegm \
1523 ])
1524
1525 OPENAFS_ROKEN()
1526 OPENAFS_C_ATTRIBUTE()
1527
1528 dnl Functions that Heimdal's libroken provides, but that we
1529 dnl haven't found a need for yet, and so haven't imported
1530 AC_CHECK_FUNCS([ \
1531         chown \
1532         fchown \
1533         gethostname \
1534         lstat \
1535         inet_aton \
1536         inet_ntop \
1537         inet_pton \
1538         putenv \
1539         readv \
1540         setenv \
1541         strdup \
1542         strftime \
1543         strndup \
1544         strsep \
1545         unsetenv \
1546 ])
1547
1548 dnl Functions that are in objects that we always build from libroken
1549 AC_CHECK_FUNCS([ \
1550         asprintf \
1551         asnprintf \
1552         vasprintf \
1553         vasnprintf \
1554         vsnprintf \
1555         snprintf \
1556 ])
1557
1558 dnl Functions that we're going to try and get from libroken
1559 AC_REPLACE_FUNCS([ \
1560         daemon \
1561         ecalloc \
1562         emalloc \
1563         erealloc \
1564         err \
1565         errx \
1566         flock \
1567         getdtablesize \
1568         getopt \
1569         getprogname \
1570         gettimeofday \
1571         localtime_r \
1572         mkstemp \
1573         setenv \
1574         setprogname \
1575         strcasecmp \
1576         strlcat \
1577         strnlen \
1578         strlcpy \
1579         strsep \
1580         tdelete \
1581         tfind \
1582         tsearch \
1583         twalk \
1584         unsetenv \
1585         verr \
1586         verrx \
1587         vsyslog \
1588         vwarn \
1589         vwarnx \
1590         warn \
1591         warnx \
1592 ])
1593
1594 dnl Headers that we're going to try and get from libroken
1595 AC_CHECK_HEADERS([ \
1596         err.h \
1597         search.h \
1598 ])
1599
1600 AC_CHECK_DECLS([h_errno], [], [], [
1601 #include <sys/types.h>
1602 #ifdef HAVE_NETDB_H
1603 #include <netdb.h>
1604 #endif
1605 ])
1606
1607 AC_HEADER_TIME
1608
1609 ROKEN_HEADERS=
1610 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1611       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1612       [])
1613 AC_SUBST(ROKEN_HEADERS)
1614
1615 dnl Stuff that's harder ...
1616 AC_MSG_CHECKING([for bswap16])
1617 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1618 #ifdef HAVE_SYS_TYPES_H
1619 #include <sys/types.h>
1620 #endif
1621 #ifdef HAVE_SYS_BSWAP_H
1622 #include <sys/bswap.h>
1623 #endif
1624 ],
1625 [short a, b; b = bswap16(a); ])],
1626 [AC_MSG_RESULT(yes)
1627  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1628 ],
1629 [AC_MSG_RESULT(no)])
1630
1631 AC_MSG_CHECKING([for bswap32])
1632 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1633 #include <sys/types.h>
1634 #endif
1635 #ifdef HAVE_SYS_BSWAP_H
1636 #include <sys/bswap.h>
1637 #endif
1638 ],
1639 [int a, b; b = bswap32(a); ])],
1640 [AC_MSG_RESULT(yes)
1641  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1642 ],
1643 [AC_MSG_RESULT(no)])
1644
1645 case $AFS_SYSNAME in
1646 *hp_ux* | *hpux*)
1647    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1648    ;;
1649 *)
1650    AC_MSG_CHECKING([for positional I/O])
1651    if test "$ac_cv_func_pread" = "yes" && \
1652            test "$ac_cv_func_pwrite" = "yes"; then
1653       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1654       AC_MSG_RESULT(yes)
1655    else
1656      AC_MSG_RESULT(no)
1657    fi
1658    AC_MSG_CHECKING([for vectored positional I/O])
1659    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1660                "$ac_cv_func_pwritev" = "yes" -a \
1661                "$ac_cv_func_preadv64" = "yes" -a \
1662                "$ac_cv_func_pwritev64" = "yes"],
1663          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1664           AC_MSG_RESULT(yes)],
1665          [AC_MSG_RESULT(no)])
1666    ;;
1667 esac
1668
1669 AC_MSG_CHECKING([for POSIX regex library])
1670 if test "$ac_cv_header_regex_h" = "yes" && \
1671         test "$ac_cv_func_regcomp" = "yes" && \
1672         test "$ac_cv_func_regexec" = "yes" && \
1673         test "$ac_cv_func_regerror" = "yes"; then
1674     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1675     AC_MSG_RESULT(yes)
1676 else
1677     AC_MSG_RESULT(no)
1678 fi
1679
1680 dnl Look for "non-portable" pthreads functions.
1681 save_LIBS="$LIBS"
1682 LIBS="$LIBS $PTHREAD_LIBS"
1683 AC_CHECK_FUNCS([ \
1684         pthread_set_name_np \
1685         pthread_setname_np \
1686 ])
1687
1688 dnl Sadly, there are three different versions of pthread_setname_np.
1689 dnl Try to cater for all of them.
1690 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1691     AC_MSG_CHECKING([for signature of pthread_setname_np])
1692     AC_TRY_COMPILE([
1693 #include <pthread.h>
1694 #ifdef HAVE_PTHREAD_NP_H
1695 #include <pthread_np.h>
1696 #endif
1697 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1698         AC_MSG_RESULT([three arguments])
1699         pthread_setname_np_args=3], [
1700         AC_TRY_COMPILE([
1701 #include <pthread.h>
1702 #ifdef HAVE_PTHREAD_NP_H
1703 #include <pthread_np.h>
1704 #endif
1705 ], [pthread_setname_np(pthread_self(), "test")], [
1706             AC_MSG_RESULT([two arguments])
1707             pthread_setname_np_args=2], [
1708             AC_TRY_COMPILE([
1709 #include <pthread.h>
1710 #ifdef HAVE_PTHREAD_NP_H
1711 #include <pthread_np.h>
1712 #endif
1713 ], [pthread_setname_np("test")], [
1714                 AC_MSG_RESULT([one argument])
1715                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1716 ])
1717 ])
1718 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1719 fi
1720 LIBS="$save_LIBS"
1721
1722 openafs_cv_saved_CFLAGS="$CFLAGS"
1723 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1724
1725 AC_TYPE_SIGNAL
1726 OPENAFS_RETSIGTYPE
1727 AC_CHECK_SIZEOF(void *)
1728 AC_CHECK_SIZEOF(unsigned long long)
1729 AC_CHECK_SIZEOF(unsigned long)
1730 AC_CHECK_SIZEOF(unsigned int)
1731 AC_TYPE_INTPTR_T
1732 AC_TYPE_UINTPTR_T
1733 AC_TYPE_SSIZE_T
1734 AC_CHECK_TYPE([sig_atomic_t],[],
1735     [AC_DEFINE([sig_atomic_t], [int],
1736         [Define to int if <signal.h> does not define.])],
1737 [#include <sys/types.h>
1738 #include <signal.h>])
1739 AC_CHECK_TYPE([socklen_t],[],
1740     [AC_DEFINE([socklen_t], [int],
1741         [Define to int if <sys/socket.h> does not define.])],
1742 [#include <sys/types.h>
1743 #include <sys/socket.h>])
1744 AC_CHECK_TYPES(off64_t)
1745 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1746 AC_CHECK_TYPES([struct winsize], [], [], [
1747 #ifdef HAVE_TERMIOS_H
1748 # include <termios.h>
1749 #else
1750 # include <sys/termios.h>
1751 #endif
1752 #include <sys/ioctl.h>])
1753 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1754                 struct sockaddr_storage],
1755                [], [], [
1756 #include <sys/types.h>
1757 #include <sys/socket.h>
1758 ])
1759 AC_CHECK_TYPES([sa_family_t], [], [], [
1760 #include <sys/types.h>
1761 #include <sys/socket.h>
1762 ])
1763 AC_CHECK_TYPES([struct addrinfo], [], [], [
1764 #include <sys/types.h>
1765 #ifdef HAVE_NETDB_H
1766 #include <netdb.h>
1767 #endif
1768 ])
1769 AC_CHECK_TYPES([long long], [], [], [])
1770
1771 AC_SIZEOF_TYPE(long)
1772
1773 CFLAGS="$openafs_cv_saved_CFLAGS"
1774
1775 RRA_HEADER_PAM_CONST
1776
1777
1778 dnl Directory PATH handling
1779 if test "x$enable_transarc_paths" = "xyes"  ; then
1780     afsconfdir=${afsconfdir=/usr/afs/etc}
1781     viceetcdir=${viceetcdir=/usr/vice/etc}
1782     afskerneldir=${afskerneldir=${viceetcdir}}
1783     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1784     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1785     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1786     afsdbdir=${afsdbdir=/usr/afs/db}
1787     afslogsdir=${afslogsdir=/usr/afs/logs}
1788     afslocaldir=${afslocaldir=/usr/afs/local}
1789     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1790     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1791     afsdatadir=${afsdatadir=/usr/vice/etc}
1792 else
1793     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1794     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1795     afskerneldir=${afskerneldir='${libdir}/openafs'}
1796     afssrvbindir=${afssrvbindir='${bindir}'}
1797     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1798     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1799     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1800     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1801     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1802     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1803     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1804     afsdatadir=${afsdatadir='${datadir}/openafs'}
1805 fi
1806 AC_SUBST(afsconfdir)
1807 AC_SUBST(viceetcdir)
1808 AC_SUBST(afskerneldir)
1809 AC_SUBST(afssrvbindir)
1810 AC_SUBST(afssrvsbindir)
1811 AC_SUBST(afssrvlibexecdir)
1812 AC_SUBST(afsdbdir)
1813 AC_SUBST(afslogsdir)
1814 AC_SUBST(afslocaldir)
1815 AC_SUBST(afsbackupdir)
1816 AC_SUBST(afsbosconfigdir)
1817 AC_SUBST(afsdatadir)
1818
1819 if test "x$enable_kernel_module" = "xyes"; then
1820 ENABLE_KERNEL_MODULE=libafs
1821 fi
1822
1823 if test "x$enable_pthreaded_ubik" = "xyes"; then
1824 ENABLE_PTHREADED_UBIK=yes
1825 fi
1826
1827 AC_SUBST(VFSCK)
1828 AC_SUBST(AFS_SYSNAME)
1829 AC_SUBST(AFS_PARAM_COMMON)
1830 AC_SUBST(ENABLE_KERNEL_MODULE)
1831 AC_SUBST(ENABLE_PTHREADED_UBIK)
1832 AC_SUBST(LIB_AFSDB)
1833 AC_SUBST(LINUX_KERNEL_PATH)
1834 AC_SUBST(LINUX_KERNEL_BUILD)
1835 AC_SUBST(HOST_CPU)
1836 AC_SUBST(BSD_KERNEL_PATH)
1837 AC_SUBST(BSD_KERNEL_BUILD)
1838 AC_SUBST(LINUX_VERSION)
1839 AC_SUBST(MKAFS_OSTYPE)
1840 AC_SUBST(TOP_OBJDIR)
1841 AC_SUBST(TOP_SRCDIR)
1842 AC_SUBST(TOP_INCDIR)
1843 AC_SUBST(TOP_LIBDIR)
1844 AC_SUBST(DEST)
1845 AC_SUBST(DARWIN_INFOFILE)
1846 AC_SUBST(IRIX_BUILD_IP35)
1847 AC_SUBST(HTML_XSL)
1848 AC_SUBST(XSLTPROC)
1849 AC_SUBST(DOCBOOK2PDF)
1850 AC_SUBST(DOCBOOK_STYLESHEETS)
1851
1852 OPENAFS_FUSE
1853 OPENAFS_SWIG
1854
1855 TOP_SRCDIR="${srcdir}/src"
1856 dnl
1857 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1858 dnl
1859 case $TOP_SRCDIR in
1860         /*)
1861                 ;;
1862         *)
1863                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1864                 ;;
1865 esac
1866
1867 TOP_OBJDIR="${SRCDIR_PARENT}"
1868 TOP_INCDIR="${SRCDIR_PARENT}/include"
1869 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1870 if test "${DEST}x" = "x"; then
1871         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1872 fi
1873
1874 if test "x$with_crosstools_dir" != "x"; then
1875         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1876                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1877                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1878                 RXGEN_PATH=$with_crosstools_dir/rxgen
1879         else
1880                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1881                 exit 1
1882         fi
1883 else
1884         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1885         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1886         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1887 fi
1888 AC_SUBST(COMPILE_ET_PATH)
1889 AC_SUBST(CONFIGTOOL_PATH)
1890 AC_SUBST(RXGEN_PATH)
1891
1892 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1893 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1894 AC_SUBST(HELPER_SPLINT)
1895 AC_SUBST(HELPER_SPLINTCFG)
1896
1897 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1898
1899 dnl Check to see if crypt lives in a different library
1900 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1901 AC_SUBST(LIB_crypt)
1902
1903 dnl Check to see if the compiler support labels in structs
1904 AC_MSG_CHECKING(for label support in structs)
1905 AC_TRY_COMPILE([], [
1906 extern void osi_UFSOpen(void);
1907 struct labeltest {
1908    void (*open) (void);
1909 };
1910 struct labeltest struct_labeltest = {
1911    .open       = osi_UFSOpen,
1912 }
1913 ],
1914 [AC_MSG_RESULT(yes)
1915  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1916 ],
1917 [AC_MSG_RESULT(no)
1918 ])
1919
1920 AC_MSG_CHECKING([checking for dirfd])
1921 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1922 #ifdef HAVE_DIRENT_H
1923 #include <dirent.h>
1924 #endif
1925 ]],
1926         [[DIR *d = 0; dirfd(d);]])],
1927         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1928 if test "$ac_rk_have_dirfd" = "yes" ; then
1929         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1930 fi
1931 AC_MSG_RESULT($ac_rk_have_dirfd)
1932
1933 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1934 #ifdef HAVE_DIRENT_H
1935 #include <dirent.h>
1936 #endif])
1937
1938 dnl Eventually, this will look for the system one, or for OpenSSL
1939 LIB_hcrypto="-lafshcrypto"
1940 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1941 AC_SUBST(LIB_hcrypto)
1942 AC_SUBST(LDFLAGS_hcrypto)
1943
1944 dnl Check for UUID library
1945 AC_CHECK_HEADERS([uuid/uuid.h])
1946 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1947 AC_CHECK_FUNCS([uuid_generate])
1948 ])
1949
1950
1951 AC_DEFUN([SUMMARY], [
1952     # Print a configuration summary
1953 echo
1954 echo "**************************************"
1955 echo configure summary
1956 echo
1957 AS_IF([test $LIB_curses],[
1958 echo "LIB_curses :                $LIB_curses" ],[
1959 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1960 ])
1961 echo
1962 echo "**************************************"
1963 ])