acinclude.m4

   1 dnl This file contains the common configuration code which would
   2 dnl otherwise be duplicated between configure and configure-libafs.
   3 dnl
   4 dnl NB: Because this code is a macro, references to positional shell
   5 dnl parameters must be done like $[]1 instead of $1
   6
   7 AC_DEFUN(OPENAFS_CONFIGURE_COMMON,[
   8
   9 AC_CANONICAL_HOST
  10 SRCDIR_PARENT=`pwd`
  11
  12 #BOZO_SAVE_CORES BOS_RESTRICTED_MODE BOS_NEW_CONFIG pam sia
  13 AC_ARG_WITH(afs-sysname,
  14 [  --with-afs-sysname=sys    use sys for the afs sysname]
  15 )
  16 AC_ARG_ENABLE( obsolete,
  17 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
  18 AC_ARG_ENABLE( insecure,
  19 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
  20 AC_ARG_ENABLE( afsdb,
  21 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
  22 AC_ARG_ENABLE( bos-restricted-mode,
  23 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
  24 AC_ARG_ENABLE( namei-fileserver,
  25 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
  26 AC_ARG_ENABLE( fast-restart,
  27 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
  28 AC_ARG_ENABLE( bitmap-later,
  29 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
  30 AC_ARG_ENABLE( full-vos-listvol-switch,
  31 [  --enable-full-vos-listvol-switch     enable vos full listvol switch for formatted output],, enable_full_vos_listvol_switch="no")
  32 AC_ARG_WITH(dux-kernel-headers,
  33 [  --with-dux-kernel-headers=path       use the kernel headers found at path(optional, defaults to first match in /usr/sys)]
  34 )
  35 AC_ARG_WITH(linux-kernel-headers,
  36 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux)]
  37 )
  38 AC_ARG_ENABLE(kernel-module,
  39 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
  40 )
  41 AC_ARG_ENABLE(redhat-buildsys,
  42 [  --enable-redhat-buildsys             enable compilation of the redhat build system kernel (defaults to disabled)],, enable_redhat_buildsys="no"
  43 )
  44 AC_ARG_ENABLE(transarc-paths,
  45 [  --enable-transarc-paths                      Use Transarc style paths like /usr/afs and /usr/vice],, enable_transarc_paths="no"
  46 )
  47 AC_ARG_ENABLE(tivoli-tsm,
  48 [  --enable-tivoli-tsm                  Enable use of the Tivoli TSM API libraries for butc support],, enable_tivoli_tsm="no"
  49 )
  50
  51 dnl weird ass systems
  52 AC_AIX
  53 AC_ISC_POSIX
  54 AC_MINIX
  55
  56 dnl Various compiler setup.
  57 AC_C_INLINE
  58 AC_C_CONST
  59 AC_PROG_CC
  60 AC_TYPE_PID_T
  61 AC_TYPE_SIZE_T
  62 AC_TYPE_SIGNAL
  63
  64 dnl Checks for programs.
  65 AC_PROG_INSTALL
  66 AC_PROG_LN_S
  67 AC_PROG_RANLIB
  68 AC_PROG_YACC
  69 AM_PROG_LEX
  70
  71 OPENAFS_CHECK_BIGENDIAN
  72
  73 AC_MSG_CHECKING(your OS)
  74 system=$host
  75 case $system in
  76         *-linux*)
  77                 MKAFS_OSTYPE=LINUX
  78                 if test "x$enable_redhat_buildsys" = "xyes"; then
  79                  AC_DEFINE(ENABLE_REDHAT_BUILDSYS)
  80                 fi
  81                 if test "x$enable_kernel_module" = "xyes"; then
  82                  if test "x$with_linux_kernel_headers" != "x"; then
  83                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
  84                  else
  85                    LINUX_KERNEL_PATH="/usr/src/linux"
  86                  fi
  87                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
  88                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
  89                   if test "x$linux_kvers" = "x"; then
  90                     if test -f "$LINUX_KERNEL_PATH/include/linux/version-up.h"; then
  91                       linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version-up.h |awk 'BEGIN { FS="\"" } { print $[]2 }'|tail -1`
  92                       if test "x$linux_kvers" = "x"; then
  93
  94                         AC_MSG_ERROR(Linux headers lack version definition [2])
  95                         exit 1
  96                       else
  97                         LINUX_VERSION="$linux_kvers"
  98                       fi
  99                     else
 100                       AC_MSG_ERROR(Linux headers lack version definition)
 101                       exit 1
 102                     fi
 103                   else
 104                     LINUX_VERSION="$linux_kvers"
 105                   fi
 106                  else
 107                     enable_kernel_module="no"
 108                  fi
 109                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
 110                      enable_kernel_module="no"
 111                  fi
 112                  if test "x$enable_kernel_module" = "xno"; then
 113                   if test "x$with_linux_kernel_headers" != "x"; then
 114                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
 115                    exit 1
 116                   else
 117                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
 118                   fi
 119                  fi
 120                 fi
 121                 AC_MSG_RESULT(linux)
 122                 if test "x$enable_kernel_module" = "xyes"; then
 123                  ifdef([OPENAFS_CONFIGURE_LIBAFS],
 124                    [LINUX_BUILD_VNODE_FROM_INODE(src/config,afs)],
 125                    [LINUX_BUILD_VNODE_FROM_INODE(${srcdir}/src/config,src/afs/LINUX,${srcdir}/src/afs/LINUX)]
 126                  )
 127                  LINUX_FS_STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK
 128                  LINUX_FS_STRUCT_INODE_HAS_I_TRUNCATE_SEM
 129                  LINUX_FS_STRUCT_INODE_HAS_I_DIRTY_DATA_BUFFERS
 130                  LINUX_FS_STRUCT_INODE_HAS_I_DEVICES
 131                  LINUX_INODE_SETATTR_RETURN_TYPE
 132                  LINUX_NEED_RHCONFIG
 133                  LINUX_WHICH_MODULES
 134                  if test "x$ac_cv_linux_func_inode_setattr_returns_int" = "xyes" ; then
 135                   AC_DEFINE(INODE_SETATTR_NOT_VOID)
 136                  fi
 137                  if test "x$ac_cv_linux_fs_struct_address_space_has_page_lock" = "xyes"; then
 138                   AC_DEFINE(STRUCT_ADDRESS_SPACE_HAS_PAGE_LOCK)
 139                  fi
 140                  if test "x$ac_cv_linux_fs_struct_inode_has_i_truncate_sem" = "xyes"; then
 141                   AC_DEFINE(STRUCT_INODE_HAS_I_TRUNCATE_SEM)
 142                  fi
 143                 :
 144                 fi
 145                 ;;
 146         *-solaris*)
 147                 MKAFS_OSTYPE=SOLARIS
 148                 AC_MSG_RESULT(sun4)
 149                 SOLARIS_UFSVFS_HAS_DQRWLOCK
 150                 ;;
 151         *-hpux*)
 152                 MKAFS_OSTYPE=HPUX
 153                 AC_MSG_RESULT(hp_ux)
 154                 ;;
 155         *-irix*)
 156                 if test -d /usr/include/sys/SN/SN1; then
 157                  IRIX_BUILD_IP35="IP35"
 158                 fi
 159                 MKAFS_OSTYPE=IRIX
 160                 AC_MSG_RESULT(sgi)
 161                 ;;
 162         *-aix*)
 163                 MKAFS_OSTYPE=AIX
 164                 AC_MSG_RESULT(rs_aix)
 165                 ;;
 166         *-osf*)
 167                 MKAFS_OSTYPE=DUX
 168                 AC_MSG_RESULT(alpha_dux)
 169                 if test "x$enable_kernel_module" = "xyes"; then
 170                  if test "x$with_dux_kernel_headers" != "x"; then
 171                    HEADER_RT=`ls ${with_dux_kernel_headers}/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 172                  else
 173                    HEADER_RT=`ls /usr/sys/*/rt_preempt.h | head -1 | sed 's,/rt_preempt.h,,;s,/usr/sys/,,'`
 174                  fi
 175                 fi
 176                 if test "$HEADER_RT" = "*" ; then
 177                         AC_MSG_ERROR([Need a configured kernel directory])
 178                 fi
 179                 AC_SUBST([HEADER_RT])
 180                 ;;
 181         *-darwin*)
 182                 MKAFS_OSTYPE=DARWIN
 183                 AC_MSG_RESULT(ppc_darwin)
 184                 ;;
 185         *-freebsd*)
 186                 MKAFS_OSTYPE=FBSD
 187                 AC_MSG_RESULT(i386_fbsd)
 188                 ;;
 189         *-netbsd*)
 190                 MKAFS_OSTYPE=NBSD
 191                 AC_MSG_RESULT(nbsd)
 192                 ;;
 193         *-openbsd*)
 194                 MKAFS_OSTYPE=OBSD
 195                 AC_MSG_RESULT(i386_obsd)
 196                 ;;
 197         *)
 198                 AC_MSG_RESULT($system)
 199                 ;;
 200 esac
 201
 202 if test "x$with_afs_sysname" != "x"; then
 203         AFS_SYSNAME="$with_afs_sysname"
 204 else
 205         AC_MSG_CHECKING(your AFS sysname)
 206         case $host in
 207                 i?86-*-freebsd4.2*)
 208                         AFS_SYSNAME="i386_fbsd_42"
 209                         ;;
 210                 i?86-*-netbsd*1.5*)
 211                         AFS_PARAM_COMMON=param.nbsd15.h
 212                         AFS_SYSNAME="i386_nbsd15"
 213                         ;;
 214                 alpha-*-netbsd*1.5*)
 215                         AFS_PARAM_COMMON=param.nbsd15.h
 216                         AFS_SYSNAME="alpha_nbsd15"
 217                         ;;
 218                 hppa*-hp-hpux11*)
 219                         AFS_SYSNAME="hp_ux110"
 220                         ;;
 221                 hppa*-hp-hpux10*)
 222                         AFS_SYSNAME="hp_ux102"
 223                         ;;
 224                 powerpc-apple-darwin1.2*)
 225                         AFS_SYSNAME="ppc_darwin_12"
 226                         ;;
 227                 powerpc-apple-darwin1.3*)
 228                         AFS_SYSNAME="ppc_darwin_13"
 229                         ;;
 230                 powerpc-apple-darwin1.4*)
 231                         AFS_SYSNAME="ppc_darwin_14"
 232                         ;;
 233                 powerpc-apple-darwin5.1*)
 234                         AFS_SYSNAME="ppc_darwin_51"
 235                         ;;
 236                 sparc-sun-solaris2.5*)
 237                         AFS_SYSNAME="sun4x_55"
 238                         ;;
 239                 sparc-sun-solaris2.6)
 240                         AFS_SYSNAME="sun4x_56"
 241                         ;;
 242                 sparc-sun-solaris2.7)
 243                         AFS_SYSNAME="sun4x_57"
 244                         ;;
 245                 sparc-sun-solaris2.8)
 246                         AFS_SYSNAME="sun4x_58"
 247                         ;;
 248                 sparc-sun-solaris2.9)
 249                         AFS_SYSNAME="sun4x_59"
 250                         ;;
 251                 alpha*-dec-osf4.0*)
 252                         AFS_SYSNAME="alpha_dux40"
 253                         ;;
 254                 alpha*-dec-osf5.0*)
 255                         AFS_SYSNAME="alpha_dux50"
 256                         ;;
 257                 mips-sgi-irix6.5)
 258                         AFS_SYSNAME="sgi_65"
 259                         ;;
 260                 ia64-*-linux*)
 261                         AFS_SYSNAME="ia64_linuxXX"
 262                         ;;
 263                 powerpc-*-linux*)
 264                         AFS_SYSNAME="ppc_linuxXX"
 265                         ;;
 266                 alpha*-linux*)
 267                         AFS_SYSNAME="alpha_linux_XX"
 268                         ;;
 269                 s390-*-linux*)
 270                         AFS_SYSNAME="s390_linuxXX"
 271                         ;;
 272                 sparc-*-linux*)
 273                         AFS_SYSNAME="sparc_linuxXX"
 274                         ;;
 275                 sparc64-*-linux*)
 276                         AFS_SYSNAME="sparc64_linuxXX"
 277                         ;;
 278                 i?86-*-linux*)
 279                         AFS_SYSNAME="i386_linuxXX"
 280                         ;;
 281                 parisc-*-linux-gnu)
 282                         AFS_SYSNAME="parisc_linuxXX"
 283                         ;;
 284                 power*-ibm-aix4.2*)
 285                         AFS_SYSNAME="rs_aix42"
 286                         ;;
 287                 power*-ibm-aix4.3*)
 288                         AFS_SYSNAME="rs_aix42"
 289                         ;;
 290                 *)
 291                         AC_MSG_ERROR(An AFS sysname is required)
 292                         exit 1
 293                         ;;
 294         esac
 295         case $AFS_SYSNAME in
 296                 *_linux*)
 297                         AFS_SYSKVERS=`echo $LINUX_VERSION | awk -F\. '{print $[]1 $[]2}'`
 298                         if test "x${AFS_SYSKVERS}" = "x"; then
 299                          AC_MSG_ERROR(Couldn't guess your Linux version. Please use the --with-afs-sysname option to configure an AFS sysname.)
 300                         fi
 301                         _AFS_SYSNAME=`echo $AFS_SYSNAME|sed s/XX\$/$AFS_SYSKVERS/`
 302                         AFS_SYSNAME="$_AFS_SYSNAME"
 303                         ;;
 304         esac
 305         AC_MSG_RESULT($AFS_SYSNAME)
 306 fi
 307
 308 case $AFS_SYSNAME in
 309         *_darwin*)
 310                 DARWIN_PLIST=src/libafs/afs.${AFS_SYSNAME}.plist
 311                 DARWIN_INFOFILE=afs.${AFS_SYSNAME}.plist
 312                 ;;
 313 esac
 314
 315 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
 316         echo Skipping library tests because they confuse Irix.
 317 else
 318   AC_CHECK_FUNCS(socket)
 319
 320   if test "$ac_cv_func_socket" = no; then
 321     for lib in socket inet; do
 322         if test "$HAVE_SOCKET" != 1; then
 323                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET))
 324         fi
 325     done
 326   fi
 327
 328   AC_CHECK_FUNCS(connect)
 329
 330   if test "$ac_cv_func_connect" = no; then
 331     for lib in nsl; do
 332         if test "$HAVE_CONNECT" != 1; then
 333                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT))
 334         fi
 335     done
 336   fi
 337
 338   AC_CHECK_FUNCS(gethostbyname)
 339   if test "$ac_cv_func_gethostbyname" = no; then
 340         for lib in dns nsl resolv; do
 341           if test "$HAVE_GETHOSTBYNAME" != 1; then
 342             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME))
 343           fi
 344         done
 345   fi
 346
 347   AC_CHECK_FUNCS(res_search)
 348   if test "$ac_cv_func_res_search" = no; then
 349         for lib in dns nsl resolv; do
 350           if test "$HAVE_RES_SEARCH" != 1; then
 351             AC_CHECK_LIB(${lib}, res_search, LIBS="$LIBS -l$lib";HAVE_RES_SEARCH=1;AC_DEFINE(HAVE_RES_SEARCH))
 352           fi
 353         done
 354         if test "$HAVE_RES_SEARCH" = 1; then
 355           LIB_res_search="-l$lib"
 356         fi
 357   fi
 358 fi
 359
 360 PTHREAD_LIBS=error
 361 AC_CHECK_LIB(pthread, pthread_attr_init,
 362              PTHREAD_LIBS="-lpthread")
 363 if test "x$PTHREAD_LIBS" = xerror; then
 364         AC_CHECK_LIB(pthreads, pthread_attr_init,
 365                 PTHREAD_LIBS="-lpthreads")
 366 fi
 367 if test "x$PTHREAD_LIBS" = xerror; then
 368         AC_CHECK_LIB(c_r, pthread_attr_init,
 369                 PTHREAD_LIBS="-lc_r")
 370 fi
 371 if test "x$PTHREAD_LIBS" = xerror; then
 372         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
 373 fi
 374 if test "x$PTHREAD_LIBS" = xerror; then
 375         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
 376 fi
 377 AC_SUBST(PTHREAD_LIBS)
 378
 379 WITH_OBSOLETE=NO
 380 if test "$enable_obsolete" = "yes"; then
 381         WITH_OBSOLETE=YES
 382 fi
 383
 384 WITH_INSECURE=NO
 385 if test "$enable_insecure" = "yes"; then
 386         WITH_INSECURE=YES
 387 fi
 388
 389 # Fast restart
 390 if test "$enable_fast_restart" = "yes"; then
 391         AC_DEFINE(FAST_RESTART)
 392 fi
 393
 394 if test "$enable_bitmap_later" = "yes"; then
 395         AC_DEFINE(BITMAP_LATER)
 396 fi
 397
 398 if test "$enable_full_vos_listvol_switch" = "yes"; then
 399         AC_DEFINE(FULL_LISTVOL_SWITCH)
 400 fi
 401
 402 if test "$enable_bos_restricted_mode" = "yes"; then
 403         AC_DEFINE(BOS_RESTRICTED_MODE)
 404 fi
 405
 406 if test "$enable_namei_fileserver" = "yes"; then
 407         AC_DEFINE(AFS_NAMEI_ENV)
 408 fi
 409
 410 if test "$enable_afsdb" = "yes"; then
 411         LIB_AFSDB="$LIB_res_search"
 412         AC_DEFINE(AFS_AFSDB_ENV)
 413 fi
 414
 415 dnl check for tivoli
 416 AC_MSG_CHECKING(for tivoli tsm butc support)
 417 XBSA_CFLAGS=""
 418 if test "$enable_tivoli_tsm" = "yes"; then
 419         XBSADIR1=/usr/tivoli/tsm/client/api/bin/xopen
 420         XBSADIR2=/opt/tivoli/tsm/client/api/bin/xopen
 421
 422         if test -e "$XBSADIR1/xbsa.h"; then
 423                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR1"
 424                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 425         elif test -e "$XBSADIR2/xbsa.h"; then
 426                 XBSA_CFLAGS="-Dxbsa -I$XBSADIR2"
 427                 AC_MSG_RESULT([yes, $XBSA_CFLAGS])
 428         else
 429                 AC_MSG_RESULT([no, missing xbsa.h header file])
 430         fi
 431 else
 432         AC_MSG_RESULT([no])
 433 fi
 434 AC_SUBST(XBSA_CFLAGS)
 435
 436 dnl checks for header files.
 437 AC_HEADER_STDC
 438 AC_HEADER_SYS_WAIT
 439 AC_HEADER_DIRENT
 440 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
 441 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
 442 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h)
 443 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
 444 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h)
 445 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h)
 446
 447 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf re_comp re_exec)
 448
 449 dnl Directory PATH handling
 450 if test "x$enable_transarc_paths" = "xyes"  ; then
 451     afsconfdir=${afsconfdir=/usr/afs/etc}
 452     viceetcdir=${viceetcdir=/usr/vice/etc}
 453     afskerneldir=${afskerneldir=${viceetcdir}}
 454     afssrvbindir=${afssrvbindir=/usr/afs/bin}
 455     afssrvsbindir=${afssrvsbindir=/usr/afs/bin}
 456     afssrvlibexecdir=${afssrvlibexecdir=/usr/afs/bin}
 457     afsdbdir=${afsdbdir=/usr/afs/db}
 458     afslogsdir=${afslogsdir=/usr/afs/logs}
 459     afslocaldir=${afslocaldir=/usr/afs/local}
 460     afsbackupdir=${afsbackupdir=/usr/afs/backup}
 461     afsbosconfigdir=${afsbosconfigdir=/usr/afs/local}
 462 else
 463     afsconfdir=${afsconfdir='${sysconfdir}/openafs/server'}
 464     viceetcdir=${viceetcdir='${sysconfdir}/openafs'}
 465     afskerneldir=${afskerneldir='${libdir}/openafs'}
 466     afssrvbindir=${afssrvbindir='${bindir}'}
 467     afssrvsbindir=${afssrvsbindir='${sbindir}'}
 468     afssrvlibexecdir=${afssrvlibexecdir='${libexecdir}/openafs'}
 469     afsdbdir=${afsdbdir='${localstatedir}/openafs/db'}
 470     afslogsdir=${afslogsdir='${localstatedir}/openafs/logs'}
 471     afslocaldir=${afslocaldir='${localstatedir}/openafs'}
 472     afsbackupdir=${afsbackupdir='${localstatedir}/openafs/backup'}
 473     afsbosconfigdir=${afsbosconfigdir='${sysconfdir}/openafs'}
 474 fi
 475 AC_SUBST(afsconfdir)
 476 AC_SUBST(viceetcdir)
 477 AC_SUBST(afskerneldir)
 478 AC_SUBST(afssrvbindir)
 479 AC_SUBST(afssrvsbindir)
 480 AC_SUBST(afssrvlibexecdir)
 481 AC_SUBST(afsdbdir)
 482 AC_SUBST(afslogsdir)
 483 AC_SUBST(afslocaldir)
 484 AC_SUBST(afsbackupdir)
 485 AC_SUBST(afsbosconfigdir)
 486
 487 if test "x$enable_kernel_module" = "xyes"; then
 488 ENABLE_KERNEL_MODULE=libafs
 489 fi
 490
 491 AC_SUBST(AFS_SYSNAME)
 492 AC_SUBST(AFS_PARAM_COMMON)
 493 AC_SUBST(ENABLE_KERNEL_MODULE)
 494 AC_SUBST(LIB_AFSDB)
 495 AC_SUBST(LINUX_KERNEL_PATH)
 496 AC_SUBST(LINUX_VERSION)
 497 AC_SUBST(MKAFS_OSTYPE)
 498 AC_SUBST(TOP_OBJDIR)
 499 AC_SUBST(TOP_SRCDIR)
 500 AC_SUBST(TOP_INCDIR)
 501 AC_SUBST(TOP_LIBDIR)
 502 AC_SUBST(DEST)
 503 AC_SUBST(WITH_OBSOLETE)
 504 AC_SUBST(WITH_INSECURE)
 505 AC_SUBST(DARWIN_INFOFILE)
 506 AC_SUBST(IRIX_BUILD_IP35)
 507
 508 OPENAFS_OSCONF
 509
 510 ])