src/cf/linux-test3.m4

   1 AC_DEFUN([LINUX_KERNEL_LINUX_SYSCALL_H],[
   2   AC_MSG_CHECKING(for linux/syscall.h in kernel)
   3   if test -f "${LINUX_KERNEL_PATH}/include/linux/syscall.h"; then
   4     ac_linux_syscall=yes
   5     AC_MSG_RESULT($ac_linux_syscall)
   6   else
   7     ac_linux_syscall=no
   8     AC_MSG_RESULT($ac_linux_syscall)
   9   fi
  10 ])
  11
  12 AC_DEFUN([LINUX_NEED_RHCONFIG],[
  13 RHCONFIG_SP=""
  14 RHCONFIG_MP=""
  15 if test "x$enable_redhat_buildsys" = "xyes"; then
  16   AC_MSG_WARN(Configured to build from a Red Hat SPEC file)
  17 else
  18   AC_MSG_CHECKING(for redhat kernel configuration)
  19   if test -f "${LINUX_KERNEL_PATH}/include/linux/rhconfig.h"; then
  20     ac_linux_rhconfig=yes
  21     RHCONFIG_SP="-D__BOOT_KERNEL_UP=1 -D__BOOT_KERNEL_SMP=0"
  22     RHCONFIG_MP="-D__BOOT_KERNEL_UP=0 -D__BOOT_KERNEL_SMP=1"
  23     AC_MSG_RESULT($ac_linux_rhconfig)
  24     if test ! -f "/boot/kernel.h"; then
  25         AC_MSG_WARN([/boot/kernel.h does not exist. build may fail])
  26     fi
  27   else
  28     ac_linux_rhconfig=no
  29     AC_MSG_RESULT($ac_linux_rhconfig)
  30   fi
  31 fi
  32 AC_SUBST(RHCONFIG_SP)
  33 AC_SUBST(RHCONFIG_MP)
  34 ])
  35
  36 AC_DEFUN([LINUX_WHICH_MODULES],[
  37 if test "x$enable_redhat_buildsys" = "xyes"; then
  38   MPS=Default
  39 else
  40   save_CPPFLAGS="$CPPFLAGS"
  41   CPPFLAGS="-I${LINUX_KERNEL_PATH}/include -D__KERNEL__ $RHCONFIG_SP $CPPFLAGS"
  42   AC_MSG_CHECKING(if kernel uses MODVERSIONS)
  43   AC_CACHE_VAL(ac_cv_linux_config_modversions,[
  44   AC_TRY_COMPILE(
  45 [#include <linux/version.h>
  46 #include <linux/config.h>
  47 ],
  48 [#if !defined(CONFIG_MODVERSIONS) || (LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0))
  49 lose;
  50 #endif
  51 ],
  52   ac_cv_linux_config_modversions=yes,
  53   ac_cv_linux_config_modversions=no)])
  54   AC_MSG_RESULT($ac_cv_linux_config_modversions)
  55   AC_MSG_CHECKING(which kernel modules to build)
  56   if test "x$ac_linux_rhconfig" = "xyes" -o "x$ac_cv_linux_config_modversions" = "xno"; then
  57       MPS="MP SP"
  58   else
  59   AC_CACHE_VAL(ac_cv_linux_config_smp, [
  60   AC_TRY_COMPILE(
  61 [#include <linux/config.h>
  62 ],
  63 [#ifndef CONFIG_SMP
  64 lose;
  65 #endif
  66 ],
  67   ac_cv_linux_config_smp=yes,
  68   ac_cv_linux_config_smp=no)])
  69   dnl AC_MSG_RESULT($ac_cv_linux_config_smp)
  70       if test "x$ac_cv_linux_config_smp" = "xyes"; then
  71           MPS=MP
  72       else
  73           MPS=SP
  74       fi
  75   fi
  76   CPPFLAGS=$save_CPPFLAGS
  77   AC_MSG_RESULT($MPS)
  78 fi
  79 AC_SUBST(MPS)
  80 ])
  81
  82 AC_DEFUN([LINUX_KERNEL_SELINUX],[
  83 AC_MSG_CHECKING(for SELinux kernel)
  84 save_CPPFLAGS="$CPPFLAGS"
  85 CPPFLAGS="-I${LINUX_KERNEL_PATH}/include $CPPFLAGS"
  86 AC_CACHE_VAL(ac_cv_linux_kernel_is_selinux,
  87 [
  88 AC_TRY_COMPILE(
  89   [#include <linux/autoconf.h>],
  90   [#ifndef CONFIG_SECURITY_SELINUX
  91    #error not SELINUX
  92    #endif],
  93   ac_cv_linux_kernel_is_selinux=yes,
  94   ac_cv_linux_kernel_is_selinux=no)])
  95 AC_MSG_RESULT($ac_cv_linux_kernel_is_selinux)
  96 CPPFLAGS="$save_CPPFLAGS"])
  97
  98 AC_DEFUN([LINUX_KERNEL_SOCK_CREATE],[
  99 AC_MSG_CHECKING(for 5th argument in sock_create found in some SELinux kernels)
 100 save_CPPFLAGS="$CPPFLAGS"
 101 CPPFLAGS="-I${LINUX_KERNEL_PATH}/include -D__KERNEL__ $CPPFLAGS"
 102 AC_CACHE_VAL(ac_cv_linux_kernel_sock_create_v,
 103 [
 104 AC_TRY_COMPILE(
 105   [#include <linux/net.h>],
 106   [
 107   sock_create(0,0,0,0,0)
 108   ],
 109   ac_cv_linux_kernel_sock_create_v=yes,
 110   ac_cv_linux_kernel_sock_create_v=no)])
 111 AC_MSG_RESULT($ac_cv_linux_kernel_sock_create_v)
 112 CPPFLAGS="$save_CPPFLAGS"])
 113