prototypes-fixes-20020821
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN(OPENAFS_CONFIGURE_COMMON,[
8
9 AC_CANONICAL_HOST
10 SRCDIR_PARENT=`pwd`
11
12 #BOZO_SAVE_CORES BOS_RESTRICTED_MODE BOS_NEW_CONFIG pam sia
13 AC_ARG_WITH(afs-sysname,
14 [  --with-afs-sysname=sys    use sys for the afs sysname]
15 )
16 AC_ARG_ENABLE( obsolete,
17 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
18 AC_ARG_ENABLE( insecure,
19 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
20 AC_ARG_ENABLE( afsdb,
21 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
22 AC_ARG_ENABLE( bos-restricted-mode,
23 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
24 AC_ARG_ENABLE( namei-fileserver,
25 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
26 AC_ARG_ENABLE( fast-restart,
27 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
28 AC_ARG_ENABLE( bitmap-later,
29 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
30 AC_ARG_ENABLE( full-vos-listvol-switch,
31 [  --enable-full-vos-listvol-switch     enable vos full listvol switch for formatted output],, enable_full_vos_listvol_switch="no")
32 AC_ARG_WITH(dux-kernel-headers,
33 [  --with-dux-kernel-headers=path       use the kernel headers found at path(optional, defaults to first match in /usr/sys)]
34 )
35 AC_ARG_WITH(linux-kernel-headers,
36 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux)]
37 )
38 AC_ARG_ENABLE(kernel-module,
39 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
40 )
41 AC_ARG_ENABLE(redhat-buildsys,
42 [  --enable-redhat-buildsys             enable compilation of the redhat build system kernel (defaults to disabled)],, enable_redhat_buildsys="no"
43 )
44 AC_ARG_ENABLE(transarc-paths,
45 [  --enable-transarc-paths                      Use Transarc style paths like /usr/afs and /usr/vice],, enable_transarc_paths="no"
46 )
47 AC_ARG_ENABLE(tivoli-tsm,
48 [  --enable-tivoli-tsm                  Enable use of the Tivoli TSM API libraries for butc support],, enable_tivoli_tsm="no"
49 )
50 AC_ARG_ENABLE(debug-kernel,
51 [  --enable-debug-kernel                enable compilation of the kernel module with debugging information (defaults to disabled)],, enable_debug_kernel="no"
52 )
53
54 dnl weird ass systems
55 AC_AIX
56 AC_ISC_POSIX
57 AC_MINIX
58
59 dnl Various compiler setup.
60 AC_TYPE_PID_T
61 AC_TYPE_SIZE_T
62 AC_TYPE_SIGNAL
63
64 dnl Checks for programs.
65 AC_PROG_INSTALL
66 AC_PROG_LN_S
67 AC_PROG_RANLIB
68 AC_PROG_YACC
69 AM_PROG_LEX
70
71 OPENAFS_CHECK_BIGENDIAN
72
73 KERN_DEBUG_OPT=
74 if test "x$enable_debug_kernel" = "xyes"; then
75   KERN_DEBUG_OPT=-g
76 fi
77
78 AC_MSG_CHECKING(your OS)
79 system=$host
80 case $system in
81         *-linux*)
82                 MKAFS_OSTYPE=LINUX
83                 if test "x$enable_redhat_buildsys" = "xyes"; then
84                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS)
85                 fi
86                 if test "x$enable_kernel_module" = "xyes"; then
87                  if test "x$with_linux_kernel_headers" != "x"; then
88                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
89                  else
90                    LINUX_KERNEL_PATH="/usr/src/linux"
91                  fi
92                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
93                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
94                   if test "x$linux_kvers" = "x"; then
95                     if test -f "$LINUX_KERNEL_PATH/include/linux/version-up.h"; then
96                       linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
97                       if test "x$linux_kvers" = "x"; then
98
99                         AC_MSG_ERROR(Linux headers lack version definition [2])
100                         exit 1
101                       else
102                         LINUX_VERSION="$linux_kvers"
103                       fi
104                     else
105                       AC_MSG_ERROR(Linux headers lack version definition)
106                       exit 1
107                     fi
108                   else
109                     LINUX_VERSION="$linux_kvers"
110                   fi
111                  else
112                     enable_kernel_module="no"
113                  fi
114                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
115                      enable_kernel_module="no"
116                  fi
117                  if test "x$enable_kernel_module" = "xno"; then
118                   if test "x$with_linux_kernel_headers" != "x"; then
119                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
120                    exit 1
121                   else
122                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
123                   fi
124                  fi
125                 fi
126                 AC_MSG_RESULT(linux)
127                 if test "x$enable_kernel_module" = "xyes"; then
128                  OMIT_FRAME_POINTER=
129                  if test "x$enable_debug_kernel" = "xno"; then
130                         OMIT_FRAME_POINTER=-fomit-frame-pointer
131                  fi
132                  AC_SUBST(OMIT_FRAME_POINTER)
133                  ifdef([OPENAFS_CONFIGURE_LIBAFS],
134                    [LINUX_BUILD_VNODE_FROM_INODE(src/config,afs)],
135                    [LINUX_BUILD_VNODE_FROM_INODE(${srcdir}/src/config,src/afs/LINUX,${srcdir}/src/afs/LINUX)]
136                  )
137                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK
138                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_GFP_MASK
139                  LINUX_FS_STRUCT_INODE_HAS_I_TRUNCATE_SEM
140                  LINUX_FS_STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS
141                  LINUX_FS_STRUCT_INODE_HAS_I_DEVICES
142                  LINUX_INODE_SETATTR_RETURN_TYPE
143                  LINUX_NEED_RHCONFIG
144                  LINUX_WHICH_MODULES
145                  if test "x$ac_cv_linux_func_inode_setattr_returns_int" = "xyes" ; then
146                   AC_DEFINE(INODE_SETATTR_NOT_VOID)
147                  fi
148                  if test "x$ac_cv_linux_fs_struct_address_space_has_page_lock" = "xyes"; then 
149                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK)
150                  fi
151                  if test "x$ac_cv_linux_fs_struct_address_space_has_gfp_mask" = "xyes"; then 
152                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_GFP_MASK)
153                  fi
154                  if test "x$ac_cv_linux_fs_struct_inode_has_i_truncate_sem" = "xyes"; then 
155                   AC_DEFINE(STRUCT_INODE_HAS_I_TRUNCATE_SEM)
156                  fi
157                  if test "x$ac_cv_linux_fs_struct_inode_has_i_devices" = "xyes"; then 
158                   AC_DEFINE(STRUCT_INODE_HAS_I_DEVICES)
159                  fi
160                  if test "x$ac_cv_linux_fs_struct_inode_has_i_dirty_data_buffers" = "xyes"; then 
161                   AC_DEFINE(STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS)
162                  fi
163                 :
164                 fi
165                 ;;
166         *-solaris*)
167                 MKAFS_OSTYPE=SOLARIS
168                 AC_MSG_RESULT(sun4)
169                 SOLARIS_UFSVFS_HAS_DQRWLOCK
170                 SOLARIS_PROC_HAS_P_COREFILE
171                 ;;
172         *-sunos*)
173                 MKAFS_OSTYPE=SUNOS
174                 enable_kernel_module=no
175                 AC_MSG_RESULT(sun4)
176                 ;;
177         *-hpux*)
178                 MKAFS_OSTYPE=HPUX
179                 AC_MSG_RESULT(hp_ux)
180                 ;;
181         *-irix*)
182                 if test -d /usr/include/sys/SN/SN1; then
183                  IRIX_BUILD_IP35="IP35"
184                 fi
185                 MKAFS_OSTYPE=IRIX
186                 AC_MSG_RESULT(sgi)
187                 ;;
188         *-aix*)
189                 MKAFS_OSTYPE=AIX
190                 AC_MSG_RESULT(rs_aix)
191                 ;;
192         *-osf*)
193                 MKAFS_OSTYPE=DUX
194                 AC_MSG_RESULT(alpha_dux)
195                 if test "x$enable_kernel_module" = "xyes"; then
196                  if test "x$with_dux_kernel_headers" != "x"; then
197                    HEADER_RT=`ls ${with_dux_kernel_headers}/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
198                  else
199                    HEADER_RT=`ls /usr/sys/*/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
200                  fi
201                 fi
202                 if test "$HEADER_RT" = "*" ; then
203                         AC_MSG_ERROR([Need a configured kernel directory])
204                 fi
205                 AC_SUBST([HEADER_RT])
206                 ;;
207         *-darwin*)
208                 MKAFS_OSTYPE=DARWIN
209                 AC_MSG_RESULT(ppc_darwin)
210                 ;;
211         *-freebsd*)
212                 MKAFS_OSTYPE=FBSD
213                 AC_MSG_RESULT(i386_fbsd)
214                 ;;
215         *-netbsd*)
216                 MKAFS_OSTYPE=NBSD
217                 AC_MSG_RESULT(nbsd)
218                 ;;
219         *-openbsd*)
220                 MKAFS_OSTYPE=OBSD
221                 AC_MSG_RESULT(i386_obsd)
222                 ;;
223         *)
224                 AC_MSG_RESULT($system)
225                 ;;
226 esac
227 AC_SUBST(KERN_DEBUG_OPT)
228
229 if test "x$with_afs_sysname" != "x"; then
230         AFS_SYSNAME="$with_afs_sysname"
231 else
232         AC_MSG_CHECKING(your AFS sysname)
233         case $host in
234                 i?86-*-freebsd4.2*)
235                         AFS_SYSNAME="i386_fbsd_42"
236                         ;;
237                 i?86-*-freebsd4.3*)
238                         AFS_SYSNAME="i386_fbsd_43"
239                         ;;
240                 i?86-*-freebsd4.4*)
241                         AFS_SYSNAME="i386_fbsd_44"
242                         ;;
243                 i?86-*-freebsd4.5*)
244                         AFS_SYSNAME="i386_fbsd_45"
245                         ;;
246                 i?86-*-freebsd4.6*)
247                         AFS_SYSNAME="i386_fbsd_46"
248                         ;;
249                 i?86-*-netbsd*1.5*)
250                         AFS_PARAM_COMMON=param.nbsd15.h
251                         AFS_SYSNAME="i386_nbsd15"
252                         ;;
253                 alpha-*-netbsd*1.5*)
254                         AFS_PARAM_COMMON=param.nbsd15.h
255                         AFS_SYSNAME="alpha_nbsd15"
256                         ;;
257                 i?86-*-netbsd*1.6*)
258                         AFS_PARAM_COMMON=param.nbsd16.h
259                         AFS_SYSNAME="i386_nbsd16"
260                         ;;
261                 alpha-*-netbsd*1.6*)
262                         AFS_PARAM_COMMON=param.nbsd16.h
263                         AFS_SYSNAME="alpha_nbsd16"
264                         ;;
265                 hppa*-hp-hpux11*)
266                         AFS_SYSNAME="hp_ux110"
267                         ;;
268                 hppa*-hp-hpux10*)
269                         AFS_SYSNAME="hp_ux102"
270                         ;;
271                 powerpc-apple-darwin1.2*)
272                         AFS_SYSNAME="ppc_darwin_12"
273                         ;;
274                 powerpc-apple-darwin1.3*)
275                         AFS_SYSNAME="ppc_darwin_13"
276                         ;;
277                 powerpc-apple-darwin1.4*)
278                         AFS_SYSNAME="ppc_darwin_14"
279                         ;;
280                 powerpc-apple-darwin5.1*)
281                         AFS_SYSNAME="ppc_darwin_14"
282                         ;;
283                 powerpc-apple-darwin5.2*)
284                         AFS_SYSNAME="ppc_darwin_14"
285                         ;;
286                 powerpc-apple-darwin5.3*)
287                         AFS_SYSNAME="ppc_darwin_14"
288                         ;;
289                 powerpc-apple-darwin5.4*)
290                         AFS_SYSNAME="ppc_darwin_14"
291                         ;;
292                 powerpc-apple-darwin5.5*)
293                         AFS_SYSNAME="ppc_darwin_14"
294                         ;;
295                 powerpc-apple-darwin6.0*)
296                         AFS_SYSNAME="ppc_darwin_60"
297                         ;;
298                 sparc-sun-solaris2.5*)
299                         AFS_SYSNAME="sun4x_55"
300                         ;;
301                 sparc-sun-solaris2.6)
302                         AFS_SYSNAME="sun4x_56"
303                         ;;
304                 sparc-sun-solaris2.7)
305                         AFS_SYSNAME="sun4x_57"
306                         ;;
307                 sparc-sun-solaris2.8)
308                         AFS_SYSNAME="sun4x_58"
309                         ;;
310                 sparc-sun-solaris2.9)
311                         AFS_SYSNAME="sun4x_59"
312                         ;;
313                 sparc-sun-sunos4*)
314                         AFS_SYSNAME="sun4_413"
315                         ;;
316                 i386-pc-solaris2.7)
317                         AFS_SYSNAME="sunx86_57"
318                         ;;
319                 i386-pc-solaris2.8)
320                         AFS_SYSNAME="sunx86_58"
321                         ;;
322                 i386-pc-solaris2.9)
323                         AFS_SYSNAME="sunx86_59"
324                         ;;
325                 alpha*-dec-osf4.0*)
326                         AFS_SYSNAME="alpha_dux40"
327                         ;;
328                 alpha*-dec-osf5.0*)
329                         AFS_SYSNAME="alpha_dux50"
330                         ;;
331                 mips-sgi-irix6.5)
332                         AFS_SYSNAME="sgi_65"
333                         ;;
334                 ia64-*-linux*)
335                         AFS_SYSNAME="ia64_linuxXX"
336                         ;;
337                 powerpc-*-linux*)
338                         AFS_SYSNAME="ppc_linuxXX"
339                         ;;
340                 alpha*-linux*)
341                         AFS_SYSNAME="alpha_linux_XX"
342                         ;;
343                 s390-*-linux*)
344                         AFS_SYSNAME="s390_linuxXX"
345                         ;;
346                 sparc-*-linux*)
347                         AFS_SYSNAME="sparc_linuxXX"
348                         ;;
349                 sparc64-*-linux*)
350                         AFS_SYSNAME="sparc64_linuxXX"
351                         ;;
352                 i?86-*-linux*)
353                         AFS_SYSNAME="i386_linuxXX"
354                         ;;
355                 parisc-*-linux-gnu)
356                         AFS_SYSNAME="parisc_linuxXX"
357                         ;;
358                 power*-ibm-aix4.2*)
359                         AFS_SYSNAME="rs_aix42"
360                         ;;
361                 power*-ibm-aix4.3*)
362                         AFS_SYSNAME="rs_aix42"
363                         ;;
364                 *)
365                         AC_MSG_ERROR(An AFS sysname is required)
366                         exit 1
367                         ;;
368         esac
369         case $AFS_SYSNAME in
370                 *_linux*)
371                         AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $[]1 $[]2}'`
372                         if test "x${AFS_SYSKVERS}" = "x"; then
373                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
374                         fi
375                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
376                         AFS_SYSNAME="$_AFS_SYSNAME"
377                         ;;
378         esac
379         AC_MSG_RESULT($AFS_SYSNAME)
380 fi
381
382 case $AFS_SYSNAME in
383         *_darwin*)
384                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
385                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
386                 ;;
387 esac
388
389 AC_MSG_CHECKING(for definition of struct buf)
390 AC_CACHE_VAL(ac_cv_have_struct_buf, [
391         ac_cv_have_struct_buf=no
392         AC_TRY_COMPILE(
393                 [#include <sys/buf.h>],
394                 [struct buf x;
395                 printf("%d\n", sizeof(x));],
396                 ac_cv_have_struct_buf=yes,)
397         ]
398 )
399 AC_MSG_RESULT($ac_cv_have_struct_buf)
400 if test "$ac_cv_have_struct_buf" = yes; then
401         AC_DEFINE(HAVE_STRUCT_BUF)
402 fi
403
404
405 AC_CACHE_VAL(ac_cv_sockaddr_len,
406 [
407 AC_MSG_CHECKING([if struct sockaddr has sa_len field])
408 AC_TRY_COMPILE( [#include <sys/types.h>
409 #include <sys/socket.h>],
410 [struct sockaddr *a;
411 a->sa_len=0;], ac_cv_sockaddr_len=yes, ac_cv_sockaddr_len=no)
412 AC_MSG_RESULT($ac_cv_sockaddr_len)])
413 if test "$ac_cv_sockaddr_len" = "yes"; then
414    AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN)
415 fi
416 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
417         echo Skipping library tests because they confuse Irix.
418 else
419   AC_CHECK_FUNCS(socket)
420
421   if test "$ac_cv_func_socket" = no; then
422     for lib in socket inet; do
423         if test "$HAVE_SOCKET" != 1; then
424                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET))
425         fi
426     done
427   fi
428   
429   AC_CHECK_FUNCS(connect)       
430
431   if test "$ac_cv_func_connect" = no; then
432     for lib in nsl; do
433         if test "$HAVE_CONNECT" != 1; then
434                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT))
435         fi
436     done
437   fi
438
439   AC_CHECK_FUNCS(gethostbyname)
440   if test "$ac_cv_func_gethostbyname" = no; then
441         for lib in dns nsl resolv; do
442           if test "$HAVE_GETHOSTBYNAME" != 1; then
443             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME))
444           fi
445         done    
446   fi    
447
448   AC_CHECK_FUNCS(res_search)
449   if test "$ac_cv_func_res_search" = no; then
450         for lib in dns nsl resolv; do
451           if test "$HAVE_RES_SEARCH" != 1; then
452             AC_CHECK_LIB(${lib}, res_search, LIBS="$LIBS -l$lib";HAVE_RES_SEARCH=1;AC_DEFINE(HAVE_RES_SEARCH))
453           fi
454         done    
455         if test "$HAVE_RES_SEARCH" = 1; then
456           LIB_res_search="-l$lib"       
457         fi
458   fi    
459 fi
460
461 PTHREAD_LIBS=error
462 AC_CHECK_LIB(pthread, pthread_attr_init,
463              PTHREAD_LIBS="-lpthread")
464 if test "x$PTHREAD_LIBS" = xerror; then
465         AC_CHECK_LIB(pthreads, pthread_attr_init,
466                 PTHREAD_LIBS="-lpthreads")
467 fi
468 if test "x$PTHREAD_LIBS" = xerror; then
469         AC_CHECK_LIB(c_r, pthread_attr_init,
470                 PTHREAD_LIBS="-lc_r")
471 fi
472 if test "x$PTHREAD_LIBS" = xerror; then
473         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
474 fi
475 if test "x$PTHREAD_LIBS" = xerror; then
476         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
477 fi
478 AC_SUBST(PTHREAD_LIBS)
479
480 WITH_OBSOLETE=NO
481 if test "$enable_obsolete" = "yes"; then
482         WITH_OBSOLETE=YES
483 fi
484
485 WITH_INSECURE=NO
486 if test "$enable_insecure" = "yes"; then
487         WITH_INSECURE=YES
488 fi
489
490 # Fast restart
491 if test "$enable_fast_restart" = "yes"; then
492         AC_DEFINE(FAST_RESTART)
493 fi
494
495 if test "$enable_bitmap_later" = "yes"; then
496         AC_DEFINE(BITMAP_LATER)
497 fi
498
499 if test "$enable_full_vos_listvol_switch" = "yes"; then
500         AC_DEFINE(FULL_LISTVOL_SWITCH)
501 fi
502
503 if test "$enable_bos_restricted_mode" = "yes"; then
504         AC_DEFINE(BOS_RESTRICTED_MODE)
505 fi
506
507 if test "$enable_namei_fileserver" = "yes"; then
508         AC_DEFINE(AFS_NAMEI_ENV)
509 fi
510
511 if test "$enable_afsdb" = "yes"; then
512         LIB_AFSDB="$LIB_res_search"
513         AC_DEFINE(AFS_AFSDB_ENV)
514 fi
515
516 dnl check for tivoli
517 AC_MSG_CHECKING(for tivoli tsm butc support)
518 XBSA_CFLAGS=""
519 if test "$enable_tivoli_tsm" = "yes"; then
520         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
521         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
522
523         if test -e "$XBSADIR1/xbsa.h"; then
524                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
525                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
526         elif test -e "$XBSADIR2/xbsa.h"; then
527                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
528                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
529         else
530                 AC_MSG_RESULT([no, missing xbsa.h header file])
531         fi
532 else
533         AC_MSG_RESULT([no])
534 fi
535 AC_SUBST(XBSA_CFLAGS)
536
537 dnl checks for header files.
538 AC_HEADER_STDC
539 AC_HEADER_SYS_WAIT
540 AC_HEADER_DIRENT
541 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
542 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
543 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h)
544 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
545 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h)
546 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h)
547
548 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf re_comp re_exec)
549 AC_CHECK_FUNCS(setprogname getprogname sigaction)
550 AC_CHECK_TYPE(ssize_t, int)
551
552 dnl Directory PATH handling
553 if test "x$enable_transarc_paths" = "xyes"  ; then 
554     afsconfdir=${afsconfdir=/usr/afs/etc}
555     viceetcdir=${viceetcdir=/usr/vice/etc}
556     afskerneldir=${afskerneldir=${viceetcdir}}
557     afssrvbindir=${afssrvbindir=/usr/afs/bin}
558     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
559     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
560     afsdbdir=${afsdbdir=/usr/afs/db}
561     afslogsdir=${afslogsdir=/usr/afs/logs}
562     afslocaldir=${afslocaldir=/usr/afs/local}
563     afsbackupdir=${afsbackupdir=/usr/afs/backup}
564     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
565 else 
566     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
567     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
568     afskerneldir=${afskerneldir='${libdir}/openafs'}
569     afssrvbindir=${afssrvbindir='${bindir}'}
570     afssrvsbindir=${afssrvsbindir='${sbindir}'}
571     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
572     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
573     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
574     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
575     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
576     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
577 fi
578 AC_SUBST(afsconfdir)
579 AC_SUBST(viceetcdir)
580 AC_SUBST(afskerneldir)
581 AC_SUBST(afssrvbindir)
582 AC_SUBST(afssrvsbindir)
583 AC_SUBST(afssrvlibexecdir)
584 AC_SUBST(afsdbdir)
585 AC_SUBST(afslogsdir)
586 AC_SUBST(afslocaldir)
587 AC_SUBST(afsbackupdir)
588 AC_SUBST(afsbosconfigdir)
589
590 if test "x$enable_kernel_module" = "xyes"; then
591 ENABLE_KERNEL_MODULE=libafs
592 fi
593
594 AC_SUBST(AFS_SYSNAME)
595 AC_SUBST(AFS_PARAM_COMMON)
596 AC_SUBST(ENABLE_KERNEL_MODULE)
597 AC_SUBST(LIB_AFSDB)
598 AC_SUBST(LINUX_KERNEL_PATH)
599 AC_SUBST(LINUX_VERSION)
600 AC_SUBST(MKAFS_OSTYPE)
601 AC_SUBST(TOP_OBJDIR)
602 AC_SUBST(TOP_SRCDIR)
603 AC_SUBST(TOP_INCDIR)
604 AC_SUBST(TOP_LIBDIR)
605 AC_SUBST(DEST)
606 AC_SUBST(WITH_OBSOLETE)
607 AC_SUBST(WITH_INSECURE)
608 AC_SUBST(DARWIN_INFOFILE)
609 AC_SUBST(IRIX_BUILD_IP35)
610
611 OPENAFS_OSCONF
612
613 ])