acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
   8 AH_BOTTOM([
   9 #undef HAVE_RES_SEARCH
  10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
  11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
  12 # if ENDIANESS_IN_SYS_PARAM_H
  13 #  ifndef KERNEL
  14 #   include <sys/types.h>
  15 #   include <sys/param.h>
  16 #   if BYTE_ORDER == BIG_ENDIAN
  17 #    define WORDS_BIGENDIAN 1
  18 #   endif
  19 #  else
  20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
  21 #    define WORDS_BIGENDIAN 1
  22 #   else
  23 #    undef WORDS_BIGENDIAN
  24 #   endif
  25 #  endif
  26 # else
  27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
  28 #   define WORDS_BIGENDIAN 1
  29 #  else
  30 #   undef WORDS_BIGENDIAN
  31 #  endif
  32 # endif
  33 #else
  34 # if defined(__BIG_ENDIAN__)
  35 #  define WORDS_BIGENDIAN 1
  36 # else
  37 #  undef WORDS_BIGENDIAN
  38 # endif
  39 #endif
  40 #ifdef UKERNEL
  41 /*
  42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
  43  * play nice with some other interfaces like FUSE. We technically only would
  44  * need to define this when building for such interfaces, but set it always to
  45  * try and reduce potential confusion.
  46  */
  47 # define _FILE_OFFSET_BITS 64
  48 # define AFS_CACHE_VNODE_PATH
  49 #endif
  50
  51 #undef AFS_NAMEI_ENV
  52 #undef BITMAP_LATER
  53 #undef FAST_RESTART
  54 #undef DEFINED_FOR_EACH_PROCESS
  55 #undef DEFINED_PREV_TASK
  56 #undef EXPORTED_SYS_CALL_TABLE
  57 #undef EXPORTED_IA32_SYS_CALL_TABLE
  58 #undef IRIX_HAS_MEM_FUNCS
  59 #undef RECALC_SIGPENDING_TAKES_VOID
  60 #undef STRUCT_FS_HAS_FS_ROLLED
  61 #undef ssize_t
  62 /* glue for RedHat kernel bug */
  63 #undef ENABLE_REDHAT_BUILDSYS
  64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
  65 # include "redhat-fix.h"
  66 #endif])
  67
  68 AC_CANONICAL_HOST
  69 SRCDIR_PARENT=`pwd`
  70
  71 #BOZO_SAVE_CORES pam
  72
  73 dnl System identity.
  74 AC_ARG_WITH([afs-sysname],
  75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])
  76 ])
  77
  78 dnl General feature options.
  79 AC_ARG_ENABLE([namei-fileserver],
  80     [AS_HELP_STRING([--enable-namei-fileserver],
  81         [force compilation of namei fileserver in preference to inode
  82          fileserver])],
  83     [],
  84     [enable_namei_fileserver="default"])
  85 AC_ARG_ENABLE([supergroups],
  86     [AS_HELP_STRING([--enable-supergroups],
  87         [enable support for nested pts groups])],
  88     [],
  89     [enable_supergroups="no"])
  90 AC_ARG_ENABLE([bitmap-later],
  91     [AS_HELP_STRING([--enable-bitmap-later],
  92         [enable fast startup of file server by not reading bitmap till
  93          needed])],
  94     [AS_IF([test x"$withval" = xyes],
  95         [AC_MSG_WARN([bitmap-later is only used by non-demand-attach
  96             fileservers.  Please migrate to demand-attach instead.])])],
  97     [enable_bitmap_later="no"])
  98 AC_ARG_ENABLE([unix-sockets],
  99     [AS_HELP_STRING([--disable-unix-sockets],
 100         [disable use of unix domain sockets for fssync (defaults to enabled)])],
 101     [],
 102     [enable_unix_sockets="yes"])
 103 AC_ARG_ENABLE([tivoli-tsm],
 104     [AS_HELP_STRING([--enable-tivoli-tsm],
 105         [enable use of the Tivoli TSM API libraries for butc support])],
 106     [],
 107     [enable_tivoli_tsm="no"])
 108 AC_ARG_ENABLE([pthreaded-ubik],
 109     [AS_HELP_STRING([--disable-pthreaded-ubik],
 110         [disable installation of pthreaded ubik applications (defaults to
 111          enabled)])],
 112     [],
 113     [enable_pthreaded_ubik="yes"])
 114 AC_ARG_ENABLE([ubik-read-while-write],
 115     [AS_HELP_STRING([--enable-ubik-read-while-write],
 116         [enable vlserver read from db cache during write locks (EXPERIMENTAL)])],
 117     [],
 118     [enable_ubik_read_while_write="no"])
 119
 120 dnl Kernel module build options.
 121 AC_ARG_WITH([linux-kernel-headers],
 122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
 123         [use the kernel headers found at path (optional, defaults to
 124          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
 125          then /usr/src/linux-2.4, and lastly /usr/src/linux)])
 126 ])
 127 AC_ARG_WITH([linux-kernel-build],
 128     [AS_HELP_STRING([--with-linux-kernel-build=path],
 129         [use the kernel build found at path(optional, defaults to
 130         kernel headers path)]
 131 )])
 132 AC_ARG_WITH([bsd-kernel-headers],
 133     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
 134         [use the kernel headers found at path (optional, defaults to
 135          /usr/src/sys)])
 136 ])
 137 AC_ARG_WITH([bsd-kernel-build],
 138     [AS_HELP_STRING([--with-bsd-kernel-build=path],
 139         [use the kernel build found at path (optional, defaults to
 140          KSRC/i386/compile/GENERIC)])
 141 ])
 142 AC_ARG_WITH([linux-kernel-packaging],
 143     [AS_HELP_STRING([--with-linux-kernel-packaging],
 144         [use standard naming conventions to aid Linux kernel build packaging
 145          (disables MPS, sets the kernel module name to openafs.ko, and
 146          installs kernel modules into the standard Linux location)])],
 147     [AC_SUBST([LINUX_KERNEL_PACKAGING], [yes])
 148      AC_SUBST([LINUX_LIBAFS_NAME], [openafs])],
 149     [AC_SUBST([LINUX_LIBAFS_NAME], [libafs])
 150 ])
 151 AC_ARG_ENABLE([kernel-module],
 152     [AS_HELP_STRING([--disable-kernel-module],
 153         [disable compilation of the kernel module (defaults to enabled)])],
 154     [],
 155     [enable_kernel_module="yes"])
 156 AC_ARG_ENABLE([redhat-buildsys],
 157     [AS_HELP_STRING([--enable-redhat-buildsys],
 158         [enable compilation of the redhat build system kernel (defaults to
 159          disabled)])],
 160     [],
 161     [enable_redhat_buildsys="no"])
 162
 163 dnl Installation locations.
 164 AC_ARG_ENABLE([transarc-paths],
 165     [AS_HELP_STRING([--enable-transarc-paths],
 166         [use Transarc style paths like /usr/afs and /usr/vice])],
 167     [],
 168     [enable_transarc_paths="no"])
 169
 170 dnl Deprecated crypto
 171 AC_ARG_ENABLE([kauth],
 172     [AS_HELP_STRING([--enable-kauth],
 173         [install the deprecated kauth server, pam modules, and utilities
 174          (defaults to disabled)])],
 175     [enable_pam="yes"],
 176     [enable_kauth="no"
 177      enable_pam="no"])
 178
 179 dnl Optimization and debugging flags.
 180 AC_ARG_ENABLE([strip-binaries],
 181     [AS_HELP_STRING([--disable-strip-binaries],
 182         [disable stripping of symbol information from binaries (defaults to
 183          enabled)])],
 184     [],
 185     [enable_strip_binaries="maybe"])
 186 AC_ARG_ENABLE([debug],
 187     [AS_HELP_STRING([--enable-debug],
 188         [enable compilation of the user space code with debugging information
 189          (defaults to disabled)])],
 190     [],
 191     [enable_debug="no"])
 192 AC_ARG_ENABLE([optimize],
 193     [AS_HELP_STRING([--disable-optimize],
 194         [disable optimization for compilation of the user space code (defaults
 195          to enabled)])],
 196     [],
 197     [enable_optimize="yes"])
 198 AC_ARG_ENABLE([warnings],
 199     [AS_HELP_STRING([--enable-warnings],
 200         [enable compilation warnings when building with gcc (defaults to
 201          disabled)])],
 202     [],
 203     [enable_warnings="no"])
 204 AC_ARG_ENABLE([checking],
 205     [AS_HELP_STRING([--enable-checking],
 206         [turn compilation warnings into errors when building with gcc (defaults
 207          to disabled)])],
 208     [enable_checking="$enableval"],
 209     [enable_checking="no"])
 210 AC_ARG_ENABLE([debug-locks],
 211     [AS_HELP_STRING([--enable-debug-locks],
 212         [turn on lock debugging assertions (defaults to disabled)])],
 213     [enable_debug_locks="$enableval"],
 214     [enable_debug_locks="no"])
 215 AC_ARG_ENABLE([debug-kernel],
 216     [AS_HELP_STRING([--enable-debug-kernel],
 217         [enable compilation of the kernel module with debugging information
 218          (defaults to disabled)])],
 219     [],
 220     [enable_debug_kernel="no"])
 221 AC_ARG_ENABLE([optimize-kernel],
 222     [AS_HELP_STRING([--disable-optimize-kernel],
 223         [disable compilation of the kernel module with optimization (defaults
 224          based on platform)])],
 225     [],
 226     [enable_optimize_kernel=""])
 227 AC_ARG_ENABLE([debug-lwp],
 228     [AS_HELP_STRING([--enable-debug-lwp],
 229         [enable compilation of the LWP code with debugging information
 230          (defaults to disabled)])],
 231     [],
 232     [enable_debug_lwp="no"])
 233 AC_ARG_ENABLE([optimize-lwp],
 234     [AS_HELP_STRING([--disable-optimize-lwp],
 235         [disable optimization for compilation of the LWP code (defaults to
 236          enabled)])],
 237     [],
 238     [enable_optimize_lwp="yes"])
 239 AC_ARG_ENABLE([debug-pam],
 240     [AS_HELP_STRING([--enable-debug-pam],
 241         [enable compilation of the PAM code with debugging information
 242          (defaults to disabled)])],
 243     [],
 244     [enable_debug_pam="no"])
 245 AC_ARG_ENABLE([optimize-pam],
 246     [AS_HELP_STRING([--disable-optimize-pam],
 247         [disable optimization for compilation of the PAM code (defaults to
 248          enabled)])],
 249     [],
 250     [enable_optimize_pam="yes"])
 251 AC_ARG_ENABLE([linux-syscall-probing],
 252     [AS_HELP_STRING([--enable-linux-syscall-probing],
 253         [enable Linux syscall probing (defaults to autodetect)])],
 254     [],
 255     [enable_linux_syscall_probing="maybe"])
 256 AC_ARG_ENABLE([linux-d_splice_alias-extra-iput],
 257     [AS_HELP_STRING([--enable-linux-d_splice_alias-extra-iput],
 258         [Linux kernels in the 3.17 series prior to 3.17.3 had a bug
 259          wherein error returns from the d_splice_alias() function were
 260          leaking a reference on the inode.  The bug was fixed for the
 261          3.17.3 kernel, and the possibility of an error return was only
 262          introduced in kernel 3.17, so only the narrow range of kernels
 263          is affected.  Enable this option for builds on systems with
 264          kernels affected by this bug, to manually release the reference
 265          on error returns and correct the reference counting.
 266          Linux commit 51486b900ee92856b977eacfc5bfbe6565028070 (or
 267          equivalent) is the fix for the upstream bug, so if such a commit
 268          is present, leave this option disabled.  We apologize
 269          that you are required to know this about your running kernel,
 270          but luckily only a narrow range of versions is affected.])],
 271     [],
 272     [enable_linux_d_splice_alias_extra_iput="no"])
 273 AC_ARG_WITH([crosstools-dir],
 274     [AS_HELP_STRING([--with-crosstools-dir=path],
 275         [use path for native versions of rxgen, compile_et and config])
 276 ])
 277
 278 AC_ARG_WITH([xslt-processor],
 279         AS_HELP_STRING([--with-xslt-processor=ARG],
 280         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
 281         [XSLTPROC="$withval"],
 282         [AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo])])
 283
 284 AC_ARG_WITH([html-xsl],
 285         AS_HELP_STRING([--with-html-xsl],
 286         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
 287         [HTML_XSL="$withval"],
 288         [HTML_XSL="html/chunk.xsl"])
 289
 290 AC_ARG_WITH([docbook2pdf],
 291         AS_HELP_STRING([--with-docbook2pdf=ARG],
 292         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
 293         [DOCBOOK2PDF="$withval"],
 294         [AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo])])
 295
 296 AC_ARG_WITH([docbook-stylesheets],
 297         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
 298         [location of DocBook stylesheets (default is to search a set of likely paths)]),
 299         [DOCBOOK_STYLESHEETS="$withval"],
 300         [OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS],
 301                 [/usr/share/xml/docbook/stylesheet/nwalsh/current \
 302                  /usr/share/xml/docbook/stylesheet/nwalsh \
 303                  /usr/share/xml/docbook/xsl-stylesheets \
 304                  /usr/share/sgml/docbook/docbook-xsl-stylesheets \
 305                  /usr/share/sgml/docbook/xsl-stylesheets \
 306                  /usr/share/docbook-xsl \
 307                  /usr/share/sgml/docbkxsl \
 308                  /usr/local/share/xsl/docbook \
 309                  /sw/share/xml/xsl/docbook-xsl \
 310                  /opt/local/share/xsl/docbook-xsl],
 311                 [$HTML_XSL])
 312            AS_IF([test "x$DOCBOOK_STYLESHEETS" = "x"],
 313                 [AC_WARN([Docbook stylesheets not found; some documentation can't be built])
 314            ])
 315         ])
 316
 317 AC_ARG_WITH([dot],
 318         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
 319         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
 320         [], [with_dot="maybe"])
 321
 322 enable_login="no"
 323
 324 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
 325 dnl documentation build.
 326 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
 327 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 328
 329 dnl Optionally generate graphs with doxygen.
 330 case "$with_dot" in
 331 maybe)
 332     AC_CHECK_PROGS([DOT], [dot])
 333     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
 334     ;;
 335 yes)
 336     HAVE_DOT="yes"
 337     ;;
 338 no)
 339     HAVE_DOT="no"
 340     ;;
 341 *)
 342     HAVE_DOT="yes"
 343     DOT_PATH=$with_dot
 344 esac
 345 AC_SUBST(HAVE_DOT)
 346 AC_SUBST(DOT_PATH)
 347
 348 dnl Checks for UNIX variants.
 349 AC_ISC_POSIX
 350
 351 dnl Various compiler setup.
 352 AC_TYPE_PID_T
 353 AC_TYPE_SIZE_T
 354
 355 dnl Checks for programs.
 356 AC_PROG_INSTALL
 357 AC_PROG_LN_S
 358 AC_PROG_RANLIB
 359 AC_PROG_YACC
 360 AM_PROG_LEX
 361 dnl if we are flex, be lex-compatible
 362 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
 363
 364 OPENAFS_FORCE_ABS_INSTALL
 365 OPENAFS_CHECK_BIGENDIAN
 366 OPENAFS_PRINTF_TAKES_Z_LEN
 367
 368 AC_MSG_CHECKING(your OS)
 369 system=$host
 370 case $system in
 371         *-linux*)
 372
 373                 MKAFS_OSTYPE=LINUX
 374                 if test "x$enable_redhat_buildsys" = "xyes"; then
 375                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
 376                 fi
 377                 if test "x$enable_kernel_module" = "xyes"; then
 378                  if test "x$with_linux_kernel_headers" != "x"; then
 379                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
 380                  else
 381                    for utsdir in "/lib/modules/`uname -r`/build" \
 382                                  "/lib/modules/`uname -r`/source" \
 383                                  "/usr/src/linux-2.4" \
 384                                  "/usr/src/linux"; do
 385                      LINUX_KERNEL_PATH="$utsdir"
 386                      for utsfile in "include/generated/utsrelease.h" \
 387                                     "include/linux/utsrelease.h" \
 388                                     "include/linux/version.h" \
 389                                     "include/linux/version-up.h"; do
 390                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
 391                          break 2
 392                        fi
 393                      done
 394                    done
 395                  fi
 396                  if test "x$with_linux_kernel_build" != "x"; then
 397                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
 398                  else
 399                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
 400                  fi
 401                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
 402                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 403                    LINUX_VERSION="$linux_kvers"
 404                  else
 405                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
 406                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 407                      LINUX_VERSION="$linux_kvers"
 408                    else
 409                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
 410                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 411                        if test "x$linux_kvers" = "x"; then
 412                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
 413                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
 414                            if test "x$linux_kvers" = "x"; then
 415                              AC_MSG_ERROR(Linux headers lack version definition [2])
 416                              exit 1
 417                            else
 418                              LINUX_VERSION="$linux_kvers"
 419                            fi
 420                          else
 421                            AC_MSG_ERROR(Linux headers lack version definition)
 422                            exit 1
 423                          fi
 424                        else
 425                          LINUX_VERSION="$linux_kvers"
 426                        fi
 427                      else
 428                        enable_kernel_module="no"
 429                      fi
 430                    fi
 431                  fi
 432                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
 433                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
 434                      enable_kernel_module="no"
 435                  fi
 436                  if test "x$enable_kernel_module" = "xno"; then
 437                   if test "x$with_linux_kernel_headers" != "x"; then
 438                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 439                    exit 1
 440                   else
 441                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 442                   fi
 443                  fi
 444                  dnl do we need to determine SUBARCH from autoconf.h
 445                  SUBARCH=default
 446                 fi
 447                 AC_MSG_RESULT(linux)
 448                 GUESS_LINUX_VERSION=
 449                 if test "x$enable_kernel_module" = "xyes"; then
 450                  GUESS_LINUX_VERSION=${LINUX_VERSION}
 451                 else
 452                  GUESS_LINUX_VERSION=`uname -r`
 453                 fi
 454                 case "$GUESS_LINUX_VERSION" in
 455                   2.2.*) AFS_SYSKVERS=22 ;;
 456                   2.4.*) AFS_SYSKVERS=24 ;;
 457                   [2.6.* | [3-9]* | [1-2][0-9]*]) AFS_SYSKVERS=26 ;;
 458                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
 459                 esac
 460                 ;;
 461         *-solaris*)
 462                 MKAFS_OSTYPE=SOLARIS
 463                 AC_MSG_RESULT(sun4)
 464                 AC_PATH_PROG(SOLARISCC, [cc], ,
 465                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
 466                 if test "x$SOLARISCC" = "x" ; then
 467                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
 468                 fi
 469                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 470                 SOLARIS_FS_HAS_FS_ROLLED
 471                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
 472                 SOLARIS_HAVE_VN_RENAMEPATH
 473                 ;;
 474         *-sunos*)
 475                 MKAFS_OSTYPE=SUNOS
 476                 enable_kernel_module=no
 477                 AC_MSG_RESULT(sun4)
 478                 ;;
 479         *-hpux*)
 480                 MKAFS_OSTYPE=HPUX
 481                 AC_MSG_RESULT(hp_ux)
 482                 if test -f "/usr/old/usr/include/ndir.h"; then
 483                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
 484                 fi
 485                 ;;
 486         *-irix*)
 487                 if test -d /usr/include/sys/SN/SN1; then
 488                  IRIX_BUILD_IP35="IP35"
 489                 fi
 490                 MKAFS_OSTYPE=IRIX
 491                 AC_MSG_RESULT(sgi)
 492                 ;;
 493         *-aix*)
 494                 MKAFS_OSTYPE=AIX
 495                 AC_MSG_RESULT(rs_aix)
 496                 ;;
 497         arm-*-darwin*)
 498                 MKAFS_OSTYPE=DARWIN
 499                 AC_MSG_RESULT(arm_darwin)
 500                 ;;
 501         powerpc-*-darwin*)
 502                 MKAFS_OSTYPE=DARWIN
 503                 AC_MSG_RESULT(ppc_darwin)
 504                 ;;
 505         i386-*-darwin*)
 506                 MKAFS_OSTYPE=DARWIN
 507                 AC_MSG_RESULT(x86_darwin)
 508                 ;;
 509         x86_64-*-darwin*)
 510                 MKAFS_OSTYPE=DARWIN
 511                 AC_MSG_RESULT(x86_darwin)
 512                 ;;
 513         i386-*-freebsd*)
 514                 MKAFS_OSTYPE=FBSD
 515                 AC_MSG_RESULT(i386_fbsd)
 516                 ;;
 517         x86_64-*-freebsd*)
 518                 MKAFS_OSTYPE=FBSD
 519                 AC_MSG_RESULT(amd64_fbsd)
 520                 ;;
 521         *-netbsd*)
 522                 MKAFS_OSTYPE=NBSD
 523                 AC_MSG_RESULT(nbsd)
 524                 ;;
 525         x86_64-*-openbsd*)
 526                 MKAFS_OSTYPE=OBSD
 527                 AC_MSG_RESULT(amd64_obsd)
 528                 ;;
 529         i386-*-openbsd*)
 530                 MKAFS_OSTYPE=OBSD
 531                 AC_MSG_RESULT(i386_obsd)
 532                 ;;
 533         *-dragonfly*)
 534                 MKAFS_OSTYPE=DFBSD
 535                 AC_MSG_RESULT(i386_dfbsd)
 536                 ;;
 537         *)
 538                 AC_MSG_RESULT($system)
 539                 ;;
 540 esac
 541
 542 if test "x$with_afs_sysname" != "x"; then
 543         AFS_SYSNAME="$with_afs_sysname"
 544 else
 545         AC_MSG_CHECKING(your AFS sysname)
 546         case $host in
 547                 i?86-*-openbsd?.?)
 548                         v=${host#*openbsd}
 549                         vM=${v%.*}
 550                         vm=${v#*.}
 551                         AFS_SYSNAME="i386_obsd${vM}${vm}"
 552                         ;;
 553                 sparc64-*-openbsd?.?)
 554                         v=${host#*openbsd}
 555                         vM=${v%.*}
 556                         vm=${v#*.}
 557                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
 558                         ;;
 559                 x86_64-*-openbsd?.?)
 560                         v=${host#*openbsd}
 561                         vM=${v%.*}
 562                         vm=${v#*.}
 563                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
 564                         ;;
 565                 i?86-*-freebsd*.*)
 566                         v=${host#*freebsd}
 567                         vM=${v%.*}
 568                         vm=${v#*.}
 569                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
 570                         ;;
 571                 x86_64-*-freebsd*.*)
 572                         v=${host#*freebsd}
 573                         vM=${v%.*}
 574                         vm=${v#*.}
 575                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
 576                         ;;
 577                 i386-*-dragonfly?.*)
 578                         v=${host#*dragonfly}
 579                         vM=${v%.*}
 580                         vm=${v#*.}
 581                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
 582                         ;;
 583                 i?86-*-netbsd*1.6[[M-Z]]*)
 584                         AFS_SYSNAME="i386_nbsd20"
 585                         ;;
 586                 powerpc-*-netbsd*1.6[[M-Z]]*)
 587                         AFS_SYSNAME="ppc_nbsd20"
 588                         ;;
 589                 *-*-netbsd*)
 590                         arch=${host%%-unknown*}
 591                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
 592                                                -e 's/powerpc/ppc/g')
 593                         v=${host#*netbsd}
 594                         v=${v#*aout}
 595                         v=${v#*ecoff}
 596                         v=${v#*elf}
 597                         vM=${v%%.*}
 598                         vM=${vM%.*}
 599                         v=${v#*.}
 600                         vm=${v%%.*}
 601                         vm=${vm%.*}
 602                         vm=${vm%%[[_A-Z]]*}
 603                         if test $vm -eq 99 ; then
 604                                 vM=$((vM+1))
 605                         fi
 606                         if test $vM -gt 1 ; then
 607                                 vm=0
 608                         fi
 609                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
 610                         ;;
 611                 hppa*-hp-hpux11.0*)
 612                         AFS_SYSNAME="hp_ux110"
 613                         ;;
 614                 hppa*-hp-hpux11.11)
 615                         AFS_SYSNAME="hp_ux11i"
 616                         ;;
 617                 hppa*-hp-hpux11.23)
 618                         AFS_SYSNAME="hp_ux1123"
 619                         ;;
 620                 ia64-hp-hpux11.22)
 621                         AFS_SYSNAME="ia64_hpux1122"
 622                         ;;
 623                 ia64-hp-hpux*)
 624                         AFS_SYSNAME="ia64_hpux1123"
 625                         ;;
 626                 hppa*-hp-hpux10*)
 627                         AFS_SYSNAME="hp_ux102"
 628                         ;;
 629                 powerpc-apple-darwin7*)
 630                         AFS_SYSNAME="ppc_darwin_70"
 631                         OSXSDK="macosx10.3"
 632                         ;;
 633                 powerpc-apple-darwin8.*)
 634                         AFS_SYSNAME="ppc_darwin_80"
 635                         OSXSDK="macosx10.4"
 636                         ;;
 637                 i386-apple-darwin8.*)
 638                         AFS_SYSNAME="x86_darwin_80"
 639                         OSXSDK="macosx10.4"
 640                         ;;
 641                 powerpc-apple-darwin9.*)
 642                         AFS_SYSNAME="ppc_darwin_90"
 643                         OSXSDK="macosx10.5"
 644                         ;;
 645                 i386-apple-darwin9.*)
 646                         AFS_SYSNAME="x86_darwin_90"
 647                         OSXSDK="macosx10.5"
 648                         ;;
 649                 i?86-apple-darwin10.*)
 650                         AFS_SYSNAME="x86_darwin_100"
 651                         OSXSDK="macosx10.6"
 652                         ;;
 653                 x86_64-apple-darwin10.*)
 654                         AFS_SYSNAME="x86_darwin_100"
 655                         OSXSDK="macosx10.6"
 656                         ;;
 657                 arm-apple-darwin10.*)
 658                         AFS_SYSNAME="arm_darwin_100"
 659                         OSXSDK="iphoneos4.0"
 660                         ;;
 661                 x86_64-apple-darwin11.*)
 662                         AFS_SYSNAME="x86_darwin_110"
 663                         OSXSDK="macosx10.7"
 664                         ;;
 665                 i?86-apple-darwin11.*)
 666                         AFS_SYSNAME="x86_darwin_110"
 667                         OSXSDK="macosx10.7"
 668                         ;;
 669                 x86_64-apple-darwin12.*)
 670                         AFS_SYSNAME="x86_darwin_120"
 671                         OSXSDK="macosx10.8"
 672                         ;;
 673                 i?86-apple-darwin12.*)
 674                         AFS_SYSNAME="x86_darwin_120"
 675                         OSXSDK="macosx10.8"
 676                         ;;
 677                 x86_64-apple-darwin13.*)
 678                         AFS_SYSNAME="x86_darwin_130"
 679                         OSXSDK="macosx10.9"
 680                         ;;
 681                 i?86-apple-darwin13.*)
 682                         AFS_SYSNAME="x86_darwin_130"
 683                         OSXSDK="macosx10.9"
 684                         ;;
 685                 x86_64-apple-darwin14.*)
 686                         AFS_SYSNAME="x86_darwin_140"
 687                         OSXSDK="macosx10.10"
 688                         ;;
 689                 i?86-apple-darwin14.*)
 690                         AFS_SYSNAME="x86_darwin_140"
 691                         OSXSDK="macosx10.10"
 692                         ;;
 693                 x86_64-apple-darwin15.*)
 694                         AFS_SYSNAME="x86_darwin_150"
 695                         OSXSDK="macosx10.11"
 696                         ;;
 697                 i?86-apple-darwin15.*)
 698                         AFS_SYSNAME="x86_darwin_150"
 699                         OSXSDK="macosx10.11"
 700                         ;;
 701                 x86_64-apple-darwin16.*)
 702                         AFS_SYSNAME="x86_darwin_160"
 703                         OSXSDK="macosx10.12"
 704                         ;;
 705                 i?86-apple-darwin16.*)
 706                         AFS_SYSNAME="x86_darwin_160"
 707                         OSXSDK="macosx10.12"
 708                         ;;
 709                 sparc-sun-solaris2.8)
 710                         AFS_SYSNAME="sun4x_58"
 711                         ;;
 712                 sparc-sun-solaris2.9)
 713                         AFS_SYSNAME="sun4x_59"
 714                         ;;
 715                 sparc-sun-solaris2.10)
 716                         AFS_SYSNAME="sun4x_510"
 717                         ;;
 718                 sparc-sun-solaris2.11)
 719                         AFS_SYSNAME="sun4x_511"
 720                         ;;
 721                 i386-pc-solaris2.8)
 722                         AFS_SYSNAME="sunx86_58"
 723                         ;;
 724                 i386-pc-solaris2.9)
 725                         AFS_SYSNAME="sunx86_59"
 726                         ;;
 727                 i386-pc-solaris2.10)
 728                         AFS_SYSNAME="sunx86_510"
 729                         ;;
 730                 i386-pc-solaris2.11)
 731                         AFS_SYSNAME="sunx86_511"
 732                         ;;
 733                 alpha*-dec-osf4.0*)
 734                         AFS_SYSNAME="alpha_dux40"
 735                         ;;
 736                 alpha*-dec-osf5.0*)
 737                         AFS_SYSNAME="alpha_dux50"
 738                         ;;
 739                 alpha*-dec-osf5.1*)
 740                         AFS_SYSNAME="alpha_dux51"
 741                         ;;
 742                 mips-sgi-irix6.5)
 743                         AFS_SYSNAME="sgi_65"
 744                         enable_pam="no"
 745                         ;;
 746                 ia64-*-linux*)
 747                         AFS_SYSNAME="ia64_linuxXX"
 748                         ;;
 749                 powerpc-*-linux*)
 750                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 751                         ;;
 752                 powerpc64-*-linux*)
 753                         AFS_SYSNAME="ppc64_linuxXX"
 754                         ;;
 755                 alpha*-linux*)
 756                         AFS_SYSNAME="alpha_linux_XX"
 757                         ;;
 758                 s390-*-linux*)
 759                         AFS_SYSNAME="s390_linuxXX"
 760                         ;;
 761                 s390x-*-linux*)
 762                         AFS_SYSNAME="s390x_linuxXX"
 763                         ;;
 764                 sparc-*-linux*)
 765                         AFS_SYSNAME="`/bin/arch`_linuxXX"
 766                         ;;
 767                 sparc64-*-linux*)
 768                         AFS_SYSNAME="sparc64_linuxXX"
 769                         ;;
 770                 i?86-*-linux*)
 771                         AFS_SYSNAME="i386_linuxXX"
 772                         ;;
 773                 arm*-linux*)
 774                         AFS_SYSNAME="arm_linuxXX"
 775                         ;;
 776                 parisc-*-linux-gnu|hppa-*-linux-gnu)
 777                         AFS_SYSNAME="parisc_linuxXX"
 778                         enable_pam="no"
 779                         ;;
 780                 power*-ibm-aix4.2*)
 781                         AFS_SYSNAME="rs_aix42"
 782                         enable_pam="no"
 783                         ;;
 784                 power*-ibm-aix4.3*)
 785                         AFS_SYSNAME="rs_aix42"
 786                         enable_pam="no"
 787                         ;;
 788                 power*-ibm-aix5.1*)
 789                         AFS_SYSNAME="rs_aix51"
 790                         enable_pam="no"
 791                         ;;
 792                 power*-ibm-aix5.2*)
 793                         AFS_SYSNAME="rs_aix52"
 794                         enable_pam="no"
 795                         ;;
 796                 power*-ibm-aix5.3*)
 797                         AFS_SYSNAME="rs_aix53"
 798                         enable_pam="no"
 799                         ;;
 800                 power*-ibm-aix6.1*)
 801                         AFS_SYSNAME="rs_aix61"
 802                         enable_pam="no"
 803                         ;;
 804                 x86_64-*-linux-gnu)
 805                         AFS_SYSNAME="amd64_linuxXX"
 806                         enable_pam="yes"
 807                         ;;
 808                 *)
 809                         AC_MSG_ERROR(An AFS sysname is required)
 810                         exit 1
 811                         ;;
 812         esac
 813         case $AFS_SYSNAME in
 814                 *_linux* | *_umlinux*)
 815                         if test "x${AFS_SYSKVERS}" = "x"; then
 816                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 817                         fi
 818                         if test "x${AFS_SYSKVERS}" = "x24" ||
 819                                 test "x${AFS_SYSKVERS}" = "x22"; then
 820                             AC_MSG_ERROR([Linux 2.4.x and older are no longer supported by OpenAFS.  Please use an OpenAFS 1.6.x release on those systems.])
 821                         fi
 822                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 823                         AFS_SYSNAME="$_AFS_SYSNAME"
 824                         AC_TRY_KBUILD(
 825                          [],
 826                          [#ifndef CONFIG_USERMODE
 827                           #error not UML
 828                           #endif],
 829                          ac_cv_linux_is_uml=yes,)
 830                         if test "${ac_cv_linux_is_uml}" = yes; then
 831                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
 832                         fi
 833                         AFS_SYSNAME="$_AFS_SYSNAME"
 834                         ;;
 835         esac
 836         AC_MSG_RESULT($AFS_SYSNAME)
 837 fi
 838
 839 case $AFS_SYSNAME in
 840         *_darwin*)
 841                 AC_CHECK_HEADERS(crt_externs.h)
 842                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 843                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 844                 AC_SUBST(OSXSDK)
 845                 ;;
 846 esac
 847
 848 dnl Some hosts have a separate common param file they should include.  Figure
 849 dnl out if we're on one of them now that we know the sysname.
 850 case $AFS_SYSNAME in
 851     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
 852     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
 853     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
 854     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
 855     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
 856     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
 857     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
 858     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
 859     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
 860     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
 861     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
 862     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
 863     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
 864     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
 865     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
 866     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
 867     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
 868     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
 869     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
 870     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
 871     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
 872     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
 873     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
 874     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
 875     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
 876     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
 877     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
 878     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
 879     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
 880     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
 881     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
 882     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
 883     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
 884     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
 885 # Linux alpha adds an extra underscore for no good reason.
 886     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
 887     *_fbsd_*)   AFS_PARAM_COMMON=param.generic_fbsd.h ;;
 888 esac
 889
 890 OPENAFS_OSCONF
 891
 892 case $AFS_SYSNAME in *_linux* | *_umlinux*)
 893
 894                 # Add (sub-) architecture-specific paths needed by conftests
 895                 case $AFS_SYSNAME  in
 896                         *_umlinux26)
 897                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
 898                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
 899                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
 900                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
 901                 esac
 902
 903                 if test "x$enable_kernel_module" = "xyes"; then
 904                  if test "x$enable_debug_kernel" = "xno"; then
 905                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
 906                  fi
 907                  OPENAFS_GCC_SUPPORTS_MARCH
 908                  AC_SUBST(P5PLUS_KOPTS)
 909                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
 910                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
 911                  OPENAFS_GCC_SUPPORTS_NO_COMMON
 912                  OPENAFS_GCC_SUPPORTS_PIPE
 913                  AC_SUBST(LINUX_GCC_KOPTS)
 914
 915                  dnl Setup the kernel build environment
 916                  LINUX_KBUILD_USES_EXTRA_CFLAGS
 917                  LINUX_KERNEL_COMPILE_WORKS
 918
 919                  dnl Operation signature checks
 920                  AC_CHECK_LINUX_OPERATION([inode_operations], [follow_link], [no_nameidata],
 921                                           [#include <linux/fs.h>],
 922                                           [const char *],
 923                                           [struct dentry *dentry, void **link_data])
 924                  AC_CHECK_LINUX_OPERATION([inode_operations], [put_link], [no_nameidata],
 925                                           [#include <linux/fs.h>],
 926                                           [void],
 927                                           [struct inode *inode, void *link_data])
 928                  AC_CHECK_LINUX_OPERATION([inode_operations], [rename], [takes_flags],
 929                                           [#include <linux/fs.h>],
 930                                           [int],
 931                                           [struct inode *oinode, struct dentry *odentry,
 932                                                 struct inode *ninode, struct dentry *ndentry,
 933                                                 unsigned int flags])
 934
 935                  dnl Check for header files
 936                  AC_CHECK_LINUX_HEADER([config.h])
 937                  AC_CHECK_LINUX_HEADER([exportfs.h])
 938                  AC_CHECK_LINUX_HEADER([freezer.h])
 939                  AC_CHECK_LINUX_HEADER([key-type.h])
 940                  AC_CHECK_LINUX_HEADER([semaphore.h])
 941                  AC_CHECK_LINUX_HEADER([seq_file.h])
 942
 943                  dnl Type existence checks
 944                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
 945                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
 946
 947                  dnl Check for structure elements
 948                  AC_CHECK_LINUX_STRUCT([address_space], [backing_dev_info], [fs.h])
 949                  AC_CHECK_LINUX_STRUCT([address_space_operations],
 950                                        [write_begin], [fs.h])
 951                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
 952                                        [backing-dev.h])
 953                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
 954                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
 955                  AC_CHECK_LINUX_STRUCT([dentry], [d_u.d_alias], [dcache.h])
 956                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
 957                  AC_CHECK_LINUX_STRUCT([group_info], [gid], [cred.h])
 958                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
 959                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
 960                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
 961                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
 962                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
 963                  AC_CHECK_LINUX_STRUCT([file], [f_path], [fs.h])
 964                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
 965                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
 966                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
 967                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
 968                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
 969                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
 970                  AC_CHECK_LINUX_STRUCT([inode_operations], [get_link], [fs.h])
 971                  AC_CHECK_LINUX_STRUCT([key], [payload.value], [key.h])
 972                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
 973                  AC_CHECK_LINUX_STRUCT([key_type], [match_preparse], [key-type.h])
 974                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
 975                  AC_CHECK_LINUX_STRUCT([msghdr], [msg_iter], [socket.h])
 976                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
 977                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
 978                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
 979                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
 980                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
 981                                        [fs.h])
 982                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
 983                                        [fs.h])
 984                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
 985                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
 986                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
 987                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
 988                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
 989                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
 990                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
 991                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
 992                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
 993                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
 994                  AC_CHECK_LINUX_STRUCT([task_struct], [total_link_count], [sched.h])
 995                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
 996
 997                  dnl Check for typed structure elements
 998                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
 999                                              [buf], [fs.h])
