rx: Reset lastSendData when resetting call
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([gtx],
79     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
80 AC_ARG_ENABLE([uss],
81     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
82 AC_ARG_ENABLE([namei-fileserver],
83     [AS_HELP_STRING([--enable-namei-fileserver],
84         [force compilation of namei fileserver in preference to inode
85          fileserver])],
86     , 
87     [enable_namei_fileserver="default"])
88 AC_ARG_ENABLE([supergroups],
89     [AS_HELP_STRING([--enable-supergroups],
90         [enable support for nested pts groups])],
91     , 
92     [enable_supergroups="no"])
93 AC_ARG_ENABLE([bitmap-later],
94     [AS_HELP_STRING([--enable-bitmap-later],
95         [enable fast startup of file server by not reading bitmap till
96          needed])],
97     [AS_IF([test x"$withval" = xyes],
98         [AC_MSG_WARN([bitmap-later is only used by non-demand-attach
99             fileservers.  Please migrate to demand-attach instead.])])],
100     [enable_bitmap_later="no"])
101 AC_ARG_ENABLE([unix-sockets],
102     [AS_HELP_STRING([--disable-unix-sockets],
103         [disable use of unix domain sockets for fssync (defaults to enabled)])],
104     ,
105     [enable_unix_sockets="yes"])
106 AC_ARG_ENABLE([tivoli-tsm],
107     [AS_HELP_STRING([--enable-tivoli-tsm],
108         [enable use of the Tivoli TSM API libraries for butc support])],
109     , 
110     [enable_tivoli_tsm="no"])
111 AC_ARG_ENABLE([pthreaded-ubik],
112     [AS_HELP_STRING([--disable-pthreaded-ubik],
113         [disable installation of pthreaded ubik applications (defaults to
114          enabled)])],
115     ,
116     [enable_pthreaded_ubik="yes"])
117
118 dnl Kernel module build options.
119 AC_ARG_WITH([linux-kernel-headers],
120     [AS_HELP_STRING([--with-linux-kernel-headers=path],
121         [use the kernel headers found at path (optional, defaults to
122          /lib/modules/`uname -r`/build, then /lib/modules/`uname -r`/source,
123          then /usr/src/linux-2.4, and lastly /usr/src/linux)])])
124 AC_ARG_WITH([linux-kernel-build],
125     [AS_HELP_STRING([--with-linux-kernel-build=path],
126         [use the kernel build found at path(optional, defaults to 
127         kernel headers path)])])
128 AC_ARG_WITH([bsd-kernel-headers],
129     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
130         [use the kernel headers found at path (optional, defaults to
131          /usr/src/sys)])])
132 AC_ARG_WITH([bsd-kernel-build],
133     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
134         [use the kernel build found at path (optional, defaults to
135          KSRC/i386/compile/GENERIC)])])
136 AC_ARG_WITH([linux-kernel-packaging],
137     [AS_HELP_STRING([--with-linux-kernel-packaging],
138         [use standard naming conventions to aid Linux kernel build packaging
139          (disables MPS, sets the kernel module name to openafs.ko, and
140          installs kernel modules into the standard Linux location)])],
141     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
142      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
143     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
144 AC_ARG_ENABLE([kernel-module],
145     [AS_HELP_STRING([--disable-kernel-module],
146         [disable compilation of the kernel module (defaults to enabled)])],
147     , 
148     [enable_kernel_module="yes"])
149 AC_ARG_ENABLE([redhat-buildsys],
150     [AS_HELP_STRING([--enable-redhat-buildsys],
151         [enable compilation of the redhat build system kernel (defaults to
152          disabled)])],
153     ,
154     [enable_redhat_buildsys="no"])
155
156 dnl Installation locations.
157 AC_ARG_ENABLE([transarc-paths],
158     [AS_HELP_STRING([--enable-transarc-paths],
159         [use Transarc style paths like /usr/afs and /usr/vice])],
160     , 
161     [enable_transarc_paths="no"])
162
163 dnl Deprecated crypto
164 AC_ARG_ENABLE([kauth],
165     [AS_HELP_STRING([--enable-kauth],
166         [install the deprecated kauth server, pam modules, and utilities
167          (defaults to disabled)])],
168     [enable_pam="yes"],
169     [enable_kauth="no"
170      enable_pam="no"])
171
172 dnl Optimization and debugging flags.
173 AC_ARG_ENABLE([strip-binaries],
174     [AS_HELP_STRING([--disable-strip-binaries],
175         [disable stripping of symbol information from binaries (defaults to
176          enabled)])],
177     ,
178     [enable_strip_binaries="maybe"])
179 AC_ARG_ENABLE([debug],
180     [AS_HELP_STRING([--enable-debug],
181         [enable compilation of the user space code with debugging information
182          (defaults to disabled)])],
183     , 
184     [enable_debug="no"])
185 AC_ARG_ENABLE([optimize],
186     [AS_HELP_STRING([--disable-optimize],
187         [disable optimization for compilation of the user space code (defaults
188          to enabled)])],
189     , 
190     [enable_optimize="yes"])
191 AC_ARG_ENABLE([warnings],
192     [AS_HELP_STRING([--enable-warnings],
193         [enable compilation warnings when building with gcc (defaults to
194          disabled)])],
195     ,
196     [enable_warnings="no"])
197 AC_ARG_ENABLE([checking],
198     [AS_HELP_STRING([--enable-checking],
199         [turn compilation warnings into errors when building with gcc (defaults
200          to disabled)])],
201     [enable_checking="$enableval"],
202     [enable_checking="no"])
203 AC_ARG_ENABLE([debug-locks],
204     [AS_HELP_STRING([--enable-debug-locks],
205         [turn on lock debugging assertions (defaults to disabled)])],
206     [enable_debug_locks="$enableval"],
207     [enable_debug_locks="no"])
208 AC_ARG_ENABLE([debug-kernel],
209     [AS_HELP_STRING([--enable-debug-kernel],
210         [enable compilation of the kernel module with debugging information
211          (defaults to disabled)])],
212     ,
213     [enable_debug_kernel="no"])
214 AC_ARG_ENABLE([optimize-kernel],
215     [AS_HELP_STRING([--disable-optimize-kernel],
216         [disable compilation of the kernel module with optimization (defaults
217          based on platform)])],
218     , 
219     [enable_optimize_kernel=""])
220 AC_ARG_ENABLE([debug-lwp],
221     [AS_HELP_STRING([--enable-debug-lwp],
222         [enable compilation of the LWP code with debugging information
223          (defaults to disabled)])],
224     ,
225     [enable_debug_lwp="no"])
226 AC_ARG_ENABLE([optimize-lwp],
227     [AS_HELP_STRING([--disable-optimize-lwp],
228         [disable optimization for compilation of the LWP code (defaults to
229          enabled)])],
230     ,
231     [enable_optimize_lwp="yes"])
232 AC_ARG_ENABLE([debug-pam],
233     [AS_HELP_STRING([--enable-debug-pam],
234         [enable compilation of the PAM code with debugging information
235          (defaults to disabled)])],
236     ,
237     [enable_debug_pam="no"])
238 AC_ARG_ENABLE([optimize-pam],
239     [AS_HELP_STRING([--disable-optimize-pam],
240         [disable optimization for compilation of the PAM code (defaults to
241          enabled)])],
242     ,
243     [enable_optimize_pam="yes"])
244 AC_ARG_ENABLE([linux-syscall-probing],
245     [AS_HELP_STRING([--enable-linux-syscall-probing],
246         [enable Linux syscall probing (defaults to autodetect)])],
247     ,
248     [enable_linux_syscall_probing="maybe"])
249 AC_ARG_WITH([crosstools-dir],
250     [AS_HELP_STRING([--with-crosstools-dir=path], [use path for native versions of rxgen, compile_et and config])])
251     
252 AC_ARG_WITH([xslt-processor],
253         AS_HELP_STRING([--with-xslt-processor=ARG],
254         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
255         [XSLTPROC="$withval"],
256         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
257
258 AC_ARG_WITH([html-xsl], 
259         AS_HELP_STRING([--with-html-xsl],
260         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
261         [HTML_XSL="$withval"],
262         [HTML_XSL="html/chunk.xsl"])
263
264 AC_ARG_WITH([docbook2pdf],
265         AS_HELP_STRING([--with-docbook2pdf=ARG],
266         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
267         [DOCBOOK2PDF="$withval"],
268         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
269
270 AC_ARG_WITH([docbook-stylesheets],
271         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
272         [location of DocBook stylesheets (default is to search a set of likely paths)]),
273         [DOCBOOK_STYLESHEETS="$withval"],
274         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
275         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
276                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
277         fi)
278
279 AC_ARG_WITH([dot],
280         AS_HELP_STRING([--with-dot@<:@=PATH@:>@],
281         [use graphviz dot to generate dependency graphs with doxygen (defaults to autodetect)]),
282         [], [with_dot="maybe"])
283
284 enable_login="no"
285
286 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
287 dnl documentation build.
288 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
289 AC_CHECK_PROGS([DOXYGEN], [doxygen])
290
291 dnl Optionally generate graphs with doxygen.
292 case "$with_dot" in
293 maybe)
294     AC_CHECK_PROGS([DOT], [dot])
295     AS_IF([test "x$DOT" = "x"], [HAVE_DOT="no"], [HAVE_DOT="yes"])
296     ;;
297 yes)
298     HAVE_DOT="yes"
299     ;;
300 no)
301     HAVE_DOT="no"
302     ;;
303 *)
304     HAVE_DOT="yes"
305     DOT_PATH=$with_dot
306 esac
307 AC_SUBST(HAVE_DOT)
308 AC_SUBST(DOT_PATH)
309
310 dnl Checks for UNIX variants.
311 AC_ISC_POSIX
312
313 dnl Various compiler setup.
314 AC_TYPE_PID_T
315 AC_TYPE_SIZE_T
316
317 dnl Checks for programs.
318 AC_PROG_INSTALL
319 AC_PROG_LN_S
320 AC_PROG_RANLIB
321 AC_PROG_YACC
322 AM_PROG_LEX
323 dnl if we are flex, be lex-compatible
324 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
325
326 OPENAFS_FORCE_ABS_INSTALL
327 OPENAFS_CHECK_BIGENDIAN
328 OPENAFS_PRINTF_TAKES_Z_LEN
329
330 AC_MSG_CHECKING(your OS)
331 system=$host
332 case $system in
333         *-linux*)
334
335                 MKAFS_OSTYPE=LINUX
336                 if test "x$enable_redhat_buildsys" = "xyes"; then
337                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
338                 fi
339                 if test "x$enable_kernel_module" = "xyes"; then
340                  if test "x$with_linux_kernel_headers" != "x"; then
341                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
342                  else
343                    for utsdir in "/lib/modules/`uname -r`/build" \
344                                  "/lib/modules/`uname -r`/source" \
345                                  "/usr/src/linux-2.4" \
346                                  "/usr/src/linux"; do
347                      LINUX_KERNEL_PATH="$utsdir"
348                      for utsfile in "include/generated/utsrelease.h" \
349                                     "include/linux/utsrelease.h" \
350                                     "include/linux/version.h" \
351                                     "include/linux/version-up.h"; do
352                        if grep "UTS_RELEASE" "$utsdir/$utsfile" >/dev/null 2>&1; then
353                          break 2
354                        fi
355                      done
356                    done
357                  fi
358                  if test "x$with_linux_kernel_build" != "x"; then
359                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
360                  else
361                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
362                  fi
363                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
364                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
365                    LINUX_VERSION="$linux_kvers"
366                  else
367                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
368                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
369                      LINUX_VERSION="$linux_kvers"
370                    else
371                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
372                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
373                        if test "x$linux_kvers" = "x"; then
374                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
375                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
376                            if test "x$linux_kvers" = "x"; then
377                              AC_MSG_ERROR(Linux headers lack version definition [2])
378                              exit 1
379                            else
380                              LINUX_VERSION="$linux_kvers"
381                            fi
382                          else
383                            AC_MSG_ERROR(Linux headers lack version definition)
384                            exit 1
385                          fi
386                        else
387                          LINUX_VERSION="$linux_kvers"
388                        fi
389                      else
390                        enable_kernel_module="no"
391                      fi
392                    fi
393                  fi
394                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
395                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
396                      enable_kernel_module="no"
397                  fi
398                  if test "x$enable_kernel_module" = "xno"; then
399                   if test "x$with_linux_kernel_headers" != "x"; then
400                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
401                    exit 1
402                   else
403                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
404                   fi
405                  fi
406                  dnl do we need to determine SUBARCH from autoconf.h
407                  SUBARCH=default
408                 fi
409                 AC_MSG_RESULT(linux)
410                 if test "x$enable_kernel_module" = "xyes"; then
411                  case "$LINUX_VERSION" in
412                   2.2.*) AFS_SYSKVERS=22 ;;
413                   2.4.*) AFS_SYSKVERS=24 ;;
414                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
415                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
416                  esac
417                 fi
418                 ;;
419         *-solaris*)
420                 MKAFS_OSTYPE=SOLARIS
421                 AC_MSG_RESULT(sun4)
422                 AC_PATH_PROG(SOLARISCC, [cc], ,
423                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
424                 if test "x$SOLARISCC" = "x" ; then
425                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
426                 fi
427                 SOLARIS_UFSVFS_HAS_DQRWLOCK
428                 SOLARIS_FS_HAS_FS_ROLLED
429                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
430                 SOLARIS_HAVE_VN_RENAMEPATH
431                 ;;
432         *-sunos*)
433                 MKAFS_OSTYPE=SUNOS
434                 enable_kernel_module=no
435                 AC_MSG_RESULT(sun4)
436                 ;;
437         *-hpux*)
438                 MKAFS_OSTYPE=HPUX
439                 AC_MSG_RESULT(hp_ux)
440                 if test -f "/usr/old/usr/include/ndir.h"; then
441                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
442                 fi
443                 ;;
444         *-irix*)
445                 if test -d /usr/include/sys/SN/SN1; then
446                  IRIX_BUILD_IP35="IP35"
447                 fi
448                 MKAFS_OSTYPE=IRIX
449                 AC_MSG_RESULT(sgi)
450                 ;;
451         *-aix*)
452                 MKAFS_OSTYPE=AIX
453                 AC_MSG_RESULT(rs_aix)
454                 ;;
455         arm-*-darwin*)
456                 MKAFS_OSTYPE=DARWIN
457                 AC_MSG_RESULT(arm_darwin)
458                 ;;
459         powerpc-*-darwin*)
460                 MKAFS_OSTYPE=DARWIN
461                 AC_MSG_RESULT(ppc_darwin)
462                 ;;
463         i386-*-darwin*)
464                 MKAFS_OSTYPE=DARWIN
465                 AC_MSG_RESULT(x86_darwin)
466                 ;;
467         x86_64-*-darwin*)
468                 MKAFS_OSTYPE=DARWIN
469                 AC_MSG_RESULT(x86_darwin)
470                 ;;
471         i386-*-freebsd*)
472                 MKAFS_OSTYPE=FBSD
473                 AC_MSG_RESULT(i386_fbsd)
474                 ;;
475         x86_64-*-freebsd*)
476                 MKAFS_OSTYPE=FBSD
477                 AC_MSG_RESULT(amd64_fbsd)
478                 ;;
479         *-netbsd*)
480                 MKAFS_OSTYPE=NBSD
481                 AC_MSG_RESULT(nbsd)
482                 ;;
483         x86_64-*-openbsd*)
484                 MKAFS_OSTYPE=OBSD
485                 AC_MSG_RESULT(amd64_obsd)
486                 ;;
487         i386-*-openbsd*)
488                 MKAFS_OSTYPE=OBSD
489                 AC_MSG_RESULT(i386_obsd)
490                 ;;
491         *-dragonfly*)
492                 MKAFS_OSTYPE=DFBSD
493                 AC_MSG_RESULT(i386_dfbsd)
494                 ;;
495         *)
496                 AC_MSG_RESULT($system)
497                 ;;
498 esac
499
500 if test "x$with_afs_sysname" != "x"; then
501         AFS_SYSNAME="$with_afs_sysname"
502 else
503         AC_MSG_CHECKING(your AFS sysname)
504         case $host in
505                 i?86-*-openbsd?.?)
506                         v=${host#*openbsd}
507                         vM=${v%.*}
508                         vm=${v#*.}
509                         AFS_SYSNAME="i386_obsd${vM}${vm}"
510                         ;;
511                 sparc64-*-openbsd?.?)
512                         v=${host#*openbsd}
513                         vM=${v%.*}
514                         vm=${v#*.}
515                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
516                         ;;
517                 x86_64-*-openbsd?.?)
518                         v=${host#*openbsd}
519                         vM=${v%.*}
520                         vm=${v#*.}
521                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
522                         ;;
523                 i?86-*-freebsd*.*)
524                         v=${host#*freebsd}
525                         vM=${v%.*}
526                         vm=${v#*.}
527                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
528                         ;;
529                 x86_64-*-freebsd*.*)
530                         v=${host#*freebsd}
531                         vM=${v%.*}
532                         vm=${v#*.}
533                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
534                         ;;
535                 i386-*-dragonfly?.*)
536                         v=${host#*dragonfly}
537                         vM=${v%.*}
538                         vm=${v#*.}
539                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
540                         ;;
541                 i?86-*-netbsd*1.6[[M-Z]]*)
542                         AFS_SYSNAME="i386_nbsd20"
543                         ;;
544                 powerpc-*-netbsd*1.6[[M-Z]]*)
545                         AFS_SYSNAME="ppc_nbsd20"
546                         ;;
547                 *-*-netbsd*)
548                         arch=${host%%-unknown*}
549                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
550                                                -e 's/powerpc/ppc/g')
551                         v=${host#*netbsd}
552                         v=${v#*aout}
553                         v=${v#*ecoff}
554                         v=${v#*elf}
555                         vM=${v%%.*}
556                         vM=${vM%.*}
557                         v=${v#*.}
558                         vm=${v%%.*}
559                         vm=${vm%.*}
560                         vm=${vm%%[[_A-Z]]*}
561                         if test $vm -eq 99 ; then
562                                 vM=$((vM+1))
563                         fi
564                         if test $vM -gt 1 ; then
565                                 vm=0
566                         fi
567                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
568                         ;;
569                 hppa*-hp-hpux11.0*)
570                         AFS_SYSNAME="hp_ux110"
571                         ;;
572                 hppa*-hp-hpux11.11)
573                         AFS_SYSNAME="hp_ux11i"
574                         ;;
575                 hppa*-hp-hpux11.23)
576                         AFS_SYSNAME="hp_ux1123"
577                         ;;
578                 ia64-hp-hpux11.22)
579                         AFS_SYSNAME="ia64_hpux1122"
580                         ;;
581                 ia64-hp-hpux*)
582                         AFS_SYSNAME="ia64_hpux1123"
583                         ;;
584                 hppa*-hp-hpux10*)
585                         AFS_SYSNAME="hp_ux102"
586                         ;;
587                 powerpc-apple-darwin7*)
588                         AFS_SYSNAME="ppc_darwin_70"
589                         OSXSDK="macosx10.3"
590                         ;;
591                 powerpc-apple-darwin8.*)
592                         AFS_SYSNAME="ppc_darwin_80"
593                         OSXSDK="macosx10.4"
594                         ;;
595                 i386-apple-darwin8.*)
596                         AFS_SYSNAME="x86_darwin_80"
597                         OSXSDK="macosx10.4"
598                         ;;
599                 powerpc-apple-darwin9.*)
600                         AFS_SYSNAME="ppc_darwin_90"
601                         OSXSDK="macosx10.5"
602                         ;;
603                 i386-apple-darwin9.*)
604                         AFS_SYSNAME="x86_darwin_90"
605                         OSXSDK="macosx10.5"
606                         ;;
607                 i?86-apple-darwin10.*)
608                         AFS_SYSNAME="x86_darwin_100"
609                         OSXSDK="macosx10.6"
610                         ;;
611                 x86_64-apple-darwin10.*)
612                         AFS_SYSNAME="x86_darwin_100"
613                         OSXSDK="macosx10.6"
614                         ;;
615                 arm-apple-darwin10.*)
616                         AFS_SYSNAME="arm_darwin_100"
617                         OSXSDK="iphoneos4.0"
618                         ;;
619                 x86_64-apple-darwin11.*)
620                         AFS_SYSNAME="x86_darwin_110"
621                         OSXSDK="macosx10.7"
622                         ;;
623                 i?86-apple-darwin11.*)
624                         AFS_SYSNAME="x86_darwin_110"
625                         OSXSDK="macosx10.7"
626                         ;;
627                 x86_64-apple-darwin12.*)
628                         AFS_SYSNAME="x86_darwin_120"
629                         OSXSDK="macosx10.8"
630                         ;;
631                 i?86-apple-darwin12.*)
632                         AFS_SYSNAME="x86_darwin_120"
633                         OSXSDK="macosx10.8"
634                         ;;
635                 x86_64-apple-darwin13.*)
636                         AFS_SYSNAME="x86_darwin_130"
637                         OSXSDK="macosx10.9"
638                         ;;
639                 i?86-apple-darwin13.*)
640                         AFS_SYSNAME="x86_darwin_130"
641                         OSXSDK="macosx10.9"
642                         ;;
643                 sparc-sun-solaris2.8)
644                         AFS_SYSNAME="sun4x_58"
645                         ;;
646                 sparc-sun-solaris2.9)
647                         AFS_SYSNAME="sun4x_59"
648                         ;;
649                 sparc-sun-solaris2.10)
650                         AFS_SYSNAME="sun4x_510"
651                         ;;
652                 sparc-sun-solaris2.11)
653                         AFS_SYSNAME="sun4x_511"
654                         ;;
655                 i386-pc-solaris2.8)
656                         AFS_SYSNAME="sunx86_58"
657                         ;;
658                 i386-pc-solaris2.9)
659                         AFS_SYSNAME="sunx86_59"
660                         ;;
661                 i386-pc-solaris2.10)
662                         AFS_SYSNAME="sunx86_510"
663                         ;;
664                 i386-pc-solaris2.11)
665                         AFS_SYSNAME="sunx86_511"
666                         ;;
667                 alpha*-dec-osf4.0*)
668                         AFS_SYSNAME="alpha_dux40"
669                         ;;
670                 alpha*-dec-osf5.0*)
671                         AFS_SYSNAME="alpha_dux50"
672                         ;;
673                 alpha*-dec-osf5.1*)
674                         AFS_SYSNAME="alpha_dux51"
675                         ;;
676                 mips-sgi-irix6.5)
677                         AFS_SYSNAME="sgi_65"
678                         enable_pam="no"
679                         ;;
680                 ia64-*-linux*)
681                         AFS_SYSNAME="ia64_linuxXX"
682                         ;;
683                 powerpc-*-linux*)
684                         AFS_SYSNAME="`/bin/arch`_linuxXX"
685                         ;;
686                 powerpc64-*-linux*)
687                         AFS_SYSNAME="ppc64_linuxXX"
688                         ;;
689                 alpha*-linux*)
690                         AFS_SYSNAME="alpha_linux_XX"
691                         ;;
692                 s390-*-linux*)
693                         AFS_SYSNAME="s390_linuxXX"
694                         ;;
695                 s390x-*-linux*)
696                         AFS_SYSNAME="s390x_linuxXX"
697                         ;;
698                 sparc-*-linux*)
699                         AFS_SYSNAME="`/bin/arch`_linuxXX"
700                         ;;
701                 sparc64-*-linux*)
702                         AFS_SYSNAME="sparc64_linuxXX"
703                         ;;
704                 i?86-*-linux*)
705                         AFS_SYSNAME="i386_linuxXX"
706                         ;;
707                 arm*-linux*)
708                         AFS_SYSNAME="arm_linuxXX"
709                         ;;
710                 parisc-*-linux-gnu|hppa-*-linux-gnu)
711                         AFS_SYSNAME="parisc_linuxXX"
712                         enable_pam="no"
713                         ;;
714                 power*-ibm-aix4.2*)
715                         AFS_SYSNAME="rs_aix42"
716                         enable_pam="no"
717                         ;;
718                 power*-ibm-aix4.3*)
719                         AFS_SYSNAME="rs_aix42"
720                         enable_pam="no"
721                         ;;
722                 power*-ibm-aix5.1*)
723                         AFS_SYSNAME="rs_aix51"
724                         enable_pam="no"
725                         ;;
726                 power*-ibm-aix5.2*)
727                         AFS_SYSNAME="rs_aix52"
728                         enable_pam="no"
729                         ;;
730                 power*-ibm-aix5.3*)
731                         AFS_SYSNAME="rs_aix53"
732                         enable_pam="no"
733                         ;;
734                 power*-ibm-aix6.1*)
735                         AFS_SYSNAME="rs_aix61"
736                         enable_pam="no"
737                         ;;
738                 x86_64-*-linux-gnu)
739                         AFS_SYSNAME="amd64_linuxXX"
740                         enable_pam="yes"
741                         ;;
742                 *)
743                         AC_MSG_ERROR(An AFS sysname is required)
744                         exit 1
745                         ;;
746         esac
747         case $AFS_SYSNAME in
748                 *_linux* | *_umlinux*)
749                         if test "x${AFS_SYSKVERS}" = "x"; then
750                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
751                         fi
752                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
753                         AFS_SYSNAME="$_AFS_SYSNAME"
754                         AC_TRY_KBUILD(
755                          [],
756                          [#ifndef CONFIG_USERMODE
757                           #error not UML
758                           #endif],
759                          ac_cv_linux_is_uml=yes,)
760                         if test "${ac_cv_linux_is_uml}" = yes; then
761                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
762                         fi
763                         AFS_SYSNAME="$_AFS_SYSNAME"
764                         ;;
765         esac
766         AC_MSG_RESULT($AFS_SYSNAME)
767 fi
768
769 case $AFS_SYSNAME in
770         *_darwin*)
771                 AC_CHECK_HEADERS(crt_externs.h)
772                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
773                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
774                 AC_SUBST(OSXSDK)
775                 ;;
776 esac
777
778 dnl Some hosts have a separate common param file they should include.  Figure
779 dnl out if we're on one of them now that we know the sysname.
780 case $AFS_SYSNAME in
781     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
782     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
783     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
784     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
785     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
786     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
787     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
788     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
789     *_nbsd70)   AFS_PARAM_COMMON=param.nbsd70.h  ;;
790     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
791     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
792     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
793     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
794     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
795     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
796     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
797     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
798     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
799     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
800     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
801     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
802     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
803     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
804     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
805     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
806     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
807     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
808     *_obsd49)   AFS_PARAM_COMMON=param.obsd49.h  ;;
809     *_obsd50)   AFS_PARAM_COMMON=param.obsd50.h  ;;
810     *_obsd51)   AFS_PARAM_COMMON=param.obsd51.h  ;;
811     *_obsd52)   AFS_PARAM_COMMON=param.obsd52.h  ;;
812     *_obsd53)   AFS_PARAM_COMMON=param.obsd53.h  ;;
813     *_obsd54)   AFS_PARAM_COMMON=param.obsd54.h  ;;
814     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
815     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
816     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
817 # Linux alpha adds an extra underscore for no good reason.
818     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
819     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
820     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
821     *_fbsd_*)   AFS_PARAM_COMMON=param.generic_fbsd.h ;;
822 esac
823
824 OPENAFS_OSCONF
825
826 case $AFS_SYSNAME in *_linux* | *_umlinux*)
827
828                 # Add (sub-) architecture-specific paths needed by conftests
829                 case $AFS_SYSNAME  in
830                         *_umlinux26)
831                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
832                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
833                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
834                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
835                 esac
836
837                 if test "x$enable_kernel_module" = "xyes"; then
838                  if test "x$enable_debug_kernel" = "xno"; then
839                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
840                  fi
841                  OPENAFS_GCC_SUPPORTS_MARCH
842                  AC_SUBST(P5PLUS_KOPTS)
843                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
844                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
845                  OPENAFS_GCC_SUPPORTS_NO_COMMON
846                  OPENAFS_GCC_SUPPORTS_PIPE
847                  AC_SUBST(LINUX_GCC_KOPTS)
848
849                  dnl Setup the kernel build environment
850                  LINUX_KBUILD_USES_EXTRA_CFLAGS
851                  LINUX_KERNEL_COMPILE_WORKS
852
853                  dnl Check for header files
854                  AC_CHECK_LINUX_HEADER([config.h])
855                  AC_CHECK_LINUX_HEADER([completion.h])
856                  AC_CHECK_LINUX_HEADER([exportfs.h])
857                  AC_CHECK_LINUX_HEADER([freezer.h])
858                  AC_CHECK_LINUX_HEADER([key-type.h])
859                  AC_CHECK_LINUX_HEADER([semaphore.h])
860                  AC_CHECK_LINUX_HEADER([seq_file.h])
861
862                  dnl Type existence checks
863                  AC_CHECK_LINUX_TYPE([struct vfs_path], [dcache.h])
864                  AC_CHECK_LINUX_TYPE([kuid_t], [uidgid.h])
865
866                  dnl Check for structure elements
867                  AC_CHECK_LINUX_STRUCT([address_space_operations],
868                                        [write_begin], [fs.h])
869                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
870                                        [backing-dev.h])
871                  AC_CHECK_LINUX_STRUCT([cred], [session_keyring], [cred.h])
872                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
873                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
874                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
875                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
876                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
877                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
878                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
879                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
880                  AC_CHECK_LINUX_STRUCT([file_operations], [iterate], [fs.h])
881                  AC_CHECK_LINUX_STRUCT([file_operations], [read_iter], [fs.h])
882                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
883                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
884                  AC_CHECK_LINUX_STRUCT([inode_operations], [truncate], [fs.h])
885                  AC_CHECK_LINUX_STRUCT([key_type], [preparse], [key-type.h])
886                  AC_CHECK_LINUX_STRUCT([key_type], [instantiate_prep], [key-type.h])
887                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
888                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
889                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
890                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
891                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
892                                        [fs.h])
893                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
894                                        [fs.h])
895                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
896                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
897                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
898                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
899                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
900                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
901                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
902                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
903                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
904                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
905                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
906
907                  dnl Check for typed structure elements
908                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
909                                              [buf], [fs.h])
910
911                  dnl Function existence checks
912
913                  AC_CHECK_LINUX_FUNC([bdi_init],
914                                      [#include <linux/backing-dev.h>],
915                                      [bdi_init(NULL);])
916                  AC_CHECK_LINUX_FUNC([PageChecked],
917                                      [#include <linux/mm.h>
918 #include <linux/page-flags.h>],
919                                      [struct page *_page;
920                                       int bchecked = PageChecked(_page);])
921                  AC_CHECK_LINUX_FUNC([PageFsMisc],
922                                      [#include <linux/mm.h>
923 #include <linux/page-flags.h>],
924                                      [struct page *_page;
925                                       int bchecked = PageFsMisc(_page);])
926                  AC_CHECK_LINUX_FUNC([clear_inode],
927                                      [#include <linux/fs.h>],
928                                      [clear_inode(NULL);])
929                  AC_CHECK_LINUX_FUNC([current_kernel_time],
930                                      [#include <linux/time.h>],
931                                      [struct timespec s;
932                                       s = current_kernel_time();])
933                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
934                                      [#include <linux/fs.h>],
935                                      [d_alloc_anon(NULL);])
936                  AC_CHECK_LINUX_FUNC([d_count],
937                                      [#include <linux/dcache.h>],
938                                      [d_count(NULL);])
939                  AC_CHECK_LINUX_FUNC([d_make_root],
940                                      [#include <linux/fs.h>],
941                                      [d_make_root(NULL);])
942                  AC_CHECK_LINUX_FUNC([do_sync_read],
943                                      [#include <linux/fs.h>],
944                                      [do_sync_read(NULL, NULL, 0, NULL);])
945                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
946                                      [#include <linux/sched.h>],
947                                      [pid_t p; find_task_by_pid(p);])
948                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
949                                      [#include <linux/fs.h>],
950                                      [generic_file_aio_read(NULL,NULL,0,0);])
951                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
952                                      [#include <linux/pagemap.h>],
953                                      [grab_cache_page_write_begin(NULL, 0, 0);])
954                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
955                                      [#include <linux/list.h>],
956                                      [hlist_unhashed(0);])
957                  AC_CHECK_LINUX_FUNC([i_size_read],
958                                      [#include <linux/fs.h>],
959                                      [i_size_read(NULL);])
960                  AC_CHECK_LINUX_FUNC([inode_setattr],
961                                      [#include <linux/fs.h>],
962                                      [inode_setattr(NULL, NULL);])
963                  AC_CHECK_LINUX_FUNC([iter_file_splice_write],
964                                      [#include <linux/fs.h>],
965                                      [iter_file_splice_write(NULL,NULL,NULL,0,0);])
966                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
967                                      [#include <linux/net.h>],
968                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
969                  AC_CHECK_LINUX_FUNC([page_follow_link],
970                                      [#include <linux/fs.h>],
971                                      [page_follow_link(0,0);])
972                  AC_CHECK_LINUX_FUNC([page_offset],
973                                      [#include <linux/pagemap.h>],
974                                      [page_offset(NULL);])
975                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
976                                      [#include <linux/pagevec.h>],
977                                      [__pagevec_lru_add_file(NULL);])
978                  AC_CHECK_LINUX_FUNC([path_lookup],
979                                      [#include <linux/fs.h>
980                                       #include <linux/namei.h>],
981                                      [path_lookup(NULL, 0, NULL);])
982                  AC_CHECK_LINUX_FUNC([proc_create],
983                                      [#include <linux/proc_fs.h>],
984                                      [proc_create(NULL, 0, NULL, NULL);])
985                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
986                                      [#include <linux/rcupdate.h>],
987                                      [rcu_read_lock();])
988                  AC_CHECK_LINUX_FUNC([set_nlink],
989                                      [#include <linux/fs.h>],
990                                      [set_nlink(NULL, 1);])
991                  AC_CHECK_LINUX_FUNC([sock_create_kern],
992                                      [#include <linux/net.h>],
993                                      [sock_create_kern(0, 0, 0, NULL);])
994                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
995                                      [#include <linux/splice.h>],
996                                      [splice_direct_to_actor(NULL,NULL,NULL);])
997                  AC_CHECK_LINUX_FUNC([svc_addr_in],
998                                      [#include <linux/sunrpc/svc.h>],
999                                      [svc_addr_in(NULL);])
1000                  AC_CHECK_LINUX_FUNC([zero_user_segments],
1001                                      [#include <linux/highmem.h>],
1002                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
1003                  AC_CHECK_LINUX_FUNC([noop_fsync],
1004                                      [#include <linux/fs.h>],
1005                                      [void *address = &noop_fsync; printk("%p\n", address)];)
1006                  AC_CHECK_LINUX_FUNC([kthread_run],
1007                                      [#include <linux/kernel.h>
1008                                       #include <linux/kthread.h>],
1009                                      [kthread_run(NULL, NULL, "test");])
1010
1011                  dnl Consequences - things which get set as a result of the
1012                  dnl                above tests
1013                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
1014                        [AC_DEFINE([AFS_NONFSTRANS], 1,
1015                                   [define to disable the nfs translator])])
1016
1017                  dnl Assorted more complex tests
1018                  LINUX_AIO_NONVECTOR
1019                  LINUX_EXPORTS_PROC_ROOT_FS
1020                  LINUX_KMEM_CACHE_INIT
1021                  LINUX_HAVE_KMEM_CACHE_T
1022                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
1023                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
1024                  LINUX_D_PATH_TAKES_STRUCT_PATH
1025                  LINUX_NEW_EXPORT_OPS
1026                  LINUX_INODE_SETATTR_RETURN_TYPE
1027                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
1028                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
1029                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
1030                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
1031                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
1032                  LINUX_DOP_D_DELETE_TAKES_CONST
1033                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
1034                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
1035                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
1036                  LINUX_FOP_F_FSYNC_TAKES_RANGE
1037                  LINUX_AOP_WRITEBACK_CONTROL
1038                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
1039                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
1040                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
1041                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
1042                  LINUX_KERNEL_SOCK_CREATE
1043                  LINUX_EXPORTS_KEY_TYPE_KEYRING
1044                  LINUX_NEED_RHCONFIG
1045                  LINUX_RECALC_SIGPENDING_ARG_TYPE
1046                  LINUX_EXPORTS_TASKLIST_LOCK
1047                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
1048                  LINUX_STATFS_TAKES_DENTRY
1049                  LINUX_REFRIGERATOR
1050                  LINUX_HAVE_TRY_TO_FREEZE
1051                  LINUX_LINUX_KEYRING_SUPPORT
1052                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
1053                  LINUX_KEY_ALLOC_NEEDS_CRED
1054                  LINUX_INIT_WORK_HAS_DATA
1055                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
1056                  LINUX_HAVE_DCACHE_LOCK
1057                  LINUX_D_COUNT_IS_INT
1058                  LINUX_IOP_MKDIR_TAKES_UMODE_T
1059                  LINUX_IOP_CREATE_TAKES_UMODE_T
1060                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
1061                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
1062                  LINUX_DENTRY_OPEN_TAKES_PATH
1063                  LINUX_D_ALIAS_IS_HLIST
1064                  LINUX_HLIST_ITERATOR_NO_NODE
1065                  LINUX_IOP_I_CREATE_TAKES_BOOL
1066                  LINUX_DOP_D_REVALIDATE_TAKES_UNSIGNED
1067                  LINUX_IOP_LOOKUP_TAKES_UNSIGNED
1068
1069                  dnl If we are guaranteed that keyrings will work - that is
1070                  dnl  a) The kernel has keyrings enabled
1071                  dnl  b) The code is new enough to give us a key_type_keyring
1072                  dnl then we just disable syscall probing unless we've been
1073                  dnl told otherwise
1074
1075                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
1076                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
1077                           [enable_linux_syscall_probing="no"],
1078                           [enable_linux_syscall_probing="yes"])
1079                  ])
1080
1081                  dnl Syscall probing needs a few tests of its own, and just
1082                  dnl won't work if the kernel doesn't export init_mm
1083                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1084                    LINUX_EXPORTS_INIT_MM
1085                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1086                      AC_MSG_ERROR(
1087                        [Can't do syscall probing without exported init_mm])
1088                    ])
1089                    LINUX_EXPORTS_SYS_CHDIR
1090                    LINUX_EXPORTS_SYS_OPEN
1091                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1092                              [define to enable syscall table probes])
1093                  ])
1094
1095                  dnl Packaging and SMP build
1096                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1097                    LINUX_WHICH_MODULES
1098                  else
1099                    AC_SUBST(MPS,'SP')
1100                  fi
1101
1102                  dnl Syscall probing
1103                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1104                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1105                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1106                    ])
1107                    ac_cv_linux_exports_sys_call_table=no
1108                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1109                      ac_cv_linux_exports_ia32_sys_call_table=yes
1110                    fi
1111                  else
1112                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1113                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1114                    LINUX_EXPORTS_SYS_CALL_TABLE
1115                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1116                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1117                          linux_syscall_method=none
1118                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1119                             linux_syscall_method=scan
1120                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1121                                linux_syscall_method=scan_with_kallsyms_address
1122                             fi
1123                          fi
1124                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1125                             linux_syscall_method=kallsyms_symbol
1126                          fi
1127                          if test "x$linux_syscall_method" = "xnone"; then
1128                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1129                             linux_syscall_method=scan
1130                          fi
1131                    fi
1132                  fi
1133                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1134                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1135                  fi
1136                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1137                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1138                  fi
1139                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1140                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1141                  else
1142                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1143                  fi
1144                 :
1145                 fi
1146 dnl Linux-only, but just enable always.
1147                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1148 esac
1149
1150 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1151     [ac_cv_sync_fetch_and_add],
1152     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1153                     [ac_cv_sync_fetch_and_add=yes],
1154                     [ac_cv_sync_fetch_and_add=no])
1155 ])
1156 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1157       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1158                 [define if your C compiler has __sync_add_and_fetch])])
1159
1160 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1161     [ac_cv_sockaddr_len],
1162     [AC_TRY_COMPILE( [#include <sys/types.h>
1163 #include <sys/socket.h>],
1164                      [struct sockaddr *a; a->sa_len=0;],
1165                      [ac_cv_sockaddr_len=yes],
1166                      [ac_cv_sockaddr_len=no])
1167 ])
1168 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1169       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1170                  [define if you struct sockaddr sa_len])])
1171
1172 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1173         echo Skipping library tests because they confuse Irix.
1174 else
1175   AC_SEARCH_LIBS([socket], [socket inet])
1176   AC_SEARCH_LIBS([connect], [nsl])
1177   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1178
1179   dnl darwin wants it, aix hates it
1180   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1181   AC_TRY_COMPILE([
1182   #include <stdlib.h>
1183   #include <stdio.h>
1184   #include <sys/types.h>
1185   #include <sys/socket.h>
1186   #include <netinet/in.h>
1187   #include <arpa/inet.h>
1188   #include <arpa/nameser.h>
1189   #include <arpa/nameser_compat.h>
1190   #include <resolv.h>
1191   ], [static int i; i = 0;],
1192   [AC_MSG_RESULT(yes)
1193    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1194   [AC_MSG_RESULT(no)
1195    ])
1196
1197   openafs_save_libs="$LIBS"
1198   AC_MSG_CHECKING([for res_search])
1199   AC_FUNC_RES_SEARCH
1200
1201   if test "$ac_cv_func_res_search" = no; then
1202       for lib in dns nsl resolv; do
1203         if test "$ac_cv_func_res_search" != yes; then
1204           LIBS="-l$lib $LIBS"
1205           AC_FUNC_RES_SEARCH
1206           LIBS="$openafs_save_libs"
1207         fi
1208       done    
1209       if test "$ac_cv_func_res_search" = yes; then
1210         LIB_AFSDB="-l$lib"
1211         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1212         AC_MSG_RESULT([yes, in lib$lib])
1213       else
1214         AC_MSG_RESULT(no)
1215       fi
1216   else
1217     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1218     AC_MSG_RESULT(yes)
1219   fi
1220   
1221 fi
1222 XLIBS="$LIB_AFSDB $XLIBS"
1223
1224 AC_CHECK_RESOLV_RETRANS
1225
1226 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1227     [ac_cv_setsockopt_iprecverr],
1228     [AC_TRY_COMPILE( [
1229 #include <sys/types.h>
1230 #include <sys/socket.h>
1231 #include <netinet/in.h>],
1232 [int on=1;
1233 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1234         [ac_cv_setsockopt_iprecverr=yes],
1235         [ac_cv_setsockopt_iprecverr=no])])
1236
1237 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1238       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1239                  [define if we can receive socket errors via IP_RECVERR])])
1240
1241 PTHREAD_LIBS=error
1242 if test "x$MKAFS_OSTYPE" = OBSD; then
1243         PTHREAD_LIBS="-pthread"
1244 fi
1245 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1246         PTHREAD_LIBS="-pthread"
1247 fi
1248 if test "x$PTHREAD_LIBS" = xerror; then
1249         AC_CHECK_LIB(pthread, pthread_attr_init,
1250                 PTHREAD_LIBS="-lpthread")
1251 fi
1252 if test "x$PTHREAD_LIBS" = xerror; then
1253         AC_CHECK_LIB(pthreads, pthread_attr_init,
1254                 PTHREAD_LIBS="-lpthreads")
1255 fi
1256 if test "x$PTHREAD_LIBS" = xerror; then
1257         AC_CHECK_LIB(c_r, pthread_attr_init,
1258                 PTHREAD_LIBS="-lc_r")
1259 fi
1260 if test "x$PTHREAD_LIBS" = xerror; then
1261         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1262 fi
1263 if test "x$PTHREAD_LIBS" = xerror; then
1264         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1265         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1266                 PTHREAD_LIBS="-lpthread")
1267 fi
1268 if test "x$PTHREAD_LIBS" = xerror; then
1269         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1270 fi
1271 AC_SUBST(PTHREAD_LIBS)
1272
1273 HOST_CPU="$host_cpu"
1274
1275 if test "x$with_bsd_kernel_headers" != "x"; then
1276         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1277 else
1278         BSD_KERNEL_PATH="/usr/src/sys"
1279 fi
1280
1281 if test "x$with_bsd_kernel_build" != "x"; then
1282         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1283 else
1284         case $AFS_SYSNAME in
1285                 *_fbsd_*)
1286                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1287                         ;;
1288                 *_nbsd*)
1289                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1290         esac
1291 fi
1292
1293 # Fast restart
1294 if test "$enable_supergroups" = "yes"; then
1295         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1296 fi
1297
1298 if test "$enable_bitmap_later" = "yes"; then
1299         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1300 fi
1301
1302 if test "$enable_unix_sockets" = "yes"; then
1303         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1304         USE_UNIX_SOCKETS="yes"
1305 else
1306         USE_UNIX_SOCKETS="no"
1307 fi
1308 AC_SUBST(USE_UNIX_SOCKETS)
1309
1310 if test "$enable_namei_fileserver" = "yes"; then
1311         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1312         VFSCK=""
1313 else
1314         if test "$enable_namei_fileserver" = "default"; then
1315                 case $host in
1316                         *-solaris2.10*)
1317                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1318                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1319                                 VFSCK=""
1320                                 ;;
1321                         *-solaris2.11*)
1322                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1323                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1324                                 VFSCK=""
1325                                 ;;
1326                         *)
1327                                 VFSCK="vfsck"
1328                                 ;;
1329                 esac
1330         else
1331                 VFSCK="vfsck"
1332         fi
1333 fi
1334
1335 dnl check for tivoli
1336 AC_MSG_CHECKING(for tivoli tsm butc support)
1337 XBSA_CFLAGS=""
1338 if test "$enable_tivoli_tsm" = "yes"; then
1339         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1340         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1341         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1342         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1343
1344         if test -r "$XBSADIR3/dsmapifp.h"; then
1345                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1346                 XBSA_XLIBS="-ldl"
1347                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1348         elif test -r "$XBSADIR4/dsmapifp.h"; then
1349                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1350                 XBSA_XLIBS="-ldl"
1351                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1352         elif test -r "$XBSADIR1/xbsa.h"; then
1353                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1354                 XBSA_XLIBS=""
1355                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1356         elif test -r "$XBSADIR2/xbsa.h"; then
1357                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1358                 XBSA_XLIBS=""
1359                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1360         else
1361                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1362         fi
1363 else
1364         AC_MSG_RESULT([no])
1365 fi
1366 AC_SUBST(XBSA_CFLAGS)
1367 AC_SUBST(XBSA_XLIBS) 
1368
1369 dnl checks for header files.
1370 AC_HEADER_STDC
1371 AC_HEADER_SYS_WAIT
1372 AC_HEADER_DIRENT
1373 AC_CHECK_HEADERS([ \
1374                    arpa/inet.h \
1375                    arpa/nameser.h \
1376                    curses.h\
1377                    direct.h \
1378                    errno.h \
1379                    fcntl.h \
1380                    grp.h \
1381                    math.h \
1382                    mntent.h \
1383                    ncurses.h \
1384                    ncurses/ncurses.h \
1385                    netdb.h \
1386                    netinet/in.h \
1387                    pthread_np.h \
1388                    pwd.h \
1389                    regex.h \
1390                    security/pam_appl.h \
1391                    signal.h \
1392                    stdint.h \
1393                    stdio_ext.h \
1394                    stdlib.h \
1395                    string.h \
1396                    strings.h \
1397                    sys/bitypes.h \
1398                    sys/bswap.h \
1399                    sys/dk.h \
1400                    sys/fcntl.h \
1401                    sys/file.h \
1402                    sys/fs_types.h \
1403                    sys/fstyp.h \
1404                    sys/ioctl.h \
1405                    sys/ipc.h \
1406                    sys/lockf.h \
1407                    sys/map.h \
1408                    sys/mount.h \
1409                    sys/mntent.h \
1410                    sys/mnttab.h \
1411                    sys/pag.h \
1412                    sys/param.h \
1413                    sys/resource.h \
1414                    sys/select.h \
1415                    sys/statfs.h \
1416                    sys/statvfs.h \
1417                    sys/socket.h \
1418                    sys/sysctl.h \
1419                    sys/time.h \
1420                    sys/types.h \
1421                    sys/uio.h \
1422                    sys/un.h \
1423                    sys/vfs.h \
1424                    syslog.h \
1425                    termios.h \
1426                    time.h \
1427                    ucontext.h \
1428                    unistd.h \
1429                    windows.h \
1430                 ])
1431
1432 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1433 #ifdef HAVE_NETINET_IN_H
1434 # include <netinet/in.h>
1435 #endif])
1436
1437 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1438 #ifdef HAVE_SYS_SOCKET_H
1439 # include <sys/socket.h>
1440 #endif])
1441
1442 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1443 #ifdef HAVE_SYS_SOCKET_H
1444 # include <sys/socket.h>
1445 #endif
1446 #ifdef HAVE_NETINET_IN_H
1447 # include <netinet/in.h>
1448 #endif
1449 #ifdef HAVE_NET_IF_H
1450 # include <net/if.h>
1451 #endif])
1452
1453 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1454 #ifdef HAVE_SECURITY_PAM_APPL_H
1455 # include <security/pam_appl.h>
1456 #endif])
1457
1458 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1459
1460 AC_CHECK_TYPES([fsblkcnt_t],,,[
1461 #include <sys/types.h>
1462 #ifdef HAVE_SYS_BITYPES_H
1463 #include <sys/bitypes.h>
1464 #endif
1465 #ifdef HAVE_SYS_STATFS_H
1466 #include <sys/statfs.h>
1467 #endif
1468 #ifdef HAVE_SYS_STATVFS_H
1469 #include <sys/statvfs.h>
1470 #endif
1471 ])
1472
1473 dnl see what struct stat has for timestamps
1474 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1475
1476 dnl check for curses-lib
1477 AS_IF([test "x$enable_gtx" != "xno"],
1478       [save_LIBS=$LIBS
1479       AC_CHECK_LIB( [ncurses], [setupterm],
1480       [LIB_curses=-lncurses],
1481         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1482           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1483       ])
1484       LIBS=$save_LIBS
1485       AC_SUBST(LIB_curses)])
1486         
1487 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1488
1489 if test "$enable_debug_locks" = yes; then
1490         AC_DEFINE(OPR_DEBUG_LOCKS, 1, [turn on lock debugging in opr])
1491 fi
1492
1493 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1494         HAVE_PAM="YES"
1495 else
1496         HAVE_PAM="no"
1497 fi
1498 AC_SUBST(HAVE_PAM)
1499
1500 if test "$enable_login" = yes; then
1501         BUILD_LOGIN="yes"
1502 else
1503         BUILD_LOGIN="no"
1504 fi
1505 AC_SUBST(BUILD_LOGIN)
1506
1507 if test "$enable_uss" = yes; then
1508         BUILD_USS="yes"
1509 else
1510         BUILD_USS="no"
1511 fi
1512 AC_SUBST(BUILD_USS)
1513
1514 if test "$enable_kauth" = yes; then
1515         INSTALL_KAUTH="yes"
1516 else
1517         INSTALL_KAUTH="no"
1518 fi
1519 AC_SUBST(INSTALL_KAUTH)
1520
1521 AC_CHECK_FUNCS([ \
1522         arc4random \
1523         fcntl \
1524         fseeko64 \
1525         ftello64 \
1526         getcwd \
1527         getegid \
1528         geteuid \
1529         getgid \
1530         getuid \
1531         getrlimit \
1532         issetugid \
1533         mkstemp \
1534         poll \
1535         pread \
1536         preadv \
1537         preadv64 \
1538         pwrite \
1539         pwritev \
1540         pwritev64 \
1541         regcomp \
1542         regerror \
1543         regexec \
1544         setitimer \
1545         setvbuf \
1546         sigaction \
1547         strcasestr \
1548         strerror \
1549         sysconf \
1550         sysctl \
1551         tdestroy \
1552         timegm \
1553 ])
1554
1555 OPENAFS_ROKEN()
1556 OPENAFS_HCRYPTO()
1557 OPENAFS_C_ATTRIBUTE()
1558
1559 dnl Functions that Heimdal's libroken provides, but that we
1560 dnl haven't found a need for yet, and so haven't imported
1561 AC_CHECK_FUNCS([ \
1562         chown \
1563         fchown \
1564         gethostname \
1565         lstat \
1566         inet_aton \
1567         inet_ntop \
1568         inet_pton \
1569         putenv \
1570         readv \
1571         setenv \
1572         strdup \
1573         strftime \
1574         strndup \
1575         strsep \
1576         unsetenv \
1577 ])
1578
1579 dnl Functions that are in objects that we always build from libroken
1580 AC_CHECK_FUNCS([ \
1581         asprintf \
1582         asnprintf \
1583         vasprintf \
1584         vasnprintf \
1585         vsnprintf \
1586         snprintf \
1587 ])
1588
1589 dnl Functions that we're going to try and get from libroken
1590 AC_REPLACE_FUNCS([ \
1591         daemon \
1592         ecalloc \
1593         emalloc \
1594         erealloc \
1595         err \
1596         errx \
1597         flock \
1598         freeaddrinfo \
1599         gai_strerror \
1600         getaddrinfo \
1601         getdtablesize \
1602         getnameinfo \
1603         getopt \
1604         getprogname \
1605         gettimeofday \
1606         localtime_r \
1607         mkstemp \
1608         setenv \
1609         setprogname \
1610         strcasecmp \
1611         strlcat \
1612         strnlen \
1613         strlcpy \
1614         strsep \
1615         tdelete \
1616         tfind \
1617         tsearch \
1618         twalk \
1619         unsetenv \
1620         verr \
1621         verrx \
1622         vsyslog \
1623         vwarn \
1624         vwarnx \
1625         warn \
1626         warnx \
1627 ])
1628
1629 dnl Headers that we're going to try and get from libroken
1630 AC_CHECK_HEADERS([ \
1631         err.h \
1632         search.h \
1633 ])
1634
1635 AC_CHECK_DECLS([h_errno], [], [], [
1636 #include <sys/types.h>
1637 #ifdef HAVE_NETDB_H
1638 #include <netdb.h>
1639 #endif
1640 ])
1641
1642 AC_HEADER_TIME
1643
1644 ROKEN_HEADERS=
1645 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1646       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1647       [])
1648 AC_SUBST(ROKEN_HEADERS)
1649
1650 dnl Stuff that's harder ...
1651 AC_MSG_CHECKING([for bswap16])
1652 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1653 #ifdef HAVE_SYS_TYPES_H
1654 #include <sys/types.h>
1655 #endif
1656 #ifdef HAVE_SYS_BSWAP_H
1657 #include <sys/bswap.h>
1658 #endif
1659 ],
1660 [short a, b; b = bswap16(a); ])],
1661 [AC_MSG_RESULT(yes)
1662  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1663 ],
1664 [AC_MSG_RESULT(no)])
1665
1666 AC_MSG_CHECKING([for bswap32])
1667 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1668 #include <sys/types.h>
1669 #endif
1670 #ifdef HAVE_SYS_BSWAP_H
1671 #include <sys/bswap.h>
1672 #endif
1673 ],
1674 [int a, b; b = bswap32(a); ])],
1675 [AC_MSG_RESULT(yes)
1676  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1677 ],
1678 [AC_MSG_RESULT(no)])
1679
1680 case $AFS_SYSNAME in
1681 *hp_ux* | *hpux*)
1682    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1683    ;;
1684 *)
1685    AC_MSG_CHECKING([for positional I/O])
1686    if test "$ac_cv_func_pread" = "yes" && \
1687            test "$ac_cv_func_pwrite" = "yes"; then
1688       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1689       AC_MSG_RESULT(yes)
1690    else
1691      AC_MSG_RESULT(no)
1692    fi
1693    AC_MSG_CHECKING([for vectored positional I/O])
1694    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1695                "$ac_cv_func_pwritev" = "yes" -a \
1696                "$ac_cv_func_preadv64" = "yes" -a \
1697                "$ac_cv_func_pwritev64" = "yes"],
1698          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1699           AC_MSG_RESULT(yes)],
1700          [AC_MSG_RESULT(no)])
1701    ;;
1702 esac
1703
1704 AC_MSG_CHECKING([for POSIX regex library])
1705 if test "$ac_cv_header_regex_h" = "yes" && \
1706         test "$ac_cv_func_regcomp" = "yes" && \
1707         test "$ac_cv_func_regexec" = "yes" && \
1708         test "$ac_cv_func_regerror" = "yes"; then
1709     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1710     AC_MSG_RESULT(yes)
1711 else
1712     AC_MSG_RESULT(no)
1713 fi
1714
1715 dnl Look for "non-portable" pthreads functions.
1716 save_LIBS="$LIBS"
1717 LIBS="$LIBS $PTHREAD_LIBS"
1718 AC_CHECK_FUNCS([ \
1719         pthread_set_name_np \
1720         pthread_setname_np \
1721 ])
1722
1723 dnl Sadly, there are three different versions of pthread_setname_np.
1724 dnl Try to cater for all of them.
1725 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1726     AC_MSG_CHECKING([for signature of pthread_setname_np])
1727     AC_TRY_COMPILE([
1728 #include <pthread.h>
1729 #ifdef HAVE_PTHREAD_NP_H
1730 #include <pthread_np.h>
1731 #endif
1732 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1733         AC_MSG_RESULT([three arguments])
1734         pthread_setname_np_args=3], [
1735         AC_TRY_COMPILE([
1736 #include <pthread.h>
1737 #ifdef HAVE_PTHREAD_NP_H
1738 #include <pthread_np.h>
1739 #endif
1740 ], [pthread_setname_np(pthread_self(), "test")], [
1741             AC_MSG_RESULT([two arguments])
1742             pthread_setname_np_args=2], [
1743             AC_TRY_COMPILE([
1744 #include <pthread.h>
1745 #ifdef HAVE_PTHREAD_NP_H
1746 #include <pthread_np.h>
1747 #endif
1748 ], [pthread_setname_np("test")], [
1749                 AC_MSG_RESULT([one argument])
1750                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1751 ])
1752 ])
1753 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1754 fi
1755 LIBS="$save_LIBS"
1756
1757 openafs_cv_saved_CFLAGS="$CFLAGS"
1758 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1759
1760 AC_TYPE_SIGNAL
1761 OPENAFS_RETSIGTYPE
1762 AC_CHECK_SIZEOF(void *)
1763 AC_CHECK_SIZEOF(unsigned long long)
1764 AC_CHECK_SIZEOF(unsigned long)
1765 AC_CHECK_SIZEOF(unsigned int)
1766 AC_TYPE_INTPTR_T
1767 AC_TYPE_UINTPTR_T
1768 AC_TYPE_SSIZE_T
1769 AC_CHECK_TYPE([sig_atomic_t],[],
1770     [AC_DEFINE([sig_atomic_t], [int],
1771         [Define to int if <signal.h> does not define.])],
1772 [#include <sys/types.h>
1773 #include <signal.h>])
1774 AC_CHECK_TYPE([socklen_t],[],
1775     [AC_DEFINE([socklen_t], [int],
1776         [Define to int if <sys/socket.h> does not define.])],
1777 [#include <sys/types.h>
1778 #include <sys/socket.h>])
1779 AC_CHECK_TYPES(off64_t)
1780 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1781 AC_CHECK_TYPES([struct winsize], [], [], [
1782 #ifdef HAVE_TERMIOS_H
1783 # include <termios.h>
1784 #else
1785 # include <sys/termios.h>
1786 #endif
1787 #include <sys/ioctl.h>])
1788 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1789                 struct sockaddr_storage],
1790                [], [], [
1791 #include <sys/types.h>
1792 #include <sys/socket.h>
1793 ])
1794 AC_CHECK_TYPES([sa_family_t], [], [], [
1795 #include <sys/types.h>
1796 #include <sys/socket.h>
1797 ])
1798 AC_CHECK_TYPES([struct addrinfo], [], [], [
1799 #include <sys/types.h>
1800 #ifdef HAVE_NETDB_H
1801 #include <netdb.h>
1802 #endif
1803 ])
1804 AC_CHECK_TYPES([long long], [], [], [])
1805
1806 AC_SIZEOF_TYPE(long)
1807
1808 CFLAGS="$openafs_cv_saved_CFLAGS"
1809
1810 RRA_HEADER_PAM_CONST
1811
1812
1813 dnl Directory PATH handling
1814 if test "x$enable_transarc_paths" = "xyes"  ; then 
1815     afsconfdir=${afsconfdir=/usr/afs/etc}
1816     viceetcdir=${viceetcdir=/usr/vice/etc}
1817     afskerneldir=${afskerneldir=${viceetcdir}}
1818     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1819     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1820     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1821     afsdbdir=${afsdbdir=/usr/afs/db}
1822     afslogsdir=${afslogsdir=/usr/afs/logs}
1823     afslocaldir=${afslocaldir=/usr/afs/local}
1824     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1825     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1826     afsdatadir=${afsdatadir=/usr/vice/etc}
1827 else 
1828     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1829     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1830     afskerneldir=${afskerneldir='${libdir}/openafs'}
1831     afssrvbindir=${afssrvbindir='${bindir}'}
1832     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1833     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1834     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1835     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1836     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1837     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1838     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1839     afsdatadir=${afsdatadir='${datadir}/openafs'}
1840 fi
1841 AC_SUBST(afsconfdir)
1842 AC_SUBST(viceetcdir)
1843 AC_SUBST(afskerneldir)
1844 AC_SUBST(afssrvbindir)
1845 AC_SUBST(afssrvsbindir)
1846 AC_SUBST(afssrvlibexecdir)
1847 AC_SUBST(afsdbdir)
1848 AC_SUBST(afslogsdir)
1849 AC_SUBST(afslocaldir)
1850 AC_SUBST(afsbackupdir)
1851 AC_SUBST(afsbosconfigdir)
1852 AC_SUBST(afsdatadir)
1853
1854 if test "x$enable_kernel_module" = "xyes"; then
1855 ENABLE_KERNEL_MODULE=libafs
1856 fi
1857
1858 if test "x$enable_pthreaded_ubik" = "xyes"; then
1859 ENABLE_PTHREADED_UBIK=yes
1860 fi
1861
1862 AC_SUBST(VFSCK)
1863 AC_SUBST(AFS_SYSNAME)
1864 AC_SUBST(AFS_PARAM_COMMON)
1865 AC_SUBST(ENABLE_KERNEL_MODULE)
1866 AC_SUBST(ENABLE_PTHREADED_UBIK)
1867 AC_SUBST(LIB_AFSDB)
1868 AC_SUBST(LINUX_KERNEL_PATH)
1869 AC_SUBST(LINUX_KERNEL_BUILD)
1870 AC_SUBST(HOST_CPU)
1871 AC_SUBST(BSD_KERNEL_PATH)
1872 AC_SUBST(BSD_KERNEL_BUILD)
1873 AC_SUBST(LINUX_VERSION)
1874 AC_SUBST(MKAFS_OSTYPE)
1875 AC_SUBST(TOP_OBJDIR)
1876 AC_SUBST(TOP_SRCDIR)
1877 AC_SUBST(TOP_INCDIR)
1878 AC_SUBST(TOP_LIBDIR)
1879 AC_SUBST(DEST)
1880 AC_SUBST(DARWIN_INFOFILE)
1881 AC_SUBST(IRIX_BUILD_IP35)
1882 AC_SUBST(HTML_XSL)
1883 AC_SUBST(XSLTPROC)
1884 AC_SUBST(DOCBOOK2PDF)
1885 AC_SUBST(DOCBOOK_STYLESHEETS)
1886
1887 OPENAFS_FUSE
1888 OPENAFS_SWIG
1889
1890 TOP_SRCDIR="${srcdir}/src"
1891 dnl
1892 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1893 dnl
1894 case $TOP_SRCDIR in
1895         /*)
1896                 ;;
1897         *)
1898                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1899                 ;;
1900 esac
1901
1902 TOP_OBJDIR="${SRCDIR_PARENT}"
1903 TOP_INCDIR="${SRCDIR_PARENT}/include"
1904 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1905 if test "${DEST}x" = "x"; then
1906         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1907 fi
1908
1909 if test "x$with_crosstools_dir" != "x"; then
1910         if test -f "$with_crosstools_dir/rxgen" -a -f "$with_crosstools_dir/compile_et" -a -f "$with_crosstools_dir/config"; then
1911                 COMPILE_ET_PATH=$with_crosstools_dir/compile_et
1912                 CONFIGTOOL_PATH=$with_crosstools_dir/config
1913                 RXGEN_PATH=$with_crosstools_dir/rxgen
1914         else
1915                 AC_MSG_ERROR(Tools not found in $with_crosstools_dir)
1916                 exit 1
1917         fi
1918 else
1919         COMPILE_ET_PATH="${SRCDIR_PARENT}/src/comerr/compile_et"
1920         CONFIGTOOL_PATH="${SRCDIR_PARENT}/src/config/config"
1921         RXGEN_PATH="${SRCDIR_PARENT}/src/rxgen/rxgen"
1922 fi
1923 AC_SUBST(COMPILE_ET_PATH)
1924 AC_SUBST(CONFIGTOOL_PATH)
1925 AC_SUBST(RXGEN_PATH)
1926
1927 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1928 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1929 AC_SUBST(HELPER_SPLINT)
1930 AC_SUBST(HELPER_SPLINTCFG)
1931
1932 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1933
1934 dnl Check to see if crypt lives in a different library
1935 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1936 AC_SUBST(LIB_crypt)
1937
1938 dnl Check to see if the compiler support labels in structs
1939 AC_MSG_CHECKING(for label support in structs)
1940 AC_TRY_COMPILE([], [
1941 extern void osi_UFSOpen(void);
1942 struct labeltest {
1943    void (*open) (void);
1944 };
1945 struct labeltest struct_labeltest = {
1946    .open       = osi_UFSOpen,
1947 }
1948 ],
1949 [AC_MSG_RESULT(yes)
1950  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1951 ],
1952 [AC_MSG_RESULT(no)
1953 ])
1954
1955 AC_MSG_CHECKING([checking for dirfd])
1956 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1957 #ifdef HAVE_DIRENT_H
1958 #include <dirent.h>
1959 #endif
1960 ]],
1961         [[DIR *d = 0; dirfd(d);]])],
1962         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1963 if test "$ac_rk_have_dirfd" = "yes" ; then
1964         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1965 fi
1966 AC_MSG_RESULT($ac_rk_have_dirfd)
1967
1968 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1969 #ifdef HAVE_DIRENT_H
1970 #include <dirent.h>
1971 #endif])
1972
1973 OPENAFS_HAVE_STRUCT_FIELD(struct rusage, ru_idrss,
1974 [#ifdef HAVE_SYS_RESOURCE_H
1975 #include <sys/resource.h>
1976 #endif])
1977
1978 dnl Check for UUID library
1979 AC_CHECK_HEADERS([uuid/uuid.h])
1980 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1981 AC_CHECK_FUNCS([uuid_generate])
1982 ])
1983
1984