src/cf/socket.m4

   1 AC_DEFUN([OPENAFS_SOCKET_CHECKS],[
   2 AC_CACHE_CHECK([if struct sockaddr has sa_len field],
   3     [ac_cv_sockaddr_len],
   4     [AC_TRY_COMPILE( [#include <sys/types.h>
   5 #include <sys/socket.h>],
   6                      [struct sockaddr *a; a->sa_len=0;],
   7                      [ac_cv_sockaddr_len=yes],
   8                      [ac_cv_sockaddr_len=no])
   9 ])
  10 AS_IF([test "$ac_cv_sockaddr_len" = "yes"],
  11       [AC_DEFINE(STRUCT_SOCKADDR_HAS_SA_LEN, 1,
  12                  [define if you struct sockaddr sa_len])])
  13 ])
  14
  15 AC_DEFUN([OPENAFS_SOCKOPT_CHECK],[
  16 AC_CACHE_CHECK([for setsockopt(, SOL_IP, IP_RECVERR)],
  17     [ac_cv_setsockopt_iprecverr],
  18     [AC_TRY_COMPILE( [
  19 #include <sys/types.h>
  20 #include <sys/socket.h>
  21 #include <netinet/in.h>],
  22 [int on=1;
  23 setsockopt(0, SOL_IP, IP_RECVERR, &on, sizeof(on));],
  24         [ac_cv_setsockopt_iprecverr=yes],
  25         [ac_cv_setsockopt_iprecverr=no])])
  26
  27 AS_IF([test "$ac_cv_setsockopt_iprecverr" = "yes"],
  28       [AC_DEFINE([HAVE_SETSOCKOPT_IP_RECVERR], [1],
  29                  [define if we can receive socket errors via IP_RECVERR])])
  30 ])