acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #   define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 #define _FILE_OFFSET_BITS 64
  48 #define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 #include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
  76
  77 dnl General feature options.
  78 AC_ARG_ENABLE([pam],
  79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
  80     ,
  81     [enable_pam="yes"])
  82 AC_ARG_ENABLE([gtx],
  83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
  84 AC_ARG_ENABLE([uss],
  85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
  86 AC_ARG_ENABLE([namei-fileserver],
  87     [AS_HELP_STRING([--enable-namei-fileserver],
  88         [force compilation of namei fileserver in preference to inode
  89          fileserver])],
  90     ,
  91     [enable_namei_fileserver="default"])
  92 AC_ARG_ENABLE([supergroups],
  93     [AS_HELP_STRING([--enable-supergroups],
  94         [enable support for nested pts groups])],
  95     ,
  96     [enable_supergroups="no"])
  97 AC_ARG_ENABLE([bitmap-later],
  98     [AS_HELP_STRING([--enable-bitmap-later],
  99         [enable fast startup of file server by not reading bitmap till
 100          needed])],
 101     ,
 102     [enable_bitmap_later="no"])
 103 AC_ARG_ENABLE([unix-sockets],
 104     [AS_HELP_STRING([--disable-unix-sockets],
 105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 106     ,
 107     [enable_unix_sockets="yes"])
 108 AC_ARG_ENABLE([tivoli-tsm],
 109     [AS_HELP_STRING([--enable-tivoli-tsm],
 110         [enable use of the Tivoli TSM API libraries for butc support])],
 111     ,
 112     [enable_tivoli_tsm="no"])
 113 AC_ARG_ENABLE([pthreaded-ubik],
 114     [AS_HELP_STRING([--enable-pthreaded-ubik],
 115         [enable installation of pthreaded ubik applications (defaults to
 116          disabled)])],
 117     ,
 118     [enable_pthreaded_ubik="no"])
 119
 120 dnl Kernel module build options.
 121 AC_ARG_WITH([linux-kernel-headers],
 122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 123         [use the kernel headers found at path (optional, defaults to
 124          /usr/src/linux-2.4, then /usr/src/linux)])])
 125 AC_ARG_WITH([linux-kernel-build],
 126     [AS_HELP_STRING([--with-linux-kernel-build=path],
 127         [use the kernel build found at path(optional, defaults to
 128         /usr/src/linux-2.4, then /usr/src/linux)])])
 129 AC_ARG_WITH([bsd-kernel-headers],
 130     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 131         [use the kernel headers found at path (optional, defaults to
 132          /usr/src/sys)])])
 133 AC_ARG_WITH([bsd-kernel-build],
 134     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 135         [use the kernel build found at path (optional, defaults to
 136          KSRC/i386/compile/GENERIC)])])
 137 AC_ARG_WITH([linux-kernel-packaging],
 138     [AS_HELP_STRING([--with-linux-kernel-packaging],
 139         [use standard naming conventions to aid Linux kernel build packaging
 140          (disables MPS, sets the kernel module name to openafs.ko, and
 141          installs kernel modules into the standard Linux location)])],
 142     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
 143      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
 144     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
 145 AC_ARG_ENABLE([kernel-module],
 146     [AS_HELP_STRING([--disable-kernel-module],
 147         [disable compilation of the kernel module (defaults to enabled)])],
 148     ,
 149     [enable_kernel_module="yes"])
 150 AC_ARG_ENABLE([redhat-buildsys],
 151     [AS_HELP_STRING([--enable-redhat-buildsys],
 152         [enable compilation of the redhat build system kernel (defaults to
 153          disabled)])],
 154     ,
 155     [enable_redhat_buildsys="no"])
 156
 157 dnl Installation locations.
 158 AC_ARG_ENABLE([transarc-paths],
 159     [AS_HELP_STRING([--enable-transarc-paths],
 160         [use Transarc style paths like /usr/afs and /usr/vice])],
 161     ,
 162     [enable_transarc_paths="no"])
 163
 164 dnl Optimization and debugging flags.
 165 AC_ARG_ENABLE([strip-binaries],
 166     [AS_HELP_STRING([--disable-strip-binaries],
 167         [disable stripping of symbol information from binaries (defaults to
 168          enabled)])],
 169     ,
 170     [enable_strip_binaries="maybe"])
 171 AC_ARG_ENABLE([debug],
 172     [AS_HELP_STRING([--enable-debug],
 173         [enable compilation of the user space code with debugging information
 174          (defaults to disabled)])],
 175     ,
 176     [enable_debug="no"])
 177 AC_ARG_ENABLE([optimize],
 178     [AS_HELP_STRING([--disable-optimize],
 179         [disable optimization for compilation of the user space code (defaults
 180          to enabled)])],
 181     ,
 182     [enable_optimize="yes"])
 183 AC_ARG_ENABLE([warnings],
 184     [AS_HELP_STRING([--enable-warnings],
 185         [enable compilation warnings when building with gcc (defaults to
 186          disabled)])],
 187     ,
 188     [enable_warnings="no"])
 189 AC_ARG_ENABLE([checking],
 190     [AS_HELP_STRING([--enable-checking],
 191         [turn compilation warnings into errors when building with gcc (defaults
 192          to disabled)])],
 193     [enable_checking="$enableval"],
 194     [enable_checking="no"])
 195 AC_ARG_ENABLE([debug-locks],
 196     [AS_HELP_STRING([--enable-debug-locks],
 197         [turn on lock debugging assertions (defaults to disabled)])],
 198     [enable_debug_locks="$enableval"],
 199     [enable_debug_locks="no"])
 200 AC_ARG_ENABLE([debug-kernel],
 201     [AS_HELP_STRING([--enable-debug-kernel],
 202         [enable compilation of the kernel module with debugging information
 203          (defaults to disabled)])],
 204     ,
 205     [enable_debug_kernel="no"])
 206 AC_ARG_ENABLE([optimize-kernel],
 207     [AS_HELP_STRING([--disable-optimize-kernel],
 208         [disable compilation of the kernel module with optimization (defaults
 209          based on platform)])],
 210     ,
 211     [enable_optimize_kernel=""])
 212 AC_ARG_ENABLE([debug-lwp],
 213     [AS_HELP_STRING([--enable-debug-lwp],
 214         [enable compilation of the LWP code with debugging information
 215          (defaults to disabled)])],
 216     ,
 217     [enable_debug_lwp="no"])
 218 AC_ARG_ENABLE([optimize-lwp],
 219     [AS_HELP_STRING([--disable-optimize-lwp],
 220         [disable optimization for compilation of the LWP code (defaults to
 221          enabled)])],
 222     ,
 223     [enable_optimize_lwp="yes"])
 224 AC_ARG_ENABLE([debug-pam],
 225     [AS_HELP_STRING([--enable-debug-pam],
 226         [enable compilation of the PAM code with debugging information
 227          (defaults to disabled)])],
 228     ,
 229     [enable_debug_pam="no"])
 230 AC_ARG_ENABLE([optimize-pam],
 231     [AS_HELP_STRING([--disable-optimize-pam],
 232         [disable optimization for compilation of the PAM code (defaults to
 233          enabled)])],
 234     ,
 235     [enable_optimize_pam="yes"])
 236 AC_ARG_ENABLE([linux-syscall-probing],
 237     [AS_HELP_STRING([--enable-linux-syscall-probing],
 238         [enable Linux syscall probing (defaults to autodetect)])],
 239     ,
 240     [enable_linux_syscall_probing="maybe"])
 241 AC_ARG_WITH([crosstools-dir],
 242     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
 243
 244 AC_ARG_WITH([xslt-processor],
 245         AS_HELP_STRING([--with-xslt-processor=ARG],
 246         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 247         [XSLTPROC="$withval"],
 248         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
 249
 250 AC_ARG_WITH([html-xsl],
 251         AS_HELP_STRING([--with-html-xsl],
 252         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 253         [HTML_XSL="$withval"],
 254         [HTML_XSL="html/chunk.xsl"])
 255
 256 AC_ARG_WITH([docbook2pdf],
 257         AS_HELP_STRING([--with-docbook2pdf=ARG],
 258         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 259         [DOCBOOK2PDF="$withval"],
 260         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
 261
 262 AC_ARG_WITH([docbook-stylesheets],
 263         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 264         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 265         [DOCBOOK_STYLESHEETS="$withval"],
 266         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
 267         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
 268                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 269         fi)
 270
 271 enable_login="no"
 272
 273 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 274 dnl documentation build.
 275 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 276
 277 dnl weird ass systems
 278 dnl AC_AIX
 279 AC_ISC_POSIX
 280 dnl AC_MINIX
 281
 282 dnl Various compiler setup.
 283 AC_TYPE_PID_T
 284 AC_TYPE_SIZE_T
 285
 286 dnl Checks for programs.
 287 AC_PROG_INSTALL
 288 AC_PROG_LN_S
 289 AC_PROG_RANLIB
 290 AC_PROG_YACC
 291 AM_PROG_LEX
 292 dnl if we are flex, be lex-compatible
 293 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 294
 295 OPENAFS_FORCE_ABS_INSTALL
 296 OPENAFS_CHECK_BIGENDIAN
 297 OPENAFS_PRINTF_TAKES_Z_LEN
 298
 299 AC_MSG_CHECKING(your OS)
 300 system=$host
 301 case $system in
 302         *-linux*)
 303
 304                 MKAFS_OSTYPE=LINUX
 305                 if test "x$enable_redhat_buildsys" = "xyes"; then
 306                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 307                 fi
 308                 if test "x$enable_kernel_module" = "xyes"; then
 309                  if test "x$with_linux_kernel_headers" != "x"; then
 310                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 311                  else
 312                    LINUX_KERNEL_PATH="/lib/modules/`uname -r`/source"
 313                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 314                      LINUX_KERNEL_PATH="/lib/modules/`uname -r`/build"
 315                    fi
 316                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 317                      LINUX_KERNEL_PATH="/usr/src/linux-2.4"
 318                    fi
 319                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 320                      LINUX_KERNEL_PATH="/usr/src/linux"
 321                    fi
 322                  fi
 323                  if test "x$with_linux_kernel_build" != "x"; then
 324                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 325                  else
 326                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 327                  fi
 328                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 329                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 330                    LINUX_VERSION="$linux_kvers"
 331                  else
 332                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 333                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 334                      LINUX_VERSION="$linux_kvers"
 335                    else
 336                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 337                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 338                        if test "x$linux_kvers" = "x"; then
 339                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 340                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 341                            if test "x$linux_kvers" = "x"; then
 342                              AC_MSG_ERROR(Linux headers lack version definition [2])
 343                              exit 1
 344                            else
 345                              LINUX_VERSION="$linux_kvers"
 346                            fi
 347                          else
 348                            AC_MSG_ERROR(Linux headers lack version definition)
 349                            exit 1
 350                          fi
 351                        else
 352                          LINUX_VERSION="$linux_kvers"
 353                        fi
 354                      else
 355                        enable_kernel_module="no"
 356                      fi
 357                    fi
 358                  fi
 359                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 360                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 361                      enable_kernel_module="no"
 362                  fi
 363                  if test "x$enable_kernel_module" = "xno"; then
 364                   if test "x$with_linux_kernel_headers" != "x"; then
 365                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 366                    exit 1
 367                   else
 368                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 369                   fi
 370                  fi
 371                  dnl do we need to determine SUBARCH from autoconf.h
 372                  SUBARCH=default
 373                 fi
 374                 AC_MSG_RESULT(linux)
 375                 if test "x$enable_kernel_module" = "xyes"; then
 376                  case "$LINUX_VERSION" in
 377                   2.2.*) AFS_SYSKVERS=22 ;;
 378                   2.4.*) AFS_SYSKVERS=24 ;;
 379                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
 380                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 381                  esac
 382                 fi
 383                 ;;
 384         *-solaris*)
 385                 MKAFS_OSTYPE=SOLARIS
 386                 AC_MSG_RESULT(sun4)
 387                 AC_PATH_PROG(SOLARISCC, [cc], ,
 388                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 389                 if test "x$SOLARISCC" = "x" ; then
 390                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 391                 fi
 392                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 393                 SOLARIS_FS_HAS_FS_ROLLED
 394                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 395                 ;;
 396         *-sunos*)
 397                 MKAFS_OSTYPE=SUNOS
 398                 enable_kernel_module=no
 399                 AC_MSG_RESULT(sun4)
 400                 ;;
 401         *-hpux*)
 402                 MKAFS_OSTYPE=HPUX
 403                 AC_MSG_RESULT(hp_ux)
 404                 if test -f "/usr/old/usr/include/ndir.h"; then
 405                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 406                 fi
 407                 ;;
 408         *-irix*)
 409                 if test -d /usr/include/sys/SN/SN1; then
 410                  IRIX_BUILD_IP35="IP35"
 411                 fi
 412                 MKAFS_OSTYPE=IRIX
 413                 AC_MSG_RESULT(sgi)
 414                 ;;
 415         *-aix*)
 416                 MKAFS_OSTYPE=AIX
 417                 AC_MSG_RESULT(rs_aix)
 418                 ;;
 419         arm-*-darwin*)
 420                 MKAFS_OSTYPE=DARWIN
 421                 AC_MSG_RESULT(arm_darwin)
 422                 ;;
 423         powerpc-*-darwin*)
 424                 MKAFS_OSTYPE=DARWIN
 425                 AC_MSG_RESULT(ppc_darwin)
 426                 ;;
 427         i386-*-darwin*)
 428                 MKAFS_OSTYPE=DARWIN
 429                 AC_MSG_RESULT(x86_darwin)
 430                 ;;
 431         x86_64-*-darwin*)
 432                 MKAFS_OSTYPE=DARWIN
 433                 AC_MSG_RESULT(x86_darwin)
 434                 ;;
 435         i386-*-freebsd*)
 436                 MKAFS_OSTYPE=FBSD
 437                 AC_MSG_RESULT(i386_fbsd)
 438                 ;;
 439         x86_64-*-freebsd*)
 440                 MKAFS_OSTYPE=FBSD
 441                 AC_MSG_RESULT(amd64_fbsd)
 442                 ;;
 443         *-netbsd*)
 444                 MKAFS_OSTYPE=NBSD
 445                 AC_MSG_RESULT(nbsd)
 446                 ;;
 447         x86_64-*-openbsd*)
 448                 MKAFS_OSTYPE=OBSD
 449                 AC_MSG_RESULT(amd64_obsd)
 450                 ;;
 451         i386-*-openbsd*)
 452                 MKAFS_OSTYPE=OBSD
 453                 AC_MSG_RESULT(i386_obsd)
 454                 ;;
 455         *-dragonfly*)
 456                 MKAFS_OSTYPE=DFBSD
 457                 AC_MSG_RESULT(i386_dfbsd)
 458                 ;;
 459         *)
 460                 AC_MSG_RESULT($system)
 461                 ;;
 462 esac
 463
 464 if test "x$with_afs_sysname" != "x"; then
 465         AFS_SYSNAME="$with_afs_sysname"
 466 else
 467         AC_MSG_CHECKING(your AFS sysname)
 468         case $host in
 469                 i?86-*-openbsd?.?)
 470                         v=${host#*openbsd}
 471                         vM=${v%.*}
 472                         vm=${v#*.}
 473                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 474                         ;;
 475                 sparc64-*-openbsd?.?)
 476                         v=${host#*openbsd}
 477                         vM=${v%.*}
 478                         vm=${v#*.}
 479                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 480                         ;;
 481                 x86_64-*-openbsd?.?)
 482                         v=${host#*openbsd}
 483                         vM=${v%.*}
 484                         vm=${v#*.}
 485                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 486                         ;;
 487                 i?86-*-freebsd*.*)
 488                         v=${host#*freebsd}
 489                         vM=${v%.*}
 490                         vm=${v#*.}
 491                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 492                         ;;
 493                 x86_64-*-freebsd*.*)
 494                         v=${host#*freebsd}
 495                         vM=${v%.*}
 496                         vm=${v#*.}
 497                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 498                         ;;
 499                 i386-*-dragonfly?.*)
 500                         v=${host#*dragonfly}
 501                         vM=${v%.*}
 502                         vm=${v#*.}
 503                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 504                         ;;
 505                 i?86-*-netbsd*1.6[[M-Z]]*)
 506                         AFS_SYSNAME="i386_nbsd20"
 507                         ;;
 508                 powerpc-*-netbsd*1.6[[M-Z]]*)
 509                         AFS_SYSNAME="ppc_nbsd20"
 510                         ;;
 511                 *-*-netbsd*)
 512                         arch=${host%%-unknown*}
 513                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 514                                                -e 's/powerpc/ppc/g')
 515                         v=${host#*netbsd}
 516                         v=${v#*aout}
 517                         v=${v#*ecoff}
 518                         v=${v#*elf}
 519                         vM=${v%%.*}
 520                         vM=${vM%.*}
 521                         v=${v#*.}
 522                         vm=${v%%.*}
 523                         vm=${vm%.*}
 524                         vm=${vm%%[[_A-Z]]*}
 525                         if test $vm -eq 99 ; then
 526                                 vM=$((vM+1))
 527                         fi
 528                         if test $vM -gt 1 ; then
 529                                 vm=0
 530                         fi
 531                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 532                         ;;
 533                 hppa*-hp-hpux11.0*)
 534                         AFS_SYSNAME="hp_ux110"
 535                         ;;
 536                 hppa*-hp-hpux11.11)
 537                         AFS_SYSNAME="hp_ux11i"
 538                         ;;
 539                 hppa*-hp-hpux11.23)
 540                         AFS_SYSNAME="hp_ux1123"
 541                         ;;
 542                 ia64-hp-hpux11.22)
 543                         AFS_SYSNAME="ia64_hpux1122"
 544                         ;;
 545                 ia64-hp-hpux*)
 546                         AFS_SYSNAME="ia64_hpux1123"
 547                         ;;
 548                 hppa*-hp-hpux10*)
 549                         AFS_SYSNAME="hp_ux102"
 550                         ;;
 551                 powerpc-apple-darwin7*)
 552                         AFS_SYSNAME="ppc_darwin_70"
 553                         OSXSDK="macosx10.3"
 554                         ;;
 555                 powerpc-apple-darwin8.*)
 556                         AFS_SYSNAME="ppc_darwin_80"
 557                         OSXSDK="macosx10.4"
 558                         ;;
 559                 i386-apple-darwin8.*)
 560                         AFS_SYSNAME="x86_darwin_80"
 561                         OSXSDK="macosx10.4"
 562                         ;;
 563                 powerpc-apple-darwin9.*)
 564                         AFS_SYSNAME="ppc_darwin_90"
 565                         OSXSDK="macosx10.5"
 566                         ;;
 567                 i386-apple-darwin9.*)
 568                         AFS_SYSNAME="x86_darwin_90"
 569                         OSXSDK="macosx10.5"
 570                         ;;
 571                 i?86-apple-darwin10.*)
 572                         AFS_SYSNAME="x86_darwin_100"
 573                         OSXSDK="macosx10.6"
 574                         ;;
 575                 x86_64-apple-darwin10.*)
 576                         AFS_SYSNAME="x86_darwin_100"
 577                         OSXSDK="macosx10.6"
 578                         ;;
 579                 arm-apple-darwin10.*)
 580                         AFS_SYSNAME="arm_darwin_100"
 581                         OSXSDK="iphoneos4.0"
 582                         ;;
 583                 x86_64-apple-darwin11.*)
 584                         AFS_SYSNAME="x86_darwin_110"
 585                         OSXSDK="macosx10.7"
 586                         ;;
 587                 i?86-apple-darwin11.*)
 588                         AFS_SYSNAME="x86_darwin_110"
 589                         OSXSDK="macosx10.7"
 590                         ;;
 591                 x86_64-apple-darwin12.*)
 592                         AFS_SYSNAME="x86_darwin_120"
 593                         OSXSDK="macosx10.8"
 594                         ;;
 595                 i?86-apple-darwin12.*)
 596                         AFS_SYSNAME="x86_darwin_120"
 597                         OSXSDK="macosx10.8"
 598                         ;;
 599                 sparc-sun-solaris2.8)
 600                         AFS_SYSNAME="sun4x_58"
 601                         ;;
 602                 sparc-sun-solaris2.9)
 603                         AFS_SYSNAME="sun4x_59"
 604                         ;;
 605                 sparc-sun-solaris2.10)
 606                         AFS_SYSNAME="sun4x_510"
 607                         ;;
 608                 sparc-sun-solaris2.11)
 609                         AFS_SYSNAME="sun4x_511"
 610                         ;;
 611                 i386-pc-solaris2.8)
 612                         AFS_SYSNAME="sunx86_58"
 613                         ;;
 614                 i386-pc-solaris2.9)
 615                         AFS_SYSNAME="sunx86_59"
 616                         ;;
 617                 i386-pc-solaris2.10)
 618                         AFS_SYSNAME="sunx86_510"
 619                         ;;
 620                 i386-pc-solaris2.11)
 621                         AFS_SYSNAME="sunx86_511"
 622                         ;;
 623                 alpha*-dec-osf4.0*)
 624                         AFS_SYSNAME="alpha_dux40"
 625                         ;;
 626                 alpha*-dec-osf5.0*)
 627                         AFS_SYSNAME="alpha_dux50"
 628                         ;;
 629                 alpha*-dec-osf5.1*)
 630                         AFS_SYSNAME="alpha_dux51"
 631                         ;;
 632                 mips-sgi-irix6.5)
 633                         AFS_SYSNAME="sgi_65"
 634                         ;;
 635                 ia64-*-linux*)
 636                         AFS_SYSNAME="ia64_linuxXX"
 637                         ;;
 638                 powerpc-*-linux*)
 639                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 640                         ;;
 641                 powerpc64-*-linux*)
 642                         AFS_SYSNAME="ppc64_linuxXX"
 643                         ;;
 644                 alpha*-linux*)
 645                         AFS_SYSNAME="alpha_linux_XX"
 646                         ;;
 647                 s390-*-linux*)
 648                         AFS_SYSNAME="s390_linuxXX"
 649                         ;;
 650                 s390x-*-linux*)
 651                         AFS_SYSNAME="s390x_linuxXX"
 652                         ;;
 653                 sparc-*-linux*)
 654                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 655                         ;;
 656                 sparc64-*-linux*)
 657                         AFS_SYSNAME="sparc64_linuxXX"
 658                         ;;
 659                 i?86-*-linux*)
 660                         AFS_SYSNAME="i386_linuxXX"
 661                         ;;
 662                 arm*-linux*)
 663                         AFS_SYSNAME="arm_linuxXX"
 664                         ;;
 665                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 666                         AFS_SYSNAME="parisc_linuxXX"
 667                         enable_pam="no"
 668                         ;;
 669                 power*-ibm-aix4.2*)
 670                         AFS_SYSNAME="rs_aix42"
 671                         enable_pam="no"
 672                         ;;
 673                 power*-ibm-aix4.3*)
 674                         AFS_SYSNAME="rs_aix42"
 675                         enable_pam="no"
 676                         ;;
 677                 power*-ibm-aix5.1*)
 678                         AFS_SYSNAME="rs_aix51"
 679                         enable_pam="no"
 680                         ;;
 681                 power*-ibm-aix5.2*)
 682                         AFS_SYSNAME="rs_aix52"
 683                         enable_pam="no"
 684                         ;;
 685                 power*-ibm-aix5.3*)
 686                         AFS_SYSNAME="rs_aix53"
 687                         enable_pam="no"
 688                         ;;
 689                 power*-ibm-aix6.1*)
 690                         AFS_SYSNAME="rs_aix61"
 691                         enable_pam="no"
 692                         ;;
 693                 x86_64-*-linux-gnu)
 694                         AFS_SYSNAME="amd64_linuxXX"
 695                         enable_pam="yes"
 696                         ;;
 697                 *)
 698                         AC_MSG_ERROR(An AFS sysname is required)
 699                         exit 1
 700                         ;;
 701         esac
 702         case $AFS_SYSNAME in
 703                 *_linux* | *_umlinux*)
 704                         if test "x${AFS_SYSKVERS}" = "x"; then
 705                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 706                         fi
 707                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 708                         AFS_SYSNAME="$_AFS_SYSNAME"
 709                         AC_TRY_KBUILD(
 710                          [],
 711                          [#ifndef CONFIG_USERMODE
 712                           #error not UML
 713                           #endif],
 714                          ac_cv_linux_is_uml=yes,)
 715                         if test "${ac_cv_linux_is_uml}" = yes; then
 716                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 717                         fi
 718                         AFS_SYSNAME="$_AFS_SYSNAME"
 719                         ;;
 720         esac
 721         AC_MSG_RESULT($AFS_SYSNAME)
 722 fi
 723
 724 case $AFS_SYSNAME in
 725         *_darwin*)
 726                 AC_CHECK_HEADERS(crt_externs.h)
 727                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 728                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 729                 AC_SUBST(OSXSDK)
 730                 ;;
 731 esac
 732
 733 dnl Some hosts have a separate common param file they should include.  Figure
 734 dnl out if we're on one of them now that we know the sysname.
 735 case $AFS_SYSNAME in
 736     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 737     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 738     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 739     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 740     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 741     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 742     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 743     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 744     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 745     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 746     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 747     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 748     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 749     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 750     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 751     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 752     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 753     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 754     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 755     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 756     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 757     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 758     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 759     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 760     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 761     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 762     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 763     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 764     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 765 # Linux alpha adds an extra underscore for no good reason.
 766     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 767     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 768     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 769 esac
 770
 771 OPENAFS_OSCONF
 772
 773 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 774
 775                 # Add (sub-) architecture-specific paths needed by conftests
 776                 case $AFS_SYSNAME  in
 777                         *_umlinux26)
 778                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 779                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 780                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 781                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 782                 esac
 783
 784                 if test "x$enable_kernel_module" = "xyes"; then
 785                  if test "x$enable_debug_kernel" = "xno"; then
 786                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 787                  fi
 788                  OPENAFS_GCC_SUPPORTS_MARCH
 789                  AC_SUBST(P5PLUS_KOPTS)
 790                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 791                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 792                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 793                  OPENAFS_GCC_SUPPORTS_PIPE
 794                  AC_SUBST(LINUX_GCC_KOPTS)
 795
 796                  dnl Setup the kernel build environment
 797                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 798                  LINUX_KERNEL_COMPILE_WORKS
 799
 800                  dnl Check for header files
 801                  AC_CHECK_LINUX_HEADER([config.h])
 802                  AC_CHECK_LINUX_HEADER([completion.h])
 803                  AC_CHECK_LINUX_HEADER([exportfs.h])
 804                  AC_CHECK_LINUX_HEADER([freezer.h])
 805                  AC_CHECK_LINUX_HEADER([key-type.h])
 806                  AC_CHECK_LINUX_HEADER([semaphore.h])
 807                  AC_CHECK_LINUX_HEADER([seq_file.h])
 808
 809                  dnl Type existence checks
 810                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 811
 812                  dnl Check for structure elements
 813                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 814                                        [write_begin], [fs.h])
 815                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 816                                        [backing-dev.h])
 817                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 818                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 819                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 820                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 821                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 822                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 823                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 824                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 825                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 826                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 827                  AC_CHECK_LINUX_STRUCT([filename], [name], [fs.h])
 828                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 829                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 830                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 831                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 832                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 833                                        [fs.h])
 834                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 835                                        [fs.h])
 836                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 837                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 838                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 839                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 840                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 841                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 842                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 843                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 844                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 845                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 846                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 847
 848                  dnl Check for typed structure elements
 849                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 850                                              [buf], [fs.h])
 851
 852                  dnl Function existence checks
 853
 854                  AC_CHECK_LINUX_FUNC([bdi_init],
 855                                      [#include <linux/backing-dev.h>],
 856                                      [bdi_init(NULL);])
 857                  AC_CHECK_LINUX_FUNC([PageChecked],
 858                                      [#include <linux/mm.h>
 859 #include <linux/page-flags.h>],
 860                                      [struct page *_page;
 861                                       int bchecked = PageChecked(_page);])
 862                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 863                                      [#include <linux/mm.h>
 864 #include <linux/page-flags.h>],
 865                                      [struct page *_page;
 866                                       int bchecked = PageFsMisc(_page);])
 867                  AC_CHECK_LINUX_FUNC([clear_inode],
 868                                      [#include <linux/fs.h>],
 869                                      [clear_inode(NULL);])
 870                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 871                                      [#include <linux/time.h>],
 872                                      [struct timespec s;
 873                                       s = current_kernel_time();])
 874                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 875                                      [#include <linux/fs.h>],
 876                                      [d_alloc_anon(NULL);])
 877                  AC_CHECK_LINUX_FUNC([d_make_root],
 878                                      [#include <linux/fs.h>],
 879                                      [d_make_root(NULL);])
 880                  AC_CHECK_LINUX_FUNC([do_sync_read],
 881                                      [#include <linux/fs.h>],
 882                                      [do_sync_read(NULL, NULL, 0, NULL);])
 883                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 884                                      [#include <linux/sched.h>],
 885                                      [pid_t p; find_task_by_pid(p);])
 886                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 887                                      [#include <linux/fs.h>],
 888                                      [generic_file_aio_read(NULL,NULL,0,0);])
 889                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 890                                      [#include <linux/pagemap.h>],
 891                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 892                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 893                                      [#include <linux/list.h>],
 894                                      [hlist_unhashed(0);])
 895                  AC_CHECK_LINUX_FUNC([i_size_read],
 896                                      [#include <linux/fs.h>],
 897                                      [i_size_read(NULL);])
 898                  AC_CHECK_LINUX_FUNC([inode_setattr],
 899                                      [#include <linux/fs.h>],
 900                                      [inode_setattr(NULL, NULL);])
 901                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
 902                                      [#include <linux/net.h>],
 903                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
 904                  AC_CHECK_LINUX_FUNC([page_follow_link],
 905                                      [#include <linux/fs.h>],
 906                                      [page_follow_link(0,0);])
 907                  AC_CHECK_LINUX_FUNC([page_offset],
 908                                      [#include <linux/pagemap.h>],
 909                                      [page_offset(NULL);])
 910                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
 911                                      [#include <linux/pagevec.h>],
 912                                      [__pagevec_lru_add_file(NULL);])
 913                  AC_CHECK_LINUX_FUNC([path_lookup],
 914                                      [#include <linux/fs.h>
 915                                       #include <linux/namei.h>],
 916                                      [path_lookup(NULL, 0, NULL);])
 917                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
 918                                      [#include <linux/rcupdate.h>],
 919                                      [rcu_read_lock();])
 920                  AC_CHECK_LINUX_FUNC([set_nlink],
 921                                      [#include <linux/fs.h>],
 922                                      [set_nlink(NULL, 1);])
 923                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
 924                                      [#include <linux/splice.h>],
 925                                      [splice_direct_to_actor(NULL,NULL,NULL);])
 926                  AC_CHECK_LINUX_FUNC([svc_addr_in],
 927                                      [#include <linux/sunrpc/svc.h>],
 928                                      [svc_addr_in(NULL);])
 929                  AC_CHECK_LINUX_FUNC([zero_user_segments],
 930                                      [#include <linux/highmem.h>],
 931                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
 932                  AC_CHECK_LINUX_FUNC([noop_fsync],
 933                                      [#include <linux/fs.h>],
 934                                      [void *address = &noop_fsync; printk("%p\n", address)];)
 935                  AC_CHECK_LINUX_FUNC([kthread_run],
 936                                      [#include <linux/kernel.h>
 937                                       #include <linux/kthread.h>],
 938                                      [kthread_run(NULL, NULL, "test");])
 939
 940                  dnl Consequences - things which get set as a result of the
 941                  dnl                above tests
 942                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
 943                        [AC_DEFINE([AFS_NONFSTRANS], 1,
 944                                   [define to disable the nfs translator])])
 945
 946                  dnl Assorted more complex tests
 947                  LINUX_AIO_NONVECTOR
 948                  LINUX_EXPORTS_PROC_ROOT_FS
 949                  LINUX_KMEM_CACHE_INIT
 950                  LINUX_HAVE_KMEM_CACHE_T
 951                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
 952                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
 953                  LINUX_D_PATH_TAKES_STRUCT_PATH
 954                  LINUX_NEW_EXPORT_OPS
 955                  LINUX_INODE_SETATTR_RETURN_TYPE
 956                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
 957                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
 958                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
 959                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
 960                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
 961                  LINUX_DOP_D_DELETE_TAKES_CONST
 962                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
 963                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
 964                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
 965                  LINUX_FOP_F_FSYNC_TAKES_RANGE
 966                  LINUX_AOP_WRITEBACK_CONTROL
 967                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
 968                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
 969                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
 970                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
 971                  LINUX_KERNEL_SOCK_CREATE
 972                  LINUX_EXPORTS_KEY_TYPE_KEYRING
 973                  LINUX_NEED_RHCONFIG
 974                  LINUX_RECALC_SIGPENDING_ARG_TYPE
 975                  LINUX_EXPORTS_TASKLIST_LOCK
 976                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
 977                  LINUX_STATFS_TAKES_DENTRY
 978                  LINUX_REFRIGERATOR
 979                  LINUX_HAVE_TRY_TO_FREEZE
 980                  LINUX_LINUX_KEYRING_SUPPORT
 981                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
 982                  LINUX_KEY_ALLOC_NEEDS_CRED
 983                  LINUX_INIT_WORK_HAS_DATA
 984                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
 985                  LINUX_HAVE_DCACHE_LOCK
 986                  LINUX_D_COUNT_IS_INT
 987                  LINUX_IOP_MKDIR_TAKES_UMODE_T
 988                  LINUX_IOP_CREATE_TAKES_UMODE_T
 989                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
 990                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
 991                  LINUX_DENTRY_OPEN_TAKES_PATH
 992                  LINUX_D_ALIAS_IS_HLIST
 993                  LINUX_IOP_I_CREATE_TAKES_BOOL
 994                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
 995                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
 996
 997                  dnl If we are guaranteed that keyrings will work - that is
 998                  dnl  a) The kernel has keyrings enabled
 999                  dnl  b) The code is new enough to give us a key_type_keyring
1000                  dnl then we just disable syscall probing unless we've been
1001                  dnl told otherwise
1002
1003                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1004                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1005                           [enable_linux_syscall_probing="no"],
1006                           [enable_linux_syscall_probing="yes"])
1007                  ])
1008
1009                  dnl Syscall probing needs a few tests of its own, and just
1010                  dnl won't work if the kernel doesn't export init_mm
1011                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1012                    LINUX_EXPORTS_INIT_MM
1013                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1014                      AC_MSG_ERROR(
1015                        [Can't do syscall probing without exported init_mm])
1016                    ])
1017                    LINUX_EXPORTS_SYS_CHDIR
1018                    LINUX_EXPORTS_SYS_OPEN
1019                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1020                              [define to enable syscall table probes])
1021                  ])
1022
1023                  dnl Packaging and SMP build
1024                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1025                    LINUX_WHICH_MODULES
1026                  else
1027                    AC_SUBST(MPS,'SP')
1028                  fi
1029
1030                  dnl Syscall probing
1031                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1032                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1033                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1034                    ])
1035                    ac_cv_linux_exports_sys_call_table=no
1036                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1037                      ac_cv_linux_exports_ia32_sys_call_table=yes
1038                    fi
1039                  else
1040                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1041                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1042                    LINUX_EXPORTS_SYS_CALL_TABLE
1043                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1044                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1045                          linux_syscall_method=none
1046                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1047                             linux_syscall_method=scan
1048                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1049                                linux_syscall_method=scan_with_kallsyms_address
1050                             fi
1051                          fi
1052                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1053                             linux_syscall_method=kallsyms_symbol
1054                          fi
1055                          if test "x$linux_syscall_method" = "xnone"; then
1056                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1057                             linux_syscall_method=scan
1058                          fi
1059                    fi
1060                  fi
1061                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1062                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1063                  fi
1064                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1065                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1066                  fi
1067                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1068                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1069                  else
1070                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1071                  fi
1072                 :
1073                 fi
1074 dnl Linux-only, but just enable always.
1075                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1076 esac
1077
1078 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1079     [ac_cv_sync_fetch_and_add],
1080     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1081                     [ac_cv_sync_fetch_and_add=yes],
1082                     [ac_cv_sync_fetch_and_add=no])
1083 ])
1084 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1085       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1086                 [define if your C compiler has __sync_add_and_fetch])])
1087
1088 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1089     [ac_cv_sockaddr_len],
1090     [AC_TRY_COMPILE( [#include <sys/types.h>
1091 #include <sys/socket.h>],
1092                      [struct sockaddr *a; a->sa_len=0;],
1093                      [ac_cv_sockaddr_len=yes],
1094                      [ac_cv_sockaddr_len=no])
1095 ])
1096 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1097       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1098                  [define if you struct sockaddr sa_len])])
1099
1100 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1101         echo Skipping library tests because they confuse Irix.
1102 else
1103   AC_SEARCH_LIBS([socket], [socket inet])
1104   AC_SEARCH_LIBS([connect], [nsl])
1105   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1106
1107   dnl darwin wants it, aix hates it
1108   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1109   AC_TRY_COMPILE([
1110   #include <stdlib.h>
1111   #include <stdio.h>
1112   #include <sys/types.h>
1113   #include <sys/socket.h>
1114   #include <netinet/in.h>
1115   #include <arpa/inet.h>
1116   #include <arpa/nameser.h>
1117   #include <arpa/nameser_compat.h>
1118   #include <resolv.h>
1119   ], [static int i; i = 0;],
1120   [AC_MSG_RESULT(yes)
1121    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1122   [AC_MSG_RESULT(no)
1123    ])
1124
1125   openafs_save_libs="$LIBS"
1126   AC_MSG_CHECKING([for res_search])
1127   AC_FUNC_RES_SEARCH
1128
1129   if test "$ac_cv_func_res_search" = no; then
1130       for lib in dns nsl resolv; do
1131         if test "$ac_cv_func_res_search" != yes; then
1132           LIBS="-l$lib $LIBS"
1133           AC_FUNC_RES_SEARCH
1134           LIBS="$openafs_save_libs"
1135         fi
1136       done
1137       if test "$ac_cv_func_res_search" = yes; then
1138         LIB_AFSDB="-l$lib"
1139         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1140         AC_MSG_RESULT([yes, in lib$lib])
1141       else
1142         AC_MSG_RESULT(no)
1143       fi
1144   else
1145     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1146     AC_MSG_RESULT(yes)
1147   fi
1148
1149 fi
1150 XLIBS="$LIB_AFSDB $XLIBS"
1151
1152 AC_CHECK_RESOLV_RETRANS
1153
1154 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1155     [ac_cv_setsockopt_iprecverr],
1156     [AC_TRY_COMPILE( [
1157 #include <sys/types.h>
1158 #include <sys/socket.h>
1159 #include <netinet/in.h>],
1160 [int on=1;
1161 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1162         [ac_cv_setsockopt_iprecverr=yes],
1163         [ac_cv_setsockopt_iprecverr=no])])
1164
1165 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1166       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1167                  [define if we can receive socket errors via IP_RECVERR])])
1168
1169 PTHREAD_LIBS=error
1170 if test "x$MKAFS_OSTYPE" = OBSD; then
1171         PTHREAD_LIBS="-pthread"
1172 fi
1173 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1174         PTHREAD_LIBS="-pthread"
1175 fi
1176 if test "x$PTHREAD_LIBS" = xerror; then
1177         AC_CHECK_LIB(pthread, pthread_attr_init,
1178                 PTHREAD_LIBS="-lpthread")
1179 fi
1180 if test "x$PTHREAD_LIBS" = xerror; then
1181         AC_CHECK_LIB(pthreads, pthread_attr_init,
1182                 PTHREAD_LIBS="-lpthreads")
1183 fi
1184 if test "x$PTHREAD_LIBS" = xerror; then
1185         AC_CHECK_LIB(c_r, pthread_attr_init,
1186                 PTHREAD_LIBS="-lc_r")
1187 fi
1188 if test "x$PTHREAD_LIBS" = xerror; then
1189         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1190 fi
1191 if test "x$PTHREAD_LIBS" = xerror; then
1192         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1193         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1194                 PTHREAD_LIBS="-lpthread")
1195 fi
1196 if test "x$PTHREAD_LIBS" = xerror; then
1197         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1198 fi
1199 AC_SUBST(PTHREAD_LIBS)
1200
1201 HOST_CPU="$host_cpu"
1202
1203 if test "x$with_bsd_kernel_headers" != "x"; then
1204         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1205 else
1206         BSD_KERNEL_PATH="/usr/src/sys"
1207 fi
1208
1209 if test "x$with_bsd_kernel_build" != "x"; then
1210         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1211 else
1212         case $AFS_SYSNAME in
1213                 *_fbsd_*)
1214                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1215                         ;;
1216                 *_nbsd*)
1217                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1218         esac
1219 fi
1220
1221 # Fast restart
1222 if test "$enable_supergroups" = "yes"; then
1223         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1224 fi
1225
1226 if test "$enable_bitmap_later" = "yes"; then
1227         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1228 fi
1229
1230 if test "$enable_unix_sockets" = "yes"; then
1231         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1232         USE_UNIX_SOCKETS="yes"
1233 else
1234         USE_UNIX_SOCKETS="no"
1235 fi
1236 AC_SUBST(USE_UNIX_SOCKETS)
1237
1238 if test "$enable_namei_fileserver" = "yes"; then
1239         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1240         VFSCK=""
1241 else
1242         if test "$enable_namei_fileserver" = "default"; then
1243                 case $host in
1244                         *-solaris2.10*)
1245                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1246                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1247                                 VFSCK=""
1248                                 ;;
1249                         *-solaris2.11*)
1250                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1251                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1252                                 VFSCK=""
1253                                 ;;
1254                         *)
1255                                 VFSCK="vfsck"
1256                                 ;;
1257                 esac
1258         else
1259                 VFSCK="vfsck"
1260         fi
1261 fi
1262
1263 dnl check for tivoli
1264 AC_MSG_CHECKING(for tivoli tsm butc support)
1265 XBSA_CFLAGS=""
1266 if test "$enable_tivoli_tsm" = "yes"; then
1267         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1268         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1269         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1270         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1271
1272         if test -r "$XBSADIR3/dsmapifp.h"; then
1273                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1274                 XBSA_XLIBS="-ldl"
1275                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1276         elif test -r "$XBSADIR4/dsmapifp.h"; then
1277                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1278                 XBSA_XLIBS="-ldl"
1279                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1280         elif test -r "$XBSADIR1/xbsa.h"; then
1281                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1282                 XBSA_XLIBS=""
1283                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1284         elif test -r "$XBSADIR2/xbsa.h"; then
1285                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1286                 XBSA_XLIBS=""
1287                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1288         else
1289                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1290         fi
1291 else
1292         AC_MSG_RESULT([no])
1293 fi
1294 AC_SUBST(XBSA_CFLAGS)
1295 AC_SUBST(XBSA_XLIBS)
1296
1297 dnl checks for header files.
1298 AC_HEADER_STDC
1299 AC_HEADER_SYS_WAIT
1300 AC_HEADER_DIRENT
1301 AC_CHECK_HEADERS([ \
1302                    arpa/inet.h \
1303                    arpa/nameser.h \
1304                    curses.h\
1305                    direct.h \
1306                    et/com_err.h \
1307                    errno.h \
1308                    fcntl.h \
1309                    grp.h \
1310                    math.h \
1311                    mntent.h \
1312                    ncurses.h \
1313                    netdb.h \
1314                    netinet/in.h \
1315                    pthread_np.h \
1316                    pwd.h \
1317                    regex.h \
1318                    security/pam_appl.h \
1319                    signal.h \
1320                    stdint.h \
1321                    stdio_ext.h \
1322                    stdlib.h \
1323                    string.h \
1324                    strings.h \
1325                    sys/bitypes.h \
1326                    sys/bswap.h \
1327                    sys/dk.h \
1328                    sys/fcntl.h \
1329                    sys/file.h \
1330                    sys/fs_types.h \
1331                    sys/fstyp.h \
1332                    sys/ioctl.h \
1333                    sys/ipc.h \
1334                    sys/lockf.h \
1335                    sys/map.h \
1336                    sys/mount.h \
1337                    sys/mntent.h \
1338                    sys/mnttab.h \
1339                    sys/pag.h \
1340                    sys/param.h \
1341                    sys/resource.h \
1342                    sys/select.h \
1343                    sys/statfs.h \
1344                    sys/statvfs.h \
1345                    sys/socket.h \
1346                    sys/sysctl.h \
1347                    sys/time.h \
1348                    sys/types.h \
1349                    sys/uio.h \
1350                    sys/un.h \
1351                    sys/vfs.h \
1352                    syslog.h \
1353                    termios.h \
1354                    time.h \
1355                    ucontext.h \
1356                    unistd.h \
1357                    windows.h \
1358                 ])
1359
1360 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1361 #ifdef HAVE_NETINET_IN_H
1362 # include <netinet/in.h>
1363 #endif])
1364
1365 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1366 #ifdef HAVE_SYS_SOCKET_H
1367 # include <sys/socket.h>
1368 #endif])
1369
1370 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1371 #ifdef HAVE_SYS_SOCKET_H
1372 # include <sys/socket.h>
1373 #endif
1374 #ifdef HAVE_NETINET_IN_H
1375 # include <netinet/in.h>
1376 #endif
1377 #ifdef HAVE_NET_IF_H
1378 # include <net/if.h>
1379 #endif])
1380
1381 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1382 #ifdef HAVE_SECURITY_PAM_APPL_H
1383 # include <security/pam_appl.h>
1384 #endif])
1385
1386 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1387
1388 AC_CHECK_TYPES([fsblkcnt_t],,,[
1389 #include <sys/types.h>
1390 #ifdef HAVE_SYS_BITYPES_H
1391 #include <sys/bitypes.h>
1392 #endif
1393 #ifdef HAVE_SYS_STATFS_H
1394 #include <sys/statfs.h>
1395 #endif
1396 #ifdef HAVE_SYS_STATVFS_H
1397 #include <sys/statvfs.h>
1398 #endif
1399 ])
1400
1401 dnl see what struct stat has for timestamps
1402 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1403
1404 dnl check for curses-lib
1405 AS_IF([test "x$enable_gtx" != "xno"],
1406       [save_LIBS=$LIBS
1407       AC_CHECK_LIB( [ncurses], [setupterm],
1408       [LIB_curses=-lncurses],
1409         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1410           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1411       ])
1412       LIBS=$save_LIBS
1413       AC_SUBST(LIB_curses)])
1414
1415 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1416
1417 if test "$enable_debug_locks" = yes; then
1418         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1419 fi
1420
1421 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1422 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1423         case $AFS_SYSNAME in
1424         sgi_*)
1425                 HAVE_PAM="no"
1426                 ;;
1427         *)
1428                 HAVE_PAM="yes"
1429                 ;;
1430         esac
1431 else
1432         HAVE_PAM="no"
1433 fi
1434 AC_SUBST(HAVE_PAM)
1435
1436 if test "$enable_login" = yes; then
1437         BUILD_LOGIN="yes"
1438 else
1439         BUILD_LOGIN="no"
1440 fi
1441 AC_SUBST(BUILD_LOGIN)
1442
1443 if test "$enable_uss" = yes; then
1444         BUILD_USS="yes"
1445 else
1446         BUILD_USS="no"
1447 fi
1448 AC_SUBST(BUILD_USS)
1449
1450 AC_CHECK_FUNCS([ \
1451         arc4random \
1452         fcntl \
1453         fseeko64 \
1454         ftello64 \
1455         getcwd \
1456         getegid \
1457         geteuid \
1458         getgid \
1459         getuid \
1460         getrlimit \
1461         issetugid \
1462         mkstemp \
1463         poll \
1464         pread \
1465         preadv \
1466         preadv64 \
1467         pwrite \
1468         pwritev \
1469         pwritev64 \
1470         regcomp \
1471         regerror \
1472         regexec \
1473         setitimer \
1474         setvbuf \
1475         sigaction \
1476         strcasestr \
1477         strerror \
1478         sysconf \
1479         sysctl \
1480         tdestroy \
1481         timegm \
1482 ])
1483
1484 OPENAFS_ROKEN()
1485 OPENAFS_C_ATTRIBUTE()
1486
1487 dnl Functions that Heimdal's libroken provides, but that we
1488 dnl haven't found a need for yet, and so haven't imported
1489 AC_CHECK_FUNCS([ \
1490         chown \
1491         fchown \
1492         gethostname \
1493         lstat \
1494         inet_aton \
1495         inet_ntop \
1496         inet_pton \
1497         putenv \
1498         readv \
1499         setenv \
1500         strdup \
1501         strftime \
1502         strndup \
1503         strsep \
1504         unsetenv \
1505 ])
1506
1507 dnl Functions that are in objects that we always build from libroken
1508 AC_CHECK_FUNCS([ \
1509         asprintf \
1510         asnprintf \
1511         vasprintf \
1512         vasnprintf \
1513         vsnprintf \
1514         snprintf \
1515 ])
1516
1517 dnl Functions that we're going to try and get from libroken
1518 AC_REPLACE_FUNCS([ \
1519         daemon \
1520         ecalloc \
1521         emalloc \
1522         erealloc \
1523         err \
1524         errx \
1525         flock \
1526         getdtablesize \
1527         getopt \
1528         getprogname \
1529         gettimeofday \
1530         localtime_r \
1531         mkstemp \
1532         setenv \
1533         setprogname \
1534         strcasecmp \
1535         strlcat \
1536         strnlen \
1537         strlcpy \
1538         strsep \
1539         tdelete \
1540         tfind \
1541         tsearch \
1542         twalk \
1543         unsetenv \
1544         verr \
1545         verrx \
1546         vsyslog \
1547         vwarn \
1548         vwarnx \
1549         warn \
1550         warnx \
1551 ])
1552
1553 dnl Headers that we're going to try and get from libroken
1554 AC_CHECK_HEADERS([ \
1555         err.h \
1556         search.h \
1557 ])
1558
1559 AC_CHECK_DECLS([h_errno], [], [], [
1560 #include <sys/types.h>
1561 #ifdef HAVE_NETDB_H
1562 #include <netdb.h>
1563 #endif
1564 ])
1565
1566 AC_HEADER_TIME
1567
1568 ROKEN_HEADERS=
1569 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1570       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1571       [])
1572 AC_SUBST(ROKEN_HEADERS)
1573
1574 dnl Stuff that's harder ...
1575 AC_MSG_CHECKING([for bswap16])
1576 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1577 #ifdef HAVE_SYS_TYPES_H
1578 #include <sys/types.h>
1579 #endif
1580 #ifdef HAVE_SYS_BSWAP_H
1581 #include <sys/bswap.h>
1582 #endif
1583 ],
1584 [short a, b; b = bswap16(a); ])],
1585 [AC_MSG_RESULT(yes)
1586  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1587 ],
1588 [AC_MSG_RESULT(no)])
1589
1590 AC_MSG_CHECKING([for bswap32])
1591 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1592 #include <sys/types.h>
1593 #endif
1594 #ifdef HAVE_SYS_BSWAP_H
1595 #include <sys/bswap.h>
1596 #endif
1597 ],
1598 [int a, b; b = bswap32(a); ])],
1599 [AC_MSG_RESULT(yes)
1600  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1601 ],
1602 [AC_MSG_RESULT(no)])
1603
1604 case $AFS_SYSNAME in
1605 *hp_ux* | *hpux*)
1606    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1607    ;;
1608 *)
1609    AC_MSG_CHECKING([for positional I/O])
1610    if test "$ac_cv_func_pread" = "yes" && \
1611            test "$ac_cv_func_pwrite" = "yes"; then
1612       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1613       AC_MSG_RESULT(yes)
1614    else
1615      AC_MSG_RESULT(no)
1616    fi
1617    AC_MSG_CHECKING([for vectored positional I/O])
1618    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1619                "$ac_cv_func_pwritev" = "yes" -a \
1620                "$ac_cv_func_preadv64" = "yes" -a \
1621                "$ac_cv_func_pwritev64" = "yes"],
1622          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1623           AC_MSG_RESULT(yes)],
1624          [AC_MSG_RESULT(no)])
1625    ;;
1626 esac
1627
1628 AC_MSG_CHECKING([for POSIX regex library])
1629 if test "$ac_cv_header_regex_h" = "yes" && \
1630         test "$ac_cv_func_regcomp" = "yes" && \
1631         test "$ac_cv_func_regexec" = "yes" && \
1632         test "$ac_cv_func_regerror" = "yes"; then
1633     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1634     AC_MSG_RESULT(yes)
1635 else
1636     AC_MSG_RESULT(no)
1637 fi
1638
1639 dnl Look for "non-portable" pthreads functions.
1640 save_LIBS="$LIBS"
1641 LIBS="$LIBS $PTHREAD_LIBS"
1642 AC_CHECK_FUNCS([ \
1643         pthread_set_name_np \
1644         pthread_setname_np \
1645 ])
1646
1647 dnl Sadly, there are three different versions of pthread_setname_np.
1648 dnl Try to cater for all of them.
1649 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1650     AC_MSG_CHECKING([for signature of pthread_setname_np])
1651     AC_TRY_COMPILE([
1652 #include <pthread.h>
1653 #ifdef HAVE_PTHREAD_NP_H
1654 #include <pthread_np.h>
1655 #endif
1656 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1657         AC_MSG_RESULT([three arguments])
1658         pthread_setname_np_args=3], [
1659         AC_TRY_COMPILE([
1660 #include <pthread.h>
1661 #ifdef HAVE_PTHREAD_NP_H
1662 #include <pthread_np.h>
1663 #endif
1664 ], [pthread_setname_np(pthread_self(), "test")], [
1665             AC_MSG_RESULT([two arguments])
1666             pthread_setname_np_args=2], [
1667             AC_TRY_COMPILE([
1668 #include <pthread.h>
1669 #ifdef HAVE_PTHREAD_NP_H
1670 #include <pthread_np.h>
1671 #endif
1672 ], [pthread_setname_np("test")], [
1673                 AC_MSG_RESULT([one argument])
1674                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1675 ])
1676 ])
1677 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1678 fi
1679 LIBS="$save_LIBS"
1680
1681 openafs_cv_saved_CFLAGS="$CFLAGS"
1682 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1683
1684 AC_TYPE_SIGNAL
1685 OPENAFS_RETSIGTYPE
1686 AC_CHECK_SIZEOF(void *)
1687 AC_CHECK_SIZEOF(unsigned long long)
1688 AC_CHECK_SIZEOF(unsigned long)
1689 AC_CHECK_SIZEOF(unsigned int)
1690 AC_TYPE_INTPTR_T
1691 AC_TYPE_UINTPTR_T
1692 AC_TYPE_SSIZE_T
1693 AC_CHECK_TYPE([sig_atomic_t],[],
1694     [AC_DEFINE([sig_atomic_t], [int],
1695         [Define to int if <signal.h> does not define.])],
1696 [#include <sys/types.h>
1697 #include <signal.h>])
1698 AC_CHECK_TYPE([socklen_t],[],
1699     [AC_DEFINE([socklen_t], [int],
1700         [Define to int if <sys/socket.h> does not define.])],
1701 [#include <sys/types.h>
1702 #include <sys/socket.h>])
1703 AC_CHECK_TYPES(off64_t)
1704 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1705 AC_CHECK_TYPES([struct winsize], [], [], [
1706 #ifdef HAVE_TERMIOS_H
1707 # include <termios.h>
1708 #else
1709 # include <sys/termios.h>
1710 #endif
1711 #include <sys/ioctl.h>])
1712 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1713                 struct sockaddr_storage],
1714                [], [], [
1715 #include <sys/types.h>
1716 #include <sys/socket.h>
1717 ])
1718 AC_CHECK_TYPES([sa_family_t], [], [], [
1719 #include <sys/types.h>
1720 #include <sys/socket.h>
1721 ])
1722 AC_CHECK_TYPES([struct addrinfo], [], [], [
1723 #include <sys/types.h>
1724 #ifdef HAVE_NETDB_H
1725 #include <netdb.h>
1726 #endif
1727 ])
1728 AC_CHECK_TYPES([long long], [], [], [])
1729
1730 AC_SIZEOF_TYPE(long)
1731
1732 CFLAGS="$openafs_cv_saved_CFLAGS"
1733
1734 RRA_HEADER_PAM_CONST
1735
1736
1737 dnl Directory PATH handling
1738 if test "x$enable_transarc_paths" = "xyes"  ; then
1739     afsconfdir=${afsconfdir=/usr/afs/etc}
1740     viceetcdir=${viceetcdir=/usr/vice/etc}
1741     afskerneldir=${afskerneldir=${viceetcdir}}
1742     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1743     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1744     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1745     afsdbdir=${afsdbdir=/usr/afs/db}
1746     afslogsdir=${afslogsdir=/usr/afs/logs}
1747     afslocaldir=${afslocaldir=/usr/afs/local}
1748     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1749     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1750     afsdatadir=${afsdatadir=/usr/vice/etc}
1751 else
1752     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1753     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1754     afskerneldir=${afskerneldir='${libdir}/openafs'}
1755     afssrvbindir=${afssrvbindir='${bindir}'}
1756     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1757     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1758     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1759     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1760     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1761     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1762     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1763     afsdatadir=${afsdatadir='${datadir}/openafs'}
1764 fi
1765 AC_SUBST(afsconfdir)
1766 AC_SUBST(viceetcdir)
1767 AC_SUBST(afskerneldir)
1768 AC_SUBST(afssrvbindir)
1769 AC_SUBST(afssrvsbindir)
1770 AC_SUBST(afssrvlibexecdir)
1771 AC_SUBST(afsdbdir)
1772 AC_SUBST(afslogsdir)
1773 AC_SUBST(afslocaldir)
1774 AC_SUBST(afsbackupdir)
1775 AC_SUBST(afsbosconfigdir)
1776 AC_SUBST(afsdatadir)
1777
1778 if test "x$enable_kernel_module" = "xyes"; then
1779 ENABLE_KERNEL_MODULE=libafs
1780 fi
1781
1782 if test "x$enable_pthreaded_ubik" = "xyes"; then
1783 ENABLE_PTHREADED_UBIK=yes
1784 fi
1785
1786 AC_SUBST(VFSCK)
1787 AC_SUBST(AFS_SYSNAME)
1788 AC_SUBST(AFS_PARAM_COMMON)
1789 AC_SUBST(ENABLE_KERNEL_MODULE)
1790 AC_SUBST(ENABLE_PTHREADED_UBIK)
1791 AC_SUBST(LIB_AFSDB)
1792 AC_SUBST(LINUX_KERNEL_PATH)
1793 AC_SUBST(LINUX_KERNEL_BUILD)
1794 AC_SUBST(HOST_CPU)
1795 AC_SUBST(BSD_KERNEL_PATH)
1796 AC_SUBST(BSD_KERNEL_BUILD)
1797 AC_SUBST(LINUX_VERSION)
1798 AC_SUBST(MKAFS_OSTYPE)
1799 AC_SUBST(TOP_OBJDIR)
1800 AC_SUBST(TOP_SRCDIR)
1801 AC_SUBST(TOP_INCDIR)
1802 AC_SUBST(TOP_LIBDIR)
1803 AC_SUBST(DEST)
1804 AC_SUBST(DARWIN_INFOFILE)
1805 AC_SUBST(IRIX_BUILD_IP35)
1806 AC_SUBST(HTML_XSL)
1807 AC_SUBST(XSLTPROC)
1808 AC_SUBST(DOCBOOK2PDF)
1809 AC_SUBST(DOCBOOK_STYLESHEETS)
1810
1811 OPENAFS_FUSE
1812 OPENAFS_SWIG
1813
1814 TOP_SRCDIR="${srcdir}/src"
1815 dnl
1816 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1817 dnl
1818 case $TOP_SRCDIR in
1819         /*)
1820                 ;;
1821         *)
1822                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1823                 ;;
1824 esac
1825
1826 TOP_OBJDIR="${SRCDIR_PARENT}"
1827 TOP_INCDIR="${SRCDIR_PARENT}/include"
1828 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1829 if test "${DEST}x" = "x"; then
1830         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1831 fi
1832
1833 if test "x$with_crosstools_dir" != "x"; then
1834         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1835                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1836                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1837                 RXGEN_PATH=$with_crosstools_dir/rxgen
1838         else
1839                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1840                 exit 1
1841         fi
1842 else
1843         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1844         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1845         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1846 fi
1847 AC_SUBST(COMPILE_ET_PATH)
1848 AC_SUBST(CONFIGTOOL_PATH)
1849 AC_SUBST(RXGEN_PATH)
1850
1851 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1852 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1853 AC_SUBST(HELPER_SPLINT)
1854 AC_SUBST(HELPER_SPLINTCFG)
1855
1856 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1857
1858 dnl Check to see if crypt lives in a different library
1859 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1860 AC_SUBST(LIB_crypt)
1861
1862 dnl Check to see if the compiler support labels in structs
1863 AC_MSG_CHECKING(for label support in structs)
1864 AC_TRY_COMPILE([], [
1865 extern void osi_UFSOpen(void);
1866 struct labeltest {
1867    void (*open) (void);
1868 };
1869 struct labeltest struct_labeltest = {
1870    .open       = osi_UFSOpen,
1871 }
1872 ],
1873 [AC_MSG_RESULT(yes)
1874  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1875 ],
1876 [AC_MSG_RESULT(no)
1877 ])
1878
1879 AC_MSG_CHECKING([checking for dirfd])
1880 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1881 #ifdef HAVE_DIRENT_H
1882 #include <dirent.h>
1883 #endif
1884 ]],
1885         [[DIR *d = 0; dirfd(d);]])],
1886         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1887 if test "$ac_rk_have_dirfd" = "yes" ; then
1888         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1889 fi
1890 AC_MSG_RESULT($ac_rk_have_dirfd)
1891
1892 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1893 #ifdef HAVE_DIRENT_H
1894 #include <dirent.h>
1895 #endif])
1896
1897 dnl Eventually, this will look for the system one, or for OpenSSL
1898 LIB_hcrypto="-lafshcrypto"
1899 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1900 AC_SUBST(LIB_hcrypto)
1901 AC_SUBST(LDFLAGS_hcrypto)
1902
1903 dnl Check for UUID library
1904 AC_CHECK_HEADERS([uuid/uuid.h])
1905 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1906 AC_CHECK_FUNCS([uuid_generate])
1907 ])
1908
1909
1910 AC_DEFUN([SUMMARY], [
1911     # Print a configuration summary
1912 echo
1913 echo "**************************************"
1914 echo configure summary
1915 echo
1916 AS_IF([test $LIB_curses],[
1917 echo "LIB_curses :                $LIB_curses" ],[
1918 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1919 ])
1920 echo
1921 echo "**************************************"
1922 ])