Linux: Add autoconf macro for structure checks

[openafs.git] / src / cf / linux-test1.m4

diff --git a/src/cf/linux-test1.m4 b/src/cf/linux-test1.m4
index 0b40eb7..6545717 100644 (file)
--- a/src/cf/linux-test1.m4
+++ b/src/cf/linux-test1.m4
@@ -84,3 +84,49 @@ AC_DEFUN([LINUX_KBUILD_USES_EXTRA_CFLAGS], [
     ac_linux_kbuild_requires_extra_cflags=yes)
     CPPFLAGS="$save_CPPFLAGS"
     AC_MSG_RESULT($ac_linux_kbuild_requires_extra_cflags)])
+
+dnl AC_CHECK_LINUX_HEADER(header)
+AC_DEFUN([AC_CHECK_LINUX_HEADER],
+ [AS_VAR_PUSHDEF([ac_linux_header], [ac_cv_linux_header_$1])dnl
+  AC_CACHE_CHECK([for linux/$1], [ac_linux_header],
+   [AC_TRY_KBUILD([#include <linux/$1>],
+                 [return;],
+                 AS_VAR_SET([ac_linux_header], [yes]),
+                 AS_VAR_SET([ac_linux_header], [no]))
+   ])
+  AS_IF([test AS_VAR_GET([ac_linux_header]) = yes],
+        [AC_DEFINE(AS_TR_CPP(HAVE_LINUX_$1),
+                 1,
+                 [Define if your kernel has linux/$1])])
+ ])
+
+dnl AC_CHECK_LINUX_FUNC([function], [includes], [code])
+AC_DEFUN([AC_CHECK_LINUX_FUNC],
+ [AS_VAR_PUSHDEF([ac_linux_func], [ac_cv_linux_func_$1])dnl
+  AC_CACHE_CHECK([for $1], [ac_linux_func],
+    [save_CPPFLAGS="$CPPFLAGS"
+     CPPFLAGS="$CPPFLAGS -Werror-implicit-function-declaration"
+     AC_TRY_KBUILD([$2], [$3],
+                  AS_VAR_SET([ac_linux_func], [yes]),
+                  AS_VAR_SET([ac_linux_func], [no]))
+     CPPFLAGS="$save_CPPFLAGS"
+    ])
+  AS_IF([test AS_VAR_GET([ac_linux_func]) = yes],
+       [AC_DEFINE(AS_TR_CPP(HAVE_LINUX_$1), 1,
+                  [Define if your kernel has the $1 function])])
+ ])
+
+dnl AC_CHECK_LINUX_STRUCT([structure], [element], [includes])
+AC_DEFUN([AC_CHECK_LINUX_STRUCT],
+ [AS_VAR_PUSHDEF([ac_linux_struct], [ac_cv_linux_struct_$1_has_$2])dnl
+  AC_CACHE_CHECK([for $2 in struct $1], [ac_linux_struct],
+   [AC_TRY_KBUILD([#include <linux/$3>],
+                 [struct $1 _test; printk("%x\n", &_test.$2); ],
+                 AS_VAR_SET([ac_linux_struct], [yes]),
+                 AS_VAR_SET([ac_linux_struct], [no]))
+   ])
+  AS_IF([test AS_VAR_GET([ac_linux_struct]) = yes],
+       [AC_DEFINE(AS_TR_CPP(STRUCT_$1_HAS_$2), 1,
+                  [Define if kernel struct $1 has the $2 element])])
+ ])
+