src/packaging/RedHat/makesrpm.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::Dir;
   7 use IO::File;
   8 use File::Path;
   9 use File::Copy;
  10 use File::Temp;
  11
  12 # Build an SRPM for OpenAFS, given a src and doc tarball, release notes,
  13 # and ChangeLog.
  14
  15 my $srcball = shift;
  16 my $docball = shift;
  17 my $relnotes = shift;
  18 my $changelog = shift;
  19 my $cellservdb = shift;
  20
  21 if (!$srcball && !$docball) {
  22   printf "Usage:  makesrpm <src.tar.bz2> <doc.tar.bz2> [<relnotes> [<changelog> [<cellservdb>]]]\n";
  23   exit(1);
  24 }
  25
  26 if (! -f $srcball) {
  27   die "Unable to open $srcball\n";
  28 }
  29
  30 my $tmpdir = File::Temp::tempdir(CLEANUP => 1);
  31
  32 system("tar -C $tmpdir -xvjf $srcball '\*/configure.in' ".
  33        "'\*/src/packaging/RedHat' > /dev/null")==0
  34   or die "Unable to unpack src tar ball\n";
  35
  36 my $dirh = IO::Dir->new($tmpdir);
  37 my $vdir;
  38 while (defined($vdir = $dirh->read) && $vdir=~/^\./) {};
  39
  40 die "Unable to find unpacked source code\n" if !$vdir;
  41
  42 my $srcdir = $tmpdir."/".$vdir;
  43
  44 # Work out which version we're dealing with from the configure.in file
  45 my $afsversion;
  46 my $linuxver;
  47 my $linuxrel;
  48 my $fh = new IO::File $srcdir."/configure.in"
  49   or die "Unable to find unpacked configure.in file";
  50 while(<$fh>) {
  51   next if (/^\s*\#/);
  52
  53   if (/AM_INIT_AUTOMAKE\(openafs,(.*)\)/) {
  54     $afsversion = $1;
  55     next;
  56   }
  57   if (/LINUX_PKGVER=(.*)/) {
  58     $linuxver = $1;
  59     next;
  60   }
  61   if (/LINUX_PKGREL=(.*)/) {
  62     $linuxrel = $1;
  63     next;
  64   }
  65 }
  66 undef $fh;
  67
  68 # Build the RPM root
  69
  70 print "Building version $afsversion\n";
  71 File::Path::mkpath([ $tmpdir."/rpmdir/SPECS",
  72                      $tmpdir."/rpmdir/SRPMS",
  73                      $tmpdir."/rpmdir/SOURCES"], 0, 0755);
  74
  75 File::Copy::copy($srcball,
  76                  $tmpdir."/rpmdir/SOURCES/openafs-$afsversion-src.tar.bz2")
  77   or die "Unable to copy $srcball into position\n";
  78
  79 File::Copy::copy($docball,
  80                  $tmpdir."/rpmdir/SOURCES/openafs-$afsversion-doc.tar.bz2")
  81   or die "Unable to copy $docball into position\n";
  82
  83 # Populate it with all the stuff in the packaging directory, except the
  84 # specfile
  85 my $pkgdirh = IO::Dir->new($srcdir."/src/packaging/RedHat")
  86   or die "Unable to find RedHat packaging directory\n";
  87 my $file;
  88 while (defined($file = $pkgdirh->read)) {
  89   if (-f $srcdir."/src/packaging/RedHat/".$file) {
  90      next if $file eq "openafs.spec.in";
  91
  92      print "Copying $file into place\n";
  93      File::Copy::copy($srcdir."/src/packaging/RedHat/".$file,
  94                       $tmpdir."/rpmdir/SOURCES/".$file);
  95   }
  96 }
  97 undef $dirh;
  98
  99 # Some files need particular modes.
 100 chmod 0755, $tmpdir."/rpmdir/SOURCES/openafs-kernel-version.sh";
 101 chmod 0755, $tmpdir."/rpmdir/SOURCES/openafs-kvers-is.sh";
 102
 103 # Create the specfile. Use sed for this, cos its easier
 104 system("cat ".$srcdir."/src/packaging/RedHat/openafs.spec.in | ".
 105        "sed -e 's/\@VERSION\@/$afsversion/g' ".
 106        "    -e 's/\@LINUX_PKGVER\@/$linuxver/g' ".
 107        "    -e 's/\@LINUX_PKGREL\@/$linuxrel/g' ".
 108        "    -e 's/\%define afsvers.*/%define afsvers $afsversion/g' ".
 109        "    -e 's/\%define pkgvers.*/%define pkgvers $linuxver/g' > ".
 110        $tmpdir."/rpmdir/SPECS/openafs.spec") == 0
 111   or die "sed failed : $!\n";
 112
 113 if ($cellservdb) {
 114     File::Copy::copy($cellservdb,
 115                      $tmpdir."/rpmdir/SOURCES/$cellservdb")
 116         or die "Unable to copy $cellservdb into position\n";
 117 } else {
 118     system("cd ".$tmpdir."/rpmdir/SOURCES && wget `cat ".$srcdir."/src/packaging/RedHat/openafs.spec.in |grep dl/cellservdb |awk '{print \$2}'`")
 119 }
 120
 121 if ($relnotes) {
 122   File::Copy::copy($relnotes,
 123                    $tmpdir."/rpmdir/SOURCES/RELNOTES-$afsversion")
 124   or die "Unable to copy $relnotes into position\n";
 125 } else {
 126   print "WARNING: No release notes provided. Using empty file\n";
 127   system("touch $tmpdir/rpmdir/SOURCES/RELNOTES-$afsversion");
 128 }
 129
 130 if ($changelog) {
 131   File::Copy::copy($changelog,
 132                    $tmpdir."/rpmdir/SOURCES/ChangeLog")
 133   or die "Unable to copy $changelog into position\n";
 134 } else {
 135   print "WARNING: No changelog provided. Using empty file\n";
 136   system("touch $tmpdir/rpmdir/SOURCES/ChangeLog");
 137 }
 138
 139 # Build an RPM
 140 system("rpmbuild -bs --define \"_topdir $tmpdir/rpmdir\" ".
 141        "$tmpdir/rpmdir/SPECS/openafs.spec > /dev/null") == 0
 142   or die "rpmbuild failed : $!\n";
 143
 144 # Copy it out to somewhere useful
 145 File::Copy::copy("$tmpdir/rpmdir/SRPMS/openafs-$linuxver-1.$linuxrel.src.rpm",
 146                  "openafs-$linuxver-1.$linuxrel.src.rpm")
 147   or die "Unable to copy output RPM : $!\n";
 148
 149 print "SRPM is openafs-$linuxver-1.$linuxrel.src.rpm\n";
 150