f83569dbbc8495649a0eb05fdc5191586801c2ac
[openafs.git] / acinclude.m4
1 dnl This file contains the common configuration code which would
2 dnl otherwise be duplicated between configure and configure-libafs.
3 dnl
4 dnl NB: Because this code is a macro, references to positional shell
5 dnl parameters must be done like $[]1 instead of $1
6
7 AC_DEFUN([OPENAFS_CONFIGURE_COMMON],[
8 AH_BOTTOM([
9 #undef HAVE_RES_SEARCH
10 #undef STRUCT_SOCKADDR_HAS_SA_LEN
11 #if !defined(__BIG_ENDIAN__) && !defined(__LITTLE_ENDIAN__)
12 # if ENDIANESS_IN_SYS_PARAM_H
13 #  ifndef KERNEL
14 #   include <sys/types.h>
15 #   include <sys/param.h>
16 #   if BYTE_ORDER == BIG_ENDIAN
17 #   define WORDS_BIGENDIAN 1
18 #   endif
19 #  else
20 #   if defined(AUTOCONF_FOUND_BIGENDIAN)
21 #    define WORDS_BIGENDIAN 1
22 #   else
23 #    undef WORDS_BIGENDIAN
24 #   endif
25 #  endif
26 # else
27 #  if defined(AUTOCONF_FOUND_BIGENDIAN)
28 #   define WORDS_BIGENDIAN 1
29 #  else
30 #   undef WORDS_BIGENDIAN
31 #  endif
32 # endif
33 #else
34 # if defined(__BIG_ENDIAN__)
35 #  define WORDS_BIGENDIAN 1
36 # else
37 #  undef WORDS_BIGENDIAN
38 # endif
39 #endif
40 #ifdef UKERNEL
41 /*
42  * Always use 64-bit file offsets for UKERNEL code. Needed for UKERNEL stuff to
43  * play nice with some other interfaces like FUSE. We technically only would
44  * need to define this when building for such interfaces, but set it always to
45  * try and reduce potential confusion. 
46  */
47 #define _FILE_OFFSET_BITS 64
48 #define AFS_CACHE_VNODE_PATH
49 #endif
50
51 #undef AFS_NAMEI_ENV
52 #undef BITMAP_LATER
53 #undef FAST_RESTART
54 #undef DEFINED_FOR_EACH_PROCESS
55 #undef DEFINED_PREV_TASK
56 #undef EXPORTED_SYS_CALL_TABLE
57 #undef EXPORTED_IA32_SYS_CALL_TABLE
58 #undef IRIX_HAS_MEM_FUNCS
59 #undef RECALC_SIGPENDING_TAKES_VOID
60 #undef STRUCT_FS_HAS_FS_ROLLED
61 #undef ssize_t
62 /* glue for RedHat kernel bug */
63 #undef ENABLE_REDHAT_BUILDSYS
64 #if defined(ENABLE_REDHAT_BUILDSYS) && defined(KERNEL) && defined(REDHAT_FIX)
65 #include "redhat-fix.h"
66 #endif])
67
68 AC_CANONICAL_HOST
69 SRCDIR_PARENT=`pwd`
70
71 #BOZO_SAVE_CORES pam
72
73 dnl System identity.
74 AC_ARG_WITH([afs-sysname],
75     [AS_HELP_STRING([--with-afs-sysname=sys], [use sys for the afs sysname])])
76
77 dnl General feature options.
78 AC_ARG_ENABLE([pam],
79     [AS_HELP_STRING([--disable-pam], [disable PAM support])],
80     ,
81     [enable_pam="yes"])
82 AC_ARG_ENABLE([gtx],
83     AS_HELP_STRING([--disable-gtx], [disable gtx curses-based terminal tools]))
84 AC_ARG_ENABLE([uss],
85     AS_HELP_STRING([--disable-uss], [disable uss bulk creation tool]))
86 AC_ARG_ENABLE([namei-fileserver],
87     [AS_HELP_STRING([--enable-namei-fileserver],
88         [force compilation of namei fileserver in preference to inode
89          fileserver])],
90     , 
91     [enable_namei_fileserver="default"])
92 AC_ARG_ENABLE([supergroups],
93     [AS_HELP_STRING([--enable-supergroups],
94         [enable support for nested pts groups])],
95     , 
96     [enable_supergroups="no"])
97 AC_ARG_ENABLE([bitmap-later],
98     [AS_HELP_STRING([--enable-bitmap-later],
99         [enable fast startup of file server by not reading bitmap till
100          needed])],
101     , 
102     [enable_bitmap_later="no"])
103 AC_ARG_ENABLE([unix-sockets],
104     [AS_HELP_STRING([--disable-unix-sockets],
105         [disable use of unix domain sockets for fssync (defaults to enabled)])],
106     ,
107     [enable_unix_sockets="yes"])
108 AC_ARG_ENABLE([tivoli-tsm],
109     [AS_HELP_STRING([--enable-tivoli-tsm],
110         [enable use of the Tivoli TSM API libraries for butc support])],
111     , 
112     [enable_tivoli_tsm="no"])
113 AC_ARG_ENABLE([pthreaded-ubik],
114     [AS_HELP_STRING([--enable-pthreaded-ubik],
115         [enable installation of pthreaded ubik applications (defaults to
116          disabled)])],
117     ,
118     [enable_pthreaded_ubik="no"])
119
120 dnl Kernel module build options.
121 AC_ARG_WITH([linux-kernel-headers],
122     [AS_HELP_STRING([--with-linux-kernel-headers=path],
123         [use the kernel headers found at path (optional, defaults to
124          /usr/src/linux-2.4, then /usr/src/linux)])])
125 AC_ARG_WITH([linux-kernel-build],
126     [AS_HELP_STRING([--with-linux-kernel-build=path],
127         [use the kernel build found at path(optional, defaults to 
128         /usr/src/linux-2.4, then /usr/src/linux)])])
129 AC_ARG_WITH([bsd-kernel-headers],
130     [AS_HELP_STRING([--with-bsd-kernel-headers=path],
131         [use the kernel headers found at path (optional, defaults to
132          /usr/src/sys)])])
133 AC_ARG_WITH([bsd-kernel-build],
134     [AS_HELP_STRING([--with-bsd-kernel-build=path], 
135         [use the kernel build found at path (optional, defaults to
136          KSRC/i386/compile/GENERIC)])])
137 AC_ARG_WITH([linux-kernel-packaging],
138     [AS_HELP_STRING([--with-linux-kernel-packaging],
139         [use standard naming conventions to aid Linux kernel build packaging
140          (disables MPS, sets the kernel module name to openafs.ko, and
141          installs kernel modules into the standard Linux location)])],
142     [AC_SUBST(LINUX_KERNEL_PACKAGING, "yes")
143      AC_SUBST(LINUX_LIBAFS_NAME, "openafs")],
144     [AC_SUBST(LINUX_LIBAFS_NAME, "libafs")])
145 AC_ARG_ENABLE([kernel-module],
146     [AS_HELP_STRING([--disable-kernel-module],
147         [disable compilation of the kernel module (defaults to enabled)])],
148     , 
149     [enable_kernel_module="yes"])
150 AC_ARG_ENABLE([redhat-buildsys],
151     [AS_HELP_STRING([--enable-redhat-buildsys],
152         [enable compilation of the redhat build system kernel (defaults to
153          disabled)])],
154     ,
155     [enable_redhat_buildsys="no"])
156
157 dnl Installation locations.
158 AC_ARG_ENABLE([transarc-paths],
159     [AS_HELP_STRING([--enable-transarc-paths],
160         [use Transarc style paths like /usr/afs and /usr/vice])],
161     , 
162     [enable_transarc_paths="no"])
163
164 dnl Optimization and debugging flags.
165 AC_ARG_ENABLE([strip-binaries],
166     [AS_HELP_STRING([--disable-strip-binaries],
167         [disable stripping of symbol information from binaries (defaults to
168          enabled)])],
169     ,
170     [enable_strip_binaries="maybe"])
171 AC_ARG_ENABLE([debug],
172     [AS_HELP_STRING([--enable-debug],
173         [enable compilation of the user space code with debugging information
174          (defaults to disabled)])],
175     , 
176     [enable_debug="no"])
177 AC_ARG_ENABLE([optimize],
178     [AS_HELP_STRING([--disable-optimize],
179         [disable optimization for compilation of the user space code (defaults
180          to enabled)])],
181     , 
182     [enable_optimize="yes"])
183 AC_ARG_ENABLE([warnings],
184     [AS_HELP_STRING([--enable-warnings],
185         [enable compilation warnings when building with gcc (defaults to
186          disabled)])],
187     ,
188     [enable_warnings="no"])
189 AC_ARG_ENABLE([checking],
190     [AS_HELP_STRING([--enable-checking],
191         [turn compilation warnings into errors when building with gcc (defaults
192          to disabled)])],
193     [enable_checking="$enableval"],
194     [enable_checking="no"])
195 AC_ARG_ENABLE([debug-kernel],
196     [AS_HELP_STRING([--enable-debug-kernel],
197         [enable compilation of the kernel module with debugging information
198          (defaults to disabled)])],
199     ,
200     [enable_debug_kernel="no"])
201 AC_ARG_ENABLE([optimize-kernel],
202     [AS_HELP_STRING([--disable-optimize-kernel],
203         [disable compilation of the kernel module with optimization (defaults
204          based on platform)])],
205     , 
206     [enable_optimize_kernel=""])
207 AC_ARG_ENABLE([debug-lwp],
208     [AS_HELP_STRING([--enable-debug-lwp],
209         [enable compilation of the LWP code with debugging information
210          (defaults to disabled)])],
211     ,
212     [enable_debug_lwp="no"])
213 AC_ARG_ENABLE([optimize-lwp],
214     [AS_HELP_STRING([--disable-optimize-lwp],
215         [disable optimization for compilation of the LWP code (defaults to
216          enabled)])],
217     ,
218     [enable_optimize_lwp="yes"])
219 AC_ARG_ENABLE([debug-pam],
220     [AS_HELP_STRING([--enable-debug-pam],
221         [enable compilation of the PAM code with debugging information
222          (defaults to disabled)])],
223     ,
224     [enable_debug_pam="no"])
225 AC_ARG_ENABLE([optimize-pam],
226     [AS_HELP_STRING([--disable-optimize-pam],
227         [disable optimization for compilation of the PAM code (defaults to
228          enabled)])],
229     ,
230     [enable_optimize_pam="yes"])
231 AC_ARG_ENABLE([linux-syscall-probing],
232     [AS_HELP_STRING([--enable-linux-syscall-probing],
233         [enable Linux syscall probing (defaults to autodetect)])],
234     ,
235     [enable_linux_syscall_probing="maybe"])
236     
237 AC_ARG_WITH([xslt-processor],
238         AS_HELP_STRING([--with-xslt-processor=ARG],
239         [which XSLT processor to use (possible choices are: libxslt, saxon, xalan-j, xsltproc)]),
240         [XSLTPROC="$withval"],
241         AC_CHECK_PROGS([XSLTPROC], [libxslt saxon xalan-j xsltproc], [echo]))
242
243 AC_ARG_WITH([html-xsl], 
244         AS_HELP_STRING([--with-html-xsl],
245         [build HTML documentation using this stylesheet (default is html/chunk.dsl; specify either html/chunk.xsl or html/docbook.xsl)]),
246         [HTML_XSL="$withval"],
247         [HTML_XSL="html/chunk.xsl"])
248
249 AC_ARG_WITH([docbook2pdf],
250         AS_HELP_STRING([--with-docbook2pdf=ARG],
251         [which Docbook to PDF utility to use (possible choices are: fop, dblatex, docbook2pdf)]),
252         [DOCBOOK2PDF="$withval"],
253         AC_CHECK_PROGS([DOCBOOK2PDF], [fop dblatex docbook2pdf], [echo]))
254
255 AC_ARG_WITH([docbook-stylesheets],
256         AS_HELP_STRING([--with-docbook-stylesheets=ARG],
257         [location of DocBook stylesheets (default is to search a set of likely paths)]),
258         [DOCBOOK_STYLESHEETS="$withval"],
259         OPENAFS_SEARCH_DIRLIST([DOCBOOK_STYLESHEETS], [/usr/share/xml/docbook/stylesheet/nwalsh/current /usr/share/xml/docbook/stylesheet/nwalsh /usr/share/xml/docbook/xsl-stylesheets /usr/share/sgml/docbook/docbook-xsl-stylesheets /usr/share/sgml/docbook/xsl-stylesheets /usr/share/docbook-xsl /usr/share/sgml/docbkxsl /usr/local/share/xsl/docbook /sw/share/xml/xsl/docbook-xsl /opt/local/share/xsl/docbook-xsl], [$HTML_XSL])
260         if test "x$DOCBOOK_STYLESHEETS" = "x"; then
261                 AC_WARN([Docbook stylesheets not found; some documentation can't be built])
262         fi)
263
264 enable_login="no"
265
266 dnl Check whether kindlegen exists.  If not, we'll suppress that part of the
267 dnl documentation build.
268 AC_CHECK_PROGS([KINDLEGEN], [kindlegen])
269
270 dnl weird ass systems
271 dnl AC_AIX
272 AC_ISC_POSIX
273 dnl AC_MINIX
274
275 dnl Various compiler setup.
276 AC_TYPE_PID_T
277 AC_TYPE_SIZE_T
278
279 dnl Checks for programs.
280 AC_PROG_INSTALL
281 AC_PROG_LN_S
282 AC_PROG_RANLIB
283 AC_PROG_YACC
284 AM_PROG_LEX
285 dnl if we are flex, be lex-compatible
286 OPENAFS_LEX_IS_FLEX([AC_SUBST([LEX], ["$LEX -l"])])
287
288 OPENAFS_FORCE_ABS_INSTALL
289 OPENAFS_CHECK_BIGENDIAN
290 OPENAFS_PRINTF_TAKES_Z_LEN
291
292 AC_MSG_CHECKING(your OS)
293 system=$host
294 case $system in
295         *-linux*)
296
297                 MKAFS_OSTYPE=LINUX
298                 if test "x$enable_redhat_buildsys" = "xyes"; then
299                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS, 1, [define if you have redhat buildsystem])
300                 fi
301                 if test "x$enable_kernel_module" = "xyes"; then
302                  if test "x$with_linux_kernel_headers" != "x"; then
303                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
304                  else
305                    LINUX_KERNEL_PATH="/lib/modules/`uname -r`/source"
306                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
307                      LINUX_KERNEL_PATH="/lib/modules/`uname -r`/build"
308                    fi
309                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
310                      LINUX_KERNEL_PATH="/usr/src/linux-2.4"
311                    fi
312                    if test ! -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
313                      LINUX_KERNEL_PATH="/usr/src/linux"
314                    fi
315                  fi
316                  if test "x$with_linux_kernel_build" != "x"; then
317                          LINUX_KERNEL_BUILD="$with_linux_kernel_build"
318                  else
319                    LINUX_KERNEL_BUILD=$LINUX_KERNEL_PATH
320                  fi
321                  if test -f "$LINUX_KERNEL_BUILD/include/generated/utsrelease.h"; then
322                    linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/generated/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
323                    LINUX_VERSION="$linux_kvers"
324                  else
325                    if test -f "$LINUX_KERNEL_BUILD/include/linux/utsrelease.h"; then
326                      linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/utsrelease.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
327                      LINUX_VERSION="$linux_kvers"
328                    else
329                      if test -f "$LINUX_KERNEL_BUILD/include/linux/version.h"; then
330                        linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
331                        if test "x$linux_kvers" = "x"; then
332                          if test -f "$LINUX_KERNEL_BUILD/include/linux/version-up.h"; then
333                            linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_BUILD/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -n 1`
334                            if test "x$linux_kvers" = "x"; then
335                              AC_MSG_ERROR(Linux headers lack version definition [2])
336                              exit 1
337                            else
338                              LINUX_VERSION="$linux_kvers"
339                            fi
340                          else
341                            AC_MSG_ERROR(Linux headers lack version definition)
342                            exit 1
343                          fi
344                        else
345                          LINUX_VERSION="$linux_kvers"
346                        fi
347                      else
348                        enable_kernel_module="no"
349                      fi
350                    fi
351                  fi
352                  if test ! -f "$LINUX_KERNEL_BUILD/include/generated/autoconf.h" &&
353                     test ! -f "$LINUX_KERNEL_BUILD/include/linux/autoconf.h"; then
354                      enable_kernel_module="no"
355                  fi
356                  if test "x$enable_kernel_module" = "xno"; then
357                   if test "x$with_linux_kernel_headers" != "x"; then
358                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
359                    exit 1
360                   else
361                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
362                   fi
363                  fi
364                  dnl do we need to determine SUBARCH from autoconf.h
365                  SUBARCH=default
366                 fi
367                 AC_MSG_RESULT(linux)
368                 if test "x$enable_kernel_module" = "xyes"; then
369                  case "$LINUX_VERSION" in
370                   2.2.*) AFS_SYSKVERS=22 ;;
371                   2.4.*) AFS_SYSKVERS=24 ;;
372                   2.6.* | 3.*) AFS_SYSKVERS=26 ;;
373                   *) AC_MSG_ERROR(Couldn't guess your Linux version [2]) ;;
374                  esac
375                 fi
376                 ;;
377         *-solaris*)
378                 MKAFS_OSTYPE=SOLARIS
379                 AC_MSG_RESULT(sun4)
380                 AC_PATH_PROG(SOLARISCC, [cc], ,
381                     [/opt/SUNWspro/bin:/opt/SunStudioExpress/bin:/opt/solarisstudio12.3/bin:/opt/solstudio12.2/bin:/opt/sunstudio12.1/bin])
382                 if test "x$SOLARISCC" = "x" ; then
383                     AC_MSG_FAILURE(Could not find the solaris cc program.  Please define the environment variable SOLARISCC to specify the path.)
384                 fi
385                 SOLARIS_UFSVFS_HAS_DQRWLOCK
386                 SOLARIS_FS_HAS_FS_ROLLED
387                 SOLARIS_SOLOOKUP_TAKES_SOCKPARAMS
388                 ;;
389         *-sunos*)
390                 MKAFS_OSTYPE=SUNOS
391                 enable_kernel_module=no
392                 AC_MSG_RESULT(sun4)
393                 ;;
394         *-hpux*)
395                 MKAFS_OSTYPE=HPUX
396                 AC_MSG_RESULT(hp_ux)
397                 if test -f "/usr/old/usr/include/ndir.h"; then
398                  AC_DEFINE(HAVE_USR_OLD_USR_INCLUDE_NDIR_H, 1, [define if you have old ndir.h])
399                 fi
400                 ;;
401         *-irix*)
402                 if test -d /usr/include/sys/SN/SN1; then
403                  IRIX_BUILD_IP35="IP35"
404                 fi
405                 MKAFS_OSTYPE=IRIX
406                 AC_MSG_RESULT(sgi)
407                 ;;
408         *-aix*)
409                 MKAFS_OSTYPE=AIX
410                 AC_MSG_RESULT(rs_aix)
411                 ;;
412         arm-*-darwin*)
413                 MKAFS_OSTYPE=DARWIN
414                 AC_MSG_RESULT(arm_darwin)
415                 ;;
416         powerpc-*-darwin*)
417                 MKAFS_OSTYPE=DARWIN
418                 AC_MSG_RESULT(ppc_darwin)
419                 ;;
420         i386-*-darwin*)
421                 MKAFS_OSTYPE=DARWIN
422                 AC_MSG_RESULT(x86_darwin)
423                 ;;
424         x86_64-*-darwin*)
425                 MKAFS_OSTYPE=DARWIN
426                 AC_MSG_RESULT(x86_darwin)
427                 ;;
428         i386-*-freebsd*)
429                 MKAFS_OSTYPE=FBSD
430                 AC_MSG_RESULT(i386_fbsd)
431                 ;;
432         x86_64-*-freebsd*)
433                 MKAFS_OSTYPE=FBSD
434                 AC_MSG_RESULT(amd64_fbsd)
435                 ;;
436         *-netbsd*)
437                 MKAFS_OSTYPE=NBSD
438                 AC_MSG_RESULT(nbsd)
439                 ;;
440         x86_64-*-openbsd*)
441                 MKAFS_OSTYPE=OBSD
442                 AC_MSG_RESULT(amd64_obsd)
443                 ;;
444         i386-*-openbsd*)
445                 MKAFS_OSTYPE=OBSD
446                 AC_MSG_RESULT(i386_obsd)
447                 ;;
448         *-dragonfly*)
449                 MKAFS_OSTYPE=DFBSD
450                 AC_MSG_RESULT(i386_dfbsd)
451                 ;;
452         *)
453                 AC_MSG_RESULT($system)
454                 ;;
455 esac
456
457 if test "x$with_afs_sysname" != "x"; then
458         AFS_SYSNAME="$with_afs_sysname"
459 else
460         AC_MSG_CHECKING(your AFS sysname)
461         case $host in
462                 i?86-*-openbsd?.?)
463                         v=${host#*openbsd}
464                         vM=${v%.*}
465                         vm=${v#*.}
466                         AFS_SYSNAME="i386_obsd${vM}${vm}"
467                         ;;
468                 sparc64-*-openbsd?.?)
469                         v=${host#*openbsd}
470                         vM=${v%.*}
471                         vm=${v#*.}
472                         AFS_SYSNAME="sparc64_obsd${vM}${vm}"
473                         ;;
474                 x86_64-*-openbsd?.?)
475                         v=${host#*openbsd}
476                         vM=${v%.*}
477                         vm=${v#*.}
478                         AFS_SYSNAME="amd64_obsd${vM}${vm}"
479                         ;;
480                 i?86-*-freebsd?.*)
481                         v=${host#*freebsd}
482                         vM=${v%.*}
483                         vm=${v#*.}
484                         AFS_SYSNAME="i386_fbsd_${vM}${vm}"
485                         ;;
486                 x86_64-*-freebsd?.*)
487                         v=${host#*freebsd}
488                         vM=${v%.*}
489                         vm=${v#*.}
490                         AFS_SYSNAME="amd64_fbsd_${vM}${vm}"
491                         ;;
492                 i386-*-dragonfly?.*)
493                         v=${host#*dragonfly}
494                         vM=${v%.*}
495                         vm=${v#*.}
496                         AFS_SYSNAME="i386_dfbsd_${vM}${vm}"
497                         ;;
498                 i?86-*-netbsd*1.6[[M-Z]]*)
499                         AFS_SYSNAME="i386_nbsd20"
500                         ;;
501                 powerpc-*-netbsd*1.6[[M-Z]]*)
502                         AFS_SYSNAME="ppc_nbsd20"
503                         ;;
504                 *-*-netbsd*)
505                         arch=${host%%-unknown*}
506                         arch=$(echo $arch |sed -e 's/x86_64/amd64/g' \
507                                                -e 's/powerpc/ppc/g')
508                         v=${host#*netbsd}
509                         v=${v#*aout}
510                         v=${v#*ecoff}
511                         v=${v#*elf}
512                         vM=${v%%.*}
513                         vM=${vM%.*}
514                         v=${v#*.}
515                         vm=${v%%.*}
516                         vm=${vm%.*}
517                         vm=${vm%%[[_A-Z]]*}
518                         if test $vm -eq 99 ; then
519                                 vM=$((vM+1))
520                         fi
521                         if test $vM -gt 1 ; then
522                                 vm=0
523                         fi
524                         AFS_SYSNAME="${arch}_nbsd${vM}${vm}"
525                         ;;
526                 hppa*-hp-hpux11.0*)
527                         AFS_SYSNAME="hp_ux110"
528                         ;;
529                 hppa*-hp-hpux11.11)
530                         AFS_SYSNAME="hp_ux11i"
531                         ;;
532                 hppa*-hp-hpux11.23)
533                         AFS_SYSNAME="hp_ux1123"
534                         ;;
535                 ia64-hp-hpux11.22)
536                         AFS_SYSNAME="ia64_hpux1122"
537                         ;;
538                 ia64-hp-hpux*)
539                         AFS_SYSNAME="ia64_hpux1123"
540                         ;;
541                 hppa*-hp-hpux10*)
542                         AFS_SYSNAME="hp_ux102"
543                         ;;
544                 powerpc-apple-darwin7*)
545                         AFS_SYSNAME="ppc_darwin_70"
546                         OSXSDK="macosx10.3"
547                         ;;
548                 powerpc-apple-darwin8.*)
549                         AFS_SYSNAME="ppc_darwin_80"
550                         OSXSDK="macosx10.4"
551                         ;;
552                 i386-apple-darwin8.*)
553                         AFS_SYSNAME="x86_darwin_80"
554                         OSXSDK="macosx10.4"
555                         ;;
556                 powerpc-apple-darwin9.*)
557                         AFS_SYSNAME="ppc_darwin_90"
558                         OSXSDK="macosx10.5"
559                         ;;
560                 i386-apple-darwin9.*)
561                         AFS_SYSNAME="x86_darwin_90"
562                         OSXSDK="macosx10.5"
563                         ;;
564                 i?86-apple-darwin10.*)
565                         AFS_SYSNAME="x86_darwin_100"
566                         OSXSDK="macosx10.6"
567                         ;;
568                 x86_64-apple-darwin10.*)
569                         AFS_SYSNAME="x86_darwin_100"
570                         OSXSDK="macosx10.6"
571                         ;;
572                 arm-apple-darwin10.*)
573                         AFS_SYSNAME="arm_darwin_100"
574                         OSXSDK="iphoneos4.0"
575                         ;;
576                 x86_64-apple-darwin11.*)
577                         AFS_SYSNAME="x86_darwin_110"
578                         OSXSDK="macosx10.7"
579                         ;;
580                 i?86-apple-darwin11.*)
581                         AFS_SYSNAME="x86_darwin_110"
582                         OSXSDK="macosx10.7"
583                         ;;
584                 x86_64-apple-darwin12.*)
585                         AFS_SYSNAME="x86_darwin_120"
586                         OSXSDK="macosx10.8"
587                         ;;
588                 i?86-apple-darwin12.*)
589                         AFS_SYSNAME="x86_darwin_120"
590                         OSXSDK="macosx10.8"
591                         ;;
592                 sparc-sun-solaris2.8)
593                         AFS_SYSNAME="sun4x_58"
594                         ;;
595                 sparc-sun-solaris2.9)
596                         AFS_SYSNAME="sun4x_59"
597                         ;;
598                 sparc-sun-solaris2.10)
599                         AFS_SYSNAME="sun4x_510"
600                         ;;
601                 sparc-sun-solaris2.11)
602                         AFS_SYSNAME="sun4x_511"
603                         ;;
604                 i386-pc-solaris2.8)
605                         AFS_SYSNAME="sunx86_58"
606                         ;;
607                 i386-pc-solaris2.9)
608                         AFS_SYSNAME="sunx86_59"
609                         ;;
610                 i386-pc-solaris2.10)
611                         AFS_SYSNAME="sunx86_510"
612                         ;;
613                 i386-pc-solaris2.11)
614                         AFS_SYSNAME="sunx86_511"
615                         ;;
616                 alpha*-dec-osf4.0*)
617                         AFS_SYSNAME="alpha_dux40"
618                         ;;
619                 alpha*-dec-osf5.0*)
620                         AFS_SYSNAME="alpha_dux50"
621                         ;;
622                 alpha*-dec-osf5.1*)
623                         AFS_SYSNAME="alpha_dux51"
624                         ;;
625                 mips-sgi-irix6.5)
626                         AFS_SYSNAME="sgi_65"
627                         ;;
628                 ia64-*-linux*)
629                         AFS_SYSNAME="ia64_linuxXX"
630                         ;;
631                 powerpc-*-linux*)
632                         AFS_SYSNAME="`/bin/arch`_linuxXX"
633                         ;;
634                 powerpc64-*-linux*)
635                         AFS_SYSNAME="ppc64_linuxXX"
636                         ;;
637                 alpha*-linux*)
638                         AFS_SYSNAME="alpha_linux_XX"
639                         ;;
640                 s390-*-linux*)
641                         AFS_SYSNAME="s390_linuxXX"
642                         ;;
643                 s390x-*-linux*)
644                         AFS_SYSNAME="s390x_linuxXX"
645                         ;;
646                 sparc-*-linux*)
647                         AFS_SYSNAME="`/bin/arch`_linuxXX"
648                         ;;
649                 sparc64-*-linux*)
650                         AFS_SYSNAME="sparc64_linuxXX"
651                         ;;
652                 i?86-*-linux*)
653                         AFS_SYSNAME="i386_linuxXX"
654                         ;;
655                 arm*-linux*)
656                         AFS_SYSNAME="arm_linuxXX"
657                         ;;
658                 parisc-*-linux-gnu|hppa-*-linux-gnu)
659                         AFS_SYSNAME="parisc_linuxXX"
660                         enable_pam="no"
661                         ;;
662                 power*-ibm-aix4.2*)
663                         AFS_SYSNAME="rs_aix42"
664                         enable_pam="no"
665                         ;;
666                 power*-ibm-aix4.3*)
667                         AFS_SYSNAME="rs_aix42"
668                         enable_pam="no"
669                         ;;
670                 power*-ibm-aix5.1*)
671                         AFS_SYSNAME="rs_aix51"
672                         enable_pam="no"
673                         ;;
674                 power*-ibm-aix5.2*)
675                         AFS_SYSNAME="rs_aix52"
676                         enable_pam="no"
677                         ;;
678                 power*-ibm-aix5.3*)
679                         AFS_SYSNAME="rs_aix53"
680                         enable_pam="no"
681                         ;;
682                 power*-ibm-aix6.1*)
683                         AFS_SYSNAME="rs_aix61"
684                         enable_pam="no"
685                         ;;
686                 x86_64-*-linux-gnu)
687                         AFS_SYSNAME="amd64_linuxXX"
688                         enable_pam="yes"
689                         ;;
690                 *)
691                         AC_MSG_ERROR(An AFS sysname is required)
692                         exit 1
693                         ;;
694         esac
695         case $AFS_SYSNAME in
696                 *_linux* | *_umlinux*)
697                         if test "x${AFS_SYSKVERS}" = "x"; then
698                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
699                         fi
700                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
701                         AFS_SYSNAME="$_AFS_SYSNAME"
702                         AC_TRY_KBUILD(
703                          [],
704                          [#ifndef CONFIG_USERMODE
705                           #error not UML
706                           #endif],
707                          ac_cv_linux_is_uml=yes,)
708                         if test "${ac_cv_linux_is_uml}" = yes; then
709                          _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/linux/umlinux/`
710                         fi
711                         AFS_SYSNAME="$_AFS_SYSNAME"
712                         ;;
713         esac
714         AC_MSG_RESULT($AFS_SYSNAME)
715 fi
716
717 case $AFS_SYSNAME in
718         *_darwin*)
719                 AC_CHECK_HEADERS(crt_externs.h)
720                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
721                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
722                 AC_SUBST(OSXSDK)
723                 ;;
724 esac
725
726 dnl Some hosts have a separate common param file they should include.  Figure
727 dnl out if we're on one of them now that we know the sysname.
728 case $AFS_SYSNAME in
729     *_nbsd15)   AFS_PARAM_COMMON=param.nbsd15.h  ;;
730     *_nbsd16)   AFS_PARAM_COMMON=param.nbsd16.h  ;;
731     *_nbsd20)   AFS_PARAM_COMMON=param.nbsd20.h  ;;
732     *_nbsd21)   AFS_PARAM_COMMON=param.nbsd21.h  ;;
733     *_nbsd30)   AFS_PARAM_COMMON=param.nbsd30.h  ;;
734     *_nbsd40)   AFS_PARAM_COMMON=param.nbsd40.h  ;;
735     *_nbsd50)   AFS_PARAM_COMMON=param.nbsd50.h  ;;
736     *_nbsd60)   AFS_PARAM_COMMON=param.nbsd60.h  ;;
737     *_obsd31)   AFS_PARAM_COMMON=param.obsd31.h  ;;
738     *_obsd32)   AFS_PARAM_COMMON=param.obsd32.h  ;;
739     *_obsd33)   AFS_PARAM_COMMON=param.obsd33.h  ;;
740     *_obsd34)   AFS_PARAM_COMMON=param.obsd34.h  ;;
741     *_obsd35)   AFS_PARAM_COMMON=param.obsd35.h  ;;
742     *_obsd36)   AFS_PARAM_COMMON=param.obsd36.h  ;;
743     *_obsd37)   AFS_PARAM_COMMON=param.obsd37.h  ;;
744     *_obsd38)   AFS_PARAM_COMMON=param.obsd38.h  ;;
745     *_obsd39)   AFS_PARAM_COMMON=param.obsd39.h  ;;
746     *_obsd40)   AFS_PARAM_COMMON=param.obsd40.h  ;;
747     *_obsd41)   AFS_PARAM_COMMON=param.obsd41.h  ;;
748     *_obsd42)   AFS_PARAM_COMMON=param.obsd42.h  ;;
749     *_obsd43)   AFS_PARAM_COMMON=param.obsd43.h  ;;
750     *_obsd44)   AFS_PARAM_COMMON=param.obsd44.h  ;;
751     *_obsd45)   AFS_PARAM_COMMON=param.obsd45.h  ;;
752     *_obsd46)   AFS_PARAM_COMMON=param.obsd46.h  ;;
753     *_obsd47)   AFS_PARAM_COMMON=param.obsd47.h  ;;
754     *_obsd48)   AFS_PARAM_COMMON=param.obsd48.h  ;;
755     *_linux22)  AFS_PARAM_COMMON=param.linux22.h ;;
756     *_linux24)  AFS_PARAM_COMMON=param.linux24.h ;;
757     *_linux26)  AFS_PARAM_COMMON=param.linux26.h ;;
758 # Linux alpha adds an extra underscore for no good reason.
759     *_linux_22) AFS_PARAM_COMMON=param.linux22.h ;;
760     *_linux_24) AFS_PARAM_COMMON=param.linux24.h ;;
761     *_linux_26) AFS_PARAM_COMMON=param.linux26.h ;;
762 esac
763
764 OPENAFS_OSCONF
765
766 case $AFS_SYSNAME in *_linux* | *_umlinux*)
767
768                 # Add (sub-) architecture-specific paths needed by conftests
769                 case $AFS_SYSNAME  in
770                         *_umlinux26)
771                                 UMLINUX26_FLAGS="-I$LINUX_KERNEL_PATH/arch/um/include"
772                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/tt/include"
773                                 UMLINUX26_FLAGS="$UMLINUX26_FLAGS -I$LINUX_KERNEL_PATH/arch/um/kernel/skas/include"
774                                 CPPFLAGS="$CPPFLAGS $UMLINUX26_FLAGS"
775                 esac
776
777                 if test "x$enable_kernel_module" = "xyes"; then
778                  if test "x$enable_debug_kernel" = "xno"; then
779                         LINUX_GCC_KOPTS="$LINUX_GCC_KOPTS -fomit-frame-pointer"
780                  fi
781                  OPENAFS_GCC_SUPPORTS_MARCH
782                  AC_SUBST(P5PLUS_KOPTS)
783                  OPENAFS_GCC_NEEDS_NO_STRENGTH_REDUCE
784                  OPENAFS_GCC_NEEDS_NO_STRICT_ALIASING
785                  OPENAFS_GCC_SUPPORTS_NO_COMMON
786                  OPENAFS_GCC_SUPPORTS_PIPE
787                  AC_SUBST(LINUX_GCC_KOPTS)
788
789                  dnl Setup the kernel build environment
790                  LINUX_KBUILD_USES_EXTRA_CFLAGS
791                  LINUX_KERNEL_COMPILE_WORKS
792
793                  dnl Check for header files
794                  AC_CHECK_LINUX_HEADER([config.h])
795                  AC_CHECK_LINUX_HEADER([completion.h])
796                  AC_CHECK_LINUX_HEADER([exportfs.h])
797                  AC_CHECK_LINUX_HEADER([freezer.h])
798                  AC_CHECK_LINUX_HEADER([key-type.h])
799                  AC_CHECK_LINUX_HEADER([semaphore.h])
800                  AC_CHECK_LINUX_HEADER([seq_file.h])
801
802                  dnl Check for structure elements
803                  AC_CHECK_LINUX_STRUCT([address_space_operations],
804                                        [write_begin], [fs.h])
805                  AC_CHECK_LINUX_STRUCT([backing_dev_info], [name],
806                                        [backing-dev.h])
807                  AC_CHECK_LINUX_STRUCT([ctl_table], [ctl_name], [sysctl.h])
808                  AC_CHECK_LINUX_STRUCT([dentry_operations], [d_automount], [dcache.h])
809                  AC_CHECK_LINUX_STRUCT([inode], [i_alloc_sem], [fs.h])
810                  AC_CHECK_LINUX_STRUCT([inode], [i_blkbits], [fs.h])
811                  AC_CHECK_LINUX_STRUCT([inode], [i_blksize], [fs.h])
812                  AC_CHECK_LINUX_STRUCT([inode], [i_mutex], [fs.h])
813                  AC_CHECK_LINUX_STRUCT([inode], [i_security], [fs.h])
814                  AC_CHECK_LINUX_STRUCT([file_operations], [flock], [fs.h])
815                  AC_CHECK_LINUX_STRUCT([file_operations], [sendfile], [fs.h])
816                  AC_CHECK_LINUX_STRUCT([file_system_type], [mount], [fs.h])
817                  AC_CHECK_LINUX_STRUCT([nameidata], [path], [namei.h])
818                  AC_CHECK_LINUX_STRUCT([proc_dir_entry], [owner], [proc_fs.h])
819                  AC_CHECK_LINUX_STRUCT([super_block], [s_bdi], [fs.h])
820                  AC_CHECK_LINUX_STRUCT([super_block], [s_d_op], [fs.h])
821                  AC_CHECK_LINUX_STRUCT([super_operations], [alloc_inode],
822                                        [fs.h])
823                  AC_CHECK_LINUX_STRUCT([super_operations], [evict_inode],
824                                        [fs.h])
825                  AC_CHECK_LINUX_STRUCT([task_struct], [cred], [sched.h])
826                  AC_CHECK_LINUX_STRUCT([task_struct], [exit_state], [sched.h])
827                  AC_CHECK_LINUX_STRUCT([task_struct], [parent], [sched.h])
828                  AC_CHECK_LINUX_STRUCT([task_struct], [real_parent], [sched.h])
829                  AC_CHECK_LINUX_STRUCT([task_struct], [rlim], [sched.h])
830                  AC_CHECK_LINUX_STRUCT([task_struct], [sig], [sched.h])
831                  AC_CHECK_LINUX_STRUCT([task_struct], [sighand], [sched.h])
832                  AC_CHECK_LINUX_STRUCT([task_struct], [sigmask_lock], [sched.h])
833                  AC_CHECK_LINUX_STRUCT([task_struct], [tgid], [sched.h])
834                  AC_CHECK_LINUX_STRUCT([task_struct], [thread_info], [sched.h])
835                  LINUX_SCHED_STRUCT_TASK_STRUCT_HAS_SIGNAL_RLIM
836
837                  dnl Check for typed structure elements
838                  AC_CHECK_LINUX_TYPED_STRUCT([read_descriptor_t],
839                                              [buf], [fs.h])
840
841                  dnl Function existence checks
842
843                  AC_CHECK_LINUX_FUNC([bdi_init],
844                                      [#include <linux/backing-dev.h>],
845                                      [bdi_init(NULL);])
846                  AC_CHECK_LINUX_FUNC([PageChecked],
847                                      [#include <linux/mm.h>
848 #include <linux/page-flags.h>],
849                                      [struct page *_page;
850                                       int bchecked = PageChecked(_page);])
851                  AC_CHECK_LINUX_FUNC([PageFsMisc],
852                                      [#include <linux/mm.h>
853 #include <linux/page-flags.h>],
854                                      [struct page *_page;
855                                       int bchecked = PageFsMisc(_page);])
856                  AC_CHECK_LINUX_FUNC([clear_inode],
857                                      [#include <linux/fs.h>],
858                                      [clear_inode(NULL);])
859                  AC_CHECK_LINUX_FUNC([current_kernel_time],
860                                      [#include <linux/time.h>],
861                                      [struct timespec s;
862                                       s = current_kernel_time();])
863                  AC_CHECK_LINUX_FUNC([d_alloc_anon],
864                                      [#include <linux/fs.h>],
865                                      [d_alloc_anon(NULL);])
866                  AC_CHECK_LINUX_FUNC([d_make_root],
867                                      [#include <linux/fs.h>],
868                                      [d_make_root(NULL);])
869                  AC_CHECK_LINUX_FUNC([do_sync_read],
870                                      [#include <linux/fs.h>],
871                                      [do_sync_read(NULL, NULL, 0, NULL);])
872                  AC_CHECK_LINUX_FUNC([find_task_by_pid],
873                                      [#include <linux/sched.h>],
874                                      [pid_t p; find_task_by_pid(p);])
875                  AC_CHECK_LINUX_FUNC([generic_file_aio_read],
876                                      [#include <linux/fs.h>],
877                                      [generic_file_aio_read(NULL,NULL,0,0);])
878                  AC_CHECK_LINUX_FUNC([grab_cache_page_write_begin],
879                                      [#include <linux/pagemap.h>],
880                                      [grab_cache_page_write_begin(NULL, 0, 0);])
881                  AC_CHECK_LINUX_FUNC([hlist_unhashed],
882                                      [#include <linux/list.h>],
883                                      [hlist_unhashed(0);])
884                  AC_CHECK_LINUX_FUNC([i_size_read],
885                                      [#include <linux/fs.h>],
886                                      [i_size_read(NULL);])
887                  AC_CHECK_LINUX_FUNC([inode_setattr],
888                                      [#include <linux/fs.h>],
889                                      [inode_setattr(NULL, NULL);])
890                  AC_CHECK_LINUX_FUNC([kernel_setsockopt],
891                                      [#include <linux/net.h>],
892                                      [kernel_setsockopt(NULL, 0, 0, NULL, 0);])
893                  AC_CHECK_LINUX_FUNC([page_follow_link],
894                                      [#include <linux/fs.h>],
895                                      [page_follow_link(0,0);])
896                  AC_CHECK_LINUX_FUNC([page_offset],
897                                      [#include <linux/pagemap.h>],
898                                      [page_offset(NULL);])
899                  AC_CHECK_LINUX_FUNC([pagevec_lru_add_file],
900                                      [#include <linux/pagevec.h>],
901                                      [__pagevec_lru_add_file(NULL);])
902                  AC_CHECK_LINUX_FUNC([path_lookup],
903                                      [#include <linux/fs.h>
904                                       #include <linux/namei.h>],
905                                      [path_lookup(NULL, 0, NULL);])
906                  AC_CHECK_LINUX_FUNC([rcu_read_lock],
907                                      [#include <linux/rcupdate.h>],
908                                      [rcu_read_lock();])
909                  AC_CHECK_LINUX_FUNC([set_nlink],
910                                      [#include <linux/fs.h>],
911                                      [set_nlink(NULL, 1);])
912                  AC_CHECK_LINUX_FUNC([splice_direct_to_actor],
913                                      [#include <linux/splice.h>],
914                                      [splice_direct_to_actor(NULL,NULL,NULL);])
915                  AC_CHECK_LINUX_FUNC([svc_addr_in],
916                                      [#include <linux/sunrpc/svc.h>],
917                                      [svc_addr_in(NULL);])
918                  AC_CHECK_LINUX_FUNC([zero_user_segments],
919                                      [#include <linux/highmem.h>],
920                                      [zero_user_segments(NULL, 0, 0, 0, 0);])
921                  AC_CHECK_LINUX_FUNC([noop_fsync],
922                                      [#include <linux/fs.h>],
923                                      [void *address = &noop_fsync; printk("%p\n", address)];)
924                  AC_CHECK_LINUX_FUNC([kthread_run],
925                                      [#include <linux/kernel.h>
926                                       #include <linux/kthread.h>],
927                                      [kthread_run(NULL, NULL, "test");])
928
929                  dnl Consequences - things which get set as a result of the
930                  dnl                above tests
931                  AS_IF([test "x$ac_cv_linux_func_d_alloc_anon" = "xno"],
932                        [AC_DEFINE([AFS_NONFSTRANS], 1,
933                                   [define to disable the nfs translator])])
934
935                  dnl Assorted more complex tests
936                  LINUX_EXPORTS_PROC_ROOT_FS
937                  LINUX_KMEM_CACHE_INIT
938                  LINUX_HAVE_KMEM_CACHE_T
939                  LINUX_KMEM_CACHE_CREATE_TAKES_DTOR
940                  LINUX_KMEM_CACHE_CREATE_CTOR_TAKES_VOID
941                  LINUX_D_PATH_TAKES_STRUCT_PATH
942                  LINUX_NEW_EXPORT_OPS
943                  LINUX_INODE_SETATTR_RETURN_TYPE
944                  LINUX_IOP_I_CREATE_TAKES_NAMEIDATA
945                  LINUX_IOP_I_LOOKUP_TAKES_NAMEIDATA
946                  LINUX_IOP_I_PERMISSION_TAKES_FLAGS
947                  LINUX_IOP_I_PERMISSION_TAKES_NAMEIDATA
948                  LINUX_IOP_I_PUT_LINK_TAKES_COOKIE
949                  LINUX_DOP_D_DELETE_TAKES_CONST
950                  LINUX_DOP_D_REVALIDATE_TAKES_NAMEIDATA
951                  LINUX_FOP_F_FLUSH_TAKES_FL_OWNER_T
952                  LINUX_FOP_F_FSYNC_TAKES_DENTRY
953                  LINUX_FOP_F_FSYNC_TAKES_RANGE
954                  LINUX_AOP_WRITEBACK_CONTROL
955                  LINUX_FS_STRUCT_FOP_HAS_SPLICE
956                  LINUX_KERNEL_POSIX_LOCK_FILE_WAIT_ARG
957                  LINUX_POSIX_TEST_LOCK_RETURNS_CONFLICT
958                  LINUX_POSIX_TEST_LOCK_CONFLICT_ARG
959                  LINUX_KERNEL_SOCK_CREATE
960                  LINUX_EXPORTS_KEY_TYPE_KEYRING
961                  LINUX_NEED_RHCONFIG
962                  LINUX_RECALC_SIGPENDING_ARG_TYPE
963                  LINUX_EXPORTS_TASKLIST_LOCK
964                  LINUX_GET_SB_HAS_STRUCT_VFSMOUNT
965                  LINUX_STATFS_TAKES_DENTRY
966                  LINUX_REFRIGERATOR
967                  LINUX_HAVE_TRY_TO_FREEZE
968                  LINUX_LINUX_KEYRING_SUPPORT
969                  LINUX_KEY_ALLOC_NEEDS_STRUCT_TASK
970                  LINUX_KEY_ALLOC_NEEDS_CRED
971                  LINUX_INIT_WORK_HAS_DATA
972                  LINUX_REGISTER_SYSCTL_TABLE_NOFLAG
973                  LINUX_HAVE_DCACHE_LOCK
974                  LINUX_D_COUNT_IS_INT
975                  LINUX_IOP_MKDIR_TAKES_UMODE_T
976                  LINUX_IOP_CREATE_TAKES_UMODE_T
977                  LINUX_EXPORT_OP_ENCODE_FH_TAKES_INODES
978                  LINUX_KMAP_ATOMIC_TAKES_NO_KM_TYPE
979                  LINUX_DENTRY_OPEN_TAKES_PATH
980                  LINUX_D_ALIAS_IS_HLIST
981                  LINUX_IOP_I_CREATE_TAKES_BOOL
982
983                  dnl If we are guaranteed that keyrings will work - that is
984                  dnl  a) The kernel has keyrings enabled
985                  dnl  b) The code is new enough to give us a key_type_keyring
986                  dnl then we just disable syscall probing unless we've been
987                  dnl told otherwise
988
989                  AS_IF([test "$enable_linux_syscall_probing" = "maybe"],
990                    [AS_IF([test "$ac_cv_linux_keyring_support" = "yes" -a "$ac_cv_linux_exports_key_type_keyring" = "yes"],
991                           [enable_linux_syscall_probing="no"],
992                           [enable_linux_syscall_probing="yes"])
993                  ])
994
995                  dnl Syscall probing needs a few tests of its own, and just
996                  dnl won't work if the kernel doesn't export init_mm
997                  AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
998                    LINUX_EXPORTS_INIT_MM
999                    AS_IF([test "$ac_cv_linux_exports_init_mm" = "no"], [
1000                      AC_MSG_ERROR(
1001                        [Can't do syscall probing without exported init_mm])
1002                    ])
1003                    LINUX_EXPORTS_SYS_CHDIR
1004                    LINUX_EXPORTS_SYS_OPEN
1005                    AC_DEFINE(ENABLE_LINUX_SYSCALL_PROBING, 1,
1006                              [define to enable syscall table probes])
1007                  ])
1008
1009                  dnl Packaging and SMP build
1010                  if test "x$with_linux_kernel_packaging" != "xyes" ; then
1011                    LINUX_WHICH_MODULES
1012                  else
1013                    AC_SUBST(MPS,'SP')
1014                  fi
1015
1016                  dnl Syscall probing
1017                  if test "x$ac_cv_linux_config_modversions" = "xno" -o $AFS_SYSKVERS -ge 26; then
1018                    AS_IF([test "$enable_linux_syscall_probing" = "yes"], [
1019                      AC_MSG_WARN([Cannot determine sys_call_table status. assuming it isn't exported])
1020                    ])
1021                    ac_cv_linux_exports_sys_call_table=no
1022                    if test -f "$LINUX_KERNEL_PATH/include/asm/ia32_unistd.h"; then
1023                      ac_cv_linux_exports_ia32_sys_call_table=yes
1024                    fi
1025                  else
1026                    LINUX_EXPORTS_KALLSYMS_ADDRESS
1027                    LINUX_EXPORTS_KALLSYMS_SYMBOL
1028                    LINUX_EXPORTS_SYS_CALL_TABLE
1029                    LINUX_EXPORTS_IA32_SYS_CALL_TABLE
1030                    if test "x$ac_cv_linux_exports_sys_call_table" = "xno"; then
1031                          linux_syscall_method=none
1032                          if test "x$ac_cv_linux_exports_init_mm" = "xyes"; then
1033                             linux_syscall_method=scan
1034                             if test "x$ac_cv_linux_exports_kallsyms_address" = "xyes"; then
1035                                linux_syscall_method=scan_with_kallsyms_address
1036                             fi
1037                          fi
1038                          if test "x$ac_cv_linux_exports_kallsyms_symbol" = "xyes"; then
1039                             linux_syscall_method=kallsyms_symbol
1040                          fi
1041                          if test "x$linux_syscall_method" = "xnone"; then
1042                             AC_MSG_WARN([no available sys_call_table access method -- guessing scan])
1043                             linux_syscall_method=scan
1044                          fi
1045                    fi
1046                  fi
1047                  if test -f "$LINUX_KERNEL_PATH/include/linux/in_systm.h"; then
1048                   AC_DEFINE(HAVE_IN_SYSTM_H, 1, [define if you have in_systm.h header file])
1049                  fi
1050                  if test -f "$LINUX_KERNEL_PATH/include/linux/mm_inline.h"; then
1051                   AC_DEFINE(HAVE_MM_INLINE_H, 1, [define if you have mm_inline.h header file])
1052                  fi
1053                  if test "x$ac_cv_linux_kernel_page_follow_link" = "xyes" -o "x$ac_cv_linux_func_i_put_link_takes_cookie" = "xyes"; then
1054                   AC_DEFINE(USABLE_KERNEL_PAGE_SYMLINK_CACHE, 1, [define if your kernel has a usable symlink cache API])
1055                  else
1056                   AC_MSG_WARN([your kernel does not have a usable symlink cache API])
1057                  fi
1058                 :
1059                 fi
1060 dnl Linux-only, but just enable always.
1061                 AC_DEFINE(AFS_CACHE_BYPASS, 1, [define to activate cache bypassing Unix client])
1062 esac
1063
1064 AC_CACHE_CHECK([if compiler has __sync_add_and_fetch],
1065     [ac_cv_sync_fetch_and_add],
1066     [AC_TRY_LINK(, [int var; return __sync_add_and_fetch(&var, 1);],
1067                     [ac_cv_sync_fetch_and_add=yes],
1068                     [ac_cv_sync_fetch_and_add=no])
1069 ])
1070 AS_IF([test "$ac_cv_sync_fetch_and_add" = "yes"],
1071       [AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
1072                 [define if your C compiler has __sync_add_and_fetch])])
1073
1074 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
1075     [ac_cv_sockaddr_len],
1076     [AC_TRY_COMPILE( [#include <sys/types.h>
1077 #include <sys/socket.h>],
1078                      [struct sockaddr *a; a->sa_len=0;],
1079                      [ac_cv_sockaddr_len=yes],
1080                      [ac_cv_sockaddr_len=no])
1081 ])
1082 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
1083       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
1084                  [define if you struct sockaddr sa_len])])
1085
1086 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
1087         echo Skipping library tests because they confuse Irix.
1088 else
1089   AC_SEARCH_LIBS([socket], [socket inet])
1090   AC_SEARCH_LIBS([connect], [nsl])
1091   AC_SEARCH_LIBS([gethostbyname], [dns nsl resolv])
1092
1093   dnl darwin wants it, aix hates it
1094   AC_MSG_CHECKING(for the useability of arpa/nameser_compat.h)
1095   AC_TRY_COMPILE([
1096   #include <stdlib.h>
1097   #include <stdio.h>
1098   #include <sys/types.h>
1099   #include <sys/socket.h>
1100   #include <netinet/in.h>
1101   #include <arpa/inet.h>
1102   #include <arpa/nameser.h>
1103   #include <arpa/nameser_compat.h>
1104   #include <resolv.h>
1105   ], [static int i; i = 0;],
1106   [AC_MSG_RESULT(yes)
1107    AC_DEFINE(HAVE_ARPA_NAMESER_COMPAT_H, 1, [define if arpa/nameser_compat.h exists])],
1108   [AC_MSG_RESULT(no)
1109    ])
1110
1111   openafs_save_libs="$LIBS"
1112   AC_MSG_CHECKING([for res_search])
1113   AC_FUNC_RES_SEARCH
1114
1115   if test "$ac_cv_func_res_search" = no; then
1116       for lib in dns nsl resolv; do
1117         if test "$ac_cv_func_res_search" != yes; then
1118           LIBS="-l$lib $LIBS"
1119           AC_FUNC_RES_SEARCH
1120           LIBS="$openafs_save_libs"
1121         fi
1122       done    
1123       if test "$ac_cv_func_res_search" = yes; then
1124         LIB_AFSDB="-l$lib"
1125         AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1126         AC_MSG_RESULT([yes, in lib$lib])
1127       else
1128         AC_MSG_RESULT(no)
1129       fi
1130   else
1131     AC_DEFINE(HAVE_RES_SEARCH, 1, [])
1132     AC_MSG_RESULT(yes)
1133   fi
1134   
1135 fi
1136 XLIBS="$LIB_AFSDB $XLIBS"
1137
1138 AC_CHECK_RESOLV_RETRANS
1139
1140 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
1141     [ac_cv_setsockopt_iprecverr],
1142     [AC_TRY_COMPILE( [
1143 #include <sys/types.h>
1144 #include <sys/socket.h>
1145 #include <netinet/in.h>],
1146 [int on=1;
1147 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
1148         [ac_cv_setsockopt_iprecverr=yes],
1149         [ac_cv_setsockopt_iprecverr=no])])
1150
1151 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
1152       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
1153                  [define if we can receive socket errors via IP_RECVERR])])
1154
1155 PTHREAD_LIBS=error
1156 if test "x$MKAFS_OSTYPE" = OBSD; then
1157         PTHREAD_LIBS="-pthread"
1158 fi
1159 if test "x$MKAFS_OSTYPE" = xDFBSD; then
1160         PTHREAD_LIBS="-pthread"
1161 fi
1162 if test "x$PTHREAD_LIBS" = xerror; then
1163         AC_CHECK_LIB(pthread, pthread_attr_init,
1164                 PTHREAD_LIBS="-lpthread")
1165 fi
1166 if test "x$PTHREAD_LIBS" = xerror; then
1167         AC_CHECK_LIB(pthreads, pthread_attr_init,
1168                 PTHREAD_LIBS="-lpthreads")
1169 fi
1170 if test "x$PTHREAD_LIBS" = xerror; then
1171         AC_CHECK_LIB(c_r, pthread_attr_init,
1172                 PTHREAD_LIBS="-lc_r")
1173 fi
1174 if test "x$PTHREAD_LIBS" = xerror; then
1175         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
1176 fi
1177 if test "x$PTHREAD_LIBS" = xerror; then
1178         # pthread_attr_init is a macro under HPUX 11.0 and 11.11
1179         AC_CHECK_LIB(pthread, pthread_attr_destroy,
1180                 PTHREAD_LIBS="-lpthread")
1181 fi
1182 if test "x$PTHREAD_LIBS" = xerror; then
1183         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
1184 fi
1185 AC_SUBST(PTHREAD_LIBS)
1186
1187 HOST_CPU="$host_cpu"
1188
1189 if test "x$with_bsd_kernel_headers" != "x"; then
1190         BSD_KERNEL_PATH="$with_bsd_kernel_headers"
1191 else
1192         BSD_KERNEL_PATH="/usr/src/sys"
1193 fi
1194
1195 if test "x$with_bsd_kernel_build" != "x"; then
1196         BSD_KERNEL_BUILD="$with_bsd_kernel_build"
1197 else
1198         case $AFS_SYSNAME in
1199                 *_fbsd_*)
1200                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/${HOST_CPU}/compile/GENERIC"
1201                         ;;
1202                 *_nbsd*)
1203                         BSD_KERNEL_BUILD="${BSD_KERNEL_PATH}/arch/${HOST_CPU}/compile/GENERIC"
1204         esac
1205 fi
1206
1207 # Fast restart
1208 if test "$enable_supergroups" = "yes"; then
1209         AC_DEFINE(SUPERGROUPS, 1, [define if you want to have support for nested pts groups])
1210 fi
1211
1212 if test "$enable_bitmap_later" = "yes"; then
1213         AC_DEFINE(BITMAP_LATER, 1, [define if you want to salvager to check bitmasks later])
1214 fi
1215
1216 if test "$enable_unix_sockets" = "yes"; then
1217         AC_DEFINE(USE_UNIX_SOCKETS, 1, [define if you want to use UNIX sockets for fssync.])
1218         USE_UNIX_SOCKETS="yes"
1219 else
1220         USE_UNIX_SOCKETS="no"
1221 fi
1222 AC_SUBST(USE_UNIX_SOCKETS)
1223
1224 if test "$enable_namei_fileserver" = "yes"; then
1225         AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1226         VFSCK=""
1227 else
1228         if test "$enable_namei_fileserver" = "default"; then
1229                 case $host in
1230                         *-solaris2.10*)
1231                                 AC_MSG_WARN(Some Solaris 10 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1232                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1233                                 VFSCK=""
1234                                 ;;
1235                         *-solaris2.11*)
1236                                 AC_MSG_WARN(Solaris 11 versions are not safe with the inode fileserver. Forcing namei. Override with --disable-namei-fileserver)
1237                                 AC_DEFINE(AFS_NAMEI_ENV, 1, [define if you want to want namei fileserver])
1238                                 VFSCK=""
1239                                 ;;
1240                         *)
1241                                 VFSCK="vfsck"
1242                                 ;;
1243                 esac
1244         else
1245                 VFSCK="vfsck"
1246         fi
1247 fi
1248
1249 dnl check for tivoli
1250 AC_MSG_CHECKING(for tivoli tsm butc support)
1251 XBSA_CFLAGS=""
1252 if test "$enable_tivoli_tsm" = "yes"; then
1253         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
1254         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
1255         XBSADIR3=/usr/tivoli/tsm/client/api/bin/sample
1256         XBSADIR4=/opt/tivoli/tsm/client/api/bin/sample
1257
1258         if test -r "$XBSADIR3/dsmapifp.h"; then
1259                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR3"
1260                 XBSA_XLIBS="-ldl"
1261                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1262         elif test -r "$XBSADIR4/dsmapifp.h"; then
1263                 XBSA_CFLAGS="-Dxbsa -DNEW_XBSA -I$XBSADIR4"
1264                 XBSA_XLIBS="-ldl"
1265                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1266         elif test -r "$XBSADIR1/xbsa.h"; then
1267                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
1268                 XBSA_XLIBS=""
1269                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1270         elif test -r "$XBSADIR2/xbsa.h"; then
1271                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
1272                 XBSA_XLIBS=""
1273                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
1274         else
1275                 AC_MSG_RESULT([no, missing xbsa.h and dsmapifp.h header files])
1276         fi
1277 else
1278         AC_MSG_RESULT([no])
1279 fi
1280 AC_SUBST(XBSA_CFLAGS)
1281 AC_SUBST(XBSA_XLIBS) 
1282
1283 dnl checks for header files.
1284 AC_HEADER_STDC
1285 AC_HEADER_SYS_WAIT
1286 AC_HEADER_DIRENT
1287 AC_CHECK_HEADERS([ \
1288                    arpa/inet.h \
1289                    arpa/nameser.h \
1290                    curses.h\
1291                    direct.h \
1292                    et/com_err.h \
1293                    errno.h \
1294                    fcntl.h \
1295                    grp.h \
1296                    math.h \
1297                    mntent.h \
1298                    ncurses.h \
1299                    netdb.h \
1300                    netinet/in.h \
1301                    pthread_np.h \
1302                    pwd.h \
1303                    regex.h \
1304                    security/pam_appl.h \
1305                    signal.h \
1306                    stdint.h \
1307                    stdio_ext.h \
1308                    stdlib.h \
1309                    string.h \
1310                    strings.h \
1311                    sys/bitypes.h \
1312                    sys/bswap.h \
1313                    sys/dk.h \
1314                    sys/fcntl.h \
1315                    sys/file.h \
1316                    sys/fs_types.h \
1317                    sys/fstyp.h \
1318                    sys/ioctl.h \
1319                    sys/ipc.h \
1320                    sys/lockf.h \
1321                    sys/map.h \
1322                    sys/mount.h \
1323                    sys/mntent.h \
1324                    sys/mnttab.h \
1325                    sys/pag.h \
1326                    sys/param.h \
1327                    sys/resource.h \
1328                    sys/select.h \
1329                    sys/statfs.h \
1330                    sys/statvfs.h \
1331                    sys/socket.h \
1332                    sys/sysctl.h \
1333                    sys/time.h \
1334                    sys/types.h \
1335                    sys/uio.h \
1336                    sys/un.h \
1337                    sys/vfs.h \
1338                    syslog.h \
1339                    termios.h \
1340                    time.h \
1341                    ucontext.h \
1342                    unistd.h \
1343                    windows.h \
1344                 ])
1345
1346 AC_CHECK_HEADERS([resolv.h], [], [], [AC_INCLUDES_DEFAULT
1347 #ifdef HAVE_NETINET_IN_H
1348 # include <netinet/in.h>
1349 #endif])
1350
1351 AC_CHECK_HEADERS([net/if.h],[],[],[AC_INCLUDES_DEFAULT
1352 #ifdef HAVE_SYS_SOCKET_H
1353 # include <sys/socket.h>
1354 #endif])
1355
1356 AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[AC_INCLUDES_DEFAULT
1357 #ifdef HAVE_SYS_SOCKET_H
1358 # include <sys/socket.h>
1359 #endif
1360 #ifdef HAVE_NETINET_IN_H
1361 # include <netinet/in.h>
1362 #endif
1363 #ifdef HAVE_NET_IF_H
1364 # include <net/if.h>
1365 #endif])
1366
1367 AC_CHECK_HEADERS([security/pam_modules.h],[],[],[AC_INCLUDES_DEFAULT
1368 #ifdef HAVE_SECURITY_PAM_APPL_H
1369 # include <security/pam_appl.h>
1370 #endif])
1371
1372 AC_CHECK_HEADERS(linux/errqueue.h,,,[#include <linux/types.h>])
1373
1374 AC_CHECK_TYPES([fsblkcnt_t],,,[
1375 #include <sys/types.h>
1376 #ifdef HAVE_SYS_BITYPES_H
1377 #include <sys/bitypes.h>
1378 #endif
1379 #ifdef HAVE_SYS_STATFS_H
1380 #include <sys/statfs.h>
1381 #endif
1382 #ifdef HAVE_SYS_STATVFS_H
1383 #include <sys/statvfs.h>
1384 #endif
1385 ])
1386
1387 dnl see what struct stat has for timestamps
1388 AC_CHECK_MEMBERS([struct stat.st_ctimespec, struct stat.st_ctimensec])
1389
1390 dnl check for curses-lib
1391 AS_IF([test "x$enable_gtx" != "xno"],
1392       [save_LIBS=$LIBS
1393       AC_CHECK_LIB( [ncurses], [setupterm],
1394       [LIB_curses=-lncurses],
1395         [AC_CHECK_LIB([Hcurses], [setupterm], [LIB_curses=-lHcurses],
1396           [AC_CHECK_LIB([curses], [setupterm], [LIB_curses=-lcurses])])
1397       ])
1398       LIBS=$save_LIBS
1399       AC_SUBST(LIB_curses)])
1400         
1401 OPENAFS_TEST_PACKAGE(libintl,[#include <libintl.h>],[-lintl],,,INTL)
1402
1403 dnl Don't build PAM on IRIX; the interface doesn't work for us.
1404 if test "$ac_cv_header_security_pam_modules_h" = yes -a "$enable_pam" = yes; then
1405         case $AFS_SYSNAME in
1406         sgi_*)
1407                 HAVE_PAM="no"
1408                 ;;
1409         *)
1410                 HAVE_PAM="yes"
1411                 ;;
1412         esac
1413 else
1414         HAVE_PAM="no"
1415 fi
1416 AC_SUBST(HAVE_PAM)
1417
1418 if test "$enable_login" = yes; then
1419         BUILD_LOGIN="yes"
1420 else
1421         BUILD_LOGIN="no"
1422 fi
1423 AC_SUBST(BUILD_LOGIN)
1424
1425 if test "$enable_uss" = yes; then
1426         BUILD_USS="yes"
1427 else
1428         BUILD_USS="no"
1429 fi
1430 AC_SUBST(BUILD_USS)
1431
1432 AC_CHECK_FUNCS([ \
1433         arc4random \
1434         fcntl \
1435         fseeko64 \
1436         ftello64 \
1437         getcwd \
1438         getegid \
1439         geteuid \
1440         getgid \
1441         getuid \
1442         getrlimit \
1443         issetugid \
1444         mkstemp \
1445         pread \
1446         preadv \
1447         preadv64 \
1448         pwrite \
1449         pwritev \
1450         pwritev64 \
1451         regcomp \
1452         regerror \
1453         regexec \
1454         setitimer \
1455         setvbuf \
1456         sigaction \
1457         strcasestr \
1458         strerror \
1459         sysconf \
1460         sysctl \
1461         tdestroy \
1462         timegm \
1463 ])
1464
1465 OPENAFS_ROKEN()
1466 OPENAFS_C_ATTRIBUTE()
1467
1468 dnl Functions that Heimdal's libroken provides, but that we
1469 dnl haven't found a need for yet, and so haven't imported
1470 AC_CHECK_FUNCS([ \
1471         chown \
1472         fchown \
1473         gethostname \
1474         lstat \
1475         inet_aton \
1476         inet_ntop \
1477         inet_pton \
1478         putenv \
1479         readv \
1480         setenv \
1481         strdup \
1482         strftime \
1483         strndup \
1484         strsep \
1485         unsetenv \
1486 ])
1487
1488 dnl Functions that are in objects that we always build from libroken
1489 AC_CHECK_FUNCS([ \
1490         asprintf \
1491         asnprintf \
1492         vasprintf \
1493         vasnprintf \
1494         vsnprintf \
1495         snprintf \
1496 ])
1497
1498 dnl Functions that we're going to try and get from libroken
1499 AC_REPLACE_FUNCS([ \
1500         daemon \
1501         ecalloc \
1502         emalloc \
1503         erealloc \
1504         err \
1505         errx \
1506         flock \
1507         getdtablesize \
1508         getopt \
1509         getprogname \
1510         gettimeofday \
1511         localtime_r \
1512         mkstemp \
1513         setenv \
1514         setprogname \
1515         strcasecmp \
1516         strlcat \
1517         strnlen \
1518         strlcpy \
1519         strsep \
1520         tdelete \
1521         tfind \
1522         tsearch \
1523         twalk \
1524         unsetenv \
1525         verr \
1526         verrx \
1527         vsyslog \
1528         vwarn \
1529         vwarnx \
1530         warn \
1531         warnx \
1532 ])
1533
1534 dnl Headers that we're going to try and get from libroken
1535 AC_CHECK_HEADERS([ \
1536         err.h \
1537         search.h \
1538 ])
1539
1540 AC_CHECK_DECLS([h_errno], [], [], [
1541 #include <sys/types.h>
1542 #ifdef HAVE_NETDB_H
1543 #include <netdb.h>
1544 #endif
1545 ])
1546
1547 AC_HEADER_TIME
1548
1549 ROKEN_HEADERS=
1550 AS_IF([test "$ac_cv_header_err_h" != "yes" ],
1551       [ROKEN_HEADERS="$ROKEN_HEADERS \$(TOP_INCDIR)/err.h"],
1552       [])
1553 AC_SUBST(ROKEN_HEADERS)
1554
1555 dnl Stuff that's harder ...
1556 AC_MSG_CHECKING([for bswap16])
1557 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1558 #ifdef HAVE_SYS_TYPES_H
1559 #include <sys/types.h>
1560 #endif
1561 #ifdef HAVE_SYS_BSWAP_H
1562 #include <sys/bswap.h>
1563 #endif
1564 ],
1565 [short a, b; b = bswap16(a); ])],
1566 [AC_MSG_RESULT(yes)
1567  AC_DEFINE(HAVE_BSWAP16, 1, [Define to 1 if you have the bswap16 function])
1568 ],
1569 [AC_MSG_RESULT(no)])
1570
1571 AC_MSG_CHECKING([for bswap32])
1572 AC_LINK_IFELSE([AC_LANG_PROGRAM([#ifdef HAVE_SYS_TYPES_H
1573 #include <sys/types.h>
1574 #endif
1575 #ifdef HAVE_SYS_BSWAP_H
1576 #include <sys/bswap.h>
1577 #endif
1578 ],
1579 [int a, b; b = bswap32(a); ])],
1580 [AC_MSG_RESULT(yes)
1581  AC_DEFINE(HAVE_BSWAP32, 1, [Define to 1 if you have the bswap32 function])
1582 ],
1583 [AC_MSG_RESULT(no)])
1584
1585 case $AFS_SYSNAME in
1586 *hp_ux* | *hpux*)
1587    AC_MSG_WARN([Some versions of HP-UX have a buggy positional I/O implementation. Forcing no positional I/O.])
1588    ;;
1589 *)
1590    AC_MSG_CHECKING([for positional I/O])
1591    if test "$ac_cv_func_pread" = "yes" && \
1592            test "$ac_cv_func_pwrite" = "yes"; then
1593       AC_DEFINE(HAVE_PIO, 1, [define if you have pread() and pwrite()])
1594       AC_MSG_RESULT(yes)
1595    else
1596      AC_MSG_RESULT(no)
1597    fi
1598    AC_MSG_CHECKING([for vectored positional I/O])
1599    AS_IF([test "$ac_cv_func_preadv" = "yes" -a \
1600                "$ac_cv_func_pwritev" = "yes" -a \
1601                "$ac_cv_func_preadv64" = "yes" -a \
1602                "$ac_cv_func_pwritev64" = "yes"],
1603          [AC_DEFINE(HAVE_PIOV, 1, [define if you have preadv() and pwritev()])
1604           AC_MSG_RESULT(yes)],
1605          [AC_MSG_RESULT(no)])
1606    ;;
1607 esac
1608
1609 AC_MSG_CHECKING([for POSIX regex library])
1610 if test "$ac_cv_header_regex_h" = "yes" && \
1611         test "$ac_cv_func_regcomp" = "yes" && \
1612         test "$ac_cv_func_regexec" = "yes" && \
1613         test "$ac_cv_func_regerror" = "yes"; then
1614     AC_DEFINE(HAVE_POSIX_REGEX, 1, [define if you have POSIX regex library])
1615     AC_MSG_RESULT(yes)
1616 else
1617     AC_MSG_RESULT(no)
1618 fi
1619
1620 dnl Look for "non-portable" pthreads functions.
1621 save_LIBS="$LIBS"
1622 LIBS="$LIBS $PTHREAD_LIBS"
1623 AC_CHECK_FUNCS([ \
1624         pthread_set_name_np \
1625         pthread_setname_np \
1626 ])
1627
1628 dnl Sadly, there are three different versions of pthread_setname_np.
1629 dnl Try to cater for all of them.
1630 if test "$ac_cv_func_pthread_setname_np" = "yes" ; then
1631     AC_MSG_CHECKING([for signature of pthread_setname_np])
1632     AC_TRY_COMPILE([
1633 #include <pthread.h>
1634 #ifdef HAVE_PTHREAD_NP_H
1635 #include <pthread_np.h>
1636 #endif
1637 ], [pthread_setname_np(pthread_self(), "test", (void *)0)], [
1638         AC_MSG_RESULT([three arguments])
1639         pthread_setname_np_args=3], [
1640         AC_TRY_COMPILE([
1641 #include <pthread.h>
1642 #ifdef HAVE_PTHREAD_NP_H
1643 #include <pthread_np.h>
1644 #endif
1645 ], [pthread_setname_np(pthread_self(), "test")], [
1646             AC_MSG_RESULT([two arguments])
1647             pthread_setname_np_args=2], [
1648             AC_TRY_COMPILE([
1649 #include <pthread.h>
1650 #ifdef HAVE_PTHREAD_NP_H
1651 #include <pthread_np.h>
1652 #endif
1653 ], [pthread_setname_np("test")], [
1654                 AC_MSG_RESULT([one argument])
1655                 pthread_setname_np_args=1], [pthread_setname_np_args=0])
1656 ])
1657 ])
1658 AC_DEFINE_UNQUOTED([PTHREAD_SETNAME_NP_ARGS], $pthread_setname_np_args, [Number of arguments required by pthread_setname_np() function])
1659 fi
1660 LIBS="$save_LIBS"
1661
1662 openafs_cv_saved_CFLAGS="$CFLAGS"
1663 CFLAGS="$CFLAGS $XCFLAGS_NOCHECKING"
1664
1665 AC_TYPE_SIGNAL
1666 OPENAFS_RETSIGTYPE
1667 AC_CHECK_SIZEOF(void *)
1668 AC_CHECK_SIZEOF(unsigned long long)
1669 AC_CHECK_SIZEOF(unsigned long)
1670 AC_CHECK_SIZEOF(unsigned int)
1671 AC_TYPE_INTPTR_T
1672 AC_TYPE_UINTPTR_T
1673 AC_TYPE_SSIZE_T
1674 AC_CHECK_TYPE([sig_atomic_t],[],
1675     [AC_DEFINE([sig_atomic_t], [int],
1676         [Define to int if <signal.h> does not define.])],
1677 [#include <sys/types.h>
1678 #include <signal.h>])
1679 AC_CHECK_TYPE([socklen_t],[],
1680     [AC_DEFINE([socklen_t], [int],
1681         [Define to int if <sys/socket.h> does not define.])],
1682 [#include <sys/types.h>
1683 #include <sys/socket.h>])
1684 AC_CHECK_TYPES(off64_t)
1685 AC_CHECK_TYPES([ssize_t], [], [], [#include <unistd.h>])
1686 AC_CHECK_TYPES([struct winsize], [], [], [
1687 #ifdef HAVE_TERMIOS_H
1688 # include <termios.h>
1689 #else
1690 # include <sys/termios.h>
1691 #endif
1692 #include <sys/ioctl.h>])
1693 AC_CHECK_TYPES([sa_family_t, socklen_t, struct sockaddr,
1694                 struct sockaddr_storage],
1695                [], [], [
1696 #include <sys/types.h>
1697 #include <sys/socket.h>
1698 ])
1699 AC_CHECK_TYPES([sa_family_t], [], [], [
1700 #include <sys/types.h>
1701 #include <sys/socket.h>
1702 ])
1703 AC_CHECK_TYPES([struct addrinfo], [], [], [
1704 #include <sys/types.h>
1705 #ifdef HAVE_NETDB_H
1706 #include <netdb.h>
1707 #endif
1708 ])
1709 AC_CHECK_TYPES([long long], [], [], [])
1710
1711 AC_SIZEOF_TYPE(long)
1712
1713 CFLAGS="$openafs_cv_saved_CFLAGS"
1714
1715 RRA_HEADER_PAM_CONST
1716
1717
1718 dnl Directory PATH handling
1719 if test "x$enable_transarc_paths" = "xyes"  ; then 
1720     afsconfdir=${afsconfdir=/usr/afs/etc}
1721     viceetcdir=${viceetcdir=/usr/vice/etc}
1722     afskerneldir=${afskerneldir=${viceetcdir}}
1723     afssrvbindir=${afssrvbindir=/usr/afs/bin}
1724     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
1725     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
1726     afsdbdir=${afsdbdir=/usr/afs/db}
1727     afslogsdir=${afslogsdir=/usr/afs/logs}
1728     afslocaldir=${afslocaldir=/usr/afs/local}
1729     afsbackupdir=${afsbackupdir=/usr/afs/backup}
1730     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
1731     afsdatadir=${afsdatadir=/usr/vice/etc}
1732 else 
1733     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
1734     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
1735     afskerneldir=${afskerneldir='${libdir}/openafs'}
1736     afssrvbindir=${afssrvbindir='${bindir}'}
1737     afssrvsbindir=${afssrvsbindir='${sbindir}'}
1738     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
1739     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
1740     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
1741     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
1742     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
1743     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
1744     afsdatadir=${afsdatadir='${datadir}/openafs'}
1745 fi
1746 AC_SUBST(afsconfdir)
1747 AC_SUBST(viceetcdir)
1748 AC_SUBST(afskerneldir)
1749 AC_SUBST(afssrvbindir)
1750 AC_SUBST(afssrvsbindir)
1751 AC_SUBST(afssrvlibexecdir)
1752 AC_SUBST(afsdbdir)
1753 AC_SUBST(afslogsdir)
1754 AC_SUBST(afslocaldir)
1755 AC_SUBST(afsbackupdir)
1756 AC_SUBST(afsbosconfigdir)
1757 AC_SUBST(afsdatadir)
1758
1759 if test "x$enable_kernel_module" = "xyes"; then
1760 ENABLE_KERNEL_MODULE=libafs
1761 fi
1762
1763 if test "x$enable_pthreaded_ubik" = "xyes"; then
1764 ENABLE_PTHREADED_UBIK=yes
1765 fi
1766
1767 AC_SUBST(VFSCK)
1768 AC_SUBST(AFS_SYSNAME)
1769 AC_SUBST(AFS_PARAM_COMMON)
1770 AC_SUBST(ENABLE_KERNEL_MODULE)
1771 AC_SUBST(ENABLE_PTHREADED_UBIK)
1772 AC_SUBST(LIB_AFSDB)
1773 AC_SUBST(LINUX_KERNEL_PATH)
1774 AC_SUBST(LINUX_KERNEL_BUILD)
1775 AC_SUBST(HOST_CPU)
1776 AC_SUBST(BSD_KERNEL_PATH)
1777 AC_SUBST(BSD_KERNEL_BUILD)
1778 AC_SUBST(LINUX_VERSION)
1779 AC_SUBST(MKAFS_OSTYPE)
1780 AC_SUBST(TOP_OBJDIR)
1781 AC_SUBST(TOP_SRCDIR)
1782 AC_SUBST(TOP_INCDIR)
1783 AC_SUBST(TOP_LIBDIR)
1784 AC_SUBST(DEST)
1785 AC_SUBST(DARWIN_INFOFILE)
1786 AC_SUBST(IRIX_BUILD_IP35)
1787 AC_SUBST(HTML_XSL)
1788 AC_SUBST(XSLTPROC)
1789 AC_SUBST(DOCBOOK2PDF)
1790 AC_SUBST(DOCBOOK_STYLESHEETS)
1791
1792 OPENAFS_FUSE
1793 OPENAFS_SWIG
1794
1795 TOP_SRCDIR="${srcdir}/src"
1796 dnl
1797 dnl If we're using ./configure, need a more reasonable TOP_SRCDIR, since relative links don't work everywhere
1798 dnl
1799 case $TOP_SRCDIR in
1800         /*)
1801                 ;;
1802         *)
1803                 TOP_SRCDIR=`cd $TOP_SRCDIR; pwd`
1804                 ;;
1805 esac
1806
1807 TOP_OBJDIR="${SRCDIR_PARENT}"
1808 TOP_INCDIR="${SRCDIR_PARENT}/include"
1809 TOP_LIBDIR="${SRCDIR_PARENT}/lib"
1810 if test "${DEST}x" = "x"; then
1811         DEST="${SRCDIR_PARENT}/${AFS_SYSNAME}/dest"
1812 fi
1813
1814 HELPER_SPLINT="${TOP_SRCDIR}/helper-splint.sh"
1815 HELPER_SPLINTCFG="${TOP_SRCDIR}/splint.cfg"
1816 AC_SUBST(HELPER_SPLINT)
1817 AC_SUBST(HELPER_SPLINTCFG)
1818
1819 mkdir -p ${TOP_OBJDIR}/src/JAVA/libjafs
1820
1821 dnl Check to see if crypt lives in a different library
1822 AC_CHECK_LIB(crypt, crypt, LIB_crypt="-lcrypt")
1823 AC_SUBST(LIB_crypt)
1824
1825 dnl Check to see if the compiler support labels in structs
1826 AC_MSG_CHECKING(for label support in structs)
1827 AC_TRY_COMPILE([], [
1828 extern void osi_UFSOpen(void);
1829 struct labeltest {
1830    void (*open) (void);
1831 };
1832 struct labeltest struct_labeltest = {
1833    .open       = osi_UFSOpen,
1834 }
1835 ],
1836 [AC_MSG_RESULT(yes)
1837  AC_DEFINE(HAVE_STRUCT_LABEL_SUPPORT, 1, [Define to 1 if your compiler supports labels in structs.])
1838 ],
1839 [AC_MSG_RESULT(no)
1840 ])
1841
1842 AC_MSG_CHECKING([checking for dirfd])
1843 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1844 #ifdef HAVE_DIRENT_H
1845 #include <dirent.h>
1846 #endif
1847 ]],
1848         [[DIR *d = 0; dirfd(d);]])],
1849         [ac_rk_have_dirfd=yes], [ac_rk_have_dirfd=no])
1850 if test "$ac_rk_have_dirfd" = "yes" ; then
1851         AC_DEFINE_UNQUOTED(HAVE_DIRFD, 1, [have a dirfd function/macro])
1852 fi
1853 AC_MSG_RESULT($ac_rk_have_dirfd)
1854
1855 OPENAFS_HAVE_STRUCT_FIELD(DIR, dd_fd, [#include <sys/types.h>
1856 #ifdef HAVE_DIRENT_H
1857 #include <dirent.h>
1858 #endif])
1859
1860 dnl Eventually, this will look for the system one, or for OpenSSL
1861 LIB_hcrypto="-lafshcrypto"
1862 LDFLAGS_hcrypto="-L\$(TOP_LIBDIR)"
1863 AC_SUBST(LIB_hcrypto)
1864 AC_SUBST(LDFLAGS_hcrypto)
1865
1866 dnl Check for UUID library
1867 AC_CHECK_HEADERS([uuid/uuid.h])
1868 AC_CHECK_LIB(uuid, uuid_generate, LIBS_uuid="-luuid")
1869 AC_CHECK_FUNCS([uuid_generate])
1870 ])
1871
1872
1873 AC_DEFUN([SUMMARY], [
1874     # Print a configuration summary
1875 echo 
1876 echo "**************************************"
1877 echo configure summary
1878 echo
1879 AS_IF([test $LIB_curses],[
1880 echo "LIB_curses :                $LIB_curses" ],[
1881 echo "XXX LIB_curses  not found! not building scout and afsmonitor!"
1882 ])
1883 echo 
1884 echo "**************************************"
1885 ])