acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #   define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 #define _FILE_OFFSET_BITS 64
  48 #define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 #include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
  76
  77 dnl General feature options.
  78 AC_ARG_ENABLE([pam],
  79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
  80     ,
  81     [enable_pam="yes"])
  82 AC_ARG_ENABLE([namei-fileserver],
  83     [AS_HELP_STRING([--enable-namei-fileserver],
  84         [force compilation of namei fileserver in preference to inode
  85          fileserver])],
  86     ,
  87     [enable_namei_fileserver="default"])
  88 AC_ARG_ENABLE([supergroups],
  89     [AS_HELP_STRING([--enable-supergroups],
  90         [enable support for nested pts groups])],
  91     ,
  92     [enable_supergroups="no"])
  93 AC_ARG_ENABLE([bitmap-later],
  94     [AS_HELP_STRING([--enable-bitmap-later],
  95         [enable fast startup of file server by not reading bitmap till
  96          needed])],
  97     ,
  98     [enable_bitmap_later="no"])
  99 AC_ARG_ENABLE([unix-sockets],
 100     [AS_HELP_STRING([--disable-unix-sockets],
 101         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 102     ,
 103     [enable_unix_sockets="yes"])
 104 AC_ARG_ENABLE([tivoli-tsm],
 105     [AS_HELP_STRING([--enable-tivoli-tsm],
 106         [enable use of the Tivoli TSM API libraries for butc support])],
 107     ,
 108     [enable_tivoli_tsm="no"])
 109 AC_ARG_ENABLE([pthreaded-ubik],
 110     [AS_HELP_STRING([--enable-pthreaded-ubik],
 111         [enable installation of pthreaded ubik applications (defaults to
 112          disabled)])],
 113     ,
 114     [enable_pthreaded_ubik="no"])
 115
 116 dnl Kernel module build options.
 117 AC_ARG_WITH([linux-kernel-headers],
 118     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 119         [use the kernel headers found at path (optional, defaults to
 120          /usr/src/linux-2.4, then /usr/src/linux)])])
 121 AC_ARG_WITH([linux-kernel-build],
 122     [AS_HELP_STRING([--with-linux-kernel-build=path],
 123         [use the kernel build found at path(optional, defaults to
 124         /usr/src/linux-2.4, then /usr/src/linux)])])
 125 AC_ARG_WITH([bsd-kernel-headers],
 126     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 127         [use the kernel headers found at path (optional, defaults to
 128          /usr/src/sys)])])
 129 AC_ARG_WITH([bsd-kernel-build],
 130     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 131         [use the kernel build found at path (optional, defaults to
 132          KSRC/i386/compile/GENERIC)])])
 133 AC_ARG_WITH([linux-kernel-packaging],
 134     [AS_HELP_STRING([--with-linux-kernel-packaging],
 135         [use standard naming conventions to aid Linux kernel build packaging
 136          (disables MPS, sets the kernel module name to openafs.ko, and
 137          installs kernel modules into the standard Linux location)])],
 138     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
 139      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
 140     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
 141 AC_ARG_ENABLE([kernel-module],
 142     [AS_HELP_STRING([--disable-kernel-module],
 143         [disable compilation of the kernel module (defaults to enabled)])],
 144     ,
 145     [enable_kernel_module="yes"])
 146 AC_ARG_ENABLE([redhat-buildsys],
 147     [AS_HELP_STRING([--enable-redhat-buildsys],
 148         [enable compilation of the redhat build system kernel (defaults to
 149          disabled)])],
 150     ,
 151     [enable_redhat_buildsys="no"])
 152
 153 dnl Installation locations.
 154 AC_ARG_ENABLE([transarc-paths],
 155     [AS_HELP_STRING([--enable-transarc-paths],
 156         [use Transarc style paths like /usr/afs and /usr/vice])],
 157     ,
 158     [enable_transarc_paths="no"])
 159
 160 dnl Optimization and debugging flags.
 161 AC_ARG_ENABLE([strip-binaries],
 162     [AS_HELP_STRING([--disable-strip-binaries],
 163         [disable stripping of symbol information from binaries (defaults to
 164          enabled)])],
 165     ,
 166     [enable_strip_binaries="maybe"])
 167 AC_ARG_ENABLE([debug],
 168     [AS_HELP_STRING([--enable-debug],
 169         [enable compilation of the user space code with debugging information
 170          (defaults to disabled)])],
 171     ,
 172     [enable_debug="no"])
 173 AC_ARG_ENABLE([optimize],
 174     [AS_HELP_STRING([--disable-optimize],
 175         [disable optimization for compilation of the user space code (defaults
 176          to enabled)])],
 177     ,
 178     [enable_optimize="yes"])
 179 AC_ARG_ENABLE([warnings],
 180     [AS_HELP_STRING([--enable-warnings],
 181         [enable compilation warnings when building with gcc (defaults to
 182          disabled)])],
 183     ,
 184     [enable_warnings="no"])
 185 AC_ARG_ENABLE([checking],
 186     [AS_HELP_STRING([--enable-checking],
 187         [turn compilation warnings into errors when building with gcc (defaults
 188          to disabled)])],
 189     [enable_checking="$enableval"],
 190     [enable_checking="no"])
 191 AC_ARG_ENABLE([debug-kernel],
 192     [AS_HELP_STRING([--enable-debug-kernel],
 193         [enable compilation of the kernel module with debugging information
 194          (defaults to disabled)])],
 195     ,
 196     [enable_debug_kernel="no"])
 197 AC_ARG_ENABLE([optimize-kernel],
 198     [AS_HELP_STRING([--disable-optimize-kernel],
 199         [disable compilation of the kernel module with optimization (defaults
 200          based on platform)])],
 201     ,
 202     [enable_optimize_kernel="yes"])
 203 AC_ARG_ENABLE([debug-lwp],
 204     [AS_HELP_STRING([--enable-debug-lwp],
 205         [enable compilation of the LWP code with debugging information
 206          (defaults to disabled)])],
 207     ,
 208     [enable_debug_lwp="no"])
 209 AC_ARG_ENABLE([optimize-lwp],
 210     [AS_HELP_STRING([--disable-optimize-lwp],
 211         [disable optimization for compilation of the LWP code (defaults to
 212          enabled)])],
 213     ,
 214     [enable_optimize_lwp="yes"])
 215 AC_ARG_ENABLE([debug-pam],
 216     [AS_HELP_STRING([--enable-debug-pam],
 217         [enable compilation of the PAM code with debugging information
 218          (defaults to disabled)])],
 219     ,
 220     [enable_debug_pam="no"])
 221 AC_ARG_ENABLE([optimize-pam],
 222     [AS_HELP_STRING([--disable-optimize-pam],
 223         [disable optimization for compilation of the PAM code (defaults to
 224          enabled)])],
 225     ,
 226     [enable_optimize_pam="yes"])
 227 AC_ARG_ENABLE([linux-syscall-probing],
 228     [AS_HELP_STRING([--enable-linux-syscall-probing],
 229         [enable Linux syscall probing (defaults to autodetect)])],
 230     ,
 231     [enable_linux_syscall_probing="maybe"])
 232
 233
 234 AC_ARG_WITH([xslt-processor],
 235         AS_HELP_STRING([--with-xslt-processor=ARG],
 236         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 237         XSLTPROC="$withval",
 238         XSLTPROC="libxslt")
 239
 240 AC_ARG_WITH([html-xsl],
 241         AS_HELP_STRING([--with-html-xsl],
 242         [build HTML documentation using Norman Walsh's DocBook XSL stylesheets (default is no; specify a path to chunk.xsl or docbook.xsl)]),
 243         HTML_XSL="$withval",
 244         HTML_XSL=no)
 245
 246 enable_login="no"
 247
 248 dnl weird ass systems
 249 dnl AC_AIX
 250 AC_ISC_POSIX
 251 dnl AC_MINIX
 252
 253 dnl Various compiler setup.
 254 AC_TYPE_PID_T
 255 AC_TYPE_SIZE_T
 256
 257 dnl Checks for programs.
 258 AC_PROG_INSTALL
 259 AC_PROG_LN_S
 260 AC_PROG_RANLIB
 261 AC_PROG_YACC
 262 AM_PROG_LEX
 263 dnl if we are flex, be lex-compatible
 264 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 265
 266 OPENAFS_FORCE_ABS_INSTALL
 267 OPENAFS_CHECK_BIGENDIAN
 268 OPENAFS_PRINTF_TAKES_Z_LEN
 269
 270 AC_MSG_CHECKING(your OS)
 271 system=$host
 272 case $system in
 273         *-linux*)
 274
 275                 MKAFS_OSTYPE=LINUX
 276                 if test "x$enable_redhat_buildsys" = "xyes"; then
 277                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 278                 fi
 279                 if test "x$enable_kernel_module" = "xyes"; then
 280                  if test "x$with_linux_kernel_headers" != "x"; then
 281                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 282                  else
 283                    LINUX_KERNEL_PATH="/lib/modules/`uname -r`/source"
 284                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 285                      LINUX_KERNEL_PATH="/lib/modules/`uname -r`/build"
 286                    fi
 287                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 288                      LINUX_KERNEL_PATH="/usr/src/linux-2.4"
 289                    fi
 290                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
 291                      LINUX_KERNEL_PATH="/usr/src/linux"
 292                    fi
 293                  fi
 294                  if test "x$with_linux_kernel_build" != "x"; then
 295                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 296                  else
 297                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 298                  fi
 299                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 300                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 301                    LINUX_VERSION="$linux_kvers"
 302                  else
 303                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 304                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 305                      LINUX_VERSION="$linux_kvers"
 306                    else
 307                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 308                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 309                        if test "x$linux_kvers" = "x"; then
 310                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 311                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 312                            if test "x$linux_kvers" = "x"; then
 313                              AC_MSG_ERROR(Linux headers lack version definition [2])
 314                              exit 1
 315                            else
 316                              LINUX_VERSION="$linux_kvers"
 317                            fi
 318                          else
 319                            AC_MSG_ERROR(Linux headers lack version definition)
 320                            exit 1
 321                          fi
 322                        else
 323                          LINUX_VERSION="$linux_kvers"
 324                        fi
 325                      else
 326                        enable_kernel_module="no"
 327                      fi
 328                    fi
 329                  fi
 330                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 331                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 332                      enable_kernel_module="no"
 333                  fi
 334                  if test "x$enable_kernel_module" = "xno"; then
 335                   if test "x$with_linux_kernel_headers" != "x"; then
 336                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 337                    exit 1
 338                   else
 339                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 340                   fi
 341                  fi
 342                  dnl do we need to determine SUBARCH from autoconf.h
 343                  SUBARCH=default
 344                 fi
 345                 AC_MSG_RESULT(linux)
 346                 if test "x$enable_kernel_module" = "xyes"; then
 347                  AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $[]1 $[]2}'`
 348                  if test "x${AFS_SYSKVERS}" = "x"; then
 349                   AC_MSG_ERROR(Couldn't guess your Linux version [2])
 350                  fi
 351                 fi
 352                 ;;
 353         *-solaris*)
 354                 MKAFS_OSTYPE=SOLARIS
 355                 AC_MSG_RESULT(sun4)
 356                 AC_PATH_PROG(SOLARISCC, [cc], ,
 357                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin])
 358                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 359                 SOLARIS_FS_HAS_FS_ROLLED
 360                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 361                 ;;
 362         *-sunos*)
 363                 MKAFS_OSTYPE=SUNOS
 364                 enable_kernel_module=no
 365                 AC_MSG_RESULT(sun4)
 366                 ;;
 367         *-hpux*)
 368                 MKAFS_OSTYPE=HPUX
 369                 AC_MSG_RESULT(hp_ux)
 370                 if test -f "/usr/old/usr/include/ndir.h"; then
 371                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 372                 fi
 373                 ;;
 374         *-irix*)
 375                 if test -d /usr/include/sys/SN/SN1; then
 376                  IRIX_BUILD_IP35="IP35"
 377                 fi
 378                 MKAFS_OSTYPE=IRIX
 379                 AC_MSG_RESULT(sgi)
 380                 ;;
 381         *-aix*)
 382                 MKAFS_OSTYPE=AIX
 383                 AC_MSG_RESULT(rs_aix)
 384                 ;;
 385         arm-*-darwin*)
 386                 MKAFS_OSTYPE=DARWIN
 387                 AC_MSG_RESULT(arm_darwin)
 388                 ;;
 389         powerpc-*-darwin*)
 390                 MKAFS_OSTYPE=DARWIN
 391                 AC_MSG_RESULT(ppc_darwin)
 392                 ;;
 393         i386-*-darwin*)
 394                 MKAFS_OSTYPE=DARWIN
 395                 AC_MSG_RESULT(x86_darwin)
 396                 ;;
 397         x86_64-*-darwin*)
 398                 MKAFS_OSTYPE=DARWIN
 399                 AC_MSG_RESULT(x86_darwin)
 400                 ;;
 401         i386-*-freebsd*)
 402                 MKAFS_OSTYPE=FBSD
 403                 AC_MSG_RESULT(i386_fbsd)
 404                 ;;
 405         x86_64-*-freebsd*)
 406                 MKAFS_OSTYPE=FBSD
 407                 AC_MSG_RESULT(amd64_fbsd)
 408                 ;;
 409         *-netbsd*)
 410                 MKAFS_OSTYPE=NBSD
 411                 AC_MSG_RESULT(nbsd)
 412                 ;;
 413         x86_64-*-openbsd*)
 414                 MKAFS_OSTYPE=OBSD
 415                 AC_MSG_RESULT(amd64_obsd)
 416                 ;;
 417         i386-*-openbsd*)
 418                 MKAFS_OSTYPE=OBSD
 419                 AC_MSG_RESULT(i386_obsd)
 420                 ;;
 421         *-dragonfly*)
 422                 MKAFS_OSTYPE=DFBSD
 423                 AC_MSG_RESULT(i386_dfbsd)
 424                 ;;
 425         *)
 426                 AC_MSG_RESULT($system)
 427                 ;;
 428 esac
 429
 430 if test "x$with_afs_sysname" != "x"; then
 431         AFS_SYSNAME="$with_afs_sysname"
 432 else
 433         AC_MSG_CHECKING(your AFS sysname)
 434         case $host in
 435                 i?86-*-openbsd?.?)
 436                         v=${host#*openbsd}
 437                         vM=${v%.*}
 438                         vm=${v#*.}
 439                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 440                         ;;
 441                 sparc64-*-openbsd?.?)
 442                         v=${host#*openbsd}
 443                         vM=${v%.*}
 444                         vm=${v#*.}
 445                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 446                         ;;
 447                 x86_64-*-openbsd?.?)
 448                         v=${host#*openbsd}
 449                         vM=${v%.*}
 450                         vm=${v#*.}
 451                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 452                         ;;
 453                 i?86-*-freebsd?.*)
 454                         v=${host#*freebsd}
 455                         vM=${v%.*}
 456                         vm=${v#*.}
 457                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 458                         ;;
 459                 x86_64-*-freebsd?.*)
 460                         v=${host#*freebsd}
 461                         vM=${v%.*}
 462                         vm=${v#*.}
 463                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 464                         ;;
 465                 i386-*-dragonfly?.*)
 466                         v=${host#*dragonfly}
 467                         vM=${v%.*}
 468                         vm=${v#*.}
 469                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 470                         ;;
 471                 i?86-*-netbsd*1.6[[M-Z]]*)
 472                         AFS_SYSNAME="i386_nbsd20"
 473                         ;;
 474                 powerpc-*-netbsd*1.6[[M-Z]]*)
 475                         AFS_SYSNAME="ppc_nbsd20"
 476                         ;;
 477                 *-*-netbsd*)
 478                         arch=${host%%-unknown*}
 479                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 480                                                -e 's/powerpc/ppc/g')
 481                         v=${host#*netbsd}
 482                         v=${v#*aout}
 483                         v=${v#*ecoff}
 484                         v=${v#*elf}
 485                         vM=${v%%.*}
 486                         vM=${vM%.*}
 487                         v=${v#*.}
 488                         vm=${v%%.*}
 489                         vm=${vm%.*}
 490                         vm=${vm%%[[_A-Z]]*}
 491                         if test $vm -eq 99 ; then
 492                                 vM=$((vM+1))
 493                         fi
 494                         if test $vM -gt 1 ; then
 495                                 vm=0
 496                         fi
 497                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 498                         ;;
 499                 hppa*-hp-hpux11.0*)
 500                         AFS_SYSNAME="hp_ux110"
 501                         ;;
 502                 hppa*-hp-hpux11.11)
 503                         AFS_SYSNAME="hp_ux11i"
 504                         ;;
 505                 hppa*-hp-hpux11.23)
 506                         AFS_SYSNAME="hp_ux1123"
 507                         ;;
 508                 ia64-hp-hpux11.22)
 509                         AFS_SYSNAME="ia64_hpux1122"
 510                         ;;
 511                 ia64-hp-hpux*)
 512                         AFS_SYSNAME="ia64_hpux1123"
 513                         ;;
 514                 hppa*-hp-hpux10*)
 515                         AFS_SYSNAME="hp_ux102"
 516                         ;;
 517                 powerpc-apple-darwin7*)
 518                         AFS_SYSNAME="ppc_darwin_70"
 519                         ;;
 520                 powerpc-apple-darwin8.*)
 521                         AFS_SYSNAME="ppc_darwin_80"
 522                         ;;
 523                 i386-apple-darwin8.*)
 524                         AFS_SYSNAME="x86_darwin_80"
 525                         ;;
 526                 powerpc-apple-darwin9.*)
 527                         AFS_SYSNAME="ppc_darwin_90"
 528                         ;;
 529                 i386-apple-darwin9.*)
 530                         AFS_SYSNAME="x86_darwin_90"
 531                         ;;
 532                 i?86-apple-darwin10.*)
 533                         AFS_SYSNAME="x86_darwin_100"
 534                         ;;
 535                 x86_64-apple-darwin10.*)
 536                         AFS_SYSNAME="x86_darwin_100"
 537                         ;;
 538                 sparc-sun-solaris2.5*)
 539                         AFS_SYSNAME="sun4x_55"
 540                         enable_login="yes"
 541                         ;;
 542                 sparc-sun-solaris2.6)
 543                         AFS_SYSNAME="sun4x_56"
 544                         ;;
 545                 sparc-sun-solaris2.7)
 546                         AFS_SYSNAME="sun4x_57"
 547                         ;;
 548                 sparc-sun-solaris2.8)
 549                         AFS_SYSNAME="sun4x_58"
 550                         ;;
 551                 sparc-sun-solaris2.9)
 552                         AFS_SYSNAME="sun4x_59"
 553                         ;;
 554                 sparc-sun-solaris2.10)
 555                         AFS_SYSNAME="sun4x_510"
 556                         ;;
 557                 sparc-sun-solaris2.11)
 558                         AFS_SYSNAME="sun4x_511"
 559                         ;;
 560                 sparc-sun-sunos4*)
 561                         AFS_SYSNAME="sun4_413"
 562                         enable_login="yes"
 563                         ;;
 564                 i386-pc-solaris2.7)
 565                         AFS_SYSNAME="sunx86_57"
 566                         ;;
 567                 i386-pc-solaris2.8)
 568                         AFS_SYSNAME="sunx86_58"
 569                         ;;
 570                 i386-pc-solaris2.9)
 571                         AFS_SYSNAME="sunx86_59"
 572                         ;;
 573                 i386-pc-solaris2.10)
 574                         AFS_SYSNAME="sunx86_510"
 575                         ;;
 576                 i386-pc-solaris2.11)
 577                         AFS_SYSNAME="sunx86_511"
 578                         ;;
 579                 alpha*-dec-osf4.0*)
 580                         AFS_SYSNAME="alpha_dux40"
 581                         ;;
 582                 alpha*-dec-osf5.0*)
 583                         AFS_SYSNAME="alpha_dux50"
 584                         ;;
 585                 alpha*-dec-osf5.1*)
 586                         AFS_SYSNAME="alpha_dux51"
 587                         ;;
 588                 mips-sgi-irix6.5)
 589                         AFS_SYSNAME="sgi_65"
 590                         ;;
 591                 ia64-*-linux*)
 592                         AFS_SYSNAME="ia64_linuxXX"
 593                         ;;
 594                 powerpc-*-linux*)
 595                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 596                         ;;
 597                 powerpc64-*-linux*)
 598                         AFS_SYSNAME="ppc64_linuxXX"
 599                         ;;
 600                 alpha*-linux*)
 601                         AFS_SYSNAME="alpha_linux_XX"
 602                         ;;
 603                 s390-*-linux*)
 604                         AFS_SYSNAME="s390_linuxXX"
 605                         ;;
 606                 s390x-*-linux*)
 607                         AFS_SYSNAME="s390x_linuxXX"
 608                         ;;
 609                 sparc-*-linux*)
 610                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 611                         ;;
 612                 sparc64-*-linux*)
 613                         AFS_SYSNAME="sparc64_linuxXX"
 614                         ;;
 615                 i?86-*-linux*)
 616                         AFS_SYSNAME="i386_linuxXX"
 617                         ;;
 618                 arm*-linux*)
 619                         AFS_SYSNAME="arm_linuxXX"
 620                         ;;
 621                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 622                         AFS_SYSNAME="parisc_linuxXX"
 623                         enable_pam="no"
 624                         ;;
 625                 power*-ibm-aix4.2*)
 626                         AFS_SYSNAME="rs_aix42"
 627                         enable_pam="no"
 628                         ;;
 629                 power*-ibm-aix4.3*)
 630                         AFS_SYSNAME="rs_aix42"
 631                         enable_pam="no"
 632                         ;;
 633                 power*-ibm-aix5.1*)
 634                         AFS_SYSNAME="rs_aix51"
 635                         enable_pam="no"
 636                         ;;
 637                 power*-ibm-aix5.2*)
 638                         AFS_SYSNAME="rs_aix52"
 639                         enable_pam="no"
 640                         ;;
 641                 power*-ibm-aix5.3*)
 642                         AFS_SYSNAME="rs_aix53"
 643                         enable_pam="no"
 644                         ;;
 645                 power*-ibm-aix6.1*)
 646                         AFS_SYSNAME="rs_aix61"
 647                         enable_pam="no"
 648                         ;;
 649                 x86_64-*-linux-gnu)
 650                         AFS_SYSNAME="amd64_linuxXX"
 651                         enable_pam="yes"
 652                         ;;
 653                 *)
 654                         AC_MSG_ERROR(An AFS sysname is required)
 655                         exit 1
 656                         ;;
 657         esac
 658         case $AFS_SYSNAME in
 659                 *_linux* | *_umlinux*)
 660                         if test "x${AFS_SYSKVERS}" = "x"; then
 661                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 662                         fi
 663                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 664                         AFS_SYSNAME="$_AFS_SYSNAME"
 665                         AC_TRY_KBUILD(
 666                          [],
 667                          [#ifndef CONFIG_USERMODE
 668                           #error not UML
 669                           #endif],
 670                          ac_cv_linux_is_uml=yes,)
 671                         if test "${ac_cv_linux_is_uml}" = yes; then
 672                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 673                         fi
 674                         AFS_SYSNAME="$_AFS_SYSNAME"
 675                         ;;
 676         esac
 677         AC_MSG_RESULT($AFS_SYSNAME)
 678 fi
 679
 680 case $AFS_SYSNAME in
 681         *_darwin*)
 682                 AC_CHECK_HEADERS(crt_externs.h)
 683                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 684                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 685                 ;;
 686 esac
 687
 688 dnl Some hosts have a separate common param file they should include.  Figure
 689 dnl out if we're on one of them now that we know the sysname.
 690 case $AFS_SYSNAME in
 691     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 692     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 693     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 694     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 695     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 696     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 697     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 698     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 699     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 700     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 701     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 702     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 703     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 704     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 705     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 706     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 707     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 708     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 709     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 710     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 711     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 712     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 713     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 714     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 715     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 716     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
 717     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
 718     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 719 # Linux alpha adds an extra underscore for no good reason.
 720     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
 721     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
 722     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 723 esac
 724
 725 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 726
 727                 # Add (sub-) architecture-specific paths needed by conftests
 728                 case $AFS_SYSNAME  in
 729                         *_umlinux26)
 730                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 731                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 732                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 733                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 734                 esac
 735
 736                 if test "x$enable_kernel_module" = "xyes"; then
 737                  if test "x$enable_debug_kernel" = "xno"; then
 738                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 739                  fi
 740                  OPENAFS_GCC_SUPPORTS_MARCH
 741                  AC_SUBST(P5PLUS_KOPTS)
 742                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 743                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 744                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 745                  OPENAFS_GCC_SUPPORTS_PIPE
 746                  AC_SUBST(LINUX_GCC_KOPTS)
 747
 748                  dnl Setup the kernel build environment
 749                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 750                  LINUX_KERNEL_COMPILE_WORKS
 751
 752                  dnl Check for header files
 753                  AC_CHECK_LINUX_HEADER([config.h])
 754                  AC_CHECK_LINUX_HEADER([completion.h])
 755                  AC_CHECK_LINUX_HEADER([exportfs.h])
 756                  AC_CHECK_LINUX_HEADER([freezer.h])
 757                  AC_CHECK_LINUX_HEADER([key-type.h])
 758                  AC_CHECK_LINUX_HEADER([semaphore.h])
 759                  AC_CHECK_LINUX_HEADER([seq_file.h])
 760
 761                  dnl Check for structure elements
 762                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 763                                        [write_begin], [fs.h])
 764                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 765                                        [backing-dev.h])
 766                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 767                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 768                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 769                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 770                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 771                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 772                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 773                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 774                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 775                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 776                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 777                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 778                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 779                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 780                                        [fs.h])
 781                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 782                                        [fs.h])
 783                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 784                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 785                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 786                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 787                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 788                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 789                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 790                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 791                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 792                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 793                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 794
 795                  dnl Function existence checks
 796
 797                  AC_CHECK_LINUX_FUNC([bdi_init],
 798                                      [#include <linux/backing-dev.h>],
 799                                      [bdi_init(NULL);])
 800                  AC_CHECK_LINUX_FUNC([PageChecked],
 801                                      [#include <linux/mm.h>
 802 #include <linux/page-flags.h>],
 803                                      [struct page *_page;
 804                                       int bchecked = PageChecked(_page);])
 805                  AC_CHECK_LINUX_FUNC([PageFsMisc],
 806                                      [#include <linux/mm.h>
 807 #include <linux/page-flags.h>],
 808                                      [struct page *_page;
 809                                       int bchecked = PageFsMisc(_page);])
 810                  AC_CHECK_LINUX_FUNC([current_kernel_time],
 811                                      [#include <linux/time.h>],
 812                                      [struct timespec s;
 813                                       s = current_kernel_time();])
 814                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
 815                                      [#include <linux/fs.h>],
 816                                      [d_alloc_anon(NULL);])
 817                  AC_CHECK_LINUX_FUNC([do_sync_read],
 818                                      [#include <linux/fs.h>],
 819                                      [do_sync_read(NULL, NULL, 0, NULL);])
 820                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
 821                                      [#include <linux/sched.h>],
 822                                      [pid_t p; find_task_by_pid(p);])
 823                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
 824                                      [#include <linux/fs.h>],
 825                                      [generic_file_aio_read(NULL,NULL,0,0);])
 826                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
 827                                      [#include <linux/pagemap.h>],
 828                                      [grab_cache_page_write_begin(NULL, 0, 0);])
 829                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
 830                                      [#include <linux/list.h>],
 831                                      [hlist_unhashed(0);])
 832                  AC_CHECK_LINUX_FUNC([i_size_read],
 833                                      [#include <linux/fs.h>],
 834                                      [i_size_read(NULL);])
 835                  AC_CHECK_LINUX_FUNC([inode_setattr],
 836                                      [#include <linux/fs.h>],
 837                                      [inode_setattr(NULL, NULL);])
 838                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
 839                                      [#include <linux/net.h>],
 840                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
 841                  AC_CHECK_LINUX_FUNC([page_follow_link],
 842                                      [#include <linux/fs.h>],
 843                                      [page_follow_link(0,0);])
 844                  AC_CHECK_LINUX_FUNC([page_offset],
 845                                      [#include <linux/pagemap.h>],
 846                                      [page_offset(NULL);])
 847                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
 848                                      [#include <linux/pagevec.h>],
 849                                      [__pagevec_lru_add_file(NULL);])
 850                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
 851                                      [#include <linux/rcupdate.h>],
 852                                      [rcu_read_lock();])
 853                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
 854                                      [#include <linux/splice.h>],
 855                                      [splice_direct_to_actor(NULL,NULL,NULL);])
 856                  AC_CHECK_LINUX_FUNC([svc_addr_in],
 857                                      [#include <linux/sunrpc/svc.h>],
 858                                      [svc_addr_in(NULL);])
 859                  AC_CHECK_LINUX_FUNC([zero_user_segments],
 860                                      [#include <linux/highmem.h>],
 861                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
 862
 863                  dnl Consequences - things which get set as a result of the
 864                  dnl                above tests
 865                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
 866                        [AC_DEFINE([AFS_NONFSTRANS], 1,
 867                                   [define to disable the nfs translator])])
 868
 869                  dnl Assorted more complex tests
 870                  LINUX_EXPORTS_PROC_ROOT_FS
 871                  LINUX_KMEM_CACHE_INIT
 872                  LINUX_HAVE_KMEM_CACHE_T
 873                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
 874                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
 875                  LINUX_D_PATH_TAKES_STRUCT_PATH
 876                  LINUX_NEW_EXPORT_OPS
 877                  LINUX_INODE_SETATTR_RETURN_TYPE
 878                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
 879                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
 880                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
 881                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
 882                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
 883                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
 884                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
 885                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
 886                  LINUX_AOP_WRITEBACK_CONTROL
 887                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
 888                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
 889                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
 890                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
 891                  LINUX_KERNEL_SOCK_CREATE
 892                  LINUX_EXPORTS_KEY_TYPE_KEYRING
 893                  LINUX_NEED_RHCONFIG
 894                  LINUX_RECALC_SIGPENDING_ARG_TYPE
 895                  LINUX_EXPORTS_TASKLIST_LOCK
 896                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
 897                  LINUX_STATFS_TAKES_DENTRY
 898                  LINUX_REFRIGERATOR
 899                  LINUX_HAVE_TRY_TO_FREEZE
 900                  LINUX_LINUX_KEYRING_SUPPORT
 901                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
 902                  LINUX_KEY_ALLOC_NEEDS_CRED
 903                  LINUX_INIT_WORK_HAS_DATA
 904                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
 905                  LINUX_HAVE_DCACHE_LOCK
 906                  LINUX_D_COUNT_IS_INT
 907
 908                  dnl If we are guaranteed that keyrings will work - that is
 909                  dnl  a) The kernel has keyrings enabled
 910                  dnl  b) The code is new enough to give us a key_type_keyring
 911                  dnl then we just disable syscall probing unless we've been
 912                  dnl told otherwise
 913
 914                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
 915                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
 916                           [enable_linux_syscall_probing="no"],
 917                           [enable_linux_syscall_probing="yes"])
 918                  ])
 919
 920                  dnl Syscall probing needs a few tests of its own, and just
 921                  dnl won't work if the kernel doesn't export init_mm
 922                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
 923                    LINUX_EXPORTS_INIT_MM
 924                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
 925                      AC_MSG_ERROR(
 926                        [Can't do syscall probing without exported init_mm])
 927                    ])
 928                    LINUX_EXPORTS_SYS_CHDIR
 929                    LINUX_EXPORTS_SYS_OPEN
 930                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
 931                              [define to enable syscall table probes])
 932                  ])
 933
 934                  dnl Packaging and SMP build
 935                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
 936                    LINUX_WHICH_MODULES
 937                  else
 938                    AC_SUBST(MPS,'SP')
 939                  fi
 940
 941                  dnl Syscall probing
 942                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
 943                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
 944                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
 945                    ])
 946                    ac_cv_linux_exports_sys_call_table=no
 947                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
 948                      ac_cv_linux_exports_ia32_sys_call_table=yes
 949                    fi
 950                  else
 951                    LINUX_EXPORTS_KALLSYMS_ADDRESS
 952                    LINUX_EXPORTS_KALLSYMS_SYMBOL
 953                    LINUX_EXPORTS_SYS_CALL_TABLE
 954                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
 955                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
 956                          linux_syscall_method=none
 957                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
 958                             linux_syscall_method=scan
 959                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
 960                                linux_syscall_method=scan_with_kallsyms_address
 961                             fi
 962                          fi
 963                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
 964                             linux_syscall_method=kallsyms_symbol
 965                          fi
 966                          if test "x$linux_syscall_method" = "xnone"; then
 967                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
 968                             linux_syscall_method=scan
 969                          fi
 970                    fi
 971                  fi
 972                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
 973                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
 974                  fi
 975                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
 976                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
 977                  fi
 978                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
 979                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
 980                  else
 981                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
 982                  fi
 983                 :
 984                 fi
 985 dnl Linux-only, but just enable always.
 986                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
 987 esac
 988
 989 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
 990     [ac_cv_sync_fetch_and_add],
 991     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
 992                     [ac_cv_sync_fetch_and_add=yes],
 993                     [ac_cv_sync_fetch_and_add=no])
 994 ])
 995 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
 996       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
 997                 [define if your C compiler has __sync_add_and_fetch])])
 998
 999 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1000     [ac_cv_sockaddr_len],
