src/cf/linux-test3.m4

   1 AC_DEFUN([LINUX_KERNEL_LINUX_SYSCALL_H],[
   2   AC_MSG_CHECKING(for linux/syscall.h in kernel)
   3   if test -f "${LINUX_KERNEL_PATH}/include/linux/syscall.h"; then
   4     ac_linux_syscall=yes
   5     AC_MSG_RESULT($ac_linux_syscall)
   6   else
   7     ac_linux_syscall=no
   8     AC_MSG_RESULT($ac_linux_syscall)
   9   fi
  10 ])
  11
  12 AC_DEFUN([LINUX_NEED_RHCONFIG],[
  13 RHCONFIG_SP=""
  14 RHCONFIG_MP=""
  15 if test "x$enable_redhat_buildsys" = "xyes"; then
  16   AC_MSG_WARN(Configured to build from a Red Hat SPEC file)
  17 else
  18   AC_MSG_CHECKING(for redhat kernel configuration)
  19   if test -f "${LINUX_KERNEL_PATH}/include/linux/rhconfig.h"; then
  20     ac_linux_rhconfig=yes
  21     RHCONFIG_SP="-D__BOOT_KERNEL_UP=1 -D__BOOT_KERNEL_SMP=0"
  22     RHCONFIG_MP="-D__BOOT_KERNEL_UP=0 -D__BOOT_KERNEL_SMP=1"
  23     AC_MSG_RESULT($ac_linux_rhconfig)
  24     if test ! -f "/boot/kernel.h"; then
  25         AC_MSG_WARN([/boot/kernel.h does not exist. build may fail])
  26     fi
  27   else
  28     ac_linux_rhconfig=no
  29     AC_MSG_RESULT($ac_linux_rhconfig)
  30   fi
  31 fi
  32 AC_SUBST(RHCONFIG_SP)
  33 AC_SUBST(RHCONFIG_MP)
  34 ])
  35
  36
  37 dnl This depends on LINUX_CONFIG_H_EXISTS running first!
  38
  39 AC_DEFUN([LINUX_WHICH_MODULES],[
  40 if test "x$enable_redhat_buildsys" = "xyes"; then
  41   MPS=Default
  42 else
  43   save_CPPFLAGS="$CPPFLAGS"
  44   CPPFLAGS="-I${LINUX_KERNEL_PATH}/include -D__KERNEL__ $RHCONFIG_SP $CPPFLAGS"
  45   AC_MSG_CHECKING(which kernel modules to build)
  46   if test "x$ac_cv_linux_config_h_exists" = "xyes"; then
  47     CPPFLAGS="-DCONFIG_H_EXISTS $CPPFLAGS"
  48   fi
  49   if test "x$ac_linux_rhconfig" = "xyes"; then
  50       MPS="MP SP"
  51   else
  52   AC_CACHE_VAL(ac_cv_linux_config_smp, [
  53   AC_TRY_KBUILD(
  54 [#ifdef CONFIG_H_EXISTS
  55 #include <linux/config.h>
  56 #endif
  57 ],
  58 [#ifndef CONFIG_SMP
  59 lose;
  60 #endif
  61 ],
  62   ac_cv_linux_config_smp=yes,
  63   ac_cv_linux_config_smp=no)])
  64   dnl AC_MSG_RESULT($ac_cv_linux_config_smp)
  65       if test "x$ac_cv_linux_config_smp" = "xyes"; then
  66           MPS=MP
  67       else
  68           MPS=SP
  69       fi
  70   fi
  71   CPPFLAGS=$save_CPPFLAGS
  72   AC_MSG_RESULT($MPS)
  73 fi
  74 AC_SUBST(MPS)
  75 ])
  76
  77 AC_DEFUN([LINUX_KERNEL_SELINUX],[
  78 AC_MSG_CHECKING(for SELinux kernel)
  79 save_CPPFLAGS="$CPPFLAGS"
  80 CPPFLAGS="-I${LINUX_KERNEL_PATH}/include $CPPFLAGS"
  81 AC_CACHE_VAL(ac_cv_linux_kernel_is_selinux,
  82 [
  83 AC_TRY_COMPILE(
  84   [#include <linux/autoconf.h>],
  85   [#ifndef CONFIG_SECURITY_SELINUX
  86    #error not SELINUX
  87    #endif],
  88   ac_cv_linux_kernel_is_selinux=yes,
  89   ac_cv_linux_kernel_is_selinux=no)])
  90 AC_MSG_RESULT($ac_cv_linux_kernel_is_selinux)
  91 CPPFLAGS="$save_CPPFLAGS"])
  92
  93 AC_DEFUN([LINUX_KERNEL_LINUX_SEQ_FILE_H],[
  94   AC_MSG_CHECKING(for linux/seq_file.h in kernel)
  95   if test -f "${LINUX_KERNEL_PATH}/include/linux/seq_file.h"; then
  96     ac_linux_seq_file=yes
  97     AC_MSG_RESULT($ac_linux_seq_file)
  98   else
  99     ac_linux_seq_file=no
 100     AC_MSG_RESULT($ac_linux_seq_file)
 101   fi
 102 ])