1000
1001                  dnl Function existence checks
1002
1003                  AC_CHECK_LINUX_FUNC([__vfs_read],
1004                                      [#include <linux/fs.h>],
1005                                      [__vfs_read(NULL, NULL, 0, NULL);])
1006                  AC_CHECK_LINUX_FUNC([bdi_init],
1007                                      [#include <linux/backing-dev.h>],
1008                                      [bdi_init(NULL);])
1009                  AC_CHECK_LINUX_FUNC([PageChecked],
1010                                      [#include <linux/mm.h>
1011 #include <linux/page-flags.h>],
1012                                      [struct page *_page;
1013                                       int bchecked = PageChecked(_page);])
1014                  AC_CHECK_LINUX_FUNC([PageFsMisc],
1015                                      [#include <linux/mm.h>
1016 #include <linux/page-flags.h>],
1017                                      [struct page *_page;
1018                                       int bchecked = PageFsMisc(_page);])
1019                  AC_CHECK_LINUX_FUNC([clear_inode],
1020                                      [#include <linux/fs.h>],
1021                                      [clear_inode(NULL);])
1022                  AC_CHECK_LINUX_FUNC([current_kernel_time],
1023                                      [#include <linux/time.h>],
1024                                      [struct timespec s;
1025                                       s = current_kernel_time();])
1026                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
1027                                      [#include <linux/fs.h>],
1028                                      [d_alloc_anon(NULL);])
1029                  AC_CHECK_LINUX_FUNC([d_count],
1030                                      [#include <linux/dcache.h>],
1031                                      [d_count(NULL);])
1032                  AC_CHECK_LINUX_FUNC([d_make_root],
1033                                      [#include <linux/fs.h>],
1034                                      [d_make_root(NULL);])
1035                  AC_CHECK_LINUX_FUNC([do_sync_read],
1036                                      [#include <linux/fs.h>],
1037                                      [do_sync_read(NULL, NULL, 0, NULL);])
1038                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
1039                                      [#include <linux/sched.h>],
1040                                      [pid_t p; find_task_by_pid(p);])
1041                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
1042                                      [#include <linux/fs.h>],
1043                                      [generic_file_aio_read(NULL,NULL,0,0);])
1044                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
1045                                      [#include <linux/pagemap.h>],
1046                                      [grab_cache_page_write_begin(NULL, 0, 0);])
1047                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
1048                                      [#include <linux/list.h>],
1049                                      [hlist_unhashed(0);])
1050                  AC_CHECK_LINUX_FUNC([ihold],
1051                                      [#include <linux/fs.h>],
1052                                      [ihold(NULL);])
1053                  AC_CHECK_LINUX_FUNC([i_size_read],
1054                                      [#include <linux/fs.h>],
1055                                      [i_size_read(NULL);])
1056                  AC_CHECK_LINUX_FUNC([inode_setattr],
1057                                      [#include <linux/fs.h>],
1058                                      [inode_setattr(NULL, NULL);])
1059                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
1060                                      [#include <linux/fs.h>],
1061                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
1062                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
1063                                      [#include <linux/net.h>],
1064                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
1065                  AC_CHECK_LINUX_FUNC([locks_lock_file_wait],
1066                                      [#include <linux/fs.h>],
1067                                      [locks_lock_file_wait(NULL, NULL);])
1068                  AC_CHECK_LINUX_FUNC([page_follow_link],
1069                                      [#include <linux/fs.h>],
1070                                      [page_follow_link(0,0);])
1071                  AC_CHECK_LINUX_FUNC([page_get_link],
1072                                      [#include <linux/fs.h>],
1073                                      [page_get_link(0,0,0);])
1074                  AC_CHECK_LINUX_FUNC([page_offset],
1075                                      [#include <linux/pagemap.h>],
1076                                      [page_offset(NULL);])
1077                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
1078                                      [#include <linux/pagevec.h>],
1079                                      [__pagevec_lru_add_file(NULL);])
1080                  AC_CHECK_LINUX_FUNC([path_lookup],
1081                                      [#include <linux/fs.h>
1082                                       #include <linux/namei.h>],
1083                                      [path_lookup(NULL, 0, NULL);])
1084                  AC_CHECK_LINUX_FUNC([proc_create],
1085                                      [#include <linux/proc_fs.h>],
1086                                      [proc_create(NULL, 0, NULL, NULL);])
1087                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
1088                                      [#include <linux/rcupdate.h>],
1089                                      [rcu_read_lock();])
1090                  AC_CHECK_LINUX_FUNC([set_nlink],
1091                                      [#include <linux/fs.h>],
1092                                      [set_nlink(NULL, 1);])
1093                  AC_CHECK_LINUX_FUNC([setattr_prepare],
1094                                      [#include <linux/fs.h>],
1095                                      [setattr_prepare(NULL, NULL);])
1096                  AC_CHECK_LINUX_FUNC([sock_create_kern],
1097                                      [#include <linux/net.h>],
1098                                      [sock_create_kern(0, 0, 0, NULL);])
1099                  AC_CHECK_LINUX_FUNC([sock_create_kern_ns],
1100                                      [#include <linux/net.h>],
1101                                      [sock_create_kern(NULL, 0, 0, 0, NULL);])
1102                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
1103                                      [#include <linux/splice.h>],
1104                                      [splice_direct_to_actor(NULL,NULL,NULL);])
1105                  AC_CHECK_LINUX_FUNC([default_file_splice_read],
1106                                      [#include <linux/fs.h>],
1107                                      [default_file_splice_read(NULL,NULL,NULL, 0, 0);])
1108                  AC_CHECK_LINUX_FUNC([svc_addr_in],
1109                                      [#include <linux/sunrpc/svc.h>],
1110                                      [svc_addr_in(NULL);])
1111                  AC_CHECK_LINUX_FUNC([zero_user_segments],
1112                                      [#include <linux/highmem.h>],
1113                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1114                  AC_CHECK_LINUX_FUNC([noop_fsync],
1115                                      [#include <linux/fs.h>],
1116                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1117                  AC_CHECK_LINUX_FUNC([kthread_run],
1118                                      [#include <linux/kernel.h>
1119                                       #include <linux/kthread.h>],
1120                                      [kthread_run(NULL, NULL, "test");])
1121                  AC_CHECK_LINUX_FUNC([inode_nohighmem],
1122                                      [#include <linux/fs.h>],
1123                                      [inode_nohighmem(NULL);])
1124                  AC_CHECK_LINUX_FUNC([inode_lock],
1125                                      [#include <linux/fs.h>],
1126                                      [inode_lock(NULL);])
1127
1128                  dnl Consequences - things which get set as a result of the
1129                  dnl                above tests
1130                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1131                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1132                                   [define to disable the nfs translator])])
1133
1134                  dnl Assorted more complex tests
1135                  LINUX_AIO_NONVECTOR
1136                  LINUX_EXPORTS_PROC_ROOT_FS
1137                  LINUX_KMEM_CACHE_INIT
1138                  LINUX_HAVE_KMEM_CACHE_T
1139                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1140                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1141                  LINUX_D_PATH_TAKES_STRUCT_PATH
1142                  LINUX_NEW_EXPORT_OPS
1143                  LINUX_INODE_SETATTR_RETURN_TYPE
1144                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1145                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1146                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1147                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1148                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1149                  LINUX_DOP_D_DELETE_TAKES_CONST
1150                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1151                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1152                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1153                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1154                  LINUX_AOP_WRITEBACK_CONTROL
1155                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1156                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1157                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1158                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1159                  LINUX_KERNEL_SOCK_CREATE
1160                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1161                  LINUX_NEED_RHCONFIG
1162                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1163                  LINUX_EXPORTS_TASKLIST_LOCK
1164                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1165                  LINUX_STATFS_TAKES_DENTRY
1166                  LINUX_REFRIGERATOR
1167                  LINUX_HAVE_TRY_TO_FREEZE
1168                  LINUX_LINUX_KEYRING_SUPPORT
1169                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1170                  LINUX_KEY_ALLOC_NEEDS_CRED
1171                  LINUX_INIT_WORK_HAS_DATA
1172                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1173                  LINUX_HAVE_DCACHE_LOCK
1174                  LINUX_D_COUNT_IS_INT
1175                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1176                  LINUX_IOP_CREATE_TAKES_UMODE_T
1177                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1178                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1179                  LINUX_DENTRY_OPEN_TAKES_PATH
1180                  LINUX_D_ALIAS_IS_HLIST
1181                  LINUX_HLIST_ITERATOR_NO_NODE
1182                  LINUX_IOP_I_CREATE_TAKES_BOOL
1183                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1184                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1185                  LINUX_D_INVALIDATE_IS_VOID
1186
1187                  dnl If we are guaranteed that keyrings will work - that is
1188                  dnl  a) The kernel has keyrings enabled
1189                  dnl  b) The code is new enough to give us a key_type_keyring
1190                  dnl then we just disable syscall probing unless we've been
1191                  dnl told otherwise
1192
1193                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1194                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1195                           [enable_linux_syscall_probing="no"],
1196                           [enable_linux_syscall_probing="yes"])
1197                  ])
1198
1199                  dnl Syscall probing needs a few tests of its own, and just
1200                  dnl won't work if the kernel doesn't export init_mm
1201                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1202                    LINUX_EXPORTS_INIT_MM
1203                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1204                      AC_MSG_ERROR(
1205                        [Can't do syscall probing without exported init_mm])
1206                    ])
1207                    LINUX_EXPORTS_SYS_CHDIR
1208                    LINUX_EXPORTS_SYS_OPEN
1209                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1210                              [define to enable syscall table probes])
1211                  ])
1212
1213                  dnl Packaging and SMP build
1214                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1215                    LINUX_WHICH_MODULES
1216                  else
1217                    AC_SUBST(MPS,'SP')
1218                  fi
1219
1220                  dnl Syscall probing
1221                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1222                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1223                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1224                    ])
1225                    ac_cv_linux_exports_sys_call_table=no
1226                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1227                      ac_cv_linux_exports_ia32_sys_call_table=yes
1228                    fi
1229                  else
1230                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1231                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1232                    LINUX_EXPORTS_SYS_CALL_TABLE
1233                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1234                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1235                          linux_syscall_method=none
1236                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1237                             linux_syscall_method=scan
1238                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1239                                linux_syscall_method=scan_with_kallsyms_address
1240                             fi
1241                          fi
1242                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1243                             linux_syscall_method=kallsyms_symbol
1244                          fi
1245                          if test "x$linux_syscall_method" = "xnone"; then
1246                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1247                             linux_syscall_method=scan
1248                          fi
1249                    fi
1250                  fi
1251                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1252                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1253                  fi
1254                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1255                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1256                  fi
1257                  if test "x$ac_cv_linux_func_page_get_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1258                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1259                  else
1260                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1261                  fi
1262                  if test "x$ac_cv_linux_func_page_get_link" != "xyes" -a "x$ac_cv_linux_struct_inode_operations_has_get_link" = "xyes"; then
1263                         AC_MSG_ERROR([Your kernel does not use follow_link - not supported without symlink cache API])
1264                         exit 1
1265                  fi
1266                 :
1267                 fi
1268                 if test "x$enable_linux_d_splice_alias_extra_iput" = xyes; then
1269                     AC_DEFINE(D_SPLICE_ALIAS_LEAK_ON_ERROR, 1, [for internal use])
1270                 fi
1271 dnl Linux-only, but just enable always.
1272                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1273 esac
1274
1275 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1276     [ac_cv_sync_fetch_and_add],
1277     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1278                     [ac_cv_sync_fetch_and_add=yes],
1279                     [ac_cv_sync_fetch_and_add=no])
1280 ])
1281 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1282       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1283                 [define if your C compiler has __sync_add_and_fetch])])
1284
1285 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1286     [ac_cv_sockaddr_len],
1287     [AC_TRY_COMPILE( [#include <sys/types.h>
1288 #include <sys/socket.h>],
1289                      [struct sockaddr *a; a->sa_len=0;],
1290                      [ac_cv_sockaddr_len=yes],
1291                      [ac_cv_sockaddr_len=no])
1292 ])
1293 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1294       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1295                  [define if you struct sockaddr sa_len])])
1296
1297 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1298         echo Skipping library tests because they confuse Irix.
1299 else
1300   AC_SEARCH_LIBS([socket], [socket inet])
1301   AC_SEARCH_LIBS([connect], [nsl])
1302   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1303
1304   dnl darwin wants it, aix hates it
1305   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1306   AC_TRY_COMPILE([
1307   #include <stdlib.h>
1308   #include <stdio.h>
1309   #include <sys/types.h>
1310   #include <sys/socket.h>
1311   #include <netinet/in.h>
1312   #include <arpa/inet.h>
1313   #include <arpa/nameser.h>
1314   #include <arpa/nameser_compat.h>
1315   #include <resolv.h>
1316   ], [static int i; i = 0;],
1317   [AC_MSG_RESULT(yes)
1318    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1319   [AC_MSG_RESULT(no)
1320    ])
1321
1322   openafs_save_libs="$LIBS"
1323   AC_MSG_CHECKING([for res_search])
1324   AC_FUNC_RES_SEARCH
1325
1326   if test "$ac_cv_func_res_search" = no; then
1327       for lib in dns nsl resolv; do
1328         if test "$ac_cv_func_res_search" != yes; then
1329           LIBS="-l$lib $LIBS"
1330           AC_FUNC_RES_SEARCH
1331           LIBS="$openafs_save_libs"
1332         fi
1333       done
1334       if test "$ac_cv_func_res_search" = yes; then
1335         LIB_AFSDB="-l$lib"
1336         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1337         AC_MSG_RESULT([yes, in lib$lib])
1338       else
1339         AC_MSG_RESULT(no)
1340       fi
1341   else
1342     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1343     AC_MSG_RESULT(yes)
1344   fi
1345
1346 fi
1347 XLIBS="$LIB_AFSDB $XLIBS"
1348
1349 AC_CHECK_RESOLV_RETRANS
1350
1351 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1352     [ac_cv_setsockopt_iprecverr],
1353     [AC_TRY_COMPILE( [
1354 #include <sys/types.h>
1355 #include <sys/socket.h>
1356 #include <netinet/in.h>],
1357 [int on=1;
1358 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1359         [ac_cv_setsockopt_iprecverr=yes],
1360         [ac_cv_setsockopt_iprecverr=no])])
1361
1362 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1363       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1364                  [define if we can receive socket errors via IP_RECVERR])])
1365
1366 PTHREAD_LIBS=error
1367 if test "x$MKAFS_OSTYPE" = OBSD; then
1368         PTHREAD_LIBS="-pthread"
1369 fi
1370 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1371         PTHREAD_LIBS="-pthread"
1372 fi
1373 if test "x$PTHREAD_LIBS" = xerror; then
1374         AC_CHECK_LIB(pthread, pthread_attr_init,
1375                 PTHREAD_LIBS="-lpthread")
1376 fi
1377 if test "x$PTHREAD_LIBS" = xerror; then
1378         AC_CHECK_LIB(pthreads, pthread_attr_init,
1379                 PTHREAD_LIBS="-lpthreads")
1380 fi
1381 if test "x$PTHREAD_LIBS" = xerror; then
1382         AC_CHECK_LIB(c_r, pthread_attr_init,
1383                 PTHREAD_LIBS="-lc_r")
1384 fi
1385 if test "x$PTHREAD_LIBS" = xerror; then
1386         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1387 fi
1388 if test "x$PTHREAD_LIBS" = xerror; then
1389         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1390         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1391                 PTHREAD_LIBS="-lpthread")
1392 fi
1393 if test "x$PTHREAD_LIBS" = xerror; then
1394         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1395 fi
1396 AC_SUBST(PTHREAD_LIBS)
1397
1398 HOST_CPU="$host_cpu"
1399
1400 if test "x$with_bsd_kernel_headers" != "x"; then
1401         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1402 else
1403         BSD_KERNEL_PATH="/usr/src/sys"
1404 fi
1405
1406 if test "x$with_bsd_kernel_build" != "x"; then
1407         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1408 else
1409         case $AFS_SYSNAME in
1410                 *_fbsd_*)
1411                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1412                         ;;
1413                 *_nbsd*)
1414                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1415         esac
1416 fi
1417
1418 # Fast restart
1419 if test "$enable_supergroups" = "yes"; then
1420         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1421 fi
1422
1423 if test "$enable_bitmap_later" = "yes"; then
1424         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1425 fi
1426
1427 if test "$enable_unix_sockets" = "yes"; then
1428         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1429         USE_UNIX_SOCKETS="yes"
1430 else
1431         USE_UNIX_SOCKETS="no"
1432 fi
1433 AC_SUBST(USE_UNIX_SOCKETS)
1434
1435 if test "$enable_ubik_read_while_write" = "yes"; then
1436         AC_DEFINE(UBIK_READ_WHILE_WRITE, 1, [define if you want to enable ubik read while write])
1437 fi
1438
1439 if test "$enable_namei_fileserver" = "yes"; then
1440         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1441         VFSCK=""
1442 else
1443         if test "$enable_namei_fileserver" = "default"; then
1444                 case $host in
1445                         *-solaris2.10*)
1446                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1447                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1448                                 VFSCK=""
1449                                 ;;
1450                         *-solaris2.11*)
1451                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1452                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1453                                 VFSCK=""
1454                                 ;;
1455                         *)
1456                                 VFSCK="vfsck"
1457                                 ;;
1458                 esac
1459         else
1460                 VFSCK="vfsck"
1461         fi
1462 fi
1463
1464 dnl check for tivoli
1465 AC_MSG_CHECKING(for tivoli tsm butc support)
1466 XBSA_CFLAGS=""
1467 if test "$enable_tivoli_tsm" = "yes"; then
1468         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1469         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1470         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1471         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1472         XBSADIR5=/usr/tivoli/tsm/client/api/bin64/sample
1473         XBSADIR6=/opt/tivoli/tsm/client/api/bin64/sample
1474
1475         if test -r "$XBSADIR3/dsmapifp.h"; then
1476                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1477                 XBSA_XLIBS="-ldl"
1478                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1479         elif test -r "$XBSADIR4/dsmapifp.h"; then
1480                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1481                 XBSA_XLIBS="-ldl"
1482                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1483         elif test -r "$XBSADIR5/dsmapifp.h"; then
1484                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR5"
1485                 XBSA_XLIBS="-ldl"
1486                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1487         elif test -r "$XBSADIR6/dsmapifp.h"; then
1488                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR6"
1489                 XBSA_XLIBS="-ldl"
1490                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1491         elif test -r "$XBSADIR1/xbsa.h"; then
1492                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1493                 XBSA_XLIBS=""
1494                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1495         elif test -r "$XBSADIR2/xbsa.h"; then
1496                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1497                 XBSA_XLIBS=""
1498                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1499         else
1500                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1501         fi
1502 else
1503         AC_MSG_RESULT([no])
1504 fi
1505 AC_SUBST(XBSA_CFLAGS)
1506 AC_SUBST(XBSA_XLIBS)
1507 XLIBS="$XBSA_XLIBS $XLIBS"
1508
1509 dnl checks for header files.
1510 AC_HEADER_STDC
1511 AC_HEADER_SYS_WAIT
1512 AC_HEADER_DIRENT
1513 AC_CHECK_HEADERS([ \
1514                    arpa/inet.h \
1515                    arpa/nameser.h \
1516                    curses.h\
1517                    direct.h \
1518                    errno.h \
1519                    fcntl.h \
1520                    grp.h \
1521                    math.h \
1522                    mntent.h \
1523                    ncurses.h \
1524                    ncurses/ncurses.h \
1525                    netdb.h \
1526                    netinet/in.h \
1527                    pthread_np.h \
1528                    pwd.h \
1529                    regex.h \
1530                    security/pam_appl.h \
1531                    signal.h \
1532                    stdint.h \
1533                    stdio_ext.h \
1534                    stdlib.h \
1535                    string.h \
1536                    strings.h \
1537                    sys/bitypes.h \
1538                    sys/bswap.h \
1539                    sys/dk.h \
1540                    sys/fcntl.h \
1541                    sys/file.h \
1542                    sys/fs_types.h \
1543                    sys/fstyp.h \
1544                    sys/ioctl.h \
1545                    sys/ipc.h \
1546                    sys/lockf.h \
1547                    sys/map.h \
1548                    sys/mount.h \
1549                    sys/mntent.h \
1550                    sys/mnttab.h \
1551                    sys/pag.h \
1552                    sys/param.h \
1553                    sys/resource.h \
1554                    sys/select.h \
1555                    sys/statfs.h \
1556                    sys/statvfs.h \
1557                    sys/socket.h \
1558                    sys/sysctl.h \
1559                    sys/time.h \
1560                    sys/types.h \
1561                    sys/uio.h \
1562                    sys/un.h \
1563                    sys/vfs.h \
1564                    syslog.h \
1565                    termios.h \
1566                    time.h \
1567                    ucontext.h \
1568                    unistd.h \
1569                    windows.h \
1570                 ])
1571
1572 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1573 #ifdef HAVE_NETINET_IN_H
1574 # include <netinet/in.h>
1575 #endif])
1576
1577 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1578 #ifdef HAVE_SYS_SOCKET_H
1579 # include <sys/socket.h>
1580 #endif])
1581
1582 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1583 #ifdef HAVE_SYS_SOCKET_H
1584 # include <sys/socket.h>
1585 #endif
1586 #ifdef HAVE_NETINET_IN_H
1587 # include <netinet/in.h>
1588 #endif
1589 #ifdef HAVE_NET_IF_H
1590 # include <net/if.h>
1591 #endif])
1592
1593 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1594 #ifdef HAVE_SECURITY_PAM_APPL_H
1595 # include <security/pam_appl.h>
1596 #endif])
1597
1598 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1599
1600 AC_CHECK_TYPES([fsblkcnt_t],,,[
1601 #include <sys/types.h>
1602 #ifdef HAVE_SYS_BITYPES_H
1603 #include <sys/bitypes.h>
1604 #endif
1605 #ifdef HAVE_SYS_STATFS_H
1606 #include <sys/statfs.h>
1607 #endif
1608 #ifdef HAVE_SYS_STATVFS_H
1609 #include <sys/statvfs.h>
1610 #endif
1611 ])
1612
1613 dnl see what struct stat has for timestamps
1614 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1615
1616 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1617
1618 if test "$enable_debug_locks" = yes; then
1619         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1620 fi
1621
1622 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1623         HAVE_PAM="yes"
1624 else
1625         HAVE_PAM="no"
1626 fi
1627 AC_SUBST(HAVE_PAM)
1628
1629 if test "$enable_login" = yes; then
1630         BUILD_LOGIN="yes"
1631 else
1632         BUILD_LOGIN="no"
1633 fi
1634 AC_SUBST(BUILD_LOGIN)
1635
1636 if test "$enable_kauth" = yes; then
1637         INSTALL_KAUTH="yes"
1638 else
1639         INSTALL_KAUTH="no"
1640 fi
1641 AC_SUBST(INSTALL_KAUTH)
1642
1643 AC_CHECK_FUNCS([ \
1644         arc4random \
1645         closelog \
1646         fcntl \
1647         fseeko64 \
1648         ftello64 \
1649         getcwd \
1650         getegid \
1651         geteuid \
1652         getgid \
1653         getuid \
1654         getrlimit \
1655         issetugid \
1656         mkstemp \
1657         openlog \
1658         poll \
1659         pread \
1660         preadv \
1661         preadv64 \
1662         pwrite \
1663         pwritev \
1664         pwritev64 \
1665         regcomp \
1666         regerror \
1667         regexec \
1668         setitimer \
1669         setvbuf \
1670         sigaction \
1671         strcasestr \
1672         strerror \
1673         sysconf \
1674         sysctl \
1675         syslog \
1676         tdestroy \
1677         timegm \
1678 ])
1679
1680 OPENAFS_ROKEN()
1681 OPENAFS_HCRYPTO()
1682 OPENAFS_CURSES()
1683 OPENAFS_C_ATTRIBUTE()
1684 OPENAFS_C_PRAGMA()
1685
1686 dnl Functions that Heimdal's libroken provides, but that we
1687 dnl haven't found a need for yet, and so haven't imported
1688 AC_CHECK_FUNCS([ \
1689         chown \
1690         fchown \
1691         gethostname \
1692         lstat \
1693         inet_aton \
1694         putenv \
1695         readv \
1696         setenv \
1697         strdup \
1698         strftime \
1699         strndup \
1700         strsep \
1701         unsetenv \
1702 ])
1703
1704 dnl Functions that are in objects that we always build from libroken
1705 AC_CHECK_FUNCS([ \
1706         asprintf \
1707         asnprintf \
1708         vasprintf \
1709         vasnprintf \
1710         vsnprintf \
1711         snprintf \
1712 ])
1713
1714 dnl Functions that we're going to try and get from libroken
1715 AC_REPLACE_FUNCS([ \
1716         daemon \
1717         ecalloc \
1718         emalloc \
1719         erealloc \
1720         err \
1721         errx \
1722         flock \
1723         freeaddrinfo \
1724         gai_strerror \
1725         getaddrinfo \
1726         getdtablesize \
1727         getnameinfo \
1728         getopt \
1729         getprogname \
1730         gettimeofday \
1731         inet_ntop \
1732         inet_pton \
1733         localtime_r \
1734         mkstemp \
1735         setenv \
1736         setprogname \
1737         strcasecmp \
1738         strlcat \
1739         strnlen \
1740         strlcpy \
1741         strsep \
1742         tdelete \
1743         tfind \
1744         tsearch \
1745         twalk \
1746         unsetenv \
1747         verr \
1748         verrx \
1749         vsyslog \
1750         vwarn \
1751         vwarnx \
1752         warn \
1753         warnx \
1754 ])
1755
1756 dnl Headers that we're going to try and get from libroken
1757 AC_CHECK_HEADERS([ \
1758         err.h \
1759         search.h \
1760 ])
1761
1762 AC_CHECK_DECLS([h_errno], [], [], [
1763 #include <sys/types.h>
1764 #ifdef HAVE_NETDB_H
1765 #include <netdb.h>
1766 #endif
1767 ])
1768
1769 AC_HEADER_TIME
1770
1771 ROKEN_HEADERS=
1772 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1773       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1774       [])
1775 AC_SUBST(ROKEN_HEADERS)
1776
1777 dnl Stuff that's harder ...
1778 AC_MSG_CHECKING([for bswap16])
1779 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1780 #ifdef HAVE_SYS_TYPES_H
1781 #include <sys/types.h>
1782 #endif
1783 #ifdef HAVE_SYS_BSWAP_H
1784 #include <sys/bswap.h>
1785 #endif
1786 ],
1787 [short a, b; b = bswap16(a); ])],
1788 [AC_MSG_RESULT(yes)
1789  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1790 ],
1791 [AC_MSG_RESULT(no)])
1792
1793 AC_MSG_CHECKING([for bswap32])
1794 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1795 #include <sys/types.h>
1796 #endif
1797 #ifdef HAVE_SYS_BSWAP_H
1798 #include <sys/bswap.h>
1799 #endif
1800 ],
1801 [int a, b; b = bswap32(a); ])],
1802 [AC_MSG_RESULT(yes)
1803  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1804 ],
1805 [AC_MSG_RESULT(no)])
1806
1807 case $AFS_SYSNAME in
1808 *hp_ux* | *hpux*)
1809    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1810    ;;
1811 *)
1812    AC_MSG_CHECKING([for positional I/O])
1813    if test "$ac_cv_func_pread" = "yes" && \
1814            test "$ac_cv_func_pwrite" = "yes"; then
1815       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1816       AC_MSG_RESULT(yes)
1817    else
1818      AC_MSG_RESULT(no)
1819    fi
1820    AC_MSG_CHECKING([for vectored positional I/O])
1821    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1822                "$ac_cv_func_pwritev" = "yes" -a \
1823                "$ac_cv_func_preadv64" = "yes" -a \
1824                "$ac_cv_func_pwritev64" = "yes"],
1825          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1826           AC_MSG_RESULT(yes)],
1827          [AC_MSG_RESULT(no)])
1828    ;;
1829 esac
1830
1831 AC_MSG_CHECKING([for POSIX regex library])
1832 if test "$ac_cv_header_regex_h" = "yes" && \
1833         test "$ac_cv_func_regcomp" = "yes" && \
1834         test "$ac_cv_func_regexec" = "yes" && \
1835         test "$ac_cv_func_regerror" = "yes"; then
1836     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1837     AC_MSG_RESULT(yes)
1838 else
1839     AC_MSG_RESULT(no)
1840 fi
1841
1842 dnl Look for "non-portable" pthreads functions.
1843 save_LIBS="$LIBS"
1844 LIBS="$LIBS $PTHREAD_LIBS"
1845 AC_CHECK_FUNCS([ \
1846         pthread_set_name_np \
1847         pthread_setname_np \
1848 ])
1849
1850 dnl Sadly, there are three different versions of pthread_setname_np.
1851 dnl Try to cater for all of them.
1852 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1853     AC_MSG_CHECKING([for signature of pthread_setname_np])
1854     AC_TRY_COMPILE([
1855 #include <pthread.h>
1856 #ifdef HAVE_PTHREAD_NP_H
1857 #include <pthread_np.h>
1858 #endif
1859 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1860         AC_MSG_RESULT([three arguments])
1861         pthread_setname_np_args=3], [
1862         AC_TRY_COMPILE([
1863 #include <pthread.h>
1864 #ifdef HAVE_PTHREAD_NP_H
1865 #include <pthread_np.h>
1866 #endif
1867 ], [pthread_setname_np(pthread_self(), "test")], [
1868             AC_MSG_RESULT([two arguments])
1869             pthread_setname_np_args=2], [
1870             AC_TRY_COMPILE([
1871 #include <pthread.h>
1872 #ifdef HAVE_PTHREAD_NP_H
1873 #include <pthread_np.h>
1874 #endif
1875 ], [pthread_setname_np("test")], [
1876                 AC_MSG_RESULT([one argument])
1877                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1878 ])
1879 ])
1880 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1881 fi
1882 LIBS="$save_LIBS"
1883
1884 openafs_cv_saved_CFLAGS="$CFLAGS"
1885 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1886
1887 AC_TYPE_SIGNAL
1888 OPENAFS_RETSIGTYPE
1889 AC_CHECK_SIZEOF(void *)
1890 AC_CHECK_SIZEOF(unsigned long long)
1891 AC_CHECK_SIZEOF(unsigned long)
1892 AC_CHECK_SIZEOF(unsigned int)
1893 AC_TYPE_INTPTR_T
1894 AC_TYPE_UINTPTR_T
1895 AC_TYPE_SSIZE_T
1896 AC_CHECK_TYPE([sig_atomic_t],[],
1897     [AC_DEFINE([sig_atomic_t], [int],
1898         [Define to int if <signal.h> does not define.])],
1899 [#include <sys/types.h>
1900 #include <signal.h>])
1901 AC_CHECK_TYPE([socklen_t],[],
1902     [AC_DEFINE([socklen_t], [int],
1903         [Define to int if <sys/socket.h> does not define.])],
1904 [#include <sys/types.h>
1905 #include <sys/socket.h>])
1906 AC_CHECK_TYPES(off64_t)
1907 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1908 AC_CHECK_TYPES([struct winsize], [], [], [
1909 #ifdef HAVE_TERMIOS_H
1910 # include <termios.h>
1911 #else
1912 # include <sys/termios.h>
1913 #endif
1914 #include <sys/ioctl.h>])
1915 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1916                 struct sockaddr_storage],
1917                [], [], [
1918 #include <sys/types.h>
1919 #include <sys/socket.h>
1920 ])
1921 AC_CHECK_TYPES([sa_family_t], [], [], [
1922 #include <sys/types.h>
1923 #include <sys/socket.h>
1924 ])
1925 AC_CHECK_TYPES([struct addrinfo], [], [], [
1926 #include <sys/types.h>
1927 #ifdef HAVE_NETDB_H
1928 #include <netdb.h>
1929 #endif
1930 ])
1931 AC_CHECK_TYPES([long long], [], [], [])
1932
1933 AC_SIZEOF_TYPE(long)
1934
1935 CFLAGS="$openafs_cv_saved_CFLAGS"
1936
1937 RRA_HEADER_PAM_CONST
1938
1939
1940 dnl Directory PATH handling
1941 if test "x$enable_transarc_paths" = "xyes"  ; then
1942     afsconfdir=${afsconfdir=/usr/afs/etc}
1943     viceetcdir=${viceetcdir=/usr/vice/etc}
1944     afskerneldir=${afskerneldir=${viceetcdir}}
1945     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1946     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1947     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1948     afsdbdir=${afsdbdir=/usr/afs/db}
1949     afslogsdir=${afslogsdir=/usr/afs/logs}
1950     afslocaldir=${afslocaldir=/usr/afs/local}
1951     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1952     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1953     afsdatadir=${afsdatadir=/usr/vice/etc}
1954 else
1955     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1956     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1957     afskerneldir=${afskerneldir='${libdir}/openafs'}
1958     afssrvbindir=${afssrvbindir='${bindir}'}
1959     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1960     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1961     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1962     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1963     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1964     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1965     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1966     afsdatadir=${afsdatadir='${datadir}/openafs'}
1967 fi
1968 AC_SUBST(afsconfdir)
1969 AC_SUBST(viceetcdir)
1970 AC_SUBST(afskerneldir)
1971 AC_SUBST(afssrvbindir)
1972 AC_SUBST(afssrvsbindir)
1973 AC_SUBST(afssrvlibexecdir)
1974 AC_SUBST(afsdbdir)
1975 AC_SUBST(afslogsdir)
1976 AC_SUBST(afslocaldir)
1977 AC_SUBST(afsbackupdir)
1978 AC_SUBST(afsbosconfigdir)
1979 AC_SUBST(afsdatadir)
1980
1981 if test "x$enable_kernel_module" = "xyes"; then
1982 ENABLE_KERNEL_MODULE=libafs
1983 fi
1984
1985 if test "x$enable_pthreaded_ubik" = "xyes"; then
1986 ENABLE_PTHREADED_UBIK=yes
1987 fi
1988
1989 AC_SUBST(VFSCK)
1990 AC_SUBST(AFS_SYSNAME)
1991 AC_SUBST(AFS_PARAM_COMMON)
1992 AC_SUBST(ENABLE_KERNEL_MODULE)
1993 AC_SUBST(ENABLE_PTHREADED_UBIK)
1994 AC_SUBST(LIB_AFSDB)
1995 AC_SUBST(LINUX_KERNEL_PATH)
1996 AC_SUBST(LINUX_KERNEL_BUILD)
1997 AC_SUBST(HOST_CPU)
1998 AC_SUBST(BSD_KERNEL_PATH)
1999 AC_SUBST(BSD_KERNEL_BUILD)
2000 AC_SUBST(LINUX_VERSION)
2001 AC_SUBST(MKAFS_OSTYPE)
2002 AC_SUBST(TOP_OBJDIR)
2003 AC_SUBST(TOP_SRCDIR)
2004 AC_SUBST(TOP_INCDIR)
2005 AC_SUBST(TOP_LIBDIR)
2006 AC_SUBST(DEST)
2007 AC_SUBST(DARWIN_INFOFILE)
2008 AC_SUBST(IRIX_BUILD_IP35)
2009 AC_SUBST(HTML_XSL)
2010 AC_SUBST(XSLTPROC)
2011 AC_SUBST(DOCBOOK2PDF)
2012 AC_SUBST(DOCBOOK_STYLESHEETS)
2013
2014 OPENAFS_FUSE
2015 OPENAFS_SWIG
2016
2017 TOP_SRCDIR="${srcdir}/src"
2018 dnl
2019 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
2020 dnl
2021 case $TOP_SRCDIR in
2022         /*)
2023                 ;;
2024         *)
2025                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
2026                 ;;
2027 esac
2028
2029 TOP_OBJDIR="${SRCDIR_PARENT}"
2030 TOP_INCDIR="${SRCDIR_PARENT}/include"
2031 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
2032 if test "${DEST}x" = "x"; then
2033         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
2034 fi
2035
2036 if test "x$with_crosstools_dir" != "x"; then
2037         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
2038                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
2039                 CONFIGTOOL_PATH=$with_crosstools_dir/config
2040                 RXGEN_PATH=$with_crosstools_dir/rxgen
2041         else
2042                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
2043                 exit 1
2044         fi
2045 else
2046         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
2047         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
2048         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
2049 fi
2050 AC_SUBST(COMPILE_ET_PATH)
2051 AC_SUBST(CONFIGTOOL_PATH)
2052 AC_SUBST(RXGEN_PATH)
2053
2054 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
2055 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
2056 AC_SUBST(HELPER_SPLINT)
2057 AC_SUBST(HELPER_SPLINTCFG)
2058
2059 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
2060
2061 dnl Check to see if crypt lives in a different library
2062 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
2063 AC_SUBST(LIB_crypt)
2064
2065 dnl Check to see if the compiler support labels in structs
2066 AC_MSG_CHECKING(for label support in structs)
2067 AC_TRY_COMPILE([], [
2068 extern void osi_UFSOpen(void);
2069 struct labeltest {
2070    void (*open) (void);
2071 };
2072 struct labeltest struct_labeltest = {
2073    .open       = osi_UFSOpen,
2074 }
2075 ],
2076 [AC_MSG_RESULT(yes)
2077  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
2078 ],
2079 [AC_MSG_RESULT(no)
2080 ])
2081
2082 AC_MSG_CHECKING([checking for dirfd])
2083 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
2084 #ifdef HAVE_DIRENT_H
2085 #include <dirent.h>
2086 #endif
2087 ]],
2088         [[DIR *d = 0; dirfd(d);]])],
2089         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
2090 if test "$ac_rk_have_dirfd" = "yes" ; then
2091         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
2092 fi
2093 AC_MSG_RESULT($ac_rk_have_dirfd)
2094
2095 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
2096 #ifdef HAVE_DIRENT_H
2097 #include <dirent.h>
2098 #endif])
2099
2100 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
2101 [#ifdef HAVE_SYS_RESOURCE_H
2102 #include <sys/resource.h>
2103 #endif])
2104
2105 dnl Check for UUID library
2106 AC_CHECK_HEADERS([uuid/uuid.h])
2107 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
2108 AC_CHECK_FUNCS([uuid_generate])
2109 ])
2110
2111