1001     [AC_TRY_COMPILE( [#include <sys/types.h>
1002 #include <sys/socket.h>],
1003                      [struct sockaddr *a; a->sa_len=0;],
1004                      [ac_cv_sockaddr_len=yes],
1005                      [ac_cv_sockaddr_len=no])
1006 ])
1007 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1008       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1009                  [define if you struct sockaddr sa_len])])
1010
1011 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1012         echo Skipping library tests because they confuse Irix.
1013 else
1014   AC_SEARCH_LIBS([socket], [socket inet])
1015   AC_SEARCH_LIBS([connect], [nsl])
1016   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1017
1018   dnl darwin wants it, aix hates it
1019   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1020   AC_TRY_COMPILE([
1021   #include <stdlib.h>
1022   #include <stdio.h>
1023   #include <sys/types.h>
1024   #include <sys/socket.h>
1025   #include <netinet/in.h>
1026   #include <arpa/inet.h>
1027   #include <arpa/nameser.h>
1028   #include <arpa/nameser_compat.h>
1029   #include <resolv.h>
1030   ], [static int i; i = 0;],
1031   [AC_MSG_RESULT(yes)
1032    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1033   [AC_MSG_RESULT(no)
1034    ])
1035
1036   openafs_save_libs="$LIBS"
1037   AC_MSG_CHECKING([for res_search])
1038   AC_FUNC_RES_SEARCH
1039
1040   if test "$ac_cv_func_res_search" = no; then
1041       for lib in dns nsl resolv; do
1042         if test "$ac_cv_func_res_search" != yes; then
1043           LIBS="-l$lib $LIBS"
1044           AC_FUNC_RES_SEARCH
1045           LIBS="$openafs_save_libs"
1046         fi
1047       done
1048       if test "$ac_cv_func_res_search" = yes; then
1049         LIB_AFSDB="-l$lib"
1050         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1051         AC_MSG_RESULT([yes, in lib$lib])
1052       else
1053         AC_MSG_RESULT(no)
1054       fi
1055   else
1056     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1057     AC_MSG_RESULT(yes)
1058   fi
1059
1060 fi
1061
1062 AC_CHECK_RESOLV_RETRANS
1063
1064 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1065     [ac_cv_setsockopt_iprecverr],
1066     [AC_TRY_COMPILE( [
1067 #include <sys/types.h>
1068 #include <sys/socket.h>
1069 #include <netinet/in.h>],
1070 [int on=1;
1071 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1072         [ac_cv_setsockopt_iprecverr=yes],
1073         [ac_cv_setsockopt_iprecverr=no])])
1074
1075 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1076       [AC_DEFINE(ADAPT_PMTU_RECVERR, 1,
1077                  [define if asynchronous socket errors can be received])])
1078
1079 PTHREAD_LIBS=error
1080 if test "x$MKAFS_OSTYPE" = OBSD; then
1081         PTHREAD_LIBS="-pthread"
1082 fi
1083 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1084         PTHREAD_LIBS="-pthread"
1085 fi
1086 if test "x$PTHREAD_LIBS" = xerror; then
1087         AC_CHECK_LIB(pthread, pthread_attr_init,
1088                 PTHREAD_LIBS="-lpthread")
1089 fi
1090 if test "x$PTHREAD_LIBS" = xerror; then
1091         AC_CHECK_LIB(pthreads, pthread_attr_init,
1092                 PTHREAD_LIBS="-lpthreads")
1093 fi
1094 if test "x$PTHREAD_LIBS" = xerror; then
1095         AC_CHECK_LIB(c_r, pthread_attr_init,
1096                 PTHREAD_LIBS="-lc_r")
1097 fi
1098 if test "x$PTHREAD_LIBS" = xerror; then
1099         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1100 fi
1101 if test "x$PTHREAD_LIBS" = xerror; then
1102         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1103         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1104                 PTHREAD_LIBS="-lpthread")
1105 fi
1106 if test "x$PTHREAD_LIBS" = xerror; then
1107         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1108 fi
1109 AC_SUBST(PTHREAD_LIBS)
1110
1111 HOST_CPU="$host_cpu"
1112
1113 if test "x$with_bsd_kernel_headers" != "x"; then
1114         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1115 else
1116         BSD_KERNEL_PATH="/usr/src/sys"
1117 fi
1118
1119 if test "x$with_bsd_kernel_build" != "x"; then
1120         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1121 else
1122         case $AFS_SYSNAME in
1123                 *_fbsd_*)
1124                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1125                         ;;
1126                 *_nbsd*)
1127                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1128         esac
1129 fi
1130
1131 # Fast restart
1132 if test "$enable_supergroups" = "yes"; then
1133         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1134 fi
1135
1136 if test "$enable_bitmap_later" = "yes"; then
1137         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1138 fi
1139
1140 if test "$enable_unix_sockets" = "yes"; then
1141         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1142         USE_UNIX_SOCKETS="yes"
1143 else
1144         USE_UNIX_SOCKETS="no"
1145 fi
1146 AC_SUBST(USE_UNIX_SOCKETS)
1147
1148 dnl if test "$ac_cv_setsockopt_iprecverr" = "yes"; then
1149 dnl     AC_DEFINE(ADAPT_PMTU, 1, [define if you want to decode icmp unreachable packets to discover path mtu])
1150 dnl fi
1151
1152 if test "$enable_namei_fileserver" = "yes"; then
1153         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1154         VFSCK=""
1155 else
1156         if test "$enable_namei_fileserver" = "default"; then
1157                 case $host in
1158                         *-solaris2.10*)
1159                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1160                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1161                                 VFSCK=""
1162                                 ;;
1163                         *-solaris2.11*)
1164                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1165                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1166                                 VFSCK=""
1167                                 ;;
1168                         *)
1169                                 VFSCK="vfsck"
1170                                 ;;
1171                 esac
1172         else
1173                 VFSCK="vfsck"
1174         fi
1175 fi
1176
1177 dnl check for tivoli
1178 AC_MSG_CHECKING(for tivoli tsm butc support)
1179 XBSA_CFLAGS=""
1180 if test "$enable_tivoli_tsm" = "yes"; then
1181         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1182         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1183         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1184         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1185
1186         if test -r "$XBSADIR3/dsmapifp.h"; then
1187                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1188                 XBSA_XLIBS="-ldl"
1189                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1190         elif test -r "$XBSADIR4/dsmapifp.h"; then
1191                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1192                 XBSA_XLIBS="-ldl"
1193                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1194         elif test -r "$XBSADIR1/xbsa.h"; then
1195                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1196                 XBSA_XLIBS=""
1197                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1198         elif test -r "$XBSADIR2/xbsa.h"; then
1199                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1200                 XBSA_XLIBS=""
1201                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1202         else
1203                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1204         fi
1205 else
1206         AC_MSG_RESULT([no])
1207 fi
1208 AC_SUBST(XBSA_CFLAGS)
1209 AC_SUBST(XBSA_XLIBS)
1210
1211 dnl checks for header files.
1212 AC_HEADER_STDC
1213 AC_HEADER_SYS_WAIT
1214 AC_HEADER_DIRENT
1215 AC_CHECK_HEADERS([ \
1216                    arpa/nameser.h \
1217                    curses.h\
1218                    direct.h \
1219                    et/com_err.h \
1220                    errno.h \
1221                    fcntl.h \
1222                    grp.h \
1223                    mntent.h \
1224                    ncurses.h \
1225                    netdb.h \
1226                    netinet/in.h \
1227                    pwd.h \
1228                    regex.h \
1229                    resolv.h \
1230                    security/pam_modules.h \
1231                    signal.h \
1232                    stdint.h \
1233                    stdio_ext.h \
1234                    stdlib.h \
1235                    string.h \
1236                    strings.h \
1237                    sys/bitypes.h \
1238                    sys/bswap.h \
1239                    sys/fcntl.h \
1240                    sys/file.h \
1241                    sys/fs_types.h \
1242                    sys/fstyp.h \
1243                    sys/ioctl.h \
1244                    sys/ipc.h \
1245                    sys/mount.h \
1246                    sys/mntent.h \
1247                    sys/mnttab.h \
1248                    sys/pag.h \
1249                    sys/param.h \
1250                    sys/resource.h \
1251                    sys/statfs.h \
1252                    sys/statvfs.h \
1253                    sys/socket.h \
1254                    sys/sysctl.h \
1255                    sys/time.h \
1256                    sys/types.h \
1257                    sys/uio.h \
1258                    sys/un.h \
1259                    sys/vfs.h \
1260                    syslog.h \
1261                    termios.h \
1262                    time.h \
1263                    ucontext.h \
1264                    unistd.h \
1265                    windows.h \
1266                 ])
1267
1268 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1269
1270 AC_CHECK_TYPES([fsblkcnt_t],,,[
1271 #include <sys/types.h>
1272 #ifdef HAVE_SYS_BITYPES_H
1273 #include <sys/bitypes.h>
1274 #endif
1275 #ifdef HAVE_SYS_STATFS_H
1276 #include <sys/statfs.h>
1277 #endif
1278 #ifdef HAVE_SYS_STATVFS_H
1279 #include <sys/statvfs.h>
1280 #endif
1281 ])
1282
1283 dnl check for curses-lib
1284 save_LIBS=$LIBS
1285 AC_CHECK_LIB( [ncurses], [setupterm],
1286 [LIB_curses=-lncurses],
1287     [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1288         [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])
1289     ])
1290 ])
1291 LIBS=$save_LIBS
1292 AC_SUBST(LIB_curses)
1293
1294 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1295
1296 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1297 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1298         case $AFS_SYSNAME in
1299         sgi_*)
1300                 HAVE_PAM="no"
1301                 ;;
1302         *)
1303                 HAVE_PAM="yes"
1304                 ;;
1305         esac
1306 else
1307         HAVE_PAM="no"
1308 fi
1309 AC_SUBST(HAVE_PAM)
1310
1311 if test "$enable_login" = yes; then
1312         BUILD_LOGIN="yes"
1313 else
1314         BUILD_LOGIN="no"
1315 fi
1316 AC_SUBST(BUILD_LOGIN)
1317
1318 AC_CHECK_FUNCS([ \
1319         arc4random \
1320         flock \
1321         fseeko64 \
1322         ftello64 \
1323         getcwd \
1324         getegid \
1325         geteuid \
1326         getgid \
1327         getuid \
1328         getprogname \
1329         getrlimit \
1330         issetugid \
1331         mkstemp \
1332         pread \
1333         preadv \
1334         preadv64 \
1335         pwrite \
1336         pwritev \
1337         pwritev64 \
1338         regcomp \
1339         regerror \
1340         regexec \
1341         setitimer \
1342         setprogname \
1343         setvbuf \
1344         sigaction \
1345         strcasestr \
1346         strerror \
1347         sysconf \
1348         sysctl \
1349         timegm \
1350 ])
1351
1352 OPENAFS_ROKEN()
1353 OPENAFS_C_ATTRIBUTE()
1354
1355 dnl Functions that Heimdal's libroken provides, but that we
1356 dnl haven't found a need for yet, and so haven't imported
1357 AC_CHECK_FUNCS([ \
1358         chown \
1359         fchown \
1360         gethostname \
1361         gettimeofday \
1362         localtime_r \
1363         lstat \
1364         inet_aton \
1365         inet_ntop \
1366         inet_pton \
1367         readv \
1368         strdup \
1369         strftime \
1370         strndup \
1371         strsep \
1372 ])
1373
1374 dnl Functions that are in objects that we always build from libroken
1375 AC_CHECK_FUNCS([ \
1376         asprintf \
1377         asnprintf \
1378         vasprintf \
1379         vasnprintf \
1380         vsnprintf \
1381         snprintf \
1382 ])
1383
1384 dnl Functions that we're going to try and get from libroken
1385 AC_REPLACE_FUNCS([ \
1386         daemon \
1387         ecalloc \
1388         emalloc \
1389         erealloc \
1390         err \
1391         errx \
1392         getdtablesize \
1393         getopt \
1394         getprogname \
1395         mkstemp \
1396         strcasecmp \
1397         strlcat \
1398         strnlen \
1399         strlcpy \
1400         strsep \
1401         verr \
1402         verrx \
1403         vsyslog \
1404         vwarn \
1405         vwarnx \
1406         warn \
1407         warnx \
1408 ])
1409
1410 dnl Headers that we're going to try and get from libroken
1411 AC_CHECK_HEADERS([ \
1412         err.h \
1413 ])
1414
1415 AC_CHECK_DECLS([h_errno], [], [], [
1416 #include <sys/types.h>
1417 #ifdef HAVE_NETDB_H
1418 #include <netdb.h>
1419 #endif
1420 ])
1421
1422 AC_HEADER_TIME
1423
1424 ROKEN_HEADERS=
1425 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1426       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1427       [])
1428 AC_SUBST(ROKEN_HEADERS)
1429
1430 dnl Stuff that's harder ...
1431 AC_MSG_CHECKING([for bswap16])
1432 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1433 #ifdef HAVE_SYS_TYPES_H
1434 #include <sys/types.h>
1435 #endif
1436 #ifdef HAVE_SYS_BSWAP_H
1437 #include <sys/bswap.h>
1438 #endif
1439 ],
1440 [short a, b; b = bswap16(a); ])],
1441 [AC_MSG_RESULT(yes)
1442  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1443 ],
1444 [AC_MSG_RESULT(no)])
1445
1446 AC_MSG_CHECKING([for bswap32])
1447 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1448 #include <sys/types.h>
1449 #endif
1450 #ifdef HAVE_SYS_BSWAP_H
1451 #include <sys/bswap.h>
1452 #endif
1453 ],
1454 [int a, b; b = bswap32(a); ])],
1455 [AC_MSG_RESULT(yes)
1456  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1457 ],
1458 [AC_MSG_RESULT(no)])
1459
1460 case $AFS_SYSNAME in
1461 *hp_ux* | *hpux*)
1462    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1463    ;;
1464 *)
1465    AC_MSG_CHECKING([for positional I/O])
1466    if test "$ac_cv_func_pread" = "yes" && \
1467            test "$ac_cv_func_pwrite" = "yes"; then
1468       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1469       AC_MSG_RESULT(yes)
1470    else
1471      AC_MSG_RESULT(no)
1472    fi
1473    AC_MSG_CHECKING([for vectored positional I/O])
1474    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1475                "$ac_cv_func_pwritev" = "yes" -a \
1476                "$ac_cv_func_preadv64" = "yes" -a \
1477                "$ac_cv_func_pwritev64" = "yes"],
1478          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1479           AC_MSG_RESULT(yes)],
1480          [AC_MSG_RESULT(no)])
1481    ;;
1482 esac
1483
1484 AC_MSG_CHECKING([for POSIX regex library])
1485 if test "$ac_cv_header_regex_h" = "yes" && \
1486         test "$ac_cv_func_regcomp" = "yes" && \
1487         test "$ac_cv_func_regexec" = "yes" && \
1488         test "$ac_cv_func_regerror" = "yes"; then
1489     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1490     AC_MSG_RESULT(yes)
1491 else
1492     AC_MSG_RESULT(no)
1493 fi
1494
1495 AC_TYPE_SIGNAL
1496 OPENAFS_RETSIGTYPE
1497 AC_CHECK_SIZEOF(void *)
1498 AC_CHECK_SIZEOF(unsigned long long)
1499 AC_CHECK_SIZEOF(unsigned long)
1500 AC_CHECK_SIZEOF(unsigned int)
1501 AC_TYPE_INTPTR_T
1502 AC_TYPE_UINTPTR_T
1503 AC_TYPE_SSIZE_T
1504 AC_CHECK_TYPE([sig_atomic_t],[],
1505     [AC_DEFINE([sig_atomic_t], [int],
1506         [Define to int if <signal.h> does not define.])],
1507 [#include <sys/types.h>
1508 #include <signal.h>])
1509 AC_CHECK_TYPE([socklen_t],[],
1510     [AC_DEFINE([socklen_t], [int],
1511         [Define to int if <sys/socket.h> does not define.])],
1512 [#include <sys/types.h>
1513 #include <sys/socket.h>])
1514 AC_CHECK_TYPES(off64_t)
1515 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1516 AC_CHECK_TYPES([struct winsize], [], [], [
1517 #ifdef HAVE_TERMIOS_H
1518 # include <termios.h>
1519 #else
1520 # include <sys/termios.h>
1521 #endif
1522 #include <sys/ioctl.h>])
1523 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1524                 struct sockaddr_storage],
1525                [], [], [
1526 #include <sys/types.h>
1527 #include <sys/socket.h>
1528 ])
1529 AC_CHECK_TYPES([sa_family_t], [], [], [
1530 #include <sys/types.h>
1531 #include <sys/socket.h>
1532 ])
1533 AC_CHECK_TYPES([struct addrinfo], [], [], [
1534 #include <sys/types.h>
1535 #ifdef HAVE_NETDB_H
1536 #include <netdb.h>
1537 #endif
1538 ])
1539 AC_CHECK_TYPES([long long], [], [], [])
1540
1541 AC_SIZEOF_TYPE(long)
1542
1543 AC_HEADER_PAM_CONST
1544
1545
1546 dnl Directory PATH handling
1547 if test "x$enable_transarc_paths" = "xyes"  ; then
1548     afsconfdir=${afsconfdir=/usr/afs/etc}
1549     viceetcdir=${viceetcdir=/usr/vice/etc}
1550     afskerneldir=${afskerneldir=${viceetcdir}}
1551     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1552     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1553     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1554     afsdbdir=${afsdbdir=/usr/afs/db}
1555     afslogsdir=${afslogsdir=/usr/afs/logs}
1556     afslocaldir=${afslocaldir=/usr/afs/local}
1557     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1558     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1559     afsdatadir=${afsdatadir=/usr/vice/etc}
1560 else
1561     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1562     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1563     afskerneldir=${afskerneldir='${libdir}/openafs'}
1564     afssrvbindir=${afssrvbindir='${bindir}'}
1565     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1566     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1567     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1568     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1569     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1570     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1571     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1572     afsdatadir=${afsdatadir='${datadir}/openafs'}
1573 fi
1574 AC_SUBST(afsconfdir)
1575 AC_SUBST(viceetcdir)
1576 AC_SUBST(afskerneldir)
1577 AC_SUBST(afssrvbindir)
1578 AC_SUBST(afssrvsbindir)
1579 AC_SUBST(afssrvlibexecdir)
1580 AC_SUBST(afsdbdir)
1581 AC_SUBST(afslogsdir)
1582 AC_SUBST(afslocaldir)
1583 AC_SUBST(afsbackupdir)
1584 AC_SUBST(afsbosconfigdir)
1585 AC_SUBST(afsdatadir)
1586
1587 if test "x$enable_kernel_module" = "xyes"; then
1588 ENABLE_KERNEL_MODULE=libafs
1589 fi
1590
1591 if test "x$enable_pthreaded_ubik" = "xyes"; then
1592 ENABLE_PTHREADED_UBIK=yes
1593 fi
1594
1595 AC_SUBST(VFSCK)
1596 AC_SUBST(AFS_SYSNAME)
1597 AC_SUBST(AFS_PARAM_COMMON)
1598 AC_SUBST(ENABLE_KERNEL_MODULE)
1599 AC_SUBST(ENABLE_PTHREADED_UBIK)
1600 AC_SUBST(LIB_AFSDB)
1601 AC_SUBST(LINUX_KERNEL_PATH)
1602 AC_SUBST(LINUX_KERNEL_BUILD)
1603 AC_SUBST(HOST_CPU)
1604 AC_SUBST(BSD_KERNEL_PATH)
1605 AC_SUBST(BSD_KERNEL_BUILD)
1606 AC_SUBST(LINUX_VERSION)
1607 AC_SUBST(MKAFS_OSTYPE)
1608 AC_SUBST(TOP_OBJDIR)
1609 AC_SUBST(TOP_SRCDIR)
1610 AC_SUBST(TOP_INCDIR)
1611 AC_SUBST(TOP_LIBDIR)
1612 AC_SUBST(DEST)
1613 AC_SUBST(DARWIN_INFOFILE)
1614 AC_SUBST(IRIX_BUILD_IP35)
1615 AC_SUBST(HTML_XSL)
1616 AC_SUBST(XSLTPROC)
1617
1618 OPENAFS_OSCONF
1619 OPENAFS_FUSE
1620
1621 TOP_SRCDIR="${srcdir}/src"
1622 dnl
1623 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1624 dnl
1625 case $TOP_SRCDIR in
1626         /*)
1627                 ;;
1628         *)
1629                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1630                 ;;
1631 esac
1632
1633 TOP_OBJDIR="${SRCDIR_PARENT}"
1634 TOP_INCDIR="${SRCDIR_PARENT}/include"
1635 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1636 if test "${DEST}x" = "x"; then
1637         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1638 fi
1639
1640 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1641 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1642 AC_SUBST(HELPER_SPLINT)
1643 AC_SUBST(HELPER_SPLINTCFG)
1644
1645 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1646
1647 dnl Check to see if crypt lives in a different library
1648 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1649 AC_SUBST(LIB_crypt)
1650
1651 dnl Check to see if the compiler support labels in structs
1652 AC_MSG_CHECKING(for label support in structs)
1653 AC_TRY_COMPILE([], [
1654 extern void osi_UFSOpen(void);
1655 struct labeltest {
1656    void (*open) (void);
1657 };
1658 struct labeltest struct_labeltest = {
1659    .open       = osi_UFSOpen,
1660 }
1661 ],
1662 [AC_MSG_RESULT(yes)
1663  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1664 ],
1665 [AC_MSG_RESULT(no)
1666 ])
1667
1668 AC_MSG_CHECKING([checking for dirfd])
1669 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1670 #ifdef HAVE_DIRENT_H
1671 #include <dirent.h>
1672 #endif
1673 ]],
1674         [[DIR *d = 0; dirfd(d);]])],
1675         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1676 if test "$ac_rk_have_dirfd" = "yes" ; then
1677         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1678 fi
1679 AC_MSG_RESULT($ac_rk_have_dirfd)
1680
1681 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1682 #ifdef HAVE_DIRENT_H
1683 #include <dirent.h>
1684 #endif])
1685
1686 dnl Eventually, this will look for the system one, or for OpenSSL
1687 LIB_hcrypto="-lafshcrypto"
1688 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1689 AC_SUBST(LIB_hcrypto)
1690 AC_SUBST(LDFLAGS_hcrypto)
1691 ])
1692
1693 AC_DEFUN([SUMMARY], [
1694     # Print a configuration summary
1695 echo
1696 echo "**************************************"
1697 echo configure summary
1698 echo
1699 AS_IF([test $LIB_curses],[
1700 echo "LIB_curses :                $LIB_curses" ],[
1701 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1702 ])
1703 echo
1704 echo "**************************************"
1705 ])