2abd444f9e9955440f4c2cd922be21e334de448a
[openafs.git] / src / cf / ressearch.m4
1 AC_DEFUN([AC_CHECK_RESOLV_RETRANS],[
2   AC_CACHE_CHECK([for retransmit support in res_state],
3     [ac_cv_res_retransretry],[
4     AC_TRY_COMPILE( [
5 #include <sys/types.h>
6 #if defined(__sun__)
7 #include <inet/ip.h>
8 #endif
9 #include <resolv.h>
10 ],[
11     _res.retrans = 2;
12     _res.retry = 1;
13 ],
14       [ac_cv_res_retransretry="yes"],
15       [ac_cv_res_retransretry="no"])
16   ])
17   AS_IF([test "$ac_cv_res_retransretry" = "yes"],
18         [AC_DEFINE([HAVE_RES_RETRANSRETRY], 1,
19            [Define if resolv.h's res_state has the fields retrans/retry])
20   ])
21 ])
22
23 AC_DEFUN([AC_FUNC_RES_SEARCH], [
24   ac_cv_func_res_search=no
25   AC_TRY_LINK([
26 #include <sys/types.h>
27 #include <netinet/in.h>
28 #include <arpa/nameser.h>
29 #ifdef HAVE_ARPA_NAMESER_COMPAT_H
30 #include <arpa/nameser_compat.h>
31 #endif
32 #include <resolv.h>],
33   [
34 const char host[11]="openafs.org";
35 u_char ans[1024];
36 int r;
37 res_init();
38 /* Capture result in r but return 0, since a working nameserver is
39  * not a requirement for compilation.
40  */
41 r =  res_search( host, C_IN, T_MX, (u_char *)&ans, sizeof(ans));
42 return 0;
43   ],
44   ac_cv_func_res_search=yes)
45 ])