afs: Add xvcache-related afs_FlushVCache comments
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #    define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 # define _FILE_OFFSET_BITS 64
48 # define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 # include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])
76 ])
77
78 dnl General feature options.
79 AC_ARG_ENABLE([gtx],
80     [AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools])])
81
82 AC_ARG_ENABLE([uss],
83     [AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool])])
84 AC_ARG_ENABLE([namei-fileserver],
85     [AS_HELP_STRING([--enable-namei-fileserver],
86         [force compilation of namei fileserver in preference to inode
87          fileserver])],
88     [],
89     [enable_namei_fileserver="default"])
90 AC_ARG_ENABLE([supergroups],
91     [AS_HELP_STRING([--enable-supergroups],
92         [enable support for nested pts groups])],
93     [],
94     [enable_supergroups="no"])
95 AC_ARG_ENABLE([bitmap-later],
96     [AS_HELP_STRING([--enable-bitmap-later],
97         [enable fast startup of file server by not reading bitmap till
98          needed])],
99     [AS_IF([test x"$withval" = xyes],
100         [AC_MSG_WARN([bitmap-later is only used by non-demand-attach
101             fileservers.  Please migrate to demand-attach instead.])])],
102     [enable_bitmap_later="no"])
103 AC_ARG_ENABLE([unix-sockets],
104     [AS_HELP_STRING([--disable-unix-sockets],
105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
106     [],
107     [enable_unix_sockets="yes"])
108 AC_ARG_ENABLE([tivoli-tsm],
109     [AS_HELP_STRING([--enable-tivoli-tsm],
110         [enable use of the Tivoli TSM API libraries for butc support])],
111     [],
112     [enable_tivoli_tsm="no"])
113 AC_ARG_ENABLE([pthreaded-ubik],
114     [AS_HELP_STRING([--disable-pthreaded-ubik],
115         [disable installation of pthreaded ubik applications (defaults to
116          enabled)])],
117     [],
118     [enable_pthreaded_ubik="yes"])
119
120 dnl Kernel module build options.
121 AC_ARG_WITH([linux-kernel-headers],
122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
123         [use the kernel headers found at path (optional, defaults to
124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])
126 ])
127 AC_ARG_WITH([linux-kernel-build],
128     [AS_HELP_STRING([--with-linux-kernel-build=path],
129         [use the kernel build found at path(optional, defaults to
130         kernel headers path)]
131 )])
132 AC_ARG_WITH([bsd-kernel-headers],
133     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
134         [use the kernel headers found at path (optional, defaults to
135          /usr/src/sys)])
136 ])
137 AC_ARG_WITH([bsd-kernel-build],
138     [AS_HELP_STRING([--with-bsd-kernel-build=path],
139         [use the kernel build found at path (optional, defaults to
140          KSRC/i386/compile/GENERIC)])
141 ])
142 AC_ARG_WITH([linux-kernel-packaging],
143     [AS_HELP_STRING([--with-linux-kernel-packaging],
144         [use standard naming conventions to aid Linux kernel build packaging
145          (disables MPS, sets the kernel module name to openafs.ko, and
146          installs kernel modules into the standard Linux location)])],
147     [AC_SUBST([LINUX_KERNEL_PACKAGING], [yes])
148      AC_SUBST([LINUX_LIBAFS_NAME], [openafs])],
149     [AC_SUBST([LINUX_LIBAFS_NAME], [libafs])
150 ])
151 AC_ARG_ENABLE([kernel-module],
152     [AS_HELP_STRING([--disable-kernel-module],
153         [disable compilation of the kernel module (defaults to enabled)])],
154     [],
155     [enable_kernel_module="yes"])
156 AC_ARG_ENABLE([redhat-buildsys],
157     [AS_HELP_STRING([--enable-redhat-buildsys],
158         [enable compilation of the redhat build system kernel (defaults to
159          disabled)])],
160     [],
161     [enable_redhat_buildsys="no"])
162
163 dnl Installation locations.
164 AC_ARG_ENABLE([transarc-paths],
165     [AS_HELP_STRING([--enable-transarc-paths],
166         [use Transarc style paths like /usr/afs and /usr/vice])],
167     [],
168     [enable_transarc_paths="no"])
169
170 dnl Deprecated crypto
171 AC_ARG_ENABLE([kauth],
172     [AS_HELP_STRING([--enable-kauth],
173         [install the deprecated kauth server, pam modules, and utilities
174          (defaults to disabled)])],
175     [enable_pam="yes"],
176     [enable_kauth="no"
177      enable_pam="no"])
178
179 dnl Optimization and debugging flags.
180 AC_ARG_ENABLE([strip-binaries],
181     [AS_HELP_STRING([--disable-strip-binaries],
182         [disable stripping of symbol information from binaries (defaults to
183          enabled)])],
184     [],
185     [enable_strip_binaries="maybe"])
186 AC_ARG_ENABLE([debug],
187     [AS_HELP_STRING([--enable-debug],
188         [enable compilation of the user space code with debugging information
189          (defaults to disabled)])],
190     [],
191     [enable_debug="no"])
192 AC_ARG_ENABLE([optimize],
193     [AS_HELP_STRING([--disable-optimize],
194         [disable optimization for compilation of the user space code (defaults
195          to enabled)])],
196     [],
197     [enable_optimize="yes"])
198 AC_ARG_ENABLE([warnings],
199     [AS_HELP_STRING([--enable-warnings],
200         [enable compilation warnings when building with gcc (defaults to
201          disabled)])],
202     [],
203     [enable_warnings="no"])
204 AC_ARG_ENABLE([checking],
205     [AS_HELP_STRING([--enable-checking],
206         [turn compilation warnings into errors when building with gcc (defaults
207          to disabled)])],
208     [enable_checking="$enableval"],
209     [enable_checking="no"])
210 AC_ARG_ENABLE([debug-locks],
211     [AS_HELP_STRING([--enable-debug-locks],
212         [turn on lock debugging assertions (defaults to disabled)])],
213     [enable_debug_locks="$enableval"],
214     [enable_debug_locks="no"])
215 AC_ARG_ENABLE([debug-kernel],
216     [AS_HELP_STRING([--enable-debug-kernel],
217         [enable compilation of the kernel module with debugging information
218          (defaults to disabled)])],
219     [],
220     [enable_debug_kernel="no"])
221 AC_ARG_ENABLE([optimize-kernel],
222     [AS_HELP_STRING([--disable-optimize-kernel],
223         [disable compilation of the kernel module with optimization (defaults
224          based on platform)])],
225     [],
226     [enable_optimize_kernel=""])
227 AC_ARG_ENABLE([debug-lwp],
228     [AS_HELP_STRING([--enable-debug-lwp],
229         [enable compilation of the LWP code with debugging information
230          (defaults to disabled)])],
231     [],
232     [enable_debug_lwp="no"])
233 AC_ARG_ENABLE([optimize-lwp],
234     [AS_HELP_STRING([--disable-optimize-lwp],
235         [disable optimization for compilation of the LWP code (defaults to
236          enabled)])],
237     [],
238     [enable_optimize_lwp="yes"])
239 AC_ARG_ENABLE([debug-pam],
240     [AS_HELP_STRING([--enable-debug-pam],
241         [enable compilation of the PAM code with debugging information
242          (defaults to disabled)])],
243     [],
244     [enable_debug_pam="no"])
245 AC_ARG_ENABLE([optimize-pam],
246     [AS_HELP_STRING([--disable-optimize-pam],
247         [disable optimization for compilation of the PAM code (defaults to
248          enabled)])],
249     [],
250     [enable_optimize_pam="yes"])
251 AC_ARG_ENABLE([linux-syscall-probing],
252     [AS_HELP_STRING([--enable-linux-syscall-probing],
253         [enable Linux syscall probing (defaults to autodetect)])],
254     [],
255     [enable_linux_syscall_probing="maybe"])
256 AC_ARG_WITH([crosstools-dir],
257     [AS_HELP_STRING([--with-crosstools-dir=path],
258         [use path for native versions of rxgen, compile_et and config])
259 ])
260
261 AC_ARG_WITH([xslt-processor],
262         AS_HELP_STRING([--with-xslt-processor=ARG],
263         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
264         [XSLTPROC="$withval"],
265         [AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo])])
266
267 AC_ARG_WITH([html-xsl],
268         AS_HELP_STRING([--with-html-xsl],
269         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
270         [HTML_XSL="$withval"],
271         [HTML_XSL="html/chunk.xsl"])
272
273 AC_ARG_WITH([docbook2pdf],
274         AS_HELP_STRING([--with-docbook2pdf=ARG],
275         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
276         [DOCBOOK2PDF="$withval"],
277         [AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo])])
278
279 AC_ARG_WITH([docbook-stylesheets],
280         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
281         [location of DocBook stylesheets (default is to search a set of likely paths)]),
282         [DOCBOOK_STYLESHEETS="$withval"],
283         [OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS],
284                 [/usr/share/xml/docbook/stylesheet/nwalsh/current \
285                  /usr/share/xml/docbook/stylesheet/nwalsh \
286                  /usr/share/xml/docbook/xsl-stylesheets \
287                  /usr/share/sgml/docbook/docbook-xsl-stylesheets \
288                  /usr/share/sgml/docbook/xsl-stylesheets \
289                  /usr/share/docbook-xsl \
290                  /usr/share/sgml/docbkxsl \
291                  /usr/local/share/xsl/docbook \
292                  /sw/share/xml/xsl/docbook-xsl \
293                  /opt/local/share/xsl/docbook-xsl],
294                 [$HTML_XSL])
295            AS_IF([test "x$DOCBOOK_STYLESHEETS" = "x"],
296                 [AC_WARN([Docbook stylesheets not found; some documentation can't be built])
297            ])
298         ])
299
300 AC_ARG_WITH([dot],
301         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
302         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
303         [], [with_dot="maybe"])
304
305 enable_login="no"
306
307 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
308 dnl documentation build.
309 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
310 AC_CHECK_PROGS([DOXYGEN], [doxygen])
311
312 dnl Optionally generate graphs with doxygen.
313 case "$with_dot" in
314 maybe)
315     AC_CHECK_PROGS([DOT], [dot])
316     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
317     ;;
318 yes)
319     HAVE_DOT="yes"
320     ;;
321 no)
322     HAVE_DOT="no"
323     ;;
324 *)
325     HAVE_DOT="yes"
326     DOT_PATH=$with_dot
327 esac
328 AC_SUBST(HAVE_DOT)
329 AC_SUBST(DOT_PATH)
330
331 dnl Checks for UNIX variants.
332 AC_ISC_POSIX
333
334 dnl Various compiler setup.
335 AC_TYPE_PID_T
336 AC_TYPE_SIZE_T
337
338 dnl Checks for programs.
339 AC_PROG_INSTALL
340 AC_PROG_LN_S
341 AC_PROG_RANLIB
342 AC_PROG_YACC
343 AM_PROG_LEX
344 dnl if we are flex, be lex-compatible
345 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
346
347 OPENAFS_FORCE_ABS_INSTALL
348 OPENAFS_CHECK_BIGENDIAN
349 OPENAFS_PRINTF_TAKES_Z_LEN
350
351 AC_MSG_CHECKING(your OS)
352 system=$host
353 case $system in
354         *-linux*)
355
356                 MKAFS_OSTYPE=LINUX
357                 if test "x$enable_redhat_buildsys" = "xyes"; then
358                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
359                 fi
360                 if test "x$enable_kernel_module" = "xyes"; then
361                  if test "x$with_linux_kernel_headers" != "x"; then
362                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
363                  else
364                    for utsdir in "/lib/modules/`uname -r`/build" \
365                                  "/lib/modules/`uname -r`/source" \
366                                  "/usr/src/linux-2.4" \
367                                  "/usr/src/linux"; do
368                      LINUX_KERNEL_PATH="$utsdir"
369                      for utsfile in "include/generated/utsrelease.h" \
370                                     "include/linux/utsrelease.h" \
371                                     "include/linux/version.h" \
372                                     "include/linux/version-up.h"; do
373                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
374                          break 2
375                        fi
376                      done
377                    done
378                  fi
379                  if test "x$with_linux_kernel_build" != "x"; then
380                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
381                  else
382                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
383                  fi
384                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
385                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
386                    LINUX_VERSION="$linux_kvers"
387                  else
388                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
389                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
390                      LINUX_VERSION="$linux_kvers"
391                    else
392                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
393                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
394                        if test "x$linux_kvers" = "x"; then
395                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
396                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
397                            if test "x$linux_kvers" = "x"; then
398                              AC_MSG_ERROR(Linux headers lack version definition [2])
399                              exit 1
400                            else
401                              LINUX_VERSION="$linux_kvers"
402                            fi
403                          else
404                            AC_MSG_ERROR(Linux headers lack version definition)
405                            exit 1
406                          fi
407                        else
408                          LINUX_VERSION="$linux_kvers"
409                        fi
410                      else
411                        enable_kernel_module="no"
412                      fi
413                    fi
414                  fi
415                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
416                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
417                      enable_kernel_module="no"
418                  fi
419                  if test "x$enable_kernel_module" = "xno"; then
420                   if test "x$with_linux_kernel_headers" != "x"; then
421                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
422                    exit 1
423                   else
424                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
425                   fi
426                  fi
427                  dnl do we need to determine SUBARCH from autoconf.h
428                  SUBARCH=default
429                 fi
430                 AC_MSG_RESULT(linux)
431                 if test "x$enable_kernel_module" = "xyes"; then
432                  case "$LINUX_VERSION" in
433                   2.2.*) AFS_SYSKVERS=22 ;;
434                   2.4.*) AFS_SYSKVERS=24 ;;
435                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
436                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
437                  esac
438                 fi
439                 ;;
440         *-solaris*)
441                 MKAFS_OSTYPE=SOLARIS
442                 AC_MSG_RESULT(sun4)
443                 AC_PATH_PROG(SOLARISCC, [cc], ,
444                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
445                 if test "x$SOLARISCC" = "x" ; then
446                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
447                 fi
448                 SOLARIS_UFSVFS_HAS_DQRWLOCK
449                 SOLARIS_FS_HAS_FS_ROLLED
450                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
451                 SOLARIS_HAVE_VN_RENAMEPATH
452                 ;;
453         *-sunos*)
454                 MKAFS_OSTYPE=SUNOS
455                 enable_kernel_module=no
456                 AC_MSG_RESULT(sun4)
457                 ;;
458         *-hpux*)
459                 MKAFS_OSTYPE=HPUX
460                 AC_MSG_RESULT(hp_ux)
461                 if test -f "/usr/old/usr/include/ndir.h"; then
462                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
463                 fi
464                 ;;
465         *-irix*)
466                 if test -d /usr/include/sys/SN/SN1; then
467                  IRIX_BUILD_IP35="IP35"
468                 fi
469                 MKAFS_OSTYPE=IRIX
470                 AC_MSG_RESULT(sgi)
471                 ;;
472         *-aix*)
473                 MKAFS_OSTYPE=AIX
474                 AC_MSG_RESULT(rs_aix)
475                 ;;
476         arm-*-darwin*)
477                 MKAFS_OSTYPE=DARWIN
478                 AC_MSG_RESULT(arm_darwin)
479                 ;;
480         powerpc-*-darwin*)
481                 MKAFS_OSTYPE=DARWIN
482                 AC_MSG_RESULT(ppc_darwin)
483                 ;;
484         i386-*-darwin*)
485                 MKAFS_OSTYPE=DARWIN
486                 AC_MSG_RESULT(x86_darwin)
487                 ;;
488         x86_64-*-darwin*)
489                 MKAFS_OSTYPE=DARWIN
490                 AC_MSG_RESULT(x86_darwin)
491                 ;;
492         i386-*-freebsd*)
493                 MKAFS_OSTYPE=FBSD
494                 AC_MSG_RESULT(i386_fbsd)
495                 ;;
496         x86_64-*-freebsd*)
497                 MKAFS_OSTYPE=FBSD
498                 AC_MSG_RESULT(amd64_fbsd)
499                 ;;
500         *-netbsd*)
501                 MKAFS_OSTYPE=NBSD
502                 AC_MSG_RESULT(nbsd)
503                 ;;
504         x86_64-*-openbsd*)
505                 MKAFS_OSTYPE=OBSD
506                 AC_MSG_RESULT(amd64_obsd)
507                 ;;
508         i386-*-openbsd*)
509                 MKAFS_OSTYPE=OBSD
510                 AC_MSG_RESULT(i386_obsd)
511                 ;;
512         *-dragonfly*)
513                 MKAFS_OSTYPE=DFBSD
514                 AC_MSG_RESULT(i386_dfbsd)
515                 ;;
516         *)
517                 AC_MSG_RESULT($system)
518                 ;;
519 esac
520
521 if test "x$with_afs_sysname" != "x"; then
522         AFS_SYSNAME="$with_afs_sysname"
523 else
524         AC_MSG_CHECKING(your AFS sysname)
525         case $host in
526                 i?86-*-openbsd?.?)
527                         v=${host#*openbsd}
528                         vM=${v%.*}
529                         vm=${v#*.}
530                         AFS_SYSNAME="i386_obsd${vM}${vm}"
531                         ;;
532                 sparc64-*-openbsd?.?)
533                         v=${host#*openbsd}
534                         vM=${v%.*}
535                         vm=${v#*.}
536                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
537                         ;;
538                 x86_64-*-openbsd?.?)
539                         v=${host#*openbsd}
540                         vM=${v%.*}
541                         vm=${v#*.}
542                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
543                         ;;
544                 i?86-*-freebsd*.*)
545                         v=${host#*freebsd}
546                         vM=${v%.*}
547                         vm=${v#*.}
548                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
549                         ;;
550                 x86_64-*-freebsd*.*)
551                         v=${host#*freebsd}
552                         vM=${v%.*}
553                         vm=${v#*.}
554                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
555                         ;;
556                 i386-*-dragonfly?.*)
557                         v=${host#*dragonfly}
558                         vM=${v%.*}
559                         vm=${v#*.}
560                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
561                         ;;
562                 i?86-*-netbsd*1.6[[M-Z]]*)
563                         AFS_SYSNAME="i386_nbsd20"
564                         ;;
565                 powerpc-*-netbsd*1.6[[M-Z]]*)
566                         AFS_SYSNAME="ppc_nbsd20"
567                         ;;
568                 *-*-netbsd*)
569                         arch=${host%%-unknown*}
570                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
571                                                -e 's/powerpc/ppc/g')
572                         v=${host#*netbsd}
573                         v=${v#*aout}
574                         v=${v#*ecoff}
575                         v=${v#*elf}
576                         vM=${v%%.*}
577                         vM=${vM%.*}
578                         v=${v#*.}
579                         vm=${v%%.*}
580                         vm=${vm%.*}
581                         vm=${vm%%[[_A-Z]]*}
582                         if test $vm -eq 99 ; then
583                                 vM=$((vM+1))
584                         fi
585                         if test $vM -gt 1 ; then
586                                 vm=0
587                         fi
588                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
589                         ;;
590                 hppa*-hp-hpux11.0*)
591                         AFS_SYSNAME="hp_ux110"
592                         ;;
593                 hppa*-hp-hpux11.11)
594                         AFS_SYSNAME="hp_ux11i"
595                         ;;
596                 hppa*-hp-hpux11.23)
597                         AFS_SYSNAME="hp_ux1123"
598                         ;;
599                 ia64-hp-hpux11.22)
600                         AFS_SYSNAME="ia64_hpux1122"
601                         ;;
602                 ia64-hp-hpux*)
603                         AFS_SYSNAME="ia64_hpux1123"
604                         ;;
605                 hppa*-hp-hpux10*)
606                         AFS_SYSNAME="hp_ux102"
607                         ;;
608                 powerpc-apple-darwin7*)
609                         AFS_SYSNAME="ppc_darwin_70"
610                         OSXSDK="macosx10.3"
611                         ;;
612                 powerpc-apple-darwin8.*)
613                         AFS_SYSNAME="ppc_darwin_80"
614                         OSXSDK="macosx10.4"
615                         ;;
616                 i386-apple-darwin8.*)
617                         AFS_SYSNAME="x86_darwin_80"
618                         OSXSDK="macosx10.4"
619                         ;;
620                 powerpc-apple-darwin9.*)
621                         AFS_SYSNAME="ppc_darwin_90"
622                         OSXSDK="macosx10.5"
623                         ;;
624                 i386-apple-darwin9.*)
625                         AFS_SYSNAME="x86_darwin_90"
626                         OSXSDK="macosx10.5"
627                         ;;
628                 i?86-apple-darwin10.*)
629                         AFS_SYSNAME="x86_darwin_100"
630                         OSXSDK="macosx10.6"
631                         ;;
632                 x86_64-apple-darwin10.*)
633                         AFS_SYSNAME="x86_darwin_100"
634                         OSXSDK="macosx10.6"
635                         ;;
636                 arm-apple-darwin10.*)
637                         AFS_SYSNAME="arm_darwin_100"
638                         OSXSDK="iphoneos4.0"
639                         ;;
640                 x86_64-apple-darwin11.*)
641                         AFS_SYSNAME="x86_darwin_110"
642                         OSXSDK="macosx10.7"
643                         ;;
644                 i?86-apple-darwin11.*)
645                         AFS_SYSNAME="x86_darwin_110"
646                         OSXSDK="macosx10.7"
647                         ;;
648                 x86_64-apple-darwin12.*)
649                         AFS_SYSNAME="x86_darwin_120"
650                         OSXSDK="macosx10.8"
651                         ;;
652                 i?86-apple-darwin12.*)
653                         AFS_SYSNAME="x86_darwin_120"
654                         OSXSDK="macosx10.8"
655                         ;;
656                 x86_64-apple-darwin13.*)
657                         AFS_SYSNAME="x86_darwin_130"
658                         OSXSDK="macosx10.9"
659                         ;;
660                 i?86-apple-darwin13.*)
661                         AFS_SYSNAME="x86_darwin_130"
662                         OSXSDK="macosx10.9"
663                         ;;
664                 x86_64-apple-darwin14.*)
665                         AFS_SYSNAME="x86_darwin_140"
666                         OSXSDK="macosx10.10"
667                         ;;
668                 i?86-apple-darwin14.*)
669                         AFS_SYSNAME="x86_darwin_140"
670                         OSXSDK="macosx10.10"
671                         ;;
672                 sparc-sun-solaris2.8)
673                         AFS_SYSNAME="sun4x_58"
674                         ;;
675                 sparc-sun-solaris2.9)
676                         AFS_SYSNAME="sun4x_59"
677                         ;;
678                 sparc-sun-solaris2.10)
679                         AFS_SYSNAME="sun4x_510"
680                         ;;
681                 sparc-sun-solaris2.11)
682                         AFS_SYSNAME="sun4x_511"
683                         ;;
684                 i386-pc-solaris2.8)
685                         AFS_SYSNAME="sunx86_58"
686                         ;;
687                 i386-pc-solaris2.9)
688                         AFS_SYSNAME="sunx86_59"
689                         ;;
690                 i386-pc-solaris2.10)
691                         AFS_SYSNAME="sunx86_510"
692                         ;;
693                 i386-pc-solaris2.11)
694                         AFS_SYSNAME="sunx86_511"
695                         ;;
696                 alpha*-dec-osf4.0*)
697                         AFS_SYSNAME="alpha_dux40"
698                         ;;
699                 alpha*-dec-osf5.0*)
700                         AFS_SYSNAME="alpha_dux50"
701                         ;;
702                 alpha*-dec-osf5.1*)
703                         AFS_SYSNAME="alpha_dux51"
704                         ;;
705                 mips-sgi-irix6.5)
706                         AFS_SYSNAME="sgi_65"
707                         enable_pam="no"
708                         ;;
709                 ia64-*-linux*)
710                         AFS_SYSNAME="ia64_linuxXX"
711                         ;;
712                 powerpc-*-linux*)
713                         AFS_SYSNAME="`/bin/arch`_linuxXX"
714                         ;;
715                 powerpc64-*-linux*)
716                         AFS_SYSNAME="ppc64_linuxXX"
717                         ;;
718                 alpha*-linux*)
719                         AFS_SYSNAME="alpha_linux_XX"
720                         ;;
721                 s390-*-linux*)
722                         AFS_SYSNAME="s390_linuxXX"
723                         ;;
724                 s390x-*-linux*)
725                         AFS_SYSNAME="s390x_linuxXX"
726                         ;;
727                 sparc-*-linux*)
728                         AFS_SYSNAME="`/bin/arch`_linuxXX"
729                         ;;
730                 sparc64-*-linux*)
731                         AFS_SYSNAME="sparc64_linuxXX"
732                         ;;
733                 i?86-*-linux*)
734                         AFS_SYSNAME="i386_linuxXX"
735                         ;;
736                 arm*-linux*)
737                         AFS_SYSNAME="arm_linuxXX"
738                         ;;
739                 parisc-*-linux-gnu|hppa-*-linux-gnu)
740                         AFS_SYSNAME="parisc_linuxXX"
741                         enable_pam="no"
742                         ;;
743                 power*-ibm-aix4.2*)
744                         AFS_SYSNAME="rs_aix42"
745                         enable_pam="no"
746                         ;;
747                 power*-ibm-aix4.3*)
748                         AFS_SYSNAME="rs_aix42"
749                         enable_pam="no"
750                         ;;
751                 power*-ibm-aix5.1*)
752                         AFS_SYSNAME="rs_aix51"
753                         enable_pam="no"
754                         ;;
755                 power*-ibm-aix5.2*)
756                         AFS_SYSNAME="rs_aix52"
757                         enable_pam="no"
758                         ;;
759                 power*-ibm-aix5.3*)
760                         AFS_SYSNAME="rs_aix53"
761                         enable_pam="no"
762                         ;;
763                 power*-ibm-aix6.1*)
764                         AFS_SYSNAME="rs_aix61"
765                         enable_pam="no"
766                         ;;
767                 x86_64-*-linux-gnu)
768                         AFS_SYSNAME="amd64_linuxXX"
769                         enable_pam="yes"
770                         ;;
771                 *)
772                         AC_MSG_ERROR(An AFS sysname is required)
773                         exit 1
774                         ;;
775         esac
776         case $AFS_SYSNAME in
777                 *_linux* | *_umlinux*)
778                         if test "x${AFS_SYSKVERS}" = "x"; then
779                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
780                         fi
781                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
782                         AFS_SYSNAME="$_AFS_SYSNAME"
783                         AC_TRY_KBUILD(
784                          [],
785                          [#ifndef CONFIG_USERMODE
786                           #error not UML
787                           #endif],
788                          ac_cv_linux_is_uml=yes,)
789                         if test "${ac_cv_linux_is_uml}" = yes; then
790                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
791                         fi
792                         AFS_SYSNAME="$_AFS_SYSNAME"
793                         ;;
794         esac
795         AC_MSG_RESULT($AFS_SYSNAME)
796 fi
797
798 case $AFS_SYSNAME in
799         *_darwin*)
800                 AC_CHECK_HEADERS(crt_externs.h)
801                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
802                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
803                 AC_SUBST(OSXSDK)
804                 ;;
805 esac
806
807 dnl Some hosts have a separate common param file they should include.  Figure
808 dnl out if we're on one of them now that we know the sysname.
809 case $AFS_SYSNAME in
810     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
811     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
812     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
813     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
814     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
815     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
816     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
817     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
818     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
819     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
820     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
821     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
822     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
823     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
824     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
825     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
826     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
827     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
828     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
829     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
830     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
831     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
832     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
833     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
834     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
835     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
836     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
837     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
838     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
839     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
840     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
841     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
842     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
843     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
844     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
845     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
846 # Linux alpha adds an extra underscore for no good reason.
847     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
848     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
849     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
850     *_fbsd_*)   AFS_PARAM_COMMON=param.generic_fbsd.h ;;
851 esac
852
853 OPENAFS_OSCONF
854
855 case $AFS_SYSNAME in *_linux* | *_umlinux*)
856
857                 # Add (sub-) architecture-specific paths needed by conftests
858                 case $AFS_SYSNAME  in
859                         *_umlinux26)
860                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
861                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
862                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
863                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
864                 esac
865
866                 if test "x$enable_kernel_module" = "xyes"; then
867                  if test "x$enable_debug_kernel" = "xno"; then
868                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
869                  fi
870                  OPENAFS_GCC_SUPPORTS_MARCH
871                  AC_SUBST(P5PLUS_KOPTS)
872                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
873                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
874                  OPENAFS_GCC_SUPPORTS_NO_COMMON
875                  OPENAFS_GCC_SUPPORTS_PIPE
876                  AC_SUBST(LINUX_GCC_KOPTS)
877
878                  dnl Setup the kernel build environment
879                  LINUX_KBUILD_USES_EXTRA_CFLAGS
880                  LINUX_KERNEL_COMPILE_WORKS
881
882                  dnl Check for header files
883                  AC_CHECK_LINUX_HEADER([config.h])
884                  AC_CHECK_LINUX_HEADER([completion.h])
885                  AC_CHECK_LINUX_HEADER([exportfs.h])
886                  AC_CHECK_LINUX_HEADER([freezer.h])
887                  AC_CHECK_LINUX_HEADER([key-type.h])
888                  AC_CHECK_LINUX_HEADER([semaphore.h])
889                  AC_CHECK_LINUX_HEADER([seq_file.h])
890
891                  dnl Type existence checks
892                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
893                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
894
895                  dnl Check for structure elements
896                  AC_CHECK_LINUX_STRUCT([address_space_operations],
897                                        [write_begin], [fs.h])
898                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
899                                        [backing-dev.h])
900                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
901                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
902                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
903                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
904                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
905                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
906                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
907                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
908                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
909                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
910                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
911                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
912                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
913                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
914                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
915                  AC_CHECK_LINUX_STRUCT([key_type], [match_preparse], [key-type.h])
916                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
917                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
918                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
919                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
920                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
921                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
922                                        [fs.h])
923                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
924                                        [fs.h])
925                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
926                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
927                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
928                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
929                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
930                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
931                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
932                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
933                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
934                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
935                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
936
937                  dnl Check for typed structure elements
938                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
939                                              [buf], [fs.h])
940
941                  dnl Function existence checks
942
943                  AC_CHECK_LINUX_FUNC([bdi_init],
944                                      [#include <linux/backing-dev.h>],
945                                      [bdi_init(NULL);])
946                  AC_CHECK_LINUX_FUNC([PageChecked],
947                                      [#include <linux/mm.h>
948 #include <linux/page-flags.h>],
949                                      [struct page *_page;
950                                       int bchecked = PageChecked(_page);])
951                  AC_CHECK_LINUX_FUNC([PageFsMisc],
952                                      [#include <linux/mm.h>
953 #include <linux/page-flags.h>],
954                                      [struct page *_page;
955                                       int bchecked = PageFsMisc(_page);])
956                  AC_CHECK_LINUX_FUNC([clear_inode],
957                                      [#include <linux/fs.h>],
958                                      [clear_inode(NULL);])
959                  AC_CHECK_LINUX_FUNC([current_kernel_time],
960                                      [#include <linux/time.h>],
961                                      [struct timespec s;
962                                       s = current_kernel_time();])
963                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
964                                      [#include <linux/fs.h>],
965                                      [d_alloc_anon(NULL);])
966                  AC_CHECK_LINUX_FUNC([d_count],
967                                      [#include <linux/dcache.h>],
968                                      [d_count(NULL);])
969                  AC_CHECK_LINUX_FUNC([d_make_root],
970                                      [#include <linux/fs.h>],
971                                      [d_make_root(NULL);])
972                  AC_CHECK_LINUX_FUNC([do_sync_read],
973                                      [#include <linux/fs.h>],
974                                      [do_sync_read(NULL, NULL, 0, NULL);])
975                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
976                                      [#include <linux/sched.h>],
977                                      [pid_t p; find_task_by_pid(p);])
978                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
979                                      [#include <linux/fs.h>],
980                                      [generic_file_aio_read(NULL,NULL,0,0);])
981                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
982                                      [#include <linux/pagemap.h>],
983                                      [grab_cache_page_write_begin(NULL, 0, 0);])
984                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
985                                      [#include <linux/list.h>],
986                                      [hlist_unhashed(0);])
987                  AC_CHECK_LINUX_FUNC([i_size_read],
988                                      [#include <linux/fs.h>],
989                                      [i_size_read(NULL);])
990                  AC_CHECK_LINUX_FUNC([inode_setattr],
991                                      [#include <linux/fs.h>],
992                                      [inode_setattr(NULL, NULL);])
993                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
994                                      [#include <linux/fs.h>],
995                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
996                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
997                                      [#include <linux/net.h>],
998                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
999                  AC_CHECK_LINUX_FUNC([page_follow_link],
1000                                      [#include <linux/fs.h>],
1001                                      [page_follow_link(0,0);])
1002                  AC_CHECK_LINUX_FUNC([page_offset],
1003                                      [#include <linux/pagemap.h>],
1004                                      [page_offset(NULL);])
1005                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
1006                                      [#include <linux/pagevec.h>],
1007                                      [__pagevec_lru_add_file(NULL);])
1008                  AC_CHECK_LINUX_FUNC([path_lookup],
1009                                      [#include <linux/fs.h>
1010                                       #include <linux/namei.h>],
1011                                      [path_lookup(NULL, 0, NULL);])
1012                  AC_CHECK_LINUX_FUNC([proc_create],
1013                                      [#include <linux/proc_fs.h>],
1014                                      [proc_create(NULL, 0, NULL, NULL);])
1015                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
1016                                      [#include <linux/rcupdate.h>],
1017                                      [rcu_read_lock();])
1018                  AC_CHECK_LINUX_FUNC([set_nlink],
1019                                      [#include <linux/fs.h>],
1020                                      [set_nlink(NULL, 1);])
1021                  AC_CHECK_LINUX_FUNC([sock_create_kern],
1022                                      [#include <linux/net.h>],
1023                                      [sock_create_kern(0, 0, 0, NULL);])
1024                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
1025                                      [#include <linux/splice.h>],
1026                                      [splice_direct_to_actor(NULL,NULL,NULL);])
1027                  AC_CHECK_LINUX_FUNC([svc_addr_in],
1028                                      [#include <linux/sunrpc/svc.h>],
1029                                      [svc_addr_in(NULL);])
1030                  AC_CHECK_LINUX_FUNC([zero_user_segments],
1031                                      [#include <linux/highmem.h>],
1032                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1033                  AC_CHECK_LINUX_FUNC([noop_fsync],
1034                                      [#include <linux/fs.h>],
1035                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1036                  AC_CHECK_LINUX_FUNC([kthread_run],
1037                                      [#include <linux/kernel.h>
1038                                       #include <linux/kthread.h>],
1039                                      [kthread_run(NULL, NULL, "test");])
1040
1041                  dnl Consequences - things which get set as a result of the
1042                  dnl                above tests
1043                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1044                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1045                                   [define to disable the nfs translator])])
1046
1047                  dnl Assorted more complex tests
1048                  LINUX_AIO_NONVECTOR
1049                  LINUX_EXPORTS_PROC_ROOT_FS
1050                  LINUX_KMEM_CACHE_INIT
1051                  LINUX_HAVE_KMEM_CACHE_T
1052                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1053                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1054                  LINUX_D_PATH_TAKES_STRUCT_PATH
1055                  LINUX_NEW_EXPORT_OPS
1056                  LINUX_INODE_SETATTR_RETURN_TYPE
1057                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1058                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1059                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1060                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1061                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1062                  LINUX_DOP_D_DELETE_TAKES_CONST
1063                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1064                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1065                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1066                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1067                  LINUX_AOP_WRITEBACK_CONTROL
1068                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1069                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1070                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1071                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1072                  LINUX_KERNEL_SOCK_CREATE
1073                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1074                  LINUX_NEED_RHCONFIG
1075                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1076                  LINUX_EXPORTS_TASKLIST_LOCK
1077                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1078                  LINUX_STATFS_TAKES_DENTRY
1079                  LINUX_REFRIGERATOR
1080                  LINUX_HAVE_TRY_TO_FREEZE
1081                  LINUX_LINUX_KEYRING_SUPPORT
1082                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1083                  LINUX_KEY_ALLOC_NEEDS_CRED
1084                  LINUX_INIT_WORK_HAS_DATA
1085                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1086                  LINUX_HAVE_DCACHE_LOCK
1087                  LINUX_D_COUNT_IS_INT
1088                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1089                  LINUX_IOP_CREATE_TAKES_UMODE_T
1090                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1091                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1092                  LINUX_DENTRY_OPEN_TAKES_PATH
1093                  LINUX_D_ALIAS_IS_HLIST
1094                  LINUX_HLIST_ITERATOR_NO_NODE
1095                  LINUX_IOP_I_CREATE_TAKES_BOOL
1096                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1097                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1098                  LINUX_D_INVALIDATE_IS_VOID
1099
1100                  dnl If we are guaranteed that keyrings will work - that is
1101                  dnl  a) The kernel has keyrings enabled
1102                  dnl  b) The code is new enough to give us a key_type_keyring
1103                  dnl then we just disable syscall probing unless we've been
1104                  dnl told otherwise
1105
1106                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1107                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1108                           [enable_linux_syscall_probing="no"],
1109                           [enable_linux_syscall_probing="yes"])
1110                  ])
1111
1112                  dnl Syscall probing needs a few tests of its own, and just
1113                  dnl won't work if the kernel doesn't export init_mm
1114                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1115                    LINUX_EXPORTS_INIT_MM
1116                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1117                      AC_MSG_ERROR(
1118                        [Can't do syscall probing without exported init_mm])
1119                    ])
1120                    LINUX_EXPORTS_SYS_CHDIR
1121                    LINUX_EXPORTS_SYS_OPEN
1122                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1123                              [define to enable syscall table probes])
1124                  ])
1125
1126                  dnl Packaging and SMP build
1127                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1128                    LINUX_WHICH_MODULES
1129                  else
1130                    AC_SUBST(MPS,'SP')
1131                  fi
1132
1133                  dnl Syscall probing
1134                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1135                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1136                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1137                    ])
1138                    ac_cv_linux_exports_sys_call_table=no
1139                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1140                      ac_cv_linux_exports_ia32_sys_call_table=yes
1141                    fi
1142                  else
1143                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1144                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1145                    LINUX_EXPORTS_SYS_CALL_TABLE
1146                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1147                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1148                          linux_syscall_method=none
1149                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1150                             linux_syscall_method=scan
1151                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1152                                linux_syscall_method=scan_with_kallsyms_address
1153                             fi
1154                          fi
1155                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1156                             linux_syscall_method=kallsyms_symbol
1157                          fi
1158                          if test "x$linux_syscall_method" = "xnone"; then
1159                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1160                             linux_syscall_method=scan
1161                          fi
1162                    fi
1163                  fi
1164                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1165                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1166                  fi
1167                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1168                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1169                  fi
1170                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1171                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1172                  else
1173                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1174                  fi
1175                 :
1176                 fi
1177 dnl Linux-only, but just enable always.
1178                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1179 esac
1180
1181 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1182     [ac_cv_sync_fetch_and_add],
1183     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1184                     [ac_cv_sync_fetch_and_add=yes],
1185                     [ac_cv_sync_fetch_and_add=no])
1186 ])
1187 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1188       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1189                 [define if your C compiler has __sync_add_and_fetch])])
1190
1191 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1192     [ac_cv_sockaddr_len],
1193     [AC_TRY_COMPILE( [#include <sys/types.h>
1194 #include <sys/socket.h>],
1195                      [struct sockaddr *a; a->sa_len=0;],
1196                      [ac_cv_sockaddr_len=yes],
1197                      [ac_cv_sockaddr_len=no])
1198 ])
1199 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1200       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1201                  [define if you struct sockaddr sa_len])])
1202
1203 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1204         echo Skipping library tests because they confuse Irix.
1205 else
1206   AC_SEARCH_LIBS([socket], [socket inet])
1207   AC_SEARCH_LIBS([connect], [nsl])
1208   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1209
1210   dnl darwin wants it, aix hates it
1211   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1212   AC_TRY_COMPILE([
1213   #include <stdlib.h>
1214   #include <stdio.h>
1215   #include <sys/types.h>
1216   #include <sys/socket.h>
1217   #include <netinet/in.h>
1218   #include <arpa/inet.h>
1219   #include <arpa/nameser.h>
1220   #include <arpa/nameser_compat.h>
1221   #include <resolv.h>
1222   ], [static int i; i = 0;],
1223   [AC_MSG_RESULT(yes)
1224    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1225   [AC_MSG_RESULT(no)
1226    ])
1227
1228   openafs_save_libs="$LIBS"
1229   AC_MSG_CHECKING([for res_search])
1230   AC_FUNC_RES_SEARCH
1231
1232   if test "$ac_cv_func_res_search" = no; then
1233       for lib in dns nsl resolv; do
1234         if test "$ac_cv_func_res_search" != yes; then
1235           LIBS="-l$lib $LIBS"
1236           AC_FUNC_RES_SEARCH
1237           LIBS="$openafs_save_libs"
1238         fi
1239       done    
1240       if test "$ac_cv_func_res_search" = yes; then
1241         LIB_AFSDB="-l$lib"
1242         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1243         AC_MSG_RESULT([yes, in lib$lib])
1244       else
1245         AC_MSG_RESULT(no)
1246       fi
1247   else
1248     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1249     AC_MSG_RESULT(yes)
1250   fi
1251   
1252 fi
1253 XLIBS="$LIB_AFSDB $XLIBS"
1254
1255 AC_CHECK_RESOLV_RETRANS
1256
1257 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1258     [ac_cv_setsockopt_iprecverr],
1259     [AC_TRY_COMPILE( [
1260 #include <sys/types.h>
1261 #include <sys/socket.h>
1262 #include <netinet/in.h>],
1263 [int on=1;
1264 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1265         [ac_cv_setsockopt_iprecverr=yes],
1266         [ac_cv_setsockopt_iprecverr=no])])
1267
1268 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1269       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1270                  [define if we can receive socket errors via IP_RECVERR])])
1271
1272 PTHREAD_LIBS=error
1273 if test "x$MKAFS_OSTYPE" = OBSD; then
1274         PTHREAD_LIBS="-pthread"
1275 fi
1276 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1277         PTHREAD_LIBS="-pthread"
1278 fi
1279 if test "x$PTHREAD_LIBS" = xerror; then
1280         AC_CHECK_LIB(pthread, pthread_attr_init,
1281                 PTHREAD_LIBS="-lpthread")
1282 fi
1283 if test "x$PTHREAD_LIBS" = xerror; then
1284         AC_CHECK_LIB(pthreads, pthread_attr_init,
1285                 PTHREAD_LIBS="-lpthreads")
1286 fi
1287 if test "x$PTHREAD_LIBS" = xerror; then
1288         AC_CHECK_LIB(c_r, pthread_attr_init,
1289                 PTHREAD_LIBS="-lc_r")
1290 fi
1291 if test "x$PTHREAD_LIBS" = xerror; then
1292         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1293 fi
1294 if test "x$PTHREAD_LIBS" = xerror; then
1295         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1296         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1297                 PTHREAD_LIBS="-lpthread")
1298 fi
1299 if test "x$PTHREAD_LIBS" = xerror; then
1300         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1301 fi
1302 AC_SUBST(PTHREAD_LIBS)
1303
1304 HOST_CPU="$host_cpu"
1305
1306 if test "x$with_bsd_kernel_headers" != "x"; then
1307         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1308 else
1309         BSD_KERNEL_PATH="/usr/src/sys"
1310 fi
1311
1312 if test "x$with_bsd_kernel_build" != "x"; then
1313         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1314 else
1315         case $AFS_SYSNAME in
1316                 *_fbsd_*)
1317                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1318                         ;;
1319                 *_nbsd*)
1320                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1321         esac
1322 fi
1323
1324 # Fast restart
1325 if test "$enable_supergroups" = "yes"; then
1326         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1327 fi
1328
1329 if test "$enable_bitmap_later" = "yes"; then
1330         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1331 fi
1332
1333 if test "$enable_unix_sockets" = "yes"; then
1334         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1335         USE_UNIX_SOCKETS="yes"
1336 else
1337         USE_UNIX_SOCKETS="no"
1338 fi
1339 AC_SUBST(USE_UNIX_SOCKETS)
1340
1341 if test "$enable_namei_fileserver" = "yes"; then
1342         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1343         VFSCK=""
1344 else
1345         if test "$enable_namei_fileserver" = "default"; then
1346                 case $host in
1347                         *-solaris2.10*)
1348                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1349                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1350                                 VFSCK=""
1351                                 ;;
1352                         *-solaris2.11*)
1353                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1354                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1355                                 VFSCK=""
1356                                 ;;
1357                         *)
1358                                 VFSCK="vfsck"
1359                                 ;;
1360                 esac
1361         else
1362                 VFSCK="vfsck"
1363         fi
1364 fi
1365
1366 dnl check for tivoli
1367 AC_MSG_CHECKING(for tivoli tsm butc support)
1368 XBSA_CFLAGS=""
1369 if test "$enable_tivoli_tsm" = "yes"; then
1370         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1371         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1372         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1373         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1374
1375         if test -r "$XBSADIR3/dsmapifp.h"; then
1376                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1377                 XBSA_XLIBS="-ldl"
1378                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1379         elif test -r "$XBSADIR4/dsmapifp.h"; then
1380                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1381                 XBSA_XLIBS="-ldl"
1382                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1383         elif test -r "$XBSADIR1/xbsa.h"; then
1384                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1385                 XBSA_XLIBS=""
1386                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1387         elif test -r "$XBSADIR2/xbsa.h"; then
1388                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1389                 XBSA_XLIBS=""
1390                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1391         else
1392                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1393         fi
1394 else
1395         AC_MSG_RESULT([no])
1396 fi
1397 AC_SUBST(XBSA_CFLAGS)
1398 AC_SUBST(XBSA_XLIBS) 
1399
1400 dnl checks for header files.
1401 AC_HEADER_STDC
1402 AC_HEADER_SYS_WAIT
1403 AC_HEADER_DIRENT
1404 AC_CHECK_HEADERS([ \
1405                    arpa/inet.h \
1406                    arpa/nameser.h \
1407                    curses.h\
1408                    direct.h \
1409                    errno.h \
1410                    fcntl.h \
1411                    grp.h \
1412                    math.h \
1413                    mntent.h \
1414                    ncurses.h \
1415                    ncurses/ncurses.h \
1416                    netdb.h \
1417                    netinet/in.h \
1418                    pthread_np.h \
1419                    pwd.h \
1420                    regex.h \
1421                    security/pam_appl.h \
1422                    signal.h \
1423                    stdint.h \
1424                    stdio_ext.h \
1425                    stdlib.h \
1426                    string.h \
1427                    strings.h \
1428                    sys/bitypes.h \
1429                    sys/bswap.h \
1430                    sys/dk.h \
1431                    sys/fcntl.h \
1432                    sys/file.h \
1433                    sys/fs_types.h \
1434                    sys/fstyp.h \
1435                    sys/ioctl.h \
1436                    sys/ipc.h \
1437                    sys/lockf.h \
1438                    sys/map.h \
1439                    sys/mount.h \
1440                    sys/mntent.h \
1441                    sys/mnttab.h \
1442                    sys/pag.h \
1443                    sys/param.h \
1444                    sys/resource.h \
1445                    sys/select.h \
1446                    sys/statfs.h \
1447                    sys/statvfs.h \
1448                    sys/socket.h \
1449                    sys/sysctl.h \
1450                    sys/time.h \
1451                    sys/types.h \
1452                    sys/uio.h \
1453                    sys/un.h \
1454                    sys/vfs.h \
1455                    syslog.h \
1456                    termios.h \
1457                    time.h \
1458                    ucontext.h \
1459                    unistd.h \
1460                    windows.h \
1461                 ])
1462
1463 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1464 #ifdef HAVE_NETINET_IN_H
1465 # include <netinet/in.h>
1466 #endif])
1467
1468 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1469 #ifdef HAVE_SYS_SOCKET_H
1470 # include <sys/socket.h>
1471 #endif])
1472
1473 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1474 #ifdef HAVE_SYS_SOCKET_H
1475 # include <sys/socket.h>
1476 #endif
1477 #ifdef HAVE_NETINET_IN_H
1478 # include <netinet/in.h>
1479 #endif
1480 #ifdef HAVE_NET_IF_H
1481 # include <net/if.h>
1482 #endif])
1483
1484 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1485 #ifdef HAVE_SECURITY_PAM_APPL_H
1486 # include <security/pam_appl.h>
1487 #endif])
1488
1489 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1490
1491 AC_CHECK_TYPES([fsblkcnt_t],,,[
1492 #include <sys/types.h>
1493 #ifdef HAVE_SYS_BITYPES_H
1494 #include <sys/bitypes.h>
1495 #endif
1496 #ifdef HAVE_SYS_STATFS_H
1497 #include <sys/statfs.h>
1498 #endif
1499 #ifdef HAVE_SYS_STATVFS_H
1500 #include <sys/statvfs.h>
1501 #endif
1502 ])
1503
1504 dnl see what struct stat has for timestamps
1505 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1506
1507 dnl check for curses-lib
1508 AS_IF([test "x$enable_gtx" != "xno"],
1509       [save_LIBS=$LIBS
1510       AC_CHECK_LIB( [ncurses], [setupterm],
1511       [LIB_curses=-lncurses],
1512         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1513           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1514       ])
1515       LIBS=$save_LIBS
1516       AC_SUBST(LIB_curses)])
1517         
1518 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1519
1520 if test "$enable_debug_locks" = yes; then
1521         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1522 fi
1523
1524 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1525         HAVE_PAM="YES"
1526 else
1527         HAVE_PAM="no"
1528 fi
1529 AC_SUBST(HAVE_PAM)
1530
1531 if test "$enable_login" = yes; then
1532         BUILD_LOGIN="yes"
1533 else
1534         BUILD_LOGIN="no"
1535 fi
1536 AC_SUBST(BUILD_LOGIN)
1537
1538 if test "$enable_uss" = yes; then
1539         BUILD_USS="yes"
1540 else
1541         BUILD_USS="no"
1542 fi
1543 AC_SUBST(BUILD_USS)
1544
1545 if test "$enable_kauth" = yes; then
1546         INSTALL_KAUTH="yes"
1547 else
1548         INSTALL_KAUTH="no"
1549 fi
1550 AC_SUBST(INSTALL_KAUTH)
1551
1552 AC_CHECK_FUNCS([ \
1553         arc4random \
1554         fcntl \
1555         fseeko64 \
1556         ftello64 \
1557         getcwd \
1558         getegid \
1559         geteuid \
1560         getgid \
1561         getuid \
1562         getrlimit \
1563         issetugid \
1564         mkstemp \
1565         poll \
1566         pread \
1567         preadv \
1568         preadv64 \
1569         pwrite \
1570         pwritev \
1571         pwritev64 \
1572         regcomp \
1573         regerror \
1574         regexec \
1575         setitimer \
1576         setvbuf \
1577         sigaction \
1578         strcasestr \
1579         strerror \
1580         sysconf \
1581         sysctl \
1582         tdestroy \
1583         timegm \
1584 ])
1585
1586 OPENAFS_ROKEN()
1587 OPENAFS_HCRYPTO()
1588 OPENAFS_C_ATTRIBUTE()
1589
1590 dnl Functions that Heimdal's libroken provides, but that we
1591 dnl haven't found a need for yet, and so haven't imported
1592 AC_CHECK_FUNCS([ \
1593         chown \
1594         fchown \
1595         gethostname \
1596         lstat \
1597         inet_aton \
1598         putenv \
1599         readv \
1600         setenv \
1601         strdup \
1602         strftime \
1603         strndup \
1604         strsep \
1605         unsetenv \
1606 ])
1607
1608 dnl Functions that are in objects that we always build from libroken
1609 AC_CHECK_FUNCS([ \
1610         asprintf \
1611         asnprintf \
1612         vasprintf \
1613         vasnprintf \
1614         vsnprintf \
1615         snprintf \
1616 ])
1617
1618 dnl Functions that we're going to try and get from libroken
1619 AC_REPLACE_FUNCS([ \
1620         daemon \
1621         ecalloc \
1622         emalloc \
1623         erealloc \
1624         err \
1625         errx \
1626         flock \
1627         freeaddrinfo \
1628         gai_strerror \
1629         getaddrinfo \
1630         getdtablesize \
1631         getnameinfo \
1632         getopt \
1633         getprogname \
1634         gettimeofday \
1635         inet_ntop \
1636         inet_pton \
1637         localtime_r \
1638         mkstemp \
1639         setenv \
1640         setprogname \
1641         strcasecmp \
1642         strlcat \
1643         strnlen \
1644         strlcpy \
1645         strsep \
1646         tdelete \
1647         tfind \
1648         tsearch \
1649         twalk \
1650         unsetenv \
1651         verr \
1652         verrx \
1653         vsyslog \
1654         vwarn \
1655         vwarnx \
1656         warn \
1657         warnx \
1658 ])
1659
1660 dnl Headers that we're going to try and get from libroken
1661 AC_CHECK_HEADERS([ \
1662         err.h \
1663         search.h \
1664 ])
1665
1666 AC_CHECK_DECLS([h_errno], [], [], [
1667 #include <sys/types.h>
1668 #ifdef HAVE_NETDB_H
1669 #include <netdb.h>
1670 #endif
1671 ])
1672
1673 AC_HEADER_TIME
1674
1675 ROKEN_HEADERS=
1676 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1677       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1678       [])
1679 AC_SUBST(ROKEN_HEADERS)
1680
1681 dnl Stuff that's harder ...
1682 AC_MSG_CHECKING([for bswap16])
1683 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1684 #ifdef HAVE_SYS_TYPES_H
1685 #include <sys/types.h>
1686 #endif
1687 #ifdef HAVE_SYS_BSWAP_H
1688 #include <sys/bswap.h>
1689 #endif
1690 ],
1691 [short a, b; b = bswap16(a); ])],
1692 [AC_MSG_RESULT(yes)
1693  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1694 ],
1695 [AC_MSG_RESULT(no)])
1696
1697 AC_MSG_CHECKING([for bswap32])
1698 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1699 #include <sys/types.h>
1700 #endif
1701 #ifdef HAVE_SYS_BSWAP_H
1702 #include <sys/bswap.h>
1703 #endif
1704 ],
1705 [int a, b; b = bswap32(a); ])],
1706 [AC_MSG_RESULT(yes)
1707  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1708 ],
1709 [AC_MSG_RESULT(no)])
1710
1711 case $AFS_SYSNAME in
1712 *hp_ux* | *hpux*)
1713    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1714    ;;
1715 *)
1716    AC_MSG_CHECKING([for positional I/O])
1717    if test "$ac_cv_func_pread" = "yes" && \
1718            test "$ac_cv_func_pwrite" = "yes"; then
1719       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1720       AC_MSG_RESULT(yes)
1721    else
1722      AC_MSG_RESULT(no)
1723    fi
1724    AC_MSG_CHECKING([for vectored positional I/O])
1725    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1726                "$ac_cv_func_pwritev" = "yes" -a \
1727                "$ac_cv_func_preadv64" = "yes" -a \
1728                "$ac_cv_func_pwritev64" = "yes"],
1729          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1730           AC_MSG_RESULT(yes)],
1731          [AC_MSG_RESULT(no)])
1732    ;;
1733 esac
1734
1735 AC_MSG_CHECKING([for POSIX regex library])
1736 if test "$ac_cv_header_regex_h" = "yes" && \
1737         test "$ac_cv_func_regcomp" = "yes" && \
1738         test "$ac_cv_func_regexec" = "yes" && \
1739         test "$ac_cv_func_regerror" = "yes"; then
1740     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1741     AC_MSG_RESULT(yes)
1742 else
1743     AC_MSG_RESULT(no)
1744 fi
1745
1746 dnl Look for "non-portable" pthreads functions.
1747 save_LIBS="$LIBS"
1748 LIBS="$LIBS $PTHREAD_LIBS"
1749 AC_CHECK_FUNCS([ \
1750         pthread_set_name_np \
1751         pthread_setname_np \
1752 ])
1753
1754 dnl Sadly, there are three different versions of pthread_setname_np.
1755 dnl Try to cater for all of them.
1756 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1757     AC_MSG_CHECKING([for signature of pthread_setname_np])
1758     AC_TRY_COMPILE([
1759 #include <pthread.h>
1760 #ifdef HAVE_PTHREAD_NP_H
1761 #include <pthread_np.h>
1762 #endif
1763 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1764         AC_MSG_RESULT([three arguments])
1765         pthread_setname_np_args=3], [
1766         AC_TRY_COMPILE([
1767 #include <pthread.h>
1768 #ifdef HAVE_PTHREAD_NP_H
1769 #include <pthread_np.h>
1770 #endif
1771 ], [pthread_setname_np(pthread_self(), "test")], [
1772             AC_MSG_RESULT([two arguments])
1773             pthread_setname_np_args=2], [
1774             AC_TRY_COMPILE([
1775 #include <pthread.h>
1776 #ifdef HAVE_PTHREAD_NP_H
1777 #include <pthread_np.h>
1778 #endif
1779 ], [pthread_setname_np("test")], [
1780                 AC_MSG_RESULT([one argument])
1781                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1782 ])
1783 ])
1784 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1785 fi
1786 LIBS="$save_LIBS"
1787
1788 openafs_cv_saved_CFLAGS="$CFLAGS"
1789 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1790
1791 AC_TYPE_SIGNAL
1792 OPENAFS_RETSIGTYPE
1793 AC_CHECK_SIZEOF(void *)
1794 AC_CHECK_SIZEOF(unsigned long long)
1795 AC_CHECK_SIZEOF(unsigned long)
1796 AC_CHECK_SIZEOF(unsigned int)
1797 AC_TYPE_INTPTR_T
1798 AC_TYPE_UINTPTR_T
1799 AC_TYPE_SSIZE_T
1800 AC_CHECK_TYPE([sig_atomic_t],[],
1801     [AC_DEFINE([sig_atomic_t], [int],
1802         [Define to int if <signal.h> does not define.])],
1803 [#include <sys/types.h>
1804 #include <signal.h>])
1805 AC_CHECK_TYPE([socklen_t],[],
1806     [AC_DEFINE([socklen_t], [int],
1807         [Define to int if <sys/socket.h> does not define.])],
1808 [#include <sys/types.h>
1809 #include <sys/socket.h>])
1810 AC_CHECK_TYPES(off64_t)
1811 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1812 AC_CHECK_TYPES([struct winsize], [], [], [
1813 #ifdef HAVE_TERMIOS_H
1814 # include <termios.h>
1815 #else
1816 # include <sys/termios.h>
1817 #endif
1818 #include <sys/ioctl.h>])
1819 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1820                 struct sockaddr_storage],
1821                [], [], [
1822 #include <sys/types.h>
1823 #include <sys/socket.h>
1824 ])
1825 AC_CHECK_TYPES([sa_family_t], [], [], [
1826 #include <sys/types.h>
1827 #include <sys/socket.h>
1828 ])
1829 AC_CHECK_TYPES([struct addrinfo], [], [], [
1830 #include <sys/types.h>
1831 #ifdef HAVE_NETDB_H
1832 #include <netdb.h>
1833 #endif
1834 ])
1835 AC_CHECK_TYPES([long long], [], [], [])
1836
1837 AC_SIZEOF_TYPE(long)
1838
1839 CFLAGS="$openafs_cv_saved_CFLAGS"
1840
1841 RRA_HEADER_PAM_CONST
1842
1843
1844 dnl Directory PATH handling
1845 if test "x$enable_transarc_paths" = "xyes"  ; then 
1846     afsconfdir=${afsconfdir=/usr/afs/etc}
1847     viceetcdir=${viceetcdir=/usr/vice/etc}
1848     afskerneldir=${afskerneldir=${viceetcdir}}
1849     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1850     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1851     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1852     afsdbdir=${afsdbdir=/usr/afs/db}
1853     afslogsdir=${afslogsdir=/usr/afs/logs}
1854     afslocaldir=${afslocaldir=/usr/afs/local}
1855     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1856     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1857     afsdatadir=${afsdatadir=/usr/vice/etc}
1858 else 
1859     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1860     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1861     afskerneldir=${afskerneldir='${libdir}/openafs'}
1862     afssrvbindir=${afssrvbindir='${bindir}'}
1863     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1864     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1865     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1866     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1867     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1868     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1869     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1870     afsdatadir=${afsdatadir='${datadir}/openafs'}
1871 fi
1872 AC_SUBST(afsconfdir)
1873 AC_SUBST(viceetcdir)
1874 AC_SUBST(afskerneldir)
1875 AC_SUBST(afssrvbindir)
1876 AC_SUBST(afssrvsbindir)
1877 AC_SUBST(afssrvlibexecdir)
1878 AC_SUBST(afsdbdir)
1879 AC_SUBST(afslogsdir)
1880 AC_SUBST(afslocaldir)
1881 AC_SUBST(afsbackupdir)
1882 AC_SUBST(afsbosconfigdir)
1883 AC_SUBST(afsdatadir)
1884
1885 if test "x$enable_kernel_module" = "xyes"; then
1886 ENABLE_KERNEL_MODULE=libafs
1887 fi
1888
1889 if test "x$enable_pthreaded_ubik" = "xyes"; then
1890 ENABLE_PTHREADED_UBIK=yes
1891 fi
1892
1893 AC_SUBST(VFSCK)
1894 AC_SUBST(AFS_SYSNAME)
1895 AC_SUBST(AFS_PARAM_COMMON)
1896 AC_SUBST(ENABLE_KERNEL_MODULE)
1897 AC_SUBST(ENABLE_PTHREADED_UBIK)
1898 AC_SUBST(LIB_AFSDB)
1899 AC_SUBST(LINUX_KERNEL_PATH)
1900 AC_SUBST(LINUX_KERNEL_BUILD)
1901 AC_SUBST(HOST_CPU)
1902 AC_SUBST(BSD_KERNEL_PATH)
1903 AC_SUBST(BSD_KERNEL_BUILD)
1904 AC_SUBST(LINUX_VERSION)
1905 AC_SUBST(MKAFS_OSTYPE)
1906 AC_SUBST(TOP_OBJDIR)
1907 AC_SUBST(TOP_SRCDIR)
1908 AC_SUBST(TOP_INCDIR)
1909 AC_SUBST(TOP_LIBDIR)
1910 AC_SUBST(DEST)
1911 AC_SUBST(DARWIN_INFOFILE)
1912 AC_SUBST(IRIX_BUILD_IP35)
1913 AC_SUBST(HTML_XSL)
1914 AC_SUBST(XSLTPROC)
1915 AC_SUBST(DOCBOOK2PDF)
1916 AC_SUBST(DOCBOOK_STYLESHEETS)
1917
1918 OPENAFS_FUSE
1919 OPENAFS_SWIG
1920
1921 TOP_SRCDIR="${srcdir}/src"
1922 dnl
1923 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1924 dnl
1925 case $TOP_SRCDIR in
1926         /*)
1927                 ;;
1928         *)
1929                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1930                 ;;
1931 esac
1932
1933 TOP_OBJDIR="${SRCDIR_PARENT}"
1934 TOP_INCDIR="${SRCDIR_PARENT}/include"
1935 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1936 if test "${DEST}x" = "x"; then
1937         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1938 fi
1939
1940 if test "x$with_crosstools_dir" != "x"; then
1941         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1942                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1943                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1944                 RXGEN_PATH=$with_crosstools_dir/rxgen
1945         else
1946                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1947                 exit 1
1948         fi
1949 else
1950         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1951         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1952         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1953 fi
1954 AC_SUBST(COMPILE_ET_PATH)
1955 AC_SUBST(CONFIGTOOL_PATH)
1956 AC_SUBST(RXGEN_PATH)
1957
1958 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1959 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1960 AC_SUBST(HELPER_SPLINT)
1961 AC_SUBST(HELPER_SPLINTCFG)
1962
1963 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1964
1965 dnl Check to see if crypt lives in a different library
1966 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1967 AC_SUBST(LIB_crypt)
1968
1969 dnl Check to see if the compiler support labels in structs
1970 AC_MSG_CHECKING(for label support in structs)
1971 AC_TRY_COMPILE([], [
1972 extern void osi_UFSOpen(void);
1973 struct labeltest {
1974    void (*open) (void);
1975 };
1976 struct labeltest struct_labeltest = {
1977    .open       = osi_UFSOpen,
1978 }
1979 ],
1980 [AC_MSG_RESULT(yes)
1981  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1982 ],
1983 [AC_MSG_RESULT(no)
1984 ])
1985
1986 AC_MSG_CHECKING([checking for dirfd])
1987 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1988 #ifdef HAVE_DIRENT_H
1989 #include <dirent.h>
1990 #endif
1991 ]],
1992         [[DIR *d = 0; dirfd(d);]])],
1993         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1994 if test "$ac_rk_have_dirfd" = "yes" ; then
1995         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1996 fi
1997 AC_MSG_RESULT($ac_rk_have_dirfd)
1998
1999 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
2000 #ifdef HAVE_DIRENT_H
2001 #include <dirent.h>
2002 #endif])
2003
2004 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
2005 [#ifdef HAVE_SYS_RESOURCE_H
2006 #include <sys/resource.h>
2007 #endif])
2008
2009 dnl Check for UUID library
2010 AC_CHECK_HEADERS([uuid/uuid.h])
2011 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
2012 AC_CHECK_FUNCS([uuid_generate])
2013 ])
2014
2015