configure.in

   1 AC_INIT(src/config/stds.h)
   2 AM_INIT_AUTOMAKE(openafs,devel)
   3 AC_CANONICAL_HOST
   4 AC_CONFIG_HEADER(src/config/afsconfig.h)
   5
   6 #BOZO_SAVE_CORES BOS_RESTRICTED_MODE BOS_NEW_CONFIG pam sia
   7 AC_ARG_WITH(afs-sysname,
   8 [  --with-afs-sysname=sys    use sys for the afs sysname]
   9 )
  10 AC_ARG_ENABLE( obsolete,
  11 [  --enable-obsolete                    enable obsolete portions of AFS (mpp, ntp and package)],, enable_obsolete="no")
  12 AC_ARG_ENABLE( insecure,
  13 [  --enable-insecure                    enable insecure portions of AFS (ftpd, inetd, rcp, rlogind and rsh)],, enable_insecure="no")
  14 AC_ARG_ENABLE( afsdb,
  15 [  --disable-afsdb                      disable AFSDB RR support],, enable_afsdb="yes")
  16 AC_ARG_ENABLE( bos-restricted-mode,
  17 [  --enable-bos-restricted-mode         enable bosserver restricted mode which disables certain bosserver functionality],, enable_bos_restricted_mode="no")
  18 AC_ARG_ENABLE( namei-fileserver,
  19 [  --enable-namei-fileserver            force compilation of namei fileserver in preference to inode fileserver],, enable_namei_fileserver="no")
  20 AC_ARG_ENABLE( fast-restart,
  21 [  --enable-fast-restart                enable fast startup of file server without salvaging],, enable_fast_restart="no")
  22 AC_ARG_ENABLE( bitmap-later,
  23 [  --enable-bitmap-later                enable fast startup of file server by not reading bitmap till needed],, enable_bitmap_later="no")
  24 AC_ARG_WITH(linux-kernel-headers,
  25 [  --with-linux-kernel-headers=path     use the kernel headers found at path(optional, defaults to /usr/src/linux)]
  26 )
  27 AC_ARG_ENABLE(kernel-module,
  28 [  --disable-kernel-module              disable compilation of the kernel module (defaults to enabled)],, enable_kernel_module="yes"
  29 )
  30
  31 AC_PROG_CC
  32
  33 dnl weird ass systems
  34 AC_AIX
  35 AC_ISC_POSIX
  36 AC_MINIX
  37
  38 dnl Various compiler setup.
  39 AC_C_INLINE
  40 AC_C_CONST
  41 AC_TYPE_PID_T
  42 AC_TYPE_SIZE_T
  43 AC_TYPE_SIGNAL
  44
  45 dnl Checks for programs.
  46 AC_PROG_INSTALL
  47 AC_PROG_LN_S
  48 AC_PROG_RANLIB
  49 AC_PROG_YACC
  50 AM_PROG_LEX
  51
  52 OPENAFS_CHECK_BIGENDIAN
  53
  54 AC_MSG_CHECKING(your OS)
  55 system=$host
  56 case $system in
  57         *-linux*)
  58                 MKAFS_OSTYPE=LINUX
  59                 if test "x$enable_kernel_module" = "xyes"; then
  60                  if test "x$with_linux_kernel_headers" != "x"; then
  61                    LINUX_KERNEL_PATH="$with_linux_kernel_headers"
  62                  else
  63                    LINUX_KERNEL_PATH="/usr/src/linux"
  64                  fi
  65                  if test -f "$LINUX_KERNEL_PATH/include/linux/version.h"; then
  66                   linux_kvers=`fgrep UTS_RELEASE $LINUX_KERNEL_PATH/include/linux/version.h |awk 'BEGIN { FS="\"" } { print $2 }'|tail -1`
  67                   if test "x$linux_kvers" = "x"; then
  68                     AC_MSG_ERROR(Linux headers lack version definition)
  69                     exit 1
  70                   else
  71                     LINUX_VERSION="$linux_kvers"
  72                   fi
  73                  else
  74                     enable_kernel_module="no"
  75                  fi
  76                  if test ! -f "$LINUX_KERNEL_PATH/include/linux/autoconf.h"; then
  77                      enable_kernel_module="no"
  78                  fi
  79                  if test "x$enable_kernel_module" = "xno"; then
  80                   if test "x$with_linux_kernel_headers" != "x"; then
  81                    AC_MSG_ERROR(No usable linux headers found at $LINUX_KERNEL_PATH)
  82                    exit 1
  83                   else
  84                    AC_MSG_WARN(No usable linux headers found at $LINUX_KERNEL_PATH so disabling kernel module)
  85                   fi
  86                  fi
  87                 fi
  88                 AC_MSG_RESULT(linux)
  89                 if test "x$enable_kernel_module" = "xyes"; then
  90                  LINUX_FS_STRUCT_INODE_HAS_I_BYTES
  91                  LINUX_INODE_SETATTR_RETURN_TYPE
  92                  LINUX_NEED_RHCONFIG
  93                  LINUX_WHICH_MODULES
  94                 :
  95                 fi
  96                 ;;
  97         *-solaris*)
  98                 MKAFS_OSTYPE=SOLARIS
  99                 AC_MSG_RESULT(sun4)
 100                 ;;
 101         *-hpux*)
 102                 MKAFS_OSTYPE=HPUX
 103                 AC_MSG_RESULT(hp_ux)
 104                 ;;
 105         *-irix*)
 106                 MKAFS_OSTYPE=IRIX
 107                 AC_MSG_RESULT(sgi)
 108                 ;;
 109         *-aix*)
 110                 MKAFS_OSTYPE=AIX
 111                 AC_MSG_RESULT(rs_aix)
 112                 ;;
 113         *-osf*)
 114                 MKAFS_OSTYPE=DUX
 115                 AC_MSG_RESULT(alpha_dux)
 116                 ;;
 117         *-darwin*)
 118                 MKAFS_OSTYPE=DARWIN
 119                 AC_MSG_RESULT(ppc_darwin)
 120                 ;;
 121         *-freebsd*)
 122                 MKAFS_OSTYPE=FBSD
 123                 AC_MSG_RESULT(i386_fbsd)
 124                 ;;
 125         *)
 126                 AC_MSG_RESULT($system)
 127                 ;;
 128 esac
 129
 130 if test "x${MKAFS_OSTYPE}" = "xIRIX"; then
 131         echo Skipping library tests because they confuse Irix.
 132 else
 133   AC_CHECK_FUNCS(socket)
 134
 135   if test "$ac_cv_func_socket" = no; then
 136     for lib in socket inet; do
 137         if test "$HAVE_SOCKET" != 1; then
 138                 AC_CHECK_LIB(${lib}, socket,LIBS="$LIBS -l$lib";HAVE_SOCKET=1;AC_DEFINE(HAVE_SOCKET))
 139         fi
 140     done
 141   fi
 142
 143   AC_CHECK_FUNCS(connect)
 144
 145   if test "$ac_cv_func_connect" = no; then
 146     for lib in nsl; do
 147         if test "$HAVE_CONNECT" != 1; then
 148                 AC_CHECK_LIB(${lib}, connect,LIBS="$LIBS -l$lib";HAVE_CONNECT=1;AC_DEFINE(HAVE_CONNECT))
 149         fi
 150     done
 151   fi
 152
 153   AC_CHECK_FUNCS(gethostbyname)
 154   if test "$ac_cv_func_gethostbyname" = no; then
 155         for lib in dns nsl resolv; do
 156           if test "$HAVE_GETHOSTBYNAME" != 1; then
 157             AC_CHECK_LIB(${lib}, gethostbyname, LIBS="$LIBS -l$lib";HAVE_GETHOSTBYNAME=1;AC_DEFINE(HAVE_GETHOSTBYNAME))
 158           fi
 159         done
 160   fi
 161
 162   AC_CHECK_FUNCS(res_search)
 163   if test "$ac_cv_func_res_search" = no; then
 164         for lib in dns nsl resolv; do
 165           if test "$HAVE_RES_SEARCH" != 1; then
 166             AC_CHECK_LIB(${lib}, res_search, LIBS="$LIBS -l$lib";HAVE_RES_SEARCH=1;AC_DEFINE(HAVE_RES_SEARCH))
 167           fi
 168         done
 169         if test "$HAVE_RES_SEARCH" = 1; then
 170           LIB_res_search="-l$lib"
 171         fi
 172   fi
 173 fi
 174
 175 PTHREAD_LIBS=error
 176 AC_CHECK_LIB(pthread, pthread_attr_init,
 177              PTHREAD_LIBS="-lpthread")
 178 if test "x$PTHREAD_LIBS" = xerror; then
 179         AC_CHECK_LIB(pthreads, pthread_attr_init,
 180                 PTHREAD_LIBS="-lpthreads")
 181 fi
 182 if test "x$PTHREAD_LIBS" = xerror; then
 183         AC_CHECK_LIB(c_r, pthread_attr_init,
 184                 PTHREAD_LIBS="-lc_r")
 185 fi
 186 if test "x$PTHREAD_LIBS" = xerror; then
 187         AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
 188 fi
 189 if test "x$PTHREAD_LIBS" = xerror; then
 190         AC_MSG_WARN(*** Unable to locate working posix thread library ***)
 191 fi
 192 AC_SUBST(PTHREAD_LIBS)
 193
 194 WITH_OBSOLETE=NO
 195 if test "$enable_obsolete" = "yes"; then
 196         WITH_OBSOLETE=YES
 197 fi
 198
 199 WITH_INSECURE=NO
 200 if test "$enable_insecure" = "yes"; then
 201         WITH_INSECURE=YES
 202 fi
 203
 204 # Fast restart
 205 if test "$enable_fast_restart" = "yes"; then
 206         AC_DEFINE(FAST_RESTART)
 207 fi
 208
 209 if test "$enable_bitmap_later" = "yes"; then
 210         AC_DEFINE(BITMAP_LATER)
 211 fi
 212
 213 # Should autocompute a default
 214 if test "x$with_afs_sysname" != "x"; then
 215         AFS_SYSNAME="$with_afs_sysname"
 216 else
 217         AC_MSG_ERROR(An AFS sysname is required)
 218         exit 1
 219 fi
 220
 221 if test "$enable_bos_restricted_mode" = "yes"; then
 222         AC_DEFINE(BOS_RESTRICTED_MODE)
 223 fi
 224
 225 if test "$enable_namei_fileserver" = "yes"; then
 226         AC_DEFINE(AFS_NAMEI_ENV)
 227 fi
 228
 229 if test "$enable_afsdb" = "yes"; then
 230         LIB_AFSDB="$LIB_res_search"
 231         AC_DEFINE(AFS_AFSDB_ENV)
 232 fi
 233
 234 SRCDIR_PARENT=`pwd`
 235 TOP_SRCDIR="${SRCDIR_PARENT}/src"
 236
 237 dnl checks for header files.
 238 AC_HEADER_STDC
 239 AC_HEADER_SYS_WAIT
 240 AC_HEADER_DIRENT
 241 AC_CHECK_HEADERS(stdlib.h string.h unistd.h fcntl.h sys/time.h sys/file.h)
 242 AC_CHECK_HEADERS(netinet/in.h netdb.h sys/fcntl.h sys/mnttab.h sys/mntent.h)
 243 AC_CHECK_HEADERS(mntent.h sys/vfs.h sys/param.h sys/fs_types.h)
 244 AC_CHECK_HEADERS(sys/mount.h strings.h termios.h signal.h)
 245 AC_CHECK_HEADERS(windows.h malloc.h winsock2.h direct.h io.h)
 246 AC_CHECK_HEADERS(security/pam_modules.h siad.h usersec.h)
 247
 248 AC_CHECK_FUNCS(utimes random srandom getdtablesize snprintf re_comp re_exec)
 249
 250 if test "x$enable_kernel_module" = "xyes"; then
 251 ENABLE_KERNEL_MODULE=libafs
 252 fi
 253
 254 AC_SUBST(AFS_SYSNAME)
 255 AC_SUBST(ENABLE_KERNEL_MODULE)
 256 AC_SUBST(LIB_AFSDB)
 257 AC_SUBST(LINUX_KERNEL_PATH)
 258 AC_SUBST(LINUX_VERSION)
 259 AC_SUBST(MKAFS_OSTYPE)
 260 AC_SUBST(TOP_SRCDIR)
 261 AC_SUBST(WITH_OBSOLETE)
 262 AC_SUBST(WITH_INSECURE)
 263
 264 AC_OUTPUT(             \
 265 Makefile               \
 266 src/config/Makefile.${AFS_SYSNAME} \
 267 src/libafs/MakefileProto.${MKAFS_OSTYPE} \
 268 )